lisp/savehist.el

   1 ;;; savehist.el --- Save minibuffer history.
   2
   3 ;; Copyright (C) 1997,2005 Free Software Foundation
   4
   5 ;; Author: Hrvoje Niksic <hniksic@xemacs.org>
   6 ;; Keywords: minibuffer
   7 ;; Version: 23
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Many editors (e.g. Vim) have the feature of saving minibuffer
  29 ;; history to an external file after exit.  This package provides the
  30 ;; same feature in Emacs.  When set up, it saves recorded minibuffer
  31 ;; histories to a file (`~/.emacs-history' by default).  Additional
  32 ;; variables may be specified by customizing
  33 ;; `savehist-additional-variables'.
  34
  35 ;; To use savehist, turn on savehist-mode by putting the following in
  36 ;; `~/.emacs':
  37 ;;
  38 ;;     (savehist-mode 1)
  39 ;;
  40 ;; or with customize: `M-x customize-option RET savehist-mode RET'.
  41 ;;
  42 ;; You can also explicitly save history with `M-x savehist-save' and
  43 ;; load it by loading the `savehist-file' with `M-x load-file'.
  44
  45 ;; If you are using a version of Emacs that does not ship with this
  46 ;; package, be sure to have `savehist.el' in a directory that is in
  47 ;; your load-path, and to byte-compile it.
  48
  49 ;;; Code:
  50
  51 (require 'custom)
  52 (eval-when-compile
  53   (require 'cl))
  54
  55 ;; User variables
  56
  57 (defgroup savehist nil
  58   "Save minibuffer history."
  59   :group 'minibuffer)
  60
  61 ;;;###autoload
  62 (defcustom savehist-mode nil
  63   "Mode for automatic saving of minibuffer history.
  64 Set this by calling the `savehist-mode' function or using the customize
  65 interface."
  66   :type 'boolean
  67   :set (lambda (symbol value) (savehist-mode (or value 0)))
  68   :initialize 'custom-initialize-default
  69   :require 'savehist
  70   :group 'savehist)
  71
  72 (defcustom savehist-save-minibuffer-history t
  73   "*If non-nil, save all recorded minibuffer histories.
  74 If you want to save only specific histories, use `savehist-save-hook' to
  75 modify the value of `savehist-minibuffer-history-variables'."
  76   :type 'boolean
  77   :group 'savehist)
  78
  79 (defcustom savehist-additional-variables ()
  80   "*List of additional variables to save.
  81 Each element is a symbol whose value will be persisted across Emacs
  82 sessions that use savehist.  The contents of variables should be
  83 printable with the Lisp printer.  You don't need to add minibuffer
  84 history variables to this list, all minibuffer histories will be
  85 saved automatically as long as `savehist-save-minibuffer-history' is
  86 non-nil.
  87
  88 User options should be saved with the customize interface.  This
  89 list is useful for saving automatically updated variables that are not
  90 minibuffer histories, such as `compile-command' or `kill-ring'."
  91   :type '(repeat variable)
  92   :group 'savehist)
  93
  94 (defcustom savehist-file
  95   (cond
  96    ;; Backward compatibility with previous versions of savehist.
  97    ((file-exists-p "~/.emacs-history") "~/.emacs-history")
  98    ((and (not (featurep 'xemacs)) (file-directory-p "~/.emacs.d/"))
  99     "~/.emacs.d/history")
 100    ((and (featurep 'xemacs) (file-directory-p "~/.xemacs/"))
 101     "~/.xemacs/history")
 102    ;; For users without `~/.emacs.d/' or `~/.xemacs/'.
 103    (t "~/.emacs-history"))
 104   "*File name where minibuffer history is saved to and loaded from.
 105 The minibuffer history is a series of Lisp expressions loaded
 106 automatically when `savehist-mode' is turned on.  See `savehist-mode'
 107 for more details.
 108
 109 If you want your minibuffer history shared between Emacs and XEmacs,
 110 customize this value and make sure that `savehist-coding-system' is
 111 set to a coding system that exists in both emacsen."
 112   :type 'file
 113   :group 'savehist)
 114
 115 (defcustom savehist-file-modes #o600
 116   "*Default permissions of the history file.
 117 This is decimal, not octal.  The default is 384 (0600 in octal).
 118 Set to nil to use the default permissions that Emacs uses, typically
 119 mandated by umask.  The default is a bit more restrictive to protect
 120 the user's privacy."
 121   :type 'integer
 122   :group 'savehist)
 123
 124 (defcustom savehist-autosave-interval (* 5 60)
 125   "*The interval between autosaves of minibuffer history.
 126 If set to nil, disables timer-based autosaving."
 127   :type 'integer
 128   :group 'savehist)
 129
 130 (defcustom savehist-save-hook nil
 131   "Hook called by `savehist-save' before saving the variables.
 132 You can use this hook to influence choice and content of variables to
 133 save."
 134   :type 'hook)
 135
 136 ;; This should be capable of representing characters used by Emacs.
 137 ;; We prefer UTF-8 over ISO 2022 because it is well-known outside
 138 ;; Mule.  XEmacs prir to 21.5 had UTF-8 provided by an external
 139 ;; package which may not be loaded, which is why we check for version.
 140 (defvar savehist-coding-system (if (and (featurep 'xemacs)
 141                                         (<= emacs-major-version 21)
 142                                         (< emacs-minor-version 5))
 143                                    'iso-2022-8 'utf-8)
 144   "The coding system savehist uses for saving the minibuffer history.
 145 Changing this value while Emacs is running is supported, but considered
 146 unwise, unless you know what you are doing.")
 147
 148 ;; Internal variables.
 149
 150 (defvar savehist-timer nil)
 151
 152 (defvar savehist-last-checksum nil)
 153
 154 (defvar savehist-minibuffer-history-variables nil
 155   "List of minibuffer histories.
 156 The contents of this variable is built while Emacs is running, and saved
 157 along with minibuffer history.  You can change its value off
 158 `savehist-save-hook' to influence which variables are saved.")
 159
 160 ;; Coding system without any conversion, used for calculating an
 161 ;; internal checksum.  Should be as fast as possible, ideally simply
 162 ;; exposing the internal representation of buffer text.
 163 (defconst savehist-no-conversion (if (featurep 'xemacs) 'binary 'no-conversion))
 164
 165 ;; Whether the history has already been loaded.  This prevents
 166 ;; toggling savehist-mode from destroying existing minibuffer history.
 167 (defvar savehist-loaded nil)
 168
 169 (when (featurep 'xemacs)
 170   ;; Must declare this under XEmacs, which doesn't have built-in
 171   ;; minibuffer history truncation.
 172   (defvar history-length 100))
 173 \f
 174 ;; Functions.
 175
 176 ;;;###autoload
 177 (defun savehist-mode (arg)
 178   "Toggle savehist-mode.
 179 Positive ARG turns on `savehist-mode'.  When on, savehist-mode causes
 180 minibuffer history to be saved periodically and when exiting Emacs.
 181 When turned on for the first time in an Emacs session, it causes the
 182 previous minibuffer history to be loaded from `savehist-file'.
 183
 184 This mode should normally be turned on from your Emacs init file.
 185 Calling it at any other time replaces your current minibuffer histories,
 186 which is probably undesirable."
 187   (interactive "P")
 188   (setq savehist-mode
 189         (if (null arg)
 190             (not savehist-mode)
 191           (> (prefix-numeric-value arg) 0)))
 192   (if (not savehist-mode)
 193       (savehist-uninstall)
 194     (when (and (not savehist-loaded)
 195                (file-exists-p savehist-file))
 196       (condition-case errvar
 197           (progn
 198             ;; Don't set coding-system-for-read -- we rely on the
 199             ;; coding cookie to convey that information.  That way, if
 200             ;; the user changes the value of savehist-coding-system,
 201             ;; we can still correctly load the old file.
 202             (load savehist-file nil (not (interactive-p)))
 203             (setq savehist-loaded t))
 204         (error
 205          ;; Don't install the mode if reading failed.  Doing so would
 206          ;; effectively destroy the user's data at the next save.
 207          (setq savehist-mode nil)
 208          (savehist-uninstall)
 209          (signal (car errvar) (cdr errvar)))))
 210     (savehist-install))
 211   ;; Return the new setting.
 212   savehist-mode)
 213 (add-minor-mode 'savehist-mode "")
 214
 215 (defun savehist-load ()
 216   "Obsolete function provided for transition from old versions of savehist.
 217 Don't call this from new code, use (savehist-mode 1) instead.
 218
 219 This function loads the variables stored in `savehist-file' and turns on
 220 savehist-mode.  If savehist-file is in the old format that doesn't record
 221 the value of `savehist-minibuffer-history-variables', that value is
 222 deducted from the contents of the file."
 223   (savehist-mode 1)
 224   ;; Old versions of savehist distributed with XEmacs didn't save
 225   ;; savehist-minibuffer-history-variables.  If that variable is nil
 226   ;; after loading the file, try to intuit the intended value.
 227   (when (null savehist-minibuffer-history-variables)
 228     (setq savehist-minibuffer-history-variables
 229           (with-temp-buffer
 230             (ignore-errors
 231               (insert-file-contents savehist-file))
 232             (let ((vars ()) form)
 233               (while (setq form (condition-case nil
 234                                     (read (current-buffer)) (error nil)))
 235                 ;; Each form read is of the form (setq VAR VALUE).
 236                 ;; Collect VAR, i.e. (nth form 1).
 237                 (push (nth 1 form) vars))
 238               vars)))))
 239 (make-obsolete 'savehist-load 'savehist-mode)
 240
 241 (defun savehist-install ()
 242   "Hook savehist into Emacs.
 243 Normally invoked by calling `savehist-mode' to set the minor mode.
 244 Installs `savehist-autosave' in `kill-emacs-hook' and on a timer.   To
 245 undo this, call `savehist-uninstall'."
 246   (add-hook 'minibuffer-setup-hook 'savehist-minibuffer-hook)
 247   (add-hook 'kill-emacs-hook 'savehist-autosave)
 248   ;; Install an invocation of savehist-autosave on a timer.  This
 249   ;; should not cause noticeable delays for users -- savehist-autosave
 250   ;; executes in under 5 ms on my system.
 251   (when (and savehist-autosave-interval
 252              (null savehist-timer))
 253     (setq savehist-timer
 254           (if (featurep 'xemacs)
 255               (start-itimer
 256                "savehist" 'savehist-autosave savehist-autosave-interval
 257                savehist-autosave-interval)
 258             (run-with-timer savehist-autosave-interval
 259                             savehist-autosave-interval 'savehist-autosave)))))
 260
 261 (defun savehist-uninstall ()
 262   "Undo installing savehist.
 263 Normally invoked by calling `savehist-mode' to unset the minor mode."
 264   (remove-hook 'minibuffer-setup-hook 'savehist-minibuffer-hook)
 265   (remove-hook 'kill-emacs-hook 'savehist-autosave)
 266   (when savehist-timer
 267     (if (featurep 'xemacs)
 268         (delete-itimer savehist-timer)
 269       (cancel-timer savehist-timer))
 270     (setq savehist-timer nil)))
 271
 272 (defun savehist-save (&optional auto-save)
 273   "Save the values of minibuffer history variables.
 274 Unbound symbols referenced in `savehist-additional-variables' are ignored.
 275 If AUTO-SAVE is non-nil, compare the saved contents to the one last saved,
 276  and don't save the buffer if they are the same."
 277   (interactive)
 278   (with-temp-buffer
 279     (insert
 280      (format ";; -*- mode: emacs-lisp; coding: %s -*-\n" savehist-coding-system)
 281      ";; Minibuffer history file, automatically generated by `savehist'.\n\n")
 282     (run-hooks 'savehist-save-hook)
 283     (let ((print-length nil)
 284           (print-string-length nil)
 285           (print-level nil)
 286           (print-readably t)
 287           (print-quoted t))
 288       ;; Save the minibuffer histories, along with the value of
 289       ;; savehist-minibuffer-history-variables itself.
 290       (when savehist-save-minibuffer-history
 291         (prin1 `(setq savehist-minibuffer-history-variables
 292                       ',savehist-minibuffer-history-variables)
 293                (current-buffer))
 294         (insert ?\n)
 295         (dolist (symbol savehist-minibuffer-history-variables)
 296           (when (boundp symbol)
 297             (let ((value (savehist-trim-history (symbol-value symbol))))
 298               (when value               ; don't save empty histories
 299                 (prin1 `(setq ,symbol ',value) (current-buffer))
 300                 (insert ?\n))))))
 301       ;; Save the additional variables.
 302       (dolist (symbol savehist-additional-variables)
 303         (when (boundp symbol)
 304           (let ((value (symbol-value symbol)))
 305             (when (savehist-printable value)
 306               (prin1 `(setq ,symbol ',value) (current-buffer))
 307               (insert ?\n))))))
 308     ;; If autosaving, avoid writing if nothing has changed since the
 309     ;; last write.
 310     (let ((checksum (md5 (current-buffer) nil nil savehist-no-conversion)))
 311       (unless (and auto-save (equal checksum savehist-last-checksum))
 312         ;; Set file-precious-flag when saving the buffer because we
 313         ;; don't want a half-finished write ruining the entire
 314         ;; history.  Remember that this is run from a timer and from
 315         ;; kill-emacs-hook, and also that multiple Emacs instances
 316         ;; could write to this file at once.
 317         (let ((file-precious-flag t)
 318               (coding-system-for-write savehist-coding-system))
 319           (write-region (point-min) (point-max) savehist-file nil
 320                         (unless (interactive-p) 'quiet)))
 321         (when savehist-file-modes
 322           (set-file-modes savehist-file savehist-file-modes))
 323         (setq savehist-last-checksum checksum)))))
 324
 325 (defun savehist-autosave ()
 326   "Save the minibuffer history if it has been modified since the last save.
 327 Does nothing if savehist-mode is off."
 328   (when savehist-mode
 329     (savehist-save t)))
 330
 331 (defun savehist-trim-history (value)
 332   ;; Retain only the first history-length items in VALUE.  Only used
 333   ;; under XEmacs, which doesn't (yet) implement automatic trimming of
 334   ;; history lists to history-length items.
 335   (if (and (featurep 'xemacs)
 336            (natnump history-length)
 337            (> (length value) history-length))
 338       ;; Equivalent to `(subseq value 0 history-length)', but doesn't
 339       ;; need cl-extra at run-time.
 340       (loop repeat history-length collect (pop value))
 341     value))
 342
 343 (defun savehist-printable (value)
 344   "Return non-nil if VALUE is printable."
 345   (cond
 346    ;; Quick response for oft-encountered types known to be printable.
 347    ((stringp value))
 348    ((numberp value))
 349    ((symbolp value))
 350    (t
 351     ;; For others, check explicitly.
 352     (with-temp-buffer
 353       (condition-case nil
 354           (let ((print-readably t) (print-level nil))
 355           ;; Print the value into a buffer...
 356           (prin1 value (current-buffer))
 357           ;; ...and attempt to read it.
 358           (read (point-min-marker))
 359           ;; The attempt worked: the object is printable.
 360           t)
 361         ;; The attempt failed: the object is not printable.
 362         (error nil))))))
 363
 364 (defun savehist-minibuffer-hook ()
 365   ;; XEmacs sets minibuffer-history-variable to t to mean "no history
 366   ;; is being recorded".
 367   (unless (eq minibuffer-history-variable t)
 368     (add-to-list 'savehist-minibuffer-history-variables
 369                  minibuffer-history-variable)))
 370
 371 (provide 'savehist)
 372 \f
 373 ;; arch-tag: b3ce47f4-c5ad-4ebc-ad02-73aba705cf9f
 374
 375 ;;; savehist.el ends here