lisp/dos-fns.el

   1 ;;; dos-fns.el --- MS-Dos specific functions
   2
   3 ;; Copyright (C) 1991, 1993, 1995, 1996 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: Morten Welinder <terra@diku.dk>
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Part of this code is taken from (or derived from) demacs.
  28
  29 ;;; Code:
  30
  31 ;; This overrides a trivial definition in files.el.
  32 (defun convert-standard-filename (filename)
  33   "Convert a standard file's name to something suitable for the current OS.
  34 This function's standard definition is trivial; it just returns the argument.
  35 However, on some systems, the function is redefined
  36 with a definition that really does change some file names."
  37   (if (or (not (stringp filename))
  38           ;; This catches the case where FILENAME is "x:" or "x:/" or
  39           ;; "/", thus preventing infinite recursion.
  40           (string-match "\\`\\([a-zA-Z]:\\)?[/\\]?\\'" filename))
  41       filename
  42     (let ((flen (length filename)))
  43       ;; If FILENAME has a trailing slash, remove it and recurse.
  44       (if (memq (aref filename (1- flen)) '(?/ ?\\))
  45           (concat (convert-standard-filename
  46                    (substring filename 0 (1- flen)))
  47                   "/")
  48         (let* (;; ange-ftp gets in the way for names like "/foo:bar".
  49                ;; We need to inhibit all magic file names, because
  50                ;; remote file names should never be passed through
  51                ;; this function, as they are not meant for the local
  52                ;; filesystem!
  53                (file-name-handler-alist nil)
  54                (dir
  55                 ;; If FILENAME is "x:foo", file-name-directory returns
  56                 ;; "x:/bar/baz", substituting the current working
  57                 ;; directory on drive x:.  We want to be left with "x:"
  58                 ;; instead.
  59                 (if (and (< 1 flen)
  60                          (eq (aref filename 1) ?:)
  61                          (null (string-match "[/\\]" filename)))
  62                     (substring filename 0 2)
  63                   (file-name-directory filename)))
  64                (dlen-m-1 (1- (length dir)))
  65                (string (copy-sequence (file-name-nondirectory filename)))
  66                (lastchar (aref string (1- (length string))))
  67                i firstdot)
  68           (cond
  69            ((msdos-long-file-names)
  70             ;; Replace characters that are invalid even on Windows.
  71             (while (setq i (string-match "[?*:<>|\"\000-\037]" string))
  72               (aset string i ?!)))
  73            ((not (member string '("" "." "..")))
  74             ;; Change a leading period to a leading underscore.
  75             (if (= (aref string 0) ?.)
  76                 (aset string 0 ?_))
  77             ;; If the name is longer than 8 chars, and doesn't have a
  78             ;; period, and we have a dash or underscore that isn't too
  79             ;; close to the beginning, change that to a period.  This
  80             ;; is so we could salvage more characters of the original
  81             ;; name by pushing them into the extension.
  82             (if (and (not (string-match "\\." string))
  83                      (> (length string) 8)
  84                      ;; We don't gain anything if we put the period closer
  85                      ;; than 5 chars from the beginning (5 + 3 = 8).
  86                      (setq i (string-match "[-_]" string 5)))
  87                 (aset string i ?\.))
  88             ;; Get rid of invalid characters.
  89             (while (setq i (string-match
  90                             "[^-a-zA-Z0-9_.%~^$!#&{}@`'()\200-\376]"
  91                             string))
  92               (aset string i ?_))
  93             ;; If we don't have a period in the first 8 chars, insert one.
  94             ;; This enables to have 3 more characters from the original
  95             ;; name in the extension.
  96             (if (> (or (string-match "\\." string) (length string))
  97                    8)
  98                 (setq string
  99                       (concat (substring string 0 8)
 100                               "."
 101                               (substring string 8))))
 102             (setq firstdot (or (string-match "\\." string)
 103                                (1- (length string))))
 104             ;; Truncate to 3 chars after the first period.
 105             (if (> (length string) (+ firstdot 4))
 106                 (setq string (substring string 0 (+ firstdot 4))))
 107             ;; Change all periods except the first one into underscores.
 108             ;; (DOS doesn't allow more than one period.)
 109             (while (string-match "\\." string (1+ firstdot))
 110               (setq i (string-match "\\." string (1+ firstdot)))
 111               (aset string i ?_))
 112             ;; If the last character of the original filename was `~' or `#',
 113             ;; make sure the munged name ends with it also.  This is so that
 114             ;; backup and auto-save files retain their telltale form.
 115             (if (memq lastchar '(?~ ?#))
 116                 (aset string (1- (length string)) lastchar))))
 117           (concat (if (and (stringp dir)
 118                            (memq (aref dir dlen-m-1) '(?/ ?\\)))
 119                       (concat (convert-standard-filename
 120                                (substring dir 0 dlen-m-1))
 121                               "/")
 122                     (convert-standard-filename dir))
 123                   string))))))
 124
 125 (defun dos-8+3-filename (filename)
 126   "Truncate FILENAME to DOS 8+3 limits."
 127   (if (or (not (stringp filename))
 128           (< (length filename) 5))      ; too short to give any trouble
 129       filename
 130     (let ((flen (length filename)))
 131       ;; If FILENAME has a trailing slash, remove it and recurse.
 132       (if (memq (aref filename (1- flen)) '(?/ ?\\))
 133           (concat (dos-8+3-filename (substring filename 0 (1- flen)))
 134                   "/")
 135         (let* (;; ange-ftp gets in the way for names like "/foo:bar".
 136                ;; We need to inhibit all magic file names, because
 137                ;; remote file names should never be passed through
 138                ;; this function, as they are not meant for the local
 139                ;; filesystem!
 140                (file-name-handler-alist nil)
 141                (dir
 142                 ;; If FILENAME is "x:foo", file-name-directory returns
 143                 ;; "x:/bar/baz", substituting the current working
 144                 ;; directory on drive x:.  We want to be left with "x:"
 145                 ;; instead.
 146                 (if (and (< 1 flen)
 147                          (eq (aref filename 1) ?:)
 148                          (null (string-match "[/\\]" filename)))
 149                     (substring filename 0 2)
 150                   (file-name-directory filename)))
 151                (dlen-m-1 (1- (length dir)))
 152                (string (copy-sequence (file-name-nondirectory filename)))
 153                (strlen (length string))
 154                (lastchar (aref string (1- strlen)))
 155                i firstdot)
 156           (setq firstdot (string-match "\\." string))
 157           (cond
 158            (firstdot
 159             ;; Truncate the extension to 3 characters.
 160             (if (> strlen (+ firstdot 4))
 161                 (setq string (substring string 0 (+ firstdot 4))))
 162             ;; Truncate the basename to 8 characters.
 163             (if (> firstdot 8)
 164                 (setq string (concat (substring string 0 8)
 165                                      "."
 166                                      (substring string (1+ firstdot))))))
 167            ((> strlen 8)
 168             ;; No dot; truncate file name to 8 characters.
 169             (setq string (substring string 0 8))))
 170           ;; If the last character of the original filename was `~',
 171           ;; make sure the munged name ends with it also.  This is so
 172           ;; a backup file retains its final `~'.
 173           (if (equal lastchar ?~)
 174               (aset string (1- (length string)) lastchar))
 175           (concat (if (and (stringp dir)
 176                            (memq (aref dir dlen-m-1) '(?/ ?\\)))
 177                       (concat (dos-8+3-filename (substring dir 0 dlen-m-1))
 178                               "/")
 179                     ;; Recurse to truncate the leading directories.
 180                     (dos-8+3-filename dir))
 181                   string))))))
 182
 183 ;; Make sure auto-save file names don't contain characters invalid for
 184 ;; the underlying filesystem.  This is particularly annoying with
 185 ;; `compose-mail's *mail* buffers: `*' is not allowed in file names on
 186 ;; DOS/Windows, so Emacs bitches on you each time it tries to autosave
 187 ;; the message being composed.
 188 (fset 'original-make-auto-save-file-name
 189       (symbol-function 'make-auto-save-file-name))
 190
 191 (defun make-auto-save-file-name ()
 192   "Return file name to use for auto-saves of current buffer.
 193 Does not consider `auto-save-visited-file-name' as that variable is checked
 194 before calling this function.  You can redefine this for customization.
 195 See also `auto-save-file-name-p'."
 196   (let ((filename (original-make-auto-save-file-name)))
 197     ;; Don't modify remote (ange-ftp) filenames
 198     (if (string-match "^/\\w+@[-A-Za-z0-9._]+:" filename)
 199         filename
 200       (convert-standard-filename filename))))
 201
 202 ;; See dos-vars.el for defcustom.
 203 (defvar msdos-shells)
 204
 205 ;;; Override setting chosen at startup.
 206 (defun set-default-process-coding-system ()
 207   (setq default-process-coding-system
 208         (if default-enable-multibyte-characters
 209             '(undecided-dos . undecided-dos)
 210           '(raw-text-dos . raw-text-dos))))
 211
 212 (add-hook 'before-init-hook 'set-default-process-coding-system)
 213
 214 (defvar register-name-alist
 215   '((ax . 0) (bx . 1) (cx . 2) (dx . 3) (si . 4) (di . 5)
 216     (cflag . 6) (flags . 7)
 217     (al . (0 . 0)) (bl . (1 . 0)) (cl . (2 . 0)) (dl . (3 . 0))
 218     (ah . (0 . 1)) (bh . (1 . 1)) (ch . (2 . 1)) (dh . (3 . 1))))
 219
 220 (defun make-register ()
 221   (make-vector 8 0))
 222
 223 (defun register-value (regs name)
 224   (let ((where (cdr (assoc name register-name-alist))))
 225     (cond ((consp where)
 226            (let ((tem (aref regs (car where))))
 227              (if (zerop (cdr where))
 228                  (% tem 256)
 229                (/ tem 256))))
 230           ((numberp where)
 231            (aref regs where))
 232           (t nil))))
 233
 234 (defun set-register-value (regs name value)
 235   (and (numberp value)
 236        (>= value 0)
 237        (let ((where (cdr (assoc name register-name-alist))))
 238          (cond ((consp where)
 239                 (let ((tem (aref regs (car where)))
 240                       (value (logand value 255)))
 241                   (aset regs
 242                         (car where)
 243                         (if (zerop (cdr where))
 244                             (logior (logand tem 65280) value)
 245                           (logior (logand tem 255) (lsh value 8))))))
 246                ((numberp where)
 247                 (aset regs where (logand value 65535))))))
 248   regs)
 249
 250 (defsubst intdos (regs)
 251   (int86 33 regs))
 252
 253 ;; Backward compatibility for obsolescent functions which
 254 ;; set screen size.
 255
 256 (defun mode25 ()
 257   "Changes the number of screen rows to 25."
 258   (interactive)
 259   (set-frame-size (selected-frame) 80 25))
 260
 261 (defun mode4350 ()
 262   "Changes the number of rows to 43 or 50.
 263 Emacs always tries to set the screen height to 50 rows first.
 264 If this fails, it will try to set it to 43 rows, on the assumption
 265 that your video hardware might not support 50-line mode."
 266   (interactive)
 267   (set-frame-size (selected-frame) 80 50)
 268   (if (eq (frame-height (selected-frame)) 50)
 269       nil  ; the original built-in function returned nil
 270     (set-frame-size (selected-frame) 80 43)))
 271
 272 (provide 'dos-fns)
 273
 274 ;;; dos-fns.el ends here