lisp/find-dired.el

   1 ;;; find-dired.el --- run a `find' command and dired the output
   2
   3 ;; Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Roland McGrath <roland@gnu.ai.mit.edu>,
   6 ;;         Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;; Maintainer: FSF
   8 ;; Keywords: unix
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Code:
  28
  29 (require 'dired)
  30
  31 (defgroup find-dired nil
  32   "Run a `find' command and dired the output."
  33   :group 'dired
  34   :prefix "find-")
  35
  36 ;; find's -ls corresponds to these switches.
  37 ;; Note -b, at least GNU find quotes spaces etc. in filenames
  38 ;;;###autoload
  39 (defcustom find-ls-option
  40   (if (eq system-type 'berkeley-unix) '("-ls" . "-gilsb")
  41     '("-exec ls -ld {} \\;" . "-ld"))
  42   "*Description of the option to `find' to produce an `ls -l'-type listing.
  43 This is a cons of two strings (FIND-OPTION . LS-SWITCHES).  FIND-OPTION
  44 gives the option (or options) to `find' that produce the desired output.
  45 LS-SWITCHES is a list of `ls' switches to tell dired how to parse the output."
  46   :type '(cons (string :tag "Find Option")
  47                (string :tag "Ls Switches"))
  48   :group 'find-dired)
  49
  50 ;;;###autoload
  51 (defcustom find-grep-options
  52   (if (or (eq system-type 'berkeley-unix)
  53           (string-match "solaris2" system-configuration)
  54           (string-match "irix" system-configuration))
  55       "-s" "-q")
  56   "*Option to grep to be as silent as possible.
  57 On Berkeley systems, this is `-s'; on Posix, and with GNU grep, `-q' does it.
  58 On other systems, the closest you can come is to use `-l'."
  59   :type 'string
  60   :group 'find-dired)
  61
  62 (defvar find-args nil
  63   "Last arguments given to `find' by \\[find-dired].")
  64
  65 ;; History of find-args values entered in the minibuffer.
  66 (defvar find-args-history nil)
  67
  68 ;;;###autoload
  69 (defun find-dired (dir args)
  70   "Run `find' and go into dired-mode on a buffer of the output.
  71 The command run (after changing into DIR) is
  72
  73     find . \\( ARGS \\) -ls
  74
  75 except that the variable `find-ls-option' specifies what to use
  76 as the final argument."
  77   (interactive (list (read-file-name "Run find in directory: " nil "" t)
  78                      (read-string "Run find (with args): " find-args
  79                                   '(find-args-history . 1))))
  80   ;; Expand DIR ("" means default-directory), and make sure it has a
  81   ;; trailing slash.
  82   (setq dir (file-name-as-directory (expand-file-name dir)))
  83   ;; Check that it's really a directory.
  84   (or (file-directory-p dir)
  85       (error "find-dired needs a directory: %s" dir))
  86   (switch-to-buffer (get-buffer-create "*Find*"))
  87   (widen)
  88   (kill-all-local-variables)
  89   (setq buffer-read-only nil)
  90   (erase-buffer)
  91   (setq default-directory dir
  92         find-args args                  ; save for next interactive call
  93         args (concat "find . "
  94                      (if (string= args "")
  95                          ""
  96                        (concat "\\( " args " \\) "))
  97                      (car find-ls-option)))
  98   ;; The next statement will bomb in classic dired (no optional arg allowed)
  99   (dired-mode dir (cdr find-ls-option))
 100   ;; This really should rerun the find command, but I don't
 101   ;; have time for that.
 102   (use-local-map (append (make-sparse-keymap) (current-local-map)))
 103   (define-key (current-local-map) "g" 'undefined)
 104   ;; Set subdir-alist so that Tree Dired will work:
 105   (if (fboundp 'dired-simple-subdir-alist)
 106       ;; will work even with nested dired format (dired-nstd.el,v 1.15
 107       ;; and later)
 108       (dired-simple-subdir-alist)
 109     ;; else we have an ancient tree dired (or classic dired, where
 110     ;; this does no harm)
 111     (set (make-local-variable 'dired-subdir-alist)
 112          (list (cons default-directory (point-min-marker)))))
 113   (setq buffer-read-only nil)
 114   ;; Subdir headlerline must come first because the first marker in
 115   ;; subdir-alist points there.
 116   (insert "  " dir ":\n")
 117   ;; Make second line a ``find'' line in analogy to the ``total'' or
 118   ;; ``wildcard'' line.
 119   (insert "  " args "\n")
 120   ;; Start the find process.
 121   (let ((proc (start-process-shell-command "find" (current-buffer) args)))
 122     (set-process-filter proc (function find-dired-filter))
 123     (set-process-sentinel proc (function find-dired-sentinel))
 124     ;; Initialize the process marker; it is used by the filter.
 125     (move-marker (process-mark proc) 1 (current-buffer)))
 126   (setq mode-line-process '(":%s")))
 127
 128 ;;;###autoload
 129 (defun find-name-dired (dir pattern)
 130   "Search DIR recursively for files matching the globbing pattern PATTERN,
 131 and run dired on those files.
 132 PATTERN is a shell wildcard (not an Emacs regexp) and need not be quoted.
 133 The command run (after changing into DIR) is
 134
 135     find . -name 'PATTERN' -ls"
 136   (interactive
 137    "DFind-name (directory): \nsFind-name (filename wildcard): ")
 138   (find-dired dir (concat "-name '" pattern "'")))
 139
 140 ;; This functionality suggested by
 141 ;; From: oblanc@watcgl.waterloo.edu (Olivier Blanc)
 142 ;; Subject: find-dired, lookfor-dired
 143 ;; Date: 10 May 91 17:50:00 GMT
 144 ;; Organization: University of Waterloo
 145
 146 (defalias 'lookfor-dired 'find-grep-dired)
 147 ;;;###autoload
 148 (defun find-grep-dired (dir args)
 149   "Find files in DIR containing a regexp ARG and start Dired on output.
 150 The command run (after changing into DIR) is
 151
 152     find . -exec grep -s ARG {} \\\; -ls
 153
 154 Thus ARG can also contain additional grep options."
 155   (interactive "DFind-grep (directory): \nsFind-grep (grep regexp): ")
 156   ;; find -exec doesn't allow shell i/o redirections in the command,
 157   ;; or we could use `grep -l >/dev/null'
 158   ;; We use -type f, not ! -type d, to avoid getting screwed
 159   ;; by FIFOs and devices.  I'm not sure what's best to do
 160   ;; about symlinks, so as far as I know this is not wrong.
 161   (find-dired dir
 162               (concat "-type f -exec grep " find-grep-options " "
 163                       args " {} \\\; ")))
 164
 165 (defun find-dired-filter (proc string)
 166   ;; Filter for \\[find-dired] processes.
 167   (let ((buf (process-buffer proc)))
 168     (if (buffer-name buf)               ; not killed?
 169         (save-excursion
 170           (set-buffer buf)
 171           (save-restriction
 172             (widen)
 173             (save-excursion
 174               (let ((buffer-read-only nil)
 175                     (end (point-max)))
 176                 (goto-char end)
 177                 (insert string)
 178                 (goto-char end)
 179                 (or (looking-at "^")
 180                     (forward-line 1))
 181                 (while (looking-at "^")
 182                   (insert "  ")
 183                   (forward-line 1))
 184                 ;; Convert ` ./FILE' to ` FILE'
 185                 ;; This would lose if the current chunk of output
 186                 ;; starts or ends within the ` ./', so back up a bit:
 187                 (goto-char (- end 3))   ; no error if < 0
 188                 (while (search-forward " ./" nil t)
 189                   (delete-region (point) (- (point) 2)))
 190                 ;; Find all the complete lines in the unprocessed
 191                 ;; output and process it to add text properties.
 192                 (goto-char end)
 193                 (if (search-backward "\n" (process-mark proc) t)
 194                     (progn
 195                       (dired-insert-set-properties (process-mark proc)
 196                                                    (1+ (point)))
 197                       (move-marker (process-mark proc) (1+ (point)))))
 198                 ))))
 199       ;; The buffer has been killed.
 200       (delete-process proc))))
 201
 202 (defun find-dired-sentinel (proc state)
 203   ;; Sentinel for \\[find-dired] processes.
 204   (let ((buf (process-buffer proc)))
 205     (if (buffer-name buf)
 206         (save-excursion
 207           (set-buffer buf)
 208           (let ((buffer-read-only nil))
 209             (save-excursion
 210               (goto-char (point-max))
 211               (insert "\nfind " state)
 212               (forward-char -1)         ;Back up before \n at end of STATE.
 213               (insert " at " (substring (current-time-string) 0 19))
 214               (forward-char 1)
 215               (setq mode-line-process
 216                     (concat ":"
 217                             (symbol-name (process-status proc))))
 218               ;; Since the buffer and mode line will show that the
 219               ;; process is dead, we can delete it now.  Otherwise it
 220               ;; will stay around until M-x list-processes.
 221               (delete-process proc)
 222               (force-mode-line-update)))
 223           (message "find-dired %s finished." (current-buffer))))))
 224 \f
 225 (provide 'find-dired)
 226
 227 ;;; find-dired.el ends here