nt/configure.bat

   1 @echo off
   2 rem   ----------------------------------------------------------------------
   3 rem   Configuration script for MS Windows 95/98/Me and NT/2000/XP
   4 rem   Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005,
   5 rem      2006, 2007, 2008 Free Software Foundation, Inc.
   6
   7 rem   This file is part of GNU Emacs.
   8
   9 rem   GNU Emacs is free software; you can redistribute it and/or modify
  10 rem   it under the terms of the GNU General Public License as published by
  11 rem   the Free Software Foundation; either version 3, or (at your option)
  12 rem   any later version.
  13
  14 rem   GNU Emacs is distributed in the hope that it will be useful,
  15 rem   but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 rem   GNU General Public License for more details.
  18
  19 rem   You should have received a copy of the GNU General Public License
  20 rem   along with GNU Emacs; see the file COPYING.  If not, write to the
  21 rem   Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 rem   Boston, MA 02110-1301, USA.
  23 rem   ----------------------------------------------------------------------
  24 rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:
  25 rem
  26 rem   + MS Windows 95/98/Me or NT/2000/XP
  27 rem   + either MSVC 2.x or later, or gcc-2.95 or later (with GNU make 3.75
  28 rem     or later) and the Mingw32 and W32 API headers and libraries.
  29 rem   + Visual Studio 2005 is not supported at this time.
  30 rem
  31 rem For reference, here is a list of which builds of GNU make are known to
  32 rem work or not, and whether they work in the presence and/or absence of
  33 rem sh.exe.
  34 rem
  35 rem                                       sh exists     no sh
  36 rem  cygwin b20.1 make (3.75):            fails[1,5]    fails[2,5]
  37 rem  MSVC compiled gmake 3.77:            okay          okay
  38 rem  MSVC compiled gmake 3.78.1:          okay          okay
  39 rem  MSVC compiled gmake 3.79.1:          okay          okay
  40 rem  mingw32/gcc-2.92.2 make (3.77):      okay          okay[4]
  41 rem  cygwin compiled gmake 3.77:          fails[1,5]    fails[2,5]
  42 rem  cygwin compiled gmake 3.78.1:        fails[5]      fails[2,5]
  43 rem  cygwin compiled gmake 3.79.1:        fails[3,5]    fails[2?,5]
  44 rem  cygwin compiled make 3.80:           okay[6]       fails?[7]
  45 rem  cygwin compiled make 3.81:           fails         fails?[7]
  46 rem  mingw32 compiled make 3.79.1:        okay          okay
  47 rem  mingw32 compiled make 3.80:          okay          okay?[7]
  48 rem  mingw32 compiled make 3.81:          okay          okay[8]
  49 rem
  50 rem [1] doesn't cope with makefiles with DOS line endings, so must mount
  51 rem     emacs source with text!=binary.
  52 rem [2] fails when needs to invoke shell commands; okay invoking gcc etc.
  53 rem [3] requires LC_MESSAGES support to build; cannot build with early
  54 rem     versions of cygwin.
  55 rem [4] may fail on Windows 9X and Windows ME; if so, install Bash.
  56 rem [5] fails when building leim due to the use of cygwin style paths.
  57 rem     May work if building emacs without leim.
  58 rem [6] need to uncomment 3 lines in nt/gmake.defs that invoke `cygpath';
  59 rem     look for "cygpath" near line 85 of gmake.defs.
  60 rem [7] not recommended; please report if you try this combination.
  61 rem [8] tested only on Windows XP.
  62 rem
  63
  64 if exist config.log del config.log
  65
  66 rem ----------------------------------------------------------------------
  67 rem   See if the environment is large enough.  We need 43 (?) bytes.
  68 set $foo$=123456789_123456789_123456789_123456789_123
  69 if not "%$foo$%" == "123456789_123456789_123456789_123456789_123" goto SmallEnv
  70 set $foo$=
  71
  72 rem ----------------------------------------------------------------------
  73 rem   Make sure we are running in the nt subdir
  74 if exist configure.bat goto start
  75 echo You must run configure from the nt subdirectory.
  76 goto end
  77
  78 :start
  79 rem ----------------------------------------------------------------------
  80 rem   Default settings.
  81 set prefix=
  82 set nodebug=N
  83 set noopt=N
  84 set nocygwin=N
  85 set COMPILER=
  86 set usercflags=
  87 set docflags=
  88 set userldflags=
  89 set doldflags=
  90 set sep1=
  91 set sep2=
  92 set usefontbackend=Y
  93
  94 rem ----------------------------------------------------------------------
  95 rem   Handle arguments.
  96 :again
  97 if "%1" == "-h" goto usage
  98 if "%1" == "--help" goto usage
  99 if "%1" == "--prefix" goto setprefix
 100 if "%1" == "--with-gcc" goto withgcc
 101 if "%1" == "--with-msvc" goto withmsvc
 102 if "%1" == "--no-debug" goto nodebug
 103 if "%1" == "--no-opt" goto noopt
 104 if "%1" == "--no-cygwin" goto nocygwin
 105 if "%1" == "--cflags" goto usercflags
 106 if "%1" == "--ldflags" goto userldflags
 107 if "%1" == "--without-png" goto withoutpng
 108 if "%1" == "--without-jpeg" goto withoutjpeg
 109 if "%1" == "--without-gif" goto withoutgif
 110 if "%1" == "--without-tiff" goto withouttiff
 111 if "%1" == "--without-xpm" goto withoutxpm
 112 if "%1" == "--disable-font-backend" goto withoutfont
 113 if "%1" == "" goto checkutils
 114 :usage
 115 echo Usage: configure [options]
 116 echo Options:
 117 echo.   --prefix PREFIX         install Emacs in directory PREFIX
 118 echo.   --with-gcc              use GCC to compile Emacs
 119 echo.   --with-msvc             use MSVC to compile Emacs
 120 echo.   --no-debug              exclude debug info from executables
 121 echo.   --no-opt                disable optimization
 122 echo.   --no-cygwin             use -mno-cygwin option with GCC
 123 echo.   --cflags FLAG           pass FLAG to compiler
 124 echo.   --ldflags FLAG          pass FLAG to compiler when linking
 125 echo.   --without-png           do not use PNG library even if it is installed
 126 echo.   --without-jpeg          do not use JPEG library even if it is installed
 127 echo.   --without-gif           do not use GIF library even if it is installed
 128 echo.   --without-tiff          do not use TIFF library even if it is installed
 129 echo.   --without-xpm           do not use XPM library even if it is installed
 130 echo.   --disable-font-backend  build without font backend support
 131 goto end
 132 rem ----------------------------------------------------------------------
 133 :setprefix
 134 shift
 135 set prefix=%1
 136 shift
 137 goto again
 138 rem ----------------------------------------------------------------------
 139 :withgcc
 140 set COMPILER=gcc
 141 shift
 142 goto again
 143 rem ----------------------------------------------------------------------
 144 :withmsvc
 145 set COMPILER=cl
 146 shift
 147 goto again
 148 rem ----------------------------------------------------------------------
 149 :nodebug
 150 set nodebug=Y
 151 shift
 152 goto again
 153 rem ----------------------------------------------------------------------
 154 :noopt
 155 set noopt=Y
 156 shift
 157 goto again
 158 rem ----------------------------------------------------------------------
 159 :nocygwin
 160 set nocygwin=Y
 161 shift
 162 goto again
 163 rem ----------------------------------------------------------------------
 164 :usercflags
 165 shift
 166 set usercflags=%usercflags%%sep1%%1
 167 set sep1= %nothing%
 168 shift
 169 goto again
 170 rem ----------------------------------------------------------------------
 171 :userldflags
 172 shift
 173 set userldflags=%userldflags%%sep2%%1
 174 set sep2= %nothing%
 175 shift
 176 goto again
 177 rem ----------------------------------------------------------------------
 178
 179 :withoutpng
 180 set pngsupport=N
 181 set HAVE_PNG=
 182 shift
 183 goto again
 184
 185 rem ----------------------------------------------------------------------
 186
 187 :withoutjpeg
 188 set jpegsupport=N
 189 set HAVE_JPEG=
 190 shift
 191 goto again
 192
 193 rem ----------------------------------------------------------------------
 194
 195 :withoutgif
 196 set gifsupport=N
 197 set HAVE_GIF=
 198 shift
 199 goto again
 200
 201 rem ----------------------------------------------------------------------
 202
 203 :withouttiff
 204 set tiffsupport=N
 205 set HAVE_TIFF=
 206 shift
 207 goto again
 208
 209 rem ----------------------------------------------------------------------
 210
 211 :withoutxpm
 212 set xpmsupport=N
 213 set HAVE_XPM=
 214 shift
 215 goto again
 216
 217 :withoutfont
 218 set usefontbackend=N
 219 shift
 220 goto again
 221
 222 rem ----------------------------------------------------------------------
 223 rem    Check that necessary utilities (cp and rm) are present.
 224 :checkutils
 225 echo Checking for 'cp'...
 226 cp configure.bat junk.bat
 227 if not exist junk.bat goto needcp
 228 echo Checking for 'rm'...
 229 rm junk.bat
 230 if exist junk.bat goto needrm
 231 goto checkcompiler
 232 :needcp
 233 echo You need 'cp' (the Unix file copy program) to build Emacs.
 234 goto end
 235 :needrm
 236 del junk.bat
 237 echo You need 'rm' (the Unix file delete program) to build Emacs.
 238 goto end
 239
 240 rem ----------------------------------------------------------------------
 241 rem   Auto-detect compiler if not specified, and validate GCC if chosen.
 242 :checkcompiler
 243 if (%COMPILER%)==(cl) goto compilercheckdone
 244 if (%COMPILER%)==(gcc) goto checkgcc
 245
 246 echo Checking whether 'gcc' is available...
 247 echo main(){} >junk.c
 248 gcc -c junk.c
 249 if exist junk.o goto checkgcc
 250
 251 echo Checking whether 'cl' is available...
 252 cl -nologo -c junk.c
 253 if exist junk.obj goto clOK
 254 goto nocompiler
 255
 256 :checkgcc
 257 if exist junk.o del junk.o
 258 Rem WARNING -- COMMAND.COM on some systems only looks at the first
 259 Rem            8 characters of a label.  So do NOT be tempted to change
 260 Rem            chkapi* into something fancier like checkw32api
 261 Rem You HAVE been warned!
 262 if (%nocygwin%) == (Y) goto chkapiN
 263 echo Checking whether gcc requires '-mno-cygwin'...
 264 echo #include "cygwin/version.h" >junk.c
 265 echo main(){} >>junk.c
 266 echo gcc -c junk.c >>config.log
 267 gcc -c junk.c >>config.log 2>&1
 268 if not exist junk.o goto chkapi
 269 echo gcc -mno-cygwin -c junk.c >>config.log
 270 gcc -mno-cygwin -c junk.c >>config.log 2>&1
 271 if exist junk.o set nocygwin=Y
 272
 273 :chkapi
 274 echo The failed program was: >>config.log
 275 type junk.c >>config.log
 276 :chkapiN
 277 rm -f junk.c junk.o
 278 rem ----------------------------------------------------------------------
 279 rem   Older versions of the Windows API headers either don't have any of
 280 rem   the IMAGE_xxx definitions (the headers that come with Cygwin b20.1
 281 rem   are like this), or have a typo in the definition of
 282 rem   IMAGE_FIRST_SECTION (the headers with gcc/mingw32 2.95 have this
 283 rem   problem).  The gcc/mingw32 2.95.2 headers are okay, as are distros
 284 rem   of w32api-xxx.zip from Anders Norlander since 1999-11-18 at least.
 285 rem   Beginning with Emacs 23, we need usp10.h.
 286 rem
 287 echo Checking whether W32 API headers are too old...
 288 echo #include "windows.h" >junk.c
 289 echo #include "usp10.h" >>junk.c
 290 echo test(PIMAGE_NT_HEADERS pHeader) >>junk.c
 291 echo {PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader);} >>junk.c
 292 if (%nocygwin%) == (Y) goto chkapi1
 293 set cf=%usercflags%
 294 goto chkapi2
 295 :chkapi1
 296 set cf=%usercflags% -mno-cygwin
 297 :chkapi2
 298 echo on
 299 gcc %cf% -c junk.c
 300 @echo off
 301 @echo gcc %cf% -c junk.c >>config.log
 302 gcc %cf% -c junk.c >>config.log 2>&1
 303 set cf=
 304 if exist junk.o goto gccOk
 305 echo The failed program was: >>config.log
 306 type junk.c >>config.log
 307
 308 :nocompiler
 309 echo.
 310 echo Configure failed.
 311 echo To configure Emacs for Windows, you need to have either
 312 echo gcc-2.95 or later with Mingw32 and the W32 API headers,
 313 echo or MSVC 2.x or later.
 314 del junk.c
 315 goto end
 316
 317 :gccOk
 318 set COMPILER=gcc
 319 echo Using 'gcc'
 320 rm -f junk.c junk.o
 321 Rem It is not clear what GCC version began supporting -mtune
 322 Rem and pentium4 on x86, so check this explicitly.
 323 echo main(){} >junk.c
 324 echo gcc -c -O2 -mtune=pentium4 junk.c >>config.log
 325 gcc -c -O2 -mtune=pentium4 junk.c >>config.log 2>&1
 326 if not errorlevel 1 goto gccMtuneOk
 327 echo The failed program was: >>config.log
 328 type junk.c >>config.log
 329 set mf=-mcpu=i686
 330 rm -f junk.c junk.o
 331 goto compilercheckdone
 332 :gccMtuneOk
 333 echo GCC supports -mtune=pentium4 >>config.log
 334 set mf=-mtune=pentium4
 335 rm -f junk.c junk.o
 336 goto compilercheckdone
 337
 338 :clOk
 339 set COMPILER=cl
 340 rm -f junk.c junk.obj
 341 echo Using 'MSVC'
 342
 343 :compilercheckdone
 344
 345 rem ----------------------------------------------------------------------
 346 rem   Check for external image libraries. Since they are loaded
 347 rem   dynamically, the libraries themselves do not need to be present
 348 rem   at compile time, but the header files are required.
 349
 350 set mingwflag=
 351
 352 if (%nocygwin%) == (N) goto flagsOK
 353 set mingwflag=-mno-cygwin
 354
 355 :flagsOK
 356
 357 if (%pngsupport%) == (N) goto pngDone
 358
 359 echo Checking for libpng...
 360 echo #include "png.h" >junk.c
 361 echo main (){} >>junk.c
 362 rem   -o option is ignored with cl, but allows result to be consistent.
 363 echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log
 364 %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log
 365 if exist junk.obj goto havePng
 366
 367 echo ...png.h not found, building without PNG support.
 368 echo The failed program was: >>config.log
 369 type junk.c >>config.log
 370 set HAVE_PNG=
 371 goto :pngDone
 372
 373 :havePng
 374 echo ...PNG header available, building with PNG support.
 375 set HAVE_PNG=1
 376
 377 :pngDone
 378 rm -f junk.c junk.obj
 379
 380 if (%jpegsupport%) == (N) goto jpegDone
 381
 382 echo Checking for jpeg-6b...
 383 echo #include "jconfig.h" >junk.c
 384 echo main (){} >>junk.c
 385 rem   -o option is ignored with cl, but allows result to be consistent.
 386 echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log
 387 %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log
 388 if exist junk.obj goto haveJpeg
 389
 390 echo ...jconfig.h not found, building without JPEG support.
 391 echo The failed program was: >>config.log
 392 type junk.c >>config.log
 393 set HAVE_JPEG=
 394 goto :jpegDone
 395
 396 :haveJpeg
 397 echo ...JPEG header available, building with JPEG support.
 398 set HAVE_JPEG=1
 399
 400 :jpegDone
 401 rm -f junk.c junk.obj
 402
 403 if (%gifsupport%) == (N) goto gifDone
 404
 405 echo Checking for libgif...
 406 echo #include "gif_lib.h" >junk.c
 407 echo main (){} >>junk.c
 408 rem   -o option is ignored with cl, but allows result to be consistent.
 409 echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log
 410 %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log
 411 if exist junk.obj goto haveGif
 412
 413 echo ...gif_lib.h not found, building without GIF support.
 414 echo The failed program was: >>config.log
 415 type junk.c >>config.log
 416 set HAVE_GIF=
 417 goto :gifDone
 418
 419 :haveGif
 420 echo ...GIF header available, building with GIF support.
 421 set HAVE_GIF=1
 422
 423 :gifDone
 424 rm -f junk.c junk.obj
 425
 426 if (%tiffsupport%) == (N) goto tiffDone
 427
 428 echo Checking for tiff...
 429 echo #include "tiffio.h" >junk.c
 430 echo main (){} >>junk.c
 431 rem   -o option is ignored with cl, but allows result to be consistent.
 432 echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log
 433 %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log
 434 if exist junk.obj goto haveTiff
 435
 436 echo ...tiffio.h not found, building without TIFF support.
 437 echo The failed program was: >>config.log
 438 type junk.c >>config.log
 439 set HAVE_TIFF=
 440 goto :tiffDone
 441
 442 :haveTiff
 443 echo ...TIFF header available, building with TIFF support.
 444 set HAVE_TIFF=1
 445
 446 :tiffDone
 447 rm -f junk.c junk.obj
 448
 449 if (%xpmsupport%) == (N) goto xpmDone
 450
 451 echo Checking for libXpm...
 452 echo #define FOR_MSW 1 >junk.c
 453 echo #include "X11/xpm.h" >>junk.c
 454 echo main (){} >>junk.c
 455 rem   -o option is ignored with cl, but allows result to be consistent.
 456 echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log
 457 %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log
 458 if exist junk.obj goto haveXpm
 459
 460 echo ...X11/xpm.h not found, building without XPM support.
 461 echo The failed program was: >>config.log
 462 type junk.c >>config.log
 463 set HAVE_XPM=
 464 goto :xpmDone
 465
 466 :haveXpm
 467 echo ...XPM header available, building with XPM support.
 468 set HAVE_XPM=1
 469
 470 :xpmDone
 471 rm -f junk.c junk.obj junk.err junk.out
 472
 473 rem ----------------------------------------------------------------------
 474 :genmakefiles
 475 echo Generating makefiles
 476 if %COMPILER% == gcc set MAKECMD=gmake
 477 if %COMPILER% == cl set MAKECMD=nmake
 478
 479 rem   Pass on chosen settings to makefiles.
 480 rem   NB. Be very careful to not have a space before redirection symbols
 481 rem   except when there is a preceding digit, when a space is required.
 482 rem
 483 echo # Start of settings from configure.bat >config.settings
 484 echo COMPILER=%COMPILER%>>config.settings
 485 if not "(%mf%)" == "()" echo MCPU_FLAG=%mf%>>config.settings
 486 if (%nodebug%) == (Y) echo NODEBUG=1 >>config.settings
 487 if (%noopt%) == (Y) echo NOOPT=1 >>config.settings
 488 if (%nocygwin%) == (Y) echo NOCYGWIN=1 >>config.settings
 489 if not "(%prefix%)" == "()" echo INSTALL_DIR=%prefix%>>config.settings
 490 rem We go thru docflags because usercflags could be "-DFOO=bar" -something
 491 rem and the if command cannot cope with this
 492 for %%v in (%usercflags%) do if not (%%v)==() set docflags=Y
 493 if (%docflags%)==(Y) echo USER_CFLAGS=%usercflags%>>config.settings
 494 for %%v in (%userldflags%) do if not (%%v)==() set doldflags=Y
 495 if (%doldflags%)==(Y) echo USER_LDFLAGS=%userldflags%>>config.settings
 496 if (%usefontbackend%) == (Y) echo USE_FONTBACKEND=1 >>config.settings
 497 echo # End of settings from configure.bat>>config.settings
 498 echo. >>config.settings
 499
 500 copy config.nt config.tmp
 501 echo. >>config.tmp
 502 echo /* Start of settings from configure.bat.  */ >>config.tmp
 503 if (%docflags%) == (Y) echo #define USER_CFLAGS " %usercflags%">>config.tmp
 504 if (%doldflags%) == (Y) echo #define USER_LDFLAGS " %userldflags%">>config.tmp
 505 if not "(%HAVE_PNG%)" == "()" echo #define HAVE_PNG 1 >>config.tmp
 506 if not "(%HAVE_JPEG%)" == "()" echo #define HAVE_JPEG 1 >>config.tmp
 507 if not "(%HAVE_GIF%)" == "()" echo #define HAVE_GIF 1 >>config.tmp
 508 if not "(%HAVE_TIFF%)" == "()" echo #define HAVE_TIFF 1 >>config.tmp
 509 if not "(%HAVE_XPM%)" == "()" echo #define HAVE_XPM 1 >>config.tmp
 510 echo /* End of settings from configure.bat.  */ >>config.tmp
 511
 512 Rem See if fc.exe returns a meaningful exit status.  If it does, we
 513 Rem might as well avoid unnecessary overwriting of config.h and epaths.h,
 514 Rem since this forces recompilation of every source file.
 515 if exist foo.bar del foo.bar
 516 fc /b foo.bar foo.bar >nul 2>&1
 517 if not errorlevel 2 goto doCopy
 518 fc /b config.tmp ..\src\config.h >nul 2>&1
 519 if errorlevel 1 goto doCopy
 520 fc /b paths.h ..\src\epaths.h >nul 2>&1
 521 if errorlevel 0 goto dontCopy
 522 :doCopy
 523 copy config.tmp ..\src\config.h
 524 copy paths.h ..\src\epaths.h
 525
 526 :dontCopy
 527 if exist config.tmp del config.tmp
 528 copy /b config.settings+%MAKECMD%.defs+..\nt\makefile.w32-in ..\nt\makefile
 529 if exist ..\admin\unidata copy /b config.settings+%MAKECMD%.defs+..\admin\unidata\makefile.w32-in ..\admin\unidata\makefile
 530 copy /b config.settings+%MAKECMD%.defs+..\lib-src\makefile.w32-in ..\lib-src\makefile
 531 copy /b config.settings+%MAKECMD%.defs+..\src\makefile.w32-in ..\src\makefile
 532 copy /b config.settings+%MAKECMD%.defs+..\doc\emacs\makefile.w32-in ..\doc\emacs\makefile
 533 copy /b config.settings+%MAKECMD%.defs+..\doc\misc\makefile.w32-in ..\doc\misc\makefile
 534 copy /b config.settings+%MAKECMD%.defs+..\doc\lispref\makefile.w32-in ..\doc\lispref\makefile
 535 copy /b config.settings+%MAKECMD%.defs+..\doc\lispintro\makefile.w32-in ..\doc\lispintro\makefile
 536 if exist ..\lisp\makefile rm -f ../lisp/[Mm]akefile
 537 copy /b config.settings+%MAKECMD%.defs+..\lisp\makefile.w32-in ..\lisp\makefile
 538 rem   Use the default (no-op) Makefile.in if the nt version is not present.
 539 if exist ..\leim\makefile.w32-in copy /b config.settings+%MAKECMD%.defs+..\leim\makefile.w32-in ..\leim\makefile
 540 if not exist ..\leim\makefile.w32-in copy /b config.settings+%MAKECMD%.defs+..\leim\Makefile.in ..\leim\makefile
 541 del config.settings
 542
 543 Rem Some people use WinZip which doesn't create empty directories!
 544 if not exist ..\site-lisp\nul mkdir ..\site-lisp\
 545 Rem Update subdirs.el only if it is different or fc.exe doesn't work.
 546 if exist foo.bar del foo.bar
 547 fc /b foo.bar foo.bar >nul 2>&1
 548 if not errorlevel 2 goto doUpdateSubdirs
 549 fc /b subdirs.el ..\site-lisp\subdirs.el >nul 2>&1
 550 if not errorlevel 1 goto dontUpdateSubdirs
 551 :doUpdateSubdirs
 552 if exist ..\site-lisp\subdirs.el del ..\site-lisp\subdirs.el
 553 copy subdirs.el ..\site-lisp\subdirs.el
 554
 555 :dontUpdateSubdirs
 556 echo.
 557
 558 rem check that we have all the libraries we need.
 559 set libsOK=1
 560
 561 if not "(%HAVE_XPM%)" == "()" goto checkpng
 562 if (%xpmsupport%) == (N) goto checkpng
 563  set libsOK=0
 564  echo XPM support is missing. It is required for color icons in the toolbar.
 565  echo   Install libXpm development files or use --without-xpm
 566
 567 :checkpng
 568 if not "(%HAVE_PNG%)" == "()" goto checkjpeg
 569 if (%pngsupport%) == (N) goto checkjpeg
 570  set libsOK=0
 571  echo PNG support is missing.
 572  echo   Install libpng development files or use --without-png
 573
 574 :checkjpeg
 575 if not "(%HAVE_JPEG%)" == "()" goto checktiff
 576 if (%jpegsupport%) == (N) goto checktiff
 577  set libsOK=0
 578  echo JPEG support is missing.
 579  echo   Install jpeg development files or use --without-jpeg
 580
 581 :checktiff
 582 if not "(%HAVE_TIFF%)" == "()" goto checkgif
 583 if (%tiffsupport%) == (N) goto checkgif
 584  set libsOK=0
 585  echo TIFF support is missing.
 586  echo   Install libtiff development files or use --without-tiff
 587
 588 :checkgif
 589 if not "(%HAVE_GIF%)" == "()" goto donelibchecks
 590 if (%gifsupport%) == (N) goto donelibchecks
 591  set libsOK=0
 592  echo GIF support is missing.
 593  echo   Install giflib or libungif development files or use --without-gif
 594
 595 :donelibchecks
 596 if (%libsOK%) == (1) goto success
 597 echo.
 598 echo Important libraries are missing. Fix these issues before running make.
 599 goto end
 600
 601 :success
 602 echo Emacs successfully configured.
 603 echo Emacs successfully configured. >>config.log
 604 if (%MAKECMD%) == (gmake) set MAKECMD=make
 605 echo Run `%MAKECMD%' to build, then run `%MAKECMD% install' to install.
 606 goto end
 607
 608 :SmallEnv
 609 echo Your environment size is too small.  Please enlarge it and rerun configure.
 610 echo For example, type "command.com /e:2048" to have 2048 bytes available.
 611 set $foo$=
 612 :end
 613 set prefix=
 614 set nodebug=
 615 set noopt=
 616 set nocygwin=
 617 set COMPILER=
 618 set MAKECMD=
 619 set usercflags=
 620 set docflags=
 621 set userldflags=
 622 set doldflags=
 623 set mingwflag=
 624 set mf=
 625
 626 goto skipArchTag
 627    arch-tag: 300d20a4-1675-4e75-b615-7ce1a8c5376c
 628 :skipArchTag