lisp/dired-x.el

   1 ;;; dired-x.el --- Sebastian Kremer's Extra DIRED hacked up for GNU Emacs19
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: Lawrence R. Dodd <dodd@roebling.poly.edu>
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions
   9
  10 ;; Copyright (C) 1993, 1994 Free Software Foundation
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  26 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  31 ;;; 1.191, hacked up for GNU Emacs 19.  Redundant or conflicting material
  32 ;;; has been removed or renamed in order to work properly with dired of
  33 ;;; GNU Emacs 19.  All suggestions or comments are most welcomed.
  34
  35 ;;;
  36 ;;; Please, PLEASE, *PLEASE* see the info pages.
  37 ;;;
  38
  39 ;;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  40
  41 ;;; INSTALLATION: In your ~/.emacs,
  42 ;;;
  43 ;;; (add-hook 'dired-load-hook
  44 ;;;           (function (lambda ()
  45 ;;;                       (load "dired-x")
  46 ;;;                       ;; Set variables here.  For example:
  47 ;;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  48 ;;;                       ;; (setq dired-omit-files-p t)
  49 ;;;                       )))
  50 ;;;
  51 ;;; At load time dired-x.el will install itself, redefine some functions, and
  52 ;;; bind some dired keys.  *Please* see the info pages for more details.
  53
  54 ;;; CAUTION: If you are using a version of GNU Emacs earlier than 19.20 than
  55 ;;; you may have to edit dired.el.  The copy of dired.el in GNU Emacs versions
  56 ;;; earlier than 19.20 incorrectly had the call to run-hooks *before* the call
  57 ;;; to provide.  In such a case, it is possible that byte-compiling and/or
  58 ;;; loading dired can cause an infinite loop.  To prevent this, make sure the
  59 ;;; line of code
  60 ;;;
  61 ;;;         (run-hooks 'dired-load-hook)
  62 ;;;
  63 ;;; is the *last* executable line in the file dired.el.  That is, make sure it
  64 ;;; comes *after* the line
  65 ;;;
  66 ;;;         (provide 'dired)
  67 ;;;
  68 ;;; *Please* see the info pages for more details.
  69
  70 ;;; User defined variables:
  71 ;;;
  72 ;;;      dired-bind-vm
  73 ;;;      dired-vm-read-only-folders
  74 ;;;      dired-bind-jump
  75 ;;;      dired-bind-info
  76 ;;;      dired-bind-man
  77 ;;;      dired-x-hands-off-my-keys
  78 ;;;      dired-find-subdir
  79 ;;;      dired-enable-local-variables
  80 ;;;      dired-local-variables-file
  81 ;;;      dired-guess-shell-gnutar
  82 ;;;      dired-guess-shell-gzip-quiet
  83 ;;;      dired-guess-shell-znew-switches
  84 ;;;      dired-guess-shell-alist-user
  85 ;;;      dired-clean-up-buffers-too
  86 ;;;      dired-omit-files-p
  87 ;;;      dired-omit-files
  88 ;;;      dired-omit-extensions
  89 ;;;
  90 ;;; To find out more about these variables, load this file, put your cursor at
  91 ;;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  92 ;;; the info pages for more details.
  93
  94 ;;; When loaded this code redefines the following functions of GNU Emacs
  95 ;;;
  96 ;;;   Function                         Found in this file of GNU Emacs
  97 ;;;   --------                         -------------------------------
  98 ;;;   dired-clean-up-after-deletion    ../lisp/dired.el
  99 ;;;   dired-find-buffer-nocreate       ../lisp/dired.el
 100 ;;;   dired-initial-position           ../lisp/dired.el
 101 ;;;   dired-up-directory               ../lisp/dired.el
 102 ;;;
 103 ;;;   dired-add-entry                  ../lisp/dired-aux.el
 104 ;;;   dired-read-shell-command         ../lisp/dired-aux.el
 105 ;;;
 106 ;;; One drawback is that dired-x.el will load dired-aux.el as soon as dired is
 107 ;;; loaded.  Thus, the advantage of separating out non-essential dired stuff
 108 ;;; into dired-aux.el and only loading when necessary will be lost.  Please
 109 ;;; note also that some of the comments in dired.el and dired-aux.el are
 110 ;;; Kremer's that referred to the old dired-x.el.  This now should be referring
 111 ;;; to this program.  (This is also a good reason to call this dired-x.el
 112 ;;; instead of dired-x19.el.)
 113
 114 \f
 115 ;;;; Code:
 116
 117 ;;; LOAD.
 118
 119 ;;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 120 ;;; here in case the user has autoloaded dired-x via the dired-jump key binding
 121 ;;; (instead of autoloading to dired as is suggested in the info-pages).
 122
 123 (require 'dired)
 124
 125 ;;; We will redefine some functions and also need some macros so we need to
 126 ;;; load dired stuff of GNU Emacs.
 127
 128 (require 'dired-aux)
 129
 130 ;;;; User-defined variables.
 131
 132 (defvar dired-bind-vm nil
 133   "*t says \"V\" in dired-mode will `dired-vm', otherwise \"V\" is `dired-rmail'.
 134 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 135 `dired-advertised-find-file', will run rmail.")
 136
 137 (defvar dired-bind-jump t
 138   "*t says bind `dired-jump' to C-x C-j, otherwise do not.")
 139
 140 (defvar dired-bind-man t
 141   "*t says bind `dired-man' to \"N\" in dired-mode, otherwise do not.")
 142
 143 (defvar dired-bind-info t
 144   "*t says bind `dired-info' to \"I\" in dired-mode, otherwise do not.")
 145
 146 (defvar dired-vm-read-only-folders nil
 147   "*If t, \\[dired-vm] will visit all folders read-only.
 148 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 149 files not writable by you are visited read-only.
 150
 151 Read-only folders only work in VM 5, not in VM 4.")
 152
 153 (defvar dired-omit-files-p nil
 154   "*If non-nil, \"uninteresting\" files are not listed (buffer-local).
 155 Use \\[dired-omit-toggle] to toggle its value.
 156 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 157 plus those ending with extensions in `dired-omit-extensions'.")
 158
 159 (defvar dired-omit-files "^#\\|^\\.$\\|^\\.\\.$"
 160   "*Filenames matching this regexp will not be displayed \(buffer-local\).
 161 This only has effect when `dired-omit-files-p' is t.  See interactive function
 162 `dired-omit-toggle' \(\\[dired-omit-toggle]\) and variable
 163 `dired-omit-extensions'.  The default is to omit  `.', `..', and auto-save
 164 files.")
 165
 166 (defvar dired-find-subdir nil           ; t is pretty near to DWIM...
 167   "*If non-nil, Dired does not make a new buffer for a directory if it
 168 can be found (perhaps as subdir) in some existing Dired buffer.
 169
 170 If there are several Dired buffers for a directory, the most recently
 171 used is chosen.
 172
 173 Dired avoids switching to the current buffer, so that if you have
 174 a normal and a wildcard buffer for the same directory, C-x d RET will
 175 toggle between those two.")
 176
 177 (defvar dired-enable-local-variables t
 178   "*Control use of local-variables lists in dired.
 179 The value can be t, nil or something else.
 180 A value of t means local-variables lists are obeyed;
 181 nil means they are ignored; anything else means query.
 182
 183 This temporarily overrides the value of `enable-local-variables' when listing
 184 a directory.  See also `dired-local-variables-file'.")
 185
 186 (defvar dired-guess-shell-gnutar nil
 187   "*If non-nil, name of GNU tar executable (e.g., \"tar\" or \"gtar\") and `z'
 188 switch will be used for compressed or gzip'ed tar files.  If no GNU tar, set
 189 to nil: a pipe using `zcat' or `gunzip -c' will be used.")
 190
 191 (defvar dired-guess-shell-gzip-quiet t
 192   "*non-nil says pass -q to gzip overriding verbose GZIP environment.")
 193
 194 (defvar dired-guess-shell-znew-switches nil
 195   "*If non-nil, then string of switches passed to `znew', example: \"-K\"")
 196
 197 (defvar dired-clean-up-buffers-too t
 198   "*t says offer to kill buffers visiting files and dirs deleted in dired.")
 199
 200 ;;;; KEY BINDINGS.
 201
 202 (define-key dired-mode-map "\M-o" 'dired-omit-toggle)
 203 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 204 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 205 (define-key dired-mode-map "T" 'dired-do-toggle)
 206 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 207 (define-key dired-mode-map "\M-g" 'dired-goto-file)
 208 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 209 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 210 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 211 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 212 (define-key dired-mode-map "V" 'dired-do-run-mail)
 213
 214 (if dired-bind-man
 215     (define-key dired-mode-map "N" 'dired-man))
 216
 217 (if dired-bind-info
 218     (define-key dired-mode-map "I" 'dired-info))
 219
 220 ;;; GLOBAL BINDING.
 221 (if dired-bind-jump
 222     (progn
 223       (define-key global-map "\C-x\C-j" 'dired-jump)
 224       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 225
 226 \f
 227 ;;;; Install into appropriate hooks.
 228
 229 (add-hook 'dired-mode-hook 'dired-extra-startup)
 230 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 231
 232 (defun dired-extra-startup ()
 233   "Automatically put on dired-mode-hook to get extra dired features:
 234 \\<dired-mode-map>
 235
 236   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 237   \\[dired-info]\t-- run info on file
 238   \\[dired-man]\t-- run man on file
 239   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 240   \\[dired-omit-toggle]\t-- toggle omitting of files
 241   \\[dired-do-toggle]\t-- toggle marks
 242   \\[dired-mark-sexp]\t-- mark by lisp expression
 243   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring.
 244   \t   You can feed it to other commands using \\[yank].
 245
 246 For more features, see variables
 247
 248   dired-bind-vm
 249   dired-bind-jump
 250   dired-bind-info
 251   dired-bind-man
 252   dired-vm-read-only-folders
 253   dired-omit-files-p
 254   dired-omit-files
 255   dired-omit-extensions
 256   dired-find-subdir
 257   dired-enable-local-variables
 258   dired-local-variables-file
 259   dired-guess-shell-gnutar
 260   dired-guess-shell-gzip-quiet
 261   dired-guess-shell-znew-switches
 262   dired-guess-shell-alist-user
 263   dired-clean-up-buffers-too
 264
 265 See also functions
 266
 267   dired-flag-extension
 268   dired-virtual
 269   dired-jump
 270   dired-man
 271   dired-vm
 272   dired-rmail
 273   dired-info
 274   dired-do-find-marked-files
 275 "
 276   (interactive)
 277
 278   ;; These must be done in each new dired buffer.
 279   (dired-hack-local-variables)
 280   (dired-omit-startup))
 281
 282 \f
 283 ;;;; BUFFER CLEANING.
 284
 285 ;;; REDEFINE.
 286 (defun dired-clean-up-after-deletion (fn)
 287
 288   ;; Clean up after a deleted file or directory FN.
 289   ;; Remove expanded subdir of deleted dir, if any.
 290   (save-excursion (and (cdr dired-subdir-alist)
 291                        (dired-goto-subdir fn)
 292                        (dired-kill-subdir)))
 293
 294   ;; Offer to kill buffer of deleted file FN.
 295   (if dired-clean-up-buffers-too
 296       (progn
 297         (let ((buf (get-file-buffer fn)))
 298           (and buf
 299                (funcall (function y-or-n-p)
 300                         (format "Kill buffer of %s, too? "
 301                                 (file-name-nondirectory fn)))
 302                (save-excursion ; you never know where kill-buffer leaves you
 303                  (kill-buffer buf))))
 304         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 305               (buf nil))
 306           (and buf-list
 307                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 308                                  (dired-plural-s (length buf-list))
 309                                  (file-name-nondirectory fn)))
 310                (while buf-list
 311                  (save-excursion (kill-buffer (car buf-list)))
 312                  (setq buf-list (cdr buf-list)))))))
 313   ;; Anything else?
 314   )
 315
 316 \f
 317 ;;;; EXTENSION MARKING FUNCTIONS.
 318
 319 ;;; Mark files with some extension.
 320 (defun dired-mark-extension (extension &optional marker-char)
 321   "Mark all files with a certain extension for use in later commands.
 322 A `.' is not automatically prepended to the string entered."
 323   ;; EXTENSION may also be a list of extensions instead of a single one.
 324   ;; Optional MARKER-CHAR is marker to use.
 325   (interactive "sMarking extension: \nP")
 326   (or (listp extension)
 327       (setq extension (list extension)))
 328   (dired-mark-files-regexp
 329    (concat ".";; don't match names with nothing but an extension
 330            "\\("
 331            (mapconcat 'regexp-quote extension "\\|")
 332            "\\)$")
 333    marker-char))
 334
 335 (defun dired-flag-extension (extension)
 336   "In dired, flag all files with a certain extension for deletion.
 337 A `.' is *not* automatically prepended to the string entered."
 338   (interactive "sFlagging extension: ")
 339   (dired-mark-extension extension dired-del-marker))
 340
 341 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 342
 343 (defvar dired-patch-unclean-extensions
 344   '(".rej" ".orig")
 345   "List of extensions of dispensable files created by the `patch' program.")
 346
 347 (defvar dired-tex-unclean-extensions
 348   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 349   "List of extensions of dispensable files created by TeX.")
 350
 351 (defvar dired-latex-unclean-extensions
 352   '(".idx" ".lof" ".lot" ".glo")
 353   "List of extensions of dispensable files created by LaTeX.")
 354
 355 (defvar dired-bibtex-unclean-extensions
 356   '(".blg" ".bbl")
 357   "List of extensions of dispensable files created by BibTeX.")
 358
 359 (defvar dired-texinfo-unclean-extensions
 360   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 361     ".tp" ".tps" ".vr" ".vrs")
 362   "List of extensions of dispensable files created by texinfo.")
 363
 364 (defun dired-clean-patch ()
 365   "Flag dispensable files created by patch for deletion.
 366 See variable `dired-patch-unclean-extensions'."
 367   (interactive)
 368   (dired-flag-extension dired-patch-unclean-extensions))
 369
 370 (defun dired-clean-tex ()
 371   "Flag dispensable files created by [La]TeX etc. for deletion.
 372 See variables `dired-texinfo-unclean-extensions',
 373 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 374 `dired-texinfo-unclean-extensions'."
 375   (interactive)
 376   (dired-flag-extension (append dired-texinfo-unclean-extensions
 377                                 dired-latex-unclean-extensions
 378                                 dired-bibtex-unclean-extensions
 379                                 dired-tex-unclean-extensions)))
 380
 381 (defun dired-very-clean-tex ()
 382   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 383 See variables `dired-texinfo-unclean-extensions',
 384 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 385 `dired-texinfo-unclean-extensions'."
 386   (interactive)
 387   (dired-flag-extension (append dired-texinfo-unclean-extensions
 388                                 dired-latex-unclean-extensions
 389                                 dired-bibtex-unclean-extensions
 390                                 dired-tex-unclean-extensions
 391                                 (list ".dvi"))))
 392 \f
 393 ;;;; JUMP.
 394
 395 ;;;###autoload
 396 (defun dired-jump (&optional other-window)
 397   "Jump to dired buffer corresponding to current buffer.
 398 If in a file, dired the current directory and move to file's line.
 399 If in dired already, pop up a level and goto old directory's line.
 400 In case the proper dired file line cannot be found, refresh the dired
 401 buffer and try again."
 402   (interactive "P")
 403   (let* ((file buffer-file-name)
 404          (dir (if file (file-name-directory file) default-directory)))
 405     (if (eq major-mode 'dired-mode)
 406         (progn
 407           (setq dir (dired-current-directory))
 408           (dired-up-directory other-window)
 409           (or (dired-goto-file dir)
 410               ;; refresh and try again
 411               (progn
 412                 (dired-insert-subdir (file-name-directory dir))
 413                 (dired-goto-file dir))))
 414       (if other-window
 415           (dired-other-window dir)
 416         (dired dir))
 417       (if file
 418           (or (dired-goto-file file)
 419               ;; Toggle omitting, if necessary, and try again.
 420               (progn
 421                 (dired-omit-toggle t)
 422                 (dired-goto-file file))
 423               ;; refresh and try again
 424               (progn
 425                 (dired-insert-subdir (file-name-directory file))
 426                 (dired-goto-file file)))))))
 427
 428 (defun dired-jump-other-window ()
 429   "Like \\[dired-jump] (dired-jump) but in other window."
 430   (interactive)
 431   (dired-jump t))
 432
 433 ;;; REDEFINE.
 434 ;;; This replaces the version in dired.el
 435 ;;; It simply adds the OTHER-WINDOW option to the one in dired.el.
 436 (defun dired-up-directory (&optional other-window)
 437   "Run dired on parent directory of current directory.
 438 Find the parent directory either in this buffer or another buffer.
 439 Finds in current window or in other window with optional OTHER-WINDOW.
 440 Creates a buffer if necessary."
 441   (interactive "P")
 442   (let* ((dir (dired-current-directory))
 443          (up (file-name-directory (directory-file-name dir))))
 444     (or (dired-goto-file (directory-file-name dir))
 445         ;; Only try dired-goto-subdir if buffer has more than one dir.
 446         (and (cdr dired-subdir-alist)
 447              (dired-goto-subdir up))
 448         (progn
 449           (if other-window
 450               (dired-other-window up)
 451             (dired up))
 452           (dired-goto-file dir)))))
 453
 454 \f
 455 ;;;; TOGGLE.
 456 ;;; Toggle marked files with unmarked files.
 457
 458 (defun dired-do-toggle ()
 459   "Toggle marks.
 460 That is, currently marked files become unmarked and vice versa.
 461 Files marked with other flags (such as `D') are not affected.
 462 `.' and `..' are never toggled.
 463 As always, hidden subdirs are not affected."
 464   (interactive)
 465   (save-excursion
 466     (goto-char (point-min))
 467     (let (buffer-read-only)
 468       (while (not (eobp))
 469         (or (dired-between-files)
 470             (looking-at dired-re-dot)
 471             ;; use subst instead of insdel because it does not move
 472             ;; the gap and thus should be faster and because
 473             ;; other characters are left alone automatically
 474             (apply 'subst-char-in-region
 475                    (point) (1+ (point))
 476                    (if (eq ?\040 (following-char)) ; SPC
 477                        (list ?\040 dired-marker-char)
 478                      (list dired-marker-char ?\040))))
 479         (forward-line 1)))))
 480
 481 \f
 482 ;;;; COPY NAMES OF MARKED FILES INTO KILL-RING.
 483
 484 (defun dired-copy-filename-as-kill (&optional arg)
 485   "Copy names of marked (or next ARG) files into the kill ring.
 486 The names are separated by a space.
 487 With a zero prefix arg, use the complete pathname of each marked file.
 488 With \\[universal-argument], use the relative pathname of each marked file.
 489
 490 If on a subdir headerline, use subdirname instead; prefix arg is ignored
 491 in this case.
 492
 493 You can then feed the file name(s) to other commands with \\[yank]."
 494   (interactive "P")
 495   (let ((string
 496          (or (dired-get-subdir)
 497              (mapconcat (function identity)
 498                         (if arg
 499                             (cond ((zerop (prefix-numeric-value arg))
 500                                    (dired-get-marked-files))
 501                                   ((integerp arg)
 502                                    (dired-get-marked-files 'no-dir arg))
 503                                   (t    ; else a raw arg
 504                                    (dired-get-marked-files t)))
 505                           (dired-get-marked-files 'no-dir))
 506                         " "))))
 507     (kill-new string)
 508     (message "%s" string)))
 509
 510 \f
 511 ;;;; OMITTING.
 512
 513 ;;; Enhanced omitting of lines from directory listings.
 514 ;;; Marked files are never omitted.
 515
 516 ;; should probably get rid of this and always use 'no-dir.
 517 ;; sk 28-Aug-1991 09:37
 518 (defvar dired-omit-localp 'no-dir
 519   "The LOCALP argument dired-omit-expunge passes to dired-get-filename.
 520 If it is 'no-dir, omitting is much faster, but you can only match
 521 against the basename of the file.  Set it to nil if you need to match the
 522 whole pathname.")
 523
 524 ;; \017=^O for Omit - other packages can chose other control characters.
 525 (defvar dired-omit-marker-char ?\017
 526   "Temporary marker used by by dired-omit.
 527 Should never be used as marker by the user or other packages.")
 528
 529 (defun dired-omit-startup ()
 530   (make-local-variable 'dired-omit-files-p)
 531   (or (assq 'dired-omit-files-p minor-mode-alist)
 532       (setq minor-mode-alist
 533             (append '((dired-omit-files-p " Omit")) minor-mode-alist))))
 534
 535 (defun dired-omit-toggle (&optional flag)
 536   "Toggle omitting files matching `dired-omit-files' and `dired-omit-extensions'.
 537 With an arg, and if omitting was off, don't toggle and just mark the
 538   files but don't actually omit them.
 539 With an arg, and if omitting was on, turn it off but don't refresh the buffer."
 540   (interactive "P")
 541   (if flag
 542       (if dired-omit-files-p
 543           (setq dired-omit-files-p (not dired-omit-files-p))
 544         (dired-mark-unmarked-files (dired-omit-regexp) nil nil
 545                                    dired-omit-localp))
 546     ;; no FLAG
 547     (setq dired-omit-files-p (not dired-omit-files-p))
 548     (if (not dired-omit-files-p)
 549         (revert-buffer)
 550       ;; this will mention how many were omitted:
 551       (dired-omit-expunge))))
 552
 553 (defvar dired-omit-extensions
 554   (append completion-ignored-extensions
 555           dired-latex-unclean-extensions
 556           dired-bibtex-unclean-extensions
 557           dired-texinfo-unclean-extensions)
 558   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 559 Defaults to elements of `completion-ignored-extensions',
 560 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 561 `dired-texinfo-unclean-extensions'.
 562
 563 See interactive function `dired-omit-toggle' \(\\[dired-omit-toggle]\) and
 564 variables `dired-omit-files-p' and `dired-omit-files'.")
 565
 566 (defun dired-omit-expunge (&optional regexp)
 567   "Erases all unmarked files matching REGEXP.
 568 Does nothing if global variable `dired-omit-files-p' is nil.
 569 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 570   filenames ending in `dired-omit-extensions'.
 571 If REGEXP is the empty string, this function is a no-op.
 572
 573 This functions works by temporarily binding `dired-marker-char' to
 574 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 575   (interactive "sOmit files (regexp): ")
 576   (if dired-omit-files-p
 577       (let ((omit-re (or regexp (dired-omit-regexp)))
 578             (old-modified-p (buffer-modified-p))
 579             count)
 580         (or (string= omit-re "")
 581             (let ((dired-marker-char dired-omit-marker-char))
 582               (message "Omitting...")
 583               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 584                   (progn
 585                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 586                     ;; Force an update of modeline.
 587                     (set-buffer-modified-p (buffer-modified-p)))
 588                 (message "(Nothing to omit)"))))
 589         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 590         ;; in mode-line of omitted buffers.
 591         (set-buffer-modified-p (and old-modified-p
 592                                     (save-excursion
 593                                       (goto-char (point-min))
 594                                       (re-search-forward dired-re-mark nil t))))
 595         count)))
 596
 597 (defun dired-omit-regexp ()
 598   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 599           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 600           (if dired-omit-extensions
 601               (concat ".";; a non-extension part should exist
 602                       "\\("
 603                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 604                       "\\)$")
 605             "")))
 606
 607 ;; Returns t if any work was done, nil otherwise.
 608 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 609   "Marks unmarked files matching REGEXP, displaying MSG.
 610 REGEXP is matched against the complete pathname.
 611 Does not re-mark files which already have a mark.
 612 With prefix argument, unflag all those files.
 613 Second optional argument LOCALP is as in `dired-get-filename'."
 614   (interactive "P")
 615   (let ((dired-marker-char (if unflag-p ?\  dired-marker-char)))
 616     (dired-mark-if
 617      (and
 618       ;; not already marked
 619       (looking-at " ")
 620       ;; uninteresting
 621       (let ((fn (dired-get-filename localp t)))
 622         (and fn (string-match regexp fn))))
 623      msg)))
 624
 625 ;;; REDEFINE.
 626 (defun dired-omit-new-add-entry (filename &optional marker-char)
 627   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 628   ;; files that are going to be omitted anyway.
 629   (if dired-omit-files-p
 630       ;; perhaps return t without calling ls
 631       (let ((omit-re (dired-omit-regexp)))
 632         (if (or (string= omit-re "")
 633                 (not
 634                  (string-match omit-re
 635                                (cond
 636                                 ((eq 'no-dir dired-omit-localp)
 637                                  filename)
 638                                 ((eq t dired-omit-localp)
 639                                  (dired-make-relative filename))
 640                                 (t
 641                                  (dired-make-absolute
 642                                   filename
 643                                   (file-name-directory filename)))))))
 644             ;; if it didn't match, go ahead and add the entry
 645             (dired-omit-old-add-entry filename marker-char)
 646           ;; dired-add-entry returns t for success, perhaps we should
 647           ;; return file-exists-p
 648           t))
 649     ;; omitting is not turned on at all
 650     (dired-omit-old-add-entry filename marker-char)))
 651
 652 ;;; REDEFINE.
 653 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 654 ;;; Save old defun if not already done:
 655 (or (fboundp 'dired-omit-old-add-entry)
 656     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 657 ;; Redefine it.
 658 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 659
 660 \f
 661 ;;;; VIRTUAL DIRED MODE.
 662
 663 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 664
 665 (fset 'virtual-dired 'dired-virtual)
 666 (defun dired-virtual (dirname &optional switches)
 667   "Put this buffer into Virtual Dired mode.
 668
 669 In Virtual Dired mode, all commands that do not actually consult the
 670 filesystem will work.
 671
 672 This is useful if you want to peruse and move around in an ls -lR
 673 output file, for example one you got from an ftp server.  With
 674 ange-ftp, you can even dired a directory containing an ls-lR file,
 675 visit that file and turn on virtual dired mode.  But don't try to save
 676 this file, as dired-virtual indents the listing and thus changes the
 677 buffer.
 678
 679 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 680 resume it in a later session.
 681
 682 Type \\<dired-mode-map>\\[revert-buffer] in the
 683 Virtual Dired buffer and answer `y' to convert the virtual to a real
 684 dired buffer again.  You don't have to do this, though: you can relist
 685 single subdirs using \\[dired-do-redisplay].
 686 "
 687
 688   ;; DIRNAME is the top level directory of the buffer.  It will become
 689   ;; its `default-directory'.  If nil, the old value of
 690   ;; default-directory is used.
 691
 692   ;; Optional SWITCHES are the ls switches to use.
 693
 694   ;; Shell wildcards will be used if there already is a `wildcard'
 695   ;; line in the buffer (thus it is a saved Dired buffer), but there
 696   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 697   ;; hand if you want them.
 698
 699   (interactive
 700    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 701   (goto-char (point-min))
 702   (or (looking-at "  ")
 703       ;; if not already indented, do it now:
 704       (indent-region (point-min) (point-max) 2))
 705   (or dirname (setq dirname default-directory))
 706   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 707   (setq default-directory dirname)      ; contains no wildcards
 708   (let ((wildcard (save-excursion
 709                     (goto-char (point-min))
 710                     (forward-line 1)
 711                     (and (looking-at "^  wildcard ")
 712                          (buffer-substring (match-end 0)
 713                                            (progn (end-of-line) (point)))))))
 714   (if wildcard
 715         (setq dirname (expand-file-name wildcard default-directory))))
 716   ;; If raw ls listing (not a saved old dired buffer), give it a
 717   ;; decent subdir headerline:
 718   (goto-char (point-min))
 719   (or (looking-at dired-subdir-regexp)
 720       (dired-insert-headerline default-directory))
 721   (dired-mode dirname (or switches dired-listing-switches))
 722   (setq mode-name "Virtual Dired"
 723         revert-buffer-function 'dired-virtual-revert)
 724   (set (make-local-variable 'dired-subdir-alist) nil)
 725   (dired-build-subdir-alist)
 726   (goto-char (point-min))
 727   (dired-initial-position dirname))
 728
 729 (defun dired-virtual-guess-dir ()
 730
 731   ;; Guess and return appropriate working directory of this buffer,
 732   ;; assumed to be in Dired or ls -lR format.
 733   ;; The guess is based upon buffer contents.
 734   ;; If nothing could be guessed, returns nil.
 735
 736   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 737         (subexpr 2))
 738     (goto-char (point-min))
 739     (cond ((looking-at regexp)
 740            ;; If a saved dired buffer, look to which dir and
 741            ;; perhaps wildcard it belongs:
 742            (let ((dir (buffer-substring (match-beginning subexpr)
 743                                         (match-end subexpr))))
 744              (file-name-as-directory dir)))
 745           ;; Else no match for headerline found.  It's a raw ls listing.
 746           ;; In raw ls listings the directory does not have a headerline
 747           ;; try parent of first subdir, if any
 748           ((re-search-forward regexp nil t)
 749            (file-name-directory
 750             (directory-file-name
 751              (file-name-as-directory
 752               (buffer-substring (match-beginning subexpr)
 753                                 (match-end subexpr))))))
 754           (t                            ; if all else fails
 755            nil))))
 756
 757
 758 (defun dired-virtual-revert (&optional arg noconfirm)
 759   (if (not
 760        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 761       (error "Cannot revert a Virtual Dired buffer.")
 762     (setq mode-name "Dired"
 763           revert-buffer-function 'dired-revert)
 764     (revert-buffer)))
 765
 766 ;; A zero-arg version of dired-virtual.
 767 ;; You need my modified version of set-auto-mode for the
 768 ;; `buffer-contents-mode-alist'.
 769 ;; Or you use infer-mode.el and infer-mode-alist, same syntax.
 770 (defun dired-virtual-mode ()
 771   "Put current buffer into virtual dired mode (see `dired-virtual').
 772 Useful on `buffer-contents-mode-alist' (which see) with the regexp
 773
 774     \"^  \\(/[^ /]+\\)/?+:$\"
 775
 776 to put saved dired buffers automatically into virtual dired mode.
 777
 778 Also useful for `auto-mode-alist' (which see) like this:
 779
 780   \(setq auto-mode-alist (cons '(\"[^/]\\.dired\\'\" . dired-virtual-mode)
 781                               auto-mode-alist)\)"
 782   (interactive)
 783   (dired-virtual (dired-virtual-guess-dir)))
 784
 785 \f
 786 ;;;; SMART SHELL.
 787
 788 ;;; An Emacs buffer can have but one working directory, stored in the
 789 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 790 ;;; several subdirectories inserted, but still has but one working directory:
 791 ;;; that of the top level Dired directory in that buffer.  For some commands
 792 ;;; it is appropriate that they use the current Dired directory instead of
 793 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 794 ;;; mechanism is provided for special handling of the working directory in
 795 ;;; special major modes.
 796
 797 ;; It's easier to add to this alist than redefine function
 798 ;; default-directory while keeping the old information.
 799 (defconst default-directory-alist
 800   '((dired-mode . (if (fboundp 'dired-current-directory)
 801                       (dired-current-directory)
 802                     default-directory)))
 803   "Alist of major modes and their opinion on default-directory, as a
 804 lisp expression to evaluate.  A resulting value of nil is ignored in
 805 favor of default-directory.")
 806
 807 (defun default-directory ()
 808   "Usage like variable `default-directory', but knows about the special
 809 cases in variable `default-directory-alist' (which see)."
 810   (or (eval (cdr (assq major-mode default-directory-alist)))
 811       default-directory))
 812
 813 (defun dired-smart-shell-command (cmd &optional insert)
 814   "Like function `shell-command', but in the current Tree Dired directory."
 815   (interactive "sShell command: \nP")
 816   (let ((default-directory (default-directory)))
 817     (shell-command cmd insert)))
 818
 819 \f
 820 ;;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 821
 822 ;;; Brief Description:
 823 ;;;
 824 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 825 ;;;
 826 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 827 ;;;
 828 ;;; * `dired-hack-local-variables' checks the value of
 829 ;;;   `dired-local-variables-file'
 830 ;;;
 831 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 832 ;;;   filename found in the directory of the Dired Buffer being created.
 833 ;;;
 834 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 835 ;;;   include it in the Dired Buffer at the bottom.
 836 ;;;
 837 ;;; * Set `enable-local-variables' temporarily to the user variable
 838 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 839 ;;;   Dired Buffer.
 840
 841 (defvar dired-local-variables-file ".dired"
 842   "Filename, as string, containing local dired buffer variables to be hacked.
 843 If this file found in current directory, then it will be inserted into dired
 844 buffer and `hack-local-variables' will be run.  See Emacs Info pages for more
 845 information on local variables.  See also `dired-enable-local-variables'.")
 846
 847 (defun dired-hack-local-variables ()
 848   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 849   (if (and dired-local-variables-file
 850            (stringp dired-local-variables-file)
 851            (file-exists-p dired-local-variables-file))
 852       (let ((opoint (point-max))
 853             buffer-read-only
 854             ;; In case user has `enable-local-variables' set to nil we
 855             ;; override it locally with dired's variable.
 856             (enable-local-variables dired-enable-local-variables))
 857         ;; Insert 'em.
 858         (save-excursion
 859           (goto-char opoint)
 860           (insert "\^L\n")
 861           (insert-file-contents dired-local-variables-file))
 862         ;; Hack 'em.
 863         (let ((buffer-file-name dired-local-variables-file))
 864           (hack-local-variables))
 865         ;; Make sure that the modeline shows the proper information.
 866         (dired-sort-set-modeline)
 867         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 868         (delete-region opoint (point-max)))))
 869
 870 (defun dired-omit-here-always ()
 871   "Creates `dired-local-variables-file' for omitting and reverts directory.
 872 Sets dired-omit-file-p to t in a local variables file that is readable by
 873 dired."
 874   (interactive)
 875   (if (file-exists-p dired-local-variables-file)
 876       (message "File `./%s' already exists." dired-local-variables-file)
 877
 878     ;; Create `dired-local-variables-file'.
 879     (save-excursion
 880       (set-buffer (get-buffer-create " *dot-dired*"))
 881       (erase-buffer)
 882       (insert "Local Variables:\ndired-omit-files-p: t\nEnd:\n")
 883       (write-file dired-local-variables-file)
 884       (kill-buffer (current-buffer)))
 885
 886     ;; Run extra-hooks and revert directory.
 887     (dired-extra-startup)
 888     (dired-revert)))
 889
 890 \f
 891 ;;;; GUESS SHELL COMMAND.
 892
 893 ;;; Brief Description:
 894 ;;;
 895 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 896 ;;;
 897 ;;; * Redefine `dired-do-shell-command' so it calls
 898 ;;;   `dired-guess-shell-command'.
 899 ;;;
 900 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 901 ;;;    marked files.
 902 ;;;
 903 ;;; * Parse `dired-guess-shell-alist-user' and
 904 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 905 ;;;   that matches the first file in the file list.
 906 ;;;
 907 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 908 ;;;   COMMAND, which is either a string or an elisp expression returning a
 909 ;;;   string.  COMMAND may be a list of commands.
 910 ;;;
 911 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 912 ;;;   with it.  The list of commands are temporaily put into the history list.
 913 ;;;   If a command is used successfully then it is stored permanently in
 914 ;;;   `dired-shell-command-history'.
 915
 916 ;;; Guess what shell command to apply to a file.
 917 (defvar dired-shell-command-history nil
 918   "History list for commands that read dired-shell commands.")
 919
 920 ;;; Default list of shell commands.
 921
 922 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 923 ;;; install GNU zip's version of zcat.
 924
 925 (defvar dired-guess-shell-alist-default
 926   (list
 927    (list "\\.tar$" '(if dired-guess-shell-gnutar
 928                         (concat dired-guess-shell-gnutar " xvf")
 929                       "tar xvf"))
 930
 931    ;; REGEXPS for compressed archives must come before the .Z rule to
 932    ;; be recognized:
 933    (list "\\.tar\\.Z$"
 934          ;; Untar it.
 935          '(if dired-guess-shell-gnutar
 936               (concat dired-guess-shell-gnutar " zxvf")
 937             (concat "zcat * | tar xvf -"))
 938          ;; Optional conversion to gzip format.
 939          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 940                   " " dired-guess-shell-znew-switches))
 941
 942    ;; gzip'ed archives
 943    (list "\\.tar\\.g?z$"
 944          '(if dired-guess-shell-gnutar
 945               (concat dired-guess-shell-gnutar " zxvf")
 946             (concat "gunzip -qc * | tar xvf -"))
 947          ;; Optional decompression.
 948          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" "")))
 949
 950    '("\\.shar.Z$" "zcat * | unshar")
 951    '("\\.shar.g?z$" "gunzip -qc * | unshar")
 952
 953    '("\\.ps$" "ghostview" "xv" "lpr")
 954    (list "\\.ps.g?z$" "gunzip -qc * | ghostview -"
 955          ;; Optional decompression.
 956          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 957    (list "\\.ps.Z$" "zcat * | ghostview -"
 958          ;; Optional conversion to gzip format.
 959          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 960                   " " dired-guess-shell-znew-switches))
 961    '("\\.patch$" "cat * | patch")
 962    '("\\.patch.g?z$" "gunzip -qc * | patch")
 963    (list "\\.patch.Z$" "zcat * | patch"
 964          ;; Optional conversion to gzip format.
 965          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 966                   " " dired-guess-shell-znew-switches))
 967
 968    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
 969    '("\\.au$" "play")                   ; play Sun audiofiles
 970    '("\\.mpg$" "mpeg_play")
 971    '("\\.uu$" "uudecode")               ; for uudecoded files
 972    '("\\.hqx$" "mcvert")
 973    '("\\.sh$" "sh")                     ; execute shell scripts
 974    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
 975    '("\\.gp$" "gnuplot")
 976    '("\\.p[bgpn]m$" "xv")
 977    '("\\.gif$" "xv")                    ; view gif pictures
 978    '("\\.tif$" "xv")
 979    '("\\.jpg$" "xv")
 980    '("\\.fig$" "xfig")                  ; edit fig pictures
 981    '("\\.out$" "xgraph")                ; for plotting purposes.
 982    '("\\.tex$" "latex" "tex")
 983    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
 984
 985    ;; Some other popular archivers.
 986    '("\\.zoo$" "zoo x//")
 987    '("\\.zip$" "unzip")
 988    '("\\.lzh$" "lharc x")
 989    '("\\.arc$" "arc x")
 990    '("\\.shar$" "unshar")
 991
 992    ;; Compression.
 993    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 994    (list "\\.Z$" "uncompress"
 995          ;; Optional conversion to gzip format.
 996          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 997                   " " dired-guess-shell-znew-switches))
 998    )
 999
1000   "Default alist used for shell command guessing.
1001 See `dired-guess-shell-alist-user'")
1002
1003 (defvar dired-guess-shell-alist-user nil
1004   "User-defined alist of rules for suggested commands. These rules take
1005 precedence over the predefined rules in the variable
1006 `dired-guess-shell-alist-default' (to which they are prepended).
1007
1008 Each element of this list looks like
1009
1010     \(REGEXP COMMAND...\)
1011
1012 where each COMMAND can either be a string or a lisp expression that evaluates
1013 to a string.  If several COMMANDs are given, the first one will be the default
1014 and the rest will be added temporarily to the history and can be retrieved
1015 with \\[previous-history-element] (M-p) .
1016
1017 You can set this variable in your ~/.emacs.  For example, to add rules for
1018 `.foo' and `.bar' files, write
1019
1020  \(setq dired-guess-shell-alist-user
1021        (list (list \"\\\\.foo$\" \"FOO-COMMAND\");; fixed rule
1022               ;; possibly more rules ...
1023               (list \"\\\\.bar$\";; rule with condition test
1024                     '(if condition
1025                           \"BAR-COMMAND-1\"
1026                         \"BAR-COMMAND-2\")))\)
1027 ")
1028
1029 (defun dired-guess-default (files)
1030
1031   ;; Guess a shell commands for FILES.  Return command or list of commands.
1032   ;; See `dired-guess-shell-alist-user'.
1033
1034   (let* ((case-fold-search nil) ; case-sensitive matching
1035          ;; Prepend the user's alist to the default alist.
1036          (alist (append dired-guess-shell-alist-user
1037                         dired-guess-shell-alist-default))
1038          (file (car files))
1039          (flist (cdr files))
1040          elt regexp cmds)
1041
1042     ;; Find the first match in the alist for first file in FILES.
1043     (while alist
1044       (setq elt (car alist)
1045             regexp (car elt)
1046             alist (cdr alist))
1047       (if (string-match regexp file)
1048           (setq cmds (cdr elt)
1049                 alist nil)))
1050
1051     ;; If more than one file, see if all of FILES match regular expression.
1052     (while (and flist
1053                 (string-match regexp (car flist)))
1054       (setq flist (cdr flist)))
1055
1056     ;; If flist is still non-nil, then do not guess since this means that not
1057     ;; all the files in FILES were matched by the regexp.
1058     (setq cmds (and (not flist) cmds))
1059
1060     ;; Return commands or nil if flist is still non-nil.
1061     ;; Evaluate the commands in order that any logical testing will be done.
1062     (cond ((not (cdr cmds))
1063            (eval (car cmds))) ; single command
1064           (t
1065            (mapcar (function eval) cmds)))))
1066
1067 (defun dired-guess-shell-command (prompt files)
1068
1069   ;; Ask user with PROMPT for a shell command, guessing a default from FILES.
1070
1071   (let ((default (dired-guess-default files))
1072         default-list old-history val (failed t))
1073
1074     (if (null default)
1075         ;; Nothing to guess
1076         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1077
1078       ;; Save current history list
1079       (setq old-history dired-shell-command-history)
1080
1081       (if (listp default)
1082
1083           ;; More than one guess
1084           (setq default-list default
1085                 default (car default)
1086                 prompt (concat
1087                         prompt
1088                         (format "{%d guesses} " (length default-list))))
1089
1090         ;; Just one guess
1091         (setq default-list (list default)))
1092
1093       ;; Push all guesses onto history so that they can be retrieved with M-p
1094       ;; and put the first guess in the prompt but not in the initial value.
1095       (setq dired-shell-command-history
1096             (append default-list dired-shell-command-history)
1097             prompt (concat prompt (format "[%s] " default)))
1098
1099       ;; The unwind-protect returns VAL, and we too.
1100       (unwind-protect
1101           ;; BODYFORM
1102           (progn
1103             (setq val (read-from-minibuffer prompt nil nil nil
1104                                             'dired-shell-command-history)
1105                   failed nil)
1106             ;; If we got a return, then use default.
1107             (if (equal val "")
1108                 (setq val default))
1109             val)
1110
1111         ;; UNWINDFORMS
1112         ;; Undo pushing onto the history list so that an aborted
1113         ;; command doesn't get the default in the next command.
1114         (setq dired-shell-command-history old-history)
1115         (if (not failed)
1116             (or (equal val (car-safe dired-shell-command-history))
1117                 (setq dired-shell-command-history
1118                       (cons val dired-shell-command-history))))))))
1119
1120
1121 ;;; REDEFINE.
1122 ;;; Redefine dired-aux.el's version:
1123 (defun dired-read-shell-command (prompt arg files)
1124 ;;  "Read a dired shell command prompting with PROMPT (using read-string).
1125 ;;ARG is the prefix arg and may be used to indicate in the prompt which
1126 ;;  files are affected.
1127 ;;This is an extra function so that you can redefine it, e.g., to use gmhist."
1128   (dired-mark-pop-up
1129    nil 'shell files
1130    'dired-guess-shell-command
1131    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1132    files))                                       ; FILES
1133
1134 \f
1135 ;;;; RELATIVE SYMBOLIC LINKS.
1136
1137 (defvar dired-keep-marker-relsymlink ?S
1138   "See variable `dired-keep-marker-move'.")
1139
1140 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1141   "Three arguments: FILE1 FILE2 &optional OK-IF-ALREADY-EXISTS
1142 Make a symbolic link (pointing to FILE1) in FILE2.
1143 The link is relative (if possible), for example
1144
1145     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1146
1147 results in
1148
1149     \"../../tex/bin/foo\" \"/vol/local/bin/foo\"
1150 "
1151   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1152   (let (name1 name2 len1 len2 (index 0) sub)
1153     (setq file1 (expand-file-name file1)
1154           file2 (expand-file-name file2)
1155           len1 (length file1)
1156           len2 (length file2))
1157     ;; Find common initial pathname components:
1158     (let (next)
1159       (while (and (setq next (string-match "/" file1 index))
1160                   (setq next (1+ next))
1161                   (< next (min len1 len2))
1162                   ;; For the comparison, both substrings must end in
1163                   ;; `/', so NEXT is *one plus* the result of the
1164                   ;; string-match.
1165                   ;; E.g., consider the case of linking "/tmp/a/abc"
1166                   ;; to "/tmp/abc" erronously giving "/tmp/a" instead
1167                   ;; of "/tmp/" as common initial component
1168                   (string-equal (substring file1 0 next)
1169                                 (substring file2 0 next)))
1170         (setq index next))
1171       (setq name2 file2
1172             sub (substring file1 0 index)
1173             name1 (substring file1 index)))
1174     (if (string-equal sub "/")
1175         ;; No common initial pathname found
1176         (setq name1 file1)
1177       ;; Else they have a common parent directory
1178       (let ((tem (substring file2 index))
1179             (start 0)
1180             (count 0))
1181         ;; Count number of slashes we must compensate for ...
1182         (while (setq start (string-match "/" tem start))
1183           (setq count (1+ count)
1184                 start (1+ start)))
1185         ;; ... and prepend a "../" for each slash found:
1186         (while (> count 0)
1187           (setq count (1- count)
1188                 name1 (concat "../" name1)))))
1189     (make-symbolic-link
1190      (directory-file-name name1)        ; must not link to foo/
1191                                         ; (trailing slash!)
1192      name2 ok-if-already-exists)))
1193
1194 (defun dired-do-relsymlink (&optional arg)
1195    "Relative symlink all marked (or next ARG) files into a directory,
1196 or make a relative symbolic link to the current file.
1197 This creates relative symbolic links like
1198
1199     foo -> ../bar/foo
1200
1201 not absolute ones like
1202
1203     foo -> /ugly/path/that/may/change/any/day/bar/foo"
1204   (interactive "P")
1205   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1206                            "RelSymLink" arg dired-keep-marker-relsymlink))
1207
1208 (defun dired-do-relsymlink-regexp (regexp newname &optional whole-path)
1209   "RelSymlink all marked files containing REGEXP to NEWNAME.
1210 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1211 for more info."
1212   (interactive (dired-mark-read-regexp "RelSymLink"))
1213   (dired-do-create-files-regexp
1214    (function dired-make-relative-symlink)
1215    "RelSymLink" nil regexp newname whole-path dired-keep-marker-relsymlink))
1216
1217 \f
1218 ;;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1219
1220 ;;; Brief Description:
1221 ;;;
1222 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1223 ;;;
1224 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1225 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1226 ;;;
1227 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1228 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1229 ;;;
1230 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1231 ;;;   list each time.
1232 ;;;
1233 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1234 ;;;   element of FILE-LIST.
1235 ;;;
1236 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1237 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1238 ;;;   cognizant of the window-configuration.
1239 ;;;
1240 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1241 ;;;   of FILE-LIST giving each a window of height `size'.
1242
1243 (defun dired-do-find-marked-files (&optional noselect)
1244   "Find all marked files displaying all of them simultaneously.
1245 With optional NOSELECT just find files but do not select them.
1246
1247 The current window is split across all files marked, as evenly as possible.
1248 Remaining lines go to bottom-most window.  The number of files that can be
1249 displayed this way is restricted by the height of the current window and
1250 `window-min-height'.
1251
1252 To keep dired buffer displayed, type \\[split-window-vertically] first.
1253 To display just marked files, type \\[delete-other-windows] first."
1254
1255   (interactive "P")
1256   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1257
1258 (defun dired-simultaneous-find-file (file-list noselect)
1259
1260   ;; Visit all files in FILE-LIST and display them simultaneously.  The
1261   ;; current window is split across all files in FILE-LIST, as evenly as
1262   ;; possible.  Remaining lines go to the bottom-most window.  The number of
1263   ;; files that can be displayed this way is restricted by the height of the
1264   ;; current window and the variable `window-min-height'.  With non-nil
1265   ;; NOSELECT the files are merely found but not selected.
1266
1267   ;; We don't make this function interactive because it is usually too clumsy
1268   ;; to specify FILE-LIST interactively unless via dired.
1269
1270   (let (size)
1271
1272     (if noselect
1273         ;; Do not select the buffer.
1274         (find-file-noselect (car file-list))
1275
1276       ;; We will have to select the buffer.  Calculate and check window size.
1277       (setq size (/ (window-height) (length file-list)))
1278       (or (<= window-min-height size)
1279           (error "Too many files to visit simultaneously.  Try C-u prefix."))
1280       (find-file (car file-list)))
1281
1282     ;; Decrement.
1283     (setq file-list (cdr file-list))
1284
1285     (while file-list
1286
1287       (if noselect
1288           ;; Do not select the buffer.
1289           (find-file-noselect (car file-list))
1290
1291         ;; Vertically split off a window of desired size.  Upper window will
1292         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1293         (select-window (split-window nil size))
1294         (find-file (car file-list)))
1295
1296       ;; Decrement.
1297       (setq file-list (cdr file-list)))))
1298
1299 \f
1300 ;;;; MISCELLANEOUS COMMANDS.
1301
1302 ;;; Run man on files.
1303
1304 (defun dired-man ()
1305   "Run man on this file.  Display old buffer if buffer name matches filename.
1306 Uses ../lisp/man.el of \\[manual-entry] fame."
1307   (interactive)
1308   (require 'man)
1309   (let ((file (dired-get-filename))
1310         (manual-program "nroff -man -h"))
1311     (Man-getpage-in-background file)))
1312
1313 ;;; Run Info on files.
1314
1315 (defun dired-info ()
1316   "Run info on this file."
1317   (interactive)
1318   (info (dired-get-filename)))
1319
1320 ;;; Run mail on mail folders.
1321
1322 ;;; (and (not (fboundp 'vm-visit-folder))
1323 ;;;      (defun vm-visit-folder (file &optional arg)
1324 ;;;        nil))
1325
1326 (defun dired-vm (&optional read-only)
1327   "Run VM on this file.
1328 With prefix arg, visit folder read-only (this requires at least VM 5).
1329 See also variable `dired-vm-read-only-folders'."
1330   (interactive "P")
1331   (let ((dir (dired-current-directory))
1332         (fil (dired-get-filename)))
1333     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1334     (cond (read-only (vm-visit-folder fil t))
1335           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1336           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1337           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1338     ;; so that pressing `v' inside VM does prompt within current directory:
1339     (set (make-local-variable 'vm-folder-directory) dir)))
1340
1341 (defun dired-rmail ()
1342   "Run RMAIL on this file."
1343   (interactive)
1344   (rmail (dired-get-filename)))
1345
1346 (defun dired-do-run-mail ()
1347   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1348   (interactive)
1349   (if dired-bind-vm
1350       ;; Read mail folder using vm.
1351       (dired-vm)
1352     ;; Read mail folder using rmail.
1353     (dired-rmail)))
1354
1355 \f
1356 ;;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1357
1358 (or (fboundp 'dired-old-find-buffer-nocreate)
1359     (fset 'dired-old-find-buffer-nocreate
1360           (symbol-function 'dired-find-buffer-nocreate)))
1361
1362 ;;; REDEFINE.
1363 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1364 (defun dired-find-buffer-nocreate (dirname)
1365   (if dired-find-subdir
1366       (let* ((cur-buf (current-buffer))
1367              (buffers (nreverse
1368                        (dired-buffers-for-dir (expand-file-name dirname))))
1369              (cur-buf-matches (and (memq cur-buf buffers)
1370                                    ;; wildcards must match, too:
1371                                    (equal dired-directory dirname))))
1372         ;; We don't want to switch to the same buffer---
1373         (setq buffers (delq cur-buf buffers));;need setq with delq
1374         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1375             ;; ---unless it's the only possibility:
1376             (and cur-buf-matches cur-buf)))
1377     (dired-old-find-buffer-nocreate dirname)))
1378
1379 ;; This should be a builtin
1380 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1381   "Return t if BUFFER1 is more recently used than BUFFER2."
1382   (if (equal buffer1 buffer2)
1383       nil
1384     (let ((more-recent nil)
1385           (list (buffer-list)))
1386       (while (and list
1387                   (not (setq more-recent (equal buffer1 (car list))))
1388                   (not (equal buffer2 (car list))))
1389         (setq list (cdr list)))
1390       more-recent)))
1391
1392 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1393 ;;; (defun dired-buffers-for-dir-exact (dir)
1394 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1395 ;;; ;; at top level, or as subdirectory.
1396 ;;; ;; Top level matches must match the wildcard part too, if any.
1397 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1398 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1399 ;;; ;; dired-buffers.
1400 ;;;   (let ((alist dired-buffers) result elt)
1401 ;;;     (while alist
1402 ;;;       (setq elt (car alist)
1403 ;;;             alist (cdr alist))
1404 ;;;       (let ((buf (cdr elt)))
1405 ;;;         (if (buffer-name buf)
1406 ;;;             ;; Top level must match exactly against dired-directory in
1407 ;;;             ;; case one of them is a wildcard.
1408 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1409 ;;;                                                dired-directory))
1410 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1411 ;;;                                                dired-subdir-alist)))
1412 ;;;                 (setq result (cons buf result)))
1413 ;;;           ;; else buffer is killed - clean up:
1414 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1415 ;;;     result))
1416
1417 ;;; REDEFINE.
1418 ;;; Redefines dired.el's version of `dired-initial-position'
1419 (defun dired-initial-position (dirname)
1420   (end-of-line)
1421   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1422   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1423
1424 \f
1425 ;; Does anyone use this? - lrd 6/29/93.
1426 (defun dired-mark-sexp (predicate &optional unflag-p)
1427   "Mark files for which PREDICATE returns non-nil.
1428 With a prefix arg, unflag those files instead.
1429
1430 PREDICATE is a lisp expression that can refer to the following symbols:
1431
1432     inode  [integer] the inode of the file (only for ls -i output)
1433     s      [integer] the size of the file for ls -s output
1434                      (ususally in blocks or, with -k, in KByte)
1435     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1436     nlink  [integer] number of links to file
1437     uid    [string]  owner
1438     gid    [string]  group  (If the gid is not displayed by ls,
1439                      this will still be set (to the same as uid))
1440     size   [integer] file size in bytes
1441     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1442     name   [string]  the name of the file
1443     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1444
1445 For example, use
1446
1447         (equal 0 size)
1448
1449 to mark all zero length files."
1450   ;; Using sym="" instead of nil avoids the trap of
1451   ;; (string-match "foo" sym) into which a user would soon fall.
1452   ;; Give `equal' instead of `=' in the example, as this works on
1453   ;; integers and strings.
1454   (interactive "xMark if (lisp expr): \nP")
1455   (message "%s" predicate)
1456   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1457         inode s mode nlink uid gid size time name sym)
1458     (dired-mark-if
1459      (save-excursion
1460        (and
1461         ;; Sets vars
1462         ;;                inode s mode nlink uid gid size time name sym
1463
1464         ;; according to current file line.  Returns t for success, nil if
1465         ;; there is no file line.  Upon success, all variables are set, either
1466         ;; to nil or the appropriate value, so they need not be initialized.
1467         ;; Moves point within the current line.
1468         (if (dired-move-to-filename)
1469             (let (pos
1470                   (mode-len 10) ; length of mode string
1471                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1472                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1473               (beginning-of-line)
1474               (forward-char 2)
1475               (if (looking-at dired-re-inode-size)
1476                   (progn
1477                     (goto-char (match-end 0))
1478                     (setq inode (string-to-int (buffer-substring (match-beginning 1)
1479                                                                  (match-end 1)))
1480                           s (string-to-int (buffer-substring (match-beginning 2)
1481                                                              (match-end 2)))))
1482                 (setq inode nil
1483                       s nil))
1484               (setq mode (buffer-substring (point) (+ mode-len (point))))
1485               (forward-char mode-len)
1486               (setq nlink (read (current-buffer)))
1487               (setq uid (buffer-substring (point) (progn (forward-word 1) (point))))
1488               (re-search-forward "\\(Jan\\|Feb\\|Mar\\|Apr\\|May\\|Jun\\|Jul\\|Aug\\|Sep\\|Oct\\|Nov\\|Dec\\)")
1489               (goto-char (match-beginning 1))
1490               (forward-char -1)
1491               (setq size (string-to-int (buffer-substring (save-excursion
1492                                                             (backward-word 1)
1493                                                             (setq pos (point)))
1494                                                           (point))))
1495               (goto-char pos)
1496               (backward-word 1)
1497               ;; if no gid is displayed, gid will be set to uid
1498               ;; but user will then not reference it anyway in PREDICATE.
1499               (setq gid (buffer-substring (save-excursion (forward-word 1) (point))
1500                                           (point))
1501                     time (buffer-substring (match-beginning 1)
1502                                            (1- (dired-move-to-filename)))
1503                     name (buffer-substring (point)
1504                                            (or (dired-move-to-end-of-filename t)
1505                                                (point)))
1506                     sym  (progn
1507                            (if (looking-at " -> ")
1508                                (buffer-substring (progn (forward-char 4) (point))
1509                                                  (progn (end-of-line) (point)))
1510                              "")))
1511               t)
1512           nil)
1513                       (eval predicate)))
1514      (format "'%s file" predicate))))
1515
1516 \f
1517 ;;;; FIND FILE AT POINT.
1518
1519 (defvar dired-x-hands-off-my-keys t
1520   "*t means don't bind `dired-x-find-file' over `find-file' on keyboard.
1521 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1522 If you change this variable after dired-x.el is loaded then do
1523 \\[dired-x-bind-find-file].")
1524
1525 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1526 ;;; `find-file{-other-window}' is bound?
1527 (defun dired-x-bind-find-file ()
1528   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1529 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1530 Binding direction based on `dired-x-hands-off-my-keys'.
1531 This function part of `after-init-hook'."
1532   (interactive)
1533   (if (interactive-p)
1534       (setq dired-x-hands-off-my-keys
1535             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1536   (cond ((not dired-x-hands-off-my-keys)
1537          (substitute-key-definition 'find-file
1538                                     'dired-x-find-file
1539                                     (current-global-map))
1540          (substitute-key-definition 'find-file-other-window
1541                                     'dired-x-find-file-other-window
1542                                     (current-global-map)))
1543         (t
1544          (substitute-key-definition 'dired-x-find-file
1545                                     'find-file
1546                                     (current-global-map))
1547          (substitute-key-definition 'dired-x-find-file-other-window
1548                                     'find-file-other-window
1549                                     (current-global-map))))
1550   ;; Clear mini-buffer.
1551   (message nil))
1552
1553 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1554 ;;; user changes binding.
1555 (dired-x-bind-find-file)
1556 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1557
1558 (defun dired-x-find-file (filename)
1559   "Edit file FILENAME.
1560 May create a new window, or reuse an existing one.
1561 See the function `display-buffer'.
1562
1563 Identical to `find-file' except when called interactively, with a prefix arg
1564 \(e.g., \\[universal-argument]\), in which case it guesses filename near
1565 point.  Useful for editing file mentioned in buffer you are viewing, or to
1566 test if that file exists.  Use minibuffer after snatching filename."
1567   (interactive (list (read-filename-at-point "Find file: ")))
1568   (find-file (expand-file-name filename)))
1569
1570 (defun dired-x-find-file-other-window (filename)
1571   "Edit file FILENAME, in another window.
1572 May create a new window, or reuse an existing one.
1573 See the function `display-buffer'.
1574
1575 Identical to `find-file-other-window' except when called interactively, with a
1576 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename
1577 near point.  Useful for editing file mentioned in buffer you are viewing, or
1578 to test if that file exists.  Use minibuffer after snatching filename."
1579   (interactive (list (read-filename-at-point "Find file: ")))
1580   (find-file-other-window (expand-file-name filename)))
1581
1582 ;;; Internal functions.
1583 (defun dired-filename-at-point ()
1584
1585   ;; Get the filename closest to point, but do not change position.  Has a
1586   ;; preference for looking backward when not directly on a symbol.  Not
1587   ;; perfect - point must be in middle of or end of filename.
1588
1589   (let ((filename-chars ".a-zA-Z0-9---_/:$+")
1590         (bol (save-excursion (beginning-of-line) (point)))
1591         (eol (save-excursion (end-of-line) (point)))
1592         start end filename)
1593
1594     (save-excursion
1595       ;; First see if just past a filename.
1596       (if (not (eobp))
1597           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1598               (progn
1599                 (skip-chars-backward " \n\t\r({[]})")
1600                 (if (not (bobp))
1601                     (backward-char 1)))))
1602
1603       (if (string-match (concat "[" filename-chars "]")
1604                         (char-to-string (following-char)))
1605           (progn
1606             (skip-chars-backward filename-chars)
1607             (setq start (point))
1608             (if (string-match "[/~]" (char-to-string (preceding-char)))
1609                 (setq start (1- start)))
1610             (skip-chars-forward filename-chars))
1611
1612         (error "No file found around point!"))
1613
1614       ;; Return string.
1615       (expand-file-name (buffer-substring start (point))))))
1616
1617 (defun read-filename-at-point (prompt)
1618   ;;; Returns filename prompting with PROMPT with completion.  If
1619   ;;; `current-prefix-arg' is non-nil, uses name at point as guess.
1620   (if current-prefix-arg
1621       (let ((guess (dired-filename-at-point)))
1622         (read-file-name prompt
1623                         (file-name-directory guess)
1624                         guess
1625                         nil (file-name-nondirectory guess)))
1626     (read-file-name prompt default-directory)))
1627
1628 \f
1629 ;;;; BUG REPORTS
1630
1631 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1632 ;;; reporter.el which is bundled with GNU Emacs v19.
1633
1634 (defconst dired-x-version "2.37"
1635   "Revision number of dired-x.el -- dired extra for GNU Emacs v19.
1636 Type \\[dired-x-submit-report] to send a bug report.  Available via anonymous
1637 ftp in
1638
1639    /roebling.poly.edu:/pub/packages/dired-x.tar.gz")
1640
1641 (defconst dired-x-help-address "dodd@roebling.poly.edu"
1642   "Address(es) accepting submission of reports on dired-x.el.")
1643
1644 (defconst dired-x-maintainer "Larry"
1645   "First name(s) of people accepting submission of reports on dired-x.el.")
1646
1647 (defconst dired-x-file "dired-x.el"
1648   "Name of file containing emacs lisp code.")
1649
1650 (defconst dired-x-variable-list
1651   (list
1652    'dired-bind-vm
1653    'dired-vm-read-only-folders
1654    'dired-bind-jump
1655    'dired-bind-info
1656    'dired-bind-man
1657    'dired-find-subdir
1658    'dired-enable-local-variables
1659    'dired-local-variables-file
1660    'dired-guess-shell-gnutar
1661    'dired-guess-shell-gzip-quiet
1662    'dired-guess-shell-znew-switches
1663    'dired-guess-shell-alist-user
1664    'dired-clean-up-buffers-too
1665    'dired-omit-files-p
1666    'dired-omit-files
1667    'dired-omit-extensions
1668    )
1669   "List of variables to be appended to reports sent by `dired-x-submit-report.'")
1670
1671 (defun dired-x-submit-report ()
1672   "Submit via reporter.el a bug report on program.  Send report on `dired-x-file'
1673 version `dired-x-version,' to `dired-x-maintainer' at address `dired-x-help-address'
1674 listing variables `dired-x-variable-list' in the message."
1675   (interactive)
1676
1677   ;; In case we can't find reporter...
1678   (condition-case err
1679       (progn
1680         ;; Get it if we can.
1681         (require 'reporter)
1682
1683         (reporter-submit-bug-report
1684          dired-x-help-address                           ; address
1685          (concat dired-x-file " (" dired-x-version ")") ; pkgname
1686          dired-x-variable-list                          ; varlist
1687          nil nil                                        ; pre-/post-hooks
1688          (concat dired-x-maintainer ",")))              ; salutation
1689
1690     ;; ...fail gracefully.
1691     (error
1692      (beep)
1693      (message "Sorry, reporter.el not found."))))
1694
1695 \f
1696 ;; As Barry Warsaw would say: "This might be useful..."
1697 (provide 'dired-x)
1698
1699 ;;; dired-x.el ends here