lisp/emacs-lisp/debug.el

   1 ;;; debug.el --- debuggers and related commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, tools, maint
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a major mode documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (defgroup debugger nil
  32   "Debuggers and related commands for Emacs."
  33   :prefix "debugger-"
  34   :group 'debug)
  35
  36 (defcustom debugger-mode-hook nil
  37   "*Hooks run when `debugger-mode' is turned on."
  38   :type 'hook
  39   :group 'debugger
  40   :version "20.3")
  41
  42 (defcustom debugger-batch-max-lines 40
  43   "*Maximum lines to show in debugger buffer in a noninteractive Emacs.
  44 When the debugger is entered and Emacs is running in batch mode,
  45 if the backtrace text has more than this many lines,
  46 the middle is discarded, and just the beginning and end are displayed."
  47   :type 'integer
  48   :group 'debugger
  49   :version "21.1")
  50
  51 (defcustom debug-function-list nil
  52   "List of functions currently set for debug on entry."
  53   :type '(repeat function)
  54   :group 'debugger)
  55
  56 (defcustom debugger-step-after-exit nil
  57   "Non-nil means \"single-step\" after the debugger exits."
  58   :type 'boolean
  59   :group 'debugger)
  60
  61 (defvar debugger-value nil
  62   "This is the value for the debugger to return, when it returns.")
  63
  64 (defvar debugger-old-buffer nil
  65   "This is the buffer that was current when the debugger was entered.")
  66
  67 (defvar debugger-outer-match-data)
  68 (defvar debugger-outer-load-read-function)
  69 (defvar debugger-outer-overriding-local-map)
  70 (defvar debugger-outer-overriding-terminal-local-map)
  71 (defvar debugger-outer-track-mouse)
  72 (defvar debugger-outer-last-command)
  73 (defvar debugger-outer-this-command)
  74 (defvar debugger-outer-unread-command-char)
  75 (defvar debugger-outer-unread-command-events)
  76 (defvar debugger-outer-unread-post-input-method-events)
  77 (defvar debugger-outer-last-input-event)
  78 (defvar debugger-outer-last-command-event)
  79 (defvar debugger-outer-last-nonmenu-event)
  80 (defvar debugger-outer-last-event-frame)
  81 (defvar debugger-outer-standard-input)
  82 (defvar debugger-outer-standard-output)
  83 (defvar debugger-outer-inhibit-redisplay)
  84 (defvar debugger-outer-cursor-in-echo-area)
  85
  86 ;;;###autoload
  87 (setq debugger 'debug)
  88 ;;;###autoload
  89 (defun debug (&rest debugger-args)
  90   "Enter debugger.  To return, type \\<debugger-mode-map>`\\[debugger-continue]'.
  91 Arguments are mainly for use when this is called from the internals
  92 of the evaluator.
  93
  94 You may call with no args, or you may pass nil as the first arg and
  95 any other args you like.  In that case, the list of args after the
  96 first will be printed into the backtrace buffer."
  97   (interactive)
  98   (unless noninteractive
  99     (message "Entering debugger..."))
 100   (let (debugger-value
 101         (debug-on-error nil)
 102         (debug-on-quit nil)
 103         (debugger-buffer (let ((default-major-mode 'fundamental-mode))
 104                            (get-buffer-create "*Backtrace*")))
 105         (debugger-old-buffer (current-buffer))
 106         (debugger-step-after-exit nil)
 107         ;; Don't keep reading from an executing kbd macro!
 108         (executing-kbd-macro nil)
 109         ;; Save the outer values of these vars for the `e' command
 110         ;; before we replace the values.
 111         (debugger-outer-match-data (match-data))
 112         (debugger-outer-load-read-function load-read-function)
 113         (debugger-outer-overriding-local-map overriding-local-map)
 114         (debugger-outer-overriding-terminal-local-map
 115          overriding-terminal-local-map)
 116         (debugger-outer-track-mouse track-mouse)
 117         (debugger-outer-last-command last-command)
 118         (debugger-outer-this-command this-command)
 119         (debugger-outer-unread-command-char unread-command-char)
 120         (debugger-outer-unread-command-events unread-command-events)
 121         (debugger-outer-unread-post-input-method-events
 122          unread-post-input-method-events)
 123         (debugger-outer-last-input-event last-input-event)
 124         (debugger-outer-last-command-event last-command-event)
 125         (debugger-outer-last-nonmenu-event last-nonmenu-event)
 126         (debugger-outer-last-event-frame last-event-frame)
 127         (debugger-outer-standard-input standard-input)
 128         (debugger-outer-standard-output standard-output)
 129         (debugger-outer-inhibit-redisplay inhibit-redisplay)
 130         (debugger-outer-cursor-in-echo-area cursor-in-echo-area))
 131     ;; Set this instead of binding it, so that `q'
 132     ;; will not restore it.
 133     (setq overriding-terminal-local-map nil)
 134     ;; Don't let these magic variables affect the debugger itself.
 135     (let ((last-command nil) this-command track-mouse
 136           (unread-command-char -1) unread-command-events
 137           unread-post-input-method-events
 138           last-input-event last-command-event last-nonmenu-event
 139           last-event-frame
 140           overriding-local-map
 141           load-read-function
 142           ;; If we are inside a minibuffer, allow nesting
 143           ;; so that we don't get an error from the `e' command.
 144           (enable-recursive-minibuffers
 145            (or enable-recursive-minibuffers (> (minibuffer-depth) 0)))
 146           (standard-input t) (standard-output t)
 147           inhibit-redisplay
 148           (cursor-in-echo-area nil))
 149       (unwind-protect
 150           (save-excursion
 151             (save-window-excursion
 152               (pop-to-buffer debugger-buffer)
 153               (debugger-mode)
 154               (debugger-setup-buffer debugger-args)
 155               (when noninteractive
 156                 ;; If the backtrace is long, save the beginning
 157                 ;; and the end, but discard the middle.
 158                 (when (> (count-lines (point-min) (point-max))
 159                          debugger-batch-max-lines)
 160                   (goto-char (point-min))
 161                   (forward-line (/ 2 debugger-batch-max-lines))
 162                   (let ((middlestart (point)))
 163                     (goto-char (point-max))
 164                     (forward-line (- (/ 2 debugger-batch-max-lines)
 165                                      debugger-batch-max-lines))
 166                     (delete-region middlestart (point)))
 167                   (insert "...\n"))
 168                 (goto-char (point-min))
 169                 (message (buffer-string))
 170                 (kill-emacs))
 171               (if (eq (car debugger-args) 'debug)
 172                   ;; Skip the frames for backtrace-debug, byte-code, and debug.
 173                   (backtrace-debug 3 t))
 174               (debugger-reenable)
 175               (message "")
 176               (let ((inhibit-trace t)
 177                     (standard-output nil)
 178                     (buffer-read-only t))
 179                 (message "")
 180                 ;; Make sure we unbind buffer-read-only in the right buffer.
 181                 (save-excursion
 182                   (recursive-edit)))))
 183         ;; Kill or at least neuter the backtrace buffer, so that users
 184         ;; don't try to execute debugger commands in an invalid context.
 185         (if (get-buffer-window debugger-buffer 'visible)
 186             ;; Still visible despite the save-window-excursion?  Maybe it
 187             ;; it's in a pop-up frame.  It would be annoying to delete and
 188             ;; recreate it every time the debugger stops, so instead we'll
 189             ;; erase it but leave it visible.
 190             (save-excursion
 191               (set-buffer debugger-buffer)
 192               (erase-buffer)
 193               (fundamental-mode))
 194           (kill-buffer debugger-buffer))
 195         (set-match-data debugger-outer-match-data)))
 196     ;; Put into effect the modified values of these variables
 197     ;; in case the user set them with the `e' command.
 198     (setq load-read-function debugger-outer-load-read-function)
 199     (setq overriding-local-map debugger-outer-overriding-local-map)
 200     (setq overriding-terminal-local-map
 201           debugger-outer-overriding-terminal-local-map)
 202     (setq track-mouse debugger-outer-track-mouse)
 203     (setq last-command debugger-outer-last-command)
 204     (setq this-command debugger-outer-this-command)
 205     (setq unread-command-char debugger-outer-unread-command-char)
 206     (setq unread-command-events debugger-outer-unread-command-events)
 207     (setq unread-post-input-method-events
 208           debugger-outer-unread-post-input-method-events)
 209     (setq last-input-event debugger-outer-last-input-event)
 210     (setq last-command-event debugger-outer-last-command-event)
 211     (setq last-nonmenu-event debugger-outer-last-nonmenu-event)
 212     (setq last-event-frame debugger-outer-last-event-frame)
 213     (setq standard-input debugger-outer-standard-input)
 214     (setq standard-output debugger-outer-standard-output)
 215     (setq inhibit-redisplay debugger-outer-inhibit-redisplay)
 216     (setq cursor-in-echo-area debugger-outer-cursor-in-echo-area)
 217     (setq debug-on-next-call debugger-step-after-exit)
 218     debugger-value))
 219 \f
 220 (defun debugger-setup-buffer (debugger-args)
 221   "Initialize the `*Backtrace*' buffer for entry to the debugger.
 222 That buffer should be current already."
 223   (setq buffer-read-only nil)
 224   (erase-buffer)
 225   (set-buffer-multibyte nil)
 226   (let ((standard-output (current-buffer))
 227         (print-escape-newlines t)
 228         (print-level 8)
 229         (print-length 50))
 230     (backtrace))
 231   (goto-char (point-min))
 232   (delete-region (point)
 233                  (progn
 234                    (search-forward "\n  debug(")
 235                    (forward-line 1)
 236                    (point)))
 237   (insert "Debugger entered")
 238   ;; lambda is for debug-on-call when a function call is next.
 239   ;; debug is for debug-on-entry function called.
 240   (cond ((memq (car debugger-args) '(lambda debug))
 241          (insert "--entering a function:\n")
 242          (if (eq (car debugger-args) 'debug)
 243              (progn
 244                (delete-char 1)
 245                (insert ?*)
 246                (beginning-of-line))))
 247         ;; Exiting a function.
 248         ((eq (car debugger-args) 'exit)
 249          (insert "--returning value: ")
 250          (setq debugger-value (nth 1 debugger-args))
 251          (prin1 debugger-value (current-buffer))
 252          (insert ?\n)
 253          (delete-char 1)
 254          (insert ? )
 255          (beginning-of-line))
 256         ;; Debugger entered for an error.
 257         ((eq (car debugger-args) 'error)
 258          (insert "--Lisp error: ")
 259          (prin1 (nth 1 debugger-args) (current-buffer))
 260          (insert ?\n))
 261         ;; debug-on-call, when the next thing is an eval.
 262         ((eq (car debugger-args) t)
 263          (insert "--beginning evaluation of function call form:\n"))
 264         ;; User calls debug directly.
 265         (t
 266          (insert ": ")
 267          (prin1 (if (eq (car debugger-args) 'nil)
 268                     (cdr debugger-args) debugger-args)
 269                 (current-buffer))
 270          (insert ?\n)))
 271   (debugger-make-xrefs))
 272
 273 (defun debugger-make-xrefs (&optional buffer)
 274   "Create cross-references in the debugger buffer."
 275   (interactive "b")
 276   (save-excursion
 277     (set-buffer (or buffer (current-buffer)))
 278     (goto-char (point-min))
 279     (let ((buffer-read-only nil))
 280       (while (re-search-forward "\\(\\(\\sw\\|\\s_\\)+\\)" nil t)
 281         (let* ((sym (intern-soft (match-string 1)))
 282                (file (symbol-file sym)))
 283           (when file (help-xref-button 1 'help-function-def sym file)))))))
 284 \f
 285 (defun debugger-step-through ()
 286   "Proceed, stepping through subexpressions of this expression.
 287 Enter another debugger on next entry to eval, apply or funcall."
 288   (interactive)
 289   (setq debugger-step-after-exit t)
 290   (message "Proceeding, will debug on next eval or call.")
 291   (exit-recursive-edit))
 292
 293 (defun debugger-continue ()
 294   "Continue, evaluating this expression without stopping."
 295   (interactive)
 296   (unless debugger-may-continue
 297     (error "Cannot continue"))
 298   (message "Continuing.")
 299   (exit-recursive-edit))
 300
 301 (defun debugger-return-value (val)
 302   "Continue, specifying value to return.
 303 This is only useful when the value returned from the debugger
 304 will be used, such as in a debug on exit from a frame."
 305   (interactive "XReturn value (evaluated): ")
 306   (setq debugger-value val)
 307   (princ "Returning " t)
 308   (prin1 debugger-value)
 309   (exit-recursive-edit))
 310
 311 ;; Chosen empirically to account for all the frames
 312 ;; that will exist when debugger-frame is called
 313 ;; within the first one that appears in the backtrace buffer.
 314 ;; Assumes debugger-frame is called from a key;
 315 ;; will be wrong if it is called with Meta-x.
 316 (defconst debugger-frame-offset 8 "")
 317
 318 (defun debugger-jump ()
 319   "Continue to exit from this frame, with all debug-on-entry suspended."
 320   (interactive)
 321   ;; Compensate for the two extra stack frames for debugger-jump.
 322   (let ((debugger-frame-offset (+ debugger-frame-offset 2)))
 323     (debugger-frame))
 324   ;; Turn off all debug-on-entry functions
 325   ;; but leave them in the list.
 326   (let ((list debug-function-list))
 327     (while list
 328       (fset (car list)
 329             (debug-on-entry-1 (car list) (symbol-function (car list)) nil))
 330       (setq list (cdr list))))
 331   (message "Continuing through this frame")
 332   (exit-recursive-edit))
 333
 334 (defun debugger-reenable ()
 335   "Turn all debug-on-entry functions back on."
 336   (let ((list debug-function-list))
 337     (while list
 338       (or (consp (symbol-function (car list)))
 339           (debug-convert-byte-code (car list)))
 340       (fset (car list)
 341             (debug-on-entry-1 (car list) (symbol-function (car list)) t))
 342       (setq list (cdr list)))))
 343
 344 (defun debugger-frame-number ()
 345   "Return number of frames in backtrace before the one point points at."
 346   (save-excursion
 347     (beginning-of-line)
 348     (let ((opoint (point))
 349           (count 0))
 350       (goto-char (point-min))
 351       (if (or (equal (buffer-substring (point) (+ (point) 6))
 352                      "Signal")
 353               (equal (buffer-substring (point) (+ (point) 6))
 354                      "Return"))
 355           (progn
 356             (search-forward ":")
 357             (forward-sexp 1)))
 358       (forward-line 1)
 359       (while (progn
 360                (forward-char 2)
 361                (if (= (following-char) ?\()
 362                    (forward-sexp 1)
 363                  (forward-sexp 2))
 364                (forward-line 1)
 365                (<= (point) opoint))
 366         (setq count (1+ count)))
 367       count)))
 368
 369 (defun debugger-frame ()
 370   "Request entry to debugger when this frame exits.
 371 Applies to the frame whose line point is on in the backtrace."
 372   (interactive)
 373   (beginning-of-line)
 374   (let ((level (debugger-frame-number)))
 375     (backtrace-debug (+ level debugger-frame-offset) t))
 376   (if (= (following-char) ? )
 377       (let ((buffer-read-only nil))
 378         (delete-char 1)
 379         (insert ?*)))
 380   (beginning-of-line))
 381
 382 (defun debugger-frame-clear ()
 383   "Do not enter debugger when this frame exits.
 384 Applies to the frame whose line point is on in the backtrace."
 385   (interactive)
 386   (beginning-of-line)
 387   (let ((level (debugger-frame-number)))
 388     (backtrace-debug (+ level debugger-frame-offset) nil))
 389   (if (= (following-char) ?*)
 390       (let ((buffer-read-only nil))
 391         (delete-char 1)
 392         (insert ? )))
 393   (beginning-of-line))
 394
 395
 396
 397 (put 'debugger-env-macro 'lisp-indent-function 0)
 398 (defmacro debugger-env-macro (&rest body)
 399   "Run BODY in original environment."
 400   `(save-excursion
 401     (if (null (buffer-name debugger-old-buffer))
 402         ;; old buffer deleted
 403         (setq debugger-old-buffer (current-buffer)))
 404     (set-buffer debugger-old-buffer)
 405     (let ((load-read-function debugger-outer-load-read-function)
 406           (overriding-terminal-local-map
 407            debugger-outer-overriding-terminal-local-map)
 408           (overriding-local-map debugger-outer-overriding-local-map)
 409           (track-mouse debugger-outer-track-mouse)
 410           (last-command debugger-outer-last-command)
 411           (this-command debugger-outer-this-command)
 412           (unread-command-char debugger-outer-unread-command-char)
 413           (unread-command-events debugger-outer-unread-command-events)
 414           (unread-post-input-method-events
 415            debugger-outer-unread-post-input-method-events)
 416           (last-input-event debugger-outer-last-input-event)
 417           (last-command-event debugger-outer-last-command-event)
 418           (last-nonmenu-event debugger-outer-last-nonmenu-event)
 419           (last-event-frame debugger-outer-last-event-frame)
 420           (standard-input debugger-outer-standard-input)
 421           (standard-output debugger-outer-standard-output)
 422           (inhibit-redisplay debugger-outer-inhibit-redisplay)
 423           (cursor-in-echo-area debugger-outer-cursor-in-echo-area))
 424       (set-match-data debugger-outer-match-data)
 425       (prog1 (progn ,@body)
 426         (setq debugger-outer-match-data (match-data))
 427         (setq debugger-outer-load-read-function load-read-function)
 428         (setq debugger-outer-overriding-terminal-local-map
 429               overriding-terminal-local-map)
 430         (setq debugger-outer-overriding-local-map overriding-local-map)
 431         (setq debugger-outer-track-mouse track-mouse)
 432         (setq debugger-outer-last-command last-command)
 433         (setq debugger-outer-this-command this-command)
 434         (setq debugger-outer-unread-command-char unread-command-char)
 435         (setq debugger-outer-unread-command-events unread-command-events)
 436         (setq debugger-outer-unread-post-input-method-events
 437               unread-post-input-method-events)
 438         (setq debugger-outer-last-input-event last-input-event)
 439         (setq debugger-outer-last-command-event last-command-event)
 440         (setq debugger-outer-last-nonmenu-event last-nonmenu-event)
 441         (setq debugger-outer-last-event-frame last-event-frame)
 442         (setq debugger-outer-standard-input standard-input)
 443         (setq debugger-outer-standard-output standard-output)
 444         (setq debugger-outer-inhibit-redisplay inhibit-redisplay)
 445         (setq debugger-outer-cursor-in-echo-area cursor-in-echo-area)
 446         ))))
 447
 448 (defun debugger-eval-expression (exp)
 449   "Eval an expression, in an environment like that outside the debugger."
 450   (interactive
 451    (list (read-from-minibuffer "Eval: "
 452                                nil read-expression-map t
 453                                'read-expression-history)))
 454   (debugger-env-macro (eval-expression exp)))
 455 \f
 456 (defvar debugger-mode-map nil)
 457 (unless debugger-mode-map
 458   (let ((loop ? ))
 459     (setq debugger-mode-map (make-keymap))
 460     (suppress-keymap debugger-mode-map)
 461     (define-key debugger-mode-map "-" 'negative-argument)
 462     (define-key debugger-mode-map "b" 'debugger-frame)
 463     (define-key debugger-mode-map "c" 'debugger-continue)
 464     (define-key debugger-mode-map "j" 'debugger-jump)
 465     (define-key debugger-mode-map "r" 'debugger-return-value)
 466     (define-key debugger-mode-map "u" 'debugger-frame-clear)
 467     (define-key debugger-mode-map "d" 'debugger-step-through)
 468     (define-key debugger-mode-map "l" 'debugger-list-functions)
 469     (define-key debugger-mode-map "h" 'describe-mode)
 470     (define-key debugger-mode-map "q" 'top-level)
 471     (define-key debugger-mode-map "e" 'debugger-eval-expression)
 472     (define-key debugger-mode-map " " 'next-line)
 473     (define-key debugger-mode-map "R" 'debugger-record-expression)
 474     (define-key debugger-mode-map [RET] 'help-follow)
 475     (define-key debugger-mode-map [mouse-2] 'push-button)
 476     ))
 477
 478
 479 (defcustom debugger-record-buffer "*Debugger-record*"
 480   "*Buffer name for expression values, for \\[debugger-record-expression]."
 481   :type 'string
 482   :group 'debugger
 483   :version "20.3")
 484
 485 (defun debugger-record-expression  (exp)
 486   "Display a variable's value and record it in `*Backtrace-record*' buffer."
 487   (interactive
 488    (list (read-from-minibuffer
 489           "Record Eval: "
 490           nil
 491           read-expression-map t
 492           'read-expression-history)))
 493   (let* ((buffer (get-buffer-create debugger-record-buffer))
 494          (standard-output buffer))
 495     (princ (format "Debugger Eval (%s): " exp))
 496     (princ (debugger-eval-expression exp))
 497     (terpri))
 498
 499   (with-current-buffer (get-buffer debugger-record-buffer)
 500     (save-excursion
 501       (forward-line -1)
 502       (message
 503        (buffer-substring (point) (progn (end-of-line) (point)))))))
 504
 505 (put 'debugger-mode 'mode-class 'special)
 506
 507 (defun debugger-mode ()
 508   "Mode for backtrace buffers, selected in debugger.
 509 \\<debugger-mode-map>
 510 A line starts with `*' if exiting that frame will call the debugger.
 511 Type \\[debugger-frame] or \\[debugger-frame-clear] to set or remove the `*'.
 512
 513 When in debugger due to frame being exited,
 514 use the \\[debugger-return-value] command to override the value
 515 being returned from that frame.
 516
 517 Use \\[debug-on-entry] and \\[cancel-debug-on-entry] to control
 518 which functions will enter the debugger when called.
 519
 520 Complete list of commands:
 521 \\{debugger-mode-map}"
 522   (kill-all-local-variables)
 523   (setq major-mode 'debugger-mode)
 524   (setq mode-name "Debugger")
 525   (setq truncate-lines t)
 526   (set-syntax-table emacs-lisp-mode-syntax-table)
 527   (use-local-map debugger-mode-map)
 528   (run-hooks 'debugger-mode-hook))
 529 \f
 530 ;;;###autoload
 531 (defun debug-on-entry (function)
 532   "Request FUNCTION to invoke debugger each time it is called.
 533 If you tell the debugger to continue, FUNCTION's execution proceeds.
 534 This works by modifying the definition of FUNCTION,
 535 which must be written in Lisp, not predefined.
 536 Use \\[cancel-debug-on-entry] to cancel the effect of this command.
 537 Redefining FUNCTION also cancels it."
 538   (interactive "aDebug on entry (to function): ")
 539   (debugger-reenable)
 540   ;; Handle a function that has been aliased to some other function.
 541   (if (symbolp (symbol-function function))
 542       (fset function `(lambda (&rest debug-on-entry-args)
 543                         (apply ',(symbol-function function)
 544                                debug-on-entry-args))))
 545   (if (subrp (symbol-function function))
 546       (error "Function %s is a primitive" function))
 547   (or (consp (symbol-function function))
 548       (debug-convert-byte-code function))
 549   (or (consp (symbol-function function))
 550       (error "Definition of %s is not a list" function))
 551   (fset function (debug-on-entry-1 function (symbol-function function) t))
 552   (or (memq function debug-function-list)
 553       (setq debug-function-list (cons function debug-function-list)))
 554   function)
 555
 556 ;;;###autoload
 557 (defun cancel-debug-on-entry (&optional function)
 558   "Undo effect of \\[debug-on-entry] on FUNCTION.
 559 If argument is nil or an empty string, cancel for all functions."
 560   (interactive
 561    (list (let ((name
 562                 (completing-read "Cancel debug on entry (to function): "
 563                                  ;; Make an "alist" of the functions
 564                                  ;; that now have debug on entry.
 565                                  (mapcar 'list
 566                                          (mapcar 'symbol-name
 567                                                  debug-function-list))
 568                                  nil t nil)))
 569            (if name (intern name)))))
 570   (debugger-reenable)
 571   (if (and function (not (string= function "")))
 572       (progn
 573         (fset function
 574               (debug-on-entry-1 function (symbol-function function) nil))
 575         (setq debug-function-list (delq function debug-function-list))
 576         function)
 577     (message "Cancelling debug-on-entry for all functions")
 578     (mapcar 'cancel-debug-on-entry debug-function-list)))
 579
 580 (defun debug-convert-byte-code (function)
 581   (let ((defn (symbol-function function)))
 582     (if (not (consp defn))
 583         ;; Assume a compiled code object.
 584         (let* ((contents (append defn nil))
 585                (body
 586                 (list (list 'byte-code (nth 1 contents)
 587                             (nth 2 contents) (nth 3 contents)))))
 588           (if (nthcdr 5 contents)
 589               (setq body (cons (list 'interactive (nth 5 contents)) body)))
 590           (if (nth 4 contents)
 591               ;; Use `documentation' here, to get the actual string,
 592               ;; in case the compiled function has a reference
 593               ;; to the .elc file.
 594               (setq body (cons (documentation function) body)))
 595           (fset function (cons 'lambda (cons (car contents) body)))))))
 596
 597 (defun debug-on-entry-1 (function defn flag)
 598   (if (subrp defn)
 599       (error "%s is a built-in function" function)
 600     (if (eq (car defn) 'macro)
 601         (debug-on-entry-1 function (cdr defn) flag)
 602       (or (eq (car defn) 'lambda)
 603           (error "%s not user-defined Lisp function" function))
 604       (let (tail prec)
 605         (if (stringp (car (nthcdr 2 defn)))
 606             (setq tail (nthcdr 3 defn)
 607                   prec (list (car defn) (car (cdr defn))
 608                              (car (cdr (cdr defn)))))
 609           (setq tail (nthcdr 2 defn)
 610                 prec (list (car defn) (car (cdr defn)))))
 611         (if (eq flag (equal (car tail) '(debug 'debug)))
 612             defn
 613           (if flag
 614               (nconc prec (cons '(debug 'debug) tail))
 615             (nconc prec (cdr tail))))))))
 616
 617 (defun debugger-list-functions ()
 618   "Display a list of all the functions now set to debug on entry."
 619   (interactive)
 620   (with-output-to-temp-buffer "*Help*"
 621     (if (null debug-function-list)
 622         (princ "No debug-on-entry functions now\n")
 623       (princ "Functions set to debug on entry:\n\n")
 624       (let ((list debug-function-list))
 625         (while list
 626           (prin1 (car list))
 627           (terpri)
 628           (setq list (cdr list))))
 629       (princ "Note: if you have redefined a function, then it may no longer\n")
 630       (princ "be set to debug on entry, even if it is in the list."))
 631     (save-excursion
 632       (set-buffer standard-output)
 633       (help-mode))))
 634
 635 (provide 'debug)
 636
 637 ;;; debug.el ends here