configure.in

   1 dnl This is an autoconf script.
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 AC_PREREQ(2.0)dnl
   6 AC_INIT(src/lisp.h)
   7 AC_CONFIG_HEADER(src/config.h)
   8
   9 bindir='${exec_prefix}/bin'
  10 datadir='${prefix}/share'
  11 sharedstatedir='${prefix}/com'
  12 libexecdir='${exec_prefix}/libexec'
  13 mandir='${prefix}/man/man1'
  14 infodir='${prefix}/info'
  15 lispdir='${datadir}/emacs/${version}/lisp'
  16 locallisppath='${datadir}/emacs/site-lisp'
  17 lisppath='${locallisppath}:${lispdir}'
  18 etcdir='${datadir}/emacs/${version}/etc'
  19 lockdir='${sharedstatedir}/emacs/lock'
  20 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  21 docdir='${datadir}/emacs/${version}/etc'
  22
  23 AC_ARG_WITH(gcc,
  24 [  --with-gcc              use GCC to compile Emacs])
  25 AC_ARG_WITH(pop,
  26 [  --with-pop              support POP for mail retrieval],
  27 [AC_DEFINE(MAIL_USE_POP)])
  28 AC_ARG_WITH(kerberos,
  29 [  --with-kerberos         support Kerberos-authenticated POP],
  30 [AC_DEFINE(KERBEROS)])
  31 AC_ARG_WITH(hesiod,
  32 [  --with-hesiod           support Hesiod to get the POP server host],
  33 [AC_DEFINE(HESIOD)])
  34 dnl This should be the last --with option, because --with-x is
  35 dnl added later on when we find the path of X, and it's best to
  36 dnl keep them together visually.
  37 AC_ARG_WITH(x-toolkit,
  38 [  --with-x-toolkit=KIT    use an X toolkit (KIT = yes/lucid/athena/motif)],
  39 [         case "${withval}" in
  40             y | ye | yes )      val=athena ;;
  41             n | no )            val=no  ;;
  42             l | lu | luc | luci | lucid )       val=lucid ;;
  43             a | at | ath | athe | athena )      val=athena ;;
  44             m | mo | mot | moti | motif )       val=motif ;;
  45 dnl These don't currently work.
  46 dnl         o | op | ope | open | open- | open-l | open-lo \
  47 dnl             | open-loo | open-look )        val=open-look ;;
  48             * )
  49 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  50 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  51 AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  52 which is \`yes', \`no', \`lucid', \`athena', or \`motif'.
  53 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  54             ;;
  55           esac
  56           with_x_toolkit=$val
  57 ])
  58
  59 #### Make srcdir absolute, if it isn't already.  It's important to
  60 #### avoid running the path through pwd unnecessary, since pwd can
  61 #### give you automounter prefixes, which can go away.  We do all this
  62 #### so Emacs can find its files when run uninstalled.
  63 case "${srcdir}" in
  64   /* ) ;;
  65   . )
  66     ## We may be able to use the $PWD environment variable to make this
  67     ## absolute.  But sometimes PWD is inaccurate.
  68     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
  69     then
  70       srcdir="$PWD"
  71     else
  72       srcdir="`(cd ${srcdir}; pwd)`"
  73     fi
  74   ;;
  75   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
  76 esac
  77
  78 #### Check if the source directory already has a configured system in it.
  79 if test `pwd` != `(cd ${srcdir} && pwd)` \
  80    && test -f "${srcdir}/src/config.h" ; then
  81   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
  82    as a build directory right now; it has been configured in its own
  83    right.  To configure in another directory as well, you MUST
  84    use GNU make.  If you do not have GNU make, then you must
  85    now do \`make distclean' in ${srcdir},
  86    and then run $0 again.])
  87
  88 changequote(, )dnl
  89   extrasub='/^VPATH[     ]*=/c\
  90 changequote([, ])dnl
  91 vpath %.c $(srcdir)\
  92 vpath %.h $(srcdir)\
  93 vpath %.y $(srcdir)\
  94 vpath %.l $(srcdir)\
  95 vpath %.s $(srcdir)\
  96 vpath %.in $(srcdir)'
  97 fi
  98
  99 #### Given the configuration name, set machfile and opsysfile to the
 100 #### names of the m/*.h and s/*.h files we should use.
 101
 102 ### Canonicalize the configuration name.
 103
 104 AC_CANONICAL_HOST
 105 canonical=$host
 106 configuration=$host_alias
 107
 108 changequote(, )dnl
 109
 110 ### If you add support for a new configuration, add code to this
 111 ### switch statement to recognize your configuration name and select
 112 ### the appropriate operating system and machine description files.
 113
 114 ### You would hope that you could choose an m/*.h file pretty much
 115 ### based on the machine portion of the configuration name, and an s-
 116 ### file based on the operating system portion.  However, it turns out
 117 ### that each m/*.h file is pretty manufacturer-specific - for
 118 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 119 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 120 ### machines.  So we basically have to have a special case for each
 121 ### configuration name.
 122 ###
 123 ### As far as handling version numbers on operating systems is
 124 ### concerned, make sure things will fail in a fixable way.  If
 125 ### /etc/MACHINES doesn't say anything about version numbers, be
 126 ### prepared to handle anything reasonably.  If version numbers
 127 ### matter, be sure /etc/MACHINES says something about it.
 128 ###
 129 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 130 ### "System V Release 4"; he writes, "The old convention encouraged
 131 ### confusion between `system' and `release' levels'."
 132
 133 machine='' opsys='' unported=no
 134 case "${canonical}" in
 135
 136   ## NetBSD ports
 137   *-*-netbsd* )
 138     opsys=netbsd
 139     case "${canonical}" in
 140       i[345]86-*-netbsd*) machine=intel386 ;;
 141       m68k-*-netbsd*)
 142                         # This is somewhat bogus.
 143                         machine=hp9000s300 ;;
 144       mips-*-netbsd*)   machine=pmax ;;
 145       ns32k-*-netbsd*)  machine=ns32000 ;;
 146       sparc-*-netbsd*)  machine=sparc ;;
 147     esac
 148   ;;
 149
 150   ## Acorn RISCiX:
 151   arm-acorn-riscix1.1* )
 152     machine=acorn opsys=riscix1-1
 153   ;;
 154   arm-acorn-riscix1.2* | arm-acorn-riscix )
 155     machine=acorn opsys=riscix1-2
 156   ;;
 157
 158   ## Alliant machines
 159   ## Strictly speaking, we need the version of the alliant operating
 160   ## system to choose the right machine file, but currently the
 161   ## configuration name doesn't tell us enough to choose the right
 162   ## one; we need to give alliants their own operating system name to
 163   ## do this right.  When someone cares, they can help us.
 164   fx80-alliant-* )
 165     machine=alliant4 opsys=bsd4-2
 166   ;;
 167   i860-alliant-* )
 168     machine=alliant-2800 opsys=bsd4-3
 169   ;;
 170
 171   alpha-dec-osf* )
 172     machine=alpha opsys=osf1
 173   ;;
 174
 175   ## Altos 3068
 176   m68*-altos-sysv* )
 177     machine=altos opsys=usg5-2
 178   ;;
 179
 180   ## Amdahl UTS
 181   580-amdahl-sysv* )
 182     machine=amdahl opsys=usg5-2-2
 183   ;;
 184
 185   ## Apollo, Domain/OS
 186   m68*-apollo-* )
 187     machine=apollo opsys=bsd4-3
 188   ;;
 189
 190   ## AT&T 3b2, 3b5, 3b15, 3b20
 191   we32k-att-sysv* )
 192     machine=att3b opsys=usg5-2-2
 193   ;;
 194
 195   ## AT&T 3b1 - The Mighty Unix PC!
 196   m68*-att-sysv* )
 197     machine=7300 opsys=usg5-2-2
 198   ;;
 199
 200   ## Bull dpx20
 201   rs6000-bull-bosx* )
 202     machine=ibmrs6000 opsys=aix3-2
 203   ;;
 204
 205   ## Bull dpx2
 206   m68*-bull-sysv3* )
 207     machine=dpx2 opsys=usg5-3
 208   ;;
 209
 210   ## Bull sps7
 211   m68*-bull-sysv2* )
 212     machine=sps7 opsys=usg5-2
 213   ;;
 214
 215   ## CCI 5/32, 6/32 -- see "Tahoe".
 216
 217   ## Celerity
 218   ## I don't know what configuration name to use for this; config.sub
 219   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 220   ## in touch with us!
 221   celerity-celerity-bsd* )
 222     machine=celerity opsys=bsd4-2
 223   ;;
 224
 225   ## Clipper
 226   ## What operating systems does this chip run that Emacs has been
 227   ## tested on?
 228   clipper-* )
 229     machine=clipper
 230     ## We'll use the catch-all code at the bottom to guess the
 231     ## operating system.
 232   ;;
 233
 234   ## Convex
 235   *-convex-bsd* | *-convex-convexos* )
 236     machine=convex opsys=bsd4-3
 237     ## Prevents suprious white space in makefiles - d.m.cooke@larc.nasa.gov
 238     NON_GNU_CPP="cc -E -P"
 239   ;;
 240
 241   ## Cubix QBx/386
 242   i[345]86-cubix-sysv* )
 243     machine=intel386 opsys=usg5-3
 244   ;;
 245
 246   ## Cydra 5
 247   cydra*-cydrome-sysv* )
 248     machine=cydra5 opsys=usg5-3
 249   ;;
 250
 251   ## Data General AViiON Machines
 252   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 253     machine=aviion opsys=dgux5-4r3
 254   ;;
 255   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 256     machine=aviion opsys=dgux5-4r2
 257   ;;
 258   m88k-dg-dgux* )
 259     machine=aviion opsys=dgux
 260   ;;
 261
 262   ## DECstations
 263   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 264     machine=pmax opsys=bsd4-2
 265   ;;
 266   mips-dec-ultrix* | mips-dec-bsd* )
 267     machine=pmax opsys=bsd4-3
 268   ;;
 269   mips-dec-osf* )
 270     machine=pmax opsys=osf1
 271   ;;
 272
 273   ## Motorola Delta machines
 274   m68k-motorola-sysv* | m68000-motorola-sysv* )
 275     machine=delta opsys=usg5-3
 276     if test -z "`type gnucc | grep 'not found'`"
 277     then
 278       if test -s /etc/167config
 279       then CC="gnucc -m68040"
 280       else CC="gnucc -m68881"
 281       fi
 282     else
 283       if test -z "`type gcc | grep 'not found'`"
 284       then CC=gcc
 285       else CC=cc
 286       fi
 287     fi
 288   ;;
 289   m88k-motorola-sysv4* )
 290     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 291     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 292     # I hope there are not other 4.0 versions for this machine
 293     # which really need usg5-4 instead.
 294     machine=delta88k opsys=usg5-4-2
 295   ;;
 296   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 297     machine=delta88k opsys=usg5-3
 298   ;;
 299
 300   ## Dual machines
 301   m68*-dual-sysv* )
 302     machine=dual opsys=usg5-2
 303   ;;
 304   m68*-dual-uniplus* )
 305     machine=dual opsys=unipl5-2
 306   ;;
 307
 308   ## Elxsi 6400
 309   elxsi-elxsi-sysv* )
 310     machine=elxsi opsys=usg5-2
 311   ;;
 312
 313   ## Encore machines
 314   ns16k-encore-bsd* )
 315     machine=ns16000 opsys=umax
 316   ;;
 317
 318   ## The GEC 93 - apparently, this port isn't really finished yet.
 319
 320   ## Gould Power Node and NP1
 321   pn-gould-bsd4.2* )
 322     machine=gould opsys=bsd4-2
 323   ;;
 324   pn-gould-bsd4.3* )
 325     machine=gould opsys=bsd4-3
 326   ;;
 327   np1-gould-bsd* )
 328     machine=gould-np1 opsys=bsd4-3
 329   ;;
 330
 331   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 332   ## as far as Emacs is concerned).
 333   m88k-harris-cxux* )
 334     # Build needs to be different on 7.0 and later releases
 335     case "`uname -r`" in
 336        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 337        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 338     esac
 339   ;;
 340   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 341   m68k-harris-cxux* )
 342     machine=nh3000 opsys=cxux
 343   ;;
 344
 345   ## Honeywell XPS100
 346   xps*-honeywell-sysv* )
 347     machine=xps100 opsys=usg5-2
 348   ;;
 349
 350   ## HP 9000 series 200 or 300
 351   m68*-hp-bsd* )
 352     machine=hp9000s300 opsys=bsd4-3
 353   ;;
 354   ## HP/UX 7, 8 and 9 are supported on these machines.
 355   m68*-hp-hpux* )
 356     case "`uname -r`" in
 357       ## Someone's system reports A.B8.05 for this.
 358       ## I wonder what other possibilities there are.
 359       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 360       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 361       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 362       *) machine=hp9000s300 opsys=hpux ;;
 363     esac
 364   ;;
 365
 366   ## HP 9000 series 700 and 800, running HP/UX
 367   hppa*-hp-hpux7* )
 368     machine=hp800 opsys=hpux
 369   ;;
 370   hppa*-hp-hpux8* )
 371     machine=hp800 opsys=hpux8
 372   ;;
 373   hppa*-hp-hpux9shr* )
 374     machine=hp800 opsys=hpux9shr
 375   ;;
 376   hppa*-hp-hpux9* )
 377     machine=hp800 opsys=hpux9
 378   ;;
 379
 380   ## HP 9000 series 700 and 800, running HP/UX
 381   hppa*-hp-hpux* )
 382     ## Cross-compilation?  Nah!
 383     case "`uname -r`" in
 384       ## Someone's system reports A.B8.05 for this.
 385       ## I wonder what other possibilities there are.
 386       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 387       *.08.* ) machine=hp800 opsys=hpux8 ;;
 388       *.09.* ) machine=hp800 opsys=hpux9 ;;
 389       *) machine=hp800 opsys=hpux ;;
 390     esac
 391   ;;
 392
 393   ## Orion machines
 394   orion-orion-bsd* )
 395     machine=orion opsys=bsd4-2
 396   ;;
 397   clipper-orion-bsd* )
 398     machine=orion105 opsys=bsd4-2
 399   ;;
 400
 401   ## IBM machines
 402   i[345]86-ibm-aix1.1* )
 403     machine=ibmps2-aix opsys=usg5-2-2
 404   ;;
 405   i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
 406     machine=ibmps2-aix opsys=usg5-3
 407   ;;
 408   i370-ibm-aix*)
 409     machine=ibm370aix opsys=usg5-3
 410   ;;
 411   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 412     machine=ibmrs6000 opsys=aix3-1
 413   ;;
 414   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 415     machine=ibmrs6000 opsys=aix3-2-5
 416   ;;
 417   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 418     machine=ibmrs6000 opsys=aix4-1
 419   ;;
 420   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 421     machine=ibmrs6000 opsys=aix4
 422   ;;
 423   rs6000-ibm-aix* | powerpc-ibm-aix* )
 424     machine=ibmrs6000 opsys=aix3-2
 425   ;;
 426   romp-ibm-bsd4.3* )
 427     machine=ibmrt opsys=bsd4-3
 428   ;;
 429   romp-ibm-bsd4.2* )
 430     machine=ibmrt opsys=bsd4-2
 431   ;;
 432   romp-ibm-aos4.3* )
 433     machine=ibmrt opsys=bsd4-3
 434   ;;
 435   romp-ibm-aos4.2* )
 436     machine=ibmrt opsys=bsd4-2
 437   ;;
 438   romp-ibm-aos* )
 439     machine=ibmrt opsys=bsd4-3
 440   ;;
 441   romp-ibm-bsd* )
 442     machine=ibmrt opsys=bsd4-3
 443   ;;
 444   romp-ibm-aix* )
 445     machine=ibmrt-aix opsys=usg5-2-2
 446   ;;
 447
 448   ## Integrated Solutions `Optimum V'
 449   m68*-isi-bsd4.2* )
 450     machine=isi-ov opsys=bsd4-2
 451   ;;
 452   m68*-isi-bsd4.3* )
 453     machine=isi-ov opsys=bsd4-3
 454   ;;
 455
 456   ## Intel 386 machines where we do care about the manufacturer
 457   i[345]86-intsys-sysv* )
 458     machine=is386 opsys=usg5-2-2
 459   ;;
 460
 461   ## Prime EXL
 462   i[345]86-prime-sysv* )
 463     machine=i386 opsys=usg5-3
 464   ;;
 465
 466   ## Sequent Symmetry running Dynix
 467   i[345]86-sequent-bsd* )
 468     machine=symmetry opsys=bsd4-3
 469   ;;
 470
 471   ## Sequent Symmetry running DYNIX/ptx
 472   ## Use the old cpp rather than the newer ANSI one.
 473   i[345]86-sequent-ptx* )
 474     machine=sequent-ptx opsys=ptx
 475     NON_GNU_CPP="/lib/cpp"
 476   ;;
 477
 478   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 479   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 480   i[345]86-ncr-sysv* )
 481     machine=ncr386 opsys=usg5-4-2
 482   ;;
 483
 484   ## Intel Paragon OSF/1
 485   i860-intel-osf1* )
 486     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 487   ;;
 488
 489   ## Intel 860
 490   i860-*-sysv4* )
 491     machine=i860 opsys=usg5-4
 492     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 493     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 494   ;;
 495
 496   ## Masscomp machines
 497   m68*-masscomp-rtu* )
 498     machine=masscomp opsys=rtu
 499   ;;
 500
 501   ## Megatest machines
 502   m68*-megatest-bsd* )
 503     machine=mega68 opsys=bsd4-2
 504   ;;
 505
 506   ## Workstations sold by MIPS
 507   ## This is not necessarily all workstations using the MIPS processor -
 508   ## Irises are produced by SGI, and DECstations by DEC.
 509
 510   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 511   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 512   ## it gives for choosing between the alternatives seems to be "Use
 513   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 514   ## the BSD world."  I'll assume that these are instructions for
 515   ## handling two odd situations, and that every other situation
 516   ## should use mips.h and usg5-2-2, they being listed first.
 517   mips-mips-usg* )
 518     machine=mips4
 519     ## Fall through to the general code at the bottom to decide on the OS.
 520   ;;
 521   mips-mips-riscos4* )
 522     machine=mips4 opsys=bsd4-3
 523     NON_GNU_CC="cc -systype bsd43"
 524     NON_GNU_CPP="cc -systype bsd43 -E"
 525   ;;
 526   mips-mips-bsd* )
 527     machine=mips opsys=bsd4-3
 528   ;;
 529   mips-mips-* )
 530     machine=mips opsys=usg5-2-2
 531   ;;
 532
 533   ## NeXT
 534   m68*-next-* | i[345]86-next-* )
 535     machine=next opsys=mach2
 536   ;;
 537
 538   ## The complete machine from National Semiconductor
 539   ns32k-ns-genix* )
 540     machine=ns32000 opsys=usg5-2
 541   ;;
 542
 543   ## NCR machines
 544   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 545     machine=tower32 opsys=usg5-2-2
 546   ;;
 547   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 548     machine=tower32v3 opsys=usg5-3
 549   ;;
 550
 551   ## Nixdorf Targon 31
 552   m68*-nixdorf-sysv* )
 553     machine=targon31 opsys=usg5-2-2
 554   ;;
 555
 556   ## Nu (TI or LMI)
 557   m68*-nu-sysv* )
 558     machine=nu opsys=usg5-2
 559   ;;
 560
 561   ## Plexus
 562   m68*-plexus-sysv* )
 563     machine=plexus opsys=usg5-2
 564   ;;
 565
 566   ## Pyramid machines
 567   ## I don't really have any idea what sort of processor the Pyramid has,
 568   ## so I'm assuming it is its own architecture.
 569   pyramid-pyramid-bsd* )
 570     machine=pyramid opsys=bsd4-2
 571   ;;
 572
 573   ## Sequent Balance
 574   ns32k-sequent-bsd4.2* )
 575     machine=sequent opsys=bsd4-2
 576   ;;
 577   ns32k-sequent-bsd4.3* )
 578     machine=sequent opsys=bsd4-3
 579   ;;
 580
 581   ## Siemens Nixdorf
 582   mips-siemens-sysv* )
 583     machine=mips-siemens opsys=usg5-4
 584     NON_GNU_CC=/usr/ccs/bin/cc
 585     NON_GNU_CPP=/usr/ccs/lib/cpp
 586   ;;
 587
 588   ## Silicon Graphics machines
 589   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 590   m68*-sgi-iris3.5* )
 591     machine=irist opsys=iris3-5
 592   ;;
 593   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 594     machine=irist opsys=iris3-6
 595   ;;
 596   ## Iris 4D
 597   mips-sgi-irix3* )
 598     machine=iris4d opsys=irix3-3
 599   ;;
 600   mips-sgi-irix4* )
 601     machine=iris4d opsys=irix4-0
 602   ;;
 603   mips-sgi-irix6* )
 604     machine=iris4d opsys=irix6-0
 605   ;;
 606   mips-sgi-irix5.[01]* )
 607     machine=iris4d opsys=irix5-0
 608   ;;
 609   mips-sgi-irix5* | mips-sgi-irix* )
 610     machine=iris4d opsys=irix5-2
 611   ;;
 612
 613   ## SONY machines
 614   m68*-sony-bsd4.2* )
 615     machine=news opsys=bsd4-2
 616   ;;
 617   m68*-sony-bsd4.3* )
 618     machine=news opsys=bsd4-3
 619   ;;
 620   m68*-sony-newsos3* | m68*-sony-news3*)
 621     machine=news opsys=bsd4-3
 622   ;;
 623   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 624     machine=news-risc opsys=bsd4-3
 625   ;;
 626   mips-sony-news* )
 627     machine=news-risc opsys=newsos5
 628   ;;
 629
 630   ## Stride
 631   m68*-stride-sysv* )
 632     machine=stride opsys=usg5-2
 633   ;;
 634
 635   ## Suns
 636   *-sun-sunos* | *-sun-bsd* | *-sun-solaris* | i[345]86-*-solaris2* | i[345]86-*-sunos5* )
 637     case "${canonical}" in
 638       m68*-sunos1* )    machine=sun1 ;;
 639       m68*-sunos2* )    machine=sun2 ;;
 640       m68* )            machine=sun3 ;;
 641       i[345]86-sun-sunos[34]* ) machine=sun386 ;;
 642       i[345]86-*-* )     machine=intel386 ;;
 643       sparc* )          machine=sparc ;;
 644       * )               unported=yes ;;
 645     esac
 646     case "${canonical}" in
 647       ## The Sun386 didn't get past 4.0.
 648       i[345]86-*-sunos4   ) opsys=sunos4-0 ;;
 649       *-sunos4.0*         ) opsys=sunos4-0 ;;
 650       *-sunos4.1.3* | *-sunos4shr*  ) opsys=sunos4shr
 651                 NON_GNU_CPP=/usr/lib/cpp
 652                 ;;
 653       *-sunos4* | *-sunos ) opsys=sunos4-1
 654                 NON_GCC_TEST_OPTIONS=-Bstatic
 655                 GCC_TEST_OPTIONS=-static
 656                 ;;
 657       *-sunos5.3* | *-solaris2.3* )
 658                 opsys=sol2-3
 659                 NON_GNU_CPP=/usr/ccs/lib/cpp
 660                 ;;
 661       *-sunos5.4* | *-solaris2.4* )
 662                 opsys=sol2-4
 663                 NON_GNU_CPP=/usr/ccs/lib/cpp
 664                 ;;
 665       *-sunos5* | *-solaris* )
 666                 opsys=sol2
 667                 NON_GNU_CPP=/usr/ccs/lib/cpp
 668                 ;;
 669       *                   ) opsys=bsd4-2   ;;
 670     esac
 671   ;;
 672
 673   ## Tadpole 68k
 674   m68*-tadpole-sysv* )
 675     machine=tad68k opsys=usg5-3
 676   ;;
 677
 678   ## Tahoe machines
 679   tahoe-tahoe-bsd4.2* )
 680     machine=tahoe opsys=bsd4-2
 681   ;;
 682   tahoe-tahoe-bsd4.3* )
 683     machine=tahoe opsys=bsd4-3
 684   ;;
 685
 686   ## Tandem Integrity S2
 687   mips-tandem-sysv* )
 688     machine=tandem-s2 opsys=usg5-3
 689   ;;
 690
 691   ## Tektronix XD88
 692   m88k-tektronix-sysv3* )
 693   machine=tekxd88 opsys=usg5-3
 694   ;;
 695
 696   ## Tektronix 16000 box (6130?)
 697   ns16k-tektronix-bsd* )
 698     machine=ns16000 opsys=bsd4-2
 699   ;;
 700   ## Tektronix 4300
 701   ## src/m/tek4300.h hints that this is a m68k machine.
 702   m68*-tektronix-bsd* )
 703     machine=tek4300 opsys=bsd4-3
 704   ;;
 705
 706   ## Titan P2 or P3
 707   ## We seem to have lost the machine-description file titan.h!
 708   titan-titan-sysv* )
 709     machine=titan opsys=usg5-3
 710   ;;
 711
 712   ## Ustation E30 (SS5E)
 713   m68*-unisys-uniplus* )
 714     machine=ustation opsystem=unipl5-2
 715   ;;
 716
 717   ## Vaxen.
 718   vax-dec-* )
 719     machine=vax
 720     case "${canonical}" in
 721       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 722       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 723       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 724       *-bsd386* | *-bsdi* )                             opsys=bsd386 ;;
 725       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 726       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 727       *-vms* )                                          opsys=vms ;;
 728       * )                                               unported=yes
 729     esac
 730   ;;
 731
 732   ## Whitechapel MG1
 733   ns16k-whitechapel-* )
 734     machine=mg1
 735     ## We don't know what sort of OS runs on these; we'll let the
 736     ## operating system guessing code below try.
 737   ;;
 738
 739   ## Wicat
 740   m68*-wicat-sysv* )
 741     machine=wicat opsys=usg5-2
 742   ;;
 743
 744   ## Intel 386 machines where we don't care about the manufacturer
 745   i[345]86-*-* )
 746     machine=intel386
 747     case "${canonical}" in
 748       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 749       *-isc2.2* )               opsys=isc2-2 ;;
 750       *-isc4.0* )               opsys=isc4-0 ;;
 751       *-isc4.* )                opsys=isc4-1 ;;
 752       *-isc* )                  opsys=isc3-0 ;;
 753       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 754       *-esix* )                 opsys=esix ;;
 755       *-xenix* )                opsys=xenix ;;
 756       *-linux* )                opsys=linux ;;
 757       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
 758       *-bsd386* | *-bsdi* )     opsys=bsd386 ;;
 759       *-386bsd* )               opsys=386bsd ;;
 760       *-freebsd* )              opsys=freebsd ;;
 761       *-nextstep* )             opsys=mach2 ;;
 762       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 763     esac
 764   ;;
 765
 766   * )
 767     unported=yes
 768   ;;
 769 esac
 770
 771 ### If the code above didn't choose an operating system, just choose
 772 ### an operating system based on the configuration name.  You really
 773 ### only want to use this when you have no idea what the right
 774 ### operating system is; if you know what operating systems a machine
 775 ### runs, it's cleaner to make it explicit in the case statement
 776 ### above.
 777 if test x"${opsys}" = x; then
 778   case "${canonical}" in
 779     *-gnu* )                            opsys=gnu ;;
 780     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 781     *-bsd4.2 )                          opsys=bsd4-2 ;;
 782     *-bsd4.3 )                          opsys=bsd4-3 ;;
 783     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 784     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 785     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 786     *-sysv3 | *-sysvr3 )                opsys=usg5-3 ;;
 787     *-sysv4 | *-sysvr4 )                opsys=usg5-4 ;;
 788     *-sysv4.1 | *-sysvr4.1 )
 789         NON_GNU_CPP=/usr/lib/cpp
 790         opsys=usg5-4 ;;
 791     *-sysv4.2 | *-sysvr4.2 )
 792         if [ x$NON_GNU_CPP = x ]; then
 793           NON_GNU_CPP=/usr/ccs/lib/cpp
 794         fi
 795         opsys=usg5-4-2 ;;
 796     * )
 797       unported=yes
 798     ;;
 799   esac
 800 fi
 801
 802 changequote([, ])dnl
 803
 804 if test $unported = yes; then
 805   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
 806 Check \`etc/MACHINES' for recognized configuration names.])
 807 fi
 808
 809 machfile="m/${machine}.h"
 810 opsysfile="s/${opsys}.h"
 811
 812
 813 #### Choose a compiler.
 814 test -n "$CC" && cc_specified=yes
 815
 816 case ${with_gcc} in
 817   "yes" ) CC="gcc" GCC=yes ;;
 818   "no"  ) : ${CC=cc} ;;
 819   * ) AC_PROG_CC
 820 esac
 821
 822 # On Suns, sometimes $CPP names a directory.
 823 if test -n "$CPP" && test -d "$CPP"; then
 824   CPP=
 825 fi
 826
 827 #### Some systems specify a CPP to use unless we are using GCC.
 828 #### Now that we know whether we are using GCC, we can decide whether
 829 #### to use that one.
 830 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 831 then
 832   CPP="$NON_GNU_CPP"
 833 fi
 834
 835 #### Some systems specify a CC to use unless we are using GCC.
 836 #### Now that we know whether we are using GCC, we can decide whether
 837 #### to use that one.
 838 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 839   test x$cc_specified != xyes
 840 then
 841   CC="$NON_GNU_CC"
 842 fi
 843
 844 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 845 then
 846   CC="$CC $GCC_TEST_OPTIONS"
 847 fi
 848
 849 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 850 then
 851   CC="$CC $NON_GCC_TEST_OPTIONS"
 852 fi
 853
 854 #### Some other nice autoconf tests.  If you add a test here which
 855 #### should make an entry in src/config.h, don't forget to add an
 856 #### #undef clause to src/config.h.in for autoconf to modify.
 857
 858 dnl checks for programs
 859 AC_PROG_LN_S
 860 AC_PROG_CPP
 861 AC_PROG_INSTALL
 862 AC_PROG_YACC
 863
 864 dnl checks for Unix variants
 865 AC_AIX
 866
 867 dnl checks for header files
 868 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h)
 869 AC_HEADER_STDC
 870 AC_HEADER_TIME
 871 AC_DECL_SYS_SIGLIST
 872
 873 dnl Some systems have utime.h but don't declare the struct anyplace.
 874 AC_MSG_CHECKING(for struct utimbuf)
 875 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 876 #include <sys/time.h>
 877 #include <time.h>
 878 #else
 879 #ifdef HAVE_SYS_TIME_H
 880 #include <sys/time.h>
 881 #else
 882 #include <time.h>
 883 #endif
 884 #endif
 885 #ifdef HAVE_UTIME_H
 886 #include <utime.h>
 887 #endif], [static struct utimbuf x; x.actime = x.modtime;],
 888   [AC_MSG_RESULT(yes)
 889    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
 890   AC_MSG_RESULT(no))
 891
 892 dnl checks for typedefs
 893 AC_TYPE_SIGNAL
 894
 895 AC_MSG_CHECKING(for struct timeval)
 896 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 897 #include <sys/time.h>
 898 #include <time.h>
 899 #else
 900 #ifdef HAVE_SYS_TIME_H
 901 #include <sys/time.h>
 902 #else
 903 #include <time.h>
 904 #endif
 905 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
 906   [AC_MSG_RESULT(yes)
 907    AC_DEFINE(HAVE_TIMEVAL)],
 908   AC_MSG_RESULT(no))
 909
 910 dnl checks for structure members
 911 AC_STRUCT_TM
 912 AC_STRUCT_TIMEZONE
 913
 914 dnl checks for compiler characteristics
 915 AC_C_CONST
 916
 917 dnl check for Make feature
 918 AC_PROG_MAKE_SET
 919
 920 dnl checks for operating system services
 921 AC_SYS_LONG_FILE_NAMES
 922
 923 #### Choose a window system.
 924
 925 AC_PATH_X
 926 if test "$no_x" = yes; then
 927   window_system=none
 928 else
 929   window_system=x11
 930 fi
 931
 932 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
 933   LD_SWITCH_X_SITE="-L${x_libraries}"
 934   LD_SWITCH_X_SITE_AUX="-R${x_libraries}"
 935 fi
 936 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
 937   C_SWITCH_X_SITE="-I${x_includes}"
 938 fi
 939
 940 if test x"${x_includes}" = x; then
 941   bitmapdir=/usr/include/X11/bitmaps
 942 else
 943   bitmapdir="${x_includes}/bitmaps"
 944 fi
 945
 946 case "${window_system}" in
 947   x11 )
 948     HAVE_X_WINDOWS=yes
 949     HAVE_X11=yes
 950     case "${with_x_toolkit}" in
 951       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
 952       motif ) USE_X_TOOLKIT=MOTIF ;;
 953 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
 954       * ) USE_X_TOOLKIT=none ;;
 955     esac
 956   ;;
 957   none )
 958     HAVE_X_WINDOWS=no
 959     HAVE_X11=no
 960     USE_X_TOOLKIT=none
 961   ;;
 962 esac
 963 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
 964
 965 ### If we're using X11, we should use the X menu package.
 966 HAVE_X_MENU=no
 967 case ${HAVE_X11} in
 968   yes ) HAVE_X_MENU=yes ;;
 969 esac
 970
 971 #### Extract some information from the operating system and machine files.
 972
 973 AC_CHECKING([the machine- and system-dependent files to find out
 974  - which libraries the lib-src programs will want, and
 975  - whether the GNU malloc routines are usable])
 976
 977 ### First figure out CFLAGS (which we use for running the compiler here)
 978 ### and REAL_CFLAGS (which we use for real compilation).
 979 ### The two are the same except on a few systems, where they are made
 980 ### different to work around various lossages.  For example,
 981 ### GCC 2.5 on Linux needs them to be different because it treats -g
 982 ### as implying static linking.
 983
 984 ### If the CFLAGS env var is specified, we use that value
 985 ### instead of the default.
 986
 987 ### It's not important that this name contain the PID; you can't run
 988 ### two configures in the same directory and have anything work
 989 ### anyway.
 990 tempcname="conftest.c"
 991
 992 echo '
 993 #include "'${srcdir}'/src/'${opsysfile}'"
 994 #include "'${srcdir}'/src/'${machfile}'"
 995 #ifndef LIBS_MACHINE
 996 #define LIBS_MACHINE
 997 #endif
 998 #ifndef LIBS_SYSTEM
 999 #define LIBS_SYSTEM
1000 #endif
1001 #ifndef C_SWITCH_SYSTEM
1002 #define C_SWITCH_SYSTEM
1003 #endif
1004 #ifndef C_SWITCH_MACHINE
1005 #define C_SWITCH_MACHINE
1006 #endif
1007 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1008 configure___ c_switch_system=C_SWITCH_SYSTEM
1009 configure___ c_switch_machine=C_SWITCH_MACHINE
1010
1011 #ifndef LIB_X11_LIB
1012 #define LIB_X11_LIB -lX11
1013 #endif
1014
1015 #ifndef LIBX11_MACHINE
1016 #define LIBX11_MACHINE
1017 #endif
1018
1019 #ifndef LIBX11_SYSTEM
1020 #define LIBX11_SYSTEM
1021 #endif
1022 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1023
1024 #ifdef UNEXEC
1025 configure___ unexec=UNEXEC
1026 #else
1027 configure___ unexec=unexec.o
1028 #endif
1029
1030 #ifdef SYSTEM_MALLOC
1031 configure___ system_malloc=yes
1032 #else
1033 configure___ system_malloc=no
1034 #endif
1035
1036 #ifndef C_DEBUG_SWITCH
1037 #define C_DEBUG_SWITCH -g
1038 #endif
1039
1040 #ifndef C_OPTIMIZE_SWITCH
1041 #define C_OPTIMIZE_SWITCH -O
1042 #endif
1043
1044 #ifdef THIS_IS_CONFIGURE
1045
1046 /* Get the CFLAGS for tests in configure.  */
1047 #ifdef __GNUC__
1048 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1049 #else
1050 configure___ CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1051 #endif
1052
1053 #else /* not THIS_IS_CONFIGURE */
1054
1055 /* Get the CFLAGS for real compilation.  */
1056 #ifdef __GNUC__
1057 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1058 #else
1059 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1060 #endif
1061
1062 #endif /* not THIS_IS_CONFIGURE */
1063 ' > ${tempcname}
1064
1065 # The value of CPP is a quoted variable reference, so we need to do this
1066 # to get its actual value...
1067 CPP=`eval "echo $CPP"`
1068 changequote(, )dnl
1069 eval `${CPP} -Isrc ${tempcname} \
1070        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1071 if test "x$CFLAGS" = x; then
1072   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1073          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1074 else
1075   REAL_CFLAGS="$CFLAGS"
1076 fi
1077 changequote([, ])dnl
1078 rm ${tempcname}
1079
1080 ### Compute the unexec source name from the object name.
1081 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1082
1083 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1084 # Assume not, until told otherwise.
1085 GNU_MALLOC=yes
1086 if test "${system_malloc}" = "yes"; then
1087   GNU_MALLOC=no
1088   GNU_MALLOC_reason="
1089   (The GNU allocators don't work with this system configuration.)"
1090 fi
1091
1092 if test x"${REL_ALLOC}" = x; then
1093   REL_ALLOC=${GNU_MALLOC}
1094 fi
1095
1096 LISP_FLOAT_TYPE=yes
1097
1098
1099 #### Add the libraries to LIBS and check for some functions.
1100
1101 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1102 LIBS="$libsrc_libs"
1103
1104 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1105 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1106 AC_CHECK_LIB(dnet, dnet_ntoa)
1107 dnl This causes -lresolv to get used in subsequent tests,
1108 dnl which causes failures on some systems such as HPUX 9.
1109 dnl AC_CHECK_LIB(resolv, gethostbyname)
1110
1111 dnl FIXME replace main with a function we actually want from this library.
1112 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1113
1114 AC_MSG_CHECKING(for XFree86)
1115 if test -d /usr/X386/include; then
1116   HAVE_XFREE386=yes
1117   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1118 else
1119   HAVE_XFREE386=no
1120 fi
1121 AC_MSG_RESULT($HAVE_XFREE386)
1122
1123 # We change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1124 # for the tests that follow.
1125
1126 if test "${HAVE_X11}" = "yes"; then
1127   DEFS="$C_SWITCH_X_SITE $DEFS"
1128   LIBS="$LD_SWITCH_X_SITE $LIBX $LIBS"
1129   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1130   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1131 XScreenNumberOfScreen XSetWMProtocols)
1132 fi
1133
1134 if test "${USE_X_TOOLKIT}" != "none"; then
1135   AC_MSG_CHECKING(X11 toolkit version)
1136   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1137 [#if XtSpecificationRelease < 6
1138 fail;
1139 #endif
1140 ], [AC_MSG_RESULT(6)
1141     AC_DEFINE(HAVE_X11XTR6)],
1142    [AC_MSG_RESULT(not 6)])
1143 fi
1144
1145 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1146 AC_MSG_CHECKING(whether netdb declarares h_errno)
1147 AC_TRY_LINK([#include <netdb.h>],
1148   [return h_errno;],
1149   [AC_MSG_RESULT(yes)
1150    AC_DEFINE(HAVE_H_ERRNO)],
1151   [AC_MSG_RESULT(no)])
1152
1153 AC_FUNC_ALLOCA
1154
1155 # logb and frexp are found in -lm on most systems.
1156 AC_CHECK_LIB(m, logb)
1157 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1158 random lrand48 bcopy bcmp logb frexp fmod drem ftime res_init setsid \
1159 strerror fpathconf select mktime eaccess getpagesize)
1160
1161 ok_so_far=yes
1162 AC_CHECK_FUNC(socket, , ok_so_far=no)
1163 if test $ok_so_far = yes; then
1164   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1165 fi
1166 if test $ok_so_far = yes; then
1167   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1168 fi
1169 if test $ok_so_far = yes; then
1170   AC_DEFINE(HAVE_INET_SOCKETS)
1171 fi
1172
1173 if test -f /usr/lpp/X11/bin/smt.exp; then
1174   AC_DEFINE(HAVE_AIX_SMT_EXP)
1175 fi
1176
1177 # Set up the CFLAGS for real compilation, so we can substitute it.
1178 CFLAGS="$REAL_CFLAGS"
1179
1180 changequote(, )dnl
1181 #### Find out which version of Emacs this is.
1182 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
1183          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1184 changequote([, ])dnl
1185 if test x"${version}" = x; then
1186   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1187 fi
1188
1189 ### Specify what sort of things we'll be editing into Makefile and config.h.
1190 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1191 AC_SUBST(version)
1192 AC_SUBST(configuration)
1193 AC_SUBST(canonical)
1194 AC_SUBST(srcdir)
1195 AC_SUBST(prefix)
1196 AC_SUBST(exec_prefix)
1197 AC_SUBST(bindir)
1198 AC_SUBST(datadir)
1199 AC_SUBST(sharedstatedir)
1200 AC_SUBST(libexecdir)
1201 AC_SUBST(mandir)
1202 AC_SUBST(infodir)
1203 AC_SUBST(lispdir)
1204 AC_SUBST(locallisppath)
1205 AC_SUBST(lisppath)
1206 AC_SUBST(etcdir)
1207 AC_SUBST(lockdir)
1208 AC_SUBST(archlibdir)
1209 AC_SUBST(docdir)
1210 AC_SUBST(bitmapdir)
1211 AC_SUBST(c_switch_system)
1212 AC_SUBST(c_switch_machine)
1213 AC_SUBST(LD_SWITCH_X_SITE)
1214 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1215 AC_SUBST(C_SWITCH_X_SITE)
1216 AC_SUBST(CFLAGS)
1217 AC_SUBST(X_TOOLKIT_TYPE)
1218 AC_SUBST(machfile)
1219 AC_SUBST(opsysfile)
1220
1221 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
1222 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1223 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
1224 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1225 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1226 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1227 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
1228 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
1229
1230 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1231   AC_DEFINE(HAVE_X_WINDOWS)
1232 fi
1233 if test "${USE_X_TOOLKIT}" != "none" ; then
1234   AC_DEFINE(USE_X_TOOLKIT)
1235 fi
1236 if test "${HAVE_X11}" = "yes" ; then
1237   AC_DEFINE(HAVE_X11)
1238 fi
1239 if test "${HAVE_XFREE386}" = "yes" ; then
1240   AC_DEFINE(HAVE_XFREE386)
1241 fi
1242 if test "${HAVE_X_MENU}" = "yes" ; then
1243   AC_DEFINE(HAVE_X_MENU)
1244 fi
1245 if test "${GNU_MALLOC}" = "yes" ; then
1246   AC_DEFINE(GNU_MALLOC)
1247 fi
1248 if test "${REL_ALLOC}" = "yes" ; then
1249   AC_DEFINE(REL_ALLOC)
1250 fi
1251 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1252   AC_DEFINE(LISP_FLOAT_TYPE)
1253 fi
1254
1255 #### Report on what we decided to do.
1256 echo "
1257
1258 Configured for \`${canonical}'.
1259
1260   Where should the build process find the source code?    ${srcdir}
1261   What operating system and machine description files should Emacs use?
1262         \`${opsysfile}' and \`${machfile}'
1263   What compiler should emacs be built with?               ${CC} ${CFLAGS}
1264   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
1265   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
1266   What window system should Emacs use?                    ${window_system}
1267   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}${x_includes+
1268   Where do we find X Windows header files?                }${x_includes}${x_libraries+
1269   Where do we find X Windows libraries?                   }${x_libraries}
1270
1271 "
1272
1273 # Remove any trailing slashes in these variables.
1274 changequote(, )dnl
1275 test "${prefix}" != NONE &&
1276   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1277 test "${exec_prefix}" != NONE &&
1278   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1279 changequote([, ])dnl
1280
1281 AC_OUTPUT(Makefile lib-src/Makefile.in oldXMenu/Makefile \
1282         man/Makefile lwlib/Makefile src/Makefile.in, [
1283
1284 ### Make the necessary directories, if they don't exist.
1285 for dir in cpp etc ; do
1286   test -d ${dir} || mkdir ${dir}
1287 done
1288
1289 # Build src/Makefile from ${srcdir}/src/Makefile.in.  This must be done
1290 # after src/config.h is built, since we rely on that file.
1291
1292 changequote(, )dnl The horror, the horror.
1293 # Now get this: Some word that is part of the ${srcdir} directory name
1294 # or the ${configuration} value might, just might, happen to be an
1295 # identifier like `sun4' or `i386' or something, and be predefined by
1296 # the C preprocessor to some helpful value like 1, or maybe the empty
1297 # string.  Needless to say consequent macro substitutions are less
1298 # than conducive to the makefile finding the correct directory.
1299 undefs="`echo $top_srcdir $configuration $canonical |
1300 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
1301     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1302 `"
1303 changequote([, ])dnl
1304
1305 echo creating lib-src/Makefile
1306 ( cd lib-src
1307   rm -f junk.c junk1.c junk2.c
1308   sed -e '/start of cpp stuff/q' \
1309       < Makefile.in > junk1.c
1310   sed -e '1,/start of cpp stuff/d'\
1311       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1312       < Makefile.in > junk.c
1313   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1314       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1315   cat junk1.c junk2.c > Makefile.new
1316   rm -f junk.c junk1.c junk2.c
1317   chmod 444 Makefile.new
1318   mv -f Makefile.new Makefile
1319 )
1320
1321 echo creating src/Makefile
1322 ( cd src
1323   rm -f junk.c junk1.c junk2.c
1324   sed -e '/start of cpp stuff/q' \
1325       < Makefile.in > junk1.c
1326   sed -e '1,/start of cpp stuff/d'\
1327       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1328       < Makefile.in > junk.c
1329   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1330       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1331   cat junk1.c junk2.c > Makefile.new
1332   rm -f junk.c junk1.c junk2.c
1333   chmod 444 Makefile.new
1334   mv -f Makefile.new Makefile
1335 )
1336
1337 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1338   echo creating src/.gdbinit
1339   echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1340 fi
1341
1342 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])