lisp/xt-mouse.el

   1 ;;; xt-mouse.el --- support the mouse when emacs run in an xterm
   2
   3 ;; Copyright (C) 1994, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Keywords: mouse, terminals
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Enable mouse support when running inside an xterm.
  29
  30 ;; This is actually useful when you are running X11 locally, but is
  31 ;; working on remote machine over a modem line or through a gateway.
  32
  33 ;; It works by translating xterm escape codes into generic emacs mouse
  34 ;; events so it should work with any package that uses the mouse.
  35
  36 ;; You don't have to turn off xterm mode to use the normal xterm mouse
  37 ;; functionality, it is still available by holding down the SHIFT key
  38 ;; when you press the mouse button.
  39
  40 ;;; Todo:
  41
  42 ;; Support multi-click -- somehow.
  43
  44 ;;; Code:
  45
  46 (defvar xterm-mouse-debug-buffer nil)
  47
  48 (defvar xterm-mouse-last)
  49
  50 ;; Mouse events symbols must have an 'event-kind property with
  51 ;; the value 'mouse-click.
  52 (dolist (event-type '(mouse-1 mouse-2 mouse-3
  53                               M-down-mouse-1 M-down-mouse-2 M-down-mouse-3))
  54   (put event-type 'event-kind 'mouse-click))
  55
  56 (defun xterm-mouse-translate (event)
  57   "Read a click and release event from XTerm."
  58   (save-excursion
  59     (save-window-excursion
  60       (deactivate-mark)
  61       (let* ((xterm-mouse-last)
  62              (down (xterm-mouse-event))
  63              (down-command (nth 0 down))
  64              (down-data (nth 1 down))
  65              (down-where (nth 1 down-data))
  66              (down-binding (key-binding (if (symbolp down-where)
  67                                             (vector down-where down-command)
  68                                           (vector down-command))))
  69              (is-click (string-match "^mouse" (symbol-name (car down)))))
  70
  71         (unless is-click
  72           (unless (and (eq (read-char) ?\e)
  73                        (eq (read-char) ?\[)
  74                        (eq (read-char) ?M))
  75             (error "Unexpected escape sequence from XTerm")))
  76
  77         (let* ((click (if is-click down (xterm-mouse-event)))
  78                ;; (click-command (nth 0 click))
  79                (click-data (nth 1 click))
  80                (click-where (nth 1 click-data)))
  81           (if (memq down-binding '(nil ignore))
  82               (if (and (symbolp click-where)
  83                        (consp click-where))
  84                   (vector (list click-where click-data) click)
  85                 (vector click))
  86             (setq unread-command-events
  87                   (if (eq down-where click-where)
  88                       (list click)
  89                     (list
  90                      ;; Cheat `mouse-drag-region' with move event.
  91                      (list 'mouse-movement click-data)
  92                      ;; Generate a drag event.
  93                      (if (symbolp down-where)
  94                          0
  95                        (list (intern (format "drag-mouse-%d"
  96                                              (+ 1 xterm-mouse-last)))
  97                              down-data click-data)))))
  98             (if xterm-mouse-debug-buffer
  99                 (print unread-command-events xterm-mouse-debug-buffer))
 100             (if (and (symbolp down-where)
 101                      (consp down-where))
 102                 (vector (list down-where down-data) down)
 103               (vector down))))))))
 104
 105 ;; These two variables have been converted to terminal parameters.
 106 ;;
 107 ;;(defvar xterm-mouse-x 0
 108 ;;  "Position of last xterm mouse event relative to the frame.")
 109 ;;
 110 ;;(defvar xterm-mouse-y 0
 111 ;;  "Position of last xterm mouse event relative to the frame.")
 112
 113 (defvar xt-mouse-epoch nil)
 114
 115 ;; Indicator for the xterm-mouse mode.
 116
 117 (defun xterm-mouse-position-function (pos)
 118   "Bound to `mouse-position-function' in XTerm mouse mode."
 119   (when (terminal-parameter nil 'xterm-mouse-x)
 120     (setcdr pos (cons (terminal-parameter nil 'xterm-mouse-x)
 121                       (terminal-parameter nil 'xterm-mouse-y))))
 122   pos)
 123
 124 ;; read xterm sequences above ascii 127 (#x7f)
 125 (defun xterm-mouse-event-read ()
 126   (let ((c (read-char)))
 127     (if (< c 0)
 128         (+ c #x8000000 128)
 129       c)))
 130
 131 (defun xterm-mouse-truncate-wrap (f)
 132   "Truncate with wrap-around."
 133   (condition-case nil
 134       ;; First try the built-in truncate, in case there's no overflow.
 135       (truncate f)
 136     ;; In case of overflow, do wraparound by hand.
 137     (range-error
 138      ;; In our case, we wrap around every 3 days or so, so if we assume
 139      ;; a maximum of 65536 wraparounds, we're safe for a couple years.
 140      ;; Using a power of 2 makes rounding errors less likely.
 141      (let* ((maxwrap (* 65536 2048))
 142             (dbig (truncate (/ f maxwrap)))
 143             (fdiff (- f (* 1.0 maxwrap dbig))))
 144        (+ (truncate fdiff) (* maxwrap dbig))))))
 145
 146 (defun xterm-mouse-event ()
 147   "Convert XTerm mouse event to Emacs mouse event."
 148   (let* ((type (- (xterm-mouse-event-read) #o40))
 149          (x (- (xterm-mouse-event-read) #o40 1))
 150          (y (- (xterm-mouse-event-read) #o40 1))
 151          ;; Emulate timestamp information.  This is accurate enough
 152          ;; for default value of mouse-1-click-follows-link (450msec).
 153          (timestamp (xterm-mouse-truncate-wrap
 154                      (* 1000
 155                         (- (float-time)
 156                            (or xt-mouse-epoch
 157                                (setq xt-mouse-epoch (float-time)))))))
 158          (mouse (intern
 159                  ;; For buttons > 3, the release-event looks
 160                  ;; differently (see xc/programs/xterm/button.c,
 161                  ;; function EditorButton), and there seems to come in
 162                  ;; a release-event only, no down-event.
 163                  (cond ((>= type 64)
 164                         (format "mouse-%d" (- type 60)))
 165                        ((memq type '(8 9 10))
 166                         (setq xterm-mouse-last type)
 167                         (format "M-down-mouse-%d" (- type 7)))
 168                        ((= type 11)
 169                         (format "mouse-%d" (- xterm-mouse-last 7)))
 170                        ((= type 3)
 171                         ;; For buttons > 5 xterm only reports a
 172                         ;; button-release event.  Avoid error by mapping
 173                         ;; them all to mouse-1.
 174                         (format "mouse-%d" (+ 1 (or xterm-mouse-last 0))))
 175                        (t
 176                         (setq xterm-mouse-last type)
 177                         (format "down-mouse-%d" (+ 1 type))))))
 178          (w (window-at x y))
 179          (ltrb (window-edges w))
 180          (left (nth 0 ltrb))
 181          (top (nth 1 ltrb)))
 182
 183     (set-terminal-parameter nil 'xterm-mouse-x x)
 184     (set-terminal-parameter nil 'xterm-mouse-y y)
 185     (setq
 186      last-input-event
 187      (list mouse
 188            (let ((event (if w
 189                             (posn-at-x-y (- x left) (- y top) w t)
 190                           (append (list nil 'menu-bar)
 191                                   (nthcdr 2 (posn-at-x-y x y))))))
 192              (setcar (nthcdr 3 event) timestamp)
 193              event)))))
 194
 195 ;;;###autoload
 196 (define-minor-mode xterm-mouse-mode
 197   "Toggle XTerm mouse mode.
 198 With prefix arg, turn XTerm mouse mode on if arg is positive, otherwise turn
 199 it off.
 200
 201 Turn it on to use Emacs mouse commands, and off to use xterm mouse commands.
 202 This works in terminal emulators compatible with xterm.  It only
 203 works for simple uses of the mouse.  Basically, only non-modified
 204 single clicks are supported.  When turned on, the normal xterm
 205 mouse functionality for such clicks is still available by holding
 206 down the SHIFT key while pressing the mouse button."
 207   :global t :group 'mouse
 208   (let ((do-hook (if xterm-mouse-mode 'add-hook 'remove-hook)))
 209     (funcall do-hook 'terminal-init-xterm-hook
 210              'turn-on-xterm-mouse-tracking-on-terminal)
 211     (funcall do-hook 'delete-terminal-functions
 212              'turn-off-xterm-mouse-tracking-on-terminal)
 213     (funcall do-hook 'suspend-tty-functions
 214              'turn-off-xterm-mouse-tracking-on-terminal)
 215     (funcall do-hook 'resume-tty-functions
 216              'turn-on-xterm-mouse-tracking-on-terminal)
 217     (funcall do-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
 218     (funcall do-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
 219     (funcall do-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking))
 220   (if xterm-mouse-mode
 221       ;; Turn it on
 222       (progn
 223         (setq mouse-position-function #'xterm-mouse-position-function)
 224         (turn-on-xterm-mouse-tracking))
 225     ;; Turn it off
 226     (turn-off-xterm-mouse-tracking 'force)
 227     (setq mouse-position-function nil)))
 228
 229 (defun turn-on-xterm-mouse-tracking ()
 230   "Enable Emacs mouse tracking in xterm."
 231   (dolist (terminal (delete-dups (mapcar 'frame-terminal (frame-list))))
 232     (turn-on-xterm-mouse-tracking-on-terminal terminal)))
 233
 234 (defun turn-off-xterm-mouse-tracking (&optional force)
 235   "Disable Emacs mouse tracking in xterm."
 236   (dolist (terminal (delete-dups (mapcar 'frame-terminal (frame-list))))
 237     (turn-off-xterm-mouse-tracking-on-terminal terminal)))
 238
 239 (defun turn-on-xterm-mouse-tracking-on-terminal (&optional terminal)
 240   "Enable xterm mouse tracking on TERMINAL."
 241   (when (and xterm-mouse-mode (eq t (terminal-live-p terminal)))
 242     (unless (terminal-parameter terminal 'xterm-mouse-mode)
 243       ;; Simulate selecting a terminal by selecting one of its frames ;-(
 244       (with-selected-frame (car (frames-on-display-list terminal))
 245         (define-key input-decode-map "\e[M" 'xterm-mouse-translate))
 246       (set-terminal-parameter terminal 'xterm-mouse-mode t))
 247     (send-string-to-terminal "\e[?1000h" terminal)))
 248
 249 (defun turn-off-xterm-mouse-tracking-on-terminal (terminal)
 250   "Disable xterm mouse tracking on TERMINAL."
 251   ;; Only send the disable command to those terminals to which we've already
 252   ;; sent the enable command.
 253   (when (and (terminal-parameter terminal 'xterm-mouse-mode)
 254              (eq t (terminal-live-p terminal)))
 255     ;; We could remove the key-binding and unset the `xterm-mouse-mode'
 256     ;; terminal parameter, but it seems less harmful to send this escape
 257     ;; command too many times (or to catch an unintended key sequence), than
 258     ;; to send it too few times (or to fail to let xterm-mouse events
 259     ;; pass by untranslated).
 260     (send-string-to-terminal "\e[?1000l" terminal)))
 261
 262 (provide 'xt-mouse)
 263
 264 ;; arch-tag: 84962d4e-fae9-4c13-a9d7-ef4925a4ac03
 265 ;;; xt-mouse.el ends here