lisp/emacs-lisp/disass.el

   1 ;;; disass.el --- disassembler for compiled Emacs Lisp code
   2
   3 ;; Copyright (C) 1986, 1991, 2002-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Doug Cutting <doug@csli.stanford.edu>
   6 ;;      Jamie Zawinski <jwz@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Keywords: internal
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; The single entry point, `disassemble', disassembles a code object generated
  28 ;; by the Emacs Lisp byte-compiler.  This doesn't invert the compilation
  29 ;; operation, not by a long shot, but it's useful for debugging.
  30
  31 ;;
  32 ;; Original version by Doug Cutting (doug@csli.stanford.edu)
  33 ;; Substantially modified by Jamie Zawinski <jwz@lucid.com> for
  34 ;; the new lapcode-based byte compiler.
  35
  36 ;;; Code:
  37
  38 ;;; The variable byte-code-vector is defined by the new bytecomp.el.
  39 ;;; The function byte-decompile-lapcode is defined in byte-opt.el.
  40 ;;; Since we don't use byte-decompile-lapcode, let's try not loading byte-opt.
  41 (require 'byte-compile "bytecomp")
  42
  43 (defvar disassemble-column-1-indent 8 "*")
  44 (defvar disassemble-column-2-indent 10 "*")
  45
  46 (defvar disassemble-recursive-indent 3 "*")
  47
  48 ;;;###autoload
  49 (defun disassemble (object &optional buffer indent interactive-p)
  50   "Print disassembled code for OBJECT in (optional) BUFFER.
  51 OBJECT can be a symbol defined as a function, or a function itself
  52 \(a lambda expression or a compiled-function object).
  53 If OBJECT is not already compiled, we compile it, but do not
  54 redefine OBJECT if it is a symbol."
  55   (interactive (list (intern (completing-read "Disassemble function: "
  56                                               obarray 'fboundp t))
  57                      nil 0 t))
  58   (if (and (consp object) (not (eq (car object) 'lambda)))
  59       (setq object (list 'lambda () object)))
  60   (or indent (setq indent 0))           ;Default indent to zero
  61   (save-excursion
  62     (if (or interactive-p (null buffer))
  63         (with-output-to-temp-buffer "*Disassemble*"
  64           (set-buffer "*Disassemble*")
  65           (disassemble-internal object indent (not interactive-p)))
  66       (set-buffer buffer)
  67       (disassemble-internal object indent nil)))
  68   nil)
  69
  70
  71 (defun disassemble-internal (obj indent interactive-p)
  72   (let ((macro 'nil)
  73         (name 'nil)
  74         (doc 'nil)
  75         (lexical-binding nil)
  76         args)
  77     (while (symbolp obj)
  78       (setq name obj
  79             obj (symbol-function obj)))
  80     (if (subrp obj)
  81         (error "Can't disassemble #<subr %s>" name))
  82     (when (and (listp obj) (eq (car obj) 'autoload))
  83       (load (nth 1 obj))
  84       (setq obj (symbol-function name)))
  85     (if (eq (car-safe obj) 'macro)      ;handle macros
  86         (setq macro t
  87               obj (cdr obj)))
  88     (when (and (listp obj) (eq (car obj) 'closure))
  89       (error "Don't know how to compile an interpreted closure"))
  90     (if (and (listp obj) (eq (car obj) 'byte-code))
  91         (setq obj (list 'lambda nil obj)))
  92     (if (and (listp obj) (not (eq (car obj) 'lambda)))
  93         (error "not a function"))
  94     (if (consp obj)
  95         (if (assq 'byte-code obj)
  96             nil
  97           (if interactive-p (message (if name
  98                                          "Compiling %s's definition..."
  99                                        "Compiling definition...")
 100                                      name))
 101           (setq obj (byte-compile obj))
 102           (if interactive-p (message "Done compiling.  Disassembling..."))))
 103     (cond ((consp obj)
 104            (setq obj (cdr obj))         ;throw lambda away
 105            (setq args (car obj))        ;save arg list
 106            (setq obj (cdr obj)))
 107           ((byte-code-function-p obj)
 108            (setq args (aref obj 0)))
 109           (t (error "Compilation failed")))
 110     (if (zerop indent) ; not a nested function
 111         (progn
 112           (indent-to indent)
 113           (insert (format "byte code%s%s%s:\n"
 114                           (if (or macro name) " for" "")
 115                           (if macro " macro" "")
 116                           (if name (format " %s" name) "")))))
 117     (let ((doc (if (consp obj)
 118                    (and (stringp (car obj)) (car obj))
 119                  ;; Use documentation to get lazy-loaded doc string
 120                  (documentation obj t))))
 121       (if (and doc (stringp doc))
 122           (progn (and (consp obj) (setq obj (cdr obj)))
 123                  (indent-to indent)
 124                  (princ "  doc:  " (current-buffer))
 125                  (if (string-match "\n" doc)
 126                      (setq doc (concat (substring doc 0 (match-beginning 0))
 127                                        " ...")))
 128                  (insert doc "\n"))))
 129     (indent-to indent)
 130     (insert "  args: ")
 131     (prin1 args (current-buffer))
 132     (insert "\n")
 133     (let ((interactive (cond ((consp obj)
 134                               (assq 'interactive obj))
 135                              ((> (length obj) 5)
 136                               (list 'interactive (aref obj 5))))))
 137       (if interactive
 138           (progn
 139             (setq interactive (nth 1 interactive))
 140             (if (eq (car-safe (car-safe obj)) 'interactive)
 141                 (setq obj (cdr obj)))
 142             (indent-to indent)
 143             (insert " interactive: ")
 144             (if (eq (car-safe interactive) 'byte-code)
 145                 (progn
 146                   (insert "\n")
 147                   (disassemble-1 interactive
 148                                  (+ indent disassemble-recursive-indent)))
 149               (let ((print-escape-newlines t))
 150                 (prin1 interactive (current-buffer))))
 151             (insert "\n"))))
 152     (cond ((and (consp obj) (assq 'byte-code obj))
 153            (disassemble-1 (assq 'byte-code obj) indent))
 154           ((byte-code-function-p obj)
 155            (disassemble-1 obj indent))
 156           (t
 157            (insert "Uncompiled body:  ")
 158            (let ((print-escape-newlines t))
 159              (prin1 (if (cdr obj) (cons 'progn obj) (car obj))
 160                     (current-buffer))))))
 161   (if interactive-p
 162       (message "")))
 163
 164
 165 (defun disassemble-1 (obj indent)
 166   "Prints the byte-code call OBJ in the current buffer.
 167 OBJ should be a call to BYTE-CODE generated by the byte compiler."
 168   (let (bytes constvec)
 169     (if (consp obj)
 170         (setq bytes (car (cdr obj))             ;the byte code
 171               constvec (car (cdr (cdr obj))))   ;constant vector
 172       ;; If it is lazy-loaded, load it now
 173       (fetch-bytecode obj)
 174       (setq bytes (aref obj 1)
 175             constvec (aref obj 2)))
 176     (let ((lap (byte-decompile-bytecode (string-as-unibyte bytes) constvec))
 177           op arg opname pc-value)
 178       (let ((tagno 0)
 179             tmp
 180             (lap lap))
 181         (while (setq tmp (assq 'TAG lap))
 182           (setcar (cdr tmp) (setq tagno (1+ tagno)))
 183           (setq lap (cdr (memq tmp lap)))))
 184       (while lap
 185         ;; Take off the pc value of the next thing
 186         ;; and put it in pc-value.
 187         (setq pc-value nil)
 188         (if (numberp (car lap))
 189             (setq pc-value (car lap)
 190                   lap (cdr lap)))
 191         ;; Fetch the next op and its arg.
 192         (setq op (car (car lap))
 193               arg (cdr (car lap)))
 194         (setq lap (cdr lap))
 195         (indent-to indent)
 196         (if (eq 'TAG op)
 197             (progn
 198               ;; We have a label.  Display it, but first its pc value.
 199               (if pc-value
 200                   (insert (format "%d:" pc-value)))
 201               (insert (int-to-string (car arg))))
 202           ;; We have an instruction.  Display its pc value first.
 203           (if pc-value
 204               (insert (format "%d" pc-value)))
 205           (indent-to (+ indent disassemble-column-1-indent))
 206           (if (and op
 207                    (string-match "^byte-" (setq opname (symbol-name op))))
 208               (setq opname (substring opname 5))
 209             (setq opname "<not-an-opcode>"))
 210           (if (eq op 'byte-constant2)
 211               (insert " #### shouldn't have seen constant2 here!\n  "))
 212           (insert opname)
 213           (indent-to (+ indent disassemble-column-1-indent
 214                         disassemble-column-2-indent
 215                         -1))
 216           (insert " ")
 217           (cond ((memq op byte-goto-ops)
 218                  (insert (int-to-string (nth 1 arg))))
 219                 ((memq op '(byte-call byte-unbind
 220                             byte-listN byte-concatN byte-insertN
 221                             byte-stack-ref byte-stack-set byte-stack-set2
 222                             byte-discardN byte-discardN-preserve-tos))
 223                  (insert (int-to-string arg)))
 224                 ((memq op '(byte-varref byte-varset byte-varbind))
 225                  (prin1 (car arg) (current-buffer)))
 226                 ((memq op '(byte-constant byte-constant2))
 227                  ;; it's a constant
 228                  (setq arg (car arg))
 229                  ;; but if the value of the constant is compiled code, then
 230                  ;; recursively disassemble it.
 231                  (cond ((or (byte-code-function-p arg)
 232                             (and (eq (car-safe arg) 'lambda)
 233                                  (assq 'byte-code arg))
 234                             (and (eq (car-safe arg) 'macro)
 235                                  (or (byte-code-function-p (cdr arg))
 236                                      (and (eq (car-safe (cdr arg)) 'lambda)
 237                                           (assq 'byte-code (cdr arg))))))
 238                         (cond ((byte-code-function-p arg)
 239                                (insert "<compiled-function>\n"))
 240                               ((eq (car-safe arg) 'lambda)
 241                                (insert "<compiled lambda>"))
 242                               (t (insert "<compiled macro>\n")))
 243                         (disassemble-internal
 244                          arg
 245                          (+ indent disassemble-recursive-indent 1)
 246                          nil))
 247                        ((eq (car-safe arg) 'byte-code)
 248                         (insert "<byte code>\n")
 249                         (disassemble-1  ;recurse on byte-code object
 250                          arg
 251                          (+ indent disassemble-recursive-indent)))
 252                        ((eq (car-safe (car-safe arg)) 'byte-code)
 253                         (insert "(<byte code>...)\n")
 254                         (mapc ;recurse on list of byte-code objects
 255                          '(lambda (obj)
 256                             (disassemble-1
 257                              obj
 258                              (+ indent disassemble-recursive-indent)))
 259                          arg))
 260                        (t
 261                         ;; really just a constant
 262                         (let ((print-escape-newlines t))
 263                           (prin1 arg (current-buffer))))))
 264                 )
 265           (insert "\n")))))
 266   nil)
 267
 268 (provide 'disass)
 269
 270 ;;; disass.el ends here