lisp/emacs-lisp/authors.el

   1 ;;; authors.el --- utility for maintaining Emacs's AUTHORS file -*-coding: utf-8 -*-
   2
   3 ;; Copyright (C) 2000-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Gerd Moellmann <gerd@gnu.org>
   6 ;; Maintainer: Kim F. Storm <storm@cua.dk>
   7 ;; Keywords: maint
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Use M-x authors RET to create an *Authors* buffer that can used as
  28 ;; or merged with Emacs's AUTHORS file.
  29
  30 ;;; Code:
  31
  32 (defvar authors-coding-system 'utf-8
  33   "Coding system used in the AUTHORS file.")
  34
  35 (defconst authors-many-files 20
  36   "Maximum number of files for which to print individual information.
  37 If an author has modified more files, only the names of the most
  38 frequently modified files are printed and a count of the additional
  39 files.")
  40
  41 (defconst authors-aliases
  42   '(
  43     ("Aaron S. Hawley" "Aaron Hawley")
  44     ("Alexandru Harsanyi" "Alex Harsanyi")
  45     ("Andrew Csillag" "Drew Csillag")
  46     ("Anna M. Bigatti" "Anna Bigatti")
  47     ("Barry A. Warsaw" "Barry A. Warsaw, Century Computing, Inc."
  48      "Barry A. Warsaw, ITB" "Barry Warsaw")
  49     ("Bill Carpenter" "WJ Carpenter")
  50     ("Bill Mann" "William F. Mann")
  51     ("Bill Rozas" "Guillermo J. Rozas")
  52     ("Björn Torkelsson" "Bjorn Torkelsson")
  53     ("Brian Fox" "Brian J. Fox")
  54     ("Brian Sniffen" "Brian T. Sniffen")
  55     ("Christoph Wedler" "Christoph.Wedler@sap.com")
  56     ("Daniel Pfeiffer" "<Daniel.Pfeiffer@Informatik.START.db.de>"
  57      "<Daniel.Pfeiffer@Informatik.START.dbp.de>")
  58     ("David Abrahams" "Dave Abrahams")
  59     ("David De La Harpe Golden" "David Golden")
  60     ("David Gillespie" "Dave Gillespie")
  61     ("David Kågedal" "David K..edal")
  62     ("David M. Koppelman" "David M. Koppelman, Koppel@Ec?e.Lsu.Edu"
  63      "David Koppelman")
  64     ("David M. Smith" "David Smith" "David M Smith")
  65     ("David O'Toole" "David T. O'Toole")
  66     ("Deepak Goel" "D. Goel")
  67     ("Ed L. Cashin" "Ed L Cashin")
  68     ("Edward M. Reingold" "Ed Reingold" "Edward M Reingold"
  69      "Reingold Edward M")
  70     ("Eli Zaretskii" "eliz")
  71     ("Emilio C. Lopes" "Emilio Lopes")
  72     ("Era Eriksson" "Era@Iki.Fi")
  73     ("Eric M. Ludlam" "Eric Ludlam")
  74     ("Eric S. Raymond" "Eric Raymond")
  75     ("Eric Youngdale" "(Eric Youngdale at youngdale@v6550c.nrl.navy.mil)")
  76     ("Francis J. Wright" "Dr Francis J. Wright" "Francis Wright")
  77     ("François Pinard" "Francois Pinard")
  78     ("Francesco Potortì" "Francesco Potorti" "Francesco Potorti`")
  79     ("Frederic Pierresteguy" "Fred Pierresteguy")
  80     ("Geoff Voelker" "voelker")
  81     ("Gerd Möllmann" "Gerd Moellmann")
  82     ("Hallvard B. Furuseth" "Hallvard B Furuseth" "Hallvard Furuseth")
  83     ("Hrvoje Nikšić" "Hrvoje Niksic")
  84     ;; lisp/org/ChangeLog 2010-11-11.
  85     (nil "aaa bbb")
  86     ;; src/ChangeLog.4, 1994-01-11, since fixed.
  87 ;;;    (nil "(afs@hplb.hpl.hp.com)")
  88     ;; lisp/gnus/ChangeLog.1, 1998-01-15.
  89     ;; http://quimby.gnus.org/cgi-bin/cvsweb.cgi/gnus/lisp/gnus-art.el?rev=4.13
  90     (nil "<Use-Author-Address-Header@\\[127.1\\]>")
  91     (nil "Code Extracted") ; lisp/newcomment.el's "Author:" header
  92     (nil "\\`FSF")  ; FIXME what is this for - no effect?
  93     ;; lisp/gnus/ChangeLog.1, 1997-10-12, since fixed.
  94 ;;;    (nil "ISO-2022-JP")
  95     ("Jaeyoun Chung" "Jae-youn Chung" "Jae-you Chung" "Chung Jae-youn")
  96     ("Jan Djärv" "Jan D." "Jan Djarv")
  97     ("Jay K. Adams" "jka@ece.cmu.edu" "Jay Adams")
  98     ("Jérôme Marant" "Jérôme Marant" "Jerome Marant")
  99     ("Jens-Ulrik Holger Petersen" "Jens-Ulrik Petersen")
 100     ("Jeremy Bertram Maitin-Shepard" "Jeremy Maitin-Shepard")
 101     ("Johan Bockgård" "Johan Bockgard")
 102     ("John J Foerch" "John Foerch")
 103     ("John W. Eaton" "John Eaton")
 104     ("Jonathan I. Kamens" "Jonathan Kamens")
 105     ("Joseph Arceneaux" "Joe Arceneaux")
 106     ("Joseph M. Kelsey" "Joe Kelsey")   ; FIXME ?
 107     ("Juan León Lahoz García" "Juan-Leon Lahoz Garcia")
 108     ("K. Shane Hartman" "Shane Hartman")
 109     ("Kai Großjohann" "Kai Grossjohann" "Kai Großjohann"
 110      "Kai.Grossjohann@Cs.Uni-Dortmund.De"
 111      "Kai.Grossjohann@Gmx.Net")
 112     ("Karl Berry" "K. Berry")
 113     ("Károly Lőrentey" "Károly Lőrentey" "Lőrentey Károly")
 114     ("Kazushi Marukawa" "Kazushi")
 115     ("Ken Manheimer" "Kenneth Manheimer")
 116     ("Kenichi Handa" "Ken'ichi Handa" "Kenichi HANDA")
 117     ("Kevin Greiner" "Kevin J. Greiner")
 118     ("Kim F. Storm" "Kim Storm")
 119     ("Kyle Jones" "Kyle E. Jones")
 120     ("Lars Magne Ingebrigtsen" "Lars Ingebrigtsen")
 121     ("Marcus G. Daniels" "Marcus Daniels")
 122     ("Mark D. Baushke" "Mark D Baushke")
 123     ("Marko Kohtala" "Kohtala Marko")
 124     ("Agustín Martín" "Agustin Martin" "Agustín Martín Domingo")
 125     ("Martin Lorentzon" "Martin Lorentzson")
 126     ("Matt Swift" "Matthew Swift")
 127     ("Maxime Edouard Robert Froumentin" "Max Froumentin")
 128     ("Michael R. Mauger" "Michael Mauger")
 129     ("Michael D. Ernst" "Michael Ernst")
 130     ("Michaël Cadilhac" "Michael Cadilhac")
 131     ("Michael I. Bushnell" "Michael I Bushnell" "Michael I. Bushnell, P/Bsg")
 132     ("Michael R. Cook" "Michael Cook")
 133     ("Michael Sperber" "Michael Sperber \\[Mr. Preprocessor\\]")
 134     ("Mikio Nakajima" "Nakajima Mikio")
 135     ("Nelson Jose dos Santos Ferreira" "Nelson Ferreira")
 136     ("Noorul Islam" "Noorul Islam K M")
 137     ("Paul Eggert" "eggert")
 138     ("Paul Reilly" "(pmr@legacy.pajato.com)")
 139     ("Pavel Janík" "Pavel Janík Ml." "Pavel Janik Ml." "Pavel Janik" "Pavel Janík" "Pavel@Janik.Cz")
 140     ("Pavel Kobiakov" "Pavel Kobyakov")
 141     ("Per Abrahamsen" "Per Abhiddenware")
 142     ("Per Starbäck" "Per Starback")
 143     ("Peter J. Weisberg" "PJ Weisberg")
 144     ("Peter S. Galbraith" "Peter Galbraith")
 145     ("Peter Runestig" "Peter 'luna' Runestig")
 146     ("Peter S. Galbraith" "Peter S Galbraith")
 147     ("Raja R. Harinath" "Raja R Harinath")
 148     ("Richard G. Bielawski" "Richard G Bielawski" "Richard Bielawski")
 149     ("Richard King" "Dick King")
 150     ("Richard M. Stallman" "Richard M. Stallman,,," "Richard Stallman"
 151      "rms" "rms@gnu.org")
 152     ("Robert J. Chassell" "Bob Chassell")
 153     ("Roland B. Roberts" "Roland B Roberts" "Roland Roberts")
 154     ("Rui-Tao Dong" "Rui-Tao Dong ~{6-Hpln~}")
 155     ("Sacha Chua" "Sandra Jean Chua")
 156     ("Sam Steingold" "Sam Shteingold")
 157     ("Satyaki Das" "Indexed search by Satyaki Das")
 158     ("Sébastien Vauban" "Sebastien Vauban")
 159     ;; There are other Stefans.
 160 ;;;    ("Stefan Monnier" "Stefan")
 161     ("Stephen A. Wood" "(saw@cebaf.gov)")
 162     ("Steven L. Baur" "SL Baur" "Steven L Baur")
 163     ("Stewart M. Clamen" "Stewart Clamen")
 164     ("Stuart D. Herring" "Stuart Herring" "Davis Herring")
 165     ("T.V. Raman" "T\\. V\\. Raman")
 166     ("Taichi Kawabata" "KAWABATA,? Taichi")
 167     ("Takaaki Ota" "Tak Ota")
 168     ("Takahashi Naoto" "Naoto Takahashi")
 169     ("Teodor Zlatanov" "Ted Zlatanov")
 170     ("Thomas Dye" "Tom Dye")
 171     ("Thomas Horsley" "Tom Horsley")    ; FIXME ?
 172     ("Thomas Wurgler" "Tom Wurgler")
 173     ("Toby Cubitt" "Toby S\\. Cubitt")
 174     ("Tomohiko Morioka" "MORIOKA Tomohiko")
 175     ("Torbjörn Axelsson" "Torbjvrn Axelsson")
 176     ("Torbjörn Einarsson" "Torbj.*rn Einarsson")
 177     ("Toru Tomabechi" "Toru Tomabechi,")
 178     ("Tsugutomo Enami" "enami tsugutomo")
 179     ("Ulrich Müller" "Ulrich Mueller")
 180     ("Vincent Del Vecchio" "Vince Del Vecchio")
 181     ("William M. Perry" "Bill Perry")
 182     ("Wlodzimierz Bzyl" "W.*dek Bzyl")
 183     ("Yoni Rabkin" "Yoni Rabkin Katzenell")
 184     ("Yoshinori Koseki" "KOSEKI Yoshinori" "小関 吉則")
 185     ("Yutaka NIIBE" "NIIBE Yutaka")
 186     )
 187   "Alist of author aliases.
 188
 189 Each entry is of the form (REALNAME REGEXP...).  If an author's name
 190 matches one of the REGEXPs, use REALNAME instead.
 191 If REALNAME is nil, ignore that author.")
 192
 193 ;; FIXME seems it would be less fragile to check for O', Mc, etc.
 194 (defconst authors-fixed-case
 195   '("Bryan O'Sullivan"
 196     "Christian von Roques"
 197     "Christophe de Dinechin"
 198     "Craig McDaniel"
 199     "David J. MacKenzie"
 200     "David McCabe"
 201     "David O'Toole"
 202     "Devon Sean McCullough"
 203     "Dominique de Waleffe"
 204     "Edward O'Connor"
 205     "Exal de Jesus Garcia Carrillo"
 206     "Greg McGary"
 207     "Hans de Graaff"
 208     "James TD Smith"
 209     "Joel N. Weber II"
 210     "Michael McNamara"
 211     "Mike McEwan"
 212     "Nelson Jose dos Santos Ferreira"
 213     "Peter von der Ahe"
 214     "Peter O'Gorman"
 215     "Piet van Oostrum"
 216     "Roland McGrath"
 217     "Sean O'Halpin"
 218     "Sean O'Rourke"
 219     "Tijs van Bakel")
 220   "List of authors whose names cannot be simply capitalized.")
 221
 222 (defvar authors-public-domain-files
 223   '("emerge\\.el"
 224     "vi\\.el"
 225     "feedmail\\.el"
 226     "mailpost\\.el"
 227     "hanoi\\.el"
 228     "meese\\.el"
 229     "studly\\.el"
 230     "modula2\\.el"
 231     "nnmaildir\\.el"
 232     "nnil\\.el"
 233     "b2m\\.c"
 234     "unexhp9k800\\.c"
 235     "emacsclient\\.1"
 236     "check-doc-strings")
 237   "List of regexps matching files for which the FSF doesn't need papers.")
 238
 239
 240 (defvar authors-obsolete-files-regexps
 241   '("vc-\\*\\.el$"
 242     "spec.txt$"
 243     ".*loaddefs.el$"                    ; not obsolete, but auto-generated
 244     "\\.\\(cvs\\|git\\)ignore$"         ; obsolete or uninteresting
 245     "\\.arch-inventory$"
 246     ;; TODO lib/? Matches other things?
 247     "build-aux/" "m4/" "Emacs.xcodeproj" "charsets" "mapfiles"
 248     "preferences\\.\\(nib\\|gorm\\)"
 249     "vc-\\(rcs\\|cvs\\|sccs\\)-hooks\\.el$")
 250   "List of regexps matching obsolete files.
 251 Changes to files matching one of the regexps in this list are not listed.")
 252
 253 (defconst authors-ignored-files
 254   '("external-lisp"
 255     "lock" "share-lib" "local-lisp"
 256     "noleim-Makefile.in"
 257     "NEWS" "ORDERS" "PROBLEMS" "FAQ" "AUTHORS" "FOR-RELEASE" "TODO" "todo"
 258     "MACHINES" "SERVICE"
 259     "README.unicode" "README.multi-tty" "TUTORIAL.translators"
 260     "NEWS.unicode" "COPYING.DJ" "Makefile.old" "Makefile.am"
 261     "NEWS.1" "OOOOONEWS...OONEWS" "OOOONEWS" "etc/NEWS"
 262     "NEWS.1-17" "NEWS.18" "NEWS.19" "NEWS.20" "NEWS.21" "NEWS.22"
 263     "MAINTAINERS" "MH-E-NEWS"
 264     "install-sh" "missing" "mkinstalldirs"
 265     "termcap.dat" "termcap.src" "termcap.ucb" "termcap"
 266     "ChangeLog.nextstep" "Emacs.clr" "spec.txt"
 267     "gfdl.1"
 268     "texi/Makefile.in"
 269     "Imakefile" "icons/sink.ico" "aixcc.lex"
 270     "nxml/char-name/unicode"
 271     "js2-mode.el"      ; only installed very briefly, replaced by js.el
 272     "cedet/tests/testtemplates.cpp"
 273     "cedet/tests/testusing.cpp"
 274     "cedet/tests/scopetest.cpp"
 275     "cedet/tests/scopetest.java"
 276     "cedet/tests/test.cpp"
 277     "cedet/tests/test.py"
 278     "cedet/tests/teststruct.cpp"
 279     "*.el"
 280     ;; Autogen:
 281     "cus-load.el" "finder-inf.el" "ldefs-boot.el"
 282     "compile" "config.guess" "config.sub" "depcomp"
 283     ;; Only existed briefly, then renamed:
 284     "images/icons/allout-widgets-dark-bg"
 285     "images/icons/allout-widgets-light-bg"
 286     ;; Never had any meaningful changes logged, now deleted:
 287     "unidata/bidimirror.awk" "unidata/biditype.awk"
 288     "split-man" "Xkeymap.txt" "ms-7bkermit" "ulimit.hack"
 289     "gnu-hp300" "refcard.bit" "ledit.l" "forms.README" "forms-d2.dat"
 290     "CXTERM-DIC/PY.tit" "CXTERM-DIC/ZIRANMA.tit"
 291     "CXTERM-DIC/CTLau.tit" "CXTERM-DIC/CTLauB.tit"
 292     "NICKLES.WORTH" "INTERVAL.IDEAS" "RCP"
 293     "3B-MAXMEM" "AIX.DUMP" "SUN-SUPPORT" "XENIX"
 294     "CODINGS" "CHARSETS"
 295     "calc/INSTALL" "calc/Makefile"
 296     "vms-pp.trans" "_emacs" "batcomp.com" "notes/cpp" ; admin/
 297     "emacsver.texi.in"
 298     ;; MH-E stuff not in Emacs:
 299     "import-emacs" "release-utils"
 300     ;; Erc stuff not in Emacs:
 301     "ChangeLog.2001" "ChangeLog.2002" "ChangeLog.2003" "ChangeLog.2004"
 302     "ChangeLog.2005"
 303     "README.extras" "dir-template" "mkChangeLog" "MkChangeLog" "erc-auto.in"
 304     "CREDITS" "HACKING"
 305     "debian/changelog"
 306     "debian/control"
 307     "debian/copyright"
 308     "debian/maint/conffiles"
 309     "debian/maint/conffiles.in"
 310     "debian/maint/postinst"
 311     "debian/maint/postinst.in"
 312     "debian/maint/prerm"
 313     "debian/maint/prerm.in"
 314     "debian/README.Debian"
 315     "debian/README.erc-speak"
 316     "debian/rules"
 317     "debian/scripts/install"
 318     "debian/scripts/install.in"
 319     "debian/scripts/remove"
 320     "debian/scripts/remove.in"
 321     "debian/scripts/startup"
 322     "debian/scripts/startup.erc"
 323     "debian/scripts/startup.erc-speak"
 324     )
 325   "List of files and directories to ignore.
 326 Changes to files in this list are not listed.")
 327
 328 ;; List via: find . -name '*.el' | sed 's/.*\///g' | sort | uniq -d
 329 ;; FIXME It would be better to discover these dynamically.
 330 ;; Note that traditionally "Makefile.in" etc have not been in this list.
 331 ;; Ditto for "abbrev.texi" etc.
 332 (defconst authors-ambiguous-files
 333   '("chart.el"
 334     "compile.el"
 335     "complete.el"
 336     "cpp.el"
 337     "ctxt.el"
 338     "custom.el"
 339     "cyrillic.el"
 340     "czech.el"
 341     "debug.el"
 342     "dired.el"
 343     "el.el"
 344     "eshell.el"
 345     "ethiopic.el"
 346     "f90.el"
 347     "files.el"
 348     "find.el"
 349     "format.el"
 350     "generic.el"
 351     "georgian.el"
 352     "greek.el"
 353     "grep.el"
 354     "hebrew.el"
 355     "imenu.el"
 356     "indian.el"
 357     "japanese.el"
 358     "java.el"
 359     "lao.el"
 360     "linux.el"
 361     "locate.el"
 362     "make.el"
 363     "mode.el"
 364     "python.el"
 365     "rmailmm.el"
 366     "semantic.el"
 367     "shell.el"
 368     "simple.el"
 369     "slovak.el"
 370     "sort.el"
 371     "speedbar.el"
 372     "srecode.el"
 373     "table.el"
 374     "texi.el"
 375     "thai.el"
 376     "tibetan.el"
 377     "util.el"
 378     "vc-bzr.el"
 379     "wisent.el")
 380   "List of basenames occurring more than once in the source.")
 381
 382 ;; FIXME :cowrote entries here can be overwritten by :wrote entries
 383 ;; derived from a file's Author: header (eg mh-e).  This really means
 384 ;; the Author: header is erroneous.
 385 (defconst authors-fixed-entries
 386   '(("Richard M. Stallman" :wrote "[The original GNU Emacs and numerous files]")
 387     ("Joseph Arceneaux" :wrote "xrdb.c")
 388     ;; This refers to the obsolete Willisson (qv) version.
 389 ;;;    ("Blitz Product Development Corporation" :wrote "ispell.el")
 390     ("Frank Bresz" :wrote "diff.el")
 391     ("David M. Brown" :wrote "array.el")
 392     ;; No longer distributed.
 393 ;;;    ("Gary Byers" :changed "xenix.h")
 394     ("Shawn M. Carey" :wrote "freebsd.h")
 395     ;; hp800.h renamed from hp9000s800.h, hpux.h merged into hpux10-20.h.
 396     ;; FIXME overwritten by Author:.
 397     ("Satyaki Das" :cowrote "mh-search.el")
 398     ("Eric Decker" :changed "hp800.h" "hpux10-20.h" "sysdep.c")
 399     ("Lawrence R. Dodd" :cowrote "dired-x.el")
 400     ;; No longer distributed.
 401 ;;;    ("Viktor Dukhovni" :wrote "unexsunos4.c")
 402     ("Paul Eggert" :wrote "rcs2log") ; "vcdiff"
 403     ("Fred Fish" :changed "unexcoff.c")
 404     ;; No longer distributed.
 405 ;;;    ("Tim Fleehart" :wrote "makefile.nt")
 406     ("Keith Gabryelski" :wrote "hexl.c")
 407     ("Kevin Gallagher" :wrote "flow-ctrl.el")
 408     ;; Also wrote an earlier version of disp-table.el, since replaced
 409     ;; by Erik Naggum's version; also iso-syntax.el, later renamed to
 410     ;; latin-1.el, since deleted.
 411     ("Howard Gayle" :wrote "casetab.c")
 412     ;; :wrote mh-pick.el, since merged into mh-search.el.
 413     ;; Originally wrote mh-funcs.el, but it has been rewritten since.
 414     ("Stephen Gildea" :wrote "refcard.tex"
 415      :cowrote "mh-funcs.el" "mh-search.el")
 416     ;; cl.texinfo renamed to cl.texi.
 417     ("David Gillespie" :wrote "cl.texi")
 418     ;; No longer distributed: emacsserver.c.
 419     ("Hewlett-Packard" :changed "emacsclient.c" "server.el" "keyboard.c")
 420     ;; No longer distributed.
 421 ;;;    ("Thomas Horsley" :wrote "cxux.h" "cxux7.h")
 422     ("Indiana University Foundation" :changed "buffer.c" "buffer.h"
 423      "indent.c" "search.c" "xdisp.c" "region-cache.c" "region-cache.h")
 424     ;; ibmrt.h, ibmrt-aix.h no longer distributed.
 425     ("International Business Machines" :changed "emacs.c" "fileio.c"
 426      "process.c" "sysdep.c" "unexcoff.c")
 427     ;; No longer distributed.
 428 ;;;    ("Ishikawa Chiaki" :changed "aviion.h" "dgux.h")
 429     ;; ymakefile no longer distributed.
 430     ("Michael K. Johnson" :changed "configure.in" "emacs.c" "intel386.h"
 431      "mem-limits.h" "process.c" "template.h" "sysdep.c" "syssignal.h"
 432      "systty.h" "unexcoff.c" "linux.h")
 433     ;; No longer distributed.
 434 ;;;    ("Kyle Jones" :wrote "mldrag.el")
 435     ("Henry Kautz" :wrote "bib-mode.el")
 436     ;; No longer distributed: vms-pwd.h, vmsfns.c, uaf.h.
 437     ("Joseph M. Kelsey" :changed "fileio.c" "dir.h")
 438     ("Sam Kendall" :changed "etags.c" "etags.el")
 439     ;; ack.texi: "We're not using his backquote.el any more."
 440     ("Richard King" :wrote "userlock.el" "filelock.c")
 441     ("Sebastian Kremer" :changed "add-log.el")
 442     ("Mark Lambert" :changed "process.c" "process.h")
 443     ("Aaron Larson" :changed "bibtex.el")
 444     ;; It was :wrote, but it has been rewritten since.
 445     ("James R. Larus" :cowrote "mh-e.el")
 446     ("Lars Lindberg" :changed "dabbrev.el" :cowrote "imenu.el")
 447     ;; No longer distributed: lselect.el.
 448     ("Lucid, Inc." :changed "bytecode.c" "byte-opt.el" "byte-run.el"
 449      "bytecomp.el" "delsel.el" "disass.el" "faces.el" "font-lock.el"
 450      "lmenu.el" "mailabbrev.el" "select.el" "xfaces.c" "xselect.c")
 451     ;; MCC.  No longer distributed: emacsserver.c.
 452     ("Microelectronics and Computer Technology Corporation"
 453      :changed "etags.c" "emacsclient.c" "movemail.c"
 454      "rmail.el" "rmailedit.el" "rmailkwd.el"
 455      "rmailmsc.el" "rmailout.el" "rmailsum.el" "scribe.el"
 456      ;; It was :wrote for xmenu.c, but it has been rewritten since.
 457      "server.el" "lisp.h" "sysdep.c" "unexcoff.c" "xmenu.c")
 458     ("Niall Mansfield" :changed "etags.c")
 459     ("Brian Marick" :cowrote "hideif.el")
 460     ("Marko Kohtala" :changed "info.el")
 461     ("Sidney Markowitz" :changed "doctor.el")
 462     ;; No longer distributed: env.c.
 463     ("Richard Mlynarik" :wrote "ehelp.el")
 464     ("Mosur Mohan" :changed "etags.c")
 465     ("Jeff Morgenthaler" :changed "flow-ctrl.el" "vt200.el" "vt201.el"
 466      "vt220.el" "vt240.el")
 467     ("Motorola" :changed "buff-menu.el")
 468     ("Hiroshi Nakano" :changed "ralloc.c")
 469     ;; File removed in Emacs 24.1.
 470 ;;;    ("Sundar Narasimhan" :changed "rnewspost.el")
 471     ;; No longer distributed.
 472 ;;;    ("NeXT, Inc." :wrote "unexnext.c")
 473     ("Mark Neale" :changed "fortran.el")
 474     ;; Renamed from sc.el.
 475     ("Martin Neitzel" :changed "supercite.el")
 476     ("Andrew Oram" :changed "calendar.texi (and other files in man/)")
 477     ("Frederic Pierresteguy" :wrote "widget.c")
 478     ("Michael D. Prange" :changed "tex-mode.el")
 479     ;; No longer distributed (dgux5-4r3.h was renamed to dgux5-4-3.h).
 480 ;;;    ("Paul Reilly" :wrote "gux5-4r2.h" "dgux5-4-3.h")
 481     ("Roland B. Roberts" :changed "files.el" "sort.el"
 482      "buffer.h" "callproc.c" "dired.c" "process.c" "sysdep.c" "systty.h")
 483      ;; No longer distributed.
 484 ;;;     "vmspaths.h" "build.com" "compile.com" "kepteditor.com" "precomp.com"
 485 ;;;     "vmsproc.el" :wrote "logout.com" "mailemacs.com")
 486 ;;;    ("Guillermo J. Rozas" :wrote "fakemail.c")
 487     ("Wolfgang Rupprecht" :changed "lisp-mode.el" "loadup.el"
 488      "sort.el" "alloc.c" "callint.c"
 489      ;; config.in renamed from config.h.in; ecrt0.c from crt0.c.
 490      "config.in" "ecrt0.c" "data.c" "fns.c"
 491      "lisp.h" "lread.c" ; "sun3.h" "ymakefile" - no longer distributed
 492      "print.c" :wrote "float-sup.el" "floatfns.c")
 493     ("Schlumberger Technology Corporation" :changed "gud.el")
 494     ;; Replaced by tcl.el.
 495 ;;;    ("Gregor Schmid" :wrote "tcl-mode.el")
 496     ("Rainer Schoepf" :wrote "alpha.h" "unexalpha.c")
 497     ;; No longer distributed: emacsserver.c.
 498     ("William Sommerfeld" :wrote "emacsclient.c" "scribe.el")
 499     ;; No longer distributed: emacsserver.c.
 500     ("Leigh Stoller" :changed "emacsclient.c" "server.el")
 501     ("Steve Strassmann" :wrote "spook.el")
 502     ("Shinichirou Sugou" :changed "etags.c")
 503     ;; No longer distributed: emacsserver.c.
 504     ("Sun Microsystems, Inc" :changed "emacsclient.c" "server.el"
 505      :wrote "emacs.icon" "sun.el")
 506     ;; No longer distributed.
 507 ;;;     "emacstool.1" "emacstool.c" "sun-curs.el"
 508 ;;;     "sun-fns.el" "sun-mouse.el" "sunfns.c")
 509     ;; Renamed from sc.el.
 510     ("Kayvan Sylvan" :changed "supercite.el")
 511     ;; No longer distributed: emacsserver.c, tcp.c.
 512     ("Spencer Thomas" :changed "emacsclient.c" "server.el"
 513      "dabbrev.el" "unexcoff.c" "gnus.texi")
 514     ("Jonathan Vail" :changed "vc.el")
 515     ("James Van Artsdalen" :changed "usg5-4.h" "unexcoff.c")
 516     ;; No longer distributed: src/makefile.nt, lisp/makefile.nt
 517     ;; winnt.el renamed to w32-fns.el; nt.[ch] to w32.[ch];
 518     ;; ntheap.[ch] to w32heap.[ch]; ntinevt.c to w32inevt.c;
 519     ;; ntproc.c to w32proc.c; ntterm.c to w32term.c;
 520     ;; windowsnt.h to ms-w32.h.
 521     ("Geoff Voelker" :wrote "w32-fns.el" "w32.c" "w32.h" "w32heap.c"
 522      "w32heap.h" "w32inevt.c" "w32proc.c" "w32term.c" "ms-w32.h")
 523     ("Morten Welinder" :wrote "dosfns.c" "[many MS-DOS files]" "msdos.h")
 524     ("Eli Zaretskii" :wrote "bidi.c" "[bidirectional display in xdisp.c]")
 525     ;; Not using this version any more.
 526 ;;;    ("Pace Willisson" :wrote "ispell.el")
 527     ;; FIXME overwritten by Author:.
 528     ("Bill Wohler" :cowrote "mh-e.el")
 529     ("Garrett Wollman" :changed "sendmail.el")
 530     ("Dale R. Worley" :changed "mail-extr.el")
 531     ("Jamie Zawinski" :changed "bytecode.c" :wrote "tar-mode.el"
 532      :cowrote "disass.el"))
 533   "Actions taken from the original, manually (un)maintained AUTHORS file.")
 534
 535
 536 (defconst authors-valid-file-names
 537   '("aclocal.m4"
 538     "build-ins.in"
 539     "Makefile.noleim"
 540     "makedist.bat"
 541     "makefile.def"
 542     "makefile.nt"
 543     "debug.bat.in" "emacs.bat.in"
 544     ".gdbinit-union"
 545     "alloca.s"
 546     "make-delta"
 547     "config.w95"
 548     "emacstool.1"
 549     "align.umax"
 550     "cxux-crt0.s"
 551     "gould-sigvec.s"
 552     "getdate.y"
 553     "ymakefile"
 554     "permute-index" "index.perm"
 555     "ibmrs6000.inp"
 556     "b2m.c" "b2m.1" "b2m.pl"
 557     "emacs.bash" "emacs.csh" "ms-kermit"
 558     "emacs.ico"
 559     "emacs21.ico"
 560     "BABYL" "LPF" "LEDIT" "OTHER.EMACSES"
 561     "emacs16_mac.png" "emacs24_mac.png"
 562     "emacs256_mac.png" "emacs32_mac.png"
 563     "emacs48_mac.png" "emacs512_mac.png"
 564     "revdiff"                           ; admin/
 565     "mainmake" "sed1.inp" "sed2.inp" "sed3.inp" ; msdos/
 566     "mac-fix-env.m"
 567     ;; Deleted vms stuff:
 568     "temacs.opt" "descrip.mms" "compile.com" "link.com"
 569     )
 570   "File names which are valid, but no longer exist (or cannot be found)
 571 in the repository.")
 572
 573 (defconst authors-renamed-files-alist
 574   '(("nt.c" . "w32.c") ("nt.h" . "w32.h")
 575     ("ntheap.c" . "w32heap.c") ("ntheap.h" . "w32heap.h")
 576     ("ntinevt.c" . "w32inevt.c") ("ntinevt.h" . "w32inevt.h")
 577     ("ntproc.c" . "w32proc.c")
 578     ("w32console.c" . "w32term.c")
 579     ("unexnt.c" . "unexw32.c")
 580     ("s/windowsnt.h" . "s/ms-w32.h")
 581     ("winnt.el" . "w32-fns.el")
 582     ("config.emacs" . "configure")
 583     ("config.h.dist" . "config.in")
 584     ("config.h-dist" . "config.in")
 585     ("config.h.in" . "config.in")
 586     ("paths.h-dist" . "paths.h.in")
 587     ("patch1" . "sed1.inp")
 588     ("GETTING.GNU.SOFTWARE" . "FTP")
 589     ("etc/MACHINES" . "MACHINES")
 590     ("ONEWS" . "NEWS.19")
 591     ("ONEWS.1" . "NEWS.1-17")
 592     ("ONEWS.2" . "NEWS.1-17")
 593     ("ONEWS.3" . "NEWS.18")
 594     ("ONEWS.4" . "NEWS.18")
 595     ("ORDERS.USA" . "ORDERS")
 596     ("EUROPE" . "ORDERS")
 597     ("DIFF" . "OTHER.EMACSES")
 598     ("CCADIFF" . "OTHER.EMACSES")
 599     ("GOSDIFF" . "OTHER.EMACSES")
 600     ("Makefile.in.in" . "Makefile.in")
 601     ("leim-Makefile" . "leim/Makefile")
 602     ("leim-Makefile.in" . "leim/Makefile.in")
 603     ("emacs-lisp/testcover-ses.el" . "tcover-ses.el")
 604     ("emacs-lisp/testcover-unsafep.el" . "tcover-unsafep.el")
 605     ;; index and pick merged into search.
 606     ("mh-index.el" . "mh-search.el")
 607     ("mh-pick.el" . "mh-search.el")
 608     ("font-setting.el" . "dynamic-setting.el")
 609     ;; INSTALL-CVS -> .CVS -> .BZR
 610     ("INSTALL-CVS" . "INSTALL.BZR")
 611     ("INSTALL.CVS" . "INSTALL.BZR")
 612     ("refcards/fr-drdref.pdf" . "refcards/fr-dired-ref.pdf")
 613     ("gnus-logo.eps" . "refcards/gnus-logo.eps")
 614     ("build-install" . "build-ins.in")
 615     ("build-install.in" . "build-ins.in")
 616     ("unidata/Makefile" . "unidata/Makefile.in")
 617     ;; Not renamed, but we only have the latter in the Emacs repo.
 618     ("trampver.texi.in" . "trampver.texi")
 619     ("e/eterm" . "e/eterm-color")
 620     ("e/eterm.ti" . "e/eterm-color.ti")
 621     ("README.txt" . "README")
 622     ("emacs.names" . "JOKES")
 623     ("ED.WORSHIP" . "JOKES")
 624     ("GNU.JOKES" . "JOKES")
 625     ("CHARACTERS" . "TODO")
 626     ("schema/xhtml-basic-form.rnc" . "schema/xhtml-bform.rnc" )
 627     ("schema/xhtml-basic-table.rnc" . "schema/xhtml-btable.rnc")
 628     ("schema/xhtml-list.rnc" . "schema/xhtml-lst.rnc")
 629     ("schema/xhtml-target.rnc" . "schema/xhtml-tgt.rnc")
 630     ("schema/xhtml-style.rnc" . "schema/xhtml-xstyle.rnc")
 631     ("schema/docbook-dyntbl.rnc" . "schema/docbk-dyntbl.rnc")
 632     ("schema/docbook-soextbl.rnc" . "schema/docbk-soextbl.rn" )
 633     ("texi/url.txi" . "url.texi")
 634     ("edt-user.doc" . "edt.texi")
 635     ("DEV-NOTES" . "nextstep")
 636     ("org/COPYRIGHT-AND-LICENSE" . "org/README")
 637     ;; Moved to different directories.
 638     ("ctags.1" . "ctags.1")
 639     ("etags.1" . "etags.1")
 640     ("emacs.1" . "emacs.1")
 641     ("emacsclient.1" . "emacsclient.1")
 642     ("icons/emacs21.ico" . "emacs21.ico")
 643     ;; Moved from admin/nt/ to nt/.
 644     ("nt/README.W32" . "README.W32")
 645     )
 646   "Alist of files which have been renamed during their lifetime.
 647 Elements are (OLDNAME . NEWNAME).")
 648
 649 (defconst authors-renamed-files-regexps
 650   '(("^m/m-\\(.*\\.h\\)$" . "m/\\1")
 651     ("^m-\\(.*\\.h\\)$" . "\\1")
 652     ("^s/s-\\(.*\\.h\\)$" . "s/\\1")
 653     ("^s-\\(.*\\.h\\)$" . "\\1")
 654     ("^s/[-.a-zA-Z0-9_]+\\.h$" . t)
 655     ("\\(.*\\)\\.cmd$" . "\\1.bat")
 656     ("\\.bat$" . t)
 657     ("\\.[ch]$" . t)
 658     ("\\.el$" . t)
 659     ("\\.ps$" . t)
 660     ("\\.texi?$" . t)
 661     ("\\.texinfo$" . t)
 662     ("\\.xml?$" . t)
 663     ("\\.x[pb]m$" . t)
 664     ("\\.[xp]bm$" . t)
 665     ("^paths\\." . t)
 666     ("^install\\." . t)
 667     ("^\\(TUTORIAL[^/]*\\)" . "tutorials/\\1")
 668     ("^\\(tree-widget/\\(?:default\\|folder\\)/[-a-z]+\\.png\\)$" .
 669      "images/\\1")
 670     ("^\\(images/icons/\\)mac\\(emacs\\)_\\([0-9]+\\)\\(\\.png\\)" .
 671      "\\1\\2\\3_mac\\4")
 672     ("\\(images/icons/\\)emacs_\\([0-9][0-9]\\)\\.png" .
 673      "\\1hicolor/\\2x\\2/apps/emacs.png")
 674     )
 675   "List regexps and rewriting rules for renamed files.
 676 Elements are (REGEXP . REPLACE).  If REPLACE is a string, the file
 677 name matching REGEXP is replaced by REPLACE using `replace-string'.
 678 Otherwise, the file name is accepted as is.")
 679
 680 (defvar authors-checked-files-alist)
 681 (defvar authors-invalid-file-names)
 682
 683 (defun authors-disambiguate-file-name (fullname)
 684   "Convert FULLNAME to an unambiguous relative-name."
 685   (let ((relname (file-name-nondirectory fullname))
 686         parent)
 687     (if (member relname authors-ambiguous-files)
 688         ;; In case of ambiguity, just prepend the parent directory.
 689         ;; FIXME obviously this is not a perfect solution.
 690         (if (string-equal "lisp"
 691                           (setq parent (file-name-nondirectory
 692                                         (directory-file-name
 693                                          (file-name-directory fullname)))))
 694             relname
 695           (format "%s/%s" parent relname))
 696       relname)))
 697
 698 (defun authors-canonical-file-name (file log-file pos author)
 699   "Return canonical file name for FILE found in LOG-FILE.
 700 Checks whether FILE is a valid (existing) file name, has been renamed,
 701 or is on the list of removed files.  Returns the non-directory part of
 702 the file name.  Only uses the LOG-FILE position POS and associated AUTHOR
 703 to print a message if FILE is not found."
 704   ;; FILE should be re-checked in every different directory associated
 705   ;; with a LOG-FILE.  Eg configure.in from src/ChangeLog is not the
 706   ;; same as that from top-level/ChangeLog.
 707   (let* ((fullname (expand-file-name file (file-name-directory log-file)))
 708          (entry (assoc fullname authors-checked-files-alist))
 709          relname
 710          valid)
 711     (if entry
 712         (cdr entry)
 713       (setq relname (file-name-nondirectory file))
 714       (if (or (member relname authors-valid-file-names)
 715               (file-exists-p file)
 716               (file-exists-p relname)
 717               (file-exists-p (concat "etc/" relname)))
 718           (setq valid (authors-disambiguate-file-name fullname))
 719         (setq valid (assoc file authors-renamed-files-alist))
 720         (if valid
 721             (setq valid (cdr valid))
 722           (let ((rules authors-renamed-files-regexps))
 723             (while rules
 724               (if (string-match (car (car rules)) file)
 725                   (setq valid (if (stringp (cdr (car rules)))
 726                                   (file-name-nondirectory
 727                                    (replace-match (cdr (car rules)) t nil file))
 728                                 relname)
 729                         rules nil))
 730               (setq rules (cdr rules))))))
 731       (setq authors-checked-files-alist
 732             (cons (cons fullname valid) authors-checked-files-alist))
 733       (unless (or valid
 734                   (member file authors-ignored-files)
 735                   (authors-obsolete-file-p file)
 736                   (string-match "[*]" file)
 737                   (string-match "^[0-9.]+$" file))
 738         (setq authors-invalid-file-names
 739               (cons (format "%s:%d: unrecognized `%s' for %s"
 740                             log-file
 741                             (1+ (count-lines (point-min) pos))
 742                             file author)
 743                     authors-invalid-file-names)))
 744       valid)))
 745
 746 (defun authors-add-fixed-entries (table)
 747   "Add actions from `authors-fixed-entries' to TABLE."
 748   (dolist (entry authors-fixed-entries)
 749     (let ((author (car entry))
 750           action)
 751       (dolist (item (cdr entry))
 752         (if (symbolp item)
 753             (setq action item)
 754           (authors-add author item action table))))))
 755
 756
 757 (defun authors-obsolete-file-p (file)
 758   "Return non-nil if FILE is obsolete.
 759 FILE is considered obsolete if it matches one of the regular expressions
 760 from `authors-obsolete-files-regexps'."
 761   (let (obsolete-p
 762         (regexps authors-obsolete-files-regexps))
 763     (while (and regexps (not obsolete-p))
 764       (setq obsolete-p (string-match (car regexps) file)
 765             regexps (cdr regexps)))
 766     obsolete-p))
 767
 768
 769 (defun authors-add (author file action table)
 770   "Record that AUTHOR worked on FILE.
 771 ACTION is a keyword symbol describing what he did.  Record file,
 772 author and what he did in hash table TABLE.  See the description of
 773 `authors-scan-change-log' for the structure of the hash table."
 774   (unless (or (member file authors-ignored-files)
 775               (authors-obsolete-file-p file)
 776               (equal author ""))
 777     (let* ((value (gethash author table))
 778            (entry (assoc file value))
 779            slot)
 780       (if (null entry)
 781           (puthash author (cons (list file (cons action 1)) value) table)
 782         (if (setq slot (assoc action (cdr entry)))
 783             (setcdr slot (1+ (cdr slot)))
 784           (nconc entry (list (cons action 1))))))))
 785
 786
 787 (defun authors-canonical-author-name (author)
 788   "Return a canonicalized form of AUTHOR, an author name.
 789 If AUTHOR has an entry in `authors-aliases', use that.  Remove
 790 email addresses.  Capitalize words in the author's name, unless
 791 it is found in `authors-fixed-case'."
 792   (let* ((aliases authors-aliases)
 793          regexps realname)
 794     (while aliases
 795       (setq realname (car (car aliases))
 796             regexps (cdr (car aliases))
 797             aliases (cdr aliases))
 798       (while regexps
 799         (if (string-match (car regexps) author)
 800             (setq author realname
 801                   regexps nil
 802                   aliases nil)
 803           (setq regexps (cdr regexps))))))
 804   (when author
 805     (setq author (replace-regexp-in-string "[ \t]*[(<].*$" "" author))
 806     (setq author (replace-regexp-in-string "\`[ \t]+" "" author))
 807     (setq author (replace-regexp-in-string "[ \t]+$" "" author))
 808     (setq author (replace-regexp-in-string "[ \t]+" " " author))
 809     (unless (string-match "[-, \t]" author)
 810       (setq author ""))
 811     (or (car (member author authors-fixed-case))
 812         (capitalize author))))
 813
 814 (defun authors-scan-change-log (log-file table)
 815   "Scan change log LOG-FILE for author information.
 816
 817 For each change mentioned in the log, add an entry to hash table TABLE
 818 under the author's canonical name.
 819
 820 Keys of TABLE are author names.  Values are alists of entries (FILE
 821 \(ACTION . COUNT) ...).  FILE is one file the author worked on.  The
 822 rest of the entry is a list of keyword symbols describing what he did
 823 with the file and the number of each action:
 824
 825 :wrote          means the author wrote the file
 826 :cowrote        means he wrote the file in collaboration with others
 827 :changed        means he changed the file COUNT times."
 828
 829   (let* ((enable-local-variables :safe) ; for find-file, hence let*
 830          (enable-local-eval nil)
 831          (existing-buffer (get-file-buffer log-file))
 832          (buffer (find-file-noselect log-file))
 833          authors pos)
 834     (with-current-buffer buffer
 835       (save-restriction
 836         (widen)
 837         (goto-char (point-min))
 838         (while (re-search-forward "^[0-9]\\|^[ \t]+\\* " nil t)
 839           (beginning-of-line)
 840           (setq pos (point))
 841           (cond ((looking-at "^[0-9]+-[0-9]+-[0-9]+")
 842                  ;; Handle joint authorship of changes.
 843                  ;; This can be a bit fragile, and is not too common.
 844                  (setq authors nil)
 845                  (while (progn
 846                           (skip-chars-forward " \t+:0-9-")
 847                           (not (looking-at "\\($\\|\\*\\|\
 848 Suggested\\|Trivial\\|Version\\|Originally\\|From:\\|Patch[ \t]+[Bb]y\\)")))
 849                    (push (authors-canonical-author-name
 850                           (buffer-substring-no-properties
 851                            (point) (line-end-position))) authors)
 852                    (forward-line 1)))
 853                 ((looking-at "^[ \t]+\\*")
 854                  (let ((line (buffer-substring-no-properties
 855                               (match-end 0) (line-end-position))))
 856                    (while (and (not (string-match ":" line))
 857                                (forward-line 1)
 858                                (not (looking-at ":\\|^[ \t]*$")))
 859                      (setq line (concat line
 860                                         (buffer-substring-no-properties
 861                                          (line-beginning-position)
 862                                          (line-end-position)))))
 863                    (when (string-match ":" line)
 864                      (setq line (substring line 0 (match-beginning 0)))
 865                      (setq line (replace-regexp-in-string "[[(<{].*$" "" line))
 866                      (setq line (replace-regexp-in-string "," "" line))
 867                      (dolist (file (split-string line))
 868                        (when (setq file (authors-canonical-file-name file log-file pos (car authors)))
 869                          (dolist (author authors)
 870                            ;;(message "%s changed %s" author file)
 871                            (authors-add author file :changed table)))))
 872                    (forward-line 1)))))))
 873     (unless existing-buffer
 874       (kill-buffer buffer))))
 875
 876
 877 (defun authors-scan-el (file table)
 878   "Scan Lisp file FILE for author information.
 879 TABLE is a hash table to add author information to."
 880   (let* ((existing-buffer (get-file-buffer file))
 881          (enable-local-variables :safe) ; for find-file, hence let*
 882          (enable-local-eval nil)
 883          (buffer (find-file-noselect file)))
 884     (setq file (authors-disambiguate-file-name (expand-file-name file)))
 885     (with-current-buffer buffer
 886       (save-restriction
 887         (widen)
 888         (goto-char (point-min))
 889         (while (and (re-search-forward
 890                      "^;+[ \t]*\\(Authors?\\|Commentary\\|Code\\):[ \t]*" nil t)
 891                     (not (member (match-string 1) '("Commentary" "Code"))))
 892           (let ((continue t)
 893                 (action :wrote)
 894                 authors)
 895             (while continue
 896               ;; Some entries contain a year range in front of the
 897               ;; author's name.
 898               (skip-chars-forward "-0-9 \t")
 899               (push (authors-canonical-author-name
 900                      (buffer-substring-no-properties
 901                       (point) (line-end-position))) authors)
 902               ;; tips.texi says the continuation line should begin
 903               ;; with a tab, but often spaces are used.
 904               (setq continue
 905                     (and (zerop (forward-line 1))
 906                          (looking-at ";;;?\\(\t+ *\\|  +\\)[[:alnum:]]")
 907                          (goto-char (1- (match-end 0)))
 908                          (not (looking-at "[[:upper:]][-[:alpha:]]+:[ \t]")))))
 909             (and (> (length authors) 1)
 910                  (setq action :cowrote))
 911             (mapc (lambda (author)
 912                     (authors-add author file action table))
 913                   authors)))))
 914     (unless existing-buffer
 915       (kill-buffer buffer))))
 916
 917
 918 (defun authors-public-domain-p (file)
 919   "Return t if FILE is a file that was put in public domain."
 920   (let ((public-domain-p nil)
 921         (list authors-public-domain-files))
 922     (while (and list (not public-domain-p))
 923       (when (string-match (car list) file)
 924         (setq public-domain-p t))
 925       (setq list (cdr list)))
 926     public-domain-p))
 927
 928 (defvar authors-author-list)
 929
 930 (defun authors-add-to-author-list (author changes)
 931   "Insert information about AUTHOR's work on Emacs into `authors-author-list'.
 932 CHANGES is an alist of entries (FILE (ACTION . COUNT) ...), as produced by
 933 `authors-scan-change-log'.
 934 The element added to `authors-author-list' is (AUTHOR WROTE CO-WROTE CHANGED),
 935 where WROTE, CO-WROTE, and CHANGED are lists of the files written, co-written
 936 and changed by AUTHOR."
 937   (when author
 938     (let ((nchanged 0)
 939           wrote-list
 940           cowrote-list
 941           changed-list)
 942       (dolist (change changes)
 943         (let* ((actions (cdr change))
 944                (file (car change))
 945                (filestat (if (authors-public-domain-p file)
 946                              (concat file " (public domain)")
 947                            file)))
 948           (cond ((assq :wrote actions)
 949                  (setq wrote-list (cons filestat wrote-list)))
 950                 ((assq :cowrote actions)
 951                  (setq cowrote-list (cons filestat cowrote-list)))
 952                 (t
 953                  (setq changed-list
 954                        (cons (cons file (cdr (assq :changed actions)))
 955                              changed-list))))))
 956       (if wrote-list
 957           (setq wrote-list (sort wrote-list 'string-lessp)))
 958       (if cowrote-list
 959           (setq cowrote-list (sort cowrote-list 'string-lessp)))
 960       (when changed-list
 961         (setq changed-list (sort changed-list
 962                                  (lambda (a b)
 963                                    (if (= (cdr a) (cdr b))
 964                                        (string-lessp (car a) (car b))
 965                                      (> (cdr a) (cdr b))))))
 966         (setq nchanged (length changed-list))
 967         (setq changed-list (mapcar 'car changed-list)))
 968       (if (> (- nchanged authors-many-files) 2)
 969           (setcdr (nthcdr authors-many-files changed-list)
 970                   (list (format "and %d other files" (- nchanged authors-many-files)))))
 971       (setq authors-author-list
 972             (cons (list author wrote-list cowrote-list changed-list)
 973                   authors-author-list)))))
 974
 975 (defun authors (root)
 976   "Extract author information from change logs and Lisp source files.
 977 ROOT is the root directory under which to find the files.  If called
 978 interactively, ROOT is read from the minibuffer.
 979 Result is a buffer *Authors* containing authorship information, and a
 980 buffer *Authors Errors* containing references to unknown files."
 981   (interactive "DEmacs source directory: ")
 982   (setq root (expand-file-name root))
 983   (let ((logs (process-lines find-program root "-name" "ChangeLog*"))
 984         (table (make-hash-table :test 'equal))
 985         (buffer-name "*Authors*")
 986         authors-checked-files-alist
 987         authors-invalid-file-names)
 988     (authors-add-fixed-entries table)
 989     (unless (file-exists-p (expand-file-name "src/emacs.c" root))
 990       (unless (y-or-n-p
 991                (format "Not the root directory of Emacs: %s, continue? " root))
 992         (error "Not the root directory")))
 993     (dolist (log logs)
 994       (when (string-match "ChangeLog\\(.[0-9]+\\)?$" log)
 995         (message "Scanning %s..." log)
 996         (authors-scan-change-log log table)))
 997     (let ((els (process-lines find-program root "-name" "*.el")))
 998       (dolist (file els)
 999         (message "Scanning %s..." file)
1000         (authors-scan-el file table)))
1001     (message "Generating buffer %s..." buffer-name)
1002     (set-buffer (get-buffer-create buffer-name))
1003     (erase-buffer)
1004     (set-buffer-file-coding-system authors-coding-system)
1005     (insert
1006 "Many people have contributed code included in the Free Software
1007 Foundation's distribution of GNU Emacs.  To show our appreciation for
1008 their public spirit, we list here in alphabetical order a condensed
1009 list of their contributions.\n")
1010     (let (authors-author-list a)
1011       (maphash #'authors-add-to-author-list table)
1012       (setq authors-author-list
1013             (sort authors-author-list
1014                   (lambda (a b) (string-lessp (car a) (car b)))))
1015       (dolist (a authors-author-list)
1016         (let ((author (car a))
1017               (wrote (nth 1 a))
1018               (cowrote (nth 2 a))
1019               (changed (nth 3 a))
1020               file)
1021         (insert "\n" author ": ")
1022         (when wrote
1023           (insert "wrote")
1024           (dolist (file wrote)
1025             (if (> (+ (current-column) (length file)) 72)
1026               (insert "\n "))
1027             (insert " " file))
1028           (insert "\n"))
1029         (when cowrote
1030           (if wrote
1031               (insert "and "))
1032           (insert "co-wrote")
1033           (dolist (file cowrote)
1034             (if (> (+ (current-column) (length file)) 72)
1035               (insert "\n "))
1036             (insert " " file))
1037           (insert "\n"))
1038         (when changed
1039           (if (or wrote cowrote)
1040               (insert "and "))
1041           (insert "changed")
1042           (dolist (file changed)
1043             (if (> (+ (current-column) (length file)) 72)
1044                 (insert "\n "))
1045             (insert " " file))
1046           (insert "\n")))))
1047     (insert "\nLocal" " Variables:\ncoding: "
1048             (symbol-name authors-coding-system) "\nEnd:\n")
1049     (message "Generating buffer %s... done" buffer-name)
1050     (unless noninteractive
1051       (when authors-invalid-file-names
1052         (with-current-buffer (get-buffer-create "*Authors Errors*")
1053           (setq buffer-read-only nil)
1054           (erase-buffer)
1055           (set-buffer-file-coding-system authors-coding-system)
1056           (insert "Unrecognized file entries found:\n\n")
1057           (mapc (lambda (f) (if (not (string-match "^[A-Za-z]+$" f)) (insert f "\n")))
1058                 (sort authors-invalid-file-names 'string-lessp))
1059           (goto-char (point-min))
1060           (compilation-mode)
1061           (message "Errors were found.  See buffer %s" (buffer-name))))
1062       (pop-to-buffer buffer-name))))
1063
1064
1065 (defun batch-update-authors ()
1066   "Produce an AUTHORS file.
1067 Call this function in batch mode with two command line arguments FILE
1068 and ROOT.  FILE is the file to write, ROOT is the root directory of
1069 the Emacs source tree, from which to build the file."
1070   (unless noninteractive
1071     (error "`batch-update-authors' is to be used only with -batch"))
1072   (when (/= (length command-line-args-left) 2)
1073     (error "Call `batch-update-authors' with the name of the file to write"))
1074   (let* ((file (pop command-line-args-left))
1075          (root (pop command-line-args-left)))
1076     (authors root)
1077     (write-file file)))
1078
1079 (provide 'authors)
1080
1081 ;;; authors.el ends here