lisp/international/mule-util.el

   1 ;;; mule-util.el --- utility functions for mulitilingual environment (mule)
   2
   3 ;; Copyright (C) 1997, 1998, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   5 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   6 ;;   2005, 2006, 2007, 2008
   7 ;;   National Institute of Advanced Industrial Science and Technology (AIST)
   8 ;;   Registration Number H14PRO021
   9 ;; Copyright (C) 2003
  10 ;;   National Institute of Advanced Industrial Science and Technology (AIST)
  11 ;;   Registration Number H13PRO009
  12
  13 ;; Keywords: mule, multilingual
  14
  15 ;; This file is part of GNU Emacs.
  16
  17 ;; GNU Emacs is free software: you can redistribute it and/or modify
  18 ;; it under the terms of the GNU General Public License as published by
  19 ;; the Free Software Foundation, either version 3 of the License, or
  20 ;; (at your option) any later version.
  21
  22 ;; GNU Emacs is distributed in the hope that it will be useful,
  23 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 ;; GNU General Public License for more details.
  26
  27 ;; You should have received a copy of the GNU General Public License
  28 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  29
  30 ;;; Commentary:
  31
  32 ;;; Code:
  33
  34 ;;; String manipulations while paying attention to multibyte
  35 ;;; characters.
  36
  37 ;;;###autoload
  38 (defun string-to-sequence (string type)
  39   "Convert STRING to a sequence of TYPE which contains characters in STRING.
  40 TYPE should be `list' or `vector'."
  41 ;;;  (let ((len (length string))
  42 ;;;        (i 0)
  43 ;;;        val)
  44     (cond ((eq type 'list)
  45            ;; Applicable post-Emacs 20.2 and asymptotically ~10 times
  46            ;; faster than the code below:
  47            (append string nil))
  48 ;;;        (setq val (make-list len 0))
  49 ;;;        (let ((l val))
  50 ;;;          (while (< i len)
  51 ;;;            (setcar l (aref string i))
  52 ;;;            (setq l (cdr l) i (1+ i))))))
  53           ((eq type 'vector)
  54            ;; As above.
  55            (vconcat string))
  56 ;;;        (setq val (make-vector len 0))
  57 ;;;        (while (< i len)
  58 ;;;          (aset val i (aref string i))
  59 ;;;          (setq i (1+ i))))
  60           (t
  61            (error "Invalid type: %s" type)))
  62 ;;;    val)
  63 )
  64
  65 ;;;###autoload
  66 (make-obsolete 'string-to-sequence
  67                "use `string-to-list' or `string-to-vector'."
  68                "22.1")
  69
  70 ;;;###autoload
  71 (defsubst string-to-list (string)
  72   "Return a list of characters in STRING."
  73   (append string nil))
  74
  75 ;;;###autoload
  76 (defsubst string-to-vector (string)
  77   "Return a vector of characters in STRING."
  78   (vconcat string))
  79
  80 ;;;###autoload
  81 (defun store-substring (string idx obj)
  82   "Embed OBJ (string or character) at index IDX of STRING."
  83   (if (integerp obj)
  84       (aset string idx obj)
  85     (let ((len1 (length obj))
  86           (len2 (length string))
  87           (i 0))
  88       (while (< i len1)
  89         (aset string (+ idx i) (aref obj i))
  90         (setq i (1+ i)))))
  91   string)
  92
  93 ;;;###autoload
  94 (defun truncate-string-to-width (str end-column
  95                                      &optional start-column padding ellipsis)
  96   "Truncate string STR to end at column END-COLUMN.
  97 The optional 3rd arg START-COLUMN, if non-nil, specifies the starting
  98 column; that means to return the characters occupying columns
  99 START-COLUMN ... END-COLUMN of STR.  Both END-COLUMN and START-COLUMN
 100 are specified in terms of character display width in the current
 101 buffer; see also `char-width'.
 102
 103 The optional 4th arg PADDING, if non-nil, specifies a padding
 104 character (which should have a display width of 1) to add at the end
 105 of the result if STR doesn't reach column END-COLUMN, or if END-COLUMN
 106 comes in the middle of a character in STR.  PADDING is also added at
 107 the beginning of the result if column START-COLUMN appears in the
 108 middle of a character in STR.
 109
 110 If PADDING is nil, no padding is added in these cases, so
 111 the resulting string may be narrower than END-COLUMN.
 112
 113 If ELLIPSIS is non-nil, it should be a string which will replace the
 114 end of STR (including any padding) if it extends beyond END-COLUMN,
 115 unless the display width of STR is equal to or less than the display
 116 width of ELLIPSIS.  If it is non-nil and not a string, then ELLIPSIS
 117 defaults to \"...\"."
 118   (or start-column
 119       (setq start-column 0))
 120   (when (and ellipsis (not (stringp ellipsis)))
 121     (setq ellipsis "..."))
 122   (let ((str-len (length str))
 123         (str-width (string-width str))
 124         (ellipsis-len (if ellipsis (length ellipsis) 0))
 125         (ellipsis-width (if ellipsis (string-width ellipsis) 0))
 126         (idx 0)
 127         (column 0)
 128         (head-padding "") (tail-padding "")
 129         ch last-column last-idx from-idx)
 130     (condition-case nil
 131         (while (< column start-column)
 132           (setq ch (aref str idx)
 133                 column (+ column (char-width ch))
 134                 idx (1+ idx)))
 135       (args-out-of-range (setq idx str-len)))
 136     (if (< column start-column)
 137         (if padding (make-string end-column padding) "")
 138       (when (and padding (> column start-column))
 139         (setq head-padding (make-string (- column start-column) padding)))
 140       (setq from-idx idx)
 141       (when (>= end-column column)
 142         (if (and (< end-column str-width)
 143                  (> str-width ellipsis-width))
 144             (setq end-column (- end-column ellipsis-width))
 145           (setq ellipsis ""))
 146         (condition-case nil
 147             (while (< column end-column)
 148               (setq last-column column
 149                     last-idx idx
 150                     ch (aref str idx)
 151                     column (+ column (char-width ch))
 152                     idx (1+ idx)))
 153           (args-out-of-range (setq idx str-len)))
 154         (when (> column end-column)
 155           (setq column last-column
 156                 idx last-idx))
 157         (when (and padding (< column end-column))
 158           (setq tail-padding (make-string (- end-column column) padding))))
 159       (concat head-padding (substring str from-idx idx)
 160               tail-padding ellipsis))))
 161
 162 ;;; Test suite for truncate-string-to-width
 163 ;; (dolist (test '((("" 0) . "")
 164 ;;              (("x" 1) . "x")
 165 ;;              (("xy" 1) . "x")
 166 ;;              (("xy" 2 1) . "y")
 167 ;;              (("xy" 0) . "")
 168 ;;              (("xy" 3) . "xy")
 169 ;;              (("\e$AVP\e(B" 0) . "")
 170 ;;              (("\e$AVP\e(B" 1) . "")
 171 ;;              (("\e$AVP\e(B" 2) . "\e$AVP\e(B")
 172 ;;              (("\e$AVP\e(B" 1 nil ? ) . " ")
 173 ;;              (("\e$AVPND\e(B" 3 1 ? ) . "  ")
 174 ;;              (("x\e$AVP\e(Bx" 2) . "x")
 175 ;;              (("x\e$AVP\e(Bx" 3) . "x\e$AVP\e(B")
 176 ;;              (("x\e$AVP\e(Bx" 3) . "x\e$AVP\e(B")
 177 ;;              (("x\e$AVP\e(Bx" 4 1) . "\e$AVP\e(Bx")
 178 ;;              (("kor\e$(CGQ\e(Be\e$(C1[\e(Ban" 8 1 ? ) . "or\e$(CGQ\e(Be\e$(C1[\e(B")
 179 ;;              (("kor\e$(CGQ\e(Be\e$(C1[\e(Ban" 7 2 ? ) . "r\e$(CGQ\e(Be ")
 180 ;;              (("" 0 nil nil "...") . "")
 181 ;;              (("x" 3 nil nil "...") . "x")
 182 ;;              (("\e$AVP\e(B" 3 nil nil "...") . "\e$AVP\e(B")
 183 ;;              (("foo" 3 nil nil "...") . "foo")
 184 ;;              (("foo" 2 nil nil "...") . "fo") ;; XEmacs failure?
 185 ;;              (("foobar" 6 0 nil "...") . "foobar")
 186 ;;              (("foobarbaz" 6 nil nil "...") . "foo...")
 187 ;;              (("foobarbaz" 7 2 nil "...") . "ob...")
 188 ;;              (("foobarbaz" 9 3 nil "...") . "barbaz")
 189 ;;              (("\e$A$3\e(Bh\e$A$s\e(Be\e$A$K\e(Bl\e$A$A\e(Bl\e$A$O\e(Bo" 15 1 ?  t) . " h\e$A$s\e(Be\e$A$K\e(Bl\e$A$A\e(Bl\e$A$O\e(Bo")
 190 ;;              (("\e$A$3\e(Bh\e$A$s\e(Be\e$A$K\e(Bl\e$A$A\e(Bl\e$A$O\e(Bo" 14 1 ?  t) . " h\e$A$s\e(Be\e$A$K\e(Bl\e$A$A\e(B...")
 191 ;;              (("x" 3 nil nil "\e$(Gemk#\e(B") . "x")
 192 ;;              (("\e$AVP\e(B" 2 nil nil "\e$(Gemk#\e(B") . "\e$AVP\e(B")
 193 ;;              (("\e$AVP\e(B" 1 nil ?x "\e$(Gemk#\e(B") . "x") ;; XEmacs error
 194 ;;              (("\e$AVPND\e(B" 3 nil ?  "\e$(Gemk#\e(B") . "\e$AVP\e(B ") ;; XEmacs error
 195 ;;              (("foobarbaz" 4 nil nil  "\e$(Gemk#\e(B") . "\e$(Gemk#\e(B")
 196 ;;              (("foobarbaz" 5 nil nil  "\e$(Gemk#\e(B") . "f\e$(Gemk#\e(B")
 197 ;;              (("foobarbaz" 6 nil nil  "\e$(Gemk#\e(B") . "fo\e$(Gemk#\e(B")
 198 ;;              (("foobarbaz" 8 3 nil "\e$(Gemk#\e(B") . "b\e$(Gemk#\e(B")
 199 ;;              (("\e$A$3\e(Bh\e$A$s\e(Be\e$A$K\e(Bl\e$A$A\e(Bl\e$A$O\e(Bo" 14 4 ?x "\e$AHU1>\e$(Gk#\e(B") . "xe\e$A$KHU1>\e$(Gk#\e(B")
 200 ;;              (("\e$A$3\e(Bh\e$A$s\e(Be\e$A$K\e(Bl\e$A$A\e(Bl\e$A$O\e(Bo" 13 4 ?x "\e$AHU1>\e$(Gk#\e(B") . "xex\e$AHU1>\e$(Gk#\e(B")
 201 ;;              ))
 202 ;;   (let (ret)
 203 ;;     (condition-case e
 204 ;;      (setq ret (apply #'truncate-string-to-width (car test)))
 205 ;;       (error (setq ret e)))
 206 ;;     (unless (equal ret (cdr test))
 207 ;;       (error "%s: expected %s, got %s"
 208 ;;           (prin1-to-string (cons 'truncate-string-to-width (car test)))
 209 ;;           (prin1-to-string (cdr test))
 210 ;;           (if (consp ret)
 211 ;;               (format "error: %s: %s" (car ret)
 212 ;;                       (prin1-to-string (cdr ret)))
 213 ;;             (prin1-to-string ret))))))
 214
 215 \f
 216 ;;; Nested alist handler.  Nested alist is alist whose elements are
 217 ;;; also nested alist.
 218
 219 ;;;###autoload
 220 (defsubst nested-alist-p (obj)
 221   "Return t if OBJ is a nested alist.
 222
 223 Nested alist is a list of the form (ENTRY . BRANCHES), where ENTRY is
 224 any Lisp object, and BRANCHES is a list of cons cells of the form
 225 \(KEY-ELEMENT . NESTED-ALIST).
 226
 227 You can use a nested alist to store any Lisp object (ENTRY) for a key
 228 sequence KEYSEQ, where KEYSEQ is a sequence of KEY-ELEMENT.  KEYSEQ
 229 can be a string, a vector, or a list."
 230   (and obj (listp obj) (listp (cdr obj))))
 231
 232 ;;;###autoload
 233 (defun set-nested-alist (keyseq entry alist &optional len branches)
 234   "Set ENTRY for KEYSEQ in a nested alist ALIST.
 235 Optional 4th arg LEN non-nil means the first LEN elements in KEYSEQ
 236  is considered.
 237 Optional argument BRANCHES if non-nil is branches for a keyseq
 238 longer than KEYSEQ.
 239 See the documentation of `nested-alist-p' for more detail."
 240   (or (nested-alist-p alist)
 241       (error "Invalid argument %s" alist))
 242   (let ((islist (listp keyseq))
 243         (len (or len (length keyseq)))
 244         (i 0)
 245         key-elt slot)
 246     (while (< i len)
 247       (if (null (nested-alist-p alist))
 248           (error "Keyseq %s is too long for this nested alist" keyseq))
 249       (setq key-elt (if islist (nth i keyseq) (aref keyseq i)))
 250       (setq slot (assoc key-elt (cdr alist)))
 251       (if (null slot)
 252           (progn
 253             (setq slot (cons key-elt (list t)))
 254             (setcdr alist (cons slot (cdr alist)))))
 255       (setq alist (cdr slot))
 256       (setq i (1+ i)))
 257     (setcar alist entry)
 258     (if branches
 259         (setcdr (last alist) branches))))
 260
 261 ;;;###autoload
 262 (defun lookup-nested-alist (keyseq alist &optional len start nil-for-too-long)
 263   "Look up key sequence KEYSEQ in nested alist ALIST.  Return the definition.
 264 Optional 1st argument LEN specifies the length of KEYSEQ.
 265 Optional 2nd argument START specifies index of the starting key.
 266 The returned value is normally a nested alist of which
 267 car part is the entry for KEYSEQ.
 268 If ALIST is not deep enough for KEYSEQ, return number which is
 269  how many key elements at the front of KEYSEQ it takes
 270  to reach a leaf in ALIST.
 271 Optional 3rd argument NIL-FOR-TOO-LONG non-nil means return nil
 272  even if ALIST is not deep enough."
 273   (or (nested-alist-p alist)
 274       (error "Invalid argument %s" alist))
 275   (or len
 276       (setq len (length keyseq)))
 277   (let ((i (or start 0)))
 278     (if (catch 'lookup-nested-alist-tag
 279           (if (listp keyseq)
 280               (while (< i len)
 281                 (if (setq alist (cdr (assoc (nth i keyseq) (cdr alist))))
 282                     (setq i (1+ i))
 283                   (throw 'lookup-nested-alist-tag t))))
 284           (while (< i len)
 285             (if (setq alist (cdr (assoc (aref keyseq i) (cdr alist))))
 286                 (setq i (1+ i))
 287               (throw 'lookup-nested-alist-tag t))))
 288         ;; KEYSEQ is too long.
 289         (if nil-for-too-long nil i)
 290       alist)))
 291
 292 \f
 293 ;; Coding system related functions.
 294
 295 ;;;###autoload
 296 (defun coding-system-post-read-conversion (coding-system)
 297   "Return the value of CODING-SYSTEM's `post-read-conversion' property."
 298   (coding-system-get coding-system :post-read-conversion))
 299
 300 ;;;###autoload
 301 (defun coding-system-pre-write-conversion (coding-system)
 302   "Return the value of CODING-SYSTEM's `pre-write-conversion' property."
 303   (coding-system-get coding-system :pre-write-conversion))
 304
 305 ;;;###autoload
 306 (defun coding-system-translation-table-for-decode (coding-system)
 307   "Return the value of CODING-SYSTEM's `decode-translation-table' property."
 308   (coding-system-get coding-system :decode-translation-table))
 309
 310 ;;;###autoload
 311 (defun coding-system-translation-table-for-encode (coding-system)
 312   "Return the value of CODING-SYSTEM's `encode-translation-table' property."
 313   (coding-system-get coding-system :encode-translation-table))
 314
 315 ;;;###autoload
 316 (defmacro with-coding-priority (coding-systems &rest body)
 317   "Execute BODY like `progn' with CODING-SYSTEMS at the front of priority list.
 318 CODING-SYSTEMS is a list of coding systems.  See
 319 `set-coding-priority'.  This affects the implicit sorting of lists of
 320 coding sysems returned by operations such as `find-coding-systems-region'."
 321   (let ((current (make-symbol "current")))
 322   `(let ((,current (coding-system-priority-list)))
 323      (apply #'set-coding-system-priority ,coding-systems)
 324      (unwind-protect
 325          (progn ,@body)
 326        (apply #'set-coding-system-priority ,current)))))
 327 (put 'with-coding-priority 'lisp-indent-function 1)
 328 (put 'with-coding-priority 'edebug-form-spec t)
 329
 330 ;;;###autoload
 331 (defmacro detect-coding-with-priority (from to priority-list)
 332   "Detect a coding system of the text between FROM and TO with PRIORITY-LIST.
 333 PRIORITY-LIST is an alist of coding categories vs the corresponding
 334 coding systems ordered by priority."
 335   `(with-coding-priority (mapcar #'cdr ,priority-list)
 336      (detect-coding-region ,from ,to)))
 337 (make-obsolete 'detect-coding-with-priority
 338                "Use with-coding-priority and detect-coding-region" "23.1")
 339
 340 ;;;###autoload
 341 (defun detect-coding-with-language-environment (from to lang-env)
 342   "Detect a coding system for the text between FROM and TO with LANG-ENV.
 343 The detection takes into account the coding system priorities for the
 344 language environment LANG-ENV."
 345   (let ((coding-priority (get-language-info lang-env 'coding-priority)))
 346     (if coding-priority
 347         (with-coding-priority coding-priority
 348           (detect-coding-region from to)))))
 349
 350 (declare-function internal-char-font "fontset.c" (position &optional ch))
 351
 352 ;;;###autoload
 353 (defun char-displayable-p (char)
 354   "Return non-nil if we should be able to display CHAR.
 355 On a multi-font display, the test is only whether there is an
 356 appropriate font from the selected frame's fontset to display CHAR's
 357 charset in general.  Since fonts may be specified on a per-character
 358 basis, this may not be accurate."
 359   (cond ((< char 128)
 360          ;; ASCII characters are always displayable.
 361          t)
 362         ((not enable-multibyte-characters)
 363          ;; Maybe there's a font for it, but we can't put it in the buffer.
 364          nil)
 365         ((display-multi-font-p)
 366          ;; On a window system, a character is displayable if we have
 367          ;; a font for that character in the default face of the
 368          ;; currently selected frame.
 369          (car (internal-char-font nil char)))
 370         (t
 371          ;; On a terminal, a character is displayable if the coding
 372          ;; system for the terminal can encode it.
 373          (let ((coding (terminal-coding-system)))
 374            (if coding
 375                (let ((cs-list (coding-system-get coding :charset-list)))
 376                  (cond
 377                   ((listp cs-list)
 378                    (catch 'tag
 379                      (mapc #'(lambda (charset)
 380                                (if (encode-char char charset)
 381                                    (throw 'tag charset)))
 382                            cs-list)
 383                      nil))
 384                   ((eq cs-list 'iso-2022)
 385                    (catch 'tag2
 386                      (mapc #'(lambda (charset)
 387                                (if (and (plist-get (charset-plist charset)
 388                                                    :iso-final-char)
 389                                         (encode-char char charset))
 390                                    (throw 'tag2 charset)))
 391                            charset-list)
 392                      nil))
 393                   ((eq cs-list 'emacs-mule)
 394                    (catch 'tag3
 395                      (mapc #'(lambda (charset)
 396                                (if (and (plist-get (charset-plist charset)
 397                                                    :emacs-mule-id)
 398                                         (encode-char char charset))
 399                                    (throw 'tag3 charset)))
 400                            charset-list)
 401                      nil)))))))))
 402 \f
 403 (provide 'mule-util)
 404
 405 ;; Local Variables:
 406 ;; coding: iso-2022-7bit
 407 ;; End:
 408
 409 ;; arch-tag: 5bdb52b6-a3a5-4529-b7a0-37d01b0e570b
 410 ;;; mule-util.el ends here