lisp/filecache.el

   1 ;;; filecache.el --- Find files using a pre-loaded cache
   2 ;;
   3 ;; Author:  Peter Breton <pbreton@cs.umb.edu>
   4 ;; Created: Sun Nov 10 1996
   5 ;; Keywords:
   6 ;; Time-stamp: <1998-04-29 22:38:56 pbreton>
   7 ;;
   8 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; The file-cache package is an attempt to make it easy to locate files
  30 ;; by name, without having to remember exactly where they are located.
  31 ;; This is very handy when working with source trees. You can also add
  32 ;; frequently used files to the cache to create a hotlist effect.
  33 ;; The cache can be used with any interactive command which takes a
  34 ;; filename as an argument.
  35 ;;
  36 ;; It is worth noting that this package works best when most of the files
  37 ;; in the cache have unique names, or (if they have the same name) exist in
  38 ;; only a few directories. The worst case is many files all with
  39 ;; the same name and in different directories, for example a big source tree
  40 ;; with a Makefile in each directory. In such a case, you should probably
  41 ;; use an alternate strategy to find the files.
  42 ;;
  43 ;; ADDING FILES TO THE CACHE:
  44 ;;
  45 ;; Use the following functions to add items to the file cache:
  46 ;;
  47 ;;   * `file-cache-add-file': Adds a single file to the cache
  48 ;;
  49 ;;   * `file-cache-add-file-list': Adds a list of files to the cache
  50 ;;
  51 ;; The following functions use the regular expressions in
  52 ;; `file-cache-delete-regexps' to eliminate unwanted files:
  53 ;;
  54 ;;   * `file-cache-add-directory': Adds the files in a directory to the
  55 ;;     cache. You can also specify a regular expression to match the files
  56 ;;     which should be added.
  57 ;;
  58 ;;   * `file-cache-add-directory-list': Same as above, but acts on a list
  59 ;;     of directories. You can use `load-path', `exec-path' and the like.
  60 ;;
  61 ;;   * `file-cache-add-directory-using-find': Uses the `find' command to
  62 ;;     add a directory tree to the cache.
  63 ;;
  64 ;;   * `file-cache-add-directory-using-locate': Uses the `locate' command to
  65 ;;     add files matching a pattern to the cache.
  66 ;;
  67 ;; Use the function `file-cache-clear-cache' to remove all items from the
  68 ;; cache. There are a number of `file-cache-delete' functions provided
  69 ;; as well, but in general it is probably better to not worry too much
  70 ;; about extra files in the cache.
  71 ;;
  72 ;; The most convenient way to initialize the cache is with an
  73 ;; `eval-after-load' function, as noted in the ADDING FILES
  74 ;; AUTOMATICALLY section.
  75 ;;
  76 ;; FINDING FILES USING THE CACHE:
  77 ;;
  78 ;; You can use the file-cache with any function that expects a filename as
  79 ;; an argument. For example:
  80 ;;
  81 ;; 1) Invoke a function which expects a filename as an argument:
  82 ;;    M-x find-file
  83 ;;
  84 ;; 2) Begin typing a file name.
  85 ;;
  86 ;; 3) Invoke `file-cache-minibuffer-complete' (bound by default to
  87 ;; C-TAB) to complete on the filename using the cache.
  88 ;;
  89 ;; 4) When you have found a unique completion, the minibuffer contents
  90 ;; will change to the full name of that file.
  91 ;;
  92 ;; If there are a number of directories which contain the completion,
  93 ;; invoking `file-cache-minibuffer-complete' repeatedly will cycle through
  94 ;; them.
  95 ;;
  96 ;; 5) You can then edit the minibuffer contents, or press RETURN.
  97 ;;
  98 ;; It is much easier to simply try it than trying to explain it :)
  99 ;;
 100 ;;; ADDING FILES AUTOMATICALLY
 101 ;;
 102 ;; For maximum utility, you should probably define an `eval-after-load'
 103 ;; form which loads your favorite files:
 104 ;;
 105 ;;      (eval-after-load
 106 ;;       "filecache"
 107 ;;       '(progn
 108 ;;          (message "Loading file cache...")
 109 ;;          (file-cache-add-directory-using-find "~/projects")
 110 ;;          (file-cache-add-directory-list load-path)
 111 ;;          (file-cache-add-directory "~/")
 112 ;;          (file-cache-add-file-list (list "~/foo/bar" "~/baz/bar"))
 113 ;;         ))
 114 ;;
 115 ;; If you clear and reload the cache frequently, it is probably easiest
 116 ;; to put your initializations in a function:
 117 ;;
 118 ;;   (eval-after-load
 119 ;;     "filecache"
 120 ;;      '(my-file-cache-initialize))
 121 ;;
 122 ;;   (defun my-file-cache-initialize ()
 123 ;;      (interactive)
 124 ;;      (message "Loading file cache...")
 125 ;;      (file-cache-add-directory-using-find "~/projects")
 126 ;;      (file-cache-add-directory-list load-path)
 127 ;;      (file-cache-add-directory "~/")
 128 ;;      (file-cache-add-file-list (list "~/foo/bar" "~/baz/bar"))
 129 ;;   ))
 130 ;;
 131 ;; Of course, you can still add files to the cache afterwards, via
 132 ;; Lisp functions.
 133 ;;
 134 ;; RELATED WORK:
 135 ;;
 136 ;; This package is a distant relative of Noah Friedman's fff utilities.
 137 ;; Our goal is pretty similar, but the implementation strategies are
 138 ;; different.
 139
 140 ;;; Code:
 141
 142 (defgroup file-cache nil
 143   "Find files using a pre-loaded cache."
 144   :group 'files
 145   :prefix "file-cache-")
 146
 147 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 148 ;; Customization Variables
 149 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 150
 151 ;; User-modifiable variables
 152 (defcustom file-cache-filter-regexps
 153   (list "~$" "\\.o$" "\\.exe$" "\\.a$" "\\.elc$" ",v$" "\\.output$"
 154         "\\.$" "#$")
 155   "*List of regular expressions used as filters by the file cache.
 156 File names which match these expressions will not be added to the cache.
 157 Note that the functions `file-cache-add-file' and `file-cache-add-file-list'
 158 do not use this variable."
 159   :type '(repeat regexp)
 160   :group 'file-cache)
 161
 162 (defcustom file-cache-find-command "find"
 163   "*External program used by `file-cache-add-directory-using-find'."
 164   :type 'string
 165   :group 'file-cache)
 166
 167 (defcustom file-cache-locate-command "locate"
 168   "*External program used by `file-cache-add-directory-using-locate'."
 169   :type 'string
 170   :group 'file-cache)
 171
 172 ;; Minibuffer messages
 173 (defcustom file-cache-no-match-message " [File Cache: No match]"
 174   "Message to display when there is no completion."
 175   :type 'string
 176   :group 'file-cache)
 177
 178 (defcustom file-cache-sole-match-message " [File Cache: sole completion]"
 179   "Message to display when there is only one completion."
 180   :type 'string
 181   :group 'file-cache)
 182
 183 (defcustom file-cache-non-unique-message
 184   " [File Cache: complete but not unique]"
 185   "Message to display when there is a non-unique completion."
 186   :type 'string
 187   :group 'file-cache)
 188
 189 (defvar file-cache-multiple-directory-message nil)
 190
 191 ;; Internal variables
 192 ;; This should be named *Completions* because that's what the function
 193 ;; switch-to-completions in simple.el expects
 194 (defcustom file-cache-completions-buffer "*Completions*"
 195   "Buffer to display completions when using the file cache."
 196   :type 'string
 197   :group 'file-cache)
 198
 199 (defcustom file-cache-buffer "*File Cache*"
 200   "Buffer to hold the cache of file names."
 201   :type 'string
 202   :group 'file-cache)
 203
 204 (defcustom file-cache-buffer-default-regexp "^.+$"
 205   "Regexp to match files in `file-cache-buffer'."
 206   :type 'regexp
 207   :group 'file-cache)
 208
 209 (defvar file-cache-last-completion nil)
 210
 211 (defvar file-cache-alist nil
 212   "Internal data structure to hold cache of file names.")
 213
 214 (defvar file-cache-completions-keymap nil
 215   "Keymap for file cache completions buffer.")
 216
 217 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 218 ;; Functions to add files to the cache
 219 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 220
 221 (defun file-cache-add-directory (directory &optional regexp)
 222   "Add DIRECTORY to the file cache.
 223 If the optional REGEXP argument is non-nil, only files which match it will
 224 be added to the cache."
 225   (interactive "DAdd files from directory: ")
 226   ;; Not an error, because otherwise we can't use load-paths that
 227   ;; contain non-existent directories.
 228   (if (not (file-accessible-directory-p directory))
 229       (message "Directory %s does not exist" directory)
 230     (let* ((dir       (expand-file-name directory))
 231            (dir-files (directory-files dir t regexp))
 232            )
 233       ;; Filter out files we don't want to see
 234       (mapcar
 235        '(lambda (file)
 236         (mapcar
 237          '(lambda (regexp)
 238             (if (string-match regexp file)
 239                 (setq dir-files (delq file dir-files))))
 240          file-cache-filter-regexps))
 241        dir-files)
 242       (file-cache-add-file-list dir-files))))
 243
 244 (defun file-cache-add-directory-list (directory-list &optional regexp)
 245   "Add DIRECTORY-LIST (a list of directory names) to the file cache.
 246 If the optional REGEXP argument is non-nil, only files which match it
 247 will be added to the cache. Note that the REGEXP is applied to the files
 248 in each directory, not to the directory list itself."
 249   (interactive "XAdd files from directory list: ")
 250   (mapcar
 251    '(lambda (dir) (file-cache-add-directory dir regexp))
 252    directory-list))
 253
 254 (defun file-cache-add-file-list  (file-list)
 255   "Add FILE-LIST (a list of files names) to the file cache."
 256   (interactive "XFile List: ")
 257   (mapcar 'file-cache-add-file file-list))
 258
 259 ;; Workhorse function
 260 (defun file-cache-add-file (file)
 261   "Add FILE to the file cache."
 262   (interactive "fAdd File: ")
 263   (if (not (file-exists-p file))
 264       (message "File %s does not exist" file)
 265     (let* ((file-name (file-name-nondirectory file))
 266            (dir-name  (file-name-directory    file))
 267            (the-entry (assoc file-name file-cache-alist))
 268            )
 269       ;; Does the entry exist already?
 270       (if the-entry
 271           (if (or (and (stringp (cdr the-entry))
 272                        (string= dir-name (cdr the-entry)))
 273                   (and (listp (cdr the-entry))
 274                        (member dir-name (cdr the-entry))))
 275               nil
 276             (setcdr the-entry (append (list dir-name) (cdr the-entry)))
 277             )
 278         ;; If not, add it to the cache
 279         (setq file-cache-alist
 280               (cons (cons file-name (list dir-name))
 281                     file-cache-alist)))
 282       )))
 283
 284 (defun file-cache-add-directory-using-find (directory)
 285   "Use the `find' command to add files to the file cache.
 286 Find is run in DIRECTORY."
 287   (interactive "DAdd files under directory: ")
 288   (let ((dir (expand-file-name directory)))
 289     (set-buffer (get-buffer-create file-cache-buffer))
 290     (erase-buffer)
 291     (call-process file-cache-find-command nil
 292                   (get-buffer file-cache-buffer) nil
 293                   dir "-name"
 294                   (if (memq system-type
 295                             (list 'windows-nt 'ms-dos)) "'*'" "*")
 296                   "-print")
 297     (file-cache-add-from-file-cache-buffer)))
 298
 299 (defun file-cache-add-directory-using-locate (string)
 300   "Use the `locate' command to add files to the file cache.
 301 STRING is passed as an argument to the locate command."
 302   (interactive "sAdd files using locate string: ")
 303   (set-buffer (get-buffer-create file-cache-buffer))
 304   (erase-buffer)
 305   (call-process file-cache-locate-command nil
 306                 (get-buffer file-cache-buffer) nil
 307                 string)
 308   (file-cache-add-from-file-cache-buffer))
 309
 310 (defun file-cache-add-from-file-cache-buffer (&optional regexp)
 311   "Add any entries found in the file cache buffer.
 312 Each entry matches the regular expression `file-cache-buffer-default-regexp'
 313 or the optional REGEXP argument."
 314   (set-buffer file-cache-buffer)
 315   (mapcar
 316    (function (lambda (elt)
 317                (goto-char (point-min))
 318                (delete-matching-lines elt)))
 319    file-cache-filter-regexps)
 320   (goto-char (point-min))
 321   (let ((full-filename))
 322     (while (re-search-forward
 323             (or regexp file-cache-buffer-default-regexp)
 324             (point-max) t)
 325       (setq full-filename (buffer-substring-no-properties
 326                       (match-beginning 0) (match-end 0)))
 327       (file-cache-add-file full-filename))))
 328
 329 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 330 ;; Functions to delete from the cache
 331 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 332
 333 (defun file-cache-clear-cache ()
 334   "Clear the file cache."
 335   (interactive)
 336   (setq file-cache-alist nil))
 337
 338 ;; This clears *all* files with the given name
 339 (defun file-cache-delete-file (file)
 340   "Delete FILE from the file cache."
 341   (interactive
 342    (list (completing-read "Delete file from cache: " file-cache-alist)))
 343   (setq file-cache-alist
 344         (delq (assoc file file-cache-alist) file-cache-alist)))
 345
 346 (defun file-cache-delete-file-list (file-list)
 347   "Delete FILE-LIST (a list of files) from the file cache."
 348   (interactive "XFile List: ")
 349   (mapcar 'file-cache-delete-file file-list))
 350
 351 (defun file-cache-delete-file-regexp (regexp)
 352   "Delete files matching REGEXP from the file cache."
 353   (interactive "sRegexp: ")
 354   (let ((delete-list))
 355     (mapcar '(lambda (elt)
 356                (and (string-match regexp (car elt))
 357                     (setq delete-list (cons (car elt) delete-list))))
 358             file-cache-alist)
 359     (file-cache-delete-file-list delete-list)
 360     (message "Deleted %d files from file cache" (length delete-list))))
 361
 362 (defun file-cache-delete-directory (directory)
 363   "Delete DIRECTORY from the file cache."
 364   (interactive "DDelete directory from file cache: ")
 365   (let ((dir (expand-file-name directory))
 366         (result 0))
 367     (mapcar
 368      '(lambda (entry)
 369         (if (file-cache-do-delete-directory dir entry)
 370             (setq result (1+ result))))
 371      file-cache-alist)
 372     (if (zerop result)
 373         (error "No entries containing %s found in cache" directory)
 374       (message "Deleted %d entries" result))))
 375
 376 (defun file-cache-do-delete-directory (dir entry)
 377   (let ((directory-list (cdr entry))
 378         (directory (file-cache-canonical-directory dir))
 379         )
 380     (and (member directory directory-list)
 381          (if (equal 1 (length directory-list))
 382              (setq file-cache-alist
 383                    (delq entry file-cache-alist))
 384            (setcdr entry (delete directory directory-list)))
 385          )
 386     ))
 387
 388 (defun file-cache-delete-directory-list (directory-list)
 389   "Delete DIRECTORY-LIST (a list of directories) from the file cache."
 390   (interactive "XDirectory List: ")
 391   (mapcar 'file-cache-delete-directory directory-list))
 392
 393 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 394 ;; Utility functions
 395 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 396
 397 ;; Returns the name of a directory for a file in the cache
 398 (defun file-cache-directory-name  (file)
 399   (let* ((directory-list (cdr (assoc file file-cache-alist)))
 400          (len            (length directory-list))
 401          (directory)
 402          (num)
 403          )
 404     (if (not (listp directory-list))
 405         (error "Unknown type in file-cache-alist for key %s" file))
 406     (cond
 407      ;; Single element
 408      ((eq 1 len)
 409       (setq directory (elt directory-list 0)))
 410      ;; No elements
 411      ((eq 0 len)
 412       (error "No directory found for key %s" file))
 413      ;; Multiple elements
 414      (t
 415       (let* ((minibuffer-dir (file-name-directory (buffer-string)))
 416              (dir-list       (member minibuffer-dir directory-list))
 417              )
 418         (setq directory
 419               ;; If the directory is in the list, return the next element
 420               ;; Otherwise, return the first element
 421               (if dir-list
 422                   (or (elt directory-list
 423                            (setq num (1+ (- len (length dir-list)))))
 424                       (elt directory-list (setq num 0)))
 425                 (elt directory-list (setq num 0))))
 426         )
 427       )
 428      )
 429     ;; If there were multiple directories, set up a minibuffer message
 430     (setq file-cache-multiple-directory-message
 431           (and num (format " [%d of %d]" (1+ num) len)))
 432     directory))
 433
 434 ;; Returns the name of a file in the cache
 435 (defun file-cache-file-name  (file)
 436   (let ((directory (file-cache-directory-name file)))
 437     (concat directory file)))
 438
 439 ;; Return a canonical directory for comparison purposes.
 440 ;; Such a directory ends with a forward slash.
 441 (defun file-cache-canonical-directory (dir)
 442   (let ((directory dir))
 443     (if (not (char-equal ?/ (string-to-char (substring directory -1))))
 444         (concat directory "/")
 445       directory)))
 446
 447 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 448 ;; Minibuffer functions
 449 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 450
 451 ;; The prefix argument works around a bug in the minibuffer completion.
 452 ;; The completion function doesn't distinguish between the states:
 453 ;;
 454 ;;   "Multiple completions of name" (eg, Makefile, Makefile.in)
 455 ;;   "Name available in multiple directories" (/tmp/Makefile, ~me/Makefile)
 456 ;;
 457 ;; The default is to do the former; a prefix arg forces the latter.
 458
 459 ;;;###autoload
 460 (defun file-cache-minibuffer-complete (arg)
 461   "Complete a filename in the minibuffer using a preloaded cache.
 462 Filecache does two kinds of substitution: it completes on names in
 463 the cache, and, once it has found a unique name, it cycles through
 464 the directories that the name is available in.  With a prefix argument,
 465 the name is considered already unique; only the second substitution
 466 \(directories) is done."
 467   (interactive "P")
 468   (let*
 469       (
 470        (completion-ignore-case nil)
 471        (case-fold-search       nil)
 472        (string                 (file-name-nondirectory (buffer-string)))
 473        (completion-string      (try-completion string file-cache-alist))
 474        (completion-list)
 475        (len)
 476        (file-cache-string)
 477        )
 478     (cond
 479      ;; If it's the only match, replace the original contents
 480      ((or arg (eq completion-string t))
 481       (setq file-cache-string (file-cache-file-name string))
 482       (if (string= file-cache-string (buffer-string))
 483           (file-cache-temp-minibuffer-message file-cache-sole-match-message)
 484         (erase-buffer)
 485         (insert-string file-cache-string)
 486         (if file-cache-multiple-directory-message
 487             (file-cache-temp-minibuffer-message
 488              file-cache-multiple-directory-message))
 489       ))
 490
 491      ;; If it's the longest match, insert it
 492      ((stringp completion-string)
 493       ;; If we've already inserted a unique string, see if the user
 494       ;; wants to use that one
 495       (if (and (string= string completion-string)
 496                (assoc string file-cache-alist))
 497           (if (and (eq last-command this-command)
 498                    (string= file-cache-last-completion completion-string))
 499               (progn
 500                 (erase-buffer)
 501                 (insert-string (file-cache-file-name completion-string))
 502                 (setq file-cache-last-completion nil)
 503                 )
 504             (file-cache-temp-minibuffer-message file-cache-non-unique-message)
 505             (setq file-cache-last-completion string)
 506             )
 507         (setq file-cache-last-completion string)
 508         (setq completion-list (all-completions string file-cache-alist)
 509               len             (length completion-list))
 510         (if (> len 1)
 511             (progn
 512               (goto-char (point-max))
 513               (insert-string
 514                (substring completion-string (length string)))
 515               ;; Add our own setup function to the Completions Buffer
 516               (let ((completion-setup-hook
 517                    (reverse
 518                     (append (list 'file-cache-completion-setup-function)
 519                             completion-setup-hook)))
 520                     )
 521                 (with-output-to-temp-buffer file-cache-completions-buffer
 522                   (display-completion-list completion-list))
 523                 )
 524               )
 525           (setq file-cache-string (file-cache-file-name completion-string))
 526           (if (string= file-cache-string (buffer-string))
 527               (file-cache-temp-minibuffer-message
 528                file-cache-sole-match-message)
 529             (erase-buffer)
 530             (insert-string file-cache-string)
 531             (if file-cache-multiple-directory-message
 532                 (file-cache-temp-minibuffer-message
 533                  file-cache-multiple-directory-message)))
 534           )))
 535
 536      ;; No match
 537      ((eq completion-string nil)
 538       (file-cache-temp-minibuffer-message file-cache-no-match-message))
 539      )
 540 ))
 541
 542 ;; Lifted from "complete.el"
 543 (defun file-cache-temp-minibuffer-message (msg)
 544   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 545   (let ((savemax (point-max)))
 546     (save-excursion
 547       (goto-char (point-max))
 548       (insert msg))
 549     (let ((inhibit-quit t))
 550       (sit-for 2)
 551       (delete-region savemax (point-max))
 552       (if quit-flag
 553           (setq quit-flag nil
 554                 unread-command-events (list 7))))))
 555
 556 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 557 ;; Completion functions
 558 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 559
 560 (defun file-cache-completion-setup-function  ()
 561   (set-buffer file-cache-completions-buffer)
 562
 563   (if file-cache-completions-keymap
 564       nil
 565     (setq file-cache-completions-keymap
 566           (copy-keymap completion-list-mode-map))
 567     (define-key file-cache-completions-keymap [mouse-2]
 568       'file-cache-mouse-choose-completion)
 569     (define-key file-cache-completions-keymap "\C-m"
 570       'file-cache-choose-completion))
 571
 572     (use-local-map file-cache-completions-keymap)
 573     )
 574
 575 (defun file-cache-choose-completion  ()
 576   "Choose a completion in the `*Completions*' buffer."
 577   (interactive)
 578   (let ((completion-no-auto-exit t))
 579     (choose-completion)
 580     (select-window (active-minibuffer-window))
 581     (file-cache-minibuffer-complete nil)
 582     )
 583   )
 584
 585 (defun file-cache-mouse-choose-completion  (event)
 586   "Choose a completion with the mouse."
 587   (interactive "e")
 588   (let ((completion-no-auto-exit t))
 589     (mouse-choose-completion event)
 590     (select-window (active-minibuffer-window))
 591     (file-cache-minibuffer-complete nil)
 592     )
 593   )
 594
 595 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 596 ;; Debugging functions
 597 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 598
 599 (defun file-cache-debug-read-from-minibuffer (file)
 600   "Debugging function."
 601   (interactive
 602    (list (completing-read "File Cache: " file-cache-alist)))
 603   (message "%s" (assoc file file-cache-alist))
 604   )
 605
 606 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 607 ;; Keybindings
 608 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 609
 610 ;;;###autoload (define-key minibuffer-local-completion-map [C-tab] 'file-cache-minibuffer-complete)
 611 ;;;###autoload (define-key minibuffer-local-map [C-tab] 'file-cache-minibuffer-complete)
 612 ;;;###autoload (define-key minibuffer-local-must-match-map [C-tab] 'file-cache-minibuffer-complete)
 613
 614 (provide 'filecache)
 615
 616 ;;; filecache.el ends here