lisp/emacs-lisp/lisp-mnt.el

   1 ;;; lisp-mnt.el --- minor mode for Emacs Lisp maintainers
   2
   3 ;; Copyright (C) 1992, 1994, 1997, 2000 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Maintainer: Eric S. Raymond <esr@snark.thyrsus.com>
   7 ;; Created: 14 Jul 1992
   8 ;; Keywords: docs
   9 ;; X-Bogus-Bureaucratic-Cruft: Gruad will get you if you don't watch out!
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  25 ;; the Free Software Foundation,  Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This minor mode adds some services to Emacs-Lisp editing mode.
  31 ;;
  32 ;; First, it knows about the header conventions for library packages.
  33 ;; One entry point supports generating synopses from a library directory.
  34 ;; Another can be used to check for missing headers in library files.
  35 ;;
  36 ;; Another entry point automatically addresses bug mail to a package's
  37 ;; maintainer or author.
  38
  39 ;; This file can be loaded by your lisp-mode-hook.  Have it (require 'lisp-mnt)
  40
  41 ;; This file is an example of the header conventions.  Note the following
  42 ;; features:
  43 ;;
  44 ;;    * Header line --- makes it possible to extract a one-line summary of
  45 ;; the package's uses automatically for use in library synopses, KWIC
  46 ;; indexes and the like.
  47 ;;
  48 ;;    Format is three semicolons, followed by the filename, followed by
  49 ;; three dashes, followed by the summary.  All fields space-separated.
  50 ;;
  51 ;;    * Author line --- contains the name and net address of at least
  52 ;; the principal author.
  53 ;;
  54 ;;    If there are multiple authors, they should be listed on continuation
  55 ;; lines led by ;;<TAB>, like this:
  56 ;;
  57 ;; ;; Author: Ashwin Ram <Ram-Ashwin@cs.yale.edu>
  58 ;; ;;   Dave Sill <de5@ornl.gov>
  59 ;; ;;   David Lawrence <tale@pawl.rpi.edu>
  60 ;; ;;   Noah Friedman <friedman@ai.mit.edu>
  61 ;; ;;   Joe Wells <jbw@maverick.uswest.com>
  62 ;; ;;   Dave Brennan <brennan@hal.com>
  63 ;; ;;   Eric Raymond <esr@snark.thyrsus.com>
  64 ;;
  65 ;; This field may have some special values; notably "FSF", meaning
  66 ;; "Free Software Foundation".
  67 ;;
  68 ;;    * Maintainer line --- should be a single name/address as in the Author
  69 ;; line, or an address only, or the string "FSF".  If there is no maintainer
  70 ;; line, the person(s) in the Author field are presumed to be it.  The example
  71 ;; in this file is mildly bogus because the maintainer line is redundant.
  72 ;;    The idea behind these two fields is to be able to write a Lisp function
  73 ;; that does "send mail to the author" without having to mine the name out by
  74 ;; hand. Please be careful about surrounding the network address with <> if
  75 ;; there's also a name in the field.
  76 ;;
  77 ;;    * Created line --- optional, gives the original creation date of the
  78 ;; file.  For historical interest, basically.
  79 ;;
  80 ;;    * Version line --- intended to give the reader a clue if they're looking
  81 ;; at a different version of the file than the one they're accustomed to.  This
  82 ;; may be an RCS or SCCS header.
  83 ;;
  84 ;;    * Adapted-By line --- this is for FSF's internal use.  The person named
  85 ;; in this field was the one responsible for installing and adapting the
  86 ;; package for the distribution.  (This file doesn't have one because the
  87 ;; author *is* one of the maintainers.)
  88 ;;
  89 ;;    * Keywords line --- used by the finder code (now under construction)
  90 ;; for finding Emacs Lisp code related to a topic.
  91 ;;
  92 ;;    * X-Bogus-Bureaucratic-Cruft line --- this is a joke and an example
  93 ;; of a comment header.  Headers starting with `X-' should never be used
  94 ;; for any real purpose; this is the way to safely add random headers
  95 ;; without invoking the wrath of any program.
  96 ;;
  97 ;;    * Commentary line --- enables Lisp code to find the developer's and
  98 ;; maintainers' explanations of the package internals.
  99 ;;
 100 ;;    * Change log line --- optional, exists to terminate the commentary
 101 ;; section and start a change-log part, if one exists.
 102 ;;
 103 ;;    * Code line --- exists so Lisp can know where commentary and/or
 104 ;; change-log sections end.
 105 ;;
 106 ;;    * Footer line --- marks end-of-file so it can be distinguished from
 107 ;; an expanded formfeed or the results of truncation.
 108
 109 ;;; Change Log:
 110
 111 ;; Tue Jul 14 23:44:17 1992     ESR
 112 ;;      * Created.
 113
 114 ;;; Code:
 115
 116 ;;; Variables:
 117
 118 (defgroup lisp-mnt nil
 119   "Minor mode for Emacs Lisp maintainers."
 120   :prefix "lm-"
 121   :group 'maint)
 122
 123 (defcustom lm-header-prefix "^;;*[ \t]+\\(@\(#\)\\)?[ \t]*\\([\$]\\)?"
 124   "Prefix that is ignored before the tag.
 125 For example, you can write the 1st line synopsis string and headers like this
 126 in your Lisp package:
 127
 128    ;; @(#) package.el -- pacakge description
 129    ;;
 130    ;; @(#) $Maintainer:   Person Foo Bar $
 131
 132 The @(#) construct is used by unix what(1) and
 133 then $identifier: doc string $ is used by GNU ident(1)"
 134   :type 'regexp
 135   :group 'lisp-mnt)
 136
 137 (defcustom lm-comment-column 16
 138   "Column used for placing formatted output."
 139   :type 'integer
 140   :group 'lisp-mnt)
 141
 142 (defcustom lm-commentary-header "Commentary\\|Documentation"
 143   "Regexp which matches start of documentation section."
 144   :type 'regexp
 145   :group 'lisp-mnt)
 146
 147 (defcustom lm-history-header "Change Log\\|History"
 148   "Regexp which matches the start of code log section."
 149   :type 'regexp
 150   :group 'lisp-mnt)
 151
 152 ;;; Functions:
 153
 154 ;; These functions all parse the headers of the current buffer
 155
 156 (defun lm-get-header-re (header &optional mode)
 157   "Return regexp for matching HEADER.
 158 If called with optional MODE and with value `section',
 159 return section regexp instead."
 160   (cond ((eq mode 'section)
 161          (concat "^;;;;* " header ":[ \t]*$"))
 162         (t
 163          (concat lm-header-prefix header ":[ \t]*"))))
 164
 165 (defun lm-get-package-name ()
 166   "Return package name by looking at the first line."
 167   (save-excursion
 168     (goto-char (point-min))
 169     (if (and (looking-at (concat lm-header-prefix))
 170              (progn (goto-char (match-end 0))
 171                     (looking-at "\\([^\t ]+\\)")
 172                     (match-end 1)))
 173         (match-string-no-properties 1))))
 174
 175 (defun lm-section-mark (header &optional after)
 176   "Return the buffer location of a given section start marker.
 177 The HEADER is the section mark string to search for.
 178 If AFTER is non-nil, return the location of the next line."
 179   (save-excursion
 180     (let ((case-fold-search t))
 181       (goto-char (point-min))
 182       (if (re-search-forward (lm-get-header-re header 'section) nil t)
 183           (progn
 184             (beginning-of-line)
 185             (if after (forward-line 1))
 186             (point))))))
 187
 188 (defsubst lm-code-mark ()
 189   "Return the buffer location of the `Code' start marker."
 190   (lm-section-mark "Code"))
 191
 192 (defsubst lm-commentary-mark ()
 193   "Return the buffer location of the `Commentary' start marker."
 194   (lm-section-mark lm-commentary-header))
 195
 196 (defsubst lm-history-mark ()
 197   "Return the buffer location of the `History' start marker."
 198   (lm-section-mark lm-history-header))
 199
 200 (defun lm-header (header)
 201   "Return the contents of the header named HEADER."
 202   (goto-char (point-min))
 203   (let ((case-fold-search t))
 204     (if (and (re-search-forward (lm-get-header-re header) (lm-code-mark) t)
 205              ;;   RCS ident likes format "$identifier: data$"
 206              (looking-at "\\([^$\n]+\\)")
 207              (match-end 1))
 208         (match-string-no-properties 1))))
 209
 210 (defun lm-header-multiline (header)
 211   "Return the contents of the header named HEADER, with continuation lines.
 212 The returned value is a list of strings, one per line."
 213   (save-excursion
 214     (goto-char (point-min))
 215     (let ((res (lm-header header)))
 216       (when res
 217         (setq res (list res))
 218         (forward-line 1)
 219         (while (and (looking-at (concat lm-header-prefix "[\t ]+"))
 220                     (progn
 221                       (goto-char (match-end 0))
 222                       (looking-at "\\(.*\\)"))
 223                     (match-end 1))
 224           (setq res (cons (match-string-no-properties 1) res))
 225           (forward-line 1)))
 226       res)))
 227
 228 ;; These give us smart access to the header fields and commentary
 229
 230 (defmacro lm-with-file (file &rest body)
 231   (let ((filesym (make-symbol "file")))
 232     `(save-excursion
 233        (let ((,filesym ,file))
 234          (if ,filesym (set-buffer (find-file-noselect ,filesym)))
 235          (prog1 (progn ,@body)
 236            (if (and ,filesym (not (get-buffer-window (current-buffer) t)))
 237                (kill-buffer (current-buffer))))))))
 238 (put 'lm-with-file 'lisp-indent-function 1)
 239 (put 'lm-with-file 'edebug-form-spec t)
 240
 241 (defun lm-summary (&optional file)
 242   "Return the one-line summary of file FILE, or current buffer if FILE is nil."
 243   (lm-with-file file
 244     (goto-char (point-min))
 245     (if (and (looking-at lm-header-prefix)
 246              (progn (goto-char (match-end 0))
 247                     (looking-at "[^ ]+[ \t]+--+[ \t]+\\(.*\\)")))
 248         (let ((summary (match-string-no-properties 1)))
 249           ;; Strip off -*- specifications.
 250           (if (string-match "[ \t]*-\\*-.*-\\*-" summary)
 251               (substring summary 0 (match-beginning 0))
 252             summary)))))
 253
 254 (defun lm-crack-address (x)
 255   "Split up an email address X into full name and real email address.
 256 The value is a cons of the form (FULLNAME . ADDRESS)."
 257   (cond ((string-match "\\(.+\\) [(<]\\(\\S-+@\\S-+\\)[>)]" x)
 258          (cons (match-string 1 x)
 259                (match-string 2 x)))
 260         ((string-match "\\(\\S-+@\\S-+\\) [(<]\\(.*\\)[>)]" x)
 261          (cons (match-string 2 x)
 262                (match-string 1 x)))
 263         ((string-match "\\S-+@\\S-+" x)
 264          (cons nil x))
 265         (t
 266          (cons x nil))))
 267
 268 (defun lm-authors (&optional file)
 269   "Return the author list of file FILE, or current buffer if FILE is nil.
 270 Each element of the list is a cons; the car is the full name,
 271 the cdr is an email address."
 272   (lm-with-file file
 273     (let ((authorlist (lm-header-multiline "author")))
 274       (mapcar 'lm-crack-address authorlist))))
 275
 276 (defun lm-maintainer (&optional file)
 277   "Return the maintainer of file FILE, or current buffer if FILE is nil.
 278 The return value has the form (NAME . ADDRESS)."
 279   (lm-with-file file
 280     (let ((maint (lm-header "maintainer")))
 281       (if maint
 282           (lm-crack-address maint)
 283         (car (lm-authors))))))
 284
 285 (defun lm-creation-date (&optional file)
 286   "Return the created date given in file FILE, or current buffer if FILE is nil."
 287   (lm-with-file file
 288     (lm-header "created")))
 289
 290 (defun lm-last-modified-date (&optional file)
 291   "Return the modify-date given in file FILE, or current buffer if FILE is nil."
 292   (lm-with-file file
 293     (if (progn
 294           (goto-char (point-min))
 295           (re-search-forward
 296            "\\$[I]d: [^ ]+ [^ ]+ \\([^/]+\\)/\\([^/]+\\)/\\([^ ]+\\) "
 297            (lm-code-mark) t))
 298         (format "%s %s %s"
 299                 (match-string 3)
 300                 (nth (string-to-int
 301                       (match-string 2))
 302                      '("" "Jan" "Feb" "Mar" "Apr" "May" "Jun"
 303                        "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"))
 304                 (match-string 1)))))
 305
 306 (defun lm-version (&optional file)
 307   "Return the version listed in file FILE, or current buffer if FILE is nil.
 308 This can be found in an RCS or SCCS header."
 309   (lm-with-file file
 310     (or (lm-header "version")
 311         (let ((header-max (lm-code-mark)))
 312           (goto-char (point-min))
 313           (cond
 314            ;; Look for an RCS header
 315            ((re-search-forward "\\$[I]d: [^ ]+ \\([^ ]+\\) " header-max t)
 316             (match-string-no-properties 1))
 317            ((re-search-forward "\\$Revision: +\\([^ ]+\\) " header-max t)
 318             (match-string-no-properties 1))
 319            ;; Look for an SCCS header
 320            ((re-search-forward
 321              (concat
 322               (regexp-quote "@(#)")
 323               (regexp-quote (file-name-nondirectory (buffer-file-name)))
 324               "\t\\([012345679.]*\\)")
 325              header-max t)
 326             (match-string-no-properties 1)))))))
 327
 328 (defun lm-keywords (&optional file)
 329   "Return the keywords given in file FILE, or current buffer if FILE is nil."
 330   (lm-with-file file
 331     (let ((keywords (lm-header "keywords")))
 332       (and keywords (downcase keywords)))))
 333
 334 (defun lm-adapted-by (&optional file)
 335   "Return the adapted-by names in file FILE, or current buffer if FILE is nil.
 336 This is the name of the person who cleaned up this package for
 337 distribution."
 338   (lm-with-file file
 339     (lm-header "adapted-by")))
 340
 341 (defun lm-commentary (&optional file)
 342   "Return the commentary in file FILE, or current buffer if FILE is nil.
 343 The value is returned as a string.  In the file, the commentary starts
 344 with the tag `Commentary' or `Documentation' and ends with one of the
 345 tags `Code', `Change Log' or `History'."
 346   (lm-with-file file
 347     (let ((commentary (lm-commentary-mark))
 348           (change-log (lm-history-mark))
 349           (code (lm-code-mark)))
 350       (cond
 351        ((and commentary change-log)
 352         (buffer-substring-no-properties commentary change-log))
 353        ((and commentary code)
 354         (buffer-substring-no-properties commentary code))))))
 355
 356 ;;; Verification and synopses
 357
 358 (defun lm-insert-at-column (col &rest strings)
 359   "Insert, at column COL, list of STRINGS."
 360   (if (> (current-column) col) (insert "\n"))
 361   (move-to-column col t)
 362   (apply 'insert strings))
 363
 364 (defun lm-verify (&optional file showok verb)
 365   "Check that the current buffer (or FILE if given) is in proper format.
 366 If FILE is a directory, recurse on its files and generate a report in
 367 a temporary buffer."
 368   (interactive)
 369   (let* ((verb (or verb (interactive-p)))
 370          (ret (and verb "Ok."))
 371          name)
 372     (if (and file (file-directory-p file))
 373         (setq ret
 374               (with-temp-buffer
 375                 (mapcar
 376                  (lambda (f)
 377                    (if (string-match ".*\\.el\\'" f)
 378                        (let ((status (lm-verify f)))
 379                          (insert f ":")
 380                          (if status
 381                              (lm-insert-at-column lm-comment-column status
 382                                                   "\n")
 383                            (if showok
 384                                (lm-insert-at-column lm-comment-column
 385                                                     "OK\n"))))))
 386                  (directory-files file))))
 387       (lm-with-file file
 388         (setq name (lm-get-package-name))
 389         (setq ret
 390               (cond
 391                ((null name)
 392                 "Can't find a package NAME")
 393                ((not (lm-authors))
 394                 "Author: tag missing.")
 395                ((not (lm-maintainer))
 396                 "Maintainer: tag missing.")
 397                ((not (lm-summary))
 398                 "Can't find a one-line 'Summary' description")
 399                ((not (lm-keywords))
 400                 "Keywords: tag missing.")
 401                ((not (lm-commentary-mark))
 402                 "Can't find a 'Commentary' section marker.")
 403                ((not (lm-history-mark))
 404                 "Can't find a 'History' section marker.")
 405                ((not (lm-code-mark))
 406                 "Can't find a 'Code' section marker")
 407                ((progn
 408                   (goto-char (point-max))
 409                   (not
 410                    (re-search-backward
 411                     (concat "^;;;[ \t]+" name "[ \t]+ends here[ \t]*$"
 412                             "\\|^;;;[ \t]+ End of file[ \t]+" name)
 413                     nil t)))
 414                 (format "Can't find a footer line for [%s]" name))
 415                (t
 416                 ret)))))
 417     (if verb
 418         (message ret))
 419     ret))
 420
 421 (defun lm-synopsis (&optional file showall)
 422   "Generate a synopsis listing for the buffer or the given FILE if given.
 423 If FILE is a directory, recurse on its files and generate a report in
 424 a temporary buffer.  If SHOWALL is non-nil, also generate a line for files
 425 which do not include a recognizable synopsis."
 426   (interactive
 427    (list
 428     (read-file-name "Synopsis for (file or dir): ")))
 429
 430   (if (and file (file-directory-p file))
 431       (with-temp-buffer
 432         (mapcar
 433          (lambda (f)
 434            (if (string-match "\\.el\\'" f)
 435                (let ((syn (lm-synopsis f)))
 436                  (if syn
 437                      (progn
 438                        (insert f ":")
 439                        (lm-insert-at-column lm-comment-column syn "\n"))
 440                    (when showall
 441                      (insert f ":")
 442                      (lm-insert-at-column lm-comment-column "NA\n"))))))
 443          (directory-files file)))
 444     (save-excursion
 445       (if file
 446           (find-file file))
 447       (prog1
 448           (lm-summary)
 449         (if file
 450             (kill-buffer (current-buffer)))))))
 451
 452 (eval-when-compile (defvar report-emacs-bug-address))
 453
 454 (defun lm-report-bug (topic)
 455   "Report a bug in the package currently being visited to its maintainer.
 456 Prompts for bug subject TOPIC.  Leaves you in a mail buffer."
 457   (interactive "sBug Subject: ")
 458   (require 'emacsbug)
 459   (let ((package (lm-get-package-name))
 460         (addr (lm-maintainer))
 461         (version (lm-version)))
 462     (compose-mail (if addr
 463                       (concat (car addr) " <" (cdr addr) ">")
 464                     report-emacs-bug-address)
 465                   topic)
 466     (goto-char (point-max))
 467     (insert "\nIn " package)
 468     (if version
 469         (insert " version " version))
 470     (newline 2)
 471     (message
 472      (substitute-command-keys "Type \\[mail-send] to send bug report."))))
 473
 474 (provide 'lisp-mnt)
 475
 476 ;;; lisp-mnt.el ends here
 477