configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AM_INIT_AUTOMAKE
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 dnl It is important that variables on the RHS not be expanded here,
  35 dnl hence the single quotes.  This is per the GNU coding standards, see
  36 dnl (autoconf) Installation Directory Variables
  37 dnl See also epaths.h below.
  38 lispdir='${datadir}/emacs/${version}/lisp'
  39 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  40 '${datadir}/emacs/site-lisp'
  41 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  42 etcdir='${datadir}/emacs/${version}/etc'
  43 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  44 docdir='${datadir}/emacs/${version}/etc'
  45 gamedir='${localstatedir}/games/emacs'
  46
  47 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  48 dnl Create a new --with option that defaults to being disabled.
  49 dnl NAME is the base name of the option.  The shell variable with_NAME
  50 dnl   will be set to either the user's value (if the option is
  51 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  52 dnl   option is not specified).  Note that the shell variable name is
  53 dnl   constructed as autoconf does, by replacing non-alphanumeric
  54 dnl   characters with "_".
  55 dnl HELP-STRING is the help text for the option.
  56 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  57   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  58     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  59 ])dnl
  60
  61 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  62 dnl Create a new --with option that defaults to being enabled.  NAME
  63 dnl   is the base name of the option.  The shell variable with_NAME
  64 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  65 dnl   'yes' (if the option is not specified).  Note that the shell
  66 dnl   variable name is constructed as autoconf does, by replacing
  67 dnl   non-alphanumeric characters with "_".
  68 dnl HELP-STRING is the help text for the option.
  69 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  70   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  71    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  72 ])dnl
  73
  74 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  75 if test "$with_pop" = yes; then
  76    AC_DEFINE(MAIL_USE_POP)
  77 fi
  78 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  79
  80 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  81 if test "$with_kerberos" != no; then
  82    AC_DEFINE(KERBEROS)
  83 fi
  84 AH_TEMPLATE(KERBEROS,
  85             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  86
  87 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  88 if test "${with_kerberos5}" != no; then
  89   if test "${with_kerberos}" = no; then
  90     with_kerberos=yes
  91     AC_DEFINE(KERBEROS)
  92   fi
  93   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  94 fi
  95
  96 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  97 dnl FIXME hesiod support may not be present, so it seems like an error
  98 dnl to define, or at least use, this unconditionally.
  99 if test "$with_hesiod" != no; then
 100   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 101 fi
 102
 103 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 104 if test "$with_mmdf" != no; then
 105    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 109 if test "$with_mail_unlink" != no; then
 110    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 111 fi
 112
 113 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 114     [string giving default POP mail host])],
 115     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 116
 117 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 118
 119 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 120 if test "$with_sync_input" = yes; then
 121    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 122 fi
 123
 124 dnl FIXME currently it is not the last.
 125 dnl This should be the last --with option, because --with-x is
 126 dnl added later on when we find the path of X, and it's best to
 127 dnl keep them together visually.
 128 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 129  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 130 [         case "${withval}" in
 131             y | ye | yes )      val=gtk ;;
 132             n | no )            val=no  ;;
 133             l | lu | luc | luci | lucid )       val=lucid ;;
 134             a | at | ath | athe | athen | athena )      val=athena ;;
 135             m | mo | mot | moti | motif )       val=motif ;;
 136             g | gt | gtk  )     val=gtk ;;
 137             gtk3  )     val=gtk3 ;;
 138             * )
 139 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 140 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 141 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 142             ;;
 143           esac
 144           with_x_toolkit=$val
 145 ])
 146
 147 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 148 if test "$with_wide_int" = yes; then
 149   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 150 fi
 151
 152 dnl _ON results in a '--without' option in the --help output, so
 153 dnl the help text should refer to "don't compile", etc.
 154 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 155 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 156 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 157 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 158 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 159 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 160 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 161 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 162
 163 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 164 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 165 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 166
 167 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 168 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 169 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 170 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 171
 172 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 173 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 174 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 175 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 176 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 177 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 178
 179 ## For the times when you want to build Emacs but don't have
 180 ## a suitable makeinfo, and can live without the manuals.
 181 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 182 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 183
 184 ## This is an option because I do not know if all info/man support
 185 ## compressed files, nor how to test if they do so.
 186 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 187 if test $with_compress_info = yes; then
 188    GZIP_INFO=yes
 189 else
 190    GZIP_INFO=
 191 fi
 192 AC_SUBST(GZIP_INFO)
 193
 194 AC_ARG_WITH([pkg-config-prog],dnl
 195 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 196                   [path to pkg-config for finding GTK and librsvg])])
 197 if test "X${with_pkg_config_prog}" != X; then
 198    if test "${with_pkg_config_prog}" != yes; then
 199       PKG_CONFIG="${with_pkg_config_prog}"
 200    fi
 201 fi
 202
 203 CRT_DIR=
 204 AC_ARG_WITH([crt-dir],dnl
 205 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 206 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 207 CRT_DIR="${with_crt_dir}"
 208
 209 AC_ARG_WITH(gameuser,dnl
 210 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 211 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 212   && gameuser="${with_gameuser}"
 213 test "X$gameuser" = X && gameuser=games
 214
 215 AC_ARG_WITH([gnustep-conf],dnl
 216 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 217 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 218   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 219 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 220      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 221
 222 AC_ARG_ENABLE(ns-self-contained,
 223 [AS_HELP_STRING([--disable-ns-self-contained],
 224                 [disable self contained build under NeXTstep])],
 225    EN_NS_SELF_CONTAINED=$enableval,
 226    EN_NS_SELF_CONTAINED=yes)
 227
 228 AC_ARG_ENABLE(asserts,
 229 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 230       USE_XASSERTS=$enableval,
 231       USE_XASSERTS=no)
 232
 233 AC_ARG_ENABLE(maintainer-mode,
 234 [AS_HELP_STRING([--disable-maintainer-mode],
 235                 [disable make rules and dependencies not useful (and sometimes
 236                  confusing) to the casual installer])],
 237       USE_MAINTAINER_MODE=$enableval,
 238       USE_MAINTAINER_MODE=yes)
 239 if test $USE_MAINTAINER_MODE = yes; then
 240   MAINT=
 241 else
 242   MAINT=#
 243 fi
 244 AC_SUBST(MAINT)
 245
 246 AC_ARG_ENABLE(locallisppath,
 247 [AS_HELP_STRING([--enable-locallisppath=PATH],
 248                 [directories Emacs should search for lisp files specific
 249                  to this site])],
 250 if test "${enableval}" = "no"; then
 251   locallisppath=
 252 elif test "${enableval}" != "yes"; then
 253   locallisppath=${enableval}
 254 fi)
 255
 256 AC_ARG_ENABLE(checking,
 257 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 258                 [enable expensive run-time checks.  With LIST,
 259                  enable only specific categories of checks.
 260                  Categories are: all,yes,no.
 261                  Flags are: stringbytes, stringoverrun, stringfreelist,
 262                  xmallocoverrun, conslist])],
 263 [ac_checking_flags="${enableval}"],[])
 264 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 265 for check in $ac_checking_flags
 266 do
 267         case $check in
 268         # these set all the flags to specific states
 269         yes)            ac_enable_checking=1 ;;
 270         no)             ac_enable_checking= ;
 271                         ac_gc_check_stringbytes= ;
 272                         ac_gc_check_string_overrun= ;
 273                         ac_gc_check_string_free_list= ;
 274                         ac_xmalloc_overrun= ;
 275                         ac_gc_check_cons_list= ;;
 276         all)            ac_enable_checking=1 ;
 277                         ac_gc_check_stringbytes=1 ;
 278                         ac_gc_check_string_overrun=1 ;
 279                         ac_gc_check_string_free_list=1 ;
 280                         ac_xmalloc_overrun=1 ;
 281                         ac_gc_check_cons_list=1 ;;
 282         # these enable particular checks
 283         stringbytes)    ac_gc_check_stringbytes=1 ;;
 284         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 285         stringfreelist) ac_gc_check_string_free_list=1 ;;
 286         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 287         conslist)       ac_gc_check_cons_list=1 ;;
 288         *)      AC_MSG_ERROR(unknown check category $check) ;;
 289         esac
 290 done
 291 IFS="$ac_save_IFS"
 292
 293 if test x$ac_enable_checking != x ; then
 294   AC_DEFINE(ENABLE_CHECKING, 1,
 295 [Enable expensive run-time checking of data types?])
 296 fi
 297 if test x$ac_gc_check_stringbytes != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 299 [Define this temporarily to hunt a bug.  If defined, the size of
 300    strings is redundantly recorded in sdata structures so that it can
 301    be compared to the sizes recorded in Lisp strings.])
 302 fi
 303 if test x$ac_gc_check_string_overrun != x ; then
 304   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 305 [Define this to check for short string overrun.])
 306 fi
 307 if test x$ac_gc_check_string_free_list != x ; then
 308   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 309 [Define this to check the string free list.])
 310 fi
 311 if test x$ac_xmalloc_overrun != x ; then
 312   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 313 [Define this to check for malloc buffer overrun.])
 314 fi
 315 if test x$ac_gc_check_cons_list != x ; then
 316   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 317 [Define this to check for errors in cons list.])
 318 fi
 319
 320 AC_ARG_ENABLE(use-lisp-union-type,
 321 [AS_HELP_STRING([--enable-use-lisp-union-type],
 322                 [use a union for the Lisp_Object data type.
 323                 This is only useful for development for catching certain types of bugs.])],
 324 if test "${enableval}" != "no"; then
 325    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 326    [Define this to use a lisp union for the Lisp_Object data type.])
 327 fi)
 328
 329
 330 AC_ARG_ENABLE(profiling,
 331 [AS_HELP_STRING([--enable-profiling],
 332                 [build emacs with profiling support.
 333                  This might not work on all platforms])],
 334 [ac_enable_profiling="${enableval}"],[])
 335 if test x$ac_enable_profiling != x ; then
 336    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 337 else
 338    PROFILING_CFLAGS=
 339 fi
 340 AC_SUBST(PROFILING_CFLAGS)
 341
 342 AC_ARG_ENABLE(autodepend,
 343 [AS_HELP_STRING([--enable-autodepend],
 344                 [automatically generate dependencies to .h-files.
 345                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 346                  found])],
 347 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 348
 349 #### Make srcdir absolute, if it isn't already.  It's important to
 350 #### avoid running the path through pwd unnecessarily, since pwd can
 351 #### give you automounter prefixes, which can go away.  We do all this
 352 #### so Emacs can find its files when run uninstalled.
 353 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 354 unset CDPATH
 355 case "${srcdir}" in
 356   /* ) ;;
 357   . )
 358     ## We may be able to use the $PWD environment variable to make this
 359     ## absolute.  But sometimes PWD is inaccurate.
 360     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 361     ## but that tested only for a well-formed and valid PWD,
 362     ## it did not object when PWD was well-formed and valid but just wrong.
 363     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 364     then
 365       srcdir="$PWD"
 366     else
 367       srcdir="`(cd ${srcdir}; pwd)`"
 368     fi
 369   ;;
 370   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 371 esac
 372
 373 #### Given the configuration name, set machfile and opsysfile to the
 374 #### names of the m/*.h and s/*.h files we should use.
 375
 376 ### Canonicalize the configuration name.
 377
 378 AC_CANONICAL_HOST
 379 canonical=$host
 380 configuration=${host_alias-${build_alias-$host}}
 381
 382 dnl This used to use changequote, but, apart from `changequote is evil'
 383 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 384 dnl the great gob of text.  Thus it's not processed for possible expansion.
 385 dnl Just make sure the brackets remain balanced.
 386 dnl
 387 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 388 dnl indicated by comments.
 389 dnl quotation begins
 390 [
 391
 392 ### If you add support for a new configuration, add code to this
 393 ### switch statement to recognize your configuration name and select
 394 ### the appropriate operating system and machine description files.
 395
 396 ### You would hope that you could choose an m/*.h file pretty much
 397 ### based on the machine portion of the configuration name, and an s/*.h
 398 ### file based on the operating system portion.  However, it turns out
 399 ### that each m/*.h file is pretty manufacturer-specific - for
 400 ### example mips.h is MIPS
 401 ### So we basically have to have a special case for each
 402 ### configuration name.
 403 ###
 404 ### As far as handling version numbers on operating systems is
 405 ### concerned, make sure things will fail in a fixable way.  If
 406 ### /etc/MACHINES doesn't say anything about version numbers, be
 407 ### prepared to handle anything reasonably.  If version numbers
 408 ### matter, be sure /etc/MACHINES says something about it.
 409
 410 machine='' opsys='' unported=no
 411 case "${canonical}" in
 412
 413   ## GNU/Linux ports
 414   *-*-linux-gnu*)
 415     opsys=gnu-linux
 416     case ${canonical} in
 417       alpha*)   machine=alpha ;;
 418       s390-*)   machine=ibms390 ;;
 419       s390x-*)  machine=ibms390x ;;
 420       powerpc*) machine=macppc ;;
 421       sparc*)   machine=sparc ;;
 422       ia64*)    machine=ia64 ;;
 423       m68k*)    machine=m68k ;;
 424       x86_64*)  machine=amdx86-64 ;;
 425     esac
 426   ;;
 427
 428   ## FreeBSD ports
 429   *-*-freebsd* )
 430     opsys=freebsd
 431     case "${canonical}" in
 432       alpha*)           machine=alpha ;;
 433       amd64-*|x86_64-*) machine=amdx86-64 ;;
 434       ia64-*)           machine=ia64 ;;
 435       i[3456]86-*)      machine=intel386 ;;
 436       powerpc-*)        machine=macppc ;;
 437       sparc-*)          machine=sparc ;;
 438       sparc64-*)        machine=sparc ;;
 439     esac
 440   ;;
 441
 442   ## FreeBSD kernel + glibc based userland
 443   *-*-kfreebsd*gnu* )
 444     opsys=gnu-kfreebsd
 445     case "${canonical}" in
 446       alpha*)           machine=alpha ;;
 447       amd64-*|x86_64-*) machine=amdx86-64 ;;
 448       ia64-*)           machine=ia64 ;;
 449       i[3456]86-*)      machine=intel386 ;;
 450       powerpc-*)        machine=macppc ;;
 451       sparc-*)          machine=sparc ;;
 452       sparc64-*)        machine=sparc ;;
 453     esac
 454   ;;
 455
 456   ## NetBSD ports
 457   *-*-netbsd* )
 458     opsys=netbsd
 459     case "${canonical}" in
 460       alpha*)      machine=alpha ;;
 461       x86_64-*)    machine=amdx86-64 ;;
 462       i[3456]86-*) machine=intel386 ;;
 463       m68k-*)      machine=m68k ;;
 464       powerpc-*)   machine=macppc ;;
 465       sparc*-)     machine=sparc ;;
 466       vax-*)       machine=vax ;;
 467     esac
 468   ;;
 469
 470   ## OpenBSD ports
 471   *-*-openbsd* )
 472     opsys=openbsd
 473     case "${canonical}" in
 474       alpha*)    machine=alpha ;;
 475       x86_64-*)  machine=amdx86-64 ;;
 476       i386-*)    machine=intel386 ;;
 477       powerpc-*) machine=macppc ;;
 478       sparc*)    machine=sparc ;;
 479       vax-*)     machine=vax ;;
 480     esac
 481   ;;
 482
 483   ## Apple Darwin / Mac OS X
 484   *-apple-darwin* )
 485     case "${canonical}" in
 486       i[3456]86-* )  machine=intel386 ;;
 487       powerpc-* )    machine=macppc ;;
 488       x86_64-* )     machine=amdx86-64 ;;
 489       * )            unported=yes ;;
 490     esac
 491     opsys=darwin
 492     # Define CPP as follows to make autoconf work correctly.
 493     CPP="${CC-cc} -E -no-cpp-precomp"
 494     # Use fink packages if available.
 495     if test -d /sw/include && test -d /sw/lib; then
 496       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 497       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 498       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 499     fi
 500   ;;
 501
 502   ## HP 9000 series 700 and 800, running HP/UX
 503   hppa*-hp-hpux10.2* )
 504     opsys=hpux10-20
 505   ;;
 506   hppa*-hp-hpux1[1-9]* )
 507     opsys=hpux11
 508     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 509   ;;
 510
 511   ia64*-hp-hpux1[1-9]* )
 512     machine=hp800 opsys=hpux11
 513     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 514     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 515     CANNOT_DUMP=yes
 516   ;;
 517
 518   hppa*-*-linux-gnu* )
 519     machine=hp800 opsys=gnu-linux
 520   ;;
 521
 522   ## IBM machines
 523   rs6000-ibm-aix4.[23]* )
 524     machine=ibmrs6000 opsys=aix4-2
 525   ;;
 526   powerpc-ibm-aix4.[23]*  )
 527     machine=ibmrs6000 opsys=aix4-2
 528   ;;
 529   rs6000-ibm-aix[56]* )
 530     machine=ibmrs6000 opsys=aix4-2
 531   ;;
 532   powerpc-ibm-aix[56]*  )
 533     machine=ibmrs6000 opsys=aix4-2
 534   ;;
 535
 536   ## Silicon Graphics machines
 537   ## Iris 4D
 538   mips-sgi-irix6.5 )
 539     opsys=irix6-5
 540     # Without defining _LANGUAGE_C, things get masked out in the headers
 541     # so that, for instance, grepping for `free' in stdlib.h fails and
 542     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 543     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 544     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 545   ;;
 546
 547   ## Suns
 548   *-sun-solaris* \
 549     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 550     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 551     case "${canonical}" in
 552       i[3456]86-*-* )     machine=intel386 ;;
 553       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 554       sparc* )          machine=sparc ;;
 555       * )               unported=yes ;;
 556     esac
 557     case "${canonical}" in
 558       *-sunos5.6* | *-solaris2.6* )
 559                 opsys=sol2-6
 560                 NON_GNU_CPP=/usr/ccs/lib/cpp
 561                 RANLIB="ar -ts"
 562                 ;;
 563       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 564                 opsys=sol2-6
 565                 emacs_check_sunpro_c=yes
 566                 NON_GNU_CPP=/usr/ccs/lib/cpp
 567                 ;;
 568       *-sunos5* | *-solaris* )
 569                 opsys=sol2-10
 570                 emacs_check_sunpro_c=yes
 571                 NON_GNU_CPP=/usr/ccs/lib/cpp
 572                 ;;
 573     esac
 574     ## Watch out for a compiler that we know will not work.
 575     case "${canonical}" in
 576      *-solaris* | *-sunos5* )
 577                 if [ "x$CC" = x/usr/ucb/cc ]; then
 578                   ## /usr/ucb/cc doesn't work;
 579                   ## we should find some other compiler that does work.
 580                   unset CC
 581                 fi
 582                 ;;
 583       *) ;;
 584     esac
 585   ;;
 586
 587   ## Intel 386 machines where we don't care about the manufacturer.
 588   i[3456]86-*-* )
 589     machine=intel386
 590     case "${canonical}" in
 591       *-cygwin )                opsys=cygwin ;;
 592       *-darwin* )               opsys=darwin
 593                                 CPP="${CC-cc} -E -no-cpp-precomp"
 594                                 ;;
 595       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 596       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 599     esac
 600   ;;
 601
 602   * )
 603     unported=yes
 604   ;;
 605 esac
 606
 607 ### If the code above didn't choose an operating system, just choose
 608 ### an operating system based on the configuration name.  You really
 609 ### only want to use this when you have no idea what the right
 610 ### operating system is; if you know what operating systems a machine
 611 ### runs, it's cleaner to make it explicit in the case statement
 612 ### above.
 613 if test x"${opsys}" = x; then
 614   case "${canonical}" in
 615     *-gnu* )                            opsys=gnu ;;
 616     * )
 617       unported=yes
 618     ;;
 619   esac
 620 fi
 621
 622 ]
 623 dnl quotation ends
 624
 625 if test $unported = yes; then
 626   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 627 Check `etc/MACHINES' for recognized configuration names.])
 628 fi
 629
 630 if test -n "$machine"; then
 631   machfile="m/${machine}.h"
 632 else
 633   machfile=
 634 fi
 635 opsysfile="s/${opsys}.h"
 636
 637
 638 #### Choose a compiler.
 639 test -n "$CC" && cc_specified=yes
 640
 641 # Save the value of CFLAGS that the user specified.
 642 SPECIFIED_CFLAGS="$CFLAGS"
 643
 644 dnl Sets GCC=yes if using gcc.
 645 AC_PROG_CC
 646 AM_PROG_CC_C_O
 647
 648 # Initialize gnulib right after verifying that the C compiler works.
 649 gl_EARLY
 650
 651 # On Suns, sometimes $CPP names a directory.
 652 if test -n "$CPP" && test -d "$CPP"; then
 653   CPP=
 654 fi
 655
 656 ## If not using gcc, and on Solaris, and no CPP specified, see if
 657 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 658 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 659  test x"$CPP" = x; then
 660   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 661   AC_CACHE_VAL(emacs_cv_sunpro_c,
 662   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 663 [[#ifndef __SUNPRO_C
 664 fail;
 665 #endif
 666 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 667   AC_MSG_RESULT($emacs_cv_sunpro_c)
 668
 669   if test x"$emacs_cv_sunpro_c" = xyes; then
 670     NON_GNU_CPP="$CC -E -Xs"
 671   fi
 672 fi
 673
 674 #### Some systems specify a CPP to use unless we are using GCC.
 675 #### Now that we know whether we are using GCC, we can decide whether
 676 #### to use that one.
 677 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 678 then
 679   CPP="$NON_GNU_CPP"
 680 fi
 681
 682 #### Some systems specify a CC to use unless we are using GCC.
 683 #### Now that we know whether we are using GCC, we can decide whether
 684 #### to use that one.
 685 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 686   test x$cc_specified != xyes
 687 then
 688   CC="$NON_GNU_CC"
 689 fi
 690
 691 if test x$GCC = xyes; then
 692   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 693 else
 694   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 695 fi
 696
 697 ### Use -Wdeclaration-after-statement if the compiler supports it
 698 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 699 SAVE_CFLAGS="$CFLAGS"
 700 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 701 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 702 if test $has_option = yes; then
 703    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 704 fi
 705 AC_MSG_RESULT($has_option)
 706 CFLAGS="$SAVE_CFLAGS"
 707 unset has_option
 708 unset SAVE_CFLAGS
 709
 710 ### Use -Wold-style-definition if the compiler supports it
 711 # This can be removed when conversion to standard C is finished.
 712 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 713 SAVE_CFLAGS="$CFLAGS"
 714 CFLAGS="$CFLAGS -Wold-style-definition"
 715 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 716 if test $has_option = yes; then
 717    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 718 fi
 719 AC_MSG_RESULT($has_option)
 720 CFLAGS="$SAVE_CFLAGS"
 721 unset has_option
 722 unset SAVE_CFLAGS
 723
 724 ### Use -Wimplicit-function-declaration if the compiler supports it
 725 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 726 SAVE_CFLAGS="$CFLAGS"
 727 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 728 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 729 if test $has_option = yes; then
 730    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 731 fi
 732 AC_MSG_RESULT($has_option)
 733 CFLAGS="$SAVE_CFLAGS"
 734 unset has_option
 735 unset SAVE_CFLAGS
 736
 737 AC_SUBST(C_WARNINGS_SWITCH)
 738
 739
 740 #### Some other nice autoconf tests.
 741
 742 dnl checks for programs
 743 AC_PROG_CPP
 744 AC_PROG_INSTALL
 745 if test "x$RANLIB" = x; then
 746   AC_PROG_RANLIB
 747 fi
 748
 749 ## Although we're running on an amd64 kernel, we're actually compiling for
 750 ## the x86 architecture.  The user should probably have provided an
 751 ## explicit --build to `configure', but if everything else than the kernel
 752 ## is running in i386 mode, we can help them out.
 753 if test "$machine" = "amdx86-64"; then
 754   AC_CHECK_DECL([i386])
 755   if test "$ac_cv_have_decl_i386" = "yes"; then
 756     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 757     machine=intel386
 758     machfile="m/${machine}.h"
 759   fi
 760 fi
 761
 762 AC_PATH_PROG(INSTALL_INFO, install-info)
 763 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 764 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 765 dnl Don't use GZIP, which is used by gzip for additional parameters.
 766 AC_PATH_PROG(GZIP_PROG, gzip)
 767
 768
 769 ## Need makeinfo >= 4.6 (?) to build the manuals.
 770 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 771 dnl By this stage, configure has already checked for egrep and set EGREP,
 772 dnl or exited with an error if no egrep was found.
 773 if test "$MAKEINFO" != "no" && \
 774   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 775    MAKEINFO=no
 776 fi
 777
 778 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 779 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 780 ## therefore in the category of "special tools" not normally required, which
 781 ## configure does not have to check for (eg autoconf itself).
 782 ## In a Bazaar checkout on the other hand, the manuals are not included.
 783 ## So makeinfo is a requirement to build from Bazaar, and configure
 784 ## should test for it as it does for any other build requirement.
 785 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 786 ## with pre-built manuals, from a Bazaar checkout.
 787 HAVE_MAKEINFO=yes
 788
 789 if test "$MAKEINFO" = "no"; then
 790   MAKEINFO=makeinfo
 791   if test "x${with_makeinfo}" = "xno"; then
 792     HAVE_MAKEINFO=no
 793   elif test ! -e $srcdir/info/emacs; then
 794     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 795 source tree does not seem to have pre-built manuals in the `info' directory.
 796 Either install a suitable version of makeinfo, or re-run configure
 797 with the `--without-makeinfo' option to build without the manuals.] )
 798   fi
 799 fi
 800 AC_SUBST(HAVE_MAKEINFO)
 801
 802 dnl Add our options to ac_link now, after it is set up.
 803
 804 if test x$GCC = xyes; then
 805   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 806     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 807 else
 808   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 809     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 810 fi
 811
 812 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 813 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 814 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 815 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 816 dnl if not built to support GNU ld.
 817
 818 late_LDFLAGS=$LDFLAGS
 819 if test x$GCC = xyes; then
 820   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 821 else
 822   LDFLAGS="$LDFLAGS -znocombreloc"
 823 fi
 824
 825 AC_MSG_CHECKING([for -znocombreloc])
 826 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 827   [AC_MSG_RESULT(yes)],
 828   LDFLAGS=$late_LDFLAGS
 829   [AC_MSG_RESULT(no)])
 830
 831
 832 # The value of CPP is a quoted variable reference, so we need to do this
 833 # to get its actual value...
 834 CPP=`eval "echo $CPP"`
 835
 836
 837 dnl The function dump-emacs will not be defined and temacs will do
 838 dnl (load "loadup") automatically unless told otherwise.
 839 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 840 case "$opsys" in
 841   your-opsys-here) CANNOT_DUMP=yes ;;
 842 esac
 843
 844 test "$CANNOT_DUMP" = "yes" && \
 845   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 846
 847 AC_SUBST(CANNOT_DUMP)
 848
 849
 850 UNEXEC_OBJ=unexelf.o
 851 case "$opsys" in
 852   # MSDOS uses unexcoff.o
 853   # MSWindows uses unexw32.o
 854   aix4-2)
 855    UNEXEC_OBJ=unexaix.o
 856    ;;
 857   cygwin)
 858    UNEXEC_OBJ=unexcw.o
 859    ;;
 860   darwin)
 861    UNEXEC_OBJ=unexmacosx.o
 862    ;;
 863   hpux10-20 | hpux11)
 864    UNEXEC_OBJ=unexhp9k800.o
 865    ;;
 866   sol2-10)
 867    # Use the Solaris dldump() function, called from unexsol.c, to dump
 868    # emacs, instead of the generic ELF dump code found in unexelf.c.
 869    # The resulting binary has a complete symbol table, and is better
 870    # for debugging and other observability tools (debuggers, pstack, etc).
 871    #
 872    # If you encounter a problem using dldump(), please consider sending
 873    # a message to the OpenSolaris tools-linking mailing list:
 874    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 875    #
 876    # It is likely that dldump() works with older Solaris too, but this has
 877    # not been tested, so for now this change is for Solaris 10 or newer.
 878    UNEXEC_OBJ=unexsol.o
 879    ;;
 880 esac
 881
 882 LD_SWITCH_SYSTEM=
 883 case "$opsys" in
 884   freebsd)
 885    ## Let `ld' find image libs and similar things in /usr/local/lib.
 886    ## The system compiler, GCC, has apparently been modified to not
 887    ## look there, contrary to what a stock GCC would do.
 888    LD_SWITCH_SYSTEM=-L/usr/local/lib
 889    ;;
 890
 891   gnu-linux)
 892    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 893    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 894    ;;
 895
 896   netbsd)
 897    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 898    ;;
 899
 900   openbsd)
 901    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 902    ## otherwise Emacs dumps core on elf systems.
 903    LD_SWITCH_SYSTEM="-Z"
 904    ;;
 905 esac
 906 AC_SUBST(LD_SWITCH_SYSTEM)
 907
 908 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 909
 910 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 911 ## which has not been defined yet.  When this was handled with cpp,
 912 ## it was expanded to null when configure sourced the s/*.h file.
 913 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 914 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 915 ## (or somesuch), but because it is supposed to go at the _front_
 916 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 917 ## Compare with the gnu-linux case below, which added to the end
 918 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 919 ## LD_SWITCH_SYSTEM_TEMACS.
 920 case "$opsys" in
 921   netbsd|openbsd)
 922    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 923    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 924 esac
 925
 926
 927 C_SWITCH_MACHINE=
 928 if test "$machine" = "alpha"; then
 929   AC_CHECK_DECL([__ELF__])
 930   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 931     ## With ELF, make sure that all common symbols get allocated to in the
 932     ## data section.  Otherwise, the dump of temacs may miss variables in
 933     ## the shared library that have been initialized.  For example, with
 934     ## GNU libc, __malloc_initialized would normally be resolved to the
 935     ## shared library's .bss section, which is fatal.
 936     if test "x$GCC" = "xyes"; then
 937       C_SWITCH_MACHINE="-fno-common"
 938     else
 939       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 940     fi
 941   else
 942     UNEXEC_OBJ=unexalpha.o
 943   fi
 944 fi
 945 AC_SUBST(C_SWITCH_MACHINE)
 946
 947 AC_SUBST(UNEXEC_OBJ)
 948
 949 C_SWITCH_SYSTEM=
 950 ## Some programs in src produce warnings saying certain subprograms
 951 ## are too complex and need a MAXMEM value greater than 2000 for
 952 ## additional optimization.  --nils@exp-math.uni-essen.de
 953 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 954   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 955 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 956 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 957 AC_SUBST(C_SWITCH_SYSTEM)
 958
 959
 960 LIBS_SYSTEM=
 961 case "$opsys" in
 962   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 963   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 964
 965   freebsd) LIBS_SYSTEM="-lutil" ;;
 966
 967   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 968
 969   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 970
 971   ## Motif needs -lgen.
 972   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 973 esac
 974 AC_SUBST(LIBS_SYSTEM)
 975
 976
 977 ### Make sure subsequent tests use flags consistent with the build flags.
 978
 979 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 980   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 981 else
 982   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 983 fi
 984
 985 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 986 AC_DEFUN([AC_TYPE_SIZE_T])
 987 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 988 AC_DEFUN([AC_TYPE_UID_T])
 989
 990 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 991 AC_SYS_LARGEFILE
 992
 993
 994 LIB_MATH=-lm
 995 LIB_STANDARD=
 996 START_FILES=
 997
 998 case $opsys in
 999   cygwin )
1000     LIB_MATH=
1001     START_FILES='pre-crt0.o'
1002     ;;
1003   darwin )
1004     ## Adding -lm confuses the dynamic linker, so omit it.
1005     LIB_MATH=
1006     START_FILES='pre-crt0.o'
1007     ;;
1008   freebsd )
1009     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1010     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1011     ;;
1012   gnu-linux | gnu-kfreebsd )
1013     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1014     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1015     ;;
1016   hpux10-20 | hpux11 )
1017     LIB_STANDARD=-lc
1018     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1019     ;;
1020   netbsd | openbsd )
1021     if test -f $CRT_DIR/crti.o; then
1022         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1023         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1024     else
1025         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1026         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1027     fi
1028     ;;
1029 esac
1030
1031 AC_SUBST(LIB_MATH)
1032 AC_SUBST(START_FILES)
1033
1034 dnl Not all platforms use crtn.o files.  Check if the current one does.
1035 crt_files=
1036
1037 for file in x $LIB_STANDARD $START_FILES; do
1038   case "$file" in
1039     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1040   esac
1041 done
1042
1043 if test "x$crt_files" != x; then
1044
1045   ## If user specified a crt-dir, use that unconditionally.
1046   crt_gcc=no
1047
1048   if test "X$CRT_DIR" = "X"; then
1049
1050     CRT_DIR=/usr/lib            # default
1051
1052     case "$canonical" in
1053       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1054       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1055       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1056       ## For anything else (eg /usr/lib32), it is up the user to specify
1057       ## the location (bug#5655).
1058       ## Test for crtn.o, not just the directory, because sometimes the
1059       ## directory exists but does not have the relevant files (bug#1287).
1060       ## FIXME better to test for binary compatibility somehow.
1061       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1062       ;;
1063
1064       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1065     esac
1066
1067     case "$opsys" in
1068       hpux10-20) CRT_DIR=/lib ;;
1069     esac
1070
1071     test "x${GCC}" = xyes && crt_gcc=yes
1072
1073   fi                            # CRT_DIR = ""
1074
1075   crt_missing=
1076
1077   for file in $crt_files; do
1078
1079     ## If we're using gcc, try to determine it automatically by asking
1080     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1081     ## system-dependent default from above.]
1082     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1083
1084        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1085        case "$crt_file" in
1086          */*)
1087            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1088            ;;
1089        esac
1090     fi
1091
1092     dnl We expect all the files to be in a single directory, so after the
1093     dnl first there is no point asking gcc.
1094     crt_gcc=no
1095
1096     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1097   done                          # $crt_files
1098
1099   test "x$crt_missing" = x || \
1100     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1101 Try using the --with-crt-dir option.])
1102
1103 fi                              # crt_files != ""
1104
1105 AC_SUBST(CRT_DIR)
1106
1107
1108 dnl This function definition taken from Gnome 2.0
1109 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1110 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1111 dnl also defines GSTUFF_PKG_ERRORS on error
1112 AC_DEFUN([PKG_CHECK_MODULES], [
1113   succeeded=no
1114
1115   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1116
1117   if test "$PKG_CONFIG" = "no" ; then
1118      ifelse([$4], , [AC_MSG_ERROR([
1119       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1120   else
1121      PKG_CONFIG_MIN_VERSION=0.9.0
1122      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1123         AC_MSG_CHECKING(for $2)
1124
1125         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1126             AC_MSG_RESULT(yes)
1127             succeeded=yes
1128
1129             AC_MSG_CHECKING($1_CFLAGS)
1130             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1131             AC_MSG_RESULT($$1_CFLAGS)
1132
1133             AC_MSG_CHECKING($1_LIBS)
1134             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1135             AC_MSG_RESULT($$1_LIBS)
1136         else
1137             AC_MSG_RESULT(no)
1138             $1_CFLAGS=""
1139             $1_LIBS=""
1140             ## If we have a custom action on failure, don't print errors, but
1141             ## do set a variable so people can do so.
1142             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1143             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1144         fi
1145
1146         AC_SUBST($1_CFLAGS)
1147         AC_SUBST($1_LIBS)
1148      else
1149         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1150         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1151      fi
1152   fi
1153
1154   if test $succeeded = yes; then
1155      ifelse([$3], , :, [$3])
1156   else
1157      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1158   fi
1159 ])
1160
1161
1162 if test "${with_sound}" != "no"; then
1163   # Sound support for GNU/Linux and the free BSDs.
1164   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1165     have_sound_header=yes)
1166   # Emulation library used on NetBSD.
1167   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1168   AC_SUBST(LIBSOUND)
1169
1170   ALSA_REQUIRED=1.0.0
1171   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1172   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1173   if test $HAVE_ALSA = yes; then
1174     SAVE_CFLAGS="$CFLAGS"
1175     SAVE_LDFLAGS="$LDFLAGS"
1176     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1177     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1178     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1179                     emacs_alsa_normal=yes,
1180                     emacs_alsa_normal=no)
1181     if test "$emacs_alsa_normal" != yes; then
1182       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1183                      [[snd_lib_error_set_handler (0);]])],
1184                      emacs_alsa_subdir=yes,
1185                      emacs_alsa_subdir=no)
1186       if test "$emacs_alsa_subdir" != yes; then
1187         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1188       fi
1189       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1190     fi
1191
1192     CFLAGS="$SAVE_CFLAGS"
1193     LDFLAGS="$SAVE_LDFLAGS"
1194     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1195     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1196     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1197   fi
1198
1199   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1200   dnl compiles only on the specified platforms.  For others, it
1201   dnl probably doesn't make sense to try.
1202   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1203      case "$opsys" in
1204        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1205        gnu-linux|freebsd|netbsd)
1206          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1207          ;;
1208      esac
1209   fi
1210
1211   AC_SUBST(CFLAGS_SOUND)
1212 fi
1213
1214 dnl checks for header files
1215 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1216   linux/version.h sys/systeminfo.h \
1217   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1218   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1219   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1220
1221 AC_MSG_CHECKING(if personality LINUX32 can be set)
1222 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1223                emacs_cv_personality_linux32=yes,
1224                emacs_cv_personality_linux32=no)
1225 AC_MSG_RESULT($emacs_cv_personality_linux32)
1226
1227 if test $emacs_cv_personality_linux32 = yes; then
1228   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1229             [Define to 1 if personality LINUX32 can be set.])
1230 fi
1231
1232 dnl On Solaris 8 there's a compilation warning for term.h because
1233 dnl it doesn't define `bool'.
1234 AC_CHECK_HEADERS(term.h, , , -)
1235 AC_HEADER_TIME
1236 AC_CHECK_DECLS([sys_siglist])
1237 if test $ac_cv_have_decl_sys_siglist != yes; then
1238   # For Tru64, at least:
1239   AC_CHECK_DECLS([__sys_siglist])
1240   if test $ac_cv_have_decl___sys_siglist = yes; then
1241     AC_DEFINE(sys_siglist, __sys_siglist,
1242               [Define to any substitute for sys_siglist.])
1243   fi
1244 fi
1245 AC_HEADER_SYS_WAIT
1246
1247 dnl Some systems have utime.h but don't declare the struct anyplace.
1248 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1249 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1250 #include <sys/time.h>
1251 #include <time.h>
1252 #else
1253 #ifdef HAVE_SYS_TIME_H
1254 #include <sys/time.h>
1255 #else
1256 #include <time.h>
1257 #endif
1258 #endif
1259 #ifdef HAVE_UTIME_H
1260 #include <utime.h>
1261 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1262   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1263 if test $emacs_cv_struct_utimbuf = yes; then
1264   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1265 fi
1266
1267 dnl Check for speed_t typedef.
1268 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1269   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1270     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1271 if test $emacs_cv_speed_t = yes; then
1272   AC_DEFINE(HAVE_SPEED_T, 1,
1273            [Define to 1 if `speed_t' is declared by <termios.h>.])
1274 fi
1275
1276 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1277 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1278 #include <sys/time.h>
1279 #include <time.h>
1280 #else
1281 #ifdef HAVE_SYS_TIME_H
1282 #include <sys/time.h>
1283 #else
1284 #include <time.h>
1285 #endif
1286 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1287   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1288 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1289 if test $emacs_cv_struct_timeval = yes; then
1290   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1291 fi
1292
1293 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1294 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1295 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1296   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1297 HAVE_EXCEPTION=$emacs_cv_struct_exception
1298 if test $emacs_cv_struct_exception != yes; then
1299   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1300 fi
1301
1302 AC_CHECK_HEADERS(sys/socket.h)
1303 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1304 #if HAVE_SYS_SOCKET_H
1305 #include <sys/socket.h>
1306 #endif])
1307 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1308 #if HAVE_SYS_SOCKET_H
1309 #include <sys/socket.h>
1310 #endif])
1311 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1312 #if HAVE_SYS_SOCKET_H
1313 #include <sys/socket.h>
1314 #endif])
1315 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1316
1317 dnl checks for structure members
1318 AC_STRUCT_TM
1319 AC_STRUCT_TIMEZONE
1320 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1321                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1322                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1323                 [#include <time.h>])
1324 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1325                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1326                   struct ifreq.ifr_addr,
1327                   struct ifreq.ifr_addr.sa_len], , ,
1328                  [AC_INCLUDES_DEFAULT
1329 #if HAVE_SYS_SOCKET_H
1330 #include <sys/socket.h>
1331 #endif
1332 #if HAVE_NET_IF_H
1333 #include <net/if.h>
1334 #endif])
1335
1336 dnl checks for compiler characteristics
1337
1338 dnl Testing __STDC__ to determine prototype support isn't good enough.
1339 dnl DEC C, for instance, doesn't define it with default options, and
1340 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1341 dnl and void *.
1342 AC_C_PROTOTYPES
1343 AC_C_VOLATILE
1344 AC_C_CONST
1345 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1346   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1347                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1348 if test $emacs_cv_void_star = yes; then
1349   AC_DEFINE(POINTER_TYPE, void)
1350 else
1351   AC_DEFINE(POINTER_TYPE, char)
1352 fi
1353 AH_TEMPLATE(POINTER_TYPE,
1354             [Define as `void' if your compiler accepts `void *'; otherwise
1355              define as `char'.])dnl
1356
1357 dnl Check for endianess
1358 AC_C_BIGENDIAN
1359
1360 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1361   [emacs_cv_attribute_aligned],
1362   [AC_COMPILE_IFELSE(
1363      [AC_LANG_PROGRAM(
1364         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1365         [[]])],
1366      [emacs_cv_attribute_aligned=yes],
1367      [emacs_cv_attribute_aligned=no])])
1368 if test $emacs_cv_attribute_aligned = yes; then
1369   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1370     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1371 fi
1372
1373 dnl check for Make feature
1374 AC_PROG_MAKE_SET
1375
1376 DEPFLAGS=
1377 MKDEPDIR=":"
1378 deps_frag=deps.mk
1379 dnl check for GNU Make if we have GCC and autodepend is on.
1380 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1381    AC_MSG_CHECKING([whether we are using GNU Make])
1382    HAVE_GNU_MAKE=no
1383    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1384    if test "x$testval" != x; then
1385       HAVE_GNU_MAKE=yes
1386    else
1387       ac_enable_autodepend=no
1388    fi
1389    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1390    if test $HAVE_GNU_MAKE = yes; then
1391       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1392       SAVE_CFLAGS="$CFLAGS"
1393       CFLAGS="$CFLAGS -MMD -MF deps.d"
1394       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1395       CFLAGS="$SAVE_CFLAGS"
1396       test -f deps.d || ac_enable_autodepend=no
1397       rm -rf deps.d
1398       AC_MSG_RESULT([$ac_enable_autodepend])
1399    fi
1400    if test $ac_enable_autodepend = yes; then
1401       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1402       ## In parallel builds, another make might create depdir between
1403       ## the first test and mkdir, so stick another test on the end.
1404       ## Or use install-sh -d?  mkdir -p is not portable.
1405       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1406       deps_frag=autodeps.mk
1407    fi
1408 fi
1409 deps_frag=$srcdir/src/$deps_frag
1410 AC_SUBST(MKDEPDIR)
1411 AC_SUBST(DEPFLAGS)
1412 AC_SUBST_FILE(deps_frag)
1413
1414
1415 lisp_frag=$srcdir/src/lisp.mk
1416 AC_SUBST_FILE(lisp_frag)
1417
1418
1419 dnl checks for operating system services
1420 AC_SYS_LONG_FILE_NAMES
1421
1422 #### Choose a window system.
1423
1424 AC_PATH_X
1425 if test "$no_x" = yes; then
1426   window_system=none
1427 else
1428   window_system=x11
1429 fi
1430
1431 ## Workaround for bug in autoconf <= 2.62.
1432 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1433 ## No need to do anything special for these standard directories.
1434 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1435
1436    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1437
1438 fi
1439
1440 LD_SWITCH_X_SITE_AUX=
1441 LD_SWITCH_X_SITE_AUX_RPATH=
1442 if test "${x_libraries}" != NONE; then
1443   if test -n "${x_libraries}"; then
1444     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1445     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1446     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1447   fi
1448   x_default_search_path=""
1449   x_search_path=${x_libraries}
1450   if test -z "${x_search_path}"; then
1451     x_search_path=/usr/lib
1452   fi
1453   for x_library in `echo ${x_search_path}: | \
1454                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1455     x_search_path="\
1456 ${x_library}/X11/%L/%T/%N%C%S:\
1457 ${x_library}/X11/%l/%T/%N%C%S:\
1458 ${x_library}/X11/%T/%N%C%S:\
1459 ${x_library}/X11/%L/%T/%N%S:\
1460 ${x_library}/X11/%l/%T/%N%S:\
1461 ${x_library}/X11/%T/%N%S"
1462     if test x"${x_default_search_path}" = x; then
1463       x_default_search_path=${x_search_path}
1464     else
1465       x_default_search_path="${x_search_path}:${x_default_search_path}"
1466     fi
1467   done
1468 fi
1469 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1470 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1471
1472 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1473   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1474 fi
1475
1476 if test x"${x_includes}" = x; then
1477   bitmapdir=/usr/include/X11/bitmaps
1478 else
1479   # accumulate include directories that have X11 bitmap subdirectories
1480   bmd_acc="dummyval"
1481   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1482     if test -d "${bmd}/X11/bitmaps"; then
1483       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1484     fi
1485     if test -d "${bmd}/bitmaps"; then
1486       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1487     fi
1488   done
1489   if test ${bmd_acc} != "dummyval"; then
1490     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1491   fi
1492 fi
1493
1494 HAVE_NS=no
1495 NS_IMPL_COCOA=no
1496 NS_IMPL_GNUSTEP=no
1497 tmp_CPPFLAGS="$CPPFLAGS"
1498 tmp_CFLAGS="$CFLAGS"
1499 CPPFLAGS="$CPPFLAGS -x objective-c"
1500 CFLAGS="$CFLAGS -x objective-c"
1501 TEMACS_LDFLAGS2="\${LDFLAGS}"
1502 dnl I don't think it's especially important, but src/Makefile.in
1503 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1504 dnl trailing "/" to it, so now we do it here.
1505 if test "${with_ns}" != no; then
1506   if test "${opsys}" = darwin; then
1507      NS_IMPL_COCOA=yes
1508      ns_appdir=`pwd`/nextstep/Emacs.app
1509      ns_appbindir=${ns_appdir}/Contents/MacOS/
1510      ns_appresdir=${ns_appdir}/Contents/Resources
1511      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1512   elif test -f $GNUSTEP_CONFIG_FILE; then
1513      NS_IMPL_GNUSTEP=yes
1514      ns_appdir=`pwd`/nextstep/Emacs.app
1515      ns_appbindir=${ns_appdir}/
1516      ns_appresdir=${ns_appdir}/Resources
1517      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1518      dnl FIXME sourcing this several times in subshells seems inefficient.
1519      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1520      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1521      dnl I seemed to need these as well with GNUstep-startup 0.25.
1522      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1523      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1524      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1525        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1526      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1527        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1528      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1529      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1530      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1531      LIB_STANDARD=
1532      START_FILES=
1533      TEMACS_LDFLAGS2=
1534   fi
1535   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1536                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1537   files are missing or cannot be compiled.])])
1538   NS_HAVE_NSINTEGER=yes
1539   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1540                                      [NSInteger i;])],
1541                     ns_have_nsinteger=yes,
1542                     ns_have_nsinteger=no)
1543   if test $ns_have_nsinteger = no; then
1544     NS_HAVE_NSINTEGER=no
1545   fi
1546 fi
1547 AC_SUBST(TEMACS_LDFLAGS2)
1548
1549 ns_frag=/dev/null
1550 NS_OBJ=
1551 NS_OBJC_OBJ=
1552 if test "${HAVE_NS}" = yes; then
1553   window_system=nextstep
1554   with_xft=no
1555   # set up packaging dirs
1556   exec_prefix=${ns_appbindir}
1557   libexecdir=${ns_appbindir}/libexec
1558   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1559      prefix=${ns_appresdir}
1560   fi
1561   ns_frag=$srcdir/src/ns.mk
1562   NS_OBJ="fontset.o fringe.o image.o"
1563   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1564 fi
1565 CFLAGS="$tmp_CFLAGS"
1566 CPPFLAGS="$tmp_CPPFLAGS"
1567 AC_SUBST(NS_OBJ)
1568 AC_SUBST(NS_OBJC_OBJ)
1569 AC_SUBST(LIB_STANDARD)
1570 AC_SUBST_FILE(ns_frag)
1571
1572 case "${window_system}" in
1573   x11 )
1574     HAVE_X_WINDOWS=yes
1575     HAVE_X11=yes
1576     case "${with_x_toolkit}" in
1577       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1578       motif ) USE_X_TOOLKIT=MOTIF ;;
1579       gtk ) with_gtk=yes
1580 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1581 dnl USE_X_TOOLKIT is set.
1582             USE_X_TOOLKIT=none ;;
1583       gtk3 ) with_gtk3=yes
1584              USE_X_TOOLKIT=none ;;
1585       no ) USE_X_TOOLKIT=none ;;
1586 dnl If user did not say whether to use a toolkit, make this decision later:
1587 dnl use the toolkit if we have gtk, or X11R5 or newer.
1588       * ) USE_X_TOOLKIT=maybe ;;
1589     esac
1590   ;;
1591   nextstep | none )
1592     HAVE_X_WINDOWS=no
1593     HAVE_X11=no
1594     USE_X_TOOLKIT=none
1595   ;;
1596 esac
1597
1598 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1599    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1600    if test "$HAVE_XSERVER" = true ||
1601       test -n "$DISPLAY" ||
1602       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1603         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1604 were found.  You should install the relevant development files for X
1605 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1606 sure you have development files for image handling, i.e.
1607 tiff, gif, jpeg, png and xpm.
1608 If you are sure you want Emacs compiled without X window support, pass
1609   --without-x
1610 to configure.])
1611    fi
1612 fi
1613
1614 ### If we're using X11, we should use the X menu package.
1615 HAVE_MENUS=no
1616 case ${HAVE_X11} in
1617   yes ) HAVE_MENUS=yes ;;
1618 esac
1619
1620 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1621 # Assume not, until told otherwise.
1622 GNU_MALLOC=yes
1623 doug_lea_malloc=yes
1624 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1625 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1626 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1627                emacs_cv_var___after_morecore_hook,
1628 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1629   emacs_cv_var___after_morecore_hook=yes,
1630   emacs_cv_var___after_morecore_hook=no)])
1631 if test $emacs_cv_var___after_morecore_hook = no; then
1632   doug_lea_malloc=no
1633 fi
1634
1635
1636 dnl See comments in aix4-2.h about maybe using system malloc there.
1637 system_malloc=no
1638 case "$opsys" in
1639   ## darwin ld insists on the use of malloc routines in the System framework.
1640   darwin|sol2-10) system_malloc=yes ;;
1641 esac
1642
1643 if test "${system_malloc}" = "yes"; then
1644   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1645   GNU_MALLOC=no
1646   GNU_MALLOC_reason="
1647     (The GNU allocators don't work with this system configuration.)"
1648   GMALLOC_OBJ=
1649   VMLIMIT_OBJ=
1650 else
1651   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1652   VMLIMIT_OBJ=vm-limit.o
1653 fi
1654 AC_SUBST(GMALLOC_OBJ)
1655 AC_SUBST(VMLIMIT_OBJ)
1656
1657 if test "$doug_lea_malloc" = "yes" ; then
1658   if test "$GNU_MALLOC" = yes ; then
1659     GNU_MALLOC_reason="
1660       (Using Doug Lea's new malloc from the GNU C Library.)"
1661   fi
1662   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1663             [Define to 1 if you are using the GNU C Library.])
1664
1665   ## Use mmap directly for allocating larger buffers.
1666   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1667   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1668   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1669   case "$opsys" in
1670     gnu*) REL_ALLOC=no ;;
1671   esac
1672 fi
1673
1674 if test x"${REL_ALLOC}" = x; then
1675   REL_ALLOC=${GNU_MALLOC}
1676 fi
1677
1678 use_mmap_for_buffers=no
1679 case "$opsys" in
1680   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1681 esac
1682
1683 AC_FUNC_MMAP
1684 if test $use_mmap_for_buffers = yes; then
1685   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1686   REL_ALLOC=no
1687 fi
1688
1689 LIBS="$LIBS_SYSTEM $LIBS"
1690
1691 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1692 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1693 AC_CHECK_LIB(dnet, dnet_ntoa)
1694 dnl This causes -lresolv to get used in subsequent tests,
1695 dnl which causes failures on some systems such as HPUX 9.
1696 dnl AC_CHECK_LIB(resolv, gethostbyname)
1697
1698 dnl FIXME replace main with a function we actually want from this library.
1699 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1700
1701 dnl Check if pthreads is available.
1702 LIB_PTHREAD=
1703 AC_CHECK_HEADERS(pthread.h)
1704 if test "$ac_cv_header_pthread_h"; then
1705   AC_CHECK_LIB(pthread, pthread_self, HAVE_PTHREAD=yes)
1706 fi
1707 if test "$HAVE_PTHREAD" = yes; then
1708   case "${canonical}" in
1709     *-hpux*) ;;
1710     *) LIB_PTHREAD="-lpthread" ;;
1711   esac
1712   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1713 fi
1714 AC_SUBST([LIB_PTHREAD])
1715
1716 AC_CHECK_LIB(pthreads, cma_open)
1717
1718 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1719 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1720 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1721 ## added to LIBS in configure would never contain the pthreads part,
1722 ## but the value used in Makefiles might.  FIXME?
1723 ##
1724 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1725 ## be harmless on older versions of X where it happens to exist.
1726 test "$opsys" = "aix4-2" && \
1727   test $ac_cv_lib_pthreads_cma_open = yes && \
1728   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1729
1730 dnl Check for need for bigtoc support on IBM AIX
1731
1732 case ${host_os} in
1733 aix*)
1734   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1735     case $GCC in
1736     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1737     *) gdb_cv_bigtoc=-bbigtoc ;;
1738     esac
1739
1740     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1741     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1742   ])
1743   ;;
1744 esac
1745
1746 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1747 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1748 # REAL_CPPFLAGS later on.
1749
1750 REAL_CFLAGS="$CFLAGS"
1751 REAL_CPPFLAGS="$CPPFLAGS"
1752
1753 if test "${HAVE_X11}" = "yes"; then
1754   DEFS="$C_SWITCH_X_SITE $DEFS"
1755   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1756   LIBS="-lX11 $LIBS"
1757   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1758   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1759
1760   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1761   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1762   # but it's more convenient here to set LD_RUN_PATH
1763   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1764   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1765     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1766     export LD_RUN_PATH
1767   fi
1768
1769   if test "${opsys}" = "gnu-linux"; then
1770     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1771     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1772      [[XOpenDisplay ("foo");]])],
1773      [xlinux_first_failure=no],
1774      [xlinux_first_failure=yes])
1775     if test "${xlinux_first_failure}" = "yes"; then
1776       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1777       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1778       OLD_CPPFLAGS="$CPPFLAGS"
1779       OLD_LIBS="$LIBS"
1780       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1781       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1782       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1783       LIBS="$LIBS -b i486-linuxaout"
1784       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1785        [[XOpenDisplay ("foo");]])],
1786        [xlinux_second_failure=no],
1787        [xlinux_second_failure=yes])
1788       if test "${xlinux_second_failure}" = "yes"; then
1789         # If we get the same failure with -b, there is no use adding -b.
1790         # So take it out.  This plays safe.
1791         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1792         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1793         CPPFLAGS="$OLD_CPPFLAGS"
1794         LIBS="$OLD_LIBS"
1795         AC_MSG_RESULT(no)
1796       else
1797         AC_MSG_RESULT(yes)
1798       fi
1799     else
1800       AC_MSG_RESULT(no)
1801     fi
1802   fi
1803
1804   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1805   # header files included from there.
1806   AC_MSG_CHECKING(for Xkb)
1807   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1808 #include <X11/XKBlib.h>]],
1809         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1810         emacs_xkb=yes, emacs_xkb=no)
1811   AC_MSG_RESULT($emacs_xkb)
1812   if test $emacs_xkb = yes; then
1813     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1814   fi
1815
1816   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1817 XScreenNumberOfScreen XSetWMProtocols)
1818 fi
1819
1820 if test "${window_system}" = "x11"; then
1821   AC_MSG_CHECKING(X11 version 6)
1822   AC_CACHE_VAL(emacs_cv_x11_version_6,
1823   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1824 [[#if XlibSpecificationRelease < 6
1825 fail;
1826 #endif
1827 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1828   if test $emacs_cv_x11_version_6 = yes; then
1829     AC_MSG_RESULT(6 or newer)
1830     AC_DEFINE(HAVE_X11R6, 1,
1831               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1832     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1833     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1834     ## XIM support.
1835     case "$opsys" in
1836       sol2-*) : ;;
1837       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1838            [Define if you have usable X11R6-style XIM support.])
1839          ;;
1840     esac
1841   else
1842     AC_MSG_RESULT(before 6)
1843   fi
1844 fi
1845
1846
1847 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1848 HAVE_RSVG=no
1849 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1850   if test "${with_rsvg}" != "no"; then
1851     RSVG_REQUIRED=2.11.0
1852     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1853
1854     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1855     AC_SUBST(RSVG_CFLAGS)
1856     AC_SUBST(RSVG_LIBS)
1857
1858     if test $HAVE_RSVG = yes; then
1859       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1860       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1861       LIBS="$RSVG_LIBS $LIBS"
1862     fi
1863   fi
1864 fi
1865
1866 HAVE_IMAGEMAGICK=no
1867 if test "${HAVE_X11}" = "yes"; then
1868   if test "${with_imagemagick}" != "no"; then
1869     ## 6.2.8 is the earliest version known to work, but earlier versions
1870     ## might work - let us know if you find one.
1871     ## 6.0.7 does not work.  See bug#7955.
1872     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1873     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1874     AC_SUBST(IMAGEMAGICK_CFLAGS)
1875     AC_SUBST(IMAGEMAGICK_LIBS)
1876
1877     if test $HAVE_IMAGEMAGICK = yes; then
1878       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1879       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1880       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1881       AC_CHECK_FUNCS(MagickExportImagePixels)
1882     fi
1883   fi
1884 fi
1885
1886
1887 HAVE_GTK=no
1888 GTK_OBJ=
1889 if test "${with_gtk3}" = "yes"; then
1890   GLIB_REQUIRED=2.28
1891   GTK_REQUIRED=3.0
1892   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1893
1894   dnl Checks for libraries.
1895   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1896   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1897      AC_MSG_ERROR($GTK_PKG_ERRORS)
1898   fi
1899   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1900   GTK_OBJ=emacsgtkfixed.o
1901 fi
1902
1903 if test "$pkg_check_gtk" != "yes"; then
1904   HAVE_GTK=no
1905 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1906   GLIB_REQUIRED=2.6
1907   GTK_REQUIRED=2.6
1908   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1909
1910   dnl Checks for libraries.
1911   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1912   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1913      AC_MSG_ERROR($GTK_PKG_ERRORS)
1914   fi
1915 fi
1916 fi
1917
1918 if test x"$pkg_check_gtk" = xyes; then
1919
1920   AC_SUBST(GTK_CFLAGS)
1921   AC_SUBST(GTK_LIBS)
1922   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1923   CFLAGS="$CFLAGS $GTK_CFLAGS"
1924   LIBS="$GTK_LIBS $LIBS"
1925   dnl Try to compile a simple GTK program.
1926   GTK_COMPILES=no
1927   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1928   if test "${GTK_COMPILES}" != "yes"; then
1929     if test "$USE_X_TOOLKIT" != "maybe"; then
1930       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1931     fi
1932   else
1933     HAVE_GTK=yes
1934     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1935     GTK_OBJ="gtkutil.o $GTK_OBJ"
1936     USE_X_TOOLKIT=none
1937     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1938       :
1939     else
1940       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1941        closing open displays.  This is no problem if you just use
1942        one display, but if you use more than one and close one of them
1943        Emacs may crash.]])
1944       sleep 3
1945     fi
1946   fi
1947
1948 fi
1949 AC_SUBST(GTK_OBJ)
1950
1951
1952 if test "${HAVE_GTK}" = "yes"; then
1953
1954   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1955   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1956   if test "$with_toolkit_scroll_bars" != no; then
1957     with_toolkit_scroll_bars=yes
1958   fi
1959
1960   dnl  Check if we have the old file selection dialog declared and
1961   dnl  in the link library.  In 2.x it may be in the library,
1962   dnl  but not declared if deprecated featured has been selected out.
1963   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1964   HAVE_GTK_FILE_SELECTION=no
1965   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1966                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1967 #include <gtk/gtk.h>])
1968   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1969     AC_CHECK_FUNCS(gtk_file_selection_new)
1970   fi
1971
1972
1973   dnl Check for functions introduced in 2.14 and later.
1974   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1975                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1976                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1977                  gtk_orientable_set_orientation)
1978
1979 fi
1980
1981 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1982 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1983 dnl also not configured.
1984 HAVE_DBUS=no
1985 DBUS_OBJ=
1986 if test "${with_dbus}" = "yes"; then
1987    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1988    if test "$HAVE_DBUS" = yes; then
1989      LIBS="$LIBS $DBUS_LIBS"
1990      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1991      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1992      DBUS_OBJ=dbusbind.o
1993    fi
1994 fi
1995 AC_SUBST(DBUS_OBJ)
1996
1997 dnl GSettings has been tested under GNU/Linux only.
1998 HAVE_GSETTINGS=no
1999 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2000    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2001    if test "$HAVE_GSETTINGS" = "yes"; then
2002       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2003       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2004       SETTINGS_LIBS="$GSETTINGS_LIBS"
2005    fi
2006 fi
2007
2008 dnl GConf has been tested under GNU/Linux only.
2009 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2010 HAVE_GCONF=no
2011 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2012    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2013    if test "$HAVE_GCONF" = yes; then
2014       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2015       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2016       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2017       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2018    fi
2019 fi
2020
2021 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2022     SAVE_CFLAGS="$CFLAGS"
2023     SAVE_LDFLAGS="$LDFLAGS"
2024     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2025     LDFLAGS="$SETTINGS_LIBS $LDFLAGS"
2026     AC_CHECK_FUNCS([g_type_init])
2027     CFLAGS="$SAVE_CFLAGS"
2028     LDFLAGS="$SAVE_LDFLAGS"
2029 fi
2030 AC_SUBST(SETTINGS_CFLAGS)
2031 AC_SUBST(SETTINGS_LIBS)
2032
2033
2034 dnl SELinux is available for GNU/Linux only.
2035 HAVE_LIBSELINUX=no
2036 LIBSELINUX_LIBS=
2037 if test "${with_selinux}" = "yes"; then
2038    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2039    if test "$HAVE_LIBSELINUX" = yes; then
2040       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2041       LIBSELINUX_LIBS=-lselinux
2042    fi
2043 fi
2044 AC_SUBST(LIBSELINUX_LIBS)
2045
2046 HAVE_GNUTLS=no
2047 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2048 if test "${with_gnutls}" = "yes" ; then
2049   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.0], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2050   if test "${HAVE_GNUTLS}" = "yes"; then
2051     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2052   fi
2053
2054   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2055   LIBS="$LIBGNUTLS_LIBS $LIBS"
2056   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2057
2058   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2059     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2060   fi
2061 fi
2062
2063 AC_SUBST(LIBGNUTLS_LIBS)
2064 AC_SUBST(LIBGNUTLS_CFLAGS)
2065
2066 dnl Do not put whitespace before the #include statements below.
2067 dnl Older compilers (eg sunos4 cc) choke on it.
2068 HAVE_XAW3D=no
2069 LUCID_LIBW=
2070 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2071   if test "$with_xaw3d" != no; then
2072     AC_MSG_CHECKING(for xaw3d)
2073     AC_CACHE_VAL(emacs_cv_xaw3d,
2074     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2075 #include <X11/Intrinsic.h>
2076 #include <X11/Xaw3d/Simple.h>]],
2077       [[]])],
2078       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2079                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2080       emacs_cv_xaw3d=no)])
2081   else
2082     emacs_cv_xaw3d=no
2083   fi
2084   if test $emacs_cv_xaw3d = yes; then
2085     AC_MSG_RESULT([yes; using Lucid toolkit])
2086     USE_X_TOOLKIT=LUCID
2087     HAVE_XAW3D=yes
2088     LUCID_LIBW=-lXaw3d
2089     AC_DEFINE(HAVE_XAW3D, 1,
2090               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2091   else
2092     AC_MSG_RESULT(no)
2093     AC_MSG_CHECKING(for libXaw)
2094     AC_CACHE_VAL(emacs_cv_xaw,
2095     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2096 #include <X11/Intrinsic.h>
2097 #include <X11/Xaw/Simple.h>]],
2098       [[]])],
2099       emacs_cv_xaw=yes,
2100       emacs_cv_xaw=no)])
2101     if test $emacs_cv_xaw = yes; then
2102       AC_MSG_RESULT([yes; using Lucid toolkit])
2103       USE_X_TOOLKIT=LUCID
2104       LUCID_LIBW=-lXaw
2105     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2106       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2107     else
2108       AC_MSG_ERROR([No X toolkit could be found.
2109 If you are sure you want Emacs compiled without an X toolkit, pass
2110   --with-x-toolkit=no
2111 to configure.  Otherwise, install the development libraries for the toolkit
2112 that you want to use (e.g. Gtk+) and re-run configure.])
2113     fi
2114   fi
2115 fi
2116
2117 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2118
2119 LIBXTR6=
2120 if test "${USE_X_TOOLKIT}" != "none"; then
2121   AC_MSG_CHECKING(X11 toolkit version)
2122   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2123   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2124 [[#if XtSpecificationRelease < 6
2125 fail;
2126 #endif
2127 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2128   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2129   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2130     AC_MSG_RESULT(6 or newer)
2131     AC_DEFINE(HAVE_X11XTR6, 1,
2132               [Define to 1 if you have the X11R6 or newer version of Xt.])
2133     LIBXTR6="-lSM -lICE"
2134     case "$opsys" in
2135       ## Use libw.a along with X11R6 Xt.
2136       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2137     esac
2138   else
2139     AC_MSG_RESULT(before 6)
2140   fi
2141
2142 dnl If using toolkit, check whether libXmu.a exists.
2143 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2144   OLDLIBS="$LIBS"
2145   if test x$HAVE_X11XTR6 = xyes; then
2146     LIBS="-lXt -lSM -lICE $LIBS"
2147   else
2148     LIBS="-lXt $LIBS"
2149   fi
2150   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2151   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2152 fi
2153 AC_SUBST(LIBXTR6)
2154
2155 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2156 dnl Why not just test for libxmu in the normal way?
2157 LIBXMU=-lXmu
2158 case $opsys in
2159   ## These systems don't supply Xmu.
2160   hpux* | aix4-2 )
2161     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2162     ;;
2163 esac
2164 AC_SUBST(LIBXMU)
2165
2166 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2167 if test "${HAVE_X11}" = "yes"; then
2168   if test "${USE_X_TOOLKIT}" != "none"; then
2169     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2170   fi
2171 fi
2172
2173 LIBXP=
2174 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2175   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2176   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2177     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2178 int x = 5;
2179 #else
2180 Motif version prior to 2.1.
2181 #endif]])],
2182     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2183   if test $emacs_cv_motif_version_2_1 = yes; then
2184     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2185   else
2186     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2187     # We put this in CFLAGS temporarily to precede other -I options
2188     # that might be in CFLAGS temporarily.
2189     # We put this in CPPFLAGS where it precedes the other -I options.
2190     OLD_CPPFLAGS=$CPPFLAGS
2191     OLD_CFLAGS=$CFLAGS
2192     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2193     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2194     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2195       [[int x = 5;]])],
2196       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2197     if test $emacs_cv_lesstif = yes; then
2198       # Make sure this -I option remains in CPPFLAGS after it is set
2199       # back to REAL_CPPFLAGS.
2200       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2201       # have those other -I options anyway.  Ultimately, having this
2202       # directory ultimately in CPPFLAGS will be enough.
2203       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2204       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2205     else
2206       CFLAGS=$OLD_CFLAGS
2207       CPPFLAGS=$OLD_CPPFLAGS
2208     fi
2209   fi
2210 fi
2211
2212 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2213 dnl using Motif or Xaw3d is available, and unless
2214 dnl --with-toolkit-scroll-bars=no was specified.
2215
2216 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2217             [Define to 1 if we should use toolkit scroll bars.])dnl
2218 USE_TOOLKIT_SCROLL_BARS=no
2219 if test "${with_toolkit_scroll_bars}" != "no"; then
2220   if test "${USE_X_TOOLKIT}" != "none"; then
2221     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2222       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2223       HAVE_XAW3D=no
2224       USE_TOOLKIT_SCROLL_BARS=yes
2225     elif test "${HAVE_XAW3D}" = "yes"; then
2226       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2227       USE_TOOLKIT_SCROLL_BARS=yes
2228     fi
2229   elif test "${HAVE_GTK}" = "yes"; then
2230     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2231     USE_TOOLKIT_SCROLL_BARS=yes
2232   elif test "${HAVE_NS}" = "yes"; then
2233     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2234     USE_TOOLKIT_SCROLL_BARS=yes
2235   fi
2236 fi
2237
2238 dnl See if XIM is available.
2239 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2240           #include <X11/Xlib.h>
2241           #include <X11/Xresource.h>]],
2242          [[XIMProc  callback;]])],
2243          [HAVE_XIM=yes
2244          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2245          HAVE_XIM=no)
2246
2247 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2248
2249 if test "${with_xim}" != "no"; then
2250   AC_DEFINE(USE_XIM, 1,
2251             [Define to 1 if we should use XIM, if it is available.])
2252 fi
2253
2254
2255 if test "${HAVE_XIM}" != "no"; then
2256   late_CFLAGS=$CFLAGS
2257   if test "$GCC" = yes; then
2258     CFLAGS="$CFLAGS --pedantic-errors"
2259   fi
2260   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2261 #include <X11/Xlib.h>
2262 #include <X11/Xresource.h>]],
2263 [[Display *display;
2264 XrmDatabase db;
2265 char *res_name;
2266 char *res_class;
2267 XIMProc  callback;
2268 XPointer *client_data;
2269 #ifndef __GNUC__
2270 /* If we're not using GCC, it's probably not XFree86, and this is
2271    probably right, but we can't use something like --pedantic-errors.  */
2272 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2273                                            char*, XIMProc, XPointer*);
2274 #endif
2275 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2276    client_data);]])],
2277     [emacs_cv_arg6_star=yes])
2278   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2279          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2280 either XPointer or XPointer*.])dnl
2281   if test "$emacs_cv_arg6_star" = yes; then
2282     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2283   else
2284     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2285   fi
2286   CFLAGS=$late_CFLAGS
2287 fi
2288
2289 ### Start of font-backend (under any platform) section.
2290 # (nothing here yet -- this is a placeholder)
2291 ### End of font-backend (under any platform) section.
2292
2293 ### Start of font-backend (under X11) section.
2294 if test "${HAVE_X11}" = "yes"; then
2295    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2296
2297    ## Use -lXft if available, unless `--with-xft=no'.
2298    HAVE_XFT=maybe
2299     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2300       with_xft="no";
2301     fi
2302     if test "x${with_xft}" != "xno"; then
2303
2304       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2305       ## Because xftfont.c uses XRenderQueryExtension, we also
2306       ## need to link to -lXrender.
2307       HAVE_XRENDER=no
2308       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2309       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2310         OLD_CPPFLAGS="$CPPFLAGS"
2311         OLD_CFLAGS="$CFLAGS"
2312         OLD_LIBS="$LIBS"
2313         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2314         CFLAGS="$CFLAGS $XFT_CFLAGS"
2315         XFT_LIBS="-lXrender $XFT_LIBS"
2316         LIBS="$XFT_LIBS $LIBS"
2317         AC_CHECK_HEADER(X11/Xft/Xft.h,
2318           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2319
2320         if test "${HAVE_XFT}" = "yes"; then
2321           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2322             AC_SUBST(XFT_LIBS)
2323           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2324         else
2325           CPPFLAGS="$OLD_CPPFLAGS"
2326           CFLAGS="$OLD_CFLAGS"
2327           LIBS="$OLD_LIBS"
2328         fi                        # "${HAVE_XFT}" = "yes"
2329       fi                          # "$HAVE_XFT" != no
2330     fi                            # "x${with_xft}" != "xno"
2331
2332     ## We used to allow building with FreeType and without Xft.
2333     ## However, the ftx font backend driver is not in good shape.
2334     if test "$HAVE_XFT" != "yes"; then
2335        dnl For the "Does Emacs use" message at the end.
2336        HAVE_XFT=no
2337        HAVE_FREETYPE=no
2338     else
2339        dnl Strict linkers fail with
2340        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2341        dnl if -lfreetype is not specified.
2342        dnl The following is needed to set FREETYPE_LIBS.
2343        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2344                          HAVE_FREETYPE=no)
2345
2346        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2347     fi
2348
2349     HAVE_LIBOTF=no
2350     if test "${HAVE_FREETYPE}" = "yes"; then
2351       AC_DEFINE(HAVE_FREETYPE, 1,
2352                 [Define to 1 if using the freetype and fontconfig libraries.])
2353       if test "${with_libotf}" != "no"; then
2354         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2355                           HAVE_LIBOTF=no)
2356         if test "$HAVE_LIBOTF" = "yes"; then
2357           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2358           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2359                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2360                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2361           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2362             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2363                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2364           fi
2365         fi
2366       fi
2367     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2368     dnl Does the new font backend require it, or can it work without it?
2369     fi
2370
2371     HAVE_M17N_FLT=no
2372     if test "${HAVE_LIBOTF}" = yes; then
2373       if test "${with_m17n_flt}" != "no"; then
2374         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2375         if test "$HAVE_M17N_FLT" = "yes"; then
2376           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2377         fi
2378       fi
2379     fi
2380 else
2381     HAVE_XFT=no
2382     HAVE_FREETYPE=no
2383     HAVE_LIBOTF=no
2384     HAVE_M17N_FLT=no
2385 fi
2386
2387 ### End of font-backend (under X11) section.
2388
2389 AC_SUBST(FREETYPE_CFLAGS)
2390 AC_SUBST(FREETYPE_LIBS)
2391 AC_SUBST(FONTCONFIG_CFLAGS)
2392 AC_SUBST(FONTCONFIG_LIBS)
2393 AC_SUBST(LIBOTF_CFLAGS)
2394 AC_SUBST(LIBOTF_LIBS)
2395 AC_SUBST(M17N_FLT_CFLAGS)
2396 AC_SUBST(M17N_FLT_LIBS)
2397
2398 ### Use -lXpm if available, unless `--with-xpm=no'.
2399 HAVE_XPM=no
2400 LIBXPM=
2401 if test "${HAVE_X11}" = "yes"; then
2402   if test "${with_xpm}" != "no"; then
2403     AC_CHECK_HEADER(X11/xpm.h,
2404       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2405     if test "${HAVE_XPM}" = "yes"; then
2406       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2407       AC_EGREP_CPP(no_return_alloc_pixels,
2408       [#include "X11/xpm.h"
2409 #ifndef XpmReturnAllocPixels
2410 no_return_alloc_pixels
2411 #endif
2412       ], HAVE_XPM=no, HAVE_XPM=yes)
2413
2414       if test "${HAVE_XPM}" = "yes"; then
2415         AC_MSG_RESULT(yes)
2416       else
2417         AC_MSG_RESULT(no)
2418       fi
2419     fi
2420   fi
2421
2422   if test "${HAVE_XPM}" = "yes"; then
2423     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2424     LIBXPM=-lXpm
2425   fi
2426 fi
2427 AC_SUBST(LIBXPM)
2428
2429 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2430 HAVE_JPEG=no
2431 LIBJPEG=
2432 if test "${HAVE_X11}" = "yes"; then
2433   if test "${with_jpeg}" != "no"; then
2434     dnl Checking for jpeglib.h can lose because of a redefinition of
2435     dnl  HAVE_STDLIB_H.
2436     AC_CHECK_HEADER(jerror.h,
2437       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2438   fi
2439
2440   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2441   if test "${HAVE_JPEG}" = "yes"; then
2442     AC_DEFINE(HAVE_JPEG)
2443     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2444         [#include <jpeglib.h>
2445          version=JPEG_LIB_VERSION
2446 ],
2447         [AC_DEFINE(HAVE_JPEG)],
2448         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2449         HAVE_JPEG=no])
2450   fi
2451   if test "${HAVE_JPEG}" = "yes"; then
2452     LIBJPEG=-ljpeg
2453   fi
2454 fi
2455 AC_SUBST(LIBJPEG)
2456
2457 ### Use -lpng if available, unless `--with-png=no'.
2458 HAVE_PNG=no
2459 LIBPNG=
2460 if test "${HAVE_X11}" = "yes"; then
2461   if test "${with_png}" != "no"; then
2462     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2463     # in /usr/include/libpng.
2464     AC_CHECK_HEADERS(png.h libpng/png.h)
2465     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2466       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2467     fi
2468   fi
2469
2470   if test "${HAVE_PNG}" = "yes"; then
2471     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2472     LIBPNG="-lpng -lz -lm"
2473   fi
2474 fi
2475 AC_SUBST(LIBPNG)
2476
2477 ### Use -ltiff if available, unless `--with-tiff=no'.
2478 HAVE_TIFF=no
2479 LIBTIFF=
2480 if test "${HAVE_X11}" = "yes"; then
2481   if test "${with_tiff}" != "no"; then
2482     AC_CHECK_HEADER(tiffio.h,
2483       [tifflibs="-lz -lm"
2484       # At least one tiff package requires the jpeg library.
2485       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2486       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2487   fi
2488
2489   if test "${HAVE_TIFF}" = "yes"; then
2490     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2491     dnl FIXME -lz -lm, as per libpng?
2492     LIBTIFF=-ltiff
2493   fi
2494 fi
2495 AC_SUBST(LIBTIFF)
2496
2497 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2498 HAVE_GIF=no
2499 LIBGIF=
2500 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2501   AC_CHECK_HEADER(gif_lib.h,
2502 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2503 # Earlier versions can crash Emacs.
2504     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2505
2506   if test "$HAVE_GIF" = yes; then
2507     LIBGIF=-lgif
2508   elif test "$HAVE_GIF" = maybe; then
2509 # If gif_lib.h but no libgif, try libungif.
2510     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2511     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2512   fi
2513
2514   if test "${HAVE_GIF}" = "yes"; then
2515     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2516   fi
2517 fi
2518 AC_SUBST(LIBGIF)
2519
2520 dnl Check for required libraries.
2521 if test "${HAVE_X11}" = "yes"; then
2522   MISSING=""
2523   WITH_NO=""
2524   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2525     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2526   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2527     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2528   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2529     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2530   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2531     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2532   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2533     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2534
2535   if test "X${MISSING}" != X; then
2536     AC_MSG_ERROR([The following required libraries were not found:
2537     $MISSING
2538 Maybe some development libraries/packages are missing?
2539 If you don't want to link with them give
2540     $WITH_NO
2541 as options to configure])
2542   fi
2543 fi
2544
2545 ### Use -lgpm if available, unless `--with-gpm=no'.
2546 HAVE_GPM=no
2547 LIBGPM=
2548 if test "${with_gpm}" != "no"; then
2549   AC_CHECK_HEADER(gpm.h,
2550     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2551
2552   if test "${HAVE_GPM}" = "yes"; then
2553     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2554     LIBGPM=-lgpm
2555   fi
2556 fi
2557 AC_SUBST(LIBGPM)
2558
2559 dnl Check for malloc/malloc.h on darwin
2560 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2561
2562 C_SWITCH_X_SYSTEM=
2563 ### Use NeXTstep API to implement GUI.
2564 if test "${HAVE_NS}" = "yes"; then
2565   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2566   if test "${NS_IMPL_COCOA}" = "yes"; then
2567     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2568     GNU_OBJC_CFLAGS=
2569   fi
2570   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2571     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2572     # See also .m.o rule in Makefile.in */
2573     # FIXME: are all these flags really needed?  Document here why.  */
2574     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2575     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2576   fi
2577   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2578     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2579   fi
2580   # We also have mouse menus.
2581   HAVE_MENUS=yes
2582   OTHER_FILES=ns-app
2583 fi
2584
2585
2586 ### Use session management (-lSM -lICE) if available
2587 HAVE_X_SM=no
2588 LIBXSM=
2589 if test "${HAVE_X11}" = "yes"; then
2590   AC_CHECK_HEADER(X11/SM/SMlib.h,
2591     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2592
2593   if test "${HAVE_X_SM}" = "yes"; then
2594     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2595     LIBXSM="-lSM -lICE"
2596     case "$LIBS" in
2597       *-lSM*) ;;
2598       *)      LIBS="$LIBXSM $LIBS" ;;
2599     esac
2600   fi
2601 fi
2602 AC_SUBST(LIBXSM)
2603
2604 ### Use libxml (-lxml2) if available
2605 if test "${with_xml2}" != "no"; then
2606   ### I'm not sure what the version number should be, so I just guessed.
2607   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2608   if test "${HAVE_LIBXML2}" = "yes"; then
2609     LIBS="$LIBXML2_LIBS $LIBS"
2610     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2611     if test "${HAVE_LIBXML2}" = "yes"; then
2612       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2613     else
2614       LIBXML2_LIBS=""
2615       LIBXML2_CFLAGS=""
2616     fi
2617   fi
2618 fi
2619 AC_SUBST(LIBXML2_LIBS)
2620 AC_SUBST(LIBXML2_CFLAGS)
2621
2622 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2623 AC_CACHE_CHECK(whether netdb declares h_errno,
2624                emacs_cv_netdb_declares_h_errno,
2625 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2626   [[return h_errno;]])],
2627   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2628 if test $emacs_cv_netdb_declares_h_errno = yes; then
2629   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2630 fi
2631
2632 # fmod, logb, and frexp are found in -lm on most systems.
2633 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2634 AC_CHECK_LIB(m, sqrt)
2635
2636 # Check for mail-locking functions in a "mail" library.  Probably this should
2637 # have the same check as for liblockfile below.
2638 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2639 if test $have_mail = yes; then
2640   LIBS_MAIL=-lmail
2641   LIBS="$LIBS_MAIL $LIBS"
2642   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2643 else
2644   LIBS_MAIL=
2645 fi
2646 dnl Debian, at least:
2647 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2648 if test $have_lockfile = yes; then
2649    LIBS_MAIL=-llockfile
2650    LIBS="$LIBS_MAIL $LIBS"
2651    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2652 else
2653 # If we have the shared liblockfile, assume we must use it for mail
2654 # locking (e.g. Debian).  If we couldn't link against liblockfile
2655 # (no liblockfile.a installed), ensure that we don't need to.
2656   dnl This works for files generally, not just executables.
2657   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2658   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2659                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2660   if test $ac_cv_prog_liblockfile = yes; then
2661     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2662 This probably means that movemail could lose mail.
2663 There may be a `development' package to install containing liblockfile.])
2664   fi
2665 fi
2666 AC_CHECK_FUNCS(touchlock)
2667 AC_CHECK_HEADERS(maillock.h)
2668 AC_SUBST(LIBS_MAIL)
2669
2670 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2671 ## interlock access to the mail spool.  The alternative is a lock file named
2672 ## /usr/spool/mail/$USER.lock.
2673 mail_lock=no
2674 case "$opsys" in
2675   aix4-2) mail_lock="lockf" ;;
2676
2677   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2678
2679   ## On GNU/Linux systems, both methods are used by various mail programs.
2680   ## I assume most people are using newer mailers that have heard of flock.
2681   ## Change this if you need to.
2682   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2683   ## configure gets the right answers, and that means *NOT* using flock.
2684   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2685   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2686   ## Debian maintainer hasn't provided a clean fix for Emacs.
2687   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2688   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2689   ## correct logic.  -- fx
2690   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2691   ## liblockfile is a Free Software replacement for libmail, used on
2692   ## Debian systems and elsewhere. -rfr.
2693   gnu-*)
2694     mail_lock="flock"
2695     if test $have_mail = yes || test $have_lockfile = yes; then
2696       test $ac_cv_header_maillock_h = yes && mail_lock=no
2697     fi
2698     ;;
2699 esac
2700
2701 BLESSMAIL_TARGET=
2702 case "$mail_lock" in
2703   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2704
2705   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2706
2707   *) BLESSMAIL_TARGET="need-blessmail" ;;
2708 esac
2709 AC_SUBST(BLESSMAIL_TARGET)
2710
2711
2712 AC_CHECK_FUNCS(gethostname getdomainname \
2713 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2714 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2715 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2716 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2717 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm \
2718 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2719 gai_strerror mkstemp getline getdelim mremap fsync sync \
2720 difftime mempcpy mblen mbrlen posix_memalign \
2721 cfmakeraw cfsetspeed isnan copysign __executable_start)
2722
2723 dnl Cannot use AC_CHECK_FUNCS
2724 AC_CACHE_CHECK([for __builtin_unwind_init],
2725                emacs_cv_func___builtin_unwind_init,
2726 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2727                 emacs_cv_func___builtin_unwind_init=yes,
2728                 emacs_cv_func___builtin_unwind_init=no)])
2729 if test $emacs_cv_func___builtin_unwind_init = yes; then
2730   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2731             [Define to 1 if you have the `__builtin_unwind_init' function.])
2732 fi
2733
2734 AC_CHECK_HEADERS(sys/un.h)
2735
2736 AC_FUNC_FSEEKO
2737
2738 AC_FUNC_GETPGRP
2739
2740 # UNIX98 PTYs.
2741 AC_CHECK_FUNCS(grantpt)
2742
2743 # PTY-related GNU extensions.
2744 AC_CHECK_FUNCS(getpt)
2745
2746 # Check this now, so that we will NOT find the above functions in ncurses.
2747 # That is because we have not set up to link ncurses in lib-src.
2748 # It's better to believe a function is not available
2749 # than to expect to find it in ncurses.
2750 # Also we need tputs and friends to be able to build at all.
2751 have_tputs_et_al=true
2752 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2753 if test "$have_tputs_et_al" != true; then
2754   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2755 Maybe some development libraries/packages are missing?  Try installing
2756 libncurses-dev(el), libterminfo-dev(el) or similar.])
2757 fi
2758 # Must define this when any termcap library is found.
2759 AC_DEFINE(HAVE_LIBNCURSES, 1,
2760           [Define to 1 if you have the `ncurses' library (-lncurses).])
2761 ## FIXME This was the cpp logic, but I am not sure it is right.
2762 ## The above test has not necessarily found libncurses.
2763 HAVE_LIBNCURSES=yes
2764
2765 ## Use terminfo instead of termcap?
2766 ## Note only system files NOT using terminfo are:
2767 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2768 ## darwin|gnu without ncurses.
2769 TERMINFO=no
2770 LIBS_TERMCAP=
2771 case "$opsys" in
2772   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2773   ## hpux10-20: Use the system provided termcap(3) library.
2774   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2775   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2776   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2777
2778   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2779   ##  The ncurses library has been moved out of the System framework in
2780   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2781   ##  option to use it.
2782   darwin|gnu*)
2783     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2784     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2785       TERMINFO=yes
2786       LIBS_TERMCAP="-lncurses"
2787     fi
2788     ;;
2789
2790   freebsd)
2791     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2792     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2793     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2794 [[#if __FreeBSD_version < 400000
2795 fail;
2796 #endif
2797 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2798
2799     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2800
2801     if test $emacs_cv_freebsd_terminfo = yes; then
2802       TERMINFO=yes
2803       LIBS_TERMCAP="-lncurses"
2804     else
2805       LIBS_TERMCAP="-ltermcap"
2806     fi
2807     ;;
2808
2809   netbsd)
2810     if test $ac_cv_search_tputs = -lterminfo; then
2811       TERMINFO=yes
2812       LIBS_TERMCAP="-lterminfo"
2813     else
2814       LIBS_TERMCAP="-ltermcap"
2815     fi
2816     ;;
2817
2818 esac
2819
2820 case "$opsys" in
2821   ## hpux: Make sure we get select from libc rather than from libcurses
2822   ##  because libcurses on HPUX 10.10 has a broken version of select.
2823   ##  We used to use -lc -lcurses, but this may be cleaner.
2824   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2825
2826   openbsd) LIBS_TERMCAP="-lncurses" ;;
2827
2828   ## Must use system termcap, if we use any termcap.  It does special things.
2829   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2830 esac
2831
2832 TERMCAP_OBJ=tparam.o
2833 if test $TERMINFO = yes; then
2834   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2835
2836   ## Default used to be -ltermcap.  Add a case above if need something else.
2837   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2838
2839   TERMCAP_OBJ=terminfo.o
2840 fi
2841 AC_SUBST(LIBS_TERMCAP)
2842 AC_SUBST(TERMCAP_OBJ)
2843
2844
2845 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2846 resolv=no
2847 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2848 #include <arpa/nameser.h>
2849 #include <resolv.h>]],
2850     [[return res_init();]])],
2851     have_res_init=yes, have_res_init=no)
2852 if test "$have_res_init" = no; then
2853   OLIBS="$LIBS"
2854   LIBS="$LIBS -lresolv"
2855   AC_MSG_CHECKING(for res_init with -lresolv)
2856   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2857 #include <arpa/nameser.h>
2858 #include <resolv.h>]],
2859     [[return res_init();]])],
2860     have_res_init=yes, have_res_init=no)
2861   AC_MSG_RESULT($have_res_init)
2862   if test "$have_res_init" = yes ; then
2863     resolv=yes
2864   fi
2865   LIBS="$OLIBS"
2866 fi
2867
2868 if test "$have_res_init" = yes; then
2869   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2870 fi
2871
2872 # Do we need the Hesiod library to provide the support routines?
2873 LIBHESIOD=
2874 if test "$with_hesiod" != no ; then
2875   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2876   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2877      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2878                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2879   if test "$resolv" = yes ; then
2880     RESOLVLIB=-lresolv
2881   else
2882     RESOLVLIB=
2883   fi
2884   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2885         hesiod=yes, :, $RESOLVLIB)])
2886
2887   if test x"$hesiod" = xyes; then
2888     AC_DEFINE(HAVE_LIBHESIOD, 1,
2889               [Define to 1 if you have the hesiod library (-lhesiod).])
2890     LIBHESIOD=-lhesiod
2891   fi
2892 fi
2893 AC_SUBST(LIBHESIOD)
2894
2895 # Do we need libresolv (due to res_init or Hesiod)?
2896 if test "$resolv" = yes ; then
2897   AC_DEFINE(HAVE_LIBRESOLV, 1,
2898             [Define to 1 if you have the resolv library (-lresolv).])
2899   LIBRESOLV=-lresolv
2900 else
2901   LIBRESOLV=
2902 fi
2903 AC_SUBST(LIBRESOLV)
2904
2905 # These tell us which Kerberos-related libraries to use.
2906 COM_ERRLIB=
2907 CRYPTOLIB=
2908 KRB5LIB=
2909 DESLIB=
2910 KRB4LIB=
2911
2912 if test "${with_kerberos}" != no; then
2913   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2914   if test $have_com_err = yes; then
2915     COM_ERRLIB=-lcom_err
2916     LIBS="$COM_ERRLIB $LIBS"
2917     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2918   fi
2919   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2920   if test $have_crypto = yes; then
2921     CRYPTOLIB=-lcrypto
2922     LIBS="$CRYPTOLIB $LIBS"
2923     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2924   fi
2925   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2926   if test $have_k5crypto = yes; then
2927     CRYPTOLIB=-lk5crypto
2928     LIBS="$CRYPTOLIB $LIBS"
2929     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2930   fi
2931   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2932   if test $have_krb5=yes; then
2933     KRB5LIB=-lkrb5
2934     LIBS="$KRB5LIB $LIBS"
2935     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2936   fi
2937   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2938   if test "${with_kerberos5}" = no; then
2939     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2940     if test $have_des425 = yes; then
2941       DESLIB=-ldes425
2942       LIBS="$DESLIB $LIBS"
2943       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2944     else
2945       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2946       if test $have_des = yes; then
2947         DESLIB=-ldes
2948         LIBS="$DESLIB $LIBS"
2949         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2950       fi
2951     fi
2952     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2953     if test $have_krb4 = yes; then
2954       KRB4LIB=-lkrb4
2955       LIBS="$KRB4LIB $LIBS"
2956       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2957     else
2958       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2959       if test $have_krb = yes; then
2960         KRB4LIB=-lkrb
2961         LIBS="$KRB4LIB $LIBS"
2962         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2963       fi
2964     fi
2965   fi
2966
2967   if test "${with_kerberos5}" != no; then
2968     AC_CHECK_HEADERS(krb5.h,
2969       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2970                         [#include <krb5.h>])])
2971   else
2972     AC_CHECK_HEADERS(des.h,,
2973                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2974                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2975     AC_CHECK_HEADERS(krb.h,,
2976                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2977                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2978   fi
2979   AC_CHECK_HEADERS(com_err.h)
2980 fi
2981
2982 AC_SUBST(COM_ERRLIB)
2983 AC_SUBST(CRYPTOLIB)
2984 AC_SUBST(KRB5LIB)
2985 AC_SUBST(DESLIB)
2986 AC_SUBST(KRB4LIB)
2987
2988 # Solaris requires -lintl if you want strerror (which calls dgettext)
2989 # to return localized messages.
2990 AC_CHECK_LIB(intl, dgettext)
2991
2992 AC_MSG_CHECKING(whether localtime caches TZ)
2993 AC_CACHE_VAL(emacs_cv_localtime_cache,
2994 [if test x$ac_cv_func_tzset = xyes; then
2995 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2996 char TZ_GMT0[] = "TZ=GMT0";
2997 char TZ_PST8[] = "TZ=PST8";
2998 main()
2999 {
3000   time_t now = time ((time_t *) 0);
3001   int hour_GMT0, hour_unset;
3002   if (putenv (TZ_GMT0) != 0)
3003     exit (1);
3004   hour_GMT0 = localtime (&now)->tm_hour;
3005   unsetenv("TZ");
3006   hour_unset = localtime (&now)->tm_hour;
3007   if (putenv (TZ_PST8) != 0)
3008     exit (1);
3009   if (localtime (&now)->tm_hour == hour_GMT0)
3010     exit (1);
3011   unsetenv("TZ");
3012   if (localtime (&now)->tm_hour != hour_unset)
3013     exit (1);
3014   exit (0);
3015 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3016 [# If we have tzset, assume the worst when cross-compiling.
3017 emacs_cv_localtime_cache=yes])
3018 else
3019         # If we lack tzset, report that localtime does not cache TZ,
3020         # since we can't invalidate the cache if we don't have tzset.
3021         emacs_cv_localtime_cache=no
3022 fi])dnl
3023 AC_MSG_RESULT($emacs_cv_localtime_cache)
3024 if test $emacs_cv_localtime_cache = yes; then
3025   AC_DEFINE(LOCALTIME_CACHE, 1,
3026             [Define to 1 if localtime caches TZ.])
3027 fi
3028
3029 if test "x$HAVE_TIMEVAL" = xyes; then
3030   AC_CHECK_FUNCS(gettimeofday)
3031   if test $ac_cv_func_gettimeofday = yes; then
3032     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3033                    emacs_cv_gettimeofday_two_arguments,
3034     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3035 #ifdef TIME_WITH_SYS_TIME
3036 #include <sys/time.h>
3037 #include <time.h>
3038 #else
3039 #ifdef HAVE_SYS_TIME_H
3040 #include <sys/time.h>
3041 #else
3042 #include <time.h>
3043 #endif
3044 #endif]],
3045       [[struct timeval time;
3046        gettimeofday (&time, 0);]])],
3047       emacs_cv_gettimeofday_two_arguments=yes,
3048       emacs_cv_gettimeofday_two_arguments=no)])
3049     if test $emacs_cv_gettimeofday_two_arguments = no; then
3050       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3051                 [Define to 1 if gettimeofday accepts only one argument.])
3052     fi
3053   fi
3054 fi
3055
3056 ok_so_far=yes
3057 AC_CHECK_FUNC(socket, , ok_so_far=no)
3058 if test $ok_so_far = yes; then
3059   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3060 fi
3061 if test $ok_so_far = yes; then
3062   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3063 fi
3064 if test $ok_so_far = yes; then
3065 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3066   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3067             [Define to 1 if you have inet sockets.])
3068 fi
3069
3070 if test -f /usr/lpp/X11/bin/smt.exp; then
3071   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3072             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3073 fi
3074
3075 AC_MSG_CHECKING(whether system supports dynamic ptys)
3076 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3077   AC_MSG_RESULT(yes)
3078   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3079 else
3080   AC_MSG_RESULT(no)
3081 fi
3082
3083 AC_FUNC_FORK
3084
3085 dnl Adapted from Haible's version.
3086 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3087   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3088     [[char* cs = nl_langinfo(CODESET);]])],
3089     emacs_cv_langinfo_codeset=yes,
3090     emacs_cv_langinfo_codeset=no)
3091   ])
3092 if test $emacs_cv_langinfo_codeset = yes; then
3093   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3094     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3095 fi
3096
3097 AC_TYPE_MBSTATE_T
3098
3099 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3100   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3101                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3102 if test "$emacs_cv_c_restrict_arr" = yes; then
3103   AC_DEFINE(__restrict_arr, __restrict,
3104     [Define to compiler's equivalent of C99 restrict keyword in array
3105      declarations.  Define as empty for no equivalent.])
3106 fi
3107
3108 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3109 dnl how the tty code is related to POSIX and/or other versions of termios.
3110 dnl The following looks like a useful start.
3111 dnl
3112 dnl AC_SYS_POSIX_TERMIOS
3113 dnl if test $ac_cv_sys_posix_termios = yes; then
3114 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3115 dnl                                and macros for terminal control.])
3116 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3117 dnl fi
3118
3119 # Set up the CFLAGS for real compilation, so we can substitute it.
3120 CFLAGS="$REAL_CFLAGS"
3121 CPPFLAGS="$REAL_CPPFLAGS"
3122
3123 ## Hack to detect a buggy GCC version.
3124 if test "x$GCC" = xyes \
3125    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3126    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3127    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3128    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3129 fi
3130
3131 version=$PACKAGE_VERSION
3132
3133 ### Specify what sort of things we'll be editing into Makefile and config.h.
3134 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3135 AC_SUBST(version)
3136 AC_SUBST(configuration)
3137 ## Unused?
3138 AC_SUBST(canonical)
3139 AC_SUBST(srcdir)
3140 AC_SUBST(prefix)
3141 AC_SUBST(exec_prefix)
3142 AC_SUBST(bindir)
3143 AC_SUBST(datadir)
3144 AC_SUBST(sharedstatedir)
3145 AC_SUBST(libexecdir)
3146 AC_SUBST(mandir)
3147 AC_SUBST(infodir)
3148 AC_SUBST(lispdir)
3149 AC_SUBST(locallisppath)
3150 AC_SUBST(lisppath)
3151 AC_SUBST(x_default_search_path)
3152 AC_SUBST(etcdir)
3153 AC_SUBST(archlibdir)
3154 AC_SUBST(docdir)
3155 AC_SUBST(bitmapdir)
3156 AC_SUBST(gamedir)
3157 AC_SUBST(gameuser)
3158 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3159 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3160 ## end of LIBX_BASE, but nothing ever set it.
3161 AC_SUBST(LD_SWITCH_X_SITE)
3162 AC_SUBST(C_SWITCH_X_SITE)
3163 AC_SUBST(C_SWITCH_X_SYSTEM)
3164 AC_SUBST(CFLAGS)
3165 ## Used in lwlib/Makefile.in.
3166 AC_SUBST(X_TOOLKIT_TYPE)
3167 if test -n "${machfile}"; then
3168   M_FILE="\$(srcdir)/${machfile}"
3169 else
3170   M_FILE=
3171 fi
3172 S_FILE="\$(srcdir)/${opsysfile}"
3173 AC_SUBST(M_FILE)
3174 AC_SUBST(S_FILE)
3175 AC_SUBST(ns_appdir)
3176 AC_SUBST(ns_appbindir)
3177 AC_SUBST(ns_appresdir)
3178 AC_SUBST(ns_appsrc)
3179 AC_SUBST(GNU_OBJC_CFLAGS)
3180 AC_SUBST(OTHER_FILES)
3181
3182 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3183                    [Define to the canonical Emacs configuration name.])
3184 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3185                    [Define to the options passed to configure.])
3186 if test -n "$machfile"; then
3187   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3188                      [Define to the used machine dependent file.])
3189 fi
3190 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3191                    [Define to the used os dependent file.])
3192
3193 XMENU_OBJ=
3194 XOBJ=
3195 FONT_OBJ=
3196 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3197   AC_DEFINE(HAVE_X_WINDOWS, 1,
3198             [Define to 1 if you want to use the X window system.])
3199   XMENU_OBJ=xmenu.o
3200   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3201   FONT_OBJ=xfont.o
3202   if test "$HAVE_XFT" = "yes"; then
3203     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3204   elif test "$HAVE_FREETYPE" = "yes"; then
3205     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3206   fi
3207   AC_SUBST(FONT_OBJ)
3208 fi
3209 AC_SUBST(XMENU_OBJ)
3210 AC_SUBST(XOBJ)
3211 AC_SUBST(FONT_OBJ)
3212
3213 WIDGET_OBJ=
3214 MOTIF_LIBW=
3215 if test "${USE_X_TOOLKIT}" != "none" ; then
3216   WIDGET_OBJ=widget.o
3217   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3218   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3219     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3220   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3221     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3222     MOTIF_LIBW=-lXm
3223     case "$opsys" in
3224       gnu-linux)
3225         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3226         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3227         ;;
3228
3229       unixware)
3230         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3231         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3232         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3233         ;;
3234
3235       aix4-2)
3236         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3237         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3238         ;;
3239     esac
3240     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3241   fi
3242 fi
3243 AC_SUBST(WIDGET_OBJ)
3244
3245 TOOLKIT_LIBW=
3246 case "$USE_X_TOOLKIT" in
3247   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3248   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3249   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3250 esac
3251 AC_SUBST(TOOLKIT_LIBW)
3252
3253 if test "$USE_X_TOOLKIT" = "none"; then
3254   LIBXT_OTHER="\$(LIBXSM)"
3255   OLDXMENU_TARGET="really-oldXMenu"
3256 else
3257   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3258   OLDXMENU_TARGET="really-lwlib"
3259 fi
3260 AC_SUBST(LIBXT_OTHER)
3261
3262 ## The X Menu stuff is present in the X10 distribution, but missing
3263 ## from X11.  If we have X10, just use the installed library;
3264 ## otherwise, use our own copy.
3265 if test "${HAVE_X11}" = "yes" ; then
3266   AC_DEFINE(HAVE_X11, 1,
3267             [Define to 1 if you want to use version 11 of X windows.
3268              Otherwise, Emacs expects to use version 10.])
3269
3270   if test "$USE_X_TOOLKIT" = "none"; then
3271     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3272   else
3273     OLDXMENU="\${lwlibdir}/liblw.a"
3274   fi
3275   LIBXMENU="\$(OLDXMENU)"
3276   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3277   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3278 else
3279   ## For a syntactically valid Makefile; not actually used for anything.
3280   ## See comments in src/Makefile.in.
3281   OLDXMENU=nothing
3282   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3283   if test "${HAVE_X_WINDOWS}" = "yes"; then
3284     LIBXMENU="-lXMenu"
3285   else
3286     LIBXMENU=
3287   fi
3288   LIBX_OTHER=
3289   OLDXMENU_DEPS=
3290 fi
3291
3292 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3293   OLDXMENU_TARGET=
3294   OLDXMENU=nothing
3295   LIBXMENU=
3296   OLDXMENU_DEPS=
3297 fi
3298
3299 AC_SUBST(OLDXMENU_TARGET)
3300 AC_SUBST(OLDXMENU)
3301 AC_SUBST(LIBXMENU)
3302 AC_SUBST(LIBX_OTHER)
3303 AC_SUBST(OLDXMENU_DEPS)
3304
3305 if test "${HAVE_MENUS}" = "yes" ; then
3306   AC_DEFINE(HAVE_MENUS, 1,
3307             [Define to 1 if you have mouse menus.
3308              (This is automatic if you use X, but the option to specify it remains.)
3309              It is also defined with other window systems that support xmenu.c.])
3310 fi
3311
3312 if test "${GNU_MALLOC}" = "yes" ; then
3313   AC_DEFINE(GNU_MALLOC, 1,
3314             [Define to 1 if you want to use the GNU memory allocator.])
3315 fi
3316
3317 RALLOC_OBJ=
3318 if test "${REL_ALLOC}" = "yes" ; then
3319   AC_DEFINE(REL_ALLOC, 1,
3320             [Define REL_ALLOC if you want to use the relocating allocator for
3321              buffer space.])
3322
3323   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3324 fi
3325 AC_SUBST(RALLOC_OBJ)
3326
3327 if test "$opsys" = "cygwin"; then
3328   CYGWIN_OBJ="sheap.o"
3329   ## Cygwin differs because of its unexec().
3330   PRE_ALLOC_OBJ=
3331   POST_ALLOC_OBJ=lastfile.o
3332 else
3333   CYGWIN_OBJ=
3334   PRE_ALLOC_OBJ=lastfile.o
3335   POST_ALLOC_OBJ=
3336 fi
3337 AC_SUBST(CYGWIN_OBJ)
3338 AC_SUBST(PRE_ALLOC_OBJ)
3339 AC_SUBST(POST_ALLOC_OBJ)
3340
3341 # Configure gnulib here, now that we know LIBS.
3342 gl_ASSERT_NO_GNULIB_POSIXCHECK
3343 gl_ASSERT_NO_GNULIB_TESTS
3344 gl_INIT
3345
3346 case "$opsys" in
3347   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3348
3349   darwin)
3350    ## The -headerpad option tells ld (see man page) to leave room at the
3351    ## end of the header for adding load commands.  Needed for dumping.
3352    ## 0x690 is the total size of 30 segment load commands (at 56
3353    ## each); under Cocoa 31 commands are required.
3354    if test "$HAVE_NS" = "yes"; then
3355      libs_nsgui="-framework AppKit"
3356      headerpad_extra=6C8
3357    else
3358      libs_nsgui=
3359      headerpad_extra=690
3360    fi
3361    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3362
3363    ## This is here because src/Makefile.in did some extra fiddling around
3364    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3365    ##   #ifndef LD_SWITCH_SYSTEM
3366    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3367    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3368    ## not using gcc, darwin system not on an alpha (ie darwin, since
3369    ## darwin + alpha does not occur).
3370    ## Because this was done in src/Makefile.in, the resulting part of
3371    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3372    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3373    ## rather than LD_SWITCH_SYSTEM.
3374    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3375      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3376    ;;
3377
3378   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3379   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3380   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3381   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3382   ## had different values in configure (in ac_link) and src/Makefile.in.
3383   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3384   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3385
3386   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3387 esac
3388
3389 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3390   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3391 fi
3392
3393 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3394
3395
3396 LD_FIRSTFLAG=
3397 ORDINARY_LINK=
3398 case "$opsys" in
3399   ## gnu: GNU needs its own crt0.
3400   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3401
3402   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3403   ## library search parth, i.e. it won't search /usr/lib for libc and
3404   ## friends.  Using -nostartfiles instead avoids this problem, and
3405   ## will also work on earlier NetBSD releases.
3406   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3407
3408   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3409   ##   MkLinux/LinuxPPC needs this.
3410   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3411   gnu-*)
3412     case "$machine" in
3413       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3414     esac
3415     ;;
3416 esac
3417
3418
3419 if test "x$ORDINARY_LINK" = "xyes"; then
3420
3421   LD_FIRSTFLAG=""
3422   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3423
3424 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3425 ## freebsd, gnu-* not on macppc|ibms390x.
3426 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3427
3428   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3429   ## places that are difficult to figure out at make time.  Fortunately,
3430   ## these same versions allow you to pass arbitrary flags on to the
3431   ## linker, so there is no reason not to use it as a linker.
3432   ##
3433   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3434   ## searching for libraries in its internal directories, so we have to
3435   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3436   LD_FIRSTFLAG="-nostdlib"
3437 fi
3438
3439 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3440 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3441
3442 AC_SUBST(LD_FIRSTFLAG)
3443
3444
3445 ## FIXME? The logic here is not precisely the same as that above.
3446 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3447 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3448 LIB_GCC=
3449 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3450
3451   case "$opsys" in
3452     freebsd|netbsd|openbsd) LIB_GCC= ;;
3453
3454     gnu-*)
3455       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3456       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3457       case $host_cpu in
3458       arm*)
3459         LIB_GCC="-lgcc_s"
3460         ;;
3461       *)
3462         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3463         ## immediately undefine it again and redefine it to empty.
3464         ## Was the C_SWITCH_X_SITE part really necessary?
3465 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3466         LIB_GCC=
3467         ;;
3468       esac
3469       ;;
3470
3471     ## Ask GCC where to find libgcc.a.
3472     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3473   esac
3474 fi                              dnl if $GCC
3475 AC_SUBST(LIB_GCC)
3476
3477
3478 ## If we're using X11/GNUstep, define some consequences.
3479 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3480   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3481   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3482 fi
3483
3484
3485 AH_TOP([/* GNU Emacs site configuration template file.
3486
3487 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3488   Free Software Foundation, Inc.
3489
3490 This file is part of GNU Emacs.
3491
3492 GNU Emacs is free software: you can redistribute it and/or modify
3493 it under the terms of the GNU General Public License as published by
3494 the Free Software Foundation, either version 3 of the License, or
3495 (at your option) any later version.
3496
3497 GNU Emacs is distributed in the hope that it will be useful,
3498 but WITHOUT ANY WARRANTY; without even the implied warranty of
3499 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3500 GNU General Public License for more details.
3501
3502 You should have received a copy of the GNU General Public License
3503 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3504
3505
3506 /* No code in Emacs #includes config.h twice, but some bits of code
3507    intended to work with other packages as well (like gmalloc.c)
3508    think they can include it as many times as they like.  */
3509 #ifndef EMACS_CONFIG_H
3510 #define EMACS_CONFIG_H
3511 ])dnl
3512
3513 AH_BOTTOM([
3514 /* On AIX 3 this must be included before any other include file.  */
3515 #include <alloca.h>
3516 #if ! HAVE_ALLOCA
3517 # error "alloca not available on this machine"
3518 #endif
3519
3520 /* Define AMPERSAND_FULL_NAME if you use the convention
3521    that & in the full name stands for the login id.  */
3522 /* Turned on June 1996 supposing nobody will mind it.  */
3523 #define AMPERSAND_FULL_NAME
3524
3525 /* `subprocesses' should be defined if you want to
3526    have code for asynchronous subprocesses
3527    (as used in M-x compile and M-x shell).
3528    Only MSDOS does not support this (it overrides
3529    this in its config_opsysfile below).  */
3530
3531 #define subprocesses
3532
3533 /* Include the os and machine dependent files.  */
3534 #include config_opsysfile
3535 #ifdef config_machfile
3536 # include config_machfile
3537 #endif
3538
3539 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3540    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3541   (There is probably a better place to do this, but right now the
3542    Cocoa side does this in s/darwin.h and we cannot parallel this
3543    exactly since GNUstep is multi-OS.  */
3544 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3545 #  define SYSTEM_PURESIZE_EXTRA 30000
3546 #endif
3547
3548 #ifdef emacs /* Don't do this for lib-src.  */
3549 /* Tell regex.c to use a type compatible with Emacs.  */
3550 #define RE_TRANSLATE_TYPE Lisp_Object
3551 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3552 #ifdef make_number
3553 /* If make_number is a macro, use it.  */
3554 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3555 #else
3556 /* If make_number is a function, avoid it.  */
3557 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3558 #endif
3559 #endif
3560
3561 /* These default definitions are good for almost all machines.
3562    Any exceptions should override them in m/MACHINE.h.
3563    They must be usable in preprocessor conditionals.  */
3564
3565 #ifndef BITS_PER_CHAR
3566 #define BITS_PER_CHAR 8
3567 #endif
3568
3569 #ifndef BITS_PER_SHORT
3570 #define BITS_PER_SHORT 16
3571 #endif
3572
3573 #ifndef BITS_PER_INT
3574 #define BITS_PER_INT 32
3575 #endif
3576
3577 #ifndef BITS_PER_LONG
3578 #ifdef _LP64
3579 #define BITS_PER_LONG 64
3580 #else
3581 #define BITS_PER_LONG 32
3582 #endif
3583 #endif
3584
3585 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3586 #define BITS_PER_LONG_LONG 64
3587 #endif
3588
3589 /* Define if the compiler supports function prototypes.  It may do so but
3590    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3591 #undef PROTOTYPES
3592
3593 #include <string.h>
3594 #include <stdlib.h>
3595
3596 #if defined __GNUC__ && (__GNUC__ > 2 \
3597                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3598 #define NO_RETURN       __attribute__ ((__noreturn__))
3599 #else
3600 #define NO_RETURN       /* nothing */
3601 #endif
3602
3603 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3604 #define NO_INLINE __attribute__((noinline))
3605 #else
3606 #define NO_INLINE
3607 #endif
3608
3609 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3610 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3611 #else
3612 #define EXTERNALLY_VISIBLE
3613 #endif
3614
3615 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3616 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3617 #else
3618 # define ATTRIBUTE_FORMAT(spec) /* empty */
3619 #endif
3620
3621 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3622 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3623    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3624 #else
3625 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3626    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3627 #endif
3628
3629 /* Some versions of GNU/Linux define noinline in their headers.  */
3630 #ifdef noinline
3631 #undef noinline
3632 #endif
3633
3634 /* These won't be used automatically yet.  We also need to know, at least,
3635    that the stack is continuous.  */
3636 #ifdef __GNUC__
3637 #  ifndef GC_SETJMP_WORKS
3638   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3639 #    define GC_SETJMP_WORKS 1
3640 #  endif
3641 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3642 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3643 #  endif
3644 #endif
3645
3646 #endif /* EMACS_CONFIG_H */
3647
3648 /*
3649 Local Variables:
3650 mode: c
3651 End:
3652 */
3653 ])dnl
3654
3655 #### Report on what we decided to do.
3656 #### Report GTK as a toolkit, even if it doesn't use Xt.
3657 #### It makes printing result more understandable as using GTK sets
3658 #### toolkit_scroll_bars to yes by default.
3659 if test "${HAVE_GTK}" = "yes"; then
3660   USE_X_TOOLKIT=GTK
3661 fi
3662
3663 and_machfile=
3664 if test -n "$machfile"; then
3665   and_machfile=" and \`${machfile}'"
3666 fi
3667
3668 echo "
3669 Configured for \`${canonical}'.
3670
3671   Where should the build process find the source code?    ${srcdir}
3672   What operating system and machine description files should Emacs use?
3673         \`${opsysfile}'${and_machfile}
3674   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3675   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3676   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3677   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3678   What window system should Emacs use?                    ${window_system}
3679   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3680
3681 if test -n "${x_includes}"; then
3682 echo "  Where do we find X Windows header files?                ${x_includes}"
3683 else
3684 echo "  Where do we find X Windows header files?                Standard dirs"
3685 fi
3686 if test -n "${x_libraries}"; then
3687 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3688 else
3689 echo "  Where do we find X Windows libraries?                   Standard dirs"
3690 fi
3691
3692 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3693 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3694 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3695 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3696 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3697 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3698 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3699 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3700
3701 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3702 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3703 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3704 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3705 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3706 echo "  Does Emacs use -lgnutls (2.6.x or higher)?              ${HAVE_GNUTLS}"
3707 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3708
3709 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3710 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3711 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3712 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3713
3714 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3715 echo
3716
3717 if test $USE_XASSERTS = yes; then
3718    echo "  Compiling with asserts turned on."
3719    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3720 fi
3721
3722 echo
3723
3724 if test "$HAVE_NS" = "yes"; then
3725    echo
3726    echo "You must run \"make install\" in order to test the built application.
3727 The installed application will go to nextstep/Emacs.app and can be
3728 run or moved from there."
3729    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3730       echo "The application will be fully self-contained."
3731     else
3732       echo "The lisp resources for the application will be installed under ${prefix}.
3733 You may need to run \"make install\" with sudo.  The application will fail
3734 to run if these resources are not installed."
3735    fi
3736    echo
3737 fi
3738
3739
3740 # Remove any trailing slashes in these variables.
3741 [test "${prefix}" != NONE &&
3742   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3743 test "${exec_prefix}" != NONE &&
3744   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3745
3746 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3747 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3748 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3749 dnl (else you get "no `Makefile.am' found for any configure output").
3750 dnl This will work, but you get a config.status that is not quite right
3751 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3752 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3753 dnl it seems better to just live with the duplication.
3754 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3755
3756 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3757        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3758        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3759        leim/Makefile])
3760
3761 dnl test/ is not present in release tarfiles.
3762 opt_makefile=test/automated/Makefile
3763
3764 if test -f $srcdir/${opt_makefile}.in; then
3765   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3766   dnl Again, it's best not to use a variable.  Though you can add
3767   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3768   AC_CONFIG_FILES([test/automated/Makefile])
3769 fi
3770
3771 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3772
3773 AC_SUBST(SUBDIR_MAKEFILES_IN)
3774
3775 dnl Make the necessary directories, if they don't exist.
3776 AC_CONFIG_COMMANDS([mkdirs], [
3777 for dir in etc lisp ; do
3778   test -d ${dir} || mkdir ${dir}
3779 done
3780 ])
3781
3782 dnl You might wonder (I did) why epaths.h is generated by running make,
3783 dnl rather than just letting configure generate it from epaths.in.
3784 dnl One reason is that the various paths are not fully expanded (see above);
3785 dnl eg gamedir=${prefix}/var/games/emacs.
3786 dnl Secondly, the GNU Coding standards require that one should be able
3787 dnl to run `make prefix=/some/where/else' and override the values set
3788 dnl by configure.  This also explains the `move-if-change' test and
3789 dnl the use of force in the `epaths-force' rule in Makefile.in.
3790 AC_CONFIG_COMMANDS([epaths], [
3791 echo creating src/epaths.h
3792 ${MAKE-make} epaths-force
3793 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3794
3795 AC_CONFIG_COMMANDS([gdbinit], [
3796 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3797   echo creating src/.gdbinit
3798   echo source $srcdir/src/.gdbinit > src/.gdbinit
3799 fi
3800 ])
3801
3802 AC_OUTPUT
3803
3804 dnl configure.in ends here