lisp/vc/log-view.el

   1 ;;; log-view.el --- Major mode for browsing RCS/CVS/SCCS log output
   2
   3 ;; Copyright (C) 1999-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords: rcs, sccs, cvs, log, vc, tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Major mode to browse revision log histories.
  26 ;; Currently supports the format output by:
  27 ;;  RCS, SCCS, CVS, Subversion, and DaRCS.
  28
  29 ;; Examples of log output:
  30
  31 ;;;; RCS/CVS:
  32
  33 ;; ----------------------------
  34 ;; revision 1.35        locked by: turlutut
  35 ;; date: 2005-03-22 18:48:38 +0000;  author: monnier;  state: Exp;  lines: +6 -8
  36 ;; (gnus-display-time-event-handler):
  37 ;; Check display-time-timer at runtime rather than only at load time
  38 ;; in case display-time-mode is turned off in the mean time.
  39 ;; ----------------------------
  40 ;; revision 1.34
  41 ;; date: 2005-02-09 15:50:38 +0000;  author: kfstorm;  state: Exp;  lines: +7 -7
  42 ;; branches:  1.34.2;
  43 ;; Change release version from 21.4 to 22.1 throughout.
  44 ;; Change development version from 21.3.50 to 22.0.50.
  45
  46 ;;;; SCCS:
  47
  48 ;;;; Subversion:
  49
  50 ;; ------------------------------------------------------------------------
  51 ;; r4622 | ckuethe | 2007-12-23 18:18:01 -0500 (Sun, 23 Dec 2007) | 2 lines
  52 ;;
  53 ;; uBlox AEK-4T in binary mode. Added to unstable because it breaks gpsfake
  54 ;;
  55 ;; ------------------------------------------------------------------------
  56 ;; r4621 | ckuethe | 2007-12-23 16:48:11 -0500 (Sun, 23 Dec 2007) | 3 lines
  57 ;;
  58 ;; Add a note about requiring usbfs to use the garmin gps18 (usb)
  59 ;; Mention firmware testing the AC12 with firmware BQ00 and BQ04
  60 ;;
  61 ;; ------------------------------------------------------------------------
  62 ;; r4620 | ckuethe | 2007-12-23 15:52:34 -0500 (Sun, 23 Dec 2007) | 1 line
  63 ;;
  64 ;; add link to latest hardware reference
  65 ;; ------------------------------------------------------------------------
  66 ;; r4619 | ckuethe | 2007-12-23 14:37:31 -0500 (Sun, 23 Dec 2007) | 1 line
  67 ;;
  68 ;; there is now a regression test for AC12 without raw data output
  69
  70 ;;;; Darcs:
  71
  72 ;; Changes to darcsum.el:
  73 ;;
  74 ;; Mon Nov 28 15:19:38 GMT 2005  Dave Love <fx@gnu.org>
  75 ;;   * Abstract process startup into darcsum-start-process.  Use TERM=dumb.
  76 ;;   TERM=dumb avoids escape characters, at least, for any old darcs that
  77 ;;   doesn't understand DARCS_DONT_COLOR & al.
  78 ;;
  79 ;; Thu Nov 24 15:20:45 GMT 2005  Dave Love <fx@gnu.org>
  80 ;;   * darcsum-mode-related changes.
  81 ;;   Don't call font-lock-mode (unnecessary) or use-local-map (redundant).
  82 ;;   Use mode-class 'special.  Add :group.
  83 ;;   Add trailing-whitespace option to mode hook and fix
  84 ;;   darcsum-display-changeset not to use trailing whitespace.
  85
  86 ;;;; Mercurial
  87
  88 ;; changeset:   11:8ff1a4166444
  89 ;; tag:         tip
  90 ;; user:        Eric S. Raymond <esr@thyrsus.com>
  91 ;; date:        Wed Dec 26 12:18:58 2007 -0500
  92 ;; summary:     Explain keywords.  Add markup fixes.
  93 ;;
  94 ;; changeset:   10:20abc7ab09c3
  95 ;; user:        Eric S. Raymond <esr@thyrsus.com>
  96 ;; date:        Wed Dec 26 11:37:28 2007 -0500
  97 ;; summary:     Typo fixes.
  98 ;;
  99 ;; changeset:   9:ada9f4da88aa
 100 ;; user:        Eric S. Raymond <esr@thyrsus.com>
 101 ;; date:        Wed Dec 26 11:23:00 2007 -0500
 102 ;; summary:     Add RCS example session.
 103
 104 ;;; Todo:
 105
 106 ;; - add ability to modify a log-entry (via cvs-mode-admin ;-)
 107 ;; - remove references to cvs-*
 108 ;; - make it easier to add support for new backends without changing the code.
 109
 110 ;;; Code:
 111
 112 (eval-when-compile (require 'cl))
 113 (require 'pcvs-util)
 114 (autoload 'vc-find-revision "vc")
 115 (autoload 'vc-diff-internal "vc")
 116
 117 (defvar cvs-minor-wrap-function)
 118
 119 (defgroup log-view nil
 120   "Major mode for browsing log output of RCS/CVS/SCCS."
 121   :group 'pcl-cvs
 122   :prefix "log-view-")
 123
 124 ;; Needed because log-view-mode-map inherits from widget-keymap.  (Bug#5311)
 125 (require 'wid-edit)
 126
 127 (easy-mmode-defmap log-view-mode-map
 128   '(
 129     ;; FIXME: (copy-keymap special-mode-map) instead
 130     ("z" . kill-this-buffer)
 131     ("q" . quit-window)
 132     ("g" . revert-buffer)
 133     ("\C-m" . log-view-toggle-entry-display)
 134
 135     ("m" . log-view-toggle-mark-entry)
 136     ("e" . log-view-modify-change-comment)
 137     ("d" . log-view-diff)
 138     ("=" . log-view-diff)
 139     ("D" . log-view-diff-changeset)
 140     ("a" . log-view-annotate-version)
 141     ("f" . log-view-find-revision)
 142     ("n" . log-view-msg-next)
 143     ("p" . log-view-msg-prev)
 144     ("\t" . log-view-msg-next)
 145     ([backtab] . log-view-msg-prev)
 146     ("N" . log-view-file-next)
 147     ("P" . log-view-file-prev)
 148     ("\M-n" . log-view-file-next)
 149     ("\M-p" . log-view-file-prev))
 150   "Log-View's keymap."
 151   :group 'log-view)
 152
 153 (easy-menu-define log-view-mode-menu log-view-mode-map
 154   "Log-View Display Menu"
 155   `("Log-View"
 156     ;; XXX Do we need menu entries for these?
 157     ;; ["Quit"  quit-window]
 158     ;; ["Kill This Buffer"  kill-this-buffer]
 159     ["Mark Log Entry for Diff"  set-mark-command
 160      :help ""]
 161     ["Diff Revisions"  log-view-diff
 162      :help "Get the diff between two revisions"]
 163     ["Changeset Diff"  log-view-diff-changeset
 164      :help "Get the changeset diff between two revisions"]
 165     ["Visit Version"  log-view-find-revision
 166      :help "Visit the version at point"]
 167     ["Annotate Version"  log-view-annotate-version
 168      :help "Annotate the version at point"]
 169     ["Modify Log Comment" log-view-modify-change-comment
 170      :help "Edit the change comment displayed at point"]
 171     ["Toggle Details at Point" log-view-toggle-entry-display
 172      :active log-view-expanded-log-entry-function]
 173     "-----"
 174     ["Next Log Entry"  log-view-msg-next
 175      :help "Go to the next count'th log message"]
 176     ["Previous Log Entry"  log-view-msg-prev
 177      :help "Go to the previous count'th log message"]
 178     ["Next File"  log-view-file-next
 179      :help "Go to the next count'th file"]
 180     ["Previous File"  log-view-file-prev
 181      :help "Go to the previous count'th file"]))
 182
 183 (defvar log-view-mode-hook nil
 184   "Hook run at the end of `log-view-mode'.")
 185
 186 (defvar log-view-expanded-log-entry-function nil
 187   "Function returning the detailed description of a Log View entry.
 188 It is called by the command `log-view-toggle-entry-display' with
 189 one arg, the revision tag (a string), and should return a string.
 190 If it is nil, `log-view-toggle-entry-display' does nothing.")
 191
 192 (defface log-view-file
 193   '((((class color) (background light))
 194      (:background "grey70" :weight bold))
 195     (t (:weight bold)))
 196   "Face for the file header line in `log-view-mode'."
 197   :group 'log-view)
 198 (define-obsolete-face-alias 'log-view-file-face 'log-view-file "22.1")
 199 (defvar log-view-file-face 'log-view-file)
 200
 201 (defface log-view-message
 202   '((((class color) (background light))
 203      (:background "grey85"))
 204     (t (:weight bold)))
 205   "Face for the message header line in `log-view-mode'."
 206   :group 'log-view)
 207 ;; backward-compatibility alias
 208 (define-obsolete-face-alias 'log-view-message-face 'log-view-message "22.1")
 209 (defvar log-view-message-face 'log-view-message)
 210
 211 (defvar log-view-file-re
 212   (concat "^\\(?:Working file: \\(?1:.+\\)"                ;RCS and CVS.
 213           ;; Subversion has no such thing??
 214           "\\|\\(?:SCCS/s\\.\\|Changes to \\)\\(?1:.+\\):" ;SCCS and Darcs.
 215           "\\)\n")                    ;Include the \n for font-lock reasons.
 216   "Regexp matching the text identifying the file.
 217 The match group number 1 should match the file name itself.")
 218
 219 (defvar log-view-per-file-logs t
 220   "Set if to t if the logs are shown one file at a time.")
 221
 222 (defvar log-view-message-re
 223   (concat "^\\(?:revision \\(?1:[.0-9]+\\)\\(?:\t.*\\)?" ; RCS and CVS.
 224           "\\|r\\(?1:[0-9]+\\) | .* | .*"                ; Subversion.
 225           "\\|D \\(?1:[.0-9]+\\) .*"                     ; SCCS.
 226           ;; Darcs doesn't have revision names.  VC-darcs uses patch names
 227           ;; instead.  Darcs patch names are hashcodes, which do not appear
 228           ;; in the log output :-(, but darcs accepts any prefix of the log
 229           ;; message as a patch name, so we match the first line of the log
 230           ;; message.
 231           ;; First loosely match the date format.
 232           (concat "\\|[^ \n].*[^0-9\n][0-9][0-9]:[0-9][0-9][^0-9\n].*[^ \n]"
 233                   ;;Email of user and finally Msg, used as revision name.
 234                   "  .*@.*\n\\(?:  \\* \\(?1:.*\\)\\)?")
 235           "\\)$")
 236   "Regexp matching the text identifying a revision.
 237 The match group number 1 should match the revision number itself.")
 238
 239 (defvar log-view-font-lock-keywords
 240   ;; We use `eval' so as to use the buffer-local value of log-view-file-re
 241   ;; and log-view-message-re, if applicable.
 242   '((eval . `(,log-view-file-re
 243               (1 (if (boundp 'cvs-filename-face) cvs-filename-face))
 244               (0 log-view-file-face append)))
 245     (eval . `(,log-view-message-re . log-view-message-face))))
 246
 247 (defconst log-view-font-lock-defaults
 248   '(log-view-font-lock-keywords t nil nil nil))
 249
 250 (defvar log-view-vc-fileset nil
 251   "Set this to the fileset corresponding to the current log.")
 252
 253 (defvar log-view-vc-backend nil
 254   "Set this to the VC backend that created the current log.")
 255
 256 ;;;;
 257 ;;;; Actual code
 258 ;;;;
 259
 260 ;;;###autoload
 261 (define-derived-mode log-view-mode special-mode "Log-View"
 262   "Major mode for browsing CVS log output."
 263   (setq buffer-read-only t)
 264   (set (make-local-variable 'font-lock-defaults) log-view-font-lock-defaults)
 265   (set (make-local-variable 'beginning-of-defun-function)
 266        'log-view-beginning-of-defun)
 267   (set (make-local-variable 'end-of-defun-function)
 268        'log-view-end-of-defun)
 269   (set (make-local-variable 'cvs-minor-wrap-function) 'log-view-minor-wrap)
 270   (hack-dir-local-variables-non-file-buffer))
 271
 272 ;;;;
 273 ;;;; Navigation
 274 ;;;;
 275
 276 ;; define log-view-{msg,file}-{next,prev}
 277 (easy-mmode-define-navigation log-view-msg log-view-message-re "log message")
 278 (easy-mmode-define-navigation log-view-file log-view-file-re "file")
 279
 280 (defun log-view-goto-rev (rev)
 281   (goto-char (point-min))
 282   (ignore-errors
 283     (while (not (equal rev (log-view-current-tag)))
 284       (log-view-msg-next))
 285     t))
 286
 287 ;;;;
 288 ;;;; Linkage to PCL-CVS (mostly copied from cvs-status.el)
 289 ;;;;
 290
 291 (defconst log-view-dir-re "^cvs[.ex]* [a-z]+: Logging \\(.+\\)$")
 292
 293 (defun log-view-current-file ()
 294   (save-excursion
 295     (forward-line 1)
 296     (or (re-search-backward log-view-file-re nil t)
 297         (re-search-forward log-view-file-re nil t)
 298         (error "Unable to determine the current file"))
 299     (let* ((file (match-string 1))
 300            (cvsdir (and (re-search-backward log-view-dir-re nil t)
 301                         (match-string 1)))
 302            (pcldir (and (boundp 'cvs-pcl-cvs-dirchange-re)
 303                         (re-search-backward cvs-pcl-cvs-dirchange-re nil t)
 304                         (match-string 1)))
 305            (dir ""))
 306       (let ((default-directory ""))
 307         (when pcldir (setq dir (expand-file-name pcldir dir)))
 308         (when cvsdir (setq dir (expand-file-name cvsdir dir))))
 309       (expand-file-name file dir))))
 310
 311 (defun log-view-current-entry (&optional pos move)
 312   "Return the position and revision tag of the Log View entry at POS.
 313 This is a list (BEG TAG), where BEG is a buffer position and TAG
 314 is a string.  If POS is nil or omitted, it defaults to point.
 315 If there is no entry at POS, return nil.
 316
 317 If optional arg MOVE is non-nil, move point to BEG if found.
 318 Otherwise, don't move point."
 319   (let ((looping t)
 320         result)
 321     (save-excursion
 322       (when pos (goto-char pos))
 323       (forward-line 1)
 324       (while looping
 325         (setq pos (re-search-backward log-view-message-re nil 'move)
 326               looping (and pos (log-view-inside-comment-p (point)))))
 327       (when pos
 328         (setq result
 329               (list pos (match-string-no-properties 1)))))
 330     (and move result (goto-char pos))
 331     result))
 332
 333 (defun log-view-inside-comment-p (pos)
 334   "Return non-nil if POS lies inside an expanded log entry."
 335   (eq (get-text-property pos 'log-view-comment) t))
 336
 337 (defun log-view-current-tag (&optional pos)
 338   "Return the revision tag (a string) of the Log View entry at POS.
 339 if POS is omitted or nil, it defaults to point."
 340   (cadr (log-view-current-entry pos)))
 341
 342 (defun log-view-toggle-mark-entry ()
 343   "Toggle the marked state for the log entry at point.
 344 Individual log entries can be marked and unmarked. The marked
 345 entries are denoted by changing their background color.
 346 `log-view-get-marked' returns the list of tags for the marked
 347 log entries."
 348   (interactive)
 349   (save-excursion
 350     (let* ((entry (log-view-current-entry nil t))
 351            (beg (car entry))
 352            found)
 353       (when entry
 354         ;; Look to see if the current entry is marked.
 355         (setq found (get-char-property beg 'log-view-self))
 356         (if found
 357             (delete-overlay found)
 358           ;; Create an overlay covering this entry and change its color.
 359           (let* ((end (if (get-text-property beg 'log-view-entry-expanded)
 360                           (next-single-property-change beg 'log-view-comment)
 361                         (log-view-end-of-defun)
 362                         (point)))
 363                  (ov (make-overlay beg end)))
 364             (overlay-put ov 'face 'log-view-file)
 365             ;; This is used to check if the overlay is present.
 366             (overlay-put ov 'log-view-self ov)
 367             (overlay-put ov 'log-view-marked (nth 1 entry))))))))
 368
 369 (defun log-view-get-marked ()
 370   "Return the list of tags for the marked log entries."
 371   (save-excursion
 372     (let ((pos (point-min))
 373           marked-list ov)
 374       (while (setq pos (next-single-property-change pos 'face))
 375         (when (setq ov (get-char-property pos 'log-view-self))
 376           (push (overlay-get ov 'log-view-marked) marked-list)
 377           (setq pos (overlay-end ov))))
 378       marked-list)))
 379
 380 (defun log-view-toggle-entry-display ()
 381   (interactive)
 382   ;; Don't do anything unless `log-view-expanded-log-entry-function'
 383   ;; is defined in this mode.
 384   (when (functionp log-view-expanded-log-entry-function)
 385     (let* ((opoint (point))
 386            (entry (log-view-current-entry nil t))
 387            (beg (car entry))
 388            (buffer-read-only nil))
 389       (when entry
 390         (if (get-text-property beg 'log-view-entry-expanded)
 391             ;; If the entry is expanded, collapse it.
 392             (let ((pos (next-single-property-change beg 'log-view-comment)))
 393               (unless (and pos (log-view-inside-comment-p pos))
 394                 (error "Broken markup in `log-view-toggle-entry-display'"))
 395               (delete-region pos
 396                              (next-single-property-change pos 'log-view-comment))
 397               (put-text-property beg (1+ beg) 'log-view-entry-expanded nil)
 398               (if (< opoint pos)
 399                   (goto-char opoint)))
 400           ;; Otherwise, expand the entry.
 401           (let ((long-entry (funcall log-view-expanded-log-entry-function
 402                                      (nth 1 entry))))
 403             (when long-entry
 404               (put-text-property beg (1+ beg) 'log-view-entry-expanded t)
 405               (log-view-end-of-defun)
 406               (setq beg (point))
 407               (insert long-entry "\n")
 408               (add-text-properties
 409                beg (point)
 410                '(font-lock-face font-lock-comment-face log-view-comment t))
 411               (goto-char opoint))))))))
 412
 413 (defun log-view-beginning-of-defun (&optional arg)
 414   "Move backward to the beginning of a Log View entry.
 415 With ARG, do it that many times.  Negative ARG means move forward
 416 to the beginning of the ARGth following entry.
 417
 418 This is Log View mode's default `beginning-of-defun-function'.
 419 It assumes that a log entry starts with a line matching
 420 `log-view-message-re'."
 421   (if (or (null arg) (zerop arg))
 422       (setq arg 1))
 423   (if (< arg 0)
 424       (dotimes (n (- arg))
 425         (log-view-end-of-defun))
 426     (catch 'beginning-of-buffer
 427       (dotimes (n arg)
 428         (or (log-view-current-entry nil t)
 429             (throw 'beginning-of-buffer nil)))
 430       (point))))
 431
 432 (defun log-view-end-of-defun ()
 433   "Move forward to the next Log View entry."
 434   (let ((looping t))
 435     (if (looking-at log-view-message-re)
 436         (goto-char (match-end 0)))
 437     (while looping
 438       (cond
 439        ((re-search-forward log-view-message-re nil 'move)
 440         (unless (log-view-inside-comment-p (point))
 441           (setq looping nil)
 442           (goto-char (match-beginning 0))))
 443        ;; Don't advance past the end buttons inserted by
 444        ;; `vc-print-log-setup-buttons'.
 445        ((looking-back "Show 2X entries    Show unlimited entries")
 446         (setq looping nil)
 447         (forward-line -1))))))
 448
 449 (defvar cvs-minor-current-files)
 450 (defvar cvs-branch-prefix)
 451 (defvar cvs-secondary-branch-prefix)
 452
 453 (defun log-view-minor-wrap (buf f)
 454   (let ((data (with-current-buffer buf
 455                 (let* ((beg (point))
 456                        (end (if mark-active (mark) (point)))
 457                        (fr (log-view-current-tag beg))
 458                        (to (log-view-current-tag end)))
 459                   (when (string-equal fr to)
 460                     (save-excursion
 461                       (goto-char end)
 462                       (log-view-msg-next)
 463                       (setq to (log-view-current-tag))))
 464                   (cons
 465                    ;; The first revision has to be the one at point, for
 466                    ;; operations that only take one revision
 467                    ;; (e.g. cvs-mode-edit).
 468                    (cons (log-view-current-file) fr)
 469                    (cons (log-view-current-file) to))))))
 470     (let ((cvs-branch-prefix (cdar data))
 471           (cvs-secondary-branch-prefix (and (cdar data) (cddr data)))
 472           (cvs-minor-current-files
 473            (cons (caar data)
 474                  (when (and (cadr data) (not (equal (caar data) (cadr data))))
 475                    (list (cadr data)))))
 476           ;; FIXME:  I need to force because the fileinfos are UNKNOWN
 477           (cvs-force-command "/F"))
 478       (funcall f))))
 479
 480 (defun log-view-find-revision (pos)
 481   "Visit the version at point."
 482   (interactive "d")
 483   (unless log-view-per-file-logs
 484     (when (> (length log-view-vc-fileset) 1)
 485       (error "Multiple files shown in this buffer, cannot use this command here")))
 486   (save-excursion
 487     (goto-char pos)
 488     (switch-to-buffer (vc-find-revision (if log-view-per-file-logs
 489                                             (log-view-current-file)
 490                                           (car log-view-vc-fileset))
 491                                         (log-view-current-tag)))))
 492
 493
 494 (defun log-view-extract-comment ()
 495   "Parse comment from around the current point in the log."
 496   (save-excursion
 497     (let (st en (backend (vc-backend (log-view-current-file))))
 498       (log-view-end-of-defun)
 499       (cond ((eq backend 'SVN)
 500              (forward-line -1)))
 501       (setq en (point))
 502       (log-view-beginning-of-defun)
 503       (cond ((memq backend '(SCCS RCS CVS MCVS SVN))
 504              (forward-line 2))
 505             ((eq backend 'Hg)
 506              (forward-line 4)
 507              (re-search-forward "summary: *" nil t)))
 508       (setq st (point))
 509       (buffer-substring st en))))
 510
 511 (declare-function vc-modify-change-comment "vc" (files rev oldcomment))
 512
 513 (defun log-view-modify-change-comment ()
 514   "Edit the change comment displayed at point."
 515   (interactive)
 516   (vc-modify-change-comment (list (if log-view-per-file-logs
 517                                       (log-view-current-file)
 518                                     (car log-view-vc-fileset)))
 519                             (log-view-current-tag)
 520                             (log-view-extract-comment)))
 521
 522 (defun log-view-annotate-version (pos)
 523   "Annotate the version at point."
 524   (interactive "d")
 525   (unless log-view-per-file-logs
 526     (when (> (length log-view-vc-fileset) 1)
 527       (error "Multiple files shown in this buffer, cannot use this command here")))
 528   (save-excursion
 529     (goto-char pos)
 530     (vc-annotate (if log-view-per-file-logs
 531                      (log-view-current-file)
 532                    (car log-view-vc-fileset))
 533                  (log-view-current-tag))))
 534
 535 ;;
 536 ;; diff
 537 ;;
 538
 539 (defun log-view-diff (beg end)
 540   "Get the diff between two revisions.
 541 If the mark is not active or the mark is on the revision at point,
 542 get the diff between the revision at point and its previous revision.
 543 Otherwise, get the diff between the revisions where the region starts
 544 and ends.
 545 Contrary to `log-view-diff-changeset', it will only show the part of the
 546 changeset that affected the currently considered file(s)."
 547   (interactive
 548    (list (if mark-active (region-beginning) (point))
 549          (if mark-active (region-end) (point))))
 550   (let ((fr (log-view-current-tag beg))
 551         (to (log-view-current-tag end)))
 552     (when (string-equal fr to)
 553       (save-excursion
 554         (goto-char end)
 555         (log-view-msg-next)
 556         (setq to (log-view-current-tag))))
 557     (vc-diff-internal
 558      t (list log-view-vc-backend
 559              (if log-view-per-file-logs
 560                  (list (log-view-current-file))
 561                log-view-vc-fileset))
 562      to fr)))
 563
 564 (declare-function vc-diff-internal "vc"
 565                   (async vc-fileset rev1 rev2 &optional verbose))
 566
 567 (defun log-view-diff-changeset (beg end)
 568   "Get the diff between two revisions.
 569 If the mark is not active or the mark is on the revision at point,
 570 get the diff between the revision at point and its previous revision.
 571 Otherwise, get the diff between the revisions where the region starts
 572 and ends.
 573 Contrary to `log-view-diff', it will show the whole changeset including
 574 the changes that affected other files than the currently considered file(s)."
 575   (interactive
 576    (list (if mark-active (region-beginning) (point))
 577          (if mark-active (region-end) (point))))
 578   (when (eq (vc-call-backend log-view-vc-backend 'revision-granularity) 'file)
 579     (error "The %s backend does not support changeset diffs" log-view-vc-backend))
 580   (let ((fr (log-view-current-tag beg))
 581         (to (log-view-current-tag end)))
 582     (when (string-equal fr to)
 583       ;; TO and FR are the same, look at the previous revision.
 584       (setq to (vc-call-backend log-view-vc-backend 'previous-revision nil fr)))
 585     (vc-diff-internal
 586      t
 587      ;; We want to see the diff for all the files in the changeset, so
 588      ;; pass NIL for the file list.  The value passed here should
 589      ;; follow what `vc-deduce-fileset' returns.
 590      (list log-view-vc-backend nil)
 591      to fr)))
 592
 593 (provide 'log-view)
 594
 595 ;;; log-view.el ends here