lisp/emacs-lisp/re-builder.el

   1 ;;; re-builder.el --- building Regexps with visual feedback
   2
   3 ;; Copyright (C) 1999, 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Detlev Zundel <dzu@gnu.org>
   6 ;; Keywords: matching, lisp, tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; When I have to come up with regular expressions that are more
  28 ;; complex than simple string matchers, especially if they contain sub
  29 ;; expressions, I find myself spending quite some time in the
  30 ;; `development cycle'.  `re-builder' aims to shorten this time span
  31 ;; so I can get on with the more interesting bits.
  32
  33 ;; With it you can have immediate visual feedback about how well the
  34 ;; regexp behaves to your expectations on the intended data.
  35
  36 ;; When called up `re-builder' attaches itself to the current buffer
  37 ;; which becomes its target buffer, where all the matching is done.
  38 ;; The active window is split so you have a view on the data while
  39 ;; authoring the RE.  If the edited expression is valid the matches in
  40 ;; the target buffer are marked automatically with colored overlays
  41 ;; (for non-color displays see below) giving you feedback over the
  42 ;; extents of the matched (sub) expressions.  The (non-)validity is
  43 ;; shown only in the modeline without throwing the errors at you.  If
  44 ;; you want to know the reason why RE Builder considers it as invalid
  45 ;; call `reb-force-update' ("\C-c\C-u") which should reveal the error.
  46
  47 ;; The target buffer can be changed with `reb-change-target-buffer'
  48 ;; ("\C-c\C-b").  Changing the target buffer automatically removes
  49 ;; the overlays from the old buffer and displays the new one in the
  50 ;; target window.
  51
  52 ;; The `re-builder' keeps the focus while updating the matches in the
  53 ;; target buffer so corrections are easy to incorporate.  If you are
  54 ;; satisfied with the result you can paste the RE to the kill-ring
  55 ;; with `reb-copy' ("\C-c\C-w"), quit the `re-builder' ("\C-c\C-q")
  56 ;; and use it wherever you need it.
  57
  58 ;; As the automatic updates can take some time on large buffers, they
  59 ;; can be limited by `reb-auto-match-limit' so that they should not
  60 ;; have a negative impact on the editing.  Setting it to nil makes
  61 ;; even the auto updates go all the way.  Forcing an update overrides
  62 ;; this limit allowing an easy way to see all matches.
  63
  64 ;; Currently `re-builder' understands four different forms of input,
  65 ;; namely `read', `string', `sregex' and `lisp-re' syntax.  Read
  66 ;; syntax and string syntax are both delimited by `"'s and behave
  67 ;; according to their name.  With the `string' syntax there's no need
  68 ;; to escape the backslashes and double quotes simplifying the editing
  69 ;; somewhat.  The other two allow editing of symbolic regular
  70 ;; expressions supported by the packages of the same name.  (`lisp-re'
  71 ;; is a package by me and its support may go away as it is nearly the
  72 ;; same as the `sregex' package in Emacs)
  73
  74 ;; Editing symbolic expressions is done through a major mode derived
  75 ;; from `emacs-lisp-mode' so you'll get all the good stuff like
  76 ;; automatic indentation and font-locking etc.
  77
  78 ;; When editing a symbolic regular expression, only the first
  79 ;; expression in the RE Builder buffer is considered, which helps
  80 ;; limiting the extent of the expression like the `"'s do for the text
  81 ;; modes.  For the `sregex' syntax the function `sregex' is applied to
  82 ;; the evaluated expression read.  So you can use quoted arguments
  83 ;; with something like '("findme") or you can construct arguments to
  84 ;; your hearts delight with a valid ELisp expression.  (The compiled
  85 ;; string form will be copied by `reb-copy')  If you want to take
  86 ;; a glance at the corresponding string you can temporarily change the
  87 ;; input syntax.
  88
  89 ;; Changing the input syntax is transparent (for the obvious exception
  90 ;; non-symbolic -> symbolic) so you can change your mind as often as
  91 ;; you like.
  92
  93 ;; There is also a shortcut function for toggling the
  94 ;; `case-fold-search' variable in the target buffer with an immediate
  95 ;; update.
  96
  97
  98 ;; Q: But what if my display cannot show colored overlays?
  99 ;; A: Then the cursor will flash around the matched text making it stand
 100 ;;    out.
 101
 102 ;; Q: But how can I then make out the sub-expressions?
 103 ;; A: Thats where the `sub-expression mode' comes in.  In it only the
 104 ;;    digit keys are assigned to perform an update that will flash the
 105 ;;    corresponding subexp only.
 106
 107
 108 ;;; Code:
 109
 110 ;; On XEmacs, load the overlay compatibility library
 111 (if (not (fboundp 'make-overlay))
 112     (require 'overlay))
 113
 114 ;; User costomizable variables
 115 (defgroup re-builder nil
 116   "Options for the RE Builder."
 117   :group 'lisp
 118   :prefix "reb-")
 119
 120 (defcustom reb-blink-delay 0.5
 121   "*Seconds to blink cursor for next/previous match in RE Builder."
 122   :group 're-builder
 123   :type 'number)
 124
 125 (defcustom reb-mode-hook nil
 126   "*Hooks to run on entering RE Builder mode."
 127   :group 're-builder
 128   :type 'hook)
 129
 130 (defcustom reb-re-syntax 'read
 131   "*Syntax for the REs in the RE Builder.
 132 Can either be `read', `string', `sregex' or `lisp-re'."
 133   :group 're-builder
 134   :type '(choice (const :tag "Read syntax" read)
 135                  (const :tag "String syntax" string)
 136                  (const :tag "`sregex' syntax" sregex)
 137                  (const :tag "`lisp-re' syntax" lisp-re)
 138                  (const :tag "`rx' syntax" rx)
 139                  (value: string)))
 140
 141 (defcustom reb-auto-match-limit 200
 142   "*Positive integer limiting the matches for RE Builder auto updates.
 143 Set it to nil if you don't want limits here."
 144   :group 're-builder
 145   :type '(restricted-sexp :match-alternatives
 146                           (integerp 'nil)))
 147
 148
 149 (defface reb-match-0
 150   '((((class color) (background light))
 151      :background "lightblue")
 152     (((class color) (background dark))
 153      :background "steelblue4")
 154     (t
 155      :inverse-video t))
 156   "Used for displaying the whole match."
 157   :group 're-builder)
 158
 159 (defface reb-match-1
 160   '((((class color) (background light))
 161      :background "aquamarine")
 162     (((class color) (background dark))
 163      :background "blue3")
 164     (t
 165      :inverse-video t))
 166   "Used for displaying the first matching subexpression."
 167   :group 're-builder)
 168
 169 (defface reb-match-2
 170   '((((class color) (background light))
 171      :background "springgreen")
 172     (((class color) (background dark))
 173      :background "chartreuse4")
 174     (t
 175      :inverse-video t))
 176   "Used for displaying the second matching subexpression."
 177   :group 're-builder)
 178
 179 (defface reb-match-3
 180   '((((class color) (background light))
 181      :background "yellow")
 182     (((class color) (background dark))
 183      :background "sienna4")
 184     (t
 185      :inverse-video t))
 186   "Used for displaying the third matching subexpression."
 187   :group 're-builder)
 188
 189 ;; Internal variables below
 190 (defvar reb-mode nil
 191   "Enables the RE Builder minor mode.")
 192
 193 (defvar reb-target-buffer nil
 194   "Buffer to which the RE is applied to.")
 195
 196 (defvar reb-target-window nil
 197   "Window to which the RE is applied to.")
 198
 199 (defvar reb-regexp nil
 200   "Last regexp used by RE Builder.")
 201
 202 (defvar reb-regexp-src nil
 203   "Last regexp used by RE Builder before processing it.
 204 Except for Lisp syntax this is the same as `reb-regexp'.")
 205
 206 (defvar reb-overlays nil
 207   "List of overlays of the RE Builder.")
 208
 209 (defvar reb-window-config nil
 210   "Old window configuration.")
 211
 212 (defvar reb-subexp-mode nil
 213   "Indicates whether sub-exp mode is active.")
 214
 215 (defvar reb-subexp-displayed nil
 216   "Indicates which sub-exp is active.")
 217
 218 (defvar reb-mode-string ""
 219   "String in mode line for additional info.")
 220
 221 (defvar reb-valid-string ""
 222   "String in mode line showing validity of RE.")
 223
 224 (make-variable-buffer-local 'reb-overlays)
 225 (make-variable-buffer-local 'reb-regexp)
 226 (make-variable-buffer-local 'reb-regexp-src)
 227
 228 (defconst reb-buffer "*RE-Builder*"
 229   "Buffer to use for the RE Builder.")
 230
 231 ;; Define the local "\C-c" keymap
 232 (defvar reb-mode-map
 233   (let ((map (make-sparse-keymap)))
 234     (define-key map "\C-c\C-c" 'reb-toggle-case)
 235     (define-key map "\C-c\C-q" 'reb-quit)
 236     (define-key map "\C-c\C-w" 'reb-copy)
 237     (define-key map "\C-c\C-s" 'reb-next-match)
 238     (define-key map "\C-c\C-r" 'reb-prev-match)
 239     (define-key map "\C-c\C-i" 'reb-change-syntax)
 240     (define-key map "\C-c\C-e" 'reb-enter-subexp-mode)
 241     (define-key map "\C-c\C-b" 'reb-change-target-buffer)
 242     (define-key map "\C-c\C-u" 'reb-force-update)
 243     map)
 244   "Keymap used by the RE Builder.")
 245
 246 (defun reb-mode ()
 247   "Major mode for interactively building Regular Expressions.
 248 \\{reb-mode-map}"
 249   (interactive)
 250   (kill-all-local-variables)
 251   (setq major-mode 'reb-mode
 252         mode-name "RE Builder")
 253   (use-local-map reb-mode-map)
 254   (reb-mode-common)
 255   (run-hooks 'reb-mode-hook))
 256
 257 (define-derived-mode reb-lisp-mode
 258   emacs-lisp-mode "RE Builder Lisp"
 259   "Major mode for interactively building symbolic Regular Expressions."
 260   (cond ((eq reb-re-syntax 'lisp-re)    ; Pull in packages
 261          (require 'lisp-re))            ; as needed
 262         ((eq reb-re-syntax 'sregex)     ; sregex is not autoloaded
 263          (require 'sregex))             ; right now..
 264         ((eq reb-re-syntax 'rx)         ; rx-to-string is autoloaded
 265          (require 'rx)))                ; require rx anyway
 266   (reb-mode-common))
 267
 268 ;; Use the same "\C-c" keymap as `reb-mode' and use font-locking from
 269 ;; `emacs-lisp-mode'
 270 (define-key reb-lisp-mode-map "\C-c"
 271   (lookup-key reb-mode-map "\C-c"))
 272
 273 (defvar reb-subexp-mode-map
 274   (let ((m (make-keymap)))
 275     (suppress-keymap m)
 276     ;; Again share the "\C-c" keymap for the commands
 277     (define-key m "\C-c" (lookup-key reb-mode-map "\C-c"))
 278     (define-key m "q" 'reb-quit-subexp-mode)
 279     (dotimes (digit 10)
 280       (define-key m (int-to-string digit) 'reb-display-subexp))
 281     m)
 282   "Keymap used by the RE Builder for the subexpression mode.")
 283
 284 (defun reb-mode-common ()
 285   "Setup functions common to functions `reb-mode' and `reb-mode-lisp'."
 286
 287   (setq reb-mode-string  ""
 288         reb-valid-string ""
 289         mode-line-buffer-identification
 290                          '(25 . ("%b" reb-mode-string reb-valid-string)))
 291   (reb-update-modestring)
 292   (make-local-variable 'after-change-functions)
 293   (add-hook 'after-change-functions
 294             'reb-auto-update)
 295   ;; At least make the overlays go away if the buffer is killed
 296   (make-local-variable 'reb-kill-buffer)
 297   (add-hook 'kill-buffer-hook 'reb-kill-buffer)
 298   (reb-auto-update nil nil nil))
 299
 300
 301 ;; Handy macro for doing things in other windows
 302 (defmacro reb-with-current-window (window &rest body)
 303   "With WINDOW selected evaluate BODY forms and reselect previous window."
 304
 305   (let ((oldwindow (make-symbol "*oldwindow*")))
 306     `(let ((,oldwindow (selected-window)))
 307        (select-window ,window)
 308        (unwind-protect
 309            (progn
 310              ,@body)
 311          (select-window ,oldwindow)))))
 312 (put 'reb-with-current-window 'lisp-indent-function 0)
 313
 314 (defun reb-color-display-p ()
 315   "Return t if display is capable of displaying colors."
 316   (eq 'color
 317       ;; emacs/xemacs compatibility
 318       (if (fboundp 'frame-parameter)
 319           (frame-parameter (selected-frame) 'display-type)
 320         (frame-property (selected-frame) 'display-type))))
 321
 322 (defsubst reb-lisp-syntax-p ()
 323   "Return non-nil if RE Builder uses a Lisp syntax."
 324   (memq reb-re-syntax '(lisp-re sregex rx)))
 325
 326 (defmacro reb-target-binding (symbol)
 327   "Return binding for SYMBOL in the RE Builder target buffer."
 328   `(with-current-buffer reb-target-buffer ,symbol))
 329
 330
 331 ;;;###autoload
 332 (defun re-builder ()
 333   "Call up the RE Builder for the current window."
 334   (interactive)
 335
 336   (if (and (string= (buffer-name) reb-buffer)
 337            (memq major-mode '(reb-mode reb-lisp-mode)))
 338       (message "Already in the RE Builder")
 339     (if reb-target-buffer
 340         (reb-delete-overlays))
 341     (setq reb-target-buffer (current-buffer)
 342           reb-target-window (selected-window)
 343           reb-window-config (current-window-configuration))
 344     (select-window (split-window (selected-window) (- (window-height) 4)))
 345     (switch-to-buffer (get-buffer-create reb-buffer))
 346     (erase-buffer)
 347     (reb-insert-regexp)
 348     (goto-char (+ 2 (point-min)))
 349     (cond
 350      ((reb-lisp-syntax-p)
 351       (reb-lisp-mode))
 352      (t (reb-mode)))))
 353
 354 (defun reb-change-target-buffer (buf)
 355   "Change the target buffer and display it in the target window."
 356   (interactive "bSet target buffer to: ")
 357
 358   (let ((buffer (get-buffer buf)))
 359     (if (not buffer)
 360         (error "No such buffer")
 361       (reb-delete-overlays)
 362       (setq reb-target-buffer buffer)
 363       (reb-do-update
 364        (if reb-subexp-mode reb-subexp-displayed nil))
 365       (reb-update-modestring))))
 366
 367 (defun reb-force-update ()
 368   "Force an update in the RE Builder target window without a match limit."
 369   (interactive)
 370
 371   (let ((reb-auto-match-limit nil))
 372     (reb-update-overlays
 373      (if reb-subexp-mode reb-subexp-displayed nil))))
 374
 375 (defun reb-quit ()
 376   "Quit the RE Builder mode."
 377   (interactive)
 378
 379   (setq reb-subexp-mode nil
 380         reb-subexp-displayed nil)
 381   (reb-delete-overlays)
 382   (bury-buffer)
 383   (set-window-configuration reb-window-config))
 384
 385 (defun reb-next-match ()
 386   "Go to next match in the RE Builder target window."
 387   (interactive)
 388
 389   (reb-assert-buffer-in-window)
 390   (reb-with-current-window
 391     reb-target-window
 392     (if (not (re-search-forward reb-regexp (point-max) t))
 393         (message "No more matches.")
 394       (reb-show-subexp
 395        (or (and reb-subexp-mode reb-subexp-displayed) 0)
 396        t))))
 397
 398 (defun reb-prev-match ()
 399   "Go to previous match in the RE Builder target window."
 400   (interactive)
 401
 402   (reb-assert-buffer-in-window)
 403   (reb-with-current-window reb-target-window
 404     (goto-char (1- (point)))
 405     (if (not (re-search-backward reb-regexp (point-min) t))
 406         (message "No more matches.")
 407       (reb-show-subexp
 408        (or (and reb-subexp-mode reb-subexp-displayed) 0)
 409        t))))
 410
 411 (defun reb-toggle-case ()
 412   "Toggle case sensitivity of searches for RE Builder target buffer."
 413   (interactive)
 414
 415   (with-current-buffer reb-target-buffer
 416     (setq case-fold-search (not case-fold-search)))
 417   (reb-update-modestring)
 418   (reb-auto-update nil nil nil t))
 419
 420 (defun reb-copy ()
 421   "Copy current RE into the kill ring for later insertion."
 422   (interactive)
 423
 424   (reb-update-regexp)
 425   (let ((re (with-output-to-string
 426               (print (reb-target-binding reb-regexp)))))
 427     (kill-new (substring re 1 (1- (length re))))
 428     (message "Regexp copied to kill-ring")))
 429
 430 ;; The subexpression mode is not electric because the number of
 431 ;; matches should be seen rather than a prompt.
 432 (defun reb-enter-subexp-mode ()
 433   "Enter the subexpression mode in the RE Builder."
 434   (interactive)
 435   (setq reb-subexp-mode t)
 436   (reb-update-modestring)
 437   (use-local-map reb-subexp-mode-map)
 438   (message "`0'-`9' to display subexpressions  `q' to quit subexp mode."))
 439
 440 (defun reb-show-subexp (subexp &optional pause)
 441   "Visually show limit of subexpression SUBEXP of recent search.
 442 On color displays this just puts point to the end of the expression as
 443 the match should already be marked by an overlay.
 444 On other displays jump to the beginning and the end of it.
 445 If the optional PAUSE is non-nil then pause at the end in any case."
 446   (reb-with-current-window reb-target-window
 447     (if (not (reb-color-display-p))
 448         (progn (goto-char (match-beginning subexp))
 449                (sit-for reb-blink-delay)))
 450     (goto-char (match-end subexp))
 451     (if (or (not (reb-color-display-p)) pause)
 452         (sit-for reb-blink-delay))))
 453
 454 (defun reb-quit-subexp-mode ()
 455   "Quit the subexpression mode in the RE Builder."
 456   (interactive)
 457   (setq reb-subexp-mode nil
 458         reb-subexp-displayed nil)
 459   (reb-update-modestring)
 460   (use-local-map reb-mode-map)
 461   (reb-do-update))
 462
 463 (defun reb-change-syntax (&optional syntax)
 464   "Change the syntax used by the RE Builder.
 465 Optional argument SYNTAX must be specified if called non-interactively."
 466   (interactive
 467    (list (intern
 468           (completing-read "Select syntax: "
 469                            (mapcar (lambda (el) (cons (symbol-name el) 1))
 470                                    '(read string lisp-re sregex rx))
 471                            nil t (symbol-name reb-re-syntax)))))
 472
 473   (if (memq syntax '(read string lisp-re sregex rx))
 474       (let ((buffer (get-buffer reb-buffer)))
 475         (setq reb-re-syntax syntax)
 476         (if buffer
 477             (with-current-buffer buffer
 478               (erase-buffer)
 479               (reb-insert-regexp)
 480               (goto-char (+ 2 (point-min)))
 481               (cond ((reb-lisp-syntax-p)
 482                      (reb-lisp-mode))
 483                     (t (reb-mode))))))
 484     (error "Invalid syntax: %s" syntax)))
 485
 486
 487 ;; Non-interactive functions below
 488 (defun reb-do-update (&optional subexp)
 489   "Update matches in the RE Builder target window.
 490 If SUBEXP is non-nil mark only the corresponding sub-expressions."
 491
 492   (reb-assert-buffer-in-window)
 493   (reb-update-regexp)
 494   (reb-update-overlays subexp))
 495
 496 (defun reb-auto-update (beg end lenold &optional force)
 497   "Called from `after-update-functions' to update the display.
 498 BEG, END and LENOLD are passed in from the hook.
 499 An actual update is only done if the regexp has changed or if the
 500 optional fourth argument FORCE is non-nil."
 501   (let ((prev-valid reb-valid-string)
 502         (new-valid
 503          (condition-case nil
 504              (progn
 505                (if (or (reb-update-regexp) force)
 506                    (progn
 507                      (reb-assert-buffer-in-window)
 508                      (reb-do-update)))
 509                "")
 510            (error " *invalid*"))))
 511     (setq reb-valid-string new-valid)
 512     (force-mode-line-update)
 513
 514     ;; Through the caching of the re a change invalidating the syntax
 515     ;; for symbolic expressions will not delete the overlays so we
 516     ;; catch it here
 517     (if (and (reb-lisp-syntax-p)
 518              (not (string= prev-valid new-valid))
 519              (string= prev-valid ""))
 520         (reb-delete-overlays))))
 521
 522 (defun reb-delete-overlays ()
 523   "Delete all RE Builder overlays in the `reb-target-buffer' buffer."
 524   (if (buffer-live-p reb-target-buffer)
 525     (with-current-buffer reb-target-buffer
 526       (mapcar 'delete-overlay reb-overlays)
 527       (setq reb-overlays nil))))
 528
 529 (defun reb-assert-buffer-in-window ()
 530   "Assert that `reb-target-buffer' is displayed in `reb-target-window'."
 531
 532   (if (not (eq reb-target-buffer (window-buffer reb-target-window)))
 533       (set-window-buffer reb-target-window reb-target-buffer)))
 534
 535 (defun reb-update-modestring ()
 536   "Update the variable `reb-mode-string' displayed in the mode line."
 537   (setq reb-mode-string
 538         (concat
 539          (if reb-subexp-mode
 540              (format " (subexp %s)" (or reb-subexp-displayed "-"))
 541            "")
 542          (if (not (reb-target-binding case-fold-search))
 543              " Case"
 544            "")))
 545   (force-mode-line-update))
 546
 547 (defun reb-display-subexp (&optional subexp)
 548   "Highlight only subexpression SUBEXP in the RE Builder."
 549   (interactive)
 550
 551   (setq reb-subexp-displayed
 552         (or subexp (string-to-int (format "%c" last-command-char))))
 553   (reb-update-modestring)
 554   (reb-do-update reb-subexp-displayed))
 555
 556 (defun reb-kill-buffer ()
 557   "When the RE Builder buffer is killed make sure no overlays stay around."
 558
 559   (if (member major-mode '(reb-mode reb-lisp-mode))
 560       (reb-delete-overlays)))
 561
 562
 563 ;; The next functions are the interface between the regexp and
 564 ;; its textual representation in the RE Builder buffer.
 565 ;; They are the only functions concerned with the actual syntax
 566 ;; being used.
 567 (defun reb-read-regexp ()
 568   "Read current RE."
 569   (save-excursion
 570     (cond ((eq reb-re-syntax 'read)
 571            (goto-char (point-min))
 572            (read (current-buffer)))
 573           ((eq reb-re-syntax 'string)
 574            (goto-char (point-min))
 575            (re-search-forward "\"")
 576            (let ((beg (point)))
 577              (goto-char (point-max))
 578              (re-search-backward "\"")
 579              (buffer-substring-no-properties beg (point))))
 580           ((reb-lisp-syntax-p)
 581            (buffer-string)))))
 582
 583 (defun reb-empty-regexp ()
 584   "Return empty RE for current syntax."
 585   (cond ((reb-lisp-syntax-p) "'()")
 586         (t "")))
 587
 588 (defun reb-insert-regexp ()
 589   "Insert current RE."
 590
 591   (let ((re (or (reb-target-binding reb-regexp)
 592                 (reb-empty-regexp))))
 593   (cond ((eq reb-re-syntax 'read)
 594          (print re (current-buffer)))
 595         ((eq reb-re-syntax 'string)
 596          (insert "\n\"" re "\""))
 597         ;; For the Lisp syntax we need the "source" of the regexp
 598         ((reb-lisp-syntax-p)
 599          (insert (or (reb-target-binding reb-regexp-src)
 600                      (reb-empty-regexp)))))))
 601
 602 (defun reb-cook-regexp (re)
 603   "Return RE after processing it according to `reb-re-syntax'."
 604   (cond ((eq reb-re-syntax 'lisp-re)
 605          (lre-compile-string (eval (car (read-from-string re)))))
 606         ((eq reb-re-syntax 'sregex)
 607          (apply 'sregex (eval (car (read-from-string re)))))
 608         ((eq reb-re-syntax 'rx)
 609          (rx-to-string (eval (car (read-from-string re)))))
 610         (t re)))
 611
 612 (defun reb-update-regexp ()
 613   "Update the regexp for the target buffer.
 614 Return t if the (cooked) expression changed."
 615   (let* ((re-src (reb-read-regexp))
 616          (re (reb-cook-regexp re-src)))
 617     (with-current-buffer reb-target-buffer
 618       (let ((oldre reb-regexp))
 619         (prog1
 620             (not (string= oldre re))
 621           (setq reb-regexp re)
 622           ;; Only update the source re for the lisp formats
 623           (if (reb-lisp-syntax-p)
 624               (setq reb-regexp-src re-src)))))))
 625
 626
 627 ;; And now the real core of the whole thing
 628 (defun reb-count-subexps (re)
 629   "Return number of sub-expressions in the regexp RE."
 630
 631   (let ((i 0) (beg 0))
 632     (while (string-match "\\\\(" re beg)
 633       (setq i (1+ i)
 634             beg (match-end 0)))
 635     i))
 636
 637
 638 (defun reb-update-overlays (&optional subexp)
 639   "Switch to `reb-target-buffer' and mark all matches of `reb-regexp'.
 640 If SUBEXP is non-nil mark only the corresponding sub-expressions."
 641
 642   (let* ((re (reb-target-binding reb-regexp))
 643          (subexps (reb-count-subexps re))
 644          (matches 0)
 645          (submatches 0)
 646          firstmatch)
 647     (save-excursion
 648       (set-buffer reb-target-buffer)
 649       (reb-delete-overlays)
 650       (goto-char (point-min))
 651       (while (and (re-search-forward re (point-max) t)
 652                   (or (not reb-auto-match-limit)
 653                       (< matches reb-auto-match-limit)))
 654         (if (= 0 (length (match-string 0)))
 655           (error "Empty regular expression!"))
 656         (let ((i 0))
 657           (setq matches (1+ matches))
 658           (while (<= i subexps)
 659             (if (and (or (not subexp) (= subexp i))
 660                      (match-beginning i))
 661                 (let ((overlay (make-overlay (match-beginning i)
 662                                              (match-end i)))
 663                       (face-name (format "reb-match-%d" i)))
 664                   (if (not firstmatch)
 665                       (setq firstmatch (match-data)))
 666                   (setq reb-overlays (cons overlay reb-overlays)
 667                         submatches (1+ submatches))
 668                   (overlay-put
 669                    overlay 'face
 670                    (or (intern-soft face-name)
 671                        (error "Too many subexpressions - face `%s' not defined"
 672                               face-name )))
 673                   (overlay-put overlay 'priority i)))
 674             (setq i (1+ i))))))
 675     (let ((count (if subexp submatches matches)))
 676       (message "%s %smatch%s%s"
 677                (if (= 0 count) "No" (int-to-string count))
 678                (if subexp "subexpression " "")
 679                (if (= 1 count) "" "es")
 680                (if (and reb-auto-match-limit
 681                         (= reb-auto-match-limit count))
 682                    " (limit reached)" "")))
 683     (if firstmatch
 684         (progn (store-match-data firstmatch)
 685                (reb-show-subexp (or subexp 0))))))
 686
 687 (provide 're-builder)
 688
 689 ;;; arch-tag: 5c5515ac-4085-4524-a421-033f44f032e7
 690 ;;; re-builder.el ends here