lisp/vc-bzr.el

   1 ;;; vc-bzr.el --- VC backend for the bzr revision control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>, Riccardo Murri <riccardo.murri@gmail.com>
   6 ;; Keywords: tools
   7 ;; Created: Sept 2006
   8 ;; Version: 2008-01-04 (Bzr revno 25)
   9 ;; URL: http://launchpad.net/vc-bzr
  10
  11 ;; This file is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; This file is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26
  27 ;;; Commentary:
  28
  29 ;; See <URL:http://bazaar-vcs.org/> concerning bzr.  See
  30 ;; <URL:http://launchpad.net/vc-bzr> for alternate development
  31 ;; branches of `vc-bzr'.
  32
  33 ;; Load this library to register bzr support in VC.
  34
  35 ;; Known bugs
  36 ;; ==========
  37
  38 ;; When edititing a symlink and *both* the symlink and its target
  39 ;; are bzr-versioned, `vc-bzr` presently runs `bzr status` on the
  40 ;; symlink, thereby not detecting whether the actual contents
  41 ;; (that is, the target contents) are changed.
  42 ;; See https://bugs.launchpad.net/vc-bzr/+bug/116607
  43
  44 ;; For an up-to-date list of bugs, please see:
  45 ;;   https://bugs.launchpad.net/vc-bzr/+bugs
  46
  47
  48 ;;; Code:
  49
  50 (eval-when-compile
  51   (require 'cl)
  52   (require 'vc))                        ; for vc-exec-after
  53
  54 ;; Clear up the cache to force vc-call to check again and discover
  55 ;; new functions when we reload this file.
  56 (put 'Bzr 'vc-functions nil)
  57
  58 (defgroup vc-bzr nil
  59   "VC bzr backend."
  60   :version "22.2"
  61   :group 'vc)
  62
  63 (defcustom vc-bzr-program "bzr"
  64   "Name of the bzr command (excluding any arguments)."
  65   :group 'vc-bzr
  66   :type 'string)
  67
  68 (defcustom vc-bzr-diff-switches nil
  69   "String/list of strings specifying extra switches for bzr diff under VC."
  70   :type '(choice (const :tag "None" nil)
  71                  (string :tag "Argument String")
  72                  (repeat :tag "Argument List" :value ("") string))
  73   :group 'vc-bzr)
  74
  75 (defcustom vc-bzr-log-switches nil
  76   "String/list of strings specifying extra switches for `bzr log' under VC."
  77   :type '(choice (const :tag "None" nil)
  78                  (string :tag "Argument String")
  79                  (repeat :tag "Argument List" :value ("") string))
  80   :group 'vc-bzr)
  81
  82 ;; since v0.9, bzr supports removing the progress indicators
  83 ;; by setting environment variable BZR_PROGRESS_BAR to "none".
  84 (defun vc-bzr-command (bzr-command buffer okstatus file-or-list &rest args)
  85   "Wrapper round `vc-do-command' using `vc-bzr-program' as COMMAND.
  86 Invoke the bzr command adding `BZR_PROGRESS_BAR=none' and
  87 `LC_MESSAGES=C' to the environment."
  88   (let ((process-environment
  89          (list* "BZR_PROGRESS_BAR=none" ; Suppress progress output (bzr >=0.9)
  90                 "LC_MESSAGES=C"         ; Force English output
  91                 process-environment)))
  92     (apply 'vc-do-command buffer okstatus vc-bzr-program
  93            file-or-list bzr-command args)))
  94
  95
  96 ;;;###autoload
  97 (defconst vc-bzr-admin-dirname ".bzr"
  98   "Name of the directory containing Bzr repository status files.")
  99 ;;;###autoload
 100 (defconst vc-bzr-admin-checkout-format-file
 101   (concat vc-bzr-admin-dirname "/checkout/format"))
 102 (defconst vc-bzr-admin-dirstate
 103   (concat vc-bzr-admin-dirname "/checkout/dirstate"))
 104 (defconst vc-bzr-admin-branch-format-file
 105   (concat vc-bzr-admin-dirname "/branch/format"))
 106 (defconst vc-bzr-admin-revhistory
 107   (concat vc-bzr-admin-dirname "/branch/revision-history"))
 108 (defconst vc-bzr-admin-lastrev
 109   (concat vc-bzr-admin-dirname "/branch/last-revision"))
 110
 111 ;;;###autoload (defun vc-bzr-registered (file)
 112 ;;;###autoload   (if (vc-find-root file vc-bzr-admin-checkout-format-file)
 113 ;;;###autoload       (progn
 114 ;;;###autoload         (load "vc-bzr")
 115 ;;;###autoload         (vc-bzr-registered file))))
 116
 117 (defun vc-bzr-root (file)
 118   "Return the root directory of the bzr repository containing FILE."
 119   ;; Cache technique copied from vc-arch.el.
 120   (or (vc-file-getprop file 'bzr-root)
 121       (let ((root (vc-find-root file vc-bzr-admin-checkout-format-file)))
 122         (when root (vc-file-setprop file 'bzr-root root)))))
 123
 124 (require 'sha1)                         ;For sha1-program
 125
 126 (defun vc-bzr-sha1 (file)
 127   (with-temp-buffer
 128     (set-buffer-multibyte nil)
 129     (let ((prog sha1-program)
 130           (args nil))
 131       (when (consp prog)
 132         (setq args (cdr prog))
 133         (setq prog (car prog)))
 134       (apply 'call-process prog file t nil args)
 135       (buffer-substring (point-min) (+ (point-min) 40)))))
 136
 137 (defun vc-bzr-state-heuristic (file)
 138   "Like `vc-bzr-state' but hopefully without running Bzr."
 139   ;; `bzr status' is excrutiatingly slow with large histories and
 140   ;; pending merges, so try to avoid using it until they fix their
 141   ;; performance problems.
 142   ;; This function tries first to parse Bzr internal file
 143   ;; `checkout/dirstate', but it may fail if Bzr internal file format
 144   ;; has changed.  As a safeguard, the `checkout/dirstate' file is
 145   ;; only parsed if it contains the string `#bazaar dirstate flat
 146   ;; format 3' in the first line.
 147   ;; If the `checkout/dirstate' file cannot be parsed, fall back to
 148   ;; running `vc-bzr-state'."
 149   (lexical-let ((root (vc-bzr-root file)))
 150     (when root    ; Short cut.
 151       ;; This looks at internal files.  May break if they change
 152       ;; their format.
 153       (lexical-let ((dirstate (expand-file-name vc-bzr-admin-dirstate root)))
 154         (if (not (file-readable-p dirstate))
 155             (vc-bzr-state file)         ; Expensive.
 156           (with-temp-buffer
 157             (insert-file-contents dirstate)
 158             (goto-char (point-min))
 159             (if (not (looking-at "#bazaar dirstate flat format 3"))
 160                 (vc-bzr-state file)     ; Some other unknown format?
 161               (let* ((relfile (file-relative-name file root))
 162                      (reldir (file-name-directory relfile)))
 163                 (if (re-search-forward
 164                      (concat "^\0"
 165                              (if reldir (regexp-quote
 166                                          (directory-file-name reldir)))
 167                              "\0"
 168                              (regexp-quote (file-name-nondirectory relfile))
 169                              "\0"
 170                              "[^\0]*\0"       ;id?
 171                              "\\([^\0]*\\)\0" ;"a/f/d", a=removed?
 172                              "[^\0]*\0"       ;sha1 (empty if conflicted)?
 173                              "\\([^\0]*\\)\0" ;size?
 174                              "[^\0]*\0"       ;"y/n", executable?
 175                              "[^\0]*\0"       ;?
 176                              "\\([^\0]*\\)\0" ;"a/f/d" a=added?
 177                              "\\([^\0]*\\)\0" ;sha1 again?
 178                              "[^\0]*\0"       ;size again?
 179                              "[^\0]*\0"       ;"y/n", executable again?
 180                              "[^\0]*\0"       ;last revid?
 181                              ;; There are more fields when merges are pending.
 182                              )
 183                      nil t)
 184                     ;; Apparently the second sha1 is the one we want: when
 185                     ;; there's a conflict, the first sha1 is absent (and the
 186                     ;; first size seems to correspond to the file with
 187                     ;; conflict markers).
 188                     (cond
 189                      ((eq (char-after (match-beginning 1)) ?a) 'removed)
 190                      ((eq (char-after (match-beginning 3)) ?a) 'added)
 191                      ((and (eq (string-to-number (match-string 2))
 192                                (nth 7 (file-attributes file)))
 193                            (equal (match-string 4)
 194                                   (vc-bzr-sha1 file)))
 195                       'up-to-date)
 196                      (t 'edited))
 197                   'unregistered)))))))))
 198
 199 (defun vc-bzr-registered (file)
 200   "Return non-nil if FILE is registered with bzr."
 201   (let ((state (vc-bzr-state-heuristic file)))
 202     (not (memq state '(nil unregistered ignored)))))
 203
 204 (defconst vc-bzr-state-words
 205   "added\\|ignored\\|kind changed\\|modified\\|removed\\|renamed\\|unknown"
 206   "Regexp matching file status words as reported in `bzr' output.")
 207
 208 (defun vc-bzr-file-name-relative (filename)
 209   "Return file name FILENAME stripped of the initial Bzr repository path."
 210   (lexical-let*
 211       ((filename* (expand-file-name filename))
 212        (rootdir (vc-bzr-root filename*)))
 213     (when rootdir
 214          (file-relative-name filename* rootdir))))
 215
 216 (defun vc-bzr-status (file)
 217   "Return FILE status according to Bzr.
 218 Return value is a cons (STATUS . WARNING), where WARNING is a
 219 string or nil, and STATUS is one of the symbols: `added',
 220 `ignored', `kindchanged', `modified', `removed', `renamed', `unknown',
 221 which directly correspond to `bzr status' output, or 'unchanged
 222 for files whose copy in the working tree is identical to the one
 223 in the branch repository, or nil for files that are not
 224 registered with Bzr.
 225
 226 If any error occurred in running `bzr status', then return nil."
 227   (with-temp-buffer
 228     (let ((ret (condition-case nil
 229                    (vc-bzr-command "status" t 0 file)
 230                  (file-error nil)))     ; vc-bzr-program not found.
 231           (status 'unchanged))
 232           ;; the only secure status indication in `bzr status' output
 233           ;; is a couple of lines following the pattern::
 234           ;;   | <status>:
 235           ;;   |   <file name>
 236           ;; if the file is up-to-date, we get no status report from `bzr',
 237           ;; so if the regexp search for the above pattern fails, we consider
 238           ;; the file to be up-to-date.
 239           (goto-char (point-min))
 240           (when (re-search-forward
 241                  ;; bzr prints paths relative to the repository root.
 242                  (concat "^\\(" vc-bzr-state-words "\\):[ \t\n]+"
 243                          (regexp-quote (vc-bzr-file-name-relative file))
 244                          ;; Bzr appends a '/' to directory names and
 245                          ;; '*' to executable files
 246                          (if (file-directory-p file) "/?" "\\*?")
 247                          "[ \t\n]*$")
 248                  nil t)
 249             (lexical-let ((statusword (match-string 1)))
 250               ;; Erase the status text that matched.
 251               (delete-region (match-beginning 0) (match-end 0))
 252               (setq status
 253                     (intern (replace-regexp-in-string " " "" statusword)))))
 254           (when status
 255             (goto-char (point-min))
 256             (skip-chars-forward " \n\t") ;Throw away spaces.
 257             (cons status
 258                   ;; "bzr" will output warnings and informational messages to
 259                   ;; stderr; due to Emacs' `vc-do-command' (and, it seems,
 260                   ;; `start-process' itself) limitations, we cannot catch stderr
 261                   ;; and stdout into different buffers.  So, if there's anything
 262                   ;; left in the buffer after removing the above status
 263                   ;; keywords, let us just presume that any other message from
 264                   ;; "bzr" is a user warning, and display it.
 265                   (unless (eobp) (buffer-substring (point) (point-max))))))))
 266
 267 (defun vc-bzr-state (file)
 268   (lexical-let ((result (vc-bzr-status file)))
 269     (when (consp result)
 270       (when (cdr result)
 271         (message "Warnings in `bzr' output: %s" (cdr result)))
 272       (cdr (assq (car result)
 273                  '((added . added)
 274                    (kindchanged . edited)
 275                    (renamed . edited)
 276                    (modified . edited)
 277                    (removed . removed)
 278                    (ignored . ignored)
 279                    (unknown . unregistered)
 280                    (unchanged . up-to-date)))))))
 281
 282 (defun vc-bzr-resolve-when-done ()
 283   "Call \"bzr resolve\" if the conflict markers have been removed."
 284   (save-excursion
 285     (goto-char (point-min))
 286     (unless (re-search-forward "^<<<<<<< " nil t)
 287       (vc-bzr-command "resolve" nil 0 buffer-file-name)
 288       ;; Remove the hook so that it is not called multiple times.
 289       (remove-hook 'after-save-hook 'vc-bzr-resolve-when-done t))))
 290
 291 (defun vc-bzr-find-file-hook ()
 292   (when (and buffer-file-name
 293              ;; FIXME: We should check that "bzr status" says "conflict".
 294              (file-exists-p (concat buffer-file-name ".BASE"))
 295              (file-exists-p (concat buffer-file-name ".OTHER"))
 296              (file-exists-p (concat buffer-file-name ".THIS"))
 297              ;; If "bzr status" says there's a conflict but there are no
 298              ;; conflict markers, it's not clear what we should do.
 299              (save-excursion
 300                (goto-char (point-min))
 301                (re-search-forward "^<<<<<<< " nil t)))
 302     ;; TODO: the merge algorithm used in `bzr merge' is nicely configurable,
 303     ;; but the one in `bzr pull' isn't, so it would be good to provide an
 304     ;; elisp function to remerge from the .BASE/OTHER/THIS files.
 305     (smerge-start-session)
 306     (add-hook 'after-save-hook 'vc-bzr-resolve-when-done nil t)
 307     (message "There are unresolved conflicts in this file")))
 308
 309 (defun vc-bzr-workfile-unchanged-p (file)
 310   (eq 'unchanged (car (vc-bzr-status file))))
 311
 312 (defun vc-bzr-working-revision (file)
 313   ;; Together with the code in vc-state-heuristic, this makes it possible
 314   ;; to get the initial VC state of a Bzr file even if Bzr is not installed.
 315   (lexical-let*
 316       ((rootdir (vc-bzr-root file))
 317        (branch-format-file (expand-file-name vc-bzr-admin-branch-format-file
 318                                              rootdir))
 319        (revhistory-file (expand-file-name vc-bzr-admin-revhistory rootdir))
 320        (lastrev-file (expand-file-name vc-bzr-admin-lastrev rootdir)))
 321     ;; This looks at internal files to avoid forking a bzr process.
 322     ;; May break if they change their format.
 323     (if (file-exists-p branch-format-file)
 324         (with-temp-buffer
 325           (insert-file-contents branch-format-file)
 326           (goto-char (point-min))
 327           (cond
 328            ((or
 329              (looking-at "Bazaar-NG branch, format 0.0.4")
 330              (looking-at "Bazaar-NG branch format 5"))
 331             ;; count lines in .bzr/branch/revision-history
 332             (insert-file-contents revhistory-file)
 333             (number-to-string (count-lines (line-end-position) (point-max))))
 334            ((looking-at "Bazaar Branch Format 6 (bzr 0.15)")
 335             ;; revno is the first number in .bzr/branch/last-revision
 336             (insert-file-contents lastrev-file)
 337             (if (re-search-forward "[0-9]+" nil t)
 338                 (buffer-substring (match-beginning 0) (match-end 0))))))
 339       ;; fallback to calling "bzr revno"
 340       (lexical-let*
 341           ((result (vc-bzr-command-discarding-stderr
 342                     vc-bzr-program "revno" file))
 343            (exitcode (car result))
 344            (output (cdr result)))
 345         (cond
 346          ((eq exitcode 0) (substring output 0 -1))
 347          (t nil))))))
 348
 349 (defun vc-bzr-checkout-model (files) 'implicit)
 350
 351 (defun vc-bzr-create-repo ()
 352   "Create a new Bzr repository."
 353   (vc-bzr-command "init" nil 0 nil))
 354
 355 (defun vc-bzr-init-revision (&optional file)
 356   "Always return nil, as Bzr cannot register explicit versions."
 357   nil)
 358
 359 (defun vc-bzr-previous-revision (file rev)
 360   (if (string-match "\\`[0-9]+\\'" rev)
 361       (number-to-string (1- (string-to-number rev)))
 362     (concat "before:" rev)))
 363
 364 (defun vc-bzr-next-revision (file rev)
 365   (if (string-match "\\`[0-9]+\\'" rev)
 366       (number-to-string (1+ (string-to-number rev)))
 367     (error "Don't know how to compute the next revision of %s" rev)))
 368
 369 (defun vc-bzr-register (files &optional rev comment)
 370   "Register FILE under bzr.
 371 Signal an error unless REV is nil.
 372 COMMENT is ignored."
 373   (if rev (error "Can't register explicit revision with bzr"))
 374   (vc-bzr-command "add" nil 0 files))
 375
 376 ;; Could run `bzr status' in the directory and see if it succeeds, but
 377 ;; that's relatively expensive.
 378 (defalias 'vc-bzr-responsible-p 'vc-bzr-root
 379   "Return non-nil if FILE is (potentially) controlled by bzr.
 380 The criterion is that there is a `.bzr' directory in the same
 381 or a superior directory.")
 382
 383 (defun vc-bzr-could-register (file)
 384   "Return non-nil if FILE could be registered under bzr."
 385   (and (vc-bzr-responsible-p file)      ; shortcut
 386        (condition-case ()
 387            (with-temp-buffer
 388              (vc-bzr-command "add" t 0 file "--dry-run")
 389              ;; The command succeeds with no output if file is
 390              ;; registered (in bzr 0.8).
 391              (goto-char (point-min))
 392              (looking-at "added "))
 393          (error))))
 394
 395 (defun vc-bzr-unregister (file)
 396   "Unregister FILE from bzr."
 397   (vc-bzr-command "remove" nil 0 file "--keep"))
 398
 399 (defun vc-bzr-checkin (files rev comment)
 400   "Check FILE in to bzr with log message COMMENT.
 401 REV non-nil gets an error."
 402   (if rev (error "Can't check in a specific revision with bzr"))
 403   (vc-bzr-command "commit" nil 0 files "-m" comment))
 404
 405 (defun vc-bzr-find-version (file rev buffer)
 406   "Fetch version REV of file FILE and put it into BUFFER."
 407     (with-current-buffer buffer
 408       (if (and rev (stringp rev) (not (string= rev "")))
 409           (vc-bzr-command "cat" t 0 file "-r" rev)
 410         (vc-bzr-command "cat" t 0 file))))
 411
 412 (defun vc-bzr-checkout (file &optional editable rev)
 413   (if rev (error "Operation not supported")
 414     ;; Else, there's nothing to do.
 415     nil))
 416
 417 (defun vc-bzr-revert (file &optional contents-done)
 418   (unless contents-done
 419     (with-temp-buffer (vc-bzr-command "revert" t 0 file))))
 420
 421 (defvar log-view-message-re)
 422 (defvar log-view-file-re)
 423 (defvar log-view-font-lock-keywords)
 424 (defvar log-view-current-tag-function)
 425
 426 (define-derived-mode vc-bzr-log-view-mode log-view-mode "Bzr-Log-View"
 427   (remove-hook 'log-view-mode-hook 'vc-bzr-log-view-mode) ;Deactivate the hack.
 428   (require 'add-log)
 429   (set (make-local-variable 'log-view-file-re) "^Working file:[ \t]+\\(.+\\)")
 430   (set (make-local-variable 'log-view-message-re)
 431        "^ *-+\n *\\(?:revno: \\([0-9.]+\\)\\|merged: .+\\)")
 432   (set (make-local-variable 'log-view-font-lock-keywords)
 433        ;; log-view-font-lock-keywords is careful to use the buffer-local
 434        ;; value of log-view-message-re only since Emacs-23.
 435        (append `((,log-view-message-re . 'log-view-message-face))
 436                ;; log-view-font-lock-keywords
 437                '(("^ *committer: \
 438 \\([^<(]+?\\)[  ]*[(<]\\([[:alnum:]_.+-]+@[[:alnum:]_.-]+\\)[>)]"
 439                   (1 'change-log-name)
 440                   (2 'change-log-email))
 441                  ("^ *timestamp: \\(.*\\)" (1 'change-log-date-face))))))
 442
 443 (defun vc-bzr-print-log (files &optional buffer) ; get buffer arg in Emacs 22
 444   "Get bzr change log for FILES into specified BUFFER."
 445   ;; `vc-do-command' creates the buffer, but we need it before running
 446   ;; the command.
 447   (vc-setup-buffer buffer)
 448   ;; If the buffer exists from a previous invocation it might be
 449   ;; read-only.
 450   ;; FIXME: `vc-bzr-command' runs `bzr log' with `LC_MESSAGES=C', so
 451   ;; the log display may not what the user wants - but I see no other
 452   ;; way of getting the above regexps working.
 453   (dolist (file files)
 454     (vc-exec-after
 455      `(let ((inhibit-read-only t))
 456         (with-current-buffer buffer
 457           ;; Insert the file name so that log-view.el can find it.
 458           (insert "Working file: " ',file "\n")) ;; Like RCS/CVS.
 459         (apply 'vc-bzr-command "log" ',buffer 'async ',file
 460                ',(if (stringp vc-bzr-log-switches)
 461                      (list vc-bzr-log-switches)
 462                    vc-bzr-log-switches))))))
 463
 464 (defun vc-bzr-show-log-entry (revision)
 465   "Find entry for patch name REVISION in bzr change log buffer."
 466   (goto-char (point-min))
 467   (let (case-fold-search)
 468     (if (re-search-forward
 469          ;; "revno:" can appear either at the beginning of a line, or indented.
 470          (concat "^[ ]*-+\n[ ]*revno: "
 471                  ;; The revision can contain ".", quote it so that it
 472                  ;; does not interfere with regexp matching.
 473                  (regexp-quote revision) "$") nil t)
 474         (beginning-of-line 0)
 475       (goto-char (point-min)))))
 476
 477 (defun vc-bzr-diff (files &optional rev1 rev2 buffer)
 478   "VC bzr backend for diff."
 479   ;; `bzr diff' exits with code 1 if diff is non-empty.
 480   (apply #'vc-bzr-command "diff" (or buffer "*vc-diff*") 'async files
 481          "--diff-options" (mapconcat 'identity
 482                                      (vc-diff-switches-list bzr)
 483                                      " ")
 484          ;; This `when' is just an optimization because bzr-1.2 is *much*
 485          ;; faster when the revision argument is not given.
 486          (when (or rev1 rev2)
 487            (list "-r" (format "%s..%s"
 488                               (or rev1 "revno:-1")
 489                               (or rev2 ""))))))
 490
 491
 492 ;; FIXME: vc-{next,previous}-revision need fixing in vc.el to deal with
 493 ;; straight integer revisions.
 494
 495 (defun vc-bzr-delete-file (file)
 496   "Delete FILE and delete it in the bzr repository."
 497   (condition-case ()
 498       (delete-file file)
 499     (file-error nil))
 500   (vc-bzr-command "remove" nil 0 file))
 501
 502 (defun vc-bzr-rename-file (old new)
 503   "Rename file from OLD to NEW using `bzr mv'."
 504   (vc-bzr-command "mv" nil 0 new old))
 505
 506 (defvar vc-bzr-annotation-table nil
 507   "Internal use.")
 508 (make-variable-buffer-local 'vc-bzr-annotation-table)
 509
 510 (defun vc-bzr-annotate-command (file buffer &optional revision)
 511   "Prepare BUFFER for `vc-annotate' on FILE.
 512 Each line is tagged with the revision number, which has a `help-echo'
 513 property containing author and date information."
 514   (apply #'vc-bzr-command "annotate" buffer 0 file "--long" "--all"
 515          (if revision (list "-r" revision)))
 516   (with-current-buffer buffer
 517     ;; Store the tags for the annotated source lines in a hash table
 518     ;; to allow saving space by sharing the text properties.
 519     (setq vc-bzr-annotation-table (make-hash-table :test 'equal))
 520     (goto-char (point-min))
 521     (while (re-search-forward "^\\( *[0-9.]+ *\\) \\([^\n ]+\\) +\\([0-9]\\{8\\}\\) |"
 522                               nil t)
 523       (let* ((rev (match-string 1))
 524              (author (match-string 2))
 525              (date (match-string 3))
 526              (key (match-string 0))
 527              (tag (gethash key vc-bzr-annotation-table)))
 528         (unless tag
 529           (setq tag (propertize rev 'help-echo (concat "Author: " author
 530                                                        ", date: " date)
 531                                 'mouse-face 'highlight))
 532           (puthash key tag vc-bzr-annotation-table))
 533         (replace-match "")
 534         (insert tag " |")))))
 535
 536 (defun vc-bzr-annotate-time ()
 537   (when (re-search-forward "^ *[0-9.]+ +|" nil t)
 538     (let ((prop (get-text-property (line-beginning-position) 'help-echo)))
 539       (string-match "[0-9]+\\'" prop)
 540       (vc-annotate-convert-time
 541        (encode-time 0 0 0
 542                     (string-to-number (substring (match-string 0 prop) 6 8))
 543                     (string-to-number (substring (match-string 0 prop) 4 6))
 544                     (string-to-number (substring (match-string 0 prop) 0 4))
 545                     )))))
 546
 547 (defun vc-bzr-annotate-extract-revision-at-line ()
 548   "Return revision for current line of annoation buffer, or nil.
 549 Return nil if current line isn't annotated."
 550   (save-excursion
 551     (beginning-of-line)
 552     (if (looking-at " *\\([0-9.]+\\) | ")
 553         (match-string-no-properties 1))))
 554
 555 (defun vc-bzr-command-discarding-stderr (command &rest args)
 556   "Execute shell command COMMAND (with ARGS); return its output and exitcode.
 557 Return value is a cons (EXITCODE . OUTPUT), where EXITCODE is
 558 the (numerical) exit code of the process, and OUTPUT is a string
 559 containing whatever the process sent to its standard output
 560 stream.  Standard error output is discarded."
 561   (with-temp-buffer
 562     (cons
 563      (apply #'call-process command nil (list (current-buffer) nil) nil args)
 564      (buffer-substring (point-min) (point-max)))))
 565
 566 ;; TODO: it would be nice to mark the conflicted files in  VC Dired,
 567 ;; and implement a command to run ediff and `bzr resolve' once the
 568 ;; changes have been merged.
 569 (defun vc-bzr-dir-state (dir &optional localp)
 570   "Find the VC state of all files in DIR and its subdirectories.
 571 Optional argument LOCALP is always ignored."
 572   (let ((bzr-root-directory (vc-bzr-root dir))
 573         (at-start t)
 574         current-bzr-state current-vc-state)
 575     ;; Check that DIR is a bzr repository.
 576     (unless (file-name-absolute-p bzr-root-directory)
 577       (error "Cannot find bzr repository for directory `%s'" dir))
 578     ;; `bzr ls --versioned' lists all versioned files;
 579     ;; assume they are up-to-date, unless we are given
 580     ;; evidence of the contrary.
 581     (setq at-start t)
 582     (with-temp-buffer
 583       (buffer-disable-undo)             ;; Because these buffers can get huge
 584       (vc-bzr-command "ls" t 0 nil "--versioned")
 585       (goto-char (point-min))
 586       (while (or at-start
 587                  (eq 0 (forward-line)))
 588         (setq at-start nil)
 589         (let ((file (expand-file-name
 590                      (buffer-substring-no-properties
 591                       (line-beginning-position) (line-end-position))
 592                      bzr-root-directory)))
 593           ;; files are up-to-date unless they appear in the `bzr
 594           ;; status' output below
 595           (vc-file-setprop file 'vc-state 'up-to-date)
 596           ;; XXX: is this correct? what happens if one
 597           ;; mixes different SCMs in the same dir?
 598           ;; Anyway, we're looking at the output of `bzr ls --versioned',
 599           ;; so we know these files are registered with Bzr.
 600           (vc-file-setprop file 'vc-backend 'Bzr))))
 601     ;; `bzr status' reports on added/modified/renamed and unknown/ignored files
 602     (setq at-start t)
 603     (with-temp-buffer
 604       (vc-bzr-command "status" t 0 nil)
 605       (goto-char (point-min))
 606       (while (or at-start
 607                  (eq 0 (forward-line)))
 608         (setq at-start nil)
 609         (cond
 610          ((looking-at "^added")
 611           (setq current-vc-state 'added)
 612           (setq current-bzr-state 'added))
 613          ((looking-at "^kind changed")
 614           (setq current-vc-state 'edited)
 615           (setq current-bzr-state 'kindchanged))
 616          ((looking-at "^modified")
 617           (setq current-vc-state 'edited)
 618           (setq current-bzr-state 'modified))
 619          ((looking-at "^renamed")
 620           (setq current-vc-state 'edited)
 621           (setq current-bzr-state 'renamed))
 622          ((looking-at "^ignored")
 623           (setq current-vc-state 'ignored)
 624           (setq current-bzr-state 'not-versioned))
 625          ((looking-at "^unknown")
 626           (setq current-vc-state 'unregistered)
 627           (setq current-bzr-state 'not-versioned))
 628          ((looking-at "  ")
 629           ;; file names are indented by two spaces
 630           (when current-vc-state
 631             (let ((file (expand-file-name
 632                          (buffer-substring-no-properties
 633                           (match-end 0) (line-end-position))
 634                          bzr-root-directory)))
 635               (vc-file-setprop file 'vc-state current-vc-state)
 636               (vc-file-setprop file 'vc-bzr-state current-bzr-state)
 637               (when (eq 'added current-bzr-state)
 638                 (vc-file-setprop file 'vc-working-revision "0"))))
 639           (when (eq 'not-versioned current-bzr-state)
 640             (let ((file (expand-file-name
 641                          (buffer-substring-no-properties
 642                           (match-end 0) (line-end-position))
 643                          bzr-root-directory)))
 644               (vc-file-setprop file 'vc-backend 'none)
 645               (vc-file-setprop file 'vc-state nil))))
 646          (t
 647           ;; skip this part of `bzr status' output
 648           (setq current-vc-state nil)
 649           (setq current-bzr-state nil)))))))
 650
 651 (defun vc-bzr-dired-state-info (file)
 652   "Bzr-specific version of `vc-dired-state-info'."
 653   (if (eq 'edited (vc-state file))
 654         (concat "(" (symbol-name (or (vc-file-getprop file 'vc-bzr-state)
 655                                      'edited)) ")")
 656     ;; else fall back to default vc.el representation
 657     (vc-default-dired-state-info 'Bzr file)))
 658
 659 ;; XXX: this needs testing, it's probably incomplete.
 660 (defun vc-bzr-after-dir-status (update-function)
 661   (let ((status-str nil)
 662         (file nil)
 663         (translation '(("+N" . added)
 664                        ("-D" . removed)
 665                        (" M" . edited)
 666                        ;; XXX: what about ignored files?
 667                        (" D" . missing)
 668                        ("C " . conflict)
 669                        ("? " . unregistered)))
 670         (translated nil)
 671         (result nil))
 672       (goto-char (point-min))
 673       (while (not (eobp))
 674         (setq status-str
 675               (buffer-substring-no-properties (point) (+ (point) 2)))
 676         (setq translated (cdr (assoc status-str translation)))
 677         ;; For conflicts the file appears twice in the listing: once
 678         ;; with the M flag and once with the C flag, so take care not
 679         ;; to add it twice to `result'.  Ugly.
 680         (if (eq translated 'conflict)
 681             (let* ((file
 682                     (buffer-substring-no-properties
 683                      ;;For files with conflicts the format is:
 684                      ;;C   Text conflict in FILENAME
 685                      ;; Bah.
 686                      (+ (point) 21) (line-end-position)))
 687                    (entry (assoc file result)))
 688               (when entry
 689                 (setf (nth 1 entry) 'conflict)))
 690           (push (list (buffer-substring-no-properties
 691                        (+ (point) 4)
 692                        (line-end-position))
 693                       translated) result))
 694         (forward-line))
 695       (funcall update-function result)))
 696
 697 ;; XXX Experimental function for the vc-dired replacement.
 698 ;; XXX This probably needs some further refinement and testing.
 699 (defun vc-bzr-dir-status (dir update-function)
 700   "Return a list of conses (file . state) for DIR."
 701   ;; XXX: Is this the right command to use?
 702   (vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S")
 703   (vc-exec-after
 704    `(vc-bzr-after-dir-status (quote ,update-function))))
 705
 706 ;;; Revision completion
 707
 708 (defun vc-bzr-revision-completion-table (files)
 709   (lexical-let ((files files))
 710     ;; What about using `files'?!?  --Stef
 711     (lambda (string pred action)
 712       (cond
 713        ((string-match "\\`\\(ancestor\\|branch\\|\\(revno:\\)?[-0-9]+:\\):"
 714                       string)
 715         (completion-table-with-context (substring string 0 (match-end 0))
 716                                        'read-file-name-internal
 717                                        (substring string (match-end 0))
 718                                        ;; Dropping `pred'.   Maybe we should
 719                                        ;; just stash it in
 720                                        ;; `read-file-name-predicate'?
 721                                        nil
 722                                        action))
 723        ((string-match "\\`\\(before\\):" string)
 724         (completion-table-with-context (substring string 0 (match-end 0))
 725                                        (vc-bzr-revision-completion-table files)
 726                                        (substring string (match-end 0))
 727                                        pred
 728                                        action))
 729        ((string-match "\\`\\(tag\\):" string)
 730         (let ((prefix (substring string 0 (match-end 0)))
 731               (tag (substring string (match-end 0)))
 732               (table nil))
 733           (with-temp-buffer
 734             ;; "bzr-1.2 tags" is much faster with --show-ids.
 735             (call-process vc-bzr-program nil '(t) nil "tags" "--show-ids")
 736             ;; The output is ambiguous, unless we assume that revids do not
 737             ;; contain spaces.
 738             (goto-char (point-min))
 739             (while (re-search-forward "^\\(.*[^ \n]\\) +[^ \n]*$" nil t)
 740               (push (match-string-no-properties 1) table)))
 741           (completion-table-with-context prefix table tag pred action)))
 742
 743        ((string-match "\\`\\(revid\\):" string)
 744         ;; FIXME: How can I get a list of revision ids?
 745         )
 746        (t
 747         (complete-with-action action '("revno:" "revid:" "last:" "before:"
 748                                        "tag:" "date:" "ancestor:" "branch:"
 749                                        "submit:")
 750                               string pred))))))
 751
 752 (eval-after-load "vc"
 753   '(add-to-list 'vc-directory-exclusion-list vc-bzr-admin-dirname t))
 754
 755 (provide 'vc-bzr)
 756 ;; arch-tag: 8101bad8-4e92-4e7d-85ae-d8e08b4e7c06
 757 ;;; vc-bzr.el ends here