lisp/gnus/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'gnus)
  34 (require 'gnus-ems)
  35 (require 'message)
  36 (require 'gnus-art)
  37 (require 'gnus-util)
  38
  39 (defcustom gnus-post-method 'current
  40   "*Preferred method for posting USENET news.
  41
  42 If this variable is `current' (which is the default), Gnus will use
  43 the \"current\" select method when posting.  If it is `native', Gnus
  44 will use the native select method when posting.
  45
  46 This method will not be used in mail groups and the like, only in
  47 \"real\" newsgroups.
  48
  49 If not `native' nor `current', the value must be a valid method as discussed
  50 in the documentation of `gnus-select-method'.  It can also be a list of
  51 methods.  If that is the case, the user will be queried for what select
  52 method to use when posting."
  53   :group 'gnus-group-foreign
  54   :link '(custom-manual "(gnus)Posting Server")
  55   :type `(choice (const native)
  56                  (const current)
  57                  (sexp :tag "Methods" ,gnus-select-method)))
  58
  59 (defcustom gnus-outgoing-message-group nil
  60   "*All outgoing messages will be put in this group.
  61 If you want to store all your outgoing mail and articles in the group
  62 \"nnml:archive\", you set this variable to that value.  This variable
  63 can also be a list of group names.
  64
  65 If you want to have greater control over what group to put each
  66 message in, you can set this variable to a function that checks the
  67 current newsgroup name and then returns a suitable group name (or list
  68 of names)."
  69   :group 'gnus-message
  70   :type '(choice (const nil)
  71                  (function)
  72                  (string :tag "Group")
  73                  (repeat :tag "List of groups" (string :tag "Group"))))
  74
  75 (defcustom gnus-mailing-list-groups nil
  76   "*If non-nil a regexp matching groups that are really mailing lists.
  77 This is useful when you're reading a mailing list that has been
  78 gatewayed to a newsgroup, and you want to followup to an article in
  79 the group."
  80   :group 'gnus-message
  81   :type '(choice (regexp)
  82                  (const nil)))
  83
  84 (defcustom gnus-add-to-list nil
  85   "*If non-nil, add a `to-list' parameter automatically."
  86   :group 'gnus-message
  87   :type 'boolean)
  88
  89 (defcustom gnus-crosspost-complaint
  90   "Hi,
  91
  92 You posted the article below with the following Newsgroups header:
  93
  94 Newsgroups: %s
  95
  96 The %s group, at least, was an inappropriate recipient
  97 of this message.  Please trim your Newsgroups header to exclude this
  98 group before posting in the future.
  99
 100 Thank you.
 101
 102 "
 103   "Format string to be inserted when complaining about crossposts.
 104 The first %s will be replaced by the Newsgroups header;
 105 the second with the current group name."
 106   :group 'gnus-message
 107   :type 'string)
 108
 109 (defcustom gnus-message-setup-hook nil
 110   "Hook run after setting up a message buffer."
 111   :group 'gnus-message
 112   :type 'hook)
 113
 114 (defcustom gnus-bug-create-help-buffer t
 115   "*Should we create the *Gnus Help Bug* buffer?"
 116   :group 'gnus-message
 117   :type 'boolean)
 118
 119 (defcustom gnus-posting-styles nil
 120   "*Alist of styles to use when posting.
 121 See Info node `(gnus)Posting Styles'."
 122   :group 'gnus-message
 123   :link '(custom-manual "(gnus)Posting Styles")
 124   :type '(repeat (cons (choice (regexp)
 125                                (variable)
 126                                (list (const header)
 127                                      (string :tag "Header")
 128                                      (regexp :tag "Regexp"))
 129                                (function)
 130                                (sexp))
 131                        (repeat (list
 132                                 (choice (const signature)
 133                                         (const signature-file)
 134                                         (const organization)
 135                                         (const address)
 136                                         (const x-face-file)
 137                                         (const name)
 138                                         (const body)
 139                                         (symbol)
 140                                         (string :tag "Header"))
 141                                 (choice (string)
 142                                         (function)
 143                                         (variable)
 144                                         (sexp)))))))
 145
 146 (defcustom gnus-gcc-mark-as-read nil
 147   "If non-nil, automatically mark Gcc articles as read."
 148   :version "22.1"
 149   :group 'gnus-message
 150   :type 'boolean)
 151
 152 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 153                         'gnus-gcc-mark-as-read)
 154
 155 (defcustom gnus-gcc-externalize-attachments nil
 156   "Should local-file attachments be included as external parts in Gcc copies?
 157 If it is `all', attach files as external parts;
 158 if a regexp and matches the Gcc group name, attach files as external parts;
 159 if nil, attach files as normal parts."
 160   :version "22.1"
 161   :group 'gnus-message
 162   :type '(choice (const nil :tag "None")
 163                  (const all :tag "Any")
 164                  (string :tag "Regexp")))
 165
 166 (gnus-define-group-parameter
 167  posting-charset-alist
 168  :type list
 169  :function-document
 170  "Return the permitted unencoded charsets for posting of GROUP."
 171  :variable gnus-group-posting-charset-alist
 172  :variable-default
 173   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 174     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 175     (message-this-is-mail nil nil)
 176     (message-this-is-news nil t))
 177  :variable-document
 178   "Alist of regexps and permitted unencoded charsets for posting.
 179 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 180 TEST is either a regular expression matching the newsgroup header or a
 181 variable to query,
 182 HEADER is the charset which may be left unencoded in the header (nil
 183 means encode all charsets),
 184 BODY-LIST is a list of charsets which may be encoded using 8bit
 185 content-transfer encoding in the body, or one of the special values
 186 nil (always encode using quoted-printable) or t (always use 8bit).
 187
 188 Note that any value other than nil for HEADER infringes some RFCs, so
 189 use this option with care."
 190  :variable-group gnus-charset
 191  :variable-type
 192  '(repeat (list :tag "Permitted unencoded charsets"
 193                 (choice :tag "Where"
 194                         (regexp :tag "Group")
 195                         (const :tag "Mail message" :value message-this-is-mail)
 196                         (const :tag "News article" :value message-this-is-news))
 197                 (choice :tag "Header"
 198                         (const :tag "None" nil)
 199                         (symbol :tag "Charset"))
 200                 (choice :tag "Body"
 201                         (const :tag "Any" :value t)
 202                         (const :tag "None" :value nil)
 203                         (repeat :tag "Charsets"
 204                                 (symbol :tag "Charset")))))
 205  :parameter-type '(choice :tag "Permitted unencoded charsets"
 206                           :value nil
 207                           (repeat (symbol)))
 208  :parameter-document       "\
 209 List of charsets that are permitted to be unencoded.")
 210
 211 (defcustom gnus-debug-files
 212   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 213     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 214     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 215     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 216     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 217   "Files whose variables will be reported in `gnus-bug'."
 218   :version "22.1"
 219   :group 'gnus-message
 220   :type '(repeat (string :tag "File")))
 221
 222 (defcustom gnus-debug-exclude-variables
 223   '(mm-mime-mule-charset-alist
 224     nnmail-split-fancy message-minibuffer-local-map)
 225   "Variables that should not be reported in `gnus-bug'."
 226   :version "22.1"
 227   :group 'gnus-message
 228   :type '(repeat (symbol :tag "Variable")))
 229
 230 (defcustom gnus-discouraged-post-methods
 231   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 232   "A list of back ends that are not used in \"real\" newsgroups.
 233 This variable is used only when `gnus-post-method' is `current'."
 234   :version "22.1"
 235   :group 'gnus-group-foreign
 236   :type '(repeat (symbol :tag "Back end")))
 237
 238 (defcustom gnus-message-replysign
 239   nil
 240   "Automatically sign replies to signed messages.
 241 See also the `mml-default-sign-method' variable."
 242   :group 'gnus-message
 243   :type 'boolean)
 244
 245 (defcustom gnus-message-replyencrypt
 246   nil
 247   "Automatically encrypt replies to encrypted messages.
 248 See also the `mml-default-encrypt-method' variable."
 249   :group 'gnus-message
 250   :type 'boolean)
 251
 252 (defcustom gnus-message-replysignencrypted
 253   t
 254   "Setting this causes automatically encrypted messages to also be signed."
 255   :group 'gnus-message
 256   :type 'boolean)
 257
 258 (defcustom gnus-confirm-mail-reply-to-news nil
 259   "If non-nil, Gnus requests confirmation when replying to news.
 260 This is done because new users often reply by mistake when reading
 261 news.
 262 This can also be a function receiving the group name as the only
 263 parameter which should return non-nil iff a confirmation is needed, or
 264 a regexp, in which case a confirmation is asked for iff the group name
 265 matches the regexp."
 266   :version "22.1"
 267   :group 'gnus-message
 268   :type '(choice (const :tag "No" nil)
 269                  (const :tag "Yes" t)
 270                  (regexp :tag "Iff group matches regexp")
 271                  (function :tag "Iff function evaluates to non-nil")))
 272
 273 (defcustom gnus-confirm-treat-mail-like-news
 274   nil
 275   "If non-nil, Gnus will treat mail like news with regard to confirmation
 276 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 277 for fine-tuning this.
 278 If nil, Gnus will never ask for confirmation if replying to mail."
 279   :version "22.1"
 280   :group 'gnus-message
 281   :type 'boolean)
 282
 283 (defcustom gnus-summary-resend-default-address t
 284   "If non-nil, Gnus tries to suggest a default address to resend to.
 285 If nil, the address field will always be empty after invoking
 286 `gnus-summary-resend-message'."
 287   :version "22.1"
 288   :group 'gnus-message
 289   :type 'boolean)
 290
 291 ;;; Internal variables.
 292
 293 (defvar gnus-inhibit-posting-styles nil
 294   "Inhibit the use of posting styles.")
 295
 296 (defvar gnus-article-yanked-articles nil)
 297 (defvar gnus-message-buffer "*Mail Gnus*")
 298 (defvar gnus-article-copy nil)
 299 (defvar gnus-check-before-posting nil)
 300 (defvar gnus-last-posting-server nil)
 301 (defvar gnus-message-group-art nil)
 302
 303 (defvar gnus-msg-force-broken-reply-to nil)
 304
 305 (defconst gnus-bug-message
 306   "Sending a bug report to the Gnus Towers.
 307 ========================================
 308
 309 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 310 be sent to the Gnus Bug Exterminators.
 311
 312 The thing near the bottom of the buffer is how the environment
 313 settings will be included in the mail.  Please do not delete that.
 314 They will tell the Bug People what your environment is, so that it
 315 will be easier to locate the bugs.
 316
 317 If you have found a bug that makes Emacs go \"beep\", set
 318 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 319 and include the backtrace in your bug report.
 320
 321 Please describe the bug in annoying, painstaking detail.
 322
 323 Thank you for your help in stamping out bugs.
 324 ")
 325
 326 (eval-and-compile
 327   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 328   (autoload 'news-setup "rnewspost")
 329   (autoload 'news-reply-mode "rnewspost")
 330   (autoload 'rmail-dont-reply-to "mail-utils")
 331   (autoload 'rmail-output "rmailout"))
 332
 333 \f
 334 ;;;
 335 ;;; Gnus Posting Functions
 336 ;;;
 337
 338 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 339   "p" gnus-summary-post-news
 340   "i" gnus-summary-news-other-window
 341   "f" gnus-summary-followup
 342   "F" gnus-summary-followup-with-original
 343   "c" gnus-summary-cancel-article
 344   "s" gnus-summary-supersede-article
 345   "r" gnus-summary-reply
 346   "y" gnus-summary-yank-message
 347   "R" gnus-summary-reply-with-original
 348   "w" gnus-summary-wide-reply
 349   "W" gnus-summary-wide-reply-with-original
 350   "v" gnus-summary-very-wide-reply
 351   "V" gnus-summary-very-wide-reply-with-original
 352   "n" gnus-summary-followup-to-mail
 353   "N" gnus-summary-followup-to-mail-with-original
 354   "m" gnus-summary-mail-other-window
 355   "u" gnus-uu-post-news
 356   "\M-c" gnus-summary-mail-crosspost-complaint
 357   "Br" gnus-summary-reply-broken-reply-to
 358   "BR" gnus-summary-reply-broken-reply-to-with-original
 359   "om" gnus-summary-mail-forward
 360   "op" gnus-summary-post-forward
 361   "Om" gnus-uu-digest-mail-forward
 362   "Op" gnus-uu-digest-post-forward)
 363
 364 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 365   "b" gnus-summary-resend-bounced-mail
 366   ;; "c" gnus-summary-send-draft
 367   "r" gnus-summary-resend-message
 368   "e" gnus-summary-resend-message-edit)
 369
 370 ;;; Internal functions.
 371
 372 (defun gnus-inews-make-draft ()
 373   `(lambda ()
 374      (gnus-inews-make-draft-meta-information
 375       ,gnus-newsgroup-name ',gnus-article-reply)))
 376
 377 (defvar gnus-article-reply nil)
 378 (defmacro gnus-setup-message (config &rest forms)
 379   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 380         (buffer (make-symbol "gnus-setup-message-buffer"))
 381         (article (make-symbol "gnus-setup-message-article"))
 382         (yanked (make-symbol "gnus-setup-yanked-articles"))
 383         (group (make-symbol "gnus-setup-message-group")))
 384     `(let ((,winconf (current-window-configuration))
 385            (,buffer (buffer-name (current-buffer)))
 386            (,article gnus-article-reply)
 387            (,yanked gnus-article-yanked-articles)
 388            (,group gnus-newsgroup-name)
 389            (message-header-setup-hook
 390             (copy-sequence message-header-setup-hook))
 391            (mbl mml-buffer-list)
 392            (message-mode-hook (copy-sequence message-mode-hook)))
 393        (setq mml-buffer-list nil)
 394        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 395        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 396        ;; message-newsreader and message-mailer were formerly set in
 397        ;; gnus-inews-add-send-actions, but this is too late when
 398        ;; message-generate-headers-first is used. --ansel
 399        (add-hook 'message-mode-hook
 400                  (lambda nil
 401                    (setq message-newsreader
 402                          (setq message-mailer (gnus-extended-version)))))
 403        ;; #### FIXME: for a reason that I did not manage to identify yet,
 404        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 405        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 406        ;; After evaluation of @forms below, it gets the value we actually want
 407        ;; to override, and the posting styles are used. For that reason, I've
 408        ;; added an optional argument to `gnus-configure-posting-styles' to
 409        ;; make sure that the correct value for the group name is used. -- drv
 410        (add-hook 'message-mode-hook
 411                  (if (memq ,config '(reply-yank reply))
 412                      (lambda ()
 413                        (gnus-configure-posting-styles ,group))
 414                    (lambda ()
 415                      ;; There may be an old " *gnus article copy*" buffer.
 416                      (let (gnus-article-copy)
 417                        (gnus-configure-posting-styles ,group)))))
 418        (gnus-pull ',(intern gnus-draft-meta-information-header)
 419                   message-required-headers)
 420        (when (and ,group
 421                   (not (string= ,group "")))
 422          (push (cons
 423                 (intern gnus-draft-meta-information-header)
 424                 (gnus-inews-make-draft))
 425                message-required-headers))
 426        (unwind-protect
 427            (progn
 428              ,@forms)
 429          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 430                                       ,yanked)
 431          (setq gnus-message-buffer (current-buffer))
 432          (set (make-local-variable 'gnus-message-group-art)
 433               (cons ,group ,article))
 434          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 435          (gnus-run-hooks 'gnus-message-setup-hook)
 436          (if (eq major-mode 'message-mode)
 437              (let ((mbl1 mml-buffer-list))
 438                (setq mml-buffer-list mbl)  ;; Global value
 439                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 440                (gnus-make-local-hook 'kill-buffer-hook)
 441                (gnus-make-local-hook 'change-major-mode-hook)
 442                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 443                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 444            (mml-destroy-buffers)
 445            (setq mml-buffer-list mbl)))
 446        (message-hide-headers)
 447        (gnus-add-buffer)
 448        (gnus-configure-windows ,config t)
 449        (run-hooks 'post-command-hook)
 450        (set-buffer-modified-p nil))))
 451
 452 (defun gnus-inews-make-draft-meta-information (group article)
 453   (concat "(\"" group "\" "
 454           (if article (number-to-string
 455                        (if (listp article)
 456                            (car article)
 457                          article)) "\"\"")
 458           ")"))
 459
 460 ;;;###autoload
 461 (defun gnus-msg-mail (&optional to subject other-headers continue
 462                                 switch-action yank-action send-actions)
 463   "Start editing a mail message to be sent.
 464 Like `message-mail', but with Gnus paraphernalia, particularly the
 465 Gcc: header for archiving purposes."
 466   (interactive)
 467   (let ((buf (current-buffer))
 468         mail-buf)
 469     (gnus-setup-message 'message
 470       (message-mail to subject other-headers continue
 471                     nil yank-action send-actions))
 472     (when switch-action
 473       (setq mail-buf (current-buffer))
 474       (switch-to-buffer buf)
 475       (apply switch-action mail-buf nil)))
 476   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 477   t)
 478
 479 ;;;###autoload
 480 (defun gnus-button-mailto (address)
 481   "Mail to ADDRESS."
 482   (set-buffer (gnus-copy-article-buffer))
 483   (gnus-setup-message 'message
 484     (message-reply address)))
 485
 486 ;;;###autoload
 487 (defun gnus-button-reply (&optional to-address wide)
 488   "Like `message-reply'."
 489   (interactive)
 490   (gnus-setup-message 'message
 491     (message-reply to-address wide)))
 492
 493 ;;;###autoload
 494 (define-mail-user-agent 'gnus-user-agent
 495   'gnus-msg-mail 'message-send-and-exit
 496   'message-kill-buffer 'message-send-hook)
 497
 498 (defun gnus-setup-posting-charset (group)
 499   (let ((alist gnus-group-posting-charset-alist)
 500         (group (or group ""))
 501         elem)
 502     (when group
 503       (catch 'found
 504         (while (setq elem (pop alist))
 505           (when (or (and (stringp (car elem))
 506                          (string-match (car elem) group))
 507                     (and (functionp (car elem))
 508                          (funcall (car elem) group))
 509                     (and (symbolp (car elem))
 510                          (symbol-value (car elem))))
 511             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 512
 513 (defun gnus-inews-add-send-actions (winconf buffer article
 514                                             &optional config yanked)
 515   (gnus-make-local-hook 'message-sent-hook)
 516   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 517                                  'gnus-inews-do-gcc) nil t)
 518   (when gnus-agent
 519     (gnus-make-local-hook 'message-header-hook)
 520     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 521   (setq message-post-method
 522         `(lambda (arg)
 523            (gnus-post-method arg ,gnus-newsgroup-name)))
 524   (message-add-action
 525    `(when (gnus-buffer-exists-p ,buffer)
 526       (set-window-configuration ,winconf))
 527    'exit 'postpone 'kill)
 528   (let ((to-be-marked (cond
 529                        (yanked
 530                         (mapcar
 531                          (lambda (x) (if (listp x) (car x) x)) yanked))
 532                        (article (if (listp article) article (list article)))
 533                        (t nil))))
 534     (message-add-action
 535      `(when (gnus-buffer-exists-p ,buffer)
 536         (save-excursion
 537           (set-buffer ,buffer)
 538           ,(when to-be-marked
 539              (if (eq config 'forward)
 540                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 541                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 542      'send)))
 543
 544 (put 'gnus-setup-message 'lisp-indent-function 1)
 545 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 546
 547 ;;; Post news commands of Gnus group mode and summary mode
 548
 549 (defun gnus-group-mail (&optional arg)
 550   "Start composing a mail.
 551 If ARG, use the group under the point to find a posting style.
 552 If ARG is 1, prompt for a group name to find the posting style."
 553   (interactive "P")
 554   ;; We can't `let' gnus-newsgroup-name here, since that leads
 555   ;; to local variables leaking.
 556   (let ((group gnus-newsgroup-name)
 557         ;; make sure last viewed article doesn't affect posting styles:
 558         (gnus-article-copy)
 559         (buffer (current-buffer)))
 560     (unwind-protect
 561         (progn
 562           (setq gnus-newsgroup-name
 563                 (if arg
 564                     (if (= 1 (prefix-numeric-value arg))
 565                         (completing-read "Use posting style of group: "
 566                                          gnus-active-hashtb nil
 567                                          (gnus-read-active-file-p))
 568                       (gnus-group-group-name))
 569                   ""))
 570           ;; #### see comment in gnus-setup-message -- drv
 571           (gnus-setup-message 'message (message-mail)))
 572       (save-excursion
 573         (set-buffer buffer)
 574         (setq gnus-newsgroup-name group)))))
 575
 576 (defun gnus-group-news (&optional arg)
 577   "Start composing a news.
 578 If ARG, post to group under point.
 579 If ARG is 1, prompt for group name to post to.
 580
 581 This function prepares a news even when using mail groups.  This is useful
 582 for posting messages to mail groups without actually sending them over the
 583 network.  The corresponding back end must have a 'request-post method."
 584   (interactive "P")
 585   ;; We can't `let' gnus-newsgroup-name here, since that leads
 586   ;; to local variables leaking.
 587   (let ((group gnus-newsgroup-name)
 588         ;; make sure last viewed article doesn't affect posting styles:
 589         (gnus-article-copy)
 590         (buffer (current-buffer)))
 591     (unwind-protect
 592         (progn
 593           (setq gnus-newsgroup-name
 594                 (if arg
 595                     (if (= 1 (prefix-numeric-value arg))
 596                         (completing-read "Use group: "
 597                                          gnus-active-hashtb nil
 598                                          (gnus-read-active-file-p))
 599                       (gnus-group-group-name))
 600                   ""))
 601           ;; #### see comment in gnus-setup-message -- drv
 602           (gnus-setup-message 'message
 603             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 604       (save-excursion
 605         (set-buffer buffer)
 606         (setq gnus-newsgroup-name group)))))
 607
 608 (defun gnus-group-post-news (&optional arg)
 609   "Start composing a message (a news by default).
 610 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 611 Depending on the selected group, the message might be either a mail or
 612 a news."
 613   (interactive "P")
 614   ;; Bind this variable here to make message mode hooks work ok.
 615   (let ((gnus-newsgroup-name
 616          (if arg
 617              (if (= 1 (prefix-numeric-value arg))
 618                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 619                                   (gnus-read-active-file-p))
 620                (gnus-group-group-name))
 621            ""))
 622         ;; make sure last viewed article doesn't affect posting styles:
 623         (gnus-article-copy))
 624     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 625                     (string= gnus-newsgroup-name ""))))
 626
 627 (defun gnus-summary-mail-other-window (&optional arg)
 628   "Start composing a mail in another window.
 629 Use the posting of the current group by default.
 630 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 631 posting style."
 632   (interactive "P")
 633   ;; We can't `let' gnus-newsgroup-name here, since that leads
 634   ;; to local variables leaking.
 635   (let ((group gnus-newsgroup-name)
 636         ;; make sure last viewed article doesn't affect posting styles:
 637         (gnus-article-copy)
 638         (buffer (current-buffer)))
 639     (unwind-protect
 640         (progn
 641           (setq gnus-newsgroup-name
 642                 (if arg
 643                     (if (= 1 (prefix-numeric-value arg))
 644                         (completing-read "Use group: "
 645                                          gnus-active-hashtb nil
 646                                          (gnus-read-active-file-p))
 647                       "")
 648                   gnus-newsgroup-name))
 649           ;; #### see comment in gnus-setup-message -- drv
 650           (gnus-setup-message 'message (message-mail)))
 651       (save-excursion
 652         (set-buffer buffer)
 653         (setq gnus-newsgroup-name group)))))
 654
 655 (defun gnus-summary-news-other-window (&optional arg)
 656   "Start composing a news in another window.
 657 Post to the current group by default.
 658 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 659
 660 This function prepares a news even when using mail groups.  This is useful
 661 for posting messages to mail groups without actually sending them over the
 662 network.  The corresponding back end must have a 'request-post method."
 663   (interactive "P")
 664   ;; We can't `let' gnus-newsgroup-name here, since that leads
 665   ;; to local variables leaking.
 666   (let ((group gnus-newsgroup-name)
 667         ;; make sure last viewed article doesn't affect posting styles:
 668         (gnus-article-copy)
 669         (buffer (current-buffer)))
 670     (unwind-protect
 671         (progn
 672           (setq gnus-newsgroup-name
 673                 (if arg
 674                     (if (= 1 (prefix-numeric-value arg))
 675                         (completing-read "Use group: "
 676                                          gnus-active-hashtb nil
 677                                          (gnus-read-active-file-p))
 678                       "")
 679                   gnus-newsgroup-name))
 680           ;; #### see comment in gnus-setup-message -- drv
 681           (gnus-setup-message 'message
 682             (progn
 683               (message-news (gnus-group-real-name gnus-newsgroup-name))
 684               (set (make-local-variable 'gnus-discouraged-post-methods)
 685                    (delq
 686                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 687                     (copy-sequence gnus-discouraged-post-methods))))))
 688       (save-excursion
 689         (set-buffer buffer)
 690         (setq gnus-newsgroup-name group)))))
 691
 692 (defun gnus-summary-post-news (&optional arg)
 693   "Start composing a message.  Post to the current group by default.
 694 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 695 Depending on the selected group, the message might be either a mail or
 696 a news."
 697   (interactive "P")
 698   ;; Bind this variable here to make message mode hooks work ok.
 699   (let ((gnus-newsgroup-name
 700          (if arg
 701              (if (= 1 (prefix-numeric-value arg))
 702                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 703                                   (gnus-read-active-file-p))
 704                "")
 705            gnus-newsgroup-name))
 706         ;; make sure last viewed article doesn't affect posting styles:
 707         (gnus-article-copy))
 708     (gnus-post-news 'post gnus-newsgroup-name)))
 709
 710
 711 (defun gnus-summary-followup (yank &optional force-news)
 712   "Compose a followup to an article.
 713 If prefix argument YANK is non-nil, the original article is yanked
 714 automatically.
 715 YANK is a list of elements, where the car of each element is the
 716 article number, and the cdr is the string to be yanked."
 717   (interactive
 718    (list (and current-prefix-arg
 719               (gnus-summary-work-articles 1))))
 720   (when yank
 721     (gnus-summary-goto-subject
 722      (if (listp (car yank))
 723          (caar yank)
 724        (car yank))))
 725   (save-window-excursion
 726     (gnus-summary-select-article))
 727   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 728         (gnus-newsgroup-name gnus-newsgroup-name))
 729     ;; Send a followup.
 730     (gnus-post-news nil gnus-newsgroup-name
 731                     headers gnus-article-buffer
 732                     yank nil force-news)
 733     (gnus-summary-handle-replysign)))
 734
 735 (defun gnus-summary-followup-with-original (n &optional force-news)
 736   "Compose a followup to an article and include the original article.
 737 The text in the region will be yanked.  If the region isn't
 738 active, the entire article will be yanked."
 739   (interactive "P")
 740   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 741
 742 (defun gnus-summary-followup-to-mail (&optional arg)
 743   "Followup to the current mail message via news."
 744   (interactive
 745    (list (and current-prefix-arg
 746               (gnus-summary-work-articles 1))))
 747   (gnus-summary-followup arg t))
 748
 749 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 750   "Followup to the current mail message via news."
 751   (interactive "P")
 752   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 753
 754 (defun gnus-inews-yank-articles (articles)
 755   (let (beg article yank-string)
 756     (message-goto-body)
 757     (while (setq article (pop articles))
 758       (when (listp article)
 759         (setq yank-string (nth 1 article)
 760               article (nth 0 article)))
 761       (save-window-excursion
 762         (set-buffer gnus-summary-buffer)
 763         (gnus-summary-select-article nil nil nil article)
 764         (gnus-summary-remove-process-mark article))
 765       (gnus-copy-article-buffer nil yank-string)
 766       (let ((message-reply-buffer gnus-article-copy)
 767             (message-reply-headers
 768              ;; The headers are decoded.
 769              (with-current-buffer gnus-article-copy
 770                (save-restriction
 771                  (nnheader-narrow-to-headers)
 772                  (nnheader-parse-naked-head)))))
 773         (message-yank-original)
 774         (message-exchange-point-and-mark)
 775         (setq beg (or beg (mark t))))
 776       (when articles
 777         (insert "\n")))
 778     (push-mark)
 779     (goto-char beg)))
 780
 781 (defun gnus-summary-cancel-article (&optional n symp)
 782   "Cancel an article you posted.
 783 Uses the process-prefix convention.  If given the symbolic
 784 prefix `a', cancel using the standard posting method; if not
 785 post using the current select method."
 786   (interactive (gnus-interactive "P\ny"))
 787   (let ((articles (gnus-summary-work-articles n))
 788         (message-post-method
 789          `(lambda (arg)
 790             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 791         article)
 792     (while (setq article (pop articles))
 793       (when (gnus-summary-select-article t nil nil article)
 794         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 795                 (message-cancel-news))
 796           (gnus-summary-mark-as-read article gnus-canceled-mark)
 797           (gnus-cache-remove-article 1))
 798         (gnus-article-hide-headers-if-wanted))
 799       (gnus-summary-remove-process-mark article))))
 800
 801 (defun gnus-summary-supersede-article ()
 802   "Compose an article that will supersede a previous article.
 803 This is done simply by taking the old article and adding a Supersedes
 804 header line with the old Message-ID."
 805   (interactive)
 806   (let ((article (gnus-summary-article-number)))
 807     (gnus-setup-message 'reply-yank
 808       (gnus-summary-select-article t)
 809       (set-buffer gnus-original-article-buffer)
 810       (message-supersede)
 811       (push
 812        `((lambda ()
 813            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 814              (save-excursion
 815                (set-buffer ,gnus-summary-buffer)
 816                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 817                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 818        message-send-actions))))
 819
 820 \f
 821
 822 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 823   ;; make a copy of the article buffer with all text properties removed
 824   ;; this copy is in the buffer gnus-article-copy.
 825   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 826   ;; this buffer should be passed to all mail/news reply/post routines.
 827   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 828   (save-excursion
 829     (set-buffer gnus-article-copy)
 830     (mm-enable-multibyte))
 831   (let ((article-buffer (or article-buffer gnus-article-buffer))
 832         end beg)
 833     (if (not (and (get-buffer article-buffer)
 834                   (gnus-buffer-exists-p article-buffer)))
 835         (error "Can't find any article buffer")
 836       (save-excursion
 837         (set-buffer article-buffer)
 838         (let ((gnus-newsgroup-charset (or gnus-article-charset
 839                                           gnus-newsgroup-charset))
 840               (gnus-newsgroup-ignored-charsets
 841                (or gnus-article-ignored-charsets
 842                    gnus-newsgroup-ignored-charsets)))
 843           (save-restriction
 844             ;; Copy over the (displayed) article buffer, delete
 845             ;; hidden text and remove text properties.
 846             (widen)
 847             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 848             (set-buffer gnus-article-copy)
 849             (when yank-string
 850               (message-goto-body)
 851               (delete-region (point) (point-max))
 852               (insert yank-string))
 853             (gnus-article-delete-text-of-type 'annotation)
 854             (gnus-article-delete-text-of-type 'multipart)
 855             (gnus-remove-text-with-property 'gnus-prev)
 856             (gnus-remove-text-with-property 'gnus-next)
 857             (gnus-remove-text-with-property 'gnus-decoration)
 858             (insert
 859              (prog1
 860                  (buffer-substring-no-properties (point-min) (point-max))
 861                (erase-buffer)))
 862             ;; Find the original headers.
 863             (set-buffer gnus-original-article-buffer)
 864             (goto-char (point-min))
 865             (while (looking-at message-unix-mail-delimiter)
 866               (forward-line 1))
 867             (let ((mail-header-separator ""))
 868               (setq beg (point)
 869                     end (or (message-goto-body)
 870                             ;; There may be just a header.
 871                             (point-max))))
 872             ;; Delete the headers from the displayed articles.
 873             (set-buffer gnus-article-copy)
 874             (let ((mail-header-separator ""))
 875               (delete-region (goto-char (point-min))
 876                              (or (message-goto-body) (point-max))))
 877             ;; Insert the original article headers.
 878             (insert-buffer-substring gnus-original-article-buffer beg end)
 879             ;; Decode charsets.
 880             (let ((gnus-article-decode-hook
 881                    (delq 'article-decode-charset
 882                          (copy-sequence gnus-article-decode-hook)))
 883                   (rfc2047-quote-decoded-words-containing-tspecials t))
 884               (run-hooks 'gnus-article-decode-hook)))))
 885       gnus-article-copy)))
 886
 887 (defun gnus-post-news (post &optional group header article-buffer yank subject
 888                             force-news)
 889   (when article-buffer
 890     (gnus-copy-article-buffer))
 891   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 892         (gnus-article-yanked-articles yank)
 893         (add-to-list gnus-add-to-list))
 894     (gnus-setup-message (cond (yank 'reply-yank)
 895                               (article-buffer 'reply)
 896                               (t 'message))
 897       (let* ((group (or group gnus-newsgroup-name))
 898              (charset (gnus-group-name-charset nil group))
 899              (pgroup group)
 900              to-address to-group mailing-list to-list
 901              newsgroup-p)
 902         (when group
 903           (setq to-address (gnus-parameter-to-address group)
 904                 to-group (gnus-group-find-parameter group 'to-group)
 905                 to-list (gnus-parameter-to-list group)
 906                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 907                 mailing-list (when gnus-mailing-list-groups
 908                                (string-match gnus-mailing-list-groups group))
 909                 group (gnus-group-name-decode (gnus-group-real-name group)
 910                                               charset)))
 911         (if (or (and to-group
 912                      (gnus-news-group-p to-group))
 913                 newsgroup-p
 914                 force-news
 915                 (and (gnus-news-group-p
 916                       (or pgroup gnus-newsgroup-name)
 917                       (or header gnus-current-article))
 918                      (not mailing-list)
 919                      (not to-list)
 920                      (not to-address)))
 921             ;; This is news.
 922             (if post
 923                 (message-news
 924                  (or to-group
 925                      (and (not (gnus-virtual-group-p pgroup)) group)))
 926               (set-buffer gnus-article-copy)
 927               (gnus-msg-treat-broken-reply-to)
 928               (message-followup (if (or newsgroup-p force-news)
 929                                     (if (save-restriction
 930                                           (article-narrow-to-head)
 931                                           (message-fetch-field "newsgroups"))
 932                                         nil
 933                                       "")
 934                                   to-group)))
 935           ;; The is mail.
 936           (if post
 937               (progn
 938                 (message-mail (or to-address to-list))
 939                 ;; Arrange for mail groups that have no `to-address' to
 940                 ;; get that when the user sends off the mail.
 941                 (when (and (not to-list)
 942                            (not to-address)
 943                            add-to-list)
 944                   (push (list 'gnus-inews-add-to-address pgroup)
 945                         message-send-actions)))
 946             (set-buffer gnus-article-copy)
 947             (gnus-msg-treat-broken-reply-to)
 948             (message-wide-reply to-address)))
 949         (when yank
 950           (gnus-inews-yank-articles yank))))))
 951
 952 (defun gnus-msg-treat-broken-reply-to (&optional force)
 953   "Remove the Reply-to header if broken-reply-to."
 954   (when (or force
 955             (gnus-group-find-parameter
 956              gnus-newsgroup-name 'broken-reply-to))
 957     (save-restriction
 958       (message-narrow-to-head)
 959       (message-remove-header "reply-to"))))
 960
 961 (defun gnus-post-method (arg group &optional silent)
 962   "Return the posting method based on GROUP and ARG.
 963 If SILENT, don't prompt the user."
 964   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 965                               gnus-post-method))
 966         (group-method (gnus-find-method-for-group group)))
 967     (cond
 968      ;; If the group-method is nil (which shouldn't happen) we use
 969      ;; the default method.
 970      ((null group-method)
 971       (or (and (listp gnus-post-method) ;If not current/native/nil
 972                (not (listp (car gnus-post-method))) ; and not a list of methods
 973                gnus-post-method)        ;then use it.
 974           gnus-select-method
 975           message-post-method))
 976      ;; We want the inverse of the default
 977      ((and arg (not (eq arg 0)))
 978       (if (eq gnus-post-method 'current)
 979           gnus-select-method
 980         group-method))
 981      ;; We query the user for a post method.
 982      ((or arg
 983           (and (listp gnus-post-method)
 984                (listp (car gnus-post-method))))
 985       (let* ((methods
 986               ;; Collect all methods we know about.
 987               (append
 988                (when (listp gnus-post-method)
 989                  (if (listp (car gnus-post-method))
 990                      gnus-post-method
 991                    (list gnus-post-method)))
 992                gnus-secondary-select-methods
 993                (mapcar 'cdr gnus-server-alist)
 994                (mapcar 'car gnus-opened-servers)
 995                (list gnus-select-method)
 996                (list group-method)))
 997              method-alist post-methods method)
 998         ;; Weed out all mail methods.
 999         (while methods
1000           (setq method (gnus-server-get-method "" (pop methods)))
1001           (when (and (or (gnus-method-option-p method 'post)
1002                          (gnus-method-option-p method 'post-mail))
1003                      (not (member method post-methods)))
1004             (push method post-methods)))
1005         ;; Create a name-method alist.
1006         (setq method-alist
1007               (mapcar
1008                (lambda (m)
1009                  (if (equal (cadr m) "")
1010                      (list (symbol-name (car m)) m)
1011                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1012                post-methods))
1013         ;; Query the user.
1014         (cadr
1015          (assoc
1016           (setq gnus-last-posting-server
1017                 (if (and silent
1018                          gnus-last-posting-server)
1019                     ;; Just use the last value.
1020                     gnus-last-posting-server
1021                   (completing-read
1022                    "Posting method: " method-alist nil t
1023                    (cons (or gnus-last-posting-server "") 0))))
1024           method-alist))))
1025      ;; Override normal method.
1026      ((and (eq gnus-post-method 'current)
1027            (not (memq (car group-method) gnus-discouraged-post-methods))
1028            (gnus-get-function group-method 'request-post t))
1029       (assert (not arg))
1030       group-method)
1031      ;; Use gnus-post-method.
1032      ((listp gnus-post-method)          ;A method...
1033       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1034       gnus-post-method)
1035      ;; Use the normal select method (nil or native).
1036      (t gnus-select-method))))
1037
1038 \f
1039
1040 (defun gnus-extended-version ()
1041   "Stringified Gnus version and Emacs version.
1042 See the variable `gnus-user-agent'."
1043   (interactive)
1044   (if (stringp gnus-user-agent)
1045       gnus-user-agent
1046     ;; `gnus-user-agent' is a list:
1047     (let* ((float-output-format nil)
1048            (gnus-v
1049             (when (memq 'gnus gnus-user-agent)
1050               (concat "Gnus/"
1051                       (prin1-to-string (gnus-continuum-version gnus-version) t)
1052                       " (" gnus-version ")")))
1053            (emacs-v (gnus-emacs-version)))
1054       (concat gnus-v (when (and gnus-v emacs-v) " ")
1055               emacs-v))))
1056
1057 \f
1058 ;;;
1059 ;;; Gnus Mail Functions
1060 ;;;
1061
1062 ;;; Mail reply commands of Gnus summary mode
1063
1064 (defun gnus-summary-reply (&optional yank wide very-wide)
1065   "Start composing a mail reply to the current message.
1066 If prefix argument YANK is non-nil, the original article is yanked
1067 automatically.
1068 If WIDE, make a wide reply.
1069 If VERY-WIDE, make a very wide reply."
1070   (interactive
1071    (list (and current-prefix-arg
1072               (gnus-summary-work-articles 1))))
1073   ;; Allow user to require confirmation before replying by mail to the
1074   ;; author of a news article (or mail message).
1075   (when (or
1076             (not (or (gnus-news-group-p gnus-newsgroup-name)
1077                      gnus-confirm-treat-mail-like-news))
1078             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1079                         (string-match gnus-confirm-mail-reply-to-news
1080                                       gnus-newsgroup-name))
1081                        ((functionp gnus-confirm-mail-reply-to-news)
1082                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1083                        (t gnus-confirm-mail-reply-to-news)))
1084             (y-or-n-p "Really reply by mail to article author? "))
1085     (let* ((article
1086             (if (listp (car yank))
1087                 (caar yank)
1088               (car yank)))
1089            (gnus-article-reply (or article (gnus-summary-article-number)))
1090            (gnus-article-yanked-articles yank)
1091            (headers ""))
1092       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1093       (when yank
1094         (gnus-summary-goto-subject article))
1095       (gnus-setup-message (if yank 'reply-yank 'reply)
1096         (if (not very-wide)
1097             (gnus-summary-select-article)
1098           (dolist (article very-wide)
1099             (gnus-summary-select-article nil nil nil article)
1100             (save-excursion
1101               (set-buffer (gnus-copy-article-buffer))
1102               (gnus-msg-treat-broken-reply-to)
1103               (save-restriction
1104                 (message-narrow-to-head)
1105                 (setq headers (concat headers (buffer-string)))))))
1106         (set-buffer (gnus-copy-article-buffer))
1107         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1108         (save-restriction
1109           (message-narrow-to-head)
1110           (when very-wide
1111             (erase-buffer)
1112             (insert headers))
1113           (goto-char (point-max)))
1114         (mml-quote-region (point) (point-max))
1115         (message-reply nil wide)
1116         (when yank
1117           (gnus-inews-yank-articles yank))
1118         (gnus-summary-handle-replysign)))))
1119
1120 (defun gnus-summary-handle-replysign ()
1121   "Check the various replysign variables and take action accordingly."
1122   (when (or gnus-message-replysign gnus-message-replyencrypt)
1123     (let (signed encrypted)
1124       (save-excursion
1125         (set-buffer gnus-article-buffer)
1126         (setq signed (memq 'signed gnus-article-wash-types))
1127         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1128       (cond ((and gnus-message-replyencrypt encrypted)
1129              (mml-secure-message mml-default-encrypt-method
1130                                  (if gnus-message-replysignencrypted
1131                                      'signencrypt
1132                                    'encrypt)))
1133             ((and gnus-message-replysign signed)
1134              (mml-secure-message mml-default-sign-method 'sign))))))
1135
1136 (defun gnus-summary-reply-with-original (n &optional wide)
1137   "Start composing a reply mail to the current message.
1138 The original article will be yanked."
1139   (interactive "P")
1140   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1141
1142 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1143   "Like `gnus-summary-reply' except removing reply-to field.
1144 If prefix argument YANK is non-nil, the original article is yanked
1145 automatically.
1146 If WIDE, make a wide reply.
1147 If VERY-WIDE, make a very wide reply."
1148   (interactive
1149    (list (and current-prefix-arg
1150               (gnus-summary-work-articles 1))))
1151   (let ((gnus-msg-force-broken-reply-to t))
1152     (gnus-summary-reply yank wide very-wide)))
1153
1154 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1155   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1156 The original article will be yanked."
1157   (interactive "P")
1158   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1159
1160 (defun gnus-summary-wide-reply (&optional yank)
1161   "Start composing a wide reply mail to the current message.
1162 If prefix argument YANK is non-nil, the original article is yanked
1163 automatically."
1164   (interactive
1165    (list (and current-prefix-arg
1166               (gnus-summary-work-articles 1))))
1167   (gnus-summary-reply yank t))
1168
1169 (defun gnus-summary-wide-reply-with-original (n)
1170   "Start composing a wide reply mail to the current message.
1171 The original article will be yanked.
1172 Uses the process/prefix convention."
1173   (interactive "P")
1174   (gnus-summary-reply-with-original n t))
1175
1176 (defun gnus-summary-very-wide-reply (&optional yank)
1177   "Start composing a very wide reply mail to the current message.
1178 If prefix argument YANK is non-nil, the original article is yanked
1179 automatically."
1180   (interactive
1181    (list (and current-prefix-arg
1182               (gnus-summary-work-articles 1))))
1183   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1184
1185 (defun gnus-summary-very-wide-reply-with-original (n)
1186   "Start composing a very wide reply mail to the current message.
1187 The original article will be yanked."
1188   (interactive "P")
1189   (gnus-summary-reply
1190    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1191
1192 (defun gnus-summary-mail-forward (&optional arg post)
1193   "Forward the current message(s) to another user.
1194 If process marks exist, forward all marked messages;
1195 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1196 if ARG is 1, decode the message and forward directly inline;
1197 if ARG is 2, forward message as an rfc822 MIME section;
1198 if ARG is 3, decode message and forward as an rfc822 MIME section;
1199 if ARG is 4, forward message directly inline;
1200 otherwise, use flipped `message-forward-as-mime'.
1201 If POST, post instead of mail.
1202 For the `inline' alternatives, also see the variable
1203 `message-forward-ignored-headers'."
1204   (interactive "P")
1205   (if (cdr (gnus-summary-work-articles nil))
1206       ;; Process marks are given.
1207       (gnus-uu-digest-mail-forward arg post)
1208     ;; No process marks.
1209     (let ((message-forward-as-mime message-forward-as-mime)
1210           (message-forward-show-mml message-forward-show-mml))
1211       (cond
1212        ((null arg))
1213        ((eq arg 1)
1214         (setq message-forward-as-mime nil
1215               message-forward-show-mml t))
1216        ((eq arg 2)
1217         (setq message-forward-as-mime t
1218               message-forward-show-mml nil))
1219        ((eq arg 3)
1220         (setq message-forward-as-mime t
1221               message-forward-show-mml t))
1222        ((eq arg 4)
1223         (setq message-forward-as-mime nil
1224               message-forward-show-mml nil))
1225        (t
1226         (setq message-forward-as-mime (not message-forward-as-mime))))
1227       (let* ((gnus-article-reply (gnus-summary-article-number))
1228              (gnus-article-yanked-articles (list gnus-article-reply)))
1229         (gnus-setup-message 'forward
1230           (gnus-summary-select-article)
1231           (let ((mail-parse-charset
1232                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1233                           (with-current-buffer gnus-article-buffer
1234                             gnus-article-charset))
1235                      gnus-newsgroup-charset))
1236                 (mail-parse-ignored-charsets
1237                  gnus-newsgroup-ignored-charsets))
1238             (set-buffer gnus-original-article-buffer)
1239             (message-forward post)))))))
1240
1241 (defun gnus-summary-resend-message (address n)
1242   "Resend the current article to ADDRESS."
1243   (interactive
1244    (list (message-read-from-minibuffer
1245           "Resend message(s) to: "
1246           (when (and gnus-summary-resend-default-address
1247                      (gnus-buffer-live-p gnus-original-article-buffer))
1248             ;; If some other article is currently selected, the
1249             ;; initial-contents is wrong. Whatever, it is just the
1250             ;; initial-contents.
1251             (with-current-buffer gnus-original-article-buffer
1252               (nnmail-fetch-field "to"))))
1253          current-prefix-arg))
1254   (let ((articles (gnus-summary-work-articles n))
1255         article)
1256     (while (setq article (pop articles))
1257       (gnus-summary-select-article nil nil nil article)
1258       (save-excursion
1259         (set-buffer gnus-original-article-buffer)
1260         (message-resend address))
1261       (gnus-summary-mark-article-as-forwarded article))))
1262
1263 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1264 (defun gnus-summary-resend-message-edit ()
1265   "Resend an article that has already been sent.
1266 A new buffer will be created to allow the user to modify body and
1267 contents of the message, and then, everything will happen as when
1268 composing a new message."
1269   (interactive)
1270   (let ((article (gnus-summary-article-number)))
1271     (gnus-setup-message 'reply-yank
1272       (gnus-summary-select-article t)
1273       (set-buffer gnus-original-article-buffer)
1274       (let ((cur (current-buffer))
1275             (to (message-fetch-field "to")))
1276         ;; Get a normal message buffer.
1277         (message-pop-to-buffer (message-buffer-name "Resend" to))
1278         (insert-buffer-substring cur)
1279         (mime-to-mml)
1280         (message-narrow-to-head-1)
1281         ;; Gnus will generate a new one when sending.
1282         (message-remove-header "Message-ID")
1283         (message-remove-header message-ignored-resent-headers t)
1284         ;; Remove unwanted headers.
1285         (goto-char (point-max))
1286         (insert mail-header-separator)
1287         (goto-char (point-min))
1288         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1289           (forward-char 1))
1290         (widen)))))
1291
1292 (defun gnus-summary-post-forward (&optional arg)
1293   "Forward the current article to a newsgroup.
1294 See `gnus-summary-mail-forward' for ARG."
1295   (interactive "P")
1296   (gnus-summary-mail-forward arg t))
1297
1298 (defvar gnus-nastygram-message
1299   "The following article was inappropriately posted to %s.\n\n"
1300   "Format string to insert in nastygrams.
1301 The current group name will be inserted at \"%s\".")
1302
1303 (defun gnus-summary-mail-nastygram (n)
1304   "Send a nastygram to the author of the current article."
1305   (interactive "P")
1306   (when (or gnus-expert-user
1307             (gnus-y-or-n-p
1308              "Really send a nastygram to the author of the current article? "))
1309     (let ((group gnus-newsgroup-name))
1310       (gnus-summary-reply-with-original n)
1311       (set-buffer gnus-message-buffer)
1312       (message-goto-body)
1313       (insert (format gnus-nastygram-message group))
1314       (message-send-and-exit))))
1315
1316 (defun gnus-summary-mail-crosspost-complaint (n)
1317   "Send a complaint about crossposting to the current article(s)."
1318   (interactive "P")
1319   (let ((articles (gnus-summary-work-articles n))
1320         article)
1321     (while (setq article (pop articles))
1322       (set-buffer gnus-summary-buffer)
1323       (gnus-summary-goto-subject article)
1324       (let ((group (gnus-group-real-name gnus-newsgroup-name))
1325             newsgroups followup-to)
1326         (gnus-summary-select-article)
1327         (set-buffer gnus-original-article-buffer)
1328         (if (and (<= (length (message-tokenize-header
1329                               (setq newsgroups
1330                                     (mail-fetch-field "newsgroups"))
1331                               ", "))
1332                      1)
1333                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
1334                      (not (member group (message-tokenize-header
1335                                          followup-to ", ")))))
1336             (if followup-to
1337                 (gnus-message 1 "Followup-to restricted")
1338               (gnus-message 1 "Not a crossposted article"))
1339           (set-buffer gnus-summary-buffer)
1340           (gnus-summary-reply-with-original 1)
1341           (set-buffer gnus-message-buffer)
1342           (message-goto-body)
1343           (insert (format gnus-crosspost-complaint newsgroups group))
1344           (message-goto-subject)
1345           (re-search-forward " *$")
1346           (replace-match " (crosspost notification)" t t)
1347           (gnus-deactivate-mark)
1348           (when (gnus-y-or-n-p "Send this complaint? ")
1349             (message-send-and-exit)))))))
1350
1351 (defun gnus-mail-parse-comma-list ()
1352   (let (accumulated
1353         beg)
1354     (skip-chars-forward " ")
1355     (while (not (eobp))
1356       (setq beg (point))
1357       (skip-chars-forward "^,")
1358       (while (zerop
1359               (save-excursion
1360                 (save-restriction
1361                   (let ((i 0))
1362                     (narrow-to-region beg (point))
1363                     (goto-char beg)
1364                     (logand (progn
1365                               (while (search-forward "\"" nil t)
1366                                 (incf i))
1367                               (if (zerop i) 2 i))
1368                             2)))))
1369         (skip-chars-forward ",")
1370         (skip-chars-forward "^,"))
1371       (skip-chars-backward " ")
1372       (push (buffer-substring beg (point))
1373             accumulated)
1374       (skip-chars-forward "^,")
1375       (skip-chars-forward ", "))
1376     accumulated))
1377
1378 (defun gnus-inews-add-to-address (group)
1379   (let ((to-address (mail-fetch-field "to")))
1380     (when (and to-address
1381                (gnus-alive-p))
1382       ;; This mail group doesn't have a `to-list', so we add one
1383       ;; here.  Magic!
1384       (when (gnus-y-or-n-p
1385              (format "Do you want to add this as `to-list': %s? " to-address))
1386         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1387
1388 (defun gnus-put-message ()
1389   "Put the current message in some group and return to Gnus."
1390   (interactive)
1391   (let ((reply gnus-article-reply)
1392         (winconf gnus-prev-winconf)
1393         (group gnus-newsgroup-name))
1394     (unless (and group
1395                  (not (gnus-group-read-only-p group)))
1396       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1397
1398     (when (gnus-gethash group gnus-newsrc-hashtb)
1399       (error "No such group: %s" group))
1400     (save-excursion
1401       (save-restriction
1402         (widen)
1403         (message-narrow-to-headers)
1404         (let ((gnus-deletable-headers nil))
1405           (message-generate-headers
1406            (if (message-news-p)
1407                message-required-news-headers
1408              message-required-mail-headers)))
1409         (goto-char (point-max))
1410         (if (string-match " " group)
1411             (insert "Gcc: \"" group "\"\n")
1412           (insert "Gcc: " group "\n"))
1413         (widen)))
1414     (gnus-inews-do-gcc)
1415     (when (and (get-buffer gnus-group-buffer)
1416                (gnus-buffer-exists-p (car-safe reply))
1417                (cdr reply))
1418       (set-buffer (car reply))
1419       (gnus-summary-mark-article-as-replied (cdr reply)))
1420     (when winconf
1421       (set-window-configuration winconf))))
1422
1423 (defun gnus-article-mail (yank)
1424   "Send a reply to the address near point.
1425 If YANK is non-nil, include the original article."
1426   (interactive "P")
1427   (let ((address
1428          (buffer-substring
1429           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1430           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1431     (when address
1432       (gnus-msg-mail address)
1433       (when yank
1434         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1435
1436 (defvar nntp-server-type)
1437 (defun gnus-bug ()
1438   "Send a bug report to the Gnus maintainers."
1439   (interactive)
1440   (unless (gnus-alive-p)
1441     (error "Gnus has been shut down"))
1442   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1443     (unless (message-mail-user-agent)
1444       (delete-other-windows)
1445       (when gnus-bug-create-help-buffer
1446         (switch-to-buffer "*Gnus Help Bug*")
1447         (erase-buffer)
1448         (insert gnus-bug-message)
1449         (goto-char (point-min)))
1450       (message-pop-to-buffer "*Gnus Bug*"))
1451     (let ((message-this-is-mail t))
1452       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1453     (when gnus-bug-create-help-buffer
1454       (push `(gnus-bug-kill-buffer) message-send-actions))
1455     (goto-char (point-min))
1456     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1457     (forward-line 1)
1458     (insert (gnus-version) "\n"
1459             (emacs-version) "\n")
1460     (when (and (boundp 'nntp-server-type)
1461                (stringp nntp-server-type))
1462       (insert nntp-server-type))
1463     (insert "\n\n\n\n\n")
1464     (let (text)
1465       (save-excursion
1466         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1467         (erase-buffer)
1468         (gnus-debug)
1469         (setq text (buffer-string)))
1470       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1471     (goto-char (point-min))
1472     (search-forward "Subject: " nil t)
1473     (message "")))
1474
1475 (defun gnus-bug-kill-buffer ()
1476   (when (get-buffer "*Gnus Help Bug*")
1477     (kill-buffer "*Gnus Help Bug*")))
1478
1479 (defun gnus-summary-yank-message (buffer n)
1480   "Yank the current article into a composed message."
1481   (interactive
1482    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1483          current-prefix-arg))
1484   (gnus-summary-iterate n
1485     (let ((gnus-inhibit-treatment t))
1486       (gnus-summary-select-article))
1487     (save-excursion
1488       (set-buffer buffer)
1489       (message-yank-buffer gnus-article-buffer))))
1490
1491 (defun gnus-debug ()
1492   "Attempts to go through the Gnus source file and report what variables have been changed.
1493 The source file has to be in the Emacs load path."
1494   (interactive)
1495   (let ((files gnus-debug-files)
1496         (point (point))
1497         file expr olist sym)
1498     (gnus-message 4 "Please wait while we snoop your variables...")
1499     (sit-for 0)
1500     ;; Go through all the files looking for non-default values for variables.
1501     (save-excursion
1502       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1503       (while files
1504         (erase-buffer)
1505         (when (and (setq file (locate-library (pop files)))
1506                    (file-exists-p file))
1507           (insert-file-contents file)
1508           (goto-char (point-min))
1509           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1510               (gnus-message 4 "Malformed sources in file %s" file)
1511             (narrow-to-region (point-min) (point))
1512             (goto-char (point-min))
1513             (while (setq expr (ignore-errors (read (current-buffer))))
1514               (ignore-errors
1515                 (and (or (eq (car expr) 'defvar)
1516                          (eq (car expr) 'defcustom))
1517                      (stringp (nth 3 expr))
1518                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1519                      (or (not (boundp (nth 1 expr)))
1520                          (not (equal (eval (nth 2 expr))
1521                                      (symbol-value (nth 1 expr)))))
1522                      (push (nth 1 expr) olist)))))))
1523       (kill-buffer (current-buffer)))
1524     (when (setq olist (nreverse olist))
1525       (insert "------------------ Environment follows ------------------\n\n"))
1526     (while olist
1527       (if (boundp (car olist))
1528           (ignore-errors
1529            (gnus-pp
1530             `(setq ,(car olist)
1531                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1532                             (and (symbolp sym)
1533                                  (not (or (eq sym nil)
1534                                           (eq sym t)))))
1535                         (list 'quote (symbol-value (car olist)))
1536                       (symbol-value (car olist))))))
1537         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1538       (setq olist (cdr olist)))
1539     (insert "\n\n")
1540     ;; Remove any control chars - they seem to cause trouble for some
1541     ;; mailers.  (Byte-compiled output from the stuff above.)
1542     (goto-char point)
1543     (while (re-search-forward (mm-string-as-multibyte
1544                                "[\000-\010\013-\037\200-\237]") nil t)
1545       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1546                      t t))))
1547
1548 ;;; Treatment of rejected articles.
1549 ;;; Bounced mail.
1550
1551 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1552   "Re-mail the current message.
1553 This only makes sense if the current message is a bounce message that
1554 contains some mail you have written which has been bounced back to
1555 you.
1556 If FETCH, try to fetch the article that this is a reply to, if indeed
1557 this is a reply."
1558   (interactive "P")
1559   (gnus-summary-select-article t)
1560   (set-buffer gnus-original-article-buffer)
1561   (gnus-setup-message 'compose-bounce
1562     (let* ((references (mail-fetch-field "references"))
1563            (parent (and references (gnus-parent-id references))))
1564       (message-bounce)
1565       ;; If there are references, we fetch the article we answered to.
1566       (and fetch parent
1567            (gnus-summary-refer-article parent)
1568            (gnus-summary-show-all-headers)))))
1569
1570 ;;; Gcc handling.
1571
1572 (defun gnus-inews-group-method (group)
1573   (cond
1574    ;; If the group doesn't exist, we assume
1575    ;; it's an archive group...
1576    ((and (null (gnus-get-info group))
1577          (eq (car (gnus-server-to-method gnus-message-archive-method))
1578              (car (gnus-server-to-method (gnus-group-method group)))))
1579     gnus-message-archive-method)
1580    ;; Use the method.
1581    ((gnus-info-method (gnus-get-info group))
1582     (gnus-info-method (gnus-get-info group)))
1583    ;; Find the method.
1584    (t (gnus-server-to-method (gnus-group-method group)))))
1585
1586 ;; Do Gcc handling, which copied the message over to some group.
1587 (defun gnus-inews-do-gcc (&optional gcc)
1588   (interactive)
1589   (save-excursion
1590     (save-restriction
1591       (message-narrow-to-headers)
1592       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1593             (cur (current-buffer))
1594             groups group method group-art
1595             mml-externalize-attachments)
1596         (when gcc
1597           (message-remove-header "gcc")
1598           (widen)
1599           (setq groups (message-unquote-tokens
1600                         (message-tokenize-header gcc " ,")))
1601           ;; Copy the article over to some group(s).
1602           (while (setq group (pop groups))
1603             (unless (gnus-check-server
1604                      (setq method (gnus-inews-group-method group)))
1605               (error "Can't open server %s" (if (stringp method) method
1606                                               (car method))))
1607             (unless (gnus-request-group group nil method)
1608               (gnus-request-create-group group method))
1609             (setq mml-externalize-attachments
1610                   (if (stringp gnus-gcc-externalize-attachments)
1611                       (string-match gnus-gcc-externalize-attachments group)
1612                     gnus-gcc-externalize-attachments))
1613             (save-excursion
1614               (nnheader-set-temp-buffer " *acc*")
1615               (insert-buffer-substring cur)
1616               (message-encode-message-body)
1617               (save-restriction
1618                 (message-narrow-to-headers)
1619                 (let* ((mail-parse-charset message-default-charset)
1620                        (newsgroups-field (save-restriction
1621                                            (message-narrow-to-headers-or-head)
1622                                            (message-fetch-field "Newsgroups")))
1623                        (followup-field (save-restriction
1624                                          (message-narrow-to-headers-or-head)
1625                                          (message-fetch-field "Followup-To")))
1626                        ;; BUG: We really need to get the charset for
1627                        ;; each name in the Newsgroups and Followup-To
1628                        ;; lines to allow crossposting between group
1629                        ;; namess with incompatible character sets.
1630                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1631                        (group-field-charset
1632                         (gnus-group-name-charset
1633                          method (or newsgroups-field "")))
1634                        (followup-field-charset
1635                         (gnus-group-name-charset
1636                          method (or followup-field "")))
1637                        (rfc2047-header-encoding-alist
1638                         (append
1639                          (when group-field-charset
1640                            (list (cons "Newsgroups" group-field-charset)))
1641                          (when followup-field-charset
1642                            (list (cons "Followup-To" followup-field-charset)))
1643                          rfc2047-header-encoding-alist)))
1644                   (mail-encode-encoded-word-buffer)))
1645               (goto-char (point-min))
1646               (when (re-search-forward
1647                      (concat "^" (regexp-quote mail-header-separator) "$")
1648                      nil t)
1649                 (replace-match "" t t ))
1650               (unless (setq group-art
1651                             (gnus-request-accept-article group method t t))
1652                 (gnus-message 1 "Couldn't store article in group %s: %s"
1653                               group (gnus-status-message method))
1654                 (sit-for 2))
1655               (when (and group-art
1656                          ;; FIXME: Should gcc-mark-as-read work when
1657                          ;; Gnus is not running?
1658                          (gnus-alive-p)
1659                          (or gnus-gcc-mark-as-read
1660                              (and
1661                               (boundp 'gnus-inews-mark-gcc-as-read)
1662                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1663                 (gnus-group-mark-article-read group (cdr group-art)))
1664               (kill-buffer (current-buffer)))))))))
1665
1666 (defun gnus-inews-insert-gcc ()
1667   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1668   (save-excursion
1669     (save-restriction
1670       (message-narrow-to-headers)
1671       (let* ((group gnus-outgoing-message-group)
1672              (gcc (cond
1673                    ((functionp group)
1674                     (funcall group))
1675                    ((or (stringp group) (listp group))
1676                     group))))
1677         (when gcc
1678           (insert "Gcc: "
1679                   (if (stringp gcc)
1680                       (if (string-match " " gcc)
1681                           (concat "\"" gcc "\"")
1682                         gcc)
1683                     (mapconcat (lambda (group)
1684                                  (if (string-match " " group)
1685                                      (concat "\"" group "\"")
1686                                    group))
1687                                gcc " "))
1688                   "\n"))))))
1689
1690 (defun gnus-inews-insert-archive-gcc (&optional group)
1691   "Insert the Gcc to say where the article is to be archived."
1692   (let* ((var gnus-message-archive-group)
1693          (group (or group gnus-newsgroup-name ""))
1694          (gcc-self-val
1695           (and gnus-newsgroup-name
1696                (not (equal gnus-newsgroup-name ""))
1697                (gnus-group-find-parameter
1698                 gnus-newsgroup-name 'gcc-self)))
1699          result
1700          (groups
1701           (cond
1702            ((null gnus-message-archive-method)
1703             ;; Ignore.
1704             nil)
1705            ((stringp var)
1706             ;; Just a single group.
1707             (list var))
1708            ((null var)
1709             ;; We don't want this.
1710             nil)
1711            ((and (listp var) (stringp (car var)))
1712             ;; A list of groups.
1713             var)
1714            ((functionp var)
1715             ;; A function.
1716             (funcall var group))
1717            (t
1718             ;; An alist of regexps/functions/forms.
1719             (while (and var
1720                         (not
1721                          (setq result
1722                                (cond
1723                                 ((stringp (caar var))
1724                                  ;; Regexp.
1725                                  (when (string-match (caar var) group)
1726                                    (cdar var)))
1727                                 ((functionp (car var))
1728                                  ;; Function.
1729                                  (funcall (car var) group))
1730                                 (t
1731                                  (eval (car var)))))))
1732               (setq var (cdr var)))
1733             result)))
1734          name)
1735     (when (or groups gcc-self-val)
1736       (when (stringp groups)
1737         (setq groups (list groups)))
1738       (save-excursion
1739         (save-restriction
1740           (message-narrow-to-headers)
1741           (goto-char (point-max))
1742           (insert "Gcc: ")
1743           (if gcc-self-val
1744               ;; Use the `gcc-self' param value instead.
1745               (progn
1746                 (insert
1747                  (if (stringp gcc-self-val)
1748                      (if (string-match " " gcc-self-val)
1749                          (concat "\"" gcc-self-val "\"")
1750                        gcc-self-val)
1751                    ;; In nndoc groups, we use the parent group name
1752                    ;; instead of the current group.
1753                    (let ((group (or (gnus-group-find-parameter
1754                                      gnus-newsgroup-name 'parent-group)
1755                                     group)))
1756                      (if (string-match " " group)
1757                          (concat "\"" group "\"")
1758                        group))))
1759                 (if (not (eq gcc-self-val 'none))
1760                     (insert "\n")
1761                   (gnus-delete-line)))
1762             ;; Use the list of groups.
1763             (while (setq name (pop groups))
1764               (let ((str (if (string-match ":" name)
1765                              name
1766                            (gnus-group-prefixed-name
1767                             name gnus-message-archive-method))))
1768                 (insert (if (string-match " " str)
1769                             (concat "\"" str "\"")
1770                           str)))
1771               (when groups
1772                 (insert " ")))
1773             (insert "\n")))))))
1774
1775 (defun gnus-mailing-list-followup-to ()
1776   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1777   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1778         (list-post (gnus-fetch-original-field "list-post")))
1779     (when (and list-post
1780                (string-match "mailto:\\([^>]+\\)" list-post))
1781       (setq list-post (match-string 1 list-post)))
1782     (or list-post
1783         x-been-there)))
1784
1785 ;;; Posting styles.
1786
1787 (defun gnus-configure-posting-styles (&optional group-name)
1788   "Configure posting styles according to `gnus-posting-styles'."
1789   (unless gnus-inhibit-posting-styles
1790     (let ((group (or group-name gnus-newsgroup-name ""))
1791           (styles gnus-posting-styles)
1792           style match attribute value v results
1793           filep name address element)
1794       ;; If the group has a posting-style parameter, add it at the end with a
1795       ;; regexp matching everything, to be sure it takes precedence over all
1796       ;; the others.
1797       (when gnus-newsgroup-name
1798         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1799           (when tmp-style
1800             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1801       ;; Go through all styles and look for matches.
1802       (dolist (style styles)
1803         (setq match (pop style))
1804         (goto-char (point-min))
1805         (when (cond
1806                ((stringp match)
1807                 ;; Regexp string match on the group name.
1808                 (string-match match group))
1809                ((eq match 'header)
1810                 ;; Obsolete format of header match.
1811                 (and (gnus-buffer-live-p gnus-article-copy)
1812                      (with-current-buffer gnus-article-copy
1813                        (save-restriction
1814                          (nnheader-narrow-to-headers)
1815                          (let ((header (message-fetch-field (pop style))))
1816                            (and header
1817                                 (string-match (pop style) header)))))))
1818                ((or (symbolp match)
1819                     (functionp match))
1820                 (cond
1821                  ((functionp match)
1822                   ;; Function to be called.
1823                   (funcall match))
1824                  ((boundp match)
1825                   ;; Variable to be checked.
1826                   (symbol-value match))))
1827                ((listp match)
1828                 (cond
1829                  ((eq (car match) 'header)
1830                   ;; New format of header match.
1831                   (and (gnus-buffer-live-p gnus-article-copy)
1832                        (with-current-buffer gnus-article-copy
1833                          (save-restriction
1834                            (nnheader-narrow-to-headers)
1835                            (let ((header (message-fetch-field (nth 1 match))))
1836                              (and header
1837                                   (string-match (nth 2 match) header)))))))
1838                  (t
1839                   ;; This is a form to be evaled.
1840                   (eval match)))))
1841           ;; We have a match, so we set the variables.
1842           (dolist (attribute style)
1843             (setq element (pop attribute)
1844                   filep nil)
1845             (setq value
1846                   (cond
1847                    ((eq (car attribute) :file)
1848                     (setq filep t)
1849                     (cadr attribute))
1850                    ((eq (car attribute) :value)
1851                     (cadr attribute))
1852                    (t
1853                     (car attribute))))
1854             ;; We get the value.
1855             (setq v
1856                   (cond
1857                    ((stringp value)
1858                     value)
1859                    ((or (symbolp value)
1860                         (functionp value))
1861                     (cond ((functionp value)
1862                            (funcall value))
1863                           ((boundp value)
1864                            (symbol-value value))))
1865                    ((listp value)
1866                     (eval value))))
1867             ;; Translate obsolescent value.
1868             (cond
1869              ((eq element 'signature-file)
1870               (setq element 'signature
1871                     filep t))
1872              ((eq element 'x-face-file)
1873               (setq element 'x-face
1874                     filep t)))
1875             ;; Get the contents of file elems.
1876             (when (and filep v)
1877               (setq v (with-temp-buffer
1878                         (insert-file-contents v)
1879                         (buffer-substring
1880                          (point-min)
1881                          (progn
1882                            (goto-char (point-max))
1883                            (if (zerop (skip-chars-backward "\n"))
1884                                (point)
1885                              (1+ (point))))))))
1886             (setq results (delq (assoc element results) results))
1887             (push (cons element v) results))))
1888       ;; Now we have all the styles, so we insert them.
1889       (setq name (assq 'name results)
1890             address (assq 'address results))
1891       (setq results (delq name (delq address results)))
1892       (gnus-make-local-hook 'message-setup-hook)
1893       (setq results (sort results (lambda (x y)
1894                                     (string-lessp (car x) (car y)))))
1895       (dolist (result results)
1896         (add-hook 'message-setup-hook
1897                   (cond
1898                    ((eq 'eval (car result))
1899                     'ignore)
1900                    ((eq 'body (car result))
1901                     `(lambda ()
1902                        (save-excursion
1903                          (message-goto-body)
1904                          (insert ,(cdr result)))))
1905                    ((eq 'signature (car result))
1906                     (set (make-local-variable 'message-signature) nil)
1907                     (set (make-local-variable 'message-signature-file) nil)
1908                     (if (not (cdr result))
1909                         'ignore
1910                       `(lambda ()
1911                          (save-excursion
1912                            (let ((message-signature ,(cdr result)))
1913                              (when message-signature
1914                                (message-insert-signature)))))))
1915                    (t
1916                     (let ((header
1917                            (if (symbolp (car result))
1918                                (capitalize (symbol-name (car result)))
1919                              (car result))))
1920                       `(lambda ()
1921                          (save-excursion
1922                            (message-remove-header ,header)
1923                            (let ((value ,(cdr result)))
1924                              (when value
1925                                (message-goto-eoh)
1926                                (insert ,header ": " value)
1927                                (unless (bolp)
1928                                  (insert "\n")))))))))
1929                   nil 'local))
1930       (when (or name address)
1931         (add-hook 'message-setup-hook
1932                   `(lambda ()
1933                      (set (make-local-variable 'user-mail-address)
1934                           ,(or (cdr address) user-mail-address))
1935                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1936                            (user-mail-address
1937                             ,(or (cdr address) user-mail-address)))
1938                        (save-excursion
1939                          (message-remove-header "From")
1940                          (message-goto-eoh)
1941                          (insert "From: " (message-make-from) "\n"))))
1942                   nil 'local)))))
1943
1944 ;;; Allow redefinition of functions.
1945
1946 (gnus-ems-redefine)
1947
1948 (provide 'gnus-msg)
1949
1950 ;;; arch-tag: 9f22b2f5-1c0a-49de-916e-4c88e984852b
1951 ;;; gnus-msg.el ends here