lisp/font-lock.el

   1 ;;; font-lock.el --- Electric font lock mode
   2
   3 ;; Copyright (C) 1992-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Jamie Zawinski
   6 ;;      Richard Stallman
   7 ;;      Stefan Monnier
   8 ;; Maintainer: FSF
   9 ;; Keywords: languages, faces
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Font Lock mode is a minor mode that causes your comments to be displayed in
  30 ;; one face, strings in another, reserved words in another, and so on.
  31 ;;
  32 ;; Comments will be displayed in `font-lock-comment-face'.
  33 ;; Strings will be displayed in `font-lock-string-face'.
  34 ;; Regexps are used to display selected patterns in other faces.
  35 ;;
  36 ;; To make the text you type be fontified, use M-x font-lock-mode RET.
  37 ;; When this minor mode is on, the faces of the current line are updated with
  38 ;; every insertion or deletion.
  39 ;;
  40 ;; To turn Font Lock mode on automatically, add this to your ~/.emacs file:
  41 ;;
  42 ;;  (add-hook 'emacs-lisp-mode-hook 'turn-on-font-lock)
  43 ;;
  44 ;; Or if you want to turn Font Lock mode on in many modes:
  45 ;;
  46 ;;  (global-font-lock-mode t)
  47 ;;
  48 ;; Fontification for a particular mode may be available in a number of levels
  49 ;; of decoration.  The higher the level, the more decoration, but the more time
  50 ;; it takes to fontify.  See the variable `font-lock-maximum-decoration', and
  51 ;; also the variable `font-lock-maximum-size'.  Support modes for Font Lock
  52 ;; mode can be used to speed up Font Lock mode.  See `font-lock-support-mode'.
  53 \f
  54 ;;; How Font Lock mode fontifies:
  55
  56 ;; When Font Lock mode is turned on in a buffer, it (a) fontifies the entire
  57 ;; buffer and (b) installs one of its fontification functions on one of the
  58 ;; hook variables that are run by Emacs after every buffer change (i.e., an
  59 ;; insertion or deletion).  Fontification means the replacement of `face' text
  60 ;; properties in a given region; Emacs displays text with these `face' text
  61 ;; properties appropriately.
  62 ;;
  63 ;; Fontification normally involves syntactic (i.e., strings and comments) and
  64 ;; regexp (i.e., keywords and everything else) passes.  There are actually
  65 ;; three passes; (a) the syntactic keyword pass, (b) the syntactic pass and (c)
  66 ;; the keyword pass.  Confused?
  67 ;;
  68 ;; The syntactic keyword pass places `syntax-table' text properties in the
  69 ;; buffer according to the variable `font-lock-syntactic-keywords'.  It is
  70 ;; necessary because Emacs' syntax table is not powerful enough to describe all
  71 ;; the different syntactic constructs required by the sort of people who decide
  72 ;; that a single quote can be syntactic or not depending on the time of day.
  73 ;; (What sort of person could decide to overload the meaning of a quote?)
  74 ;; Obviously the syntactic keyword pass must occur before the syntactic pass.
  75 ;;
  76 ;; The syntactic pass places `face' text properties in the buffer according to
  77 ;; syntactic context, i.e., according to the buffer's syntax table and buffer
  78 ;; text's `syntax-table' text properties.  It involves using a syntax parsing
  79 ;; function to determine the context of different parts of a region of text.  A
  80 ;; syntax parsing function is necessary because generally strings and/or
  81 ;; comments can span lines, and so the context of a given region is not
  82 ;; necessarily apparent from the content of that region.  Because the keyword
  83 ;; pass only works within a given region, it is not generally appropriate for
  84 ;; syntactic fontification.  This is the first fontification pass that makes
  85 ;; changes visible to the user; it fontifies strings and comments.
  86 ;;
  87 ;; The keyword pass places `face' text properties in the buffer according to
  88 ;; the variable `font-lock-keywords'.  It involves searching for given regexps
  89 ;; (or calling given search functions) within the given region.  This is the
  90 ;; second fontification pass that makes changes visible to the user; it
  91 ;; fontifies language reserved words, etc.
  92 ;;
  93 ;; Oh, and the answer is, "Yes, obviously just about everything should be done
  94 ;; in a single syntactic pass, but the only syntactic parser available
  95 ;; understands only strings and comments."  Perhaps one day someone will write
  96 ;; some syntactic parsers for common languages and a son-of-font-lock.el could
  97 ;; use them rather then relying so heavily on the keyword (regexp) pass.
  98
  99 ;;; How Font Lock mode supports modes or is supported by modes:
 100
 101 ;; Modes that support Font Lock mode do so by defining one or more variables
 102 ;; whose values specify the fontification.  Font Lock mode knows of these
 103 ;; variable names from the buffer local variable `font-lock-defaults'.
 104 ;; (Font Lock mode is set up via (a) where a mode's patterns are
 105 ;; distributed with the mode's package library, and (b) where a mode's
 106 ;; patterns are distributed with font-lock.el itself.  An example of (a)
 107 ;; is Pascal mode, an example of (b) is Lisp mode.  Normally, the mechanism is
 108 ;; (a); (b) is used where it is not clear which package library should contain
 109 ;; the pattern definitions.)  Font Lock mode chooses which variable to use for
 110 ;; fontification based on `font-lock-maximum-decoration'.
 111 ;;
 112 ;; Font Lock mode fontification behavior can be modified in a number of ways.
 113 ;; See the below comments and the comments distributed throughout this file.
 114
 115 ;;; Constructing patterns:
 116
 117 ;; See the documentation for the variable `font-lock-keywords'.
 118 ;;
 119 ;; Efficient regexps for use as MATCHERs for `font-lock-keywords' and
 120 ;; `font-lock-syntactic-keywords' can be generated via the function
 121 ;; `regexp-opt'.
 122
 123 ;;; Adding patterns for modes that already support Font Lock:
 124
 125 ;; Though Font Lock highlighting patterns already exist for many modes, it's
 126 ;; likely there's something that you want fontified that currently isn't, even
 127 ;; at the maximum fontification level.  You can add highlighting patterns via
 128 ;; `font-lock-add-keywords'.  For example, say in some C
 129 ;; header file you #define the token `and' to expand to `&&', etc., to make
 130 ;; your C code almost readable.  In your ~/.emacs there could be:
 131 ;;
 132 ;;  (font-lock-add-keywords 'c-mode '("\\<\\(and\\|or\\|not\\)\\>"))
 133 ;;
 134 ;; Some modes provide specific ways to modify patterns based on the values of
 135 ;; other variables.  For example, additional C types can be specified via the
 136 ;; variable `c-font-lock-extra-types'.
 137
 138 ;;; Adding patterns for modes that do not support Font Lock:
 139
 140 ;; Not all modes support Font Lock mode.  If you (as a user of the mode) add
 141 ;; patterns for a new mode, you must define in your ~/.emacs a variable or
 142 ;; variables that specify regexp fontification.  Then, you should indicate to
 143 ;; Font Lock mode, via the mode hook setting `font-lock-defaults', exactly what
 144 ;; support is required.  For example, say Foo mode should have the following
 145 ;; regexps fontified case-sensitively, and comments and strings should not be
 146 ;; fontified automagically.  In your ~/.emacs there could be:
 147 ;;
 148 ;;  (defvar foo-font-lock-keywords
 149 ;;    '(("\\<\\(one\\|two\\|three\\)\\>" . font-lock-keyword-face)
 150 ;;      ("\\<\\(four\\|five\\|six\\)\\>" . font-lock-type-face))
 151 ;;    "Default expressions to highlight in Foo mode.")
 152 ;;
 153 ;;  (add-hook 'foo-mode-hook
 154 ;;   (lambda ()
 155 ;;     (set (make-local-variable 'font-lock-defaults)
 156 ;;          '(foo-font-lock-keywords t))))
 157
 158 ;;; Adding Font Lock support for modes:
 159
 160 ;; Of course, it would be better that the mode already supports Font Lock mode.
 161 ;; The package author would do something similar to above.  The mode must
 162 ;; define at the top-level a variable or variables that specify regexp
 163 ;; fontification.  Then, the mode command should indicate to Font Lock mode,
 164 ;; via `font-lock-defaults', exactly what support is required.  For example,
 165 ;; say Bar mode should have the following regexps fontified case-insensitively,
 166 ;; and comments and strings should be fontified automagically.  In bar.el there
 167 ;; could be:
 168 ;;
 169 ;;  (defvar bar-font-lock-keywords
 170 ;;    '(("\\<\\(uno\\|due\\|tre\\)\\>" . font-lock-keyword-face)
 171 ;;      ("\\<\\(quattro\\|cinque\\|sei\\)\\>" . font-lock-type-face))
 172 ;;    "Default expressions to highlight in Bar mode.")
 173 ;;
 174 ;; and within `bar-mode' there could be:
 175 ;;
 176 ;;  (set (make-local-variable 'font-lock-defaults)
 177 ;;       '(bar-font-lock-keywords nil t))
 178 \f
 179 ;; What is fontification for?  You might say, "It's to make my code look nice."
 180 ;; I think it should be for adding information in the form of cues.  These cues
 181 ;; should provide you with enough information to both (a) distinguish between
 182 ;; different items, and (b) identify the item meanings, without having to read
 183 ;; the items and think about it.  Therefore, fontification allows you to think
 184 ;; less about, say, the structure of code, and more about, say, why the code
 185 ;; doesn't work.  Or maybe it allows you to think less and drift off to sleep.
 186 ;;
 187 ;; So, here are my opinions/advice/guidelines:
 188 ;;
 189 ;; - Highlight conceptual objects, such as function and variable names, and
 190 ;;   different objects types differently, i.e., (a) and (b) above, highlight
 191 ;;   function names differently to variable names.
 192 ;; - Keep the faces distinct from each other as far as possible.
 193 ;;   i.e., (a) above.
 194 ;; - Use the same face for the same conceptual object, across all modes.
 195 ;;   i.e., (b) above, all modes that have items that can be thought of as, say,
 196 ;;   keywords, should be highlighted with the same face, etc.
 197 ;; - Make the face attributes fit the concept as far as possible.
 198 ;;   i.e., function names might be a bold color such as blue, comments might
 199 ;;   be a bright color such as red, character strings might be brown, because,
 200 ;;   err, strings are brown (that was not the reason, please believe me).
 201 ;; - Don't use a non-nil OVERRIDE unless you have a good reason.
 202 ;;   Only use OVERRIDE for special things that are easy to define, such as the
 203 ;;   way `...' quotes are treated in strings and comments in Emacs Lisp mode.
 204 ;;   Don't use it to, say, highlight keywords in commented out code or strings.
 205 ;; - Err, that's it.
 206 \f
 207 ;;; Code:
 208
 209 (require 'syntax)
 210 (eval-when-compile (require 'cl))
 211
 212 ;; Define core `font-lock' group.
 213 (defgroup font-lock '((jit-lock custom-group))
 214   "Font Lock mode text highlighting package."
 215   :link '(custom-manual :tag "Emacs Manual" "(emacs)Font Lock")
 216   :link '(custom-manual :tag "Elisp Manual" "(elisp)Font Lock Mode")
 217   :group 'faces)
 218
 219 (defgroup font-lock-faces nil
 220   "Faces for highlighting text."
 221   :prefix "font-lock-"
 222   :group 'font-lock)
 223
 224 (defgroup font-lock-extra-types nil
 225   "Extra mode-specific type names for highlighting declarations."
 226   :group 'font-lock)
 227 \f
 228 ;; User variables.
 229
 230 (defcustom font-lock-maximum-size 256000
 231   "Maximum size of a buffer for buffer fontification.
 232 Only buffers less than this can be fontified when Font Lock mode is turned on.
 233 If nil, means size is irrelevant.
 234 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 235 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 236  ((c-mode . 256000) (c++-mode . 256000) (rmail-mode . 1048576))
 237 means that the maximum size is 250K for buffers in C or C++ modes, one megabyte
 238 for buffers in Rmail mode, and size is irrelevant otherwise."
 239   :type '(choice (const :tag "none" nil)
 240                  (integer :tag "size")
 241                  (repeat :menu-tag "mode specific" :tag "mode specific"
 242                          :value ((t . nil))
 243                          (cons :tag "Instance"
 244                                (radio :tag "Mode"
 245                                       (const :tag "all" t)
 246                                       (symbol :tag "name"))
 247                                (radio :tag "Size"
 248                                       (const :tag "none" nil)
 249                                       (integer :tag "size")))))
 250   :group 'font-lock)
 251
 252 (defcustom font-lock-maximum-decoration t
 253   "Maximum decoration level for fontification.
 254 If nil, use the default decoration (typically the minimum available).
 255 If t, use the maximum decoration available.
 256 If a number, use that level of decoration (or if not available the maximum).
 257 The higher the number, the more decoration is done.
 258 If a list, each element should be a cons pair of the form (MAJOR-MODE . LEVEL),
 259 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 260  ((c-mode . t) (c++-mode . 2) (t . 1))
 261 means use the maximum decoration available for buffers in C mode, level 2
 262 decoration for buffers in C++ mode, and level 1 decoration otherwise."
 263   :type '(choice (const :tag "default" nil)
 264                  (const :tag "maximum" t)
 265                  (integer :tag "level" 1)
 266                  (repeat :menu-tag "mode specific" :tag "mode specific"
 267                          :value ((t . t))
 268                          (cons :tag "Instance"
 269                                (radio :tag "Mode"
 270                                       (const :tag "all" t)
 271                                       (symbol :tag "name"))
 272                                (radio :tag "Decoration"
 273                                       (const :tag "default" nil)
 274                                       (const :tag "maximum" t)
 275                                       (integer :tag "level" 1)))))
 276   :group 'font-lock)
 277
 278 (defcustom font-lock-verbose nil
 279   "If non-nil, means show status messages for buffer fontification.
 280 If a number, only buffers greater than this size have fontification messages."
 281   :type '(choice (const :tag "never" nil)
 282                  (other :tag "always" t)
 283                  (integer :tag "size"))
 284   :group 'font-lock
 285   :version "24.1")
 286 \f
 287
 288 ;; Originally these variable values were face names such as `bold' etc.
 289 ;; Now we create our own faces, but we keep these variables for compatibility
 290 ;; and they give users another mechanism for changing face appearance.
 291 ;; We now allow a FACENAME in `font-lock-keywords' to be any expression that
 292 ;; returns a face.  So the easiest thing is to continue using these variables,
 293 ;; rather than sometimes evaling FACENAME and sometimes not.  sm.
 294
 295 ;; Note that in new code, in the vast majority of cases there is no
 296 ;; need to create variables that specify face names.  Simply using
 297 ;; faces directly is enough.  Font-lock is not a template to be
 298 ;; followed in this area.
 299 (defvar font-lock-comment-face          'font-lock-comment-face
 300   "Face name to use for comments.")
 301
 302 (defvar font-lock-comment-delimiter-face 'font-lock-comment-delimiter-face
 303   "Face name to use for comment delimiters.")
 304
 305 (defvar font-lock-string-face           'font-lock-string-face
 306   "Face name to use for strings.")
 307
 308 (defvar font-lock-doc-face              'font-lock-doc-face
 309   "Face name to use for documentation.")
 310
 311 (defvar font-lock-keyword-face          'font-lock-keyword-face
 312   "Face name to use for keywords.")
 313
 314 (defvar font-lock-builtin-face          'font-lock-builtin-face
 315   "Face name to use for builtins.")
 316
 317 (defvar font-lock-function-name-face    'font-lock-function-name-face
 318   "Face name to use for function names.")
 319
 320 (defvar font-lock-variable-name-face    'font-lock-variable-name-face
 321   "Face name to use for variable names.")
 322
 323 (defvar font-lock-type-face             'font-lock-type-face
 324   "Face name to use for type and class names.")
 325
 326 (defvar font-lock-constant-face         'font-lock-constant-face
 327   "Face name to use for constant and label names.")
 328
 329 (defvar font-lock-warning-face          'font-lock-warning-face
 330   "Face name to use for things that should stand out.")
 331
 332 (defvar font-lock-negation-char-face    'font-lock-negation-char-face
 333   "Face name to use for easy to overlook negation.
 334 This can be an \"!\" or the \"n\" in \"ifndef\".")
 335
 336 (defvar font-lock-preprocessor-face     'font-lock-preprocessor-face
 337   "Face name to use for preprocessor directives.")
 338
 339 (defvar font-lock-reference-face        'font-lock-constant-face)
 340 (make-obsolete-variable 'font-lock-reference-face 'font-lock-constant-face "20.3")
 341
 342 ;; Fontification variables:
 343
 344 (defvar font-lock-keywords nil
 345   "A list of the keywords to highlight.
 346 There are two kinds of values: user-level, and compiled.
 347
 348 A user-level keywords list is what a major mode or the user would
 349 set up.  Normally the list would come from `font-lock-defaults'.
 350 through selection of a fontification level and evaluation of any
 351 contained expressions.  You can also alter it by calling
 352 `font-lock-add-keywords' or `font-lock-remove-keywords' with MODE = nil.
 353
 354 Each element in a user-level keywords list should have one of these forms:
 355
 356  MATCHER
 357  (MATCHER . SUBEXP)
 358  (MATCHER . FACENAME)
 359  (MATCHER . HIGHLIGHT)
 360  (MATCHER HIGHLIGHT ...)
 361  (eval . FORM)
 362
 363 where MATCHER can be either the regexp to search for, or the function name to
 364 call to make the search (called with one argument, the limit of the search;
 365 it should return non-nil, move point, and set `match-data' appropriately if
 366 it succeeds; like `re-search-forward' would).
 367 MATCHER regexps can be generated via the function `regexp-opt'.
 368
 369 FORM is an expression, whose value should be a keyword element, evaluated when
 370 the keyword is (first) used in a buffer.  This feature can be used to provide a
 371 keyword that can only be generated when Font Lock mode is actually turned on.
 372
 373 HIGHLIGHT should be either MATCH-HIGHLIGHT or MATCH-ANCHORED.
 374
 375 For highlighting single items, for example each instance of the word \"foo\",
 376 typically only MATCH-HIGHLIGHT is required.
 377 However, if an item or (typically) items are to be highlighted following the
 378 instance of another item (the anchor), for example each instance of the
 379 word \"bar\" following the word \"anchor\" then MATCH-ANCHORED may be required.
 380
 381 MATCH-HIGHLIGHT should be of the form:
 382
 383  (SUBEXP FACENAME [OVERRIDE [LAXMATCH]])
 384
 385 SUBEXP is the number of the subexpression of MATCHER to be highlighted.
 386
 387 FACENAME is an expression whose value is the face name to use.
 388 Instead of a face, FACENAME can evaluate to a property list
 389 of the form (face FACE PROP1 VAL1 PROP2 VAL2 ...)
 390 in which case all the listed text-properties will be set rather than
 391 just FACE.  In such a case, you will most likely want to put those
 392 properties in `font-lock-extra-managed-props' or to override
 393 `font-lock-unfontify-region-function'.
 394
 395 OVERRIDE and LAXMATCH are flags.  If OVERRIDE is t, existing fontification can
 396 be overwritten.  If `keep', only parts not already fontified are highlighted.
 397 If `prepend' or `append', existing fontification is merged with the new, in
 398 which the new or existing fontification, respectively, takes precedence.
 399 If LAXMATCH is non-nil, that means don't signal an error if there is
 400 no match for SUBEXP in MATCHER.
 401
 402 For example, an element of the form highlights (if not already highlighted):
 403
 404  \"\\\\\\=<foo\\\\\\=>\"                discrete occurrences of \"foo\" in the value of the
 405                         variable `font-lock-keyword-face'.
 406  (\"fu\\\\(bar\\\\)\" . 1)      substring \"bar\" within all occurrences of \"fubar\" in
 407                         the value of `font-lock-keyword-face'.
 408  (\"fubar\" . fubar-face)       Occurrences of \"fubar\" in the value of `fubar-face'.
 409  (\"foo\\\\|bar\" 0 foo-bar-face t)
 410                         occurrences of either \"foo\" or \"bar\" in the value
 411                         of `foo-bar-face', even if already highlighted.
 412  (fubar-match 1 fubar-face)
 413                         the first subexpression within all occurrences of
 414                         whatever the function `fubar-match' finds and matches
 415                         in the value of `fubar-face'.
 416
 417 MATCH-ANCHORED should be of the form:
 418
 419  (MATCHER PRE-MATCH-FORM POST-MATCH-FORM MATCH-HIGHLIGHT ...)
 420
 421 where MATCHER is a regexp to search for or the function name to call to make
 422 the search, as for MATCH-HIGHLIGHT above, but with one exception; see below.
 423 PRE-MATCH-FORM and POST-MATCH-FORM are evaluated before the first, and after
 424 the last, instance MATCH-ANCHORED's MATCHER is used.  Therefore they can be
 425 used to initialize before, and cleanup after, MATCHER is used.  Typically,
 426 PRE-MATCH-FORM is used to move to some position relative to the original
 427 MATCHER, before starting with MATCH-ANCHORED's MATCHER.  POST-MATCH-FORM might
 428 be used to move back, before resuming with MATCH-ANCHORED's parent's MATCHER.
 429
 430 For example, an element of the form highlights (if not already highlighted):
 431
 432  (\"\\\\\\=<anchor\\\\\\=>\" (0 anchor-face) (\"\\\\\\=<item\\\\\\=>\" nil nil (0 item-face)))
 433
 434  discrete occurrences of \"anchor\" in the value of `anchor-face', and subsequent
 435  discrete occurrences of \"item\" (on the same line) in the value of `item-face'.
 436  (Here PRE-MATCH-FORM and POST-MATCH-FORM are nil.  Therefore \"item\" is
 437  initially searched for starting from the end of the match of \"anchor\", and
 438  searching for subsequent instances of \"anchor\" resumes from where searching
 439  for \"item\" concluded.)
 440
 441 The above-mentioned exception is as follows.  The limit of the MATCHER search
 442 defaults to the end of the line after PRE-MATCH-FORM is evaluated.
 443 However, if PRE-MATCH-FORM returns a position greater than the position after
 444 PRE-MATCH-FORM is evaluated, that position is used as the limit of the search.
 445 It is generally a bad idea to return a position greater than the end of the
 446 line, i.e., cause the MATCHER search to span lines.
 447
 448 These regular expressions can match text which spans lines, although
 449 it is better to avoid it if possible since updating them while editing
 450 text is slower, and it is not guaranteed to be always correct when using
 451 support modes like jit-lock or lazy-lock.
 452
 453 This variable is set by major modes via the variable `font-lock-defaults'.
 454 Be careful when composing regexps for this list; a poorly written pattern can
 455 dramatically slow things down!
 456
 457 A compiled keywords list starts with t.  It is produced internal
 458 by `font-lock-compile-keywords' from a user-level keywords list.
 459 Its second element is the user-level keywords list that was
 460 compiled.  The remaining elements have the same form as
 461 user-level keywords, but normally their values have been
 462 optimized.")
 463
 464 (defvar font-lock-keywords-alist nil
 465   "Alist of additional `font-lock-keywords' elements for major modes.
 466
 467 Each element has the form (MODE KEYWORDS . HOW).
 468 `font-lock-set-defaults' adds the elements in the list KEYWORDS to
 469 `font-lock-keywords' when Font Lock is turned on in major mode MODE.
 470
 471 If HOW is nil, KEYWORDS are added at the beginning of
 472 `font-lock-keywords'.  If it is `set', they are used to replace the
 473 value of `font-lock-keywords'.  If HOW is any other non-nil value,
 474 they are added at the end.
 475
 476 This is normally set via `font-lock-add-keywords' and
 477 `font-lock-remove-keywords'.")
 478 (put 'font-lock-keywords-alist 'risky-local-variable t)
 479
 480 (defvar font-lock-removed-keywords-alist nil
 481   "Alist of `font-lock-keywords' elements to be removed for major modes.
 482
 483 Each element has the form (MODE . KEYWORDS).  `font-lock-set-defaults'
 484 removes the elements in the list KEYWORDS from `font-lock-keywords'
 485 when Font Lock is turned on in major mode MODE.
 486
 487 This is normally set via `font-lock-add-keywords' and
 488 `font-lock-remove-keywords'.")
 489
 490 (defvar font-lock-keywords-only nil
 491   "*Non-nil means Font Lock should not fontify comments or strings.
 492 This is normally set via `font-lock-defaults'.")
 493
 494 (defvar font-lock-keywords-case-fold-search nil
 495   "*Non-nil means the patterns in `font-lock-keywords' are case-insensitive.
 496 This is set via the function `font-lock-set-defaults', based on
 497 the CASE-FOLD argument of `font-lock-defaults'.")
 498 (make-variable-buffer-local 'font-lock-keywords-case-fold-search)
 499
 500 (defvar font-lock-syntactically-fontified 0
 501   "Point up to which `font-lock-syntactic-keywords' has been applied.
 502 If nil, this is ignored, in which case the syntactic fontification may
 503 sometimes be slightly incorrect.")
 504 (make-variable-buffer-local 'font-lock-syntactically-fontified)
 505
 506 (defvar font-lock-syntactic-face-function
 507   (lambda (state)
 508     (if (nth 3 state) font-lock-string-face font-lock-comment-face))
 509   "Function to determine which face to use when fontifying syntactically.
 510 The function is called with a single parameter (the state as returned by
 511 `parse-partial-sexp' at the beginning of the region to highlight) and
 512 should return a face.  This is normally set via `font-lock-defaults'.")
 513
 514 (defvar font-lock-syntactic-keywords nil
 515   "A list of the syntactic keywords to put syntax properties on.
 516 The value can be the list itself, or the name of a function or variable
 517 whose value is the list.
 518
 519 See `font-lock-keywords' for a description of the form of this list;
 520 only the differences are stated here.  MATCH-HIGHLIGHT should be of the form:
 521
 522  (SUBEXP SYNTAX OVERRIDE LAXMATCH)
 523
 524 where SYNTAX can be a string (as taken by `modify-syntax-entry'), a syntax
 525 table, a cons cell (as returned by `string-to-syntax') or an expression whose
 526 value is such a form.  OVERRIDE cannot be `prepend' or `append'.
 527
 528 Here are two examples of elements of `font-lock-syntactic-keywords'
 529 and what they do:
 530
 531  (\"\\\\$\\\\(#\\\\)\" 1 \".\")
 532
 533  gives a hash character punctuation syntax (\".\") when following a
 534  dollar-sign character.  Hash characters in other contexts will still
 535  follow whatever the syntax table says about the hash character.
 536
 537  (\"\\\\('\\\\).\\\\('\\\\)\"
 538   (1 \"\\\"\")
 539   (2 \"\\\"\"))
 540
 541  gives a pair single-quotes, which surround a single character, a SYNTAX of
 542  \"\\\"\" (meaning string quote syntax).  Single-quote characters in other
 543  contexts will not be affected.
 544
 545 This is normally set via `font-lock-defaults'.")
 546 (make-obsolete-variable 'font-lock-syntactic-keywords
 547                         'syntax-propertize-function "24.1")
 548
 549 (defvar font-lock-syntax-table nil
 550   "Non-nil means use this syntax table for fontifying.
 551 If this is nil, the major mode's syntax table is used.
 552 This is normally set via `font-lock-defaults'.")
 553
 554 (defvar font-lock-beginning-of-syntax-function nil
 555   "*Non-nil means use this function to move back outside all constructs.
 556 When called with no args it should move point backward to a place which
 557 is not in a string or comment and not within any bracket-pairs (or else,
 558 a place such that any bracket-pairs outside it can be ignored for Emacs
 559 syntax analysis and fontification).
 560
 561 If this is nil, Font Lock uses `syntax-begin-function' to move back
 562 outside of any comment, string, or sexp.  This variable is semi-obsolete;
 563 we recommend setting `syntax-begin-function' instead.
 564
 565 This is normally set via `font-lock-defaults'.")
 566 (make-obsolete-variable 'font-lock-beginning-of-syntax-function
 567                         'syntax-begin-function "23.3" 'set)
 568
 569 (defvar font-lock-mark-block-function nil
 570   "*Non-nil means use this function to mark a block of text.
 571 When called with no args it should leave point at the beginning of any
 572 enclosing textual block and mark at the end.
 573 This is normally set via `font-lock-defaults'.")
 574
 575 (defvar font-lock-fontify-buffer-function 'font-lock-default-fontify-buffer
 576   "Function to use for fontifying the buffer.
 577 This is normally set via `font-lock-defaults'.")
 578
 579 (defvar font-lock-unfontify-buffer-function 'font-lock-default-unfontify-buffer
 580   "Function to use for unfontifying the buffer.
 581 This is used when turning off Font Lock mode.
 582 This is normally set via `font-lock-defaults'.")
 583
 584 (defvar font-lock-fontify-region-function 'font-lock-default-fontify-region
 585   "Function to use for fontifying a region.
 586 It should take two args, the beginning and end of the region, and an optional
 587 third arg VERBOSE.  If VERBOSE is non-nil, the function should print status
 588 messages.  This is normally set via `font-lock-defaults'.")
 589
 590 (defvar font-lock-unfontify-region-function 'font-lock-default-unfontify-region
 591   "Function to use for unfontifying a region.
 592 It should take two args, the beginning and end of the region.
 593 This is normally set via `font-lock-defaults'.")
 594
 595 (defvar font-lock-inhibit-thing-lock nil
 596   "List of Font Lock mode related modes that should not be turned on.
 597 Currently, valid mode names are `fast-lock-mode', `jit-lock-mode' and
 598 `lazy-lock-mode'.  This is normally set via `font-lock-defaults'.")
 599
 600 (defvar font-lock-multiline nil
 601   "Whether font-lock should cater to multiline keywords.
 602 If nil, don't try to handle multiline patterns.
 603 If t, always handle multiline patterns.
 604 If `undecided', don't try to handle multiline patterns until you see one.
 605 Major/minor modes can set this variable if they know which option applies.")
 606
 607 (defvar font-lock-fontified nil)        ; Whether we have fontified the buffer.
 608 \f
 609 ;; Font Lock mode.
 610
 611 (eval-when-compile
 612   ;;
 613   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 614   (require 'cl)
 615   ;;
 616   ;; Borrowed from lazy-lock.el.
 617   ;; We use this to preserve or protect things when modifying text properties.
 618   (defmacro save-buffer-state (&rest body)
 619     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 620     (declare (indent 0) (debug t))
 621     `(let ((inhibit-point-motion-hooks t))
 622        (with-silent-modifications
 623          ,@body)))
 624   ;;
 625   ;; Shut up the byte compiler.
 626   (defvar font-lock-face-attributes))   ; Obsolete but respected if set.
 627
 628 (defun font-lock-mode-internal (arg)
 629   ;; Turn on Font Lock mode.
 630   (when arg
 631     (add-hook 'after-change-functions 'font-lock-after-change-function t t)
 632     (font-lock-set-defaults)
 633     (font-lock-turn-on-thing-lock)
 634     ;; Fontify the buffer if we have to.
 635     (let ((max-size (font-lock-value-in-major-mode font-lock-maximum-size)))
 636       (cond (font-lock-fontified
 637              nil)
 638             ((or (null max-size) (> max-size (buffer-size)))
 639              (font-lock-fontify-buffer))
 640             (font-lock-verbose
 641              (message "Fontifying %s...buffer size greater than font-lock-maximum-size"
 642                       (buffer-name))))))
 643   ;; Turn off Font Lock mode.
 644   (unless font-lock-mode
 645     (remove-hook 'after-change-functions 'font-lock-after-change-function t)
 646     (font-lock-unfontify-buffer)
 647     (font-lock-turn-off-thing-lock)))
 648
 649 (defun font-lock-add-keywords (mode keywords &optional how)
 650   "Add highlighting KEYWORDS for MODE.
 651
 652 MODE should be a symbol, the major mode command name, such as `c-mode'
 653 or nil.  If nil, highlighting keywords are added for the current buffer.
 654 KEYWORDS should be a list; see the variable `font-lock-keywords'.
 655 By default they are added at the beginning of the current highlighting list.
 656 If optional argument HOW is `set', they are used to replace the current
 657 highlighting list.  If HOW is any other non-nil value, they are added at the
 658 end of the current highlighting list.
 659
 660 For example:
 661
 662  (font-lock-add-keywords 'c-mode
 663   '((\"\\\\\\=<\\\\(FIXME\\\\):\" 1 font-lock-warning-face prepend)
 664     (\"\\\\\\=<\\\\(and\\\\|or\\\\|not\\\\)\\\\\\=>\" . font-lock-keyword-face)))
 665
 666 adds two fontification patterns for C mode, to fontify `FIXME:' words, even in
 667 comments, and to fontify `and', `or' and `not' words as keywords.
 668
 669 The above procedure will only add the keywords for C mode, not
 670 for modes derived from C mode.  To add them for derived modes too,
 671 pass nil for MODE and add the call to c-mode-hook.
 672
 673 For example:
 674
 675  (add-hook 'c-mode-hook
 676   (lambda ()
 677    (font-lock-add-keywords nil
 678     '((\"\\\\\\=<\\\\(FIXME\\\\):\" 1 font-lock-warning-face prepend)
 679       (\"\\\\\\=<\\\\(and\\\\|or\\\\|not\\\\)\\\\\\=>\" .
 680        font-lock-keyword-face)))))
 681
 682 The above procedure may fail to add keywords to derived modes if
 683 some involved major mode does not follow the standard conventions.
 684 File a bug report if this happens, so the major mode can be corrected.
 685
 686 Note that some modes have specialized support for additional patterns, e.g.,
 687 see the variables `c-font-lock-extra-types', `c++-font-lock-extra-types',
 688 `objc-font-lock-extra-types' and `java-font-lock-extra-types'."
 689   (cond (mode
 690          ;; If MODE is non-nil, add the KEYWORDS and HOW spec to
 691          ;; `font-lock-keywords-alist' so `font-lock-set-defaults' uses them.
 692          (let ((spec (cons keywords how)) cell)
 693            (if (setq cell (assq mode font-lock-keywords-alist))
 694                (if (eq how 'set)
 695                    (setcdr cell (list spec))
 696                  (setcdr cell (append (cdr cell) (list spec))))
 697              (push (list mode spec) font-lock-keywords-alist)))
 698          ;; Make sure that `font-lock-removed-keywords-alist' does not
 699          ;; contain the new keywords.
 700          (font-lock-update-removed-keyword-alist mode keywords how))
 701         (t
 702          (when (and font-lock-mode
 703                     (not (or font-lock-keywords font-lock-defaults)))
 704            ;; The major mode has not set any keywords, so when we enabled
 705            ;; font-lock-mode it only enabled the font-core.el part, not the
 706            ;; font-lock-mode-internal.  Try again.
 707            (font-lock-mode -1)
 708            (set (make-local-variable 'font-lock-defaults) '(nil t))
 709            (font-lock-mode 1))
 710          ;; Otherwise set or add the keywords now.
 711          ;; This is a no-op if it has been done already in this buffer
 712          ;; for the correct major mode.
 713          (font-lock-set-defaults)
 714          (let ((was-compiled (eq (car font-lock-keywords) t)))
 715            ;; Bring back the user-level (uncompiled) keywords.
 716            (if was-compiled
 717                (setq font-lock-keywords (cadr font-lock-keywords)))
 718            ;; Now modify or replace them.
 719            (if (eq how 'set)
 720                (setq font-lock-keywords keywords)
 721              (font-lock-remove-keywords nil keywords) ;to avoid duplicates
 722              (let ((old (if (eq (car-safe font-lock-keywords) t)
 723                             (cdr font-lock-keywords)
 724                           font-lock-keywords)))
 725                (setq font-lock-keywords (if how
 726                                             (append old keywords)
 727                                           (append keywords old)))))
 728            ;; If the keywords were compiled before, compile them again.
 729            (if was-compiled
 730                (setq font-lock-keywords
 731                      (font-lock-compile-keywords font-lock-keywords)))))))
 732
 733 (defun font-lock-update-removed-keyword-alist (mode keywords how)
 734   "Update `font-lock-removed-keywords-alist' when adding new KEYWORDS to MODE."
 735   ;; When font-lock is enabled first all keywords in the list
 736   ;; `font-lock-keywords-alist' are added, then all keywords in the
 737   ;; list `font-lock-removed-keywords-alist' are removed.  If a
 738   ;; keyword was once added, removed, and then added again it must be
 739   ;; removed from the removed-keywords list.  Otherwise the second add
 740   ;; will not take effect.
 741   (let ((cell (assq mode font-lock-removed-keywords-alist)))
 742     (if cell
 743         (if (eq how 'set)
 744             ;; A new set of keywords is defined.  Forget all about
 745             ;; our old keywords that should be removed.
 746             (setq font-lock-removed-keywords-alist
 747                   (delq cell font-lock-removed-keywords-alist))
 748           ;; Delete all previously removed keywords.
 749           (dolist (kword keywords)
 750             (setcdr cell (delete kword (cdr cell))))
 751           ;; Delete the mode cell if empty.
 752           (if (null (cdr cell))
 753               (setq font-lock-removed-keywords-alist
 754                     (delq cell font-lock-removed-keywords-alist)))))))
 755
 756 ;; Written by Anders Lindgren <andersl@andersl.com>.
 757 ;;
 758 ;; Case study:
 759 ;; (I)  The keywords are removed from a major mode.
 760 ;;      In this case the keyword could be local (i.e. added earlier by
 761 ;;      `font-lock-add-keywords'), global, or both.
 762 ;;
 763 ;;      (a) In the local case we remove the keywords from the variable
 764 ;;          `font-lock-keywords-alist'.
 765 ;;
 766 ;;      (b) The actual global keywords are not known at this time.
 767 ;;          All keywords are added to `font-lock-removed-keywords-alist',
 768 ;;          when font-lock is enabled those keywords are removed.
 769 ;;
 770 ;;      Note that added keywords are taken out of the list of removed
 771 ;;      keywords.  This ensure correct operation when the same keyword
 772 ;;      is added and removed several times.
 773 ;;
 774 ;; (II) The keywords are removed from the current buffer.
 775 (defun font-lock-remove-keywords (mode keywords)
 776   "Remove highlighting KEYWORDS for MODE.
 777
 778 MODE should be a symbol, the major mode command name, such as `c-mode'
 779 or nil.  If nil, highlighting keywords are removed for the current buffer.
 780
 781 To make the removal apply to modes derived from MODE as well,
 782 pass nil for MODE and add the call to MODE-hook.  This may fail
 783 for some derived modes if some involved major mode does not
 784 follow the standard conventions.  File a bug report if this
 785 happens, so the major mode can be corrected."
 786   (cond (mode
 787          ;; Remove one keyword at the time.
 788          (dolist (keyword keywords)
 789            (let ((top-cell (assq mode font-lock-keywords-alist)))
 790              ;; If MODE is non-nil, remove the KEYWORD from
 791              ;; `font-lock-keywords-alist'.
 792              (when top-cell
 793                (dolist (keyword-list-how-pair (cdr top-cell))
 794                  ;; `keywords-list-how-pair' is a cons with a list of
 795                  ;; keywords in the car top-cell and the original how
 796                  ;; argument in the cdr top-cell.
 797                  (setcar keyword-list-how-pair
 798                          (delete keyword (car keyword-list-how-pair))))
 799                ;; Remove keyword list/how pair when the keyword list
 800                ;; is empty and how doesn't specify `set'.  (If it
 801                ;; should be deleted then previously deleted keywords
 802                ;; would appear again.)
 803                (let ((cell top-cell))
 804                  (while (cdr cell)
 805                    (if (and (null (car (car (cdr cell))))
 806                             (not (eq (cdr (car (cdr cell))) 'set)))
 807                        (setcdr cell (cdr (cdr cell)))
 808                      (setq cell (cdr cell)))))
 809                ;; Final cleanup, remove major mode cell if last keyword
 810                ;; was deleted.
 811                (if (null (cdr top-cell))
 812                    (setq font-lock-keywords-alist
 813                          (delq top-cell font-lock-keywords-alist))))
 814              ;; Remember the keyword in case it is not local.
 815              (let ((cell (assq mode font-lock-removed-keywords-alist)))
 816                (if cell
 817                    (unless (member keyword (cdr cell))
 818                      (nconc cell (list keyword)))
 819                  (push (cons mode (list keyword))
 820                        font-lock-removed-keywords-alist))))))
 821         (t
 822          ;; Otherwise remove it immediately.
 823          (font-lock-set-defaults)
 824          (let ((was-compiled (eq (car font-lock-keywords) t)))
 825            ;; Bring back the user-level (uncompiled) keywords.
 826            (if was-compiled
 827                (setq font-lock-keywords (cadr font-lock-keywords)))
 828
 829            ;; Edit them.
 830            (setq font-lock-keywords (copy-sequence font-lock-keywords))
 831            (dolist (keyword keywords)
 832              (setq font-lock-keywords
 833                    (delete keyword font-lock-keywords)))
 834
 835            ;; If the keywords were compiled before, compile them again.
 836            (if was-compiled
 837                (setq font-lock-keywords
 838                      (font-lock-compile-keywords font-lock-keywords)))))))
 839 \f
 840 ;;; Font Lock Support mode.
 841
 842 ;; This is the code used to interface font-lock.el with any of its add-on
 843 ;; packages, and provide the user interface.  Packages that have their own
 844 ;; local buffer fontification functions (see below) may have to call
 845 ;; `font-lock-after-fontify-buffer' and/or `font-lock-after-unfontify-buffer'
 846 ;; themselves.
 847
 848 (defcustom font-lock-support-mode 'jit-lock-mode
 849   "Support mode for Font Lock mode.
 850 Support modes speed up Font Lock mode by being choosy about when fontification
 851 occurs.  The default support mode, Just-in-time Lock mode (symbol
 852 `jit-lock-mode'), is recommended.
 853
 854 Other, older support modes are Fast Lock mode (symbol `fast-lock-mode') and
 855 Lazy Lock mode (symbol `lazy-lock-mode').  See those modes for more info.
 856 However, they are no longer recommended, as Just-in-time Lock mode is better.
 857
 858 If nil, means support for Font Lock mode is never performed.
 859 If a symbol, use that support mode.
 860 If a list, each element should be of the form (MAJOR-MODE . SUPPORT-MODE),
 861 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 862  ((c-mode . fast-lock-mode) (c++-mode . fast-lock-mode) (t . lazy-lock-mode))
 863 means that Fast Lock mode is used to support Font Lock mode for buffers in C or
 864 C++ modes, and Lazy Lock mode is used to support Font Lock mode otherwise.
 865
 866 The value of this variable is used when Font Lock mode is turned on."
 867   :type '(choice (const :tag "none" nil)
 868                  (const :tag "fast lock" fast-lock-mode)
 869                  (const :tag "lazy lock" lazy-lock-mode)
 870                  (const :tag "jit lock" jit-lock-mode)
 871                  (repeat :menu-tag "mode specific" :tag "mode specific"
 872                          :value ((t . jit-lock-mode))
 873                          (cons :tag "Instance"
 874                                (radio :tag "Mode"
 875                                       (const :tag "all" t)
 876                                       (symbol :tag "name"))
 877                                (radio :tag "Support"
 878                                       (const :tag "none" nil)
 879                                       (const :tag "fast lock" fast-lock-mode)
 880                                       (const :tag "lazy lock" lazy-lock-mode)
 881                                       (const :tag "JIT lock" jit-lock-mode)))
 882                          ))
 883   :version "21.1"
 884   :group 'font-lock)
 885
 886 (defvar fast-lock-mode)
 887 (defvar lazy-lock-mode)
 888 (defvar jit-lock-mode)
 889
 890 (declare-function fast-lock-after-fontify-buffer "fast-lock")
 891 (declare-function fast-lock-after-unfontify-buffer "fast-lock")
 892 (declare-function fast-lock-mode "fast-lock")
 893 (declare-function lazy-lock-after-fontify-buffer "lazy-lock")
 894 (declare-function lazy-lock-after-unfontify-buffer "lazy-lock")
 895 (declare-function lazy-lock-mode "lazy-lock")
 896
 897 (defun font-lock-turn-on-thing-lock ()
 898   (case (font-lock-value-in-major-mode font-lock-support-mode)
 899     (fast-lock-mode (fast-lock-mode t))
 900     (lazy-lock-mode (lazy-lock-mode t))
 901     (jit-lock-mode
 902      ;; Prepare for jit-lock
 903      (remove-hook 'after-change-functions
 904                   'font-lock-after-change-function t)
 905      (set (make-local-variable 'font-lock-fontify-buffer-function)
 906           'jit-lock-refontify)
 907      ;; Don't fontify eagerly (and don't abort if the buffer is large).
 908      (set (make-local-variable 'font-lock-fontified) t)
 909      ;; Use jit-lock.
 910      (jit-lock-register 'font-lock-fontify-region
 911                         (not font-lock-keywords-only))
 912      ;; Tell jit-lock how we extend the region to refontify.
 913      (add-hook 'jit-lock-after-change-extend-region-functions
 914                'font-lock-extend-jit-lock-region-after-change
 915                nil t))))
 916
 917 (defun font-lock-turn-off-thing-lock ()
 918   (cond ((bound-and-true-p fast-lock-mode)
 919          (fast-lock-mode -1))
 920         ((bound-and-true-p jit-lock-mode)
 921          (jit-lock-unregister 'font-lock-fontify-region)
 922          ;; Reset local vars to the non-jit-lock case.
 923          (kill-local-variable 'font-lock-fontify-buffer-function))
 924         ((bound-and-true-p lazy-lock-mode)
 925          (lazy-lock-mode -1))))
 926
 927 (defun font-lock-after-fontify-buffer ()
 928   (cond ((bound-and-true-p fast-lock-mode)
 929          (fast-lock-after-fontify-buffer))
 930         ;; Useless now that jit-lock intercepts font-lock-fontify-buffer.  -sm
 931         ;; (jit-lock-mode
 932         ;;  (jit-lock-after-fontify-buffer))
 933         ((bound-and-true-p lazy-lock-mode)
 934          (lazy-lock-after-fontify-buffer))))
 935
 936 (defun font-lock-after-unfontify-buffer ()
 937   (cond ((bound-and-true-p fast-lock-mode)
 938          (fast-lock-after-unfontify-buffer))
 939         ;; Useless as well.  It's only called when:
 940         ;; - turning off font-lock: it does not matter if we leave spurious
 941         ;;   `fontified' text props around since jit-lock-mode is also off.
 942         ;; - font-lock-default-fontify-buffer fails: this is not run
 943         ;;   any more anyway.   -sm
 944         ;;
 945         ;; (jit-lock-mode
 946         ;;  (jit-lock-after-unfontify-buffer))
 947         ((bound-and-true-p lazy-lock-mode)
 948          (lazy-lock-after-unfontify-buffer))))
 949
 950 ;;; End of Font Lock Support mode.
 951 \f
 952 ;;; Fontification functions.
 953
 954 ;; Rather than the function, e.g., `font-lock-fontify-region' containing the
 955 ;; code to fontify a region, the function runs the function whose name is the
 956 ;; value of the variable, e.g., `font-lock-fontify-region-function'.  Normally,
 957 ;; the value of this variable is, e.g., `font-lock-default-fontify-region'
 958 ;; which does contain the code to fontify a region.  However, the value of the
 959 ;; variable could be anything and thus, e.g., `font-lock-fontify-region' could
 960 ;; do anything.  The indirection of the fontification functions gives major
 961 ;; modes the capability of modifying the way font-lock.el fontifies.  Major
 962 ;; modes can modify the values of, e.g., `font-lock-fontify-region-function',
 963 ;; via the variable `font-lock-defaults'.
 964 ;;
 965 ;; For example, Rmail mode sets the variable `font-lock-defaults' so that
 966 ;; font-lock.el uses its own function for buffer fontification.  This function
 967 ;; makes fontification be on a message-by-message basis and so visiting an
 968 ;; RMAIL file is much faster.  A clever implementation of the function might
 969 ;; fontify the headers differently than the message body.  (It should, and
 970 ;; correspondingly for Mail mode, but I can't be bothered to do the work.  Can
 971 ;; you?)  This hints at a more interesting use...
 972 ;;
 973 ;; Languages that contain text normally contained in different major modes
 974 ;; could define their own fontification functions that treat text differently
 975 ;; depending on its context.  For example, Perl mode could arrange that here
 976 ;; docs are fontified differently than Perl code.  Or Yacc mode could fontify
 977 ;; rules one way and C code another.  Neat!
 978 ;;
 979 ;; A further reason to use the fontification indirection feature is when the
 980 ;; default syntactual fontification, or the default fontification in general,
 981 ;; is not flexible enough for a particular major mode.  For example, perhaps
 982 ;; comments are just too hairy for `font-lock-fontify-syntactically-region' to
 983 ;; cope with.  You need to write your own version of that function, e.g.,
 984 ;; `hairy-fontify-syntactically-region', and make your own version of
 985 ;; `hairy-fontify-region' call that function before calling
 986 ;; `font-lock-fontify-keywords-region' for the normal regexp fontification
 987 ;; pass.  And Hairy mode would set `font-lock-defaults' so that font-lock.el
 988 ;; would call your region fontification function instead of its own.  For
 989 ;; example, TeX modes could fontify {\foo ...} and \bar{...}  etc. multi-line
 990 ;; directives correctly and cleanly.  (It is the same problem as fontifying
 991 ;; multi-line strings and comments; regexps are not appropriate for the job.)
 992
 993 (defvar font-lock-extend-after-change-region-function nil
 994   "A function that determines the region to refontify after a change.
 995
 996 This variable is either nil, or is a function that determines the
 997 region to refontify after a change.
 998 It is usually set by the major mode via `font-lock-defaults'.
 999 Font-lock calls this function after each buffer change.
1000
1001 The function is given three parameters, the standard BEG, END, and OLD-LEN
1002 from `after-change-functions'.  It should return either a cons of the beginning
1003 and end buffer positions \(in that order) of the region to refontify, or nil
1004 \(which directs the caller to fontify a default region).
1005 This function should preserve the match-data.
1006 The region it returns may start or end in the middle of a line.")
1007 (make-variable-buffer-local 'font-lock-extend-after-change-region-function)
1008
1009 (defun font-lock-fontify-buffer ()
1010   "Fontify the current buffer the way the function `font-lock-mode' would."
1011   (interactive)
1012   (font-lock-set-defaults)
1013   (let ((font-lock-verbose (or font-lock-verbose
1014                                (called-interactively-p 'interactive))))
1015     (funcall font-lock-fontify-buffer-function)))
1016
1017 (defun font-lock-unfontify-buffer ()
1018   (funcall font-lock-unfontify-buffer-function))
1019
1020 (defun font-lock-fontify-region (beg end &optional loudly)
1021   (font-lock-set-defaults)
1022   (funcall font-lock-fontify-region-function beg end loudly))
1023
1024 (defun font-lock-unfontify-region (beg end)
1025   (save-buffer-state
1026     (funcall font-lock-unfontify-region-function beg end)))
1027
1028 (defun font-lock-default-fontify-buffer ()
1029   (let ((verbose (if (numberp font-lock-verbose)
1030                      (> (buffer-size) font-lock-verbose)
1031                    font-lock-verbose)))
1032     (with-temp-message
1033         (when verbose
1034           (format "Fontifying %s..." (buffer-name)))
1035       ;; Make sure we fontify etc. in the whole buffer.
1036       (save-restriction
1037         (widen)
1038         (condition-case nil
1039             (save-excursion
1040               (save-match-data
1041                 (font-lock-fontify-region (point-min) (point-max) verbose)
1042                 (font-lock-after-fontify-buffer)
1043                 (setq font-lock-fontified t)))
1044           ;; We don't restore the old fontification, so it's best to unfontify.
1045           (quit (font-lock-unfontify-buffer)))))))
1046
1047 (defun font-lock-default-unfontify-buffer ()
1048   ;; Make sure we unfontify etc. in the whole buffer.
1049   (save-restriction
1050     (widen)
1051     (font-lock-unfontify-region (point-min) (point-max))
1052     (font-lock-after-unfontify-buffer)
1053     (setq font-lock-fontified nil)))
1054
1055 (defvar font-lock-dont-widen nil
1056   "If non-nil, font-lock will work on the non-widened buffer.
1057 Useful for things like RMAIL and Info where the whole buffer is not
1058 a very meaningful entity to highlight.")
1059
1060
1061 (defvar font-lock-beg) (defvar font-lock-end)
1062 (defvar font-lock-extend-region-functions
1063   '(font-lock-extend-region-wholelines
1064     ;; This use of font-lock-multiline property is unreliable but is just
1065     ;; a handy heuristic: in case you don't have a function that does
1066     ;; /identification/ of multiline elements, you may still occasionally
1067     ;; discover them by accident (or you may /identify/ them but not in all
1068     ;; cases), in which case the font-lock-multiline property can help make
1069     ;; sure you will properly *re*identify them during refontification.
1070     font-lock-extend-region-multiline)
1071   "Special hook run just before proceeding to fontify a region.
1072 This is used to allow major modes to help font-lock find safe buffer positions
1073 as beginning and end of the fontified region.  Its most common use is to solve
1074 the problem of /identification/ of multiline elements by providing a function
1075 that tries to find such elements and move the boundaries such that they do
1076 not fall in the middle of one.
1077 Each function is called with no argument; it is expected to adjust the
1078 dynamically bound variables `font-lock-beg' and `font-lock-end'; and return
1079 non-nil if it did make such an adjustment.
1080 These functions are run in turn repeatedly until they all return nil.
1081 Put first the functions more likely to cause a change and cheaper to compute.")
1082 ;; Mark it as a special hook which doesn't use any global setting
1083 ;; (i.e. doesn't obey the element t in the buffer-local value).
1084 (make-variable-buffer-local 'font-lock-extend-region-functions)
1085
1086 (defun font-lock-extend-region-multiline ()
1087   "Move fontification boundaries away from any `font-lock-multiline' property."
1088   (let ((changed nil))
1089     (when (and (> font-lock-beg (point-min))
1090                (get-text-property (1- font-lock-beg) 'font-lock-multiline))
1091       (setq changed t)
1092       (setq font-lock-beg (or (previous-single-property-change
1093                                font-lock-beg 'font-lock-multiline)
1094                               (point-min))))
1095     ;;
1096     (when (get-text-property font-lock-end 'font-lock-multiline)
1097       (setq changed t)
1098       (setq font-lock-end (or (text-property-any font-lock-end (point-max)
1099                                                  'font-lock-multiline nil)
1100                               (point-max))))
1101     changed))
1102
1103 (defun font-lock-extend-region-wholelines ()
1104   "Move fontification boundaries to beginning of lines."
1105   (let ((changed nil))
1106     (goto-char font-lock-beg)
1107     (unless (bolp)
1108       (setq changed t font-lock-beg (line-beginning-position)))
1109     (goto-char font-lock-end)
1110     (unless (bolp)
1111       (unless (eq font-lock-end
1112                   (setq font-lock-end (line-beginning-position 2)))
1113         (setq changed t)))
1114     changed))
1115
1116 (defun font-lock-default-fontify-region (beg end loudly)
1117   (save-buffer-state
1118     ;; Use the fontification syntax table, if any.
1119     (with-syntax-table (or font-lock-syntax-table (syntax-table))
1120       (save-restriction
1121         (unless font-lock-dont-widen (widen))
1122         ;; Extend the region to fontify so that it starts and ends at
1123         ;; safe places.
1124         (let ((funs font-lock-extend-region-functions)
1125               (font-lock-beg beg)
1126               (font-lock-end end))
1127           (while funs
1128             (setq funs (if (or (not (funcall (car funs)))
1129                                (eq funs font-lock-extend-region-functions))
1130                            (cdr funs)
1131                          ;; If there's been a change, we should go through
1132                          ;; the list again since this new position may
1133                          ;; warrant a different answer from one of the fun
1134                          ;; we've already seen.
1135                          font-lock-extend-region-functions)))
1136           (setq beg font-lock-beg end font-lock-end))
1137         ;; Now do the fontification.
1138         (font-lock-unfontify-region beg end)
1139         (when (and font-lock-syntactic-keywords
1140                    (null syntax-propertize-function))
1141           ;; Ensure the beginning of the file is properly syntactic-fontified.
1142           (let ((start beg))
1143             (when (< font-lock-syntactically-fontified start)
1144               (setq start (max font-lock-syntactically-fontified (point-min)))
1145               (setq font-lock-syntactically-fontified end))
1146             (font-lock-fontify-syntactic-keywords-region start end)))
1147         (unless font-lock-keywords-only
1148           (font-lock-fontify-syntactically-region beg end loudly))
1149         (font-lock-fontify-keywords-region beg end loudly)))))
1150
1151 ;; The following must be rethought, since keywords can override fontification.
1152 ;;    ;; Now scan for keywords, but not if we are inside a comment now.
1153 ;;    (or (and (not font-lock-keywords-only)
1154 ;;             (let ((state (parse-partial-sexp beg end nil nil
1155 ;;                                              font-lock-cache-state)))
1156 ;;               (or (nth 4 state) (nth 7 state))))
1157 ;;        (font-lock-fontify-keywords-region beg end))
1158
1159 (defvar font-lock-extra-managed-props nil
1160   "Additional text properties managed by font-lock.
1161 This is used by `font-lock-default-unfontify-region' to decide
1162 what properties to clear before refontifying a region.")
1163
1164 (defun font-lock-default-unfontify-region (beg end)
1165   (remove-list-of-text-properties
1166    beg end (append
1167             font-lock-extra-managed-props
1168             (if font-lock-syntactic-keywords
1169                 '(syntax-table face font-lock-multiline)
1170               '(face font-lock-multiline)))))
1171
1172 ;; Called when any modification is made to buffer text.
1173 (defun font-lock-after-change-function (beg end old-len)
1174   (save-excursion
1175     (let ((inhibit-point-motion-hooks t)
1176           (inhibit-quit t)
1177           (region (if font-lock-extend-after-change-region-function
1178                       (funcall font-lock-extend-after-change-region-function
1179                                beg end old-len))))
1180       (save-match-data
1181         (if region
1182             ;; Fontify the region the major mode has specified.
1183             (setq beg (car region) end (cdr region))
1184           ;; Fontify the whole lines which enclose the region.
1185           ;; Actually, this is not needed because
1186           ;; font-lock-default-fontify-region already rounds up to a whole
1187           ;; number of lines.
1188           ;; (setq beg (progn (goto-char beg) (line-beginning-position))
1189           ;;       end (progn (goto-char end) (line-beginning-position 2)))
1190           (unless (eq end (point-max))
1191             ;; Rounding up to a whole number of lines should include the
1192             ;; line right after `end'.  Typical case: the first char of
1193             ;; the line was deleted.  Or a \n was inserted in the middle
1194             ;; of a line.
1195             (setq end (1+ end))))
1196         (font-lock-fontify-region beg end)))))
1197
1198 (defvar jit-lock-start) (defvar jit-lock-end)
1199 (defun font-lock-extend-jit-lock-region-after-change (beg end old-len)
1200   "Function meant for `jit-lock-after-change-extend-region-functions'.
1201 This function does 2 things:
1202 - extend the region so that it not only includes the part that was modified
1203   but also the surrounding text whose highlighting may change as a consequence.
1204 - anticipate (part of) the region extension that will happen later in
1205   `font-lock-default-fontify-region', in order to avoid the need for
1206   double-redisplay in `jit-lock-fontify-now'."
1207   (save-excursion
1208     ;; First extend the region as font-lock-after-change-function would.
1209     (let ((region (if font-lock-extend-after-change-region-function
1210                       (funcall font-lock-extend-after-change-region-function
1211                                beg end old-len))))
1212       (if region
1213           (setq beg (min jit-lock-start (car region))
1214                 end (max jit-lock-end (cdr region))))
1215       ;; Then extend the region obeying font-lock-multiline properties,
1216       ;; indicating which part of the buffer needs to be refontified.
1217       ;; !!! This is the *main* user of font-lock-multiline property !!!
1218       ;; font-lock-after-change-function could/should also do that, but it
1219       ;; doesn't need to because font-lock-default-fontify-region does
1220       ;; it anyway.  Here OTOH we have no guarantee that
1221       ;; font-lock-default-fontify-region will be executed on this region
1222       ;; any time soon.
1223       ;; Note: contrary to font-lock-default-fontify-region, we do not do
1224       ;; any loop here because we are not looking for a safe spot: we just
1225       ;; mark the text whose appearance may need to change as a result of
1226       ;; the buffer modification.
1227       (when (and (> beg (point-min))
1228                  (get-text-property (1- beg) 'font-lock-multiline))
1229         (setq beg (or (previous-single-property-change
1230                        beg 'font-lock-multiline)
1231                       (point-min))))
1232       (when (< end (point-max))
1233         (setq end
1234               (if (get-text-property end 'font-lock-multiline)
1235                   (or (text-property-any end (point-max)
1236                                          'font-lock-multiline nil)
1237                       (point-max))
1238                 ;; Rounding up to a whole number of lines should include the
1239                 ;; line right after `end'.  Typical case: the first char of
1240                 ;; the line was deleted.  Or a \n was inserted in the middle
1241                 ;; of a line.
1242                 (1+ end))))
1243       ;; Finally, pre-enlarge the region to a whole number of lines, to try
1244       ;; and anticipate what font-lock-default-fontify-region will do, so as to
1245       ;; avoid double-redisplay.
1246       ;; We could just run `font-lock-extend-region-functions', but since
1247       ;; the only purpose is to avoid the double-redisplay, we prefer to
1248       ;; do here only the part that is cheap and most likely to be useful.
1249       (when (memq 'font-lock-extend-region-wholelines
1250                   font-lock-extend-region-functions)
1251         (goto-char beg)
1252         (setq jit-lock-start (min jit-lock-start (line-beginning-position)))
1253         (goto-char end)
1254         (setq jit-lock-end
1255               (max jit-lock-end
1256                    (if (bolp) (point) (line-beginning-position 2))))))))
1257
1258 (defun font-lock-fontify-block (&optional arg)
1259   "Fontify some lines the way `font-lock-fontify-buffer' would.
1260 The lines could be a function or paragraph, or a specified number of lines.
1261 If ARG is given, fontify that many lines before and after point, or 16 lines if
1262 no ARG is given and `font-lock-mark-block-function' is nil.
1263 If `font-lock-mark-block-function' non-nil and no ARG is given, it is used to
1264 delimit the region to fontify."
1265   (interactive "P")
1266   (let ((inhibit-point-motion-hooks t) font-lock-beginning-of-syntax-function
1267         deactivate-mark)
1268     ;; Make sure we have the right `font-lock-keywords' etc.
1269     (if (not font-lock-mode) (font-lock-set-defaults))
1270     (save-excursion
1271       (save-match-data
1272         (condition-case error-data
1273             (if (or arg (not font-lock-mark-block-function))
1274                 (let ((lines (if arg (prefix-numeric-value arg) 16)))
1275                   (font-lock-fontify-region
1276                    (save-excursion (forward-line (- lines)) (point))
1277                    (save-excursion (forward-line lines) (point))))
1278               (funcall font-lock-mark-block-function)
1279               (font-lock-fontify-region (point) (mark)))
1280           ((error quit) (message "Fontifying block...%s" error-data)))))))
1281
1282 ;;; End of Fontification functions.
1283 \f
1284 ;;; Additional text property functions.
1285
1286 ;; The following text property functions should be builtins.  This means they
1287 ;; should be written in C and put with all the other text property functions.
1288 ;; In the meantime, those that are used by font-lock.el are defined in Lisp
1289 ;; below and given a `font-lock-' prefix.  Those that are not used are defined
1290 ;; in Lisp below and commented out.  sm.
1291
1292 (defun font-lock-prepend-text-property (start end prop value &optional object)
1293   "Prepend to one property of the text from START to END.
1294 Arguments PROP and VALUE specify the property and value to prepend to the value
1295 already in place.  The resulting property values are always lists.
1296 Optional argument OBJECT is the string or buffer containing the text."
1297   (let ((val (if (listp value) value (list value))) next prev)
1298     (while (/= start end)
1299       (setq next (next-single-property-change start prop object end)
1300             prev (get-text-property start prop object))
1301       ;; Canonicalize old forms of face property.
1302       (and (memq prop '(face font-lock-face))
1303            (listp prev)
1304            (or (keywordp (car prev))
1305                (memq (car prev) '(foreground-color background-color)))
1306            (setq prev (list prev)))
1307       (put-text-property start next prop
1308                          (append val (if (listp prev) prev (list prev)))
1309                          object)
1310       (setq start next))))
1311
1312 (defun font-lock-append-text-property (start end prop value &optional object)
1313   "Append to one property of the text from START to END.
1314 Arguments PROP and VALUE specify the property and value to append to the value
1315 already in place.  The resulting property values are always lists.
1316 Optional argument OBJECT is the string or buffer containing the text."
1317   (let ((val (if (listp value) value (list value))) next prev)
1318     (while (/= start end)
1319       (setq next (next-single-property-change start prop object end)
1320             prev (get-text-property start prop object))
1321       ;; Canonicalize old forms of face property.
1322       (and (memq prop '(face font-lock-face))
1323            (listp prev)
1324            (or (keywordp (car prev))
1325                (memq (car prev) '(foreground-color background-color)))
1326            (setq prev (list prev)))
1327       (put-text-property start next prop
1328                          (append (if (listp prev) prev (list prev)) val)
1329                          object)
1330       (setq start next))))
1331
1332 (defun font-lock-fillin-text-property (start end prop value &optional object)
1333   "Fill in one property of the text from START to END.
1334 Arguments PROP and VALUE specify the property and value to put where none are
1335 already in place.  Therefore existing property values are not overwritten.
1336 Optional argument OBJECT is the string or buffer containing the text."
1337   (let ((start (text-property-any start end prop nil object)) next)
1338     (while start
1339       (setq next (next-single-property-change start prop object end))
1340       (put-text-property start next prop value object)
1341       (setq start (text-property-any next end prop nil object)))))
1342
1343 ;; For completeness: this is to `remove-text-properties' as `put-text-property'
1344 ;; is to `add-text-properties', etc.
1345 ;;(defun remove-text-property (start end property &optional object)
1346 ;;  "Remove a property from text from START to END.
1347 ;;Argument PROPERTY is the property to remove.
1348 ;;Optional argument OBJECT is the string or buffer containing the text.
1349 ;;Return t if the property was actually removed, nil otherwise."
1350 ;;  (remove-text-properties start end (list property) object))
1351
1352 ;; For consistency: maybe this should be called `remove-single-property' like
1353 ;; `next-single-property-change' (not `next-single-text-property-change'), etc.
1354 ;;(defun remove-single-text-property (start end prop value &optional object)
1355 ;;  "Remove a specific property value from text from START to END.
1356 ;;Arguments PROP and VALUE specify the property and value to remove.  The
1357 ;;resulting property values are not equal to VALUE nor lists containing VALUE.
1358 ;;Optional argument OBJECT is the string or buffer containing the text."
1359 ;;  (let ((start (text-property-not-all start end prop nil object)) next prev)
1360 ;;    (while start
1361 ;;      (setq next (next-single-property-change start prop object end)
1362 ;;          prev (get-text-property start prop object))
1363 ;;      (cond ((and (symbolp prev) (eq value prev))
1364 ;;           (remove-text-property start next prop object))
1365 ;;          ((and (listp prev) (memq value prev))
1366 ;;           (let ((new (delq value prev)))
1367 ;;             (cond ((null new)
1368 ;;                    (remove-text-property start next prop object))
1369 ;;                   ((= (length new) 1)
1370 ;;                    (put-text-property start next prop (car new) object))
1371 ;;                   (t
1372 ;;                    (put-text-property start next prop new object))))))
1373 ;;      (setq start (text-property-not-all next end prop nil object)))))
1374
1375 ;;; End of Additional text property functions.
1376 \f
1377 ;;; Syntactic regexp fontification functions.
1378
1379 ;; These syntactic keyword pass functions are identical to those keyword pass
1380 ;; functions below, with the following exceptions; (a) they operate on
1381 ;; `font-lock-syntactic-keywords' of course, (b) they are all `defun' as speed
1382 ;; is less of an issue, (c) eval of property value does not occur JIT as speed
1383 ;; is less of an issue, (d) OVERRIDE cannot be `prepend' or `append' as it
1384 ;; makes no sense for `syntax-table' property values, (e) they do not do it
1385 ;; LOUDLY as it is not likely to be intensive.
1386
1387 (defun font-lock-apply-syntactic-highlight (highlight)
1388   "Apply HIGHLIGHT following a match.
1389 HIGHLIGHT should be of the form MATCH-HIGHLIGHT,
1390 see `font-lock-syntactic-keywords'."
1391   (let* ((match (nth 0 highlight))
1392          (start (match-beginning match)) (end (match-end match))
1393          (value (nth 1 highlight))
1394          (override (nth 2 highlight)))
1395     (if (not start)
1396         ;; No match but we might not signal an error.
1397         (or (nth 3 highlight)
1398             (error "No match %d in highlight %S" match highlight))
1399       (when (and (consp value) (not (numberp (car value))))
1400         (setq value (eval value)))
1401       (when (stringp value) (setq value (string-to-syntax value)))
1402       ;; Flush the syntax-cache.  I believe this is not necessary for
1403       ;; font-lock's use of syntax-ppss, but I'm not 100% sure and it can
1404       ;; still be necessary for other users of syntax-ppss anyway.
1405       (syntax-ppss-after-change-function start)
1406       (cond
1407        ((not override)
1408         ;; Cannot override existing fontification.
1409         (or (text-property-not-all start end 'syntax-table nil)
1410             (put-text-property start end 'syntax-table value)))
1411        ((eq override t)
1412         ;; Override existing fontification.
1413         (put-text-property start end 'syntax-table value))
1414        ((eq override 'keep)
1415         ;; Keep existing fontification.
1416         (font-lock-fillin-text-property start end 'syntax-table value))))))
1417
1418 (defun font-lock-fontify-syntactic-anchored-keywords (keywords limit)
1419   "Fontify according to KEYWORDS until LIMIT.
1420 KEYWORDS should be of the form MATCH-ANCHORED, see `font-lock-keywords',
1421 LIMIT can be modified by the value of its PRE-MATCH-FORM."
1422   (let ((matcher (nth 0 keywords)) (lowdarks (nthcdr 3 keywords)) highlights
1423         ;; Evaluate PRE-MATCH-FORM.
1424         (pre-match-value (eval (nth 1 keywords))))
1425     ;; Set LIMIT to value of PRE-MATCH-FORM or the end of line.
1426     (if (and (numberp pre-match-value) (> pre-match-value (point)))
1427         (setq limit pre-match-value)
1428       (setq limit (line-end-position)))
1429     (save-match-data
1430       ;; Find an occurrence of `matcher' before `limit'.
1431       (while (if (stringp matcher)
1432                  (re-search-forward matcher limit t)
1433                (funcall matcher limit))
1434         ;; Apply each highlight to this instance of `matcher'.
1435         (setq highlights lowdarks)
1436         (while highlights
1437           (font-lock-apply-syntactic-highlight (car highlights))
1438           (setq highlights (cdr highlights)))))
1439     ;; Evaluate POST-MATCH-FORM.
1440     (eval (nth 2 keywords))))
1441
1442 (defun font-lock-fontify-syntactic-keywords-region (start end)
1443   "Fontify according to `font-lock-syntactic-keywords' between START and END.
1444 START should be at the beginning of a line."
1445   (unless parse-sexp-lookup-properties
1446     ;; We wouldn't go through so much trouble if we didn't intend to use those
1447     ;; properties, would we?
1448     (set (make-local-variable 'parse-sexp-lookup-properties) t))
1449   ;; If `font-lock-syntactic-keywords' is a symbol, get the real keywords.
1450   (when (symbolp font-lock-syntactic-keywords)
1451     (setq font-lock-syntactic-keywords (font-lock-eval-keywords
1452                                         font-lock-syntactic-keywords)))
1453   ;; If `font-lock-syntactic-keywords' is not compiled, compile it.
1454   (unless (eq (car font-lock-syntactic-keywords) t)
1455     (setq font-lock-syntactic-keywords (font-lock-compile-keywords
1456                                         font-lock-syntactic-keywords
1457                                         t)))
1458   ;; Get down to business.
1459   (let ((case-fold-search font-lock-keywords-case-fold-search)
1460         (keywords (cddr font-lock-syntactic-keywords))
1461         keyword matcher highlights)
1462     (while keywords
1463       ;; Find an occurrence of `matcher' from `start' to `end'.
1464       (setq keyword (car keywords) matcher (car keyword))
1465       (goto-char start)
1466       (while (and (< (point) end)
1467                   (if (stringp matcher)
1468                       (re-search-forward matcher end t)
1469                     (funcall matcher end)))
1470         ;; Apply each highlight to this instance of `matcher', which may be
1471         ;; specific highlights or more keywords anchored to `matcher'.
1472         (setq highlights (cdr keyword))
1473         (while highlights
1474           (if (numberp (car (car highlights)))
1475               (font-lock-apply-syntactic-highlight (car highlights))
1476             (font-lock-fontify-syntactic-anchored-keywords (car highlights)
1477                                                            end))
1478           (setq highlights (cdr highlights))))
1479       (setq keywords (cdr keywords)))))
1480
1481 ;;; End of Syntactic regexp fontification functions.
1482 \f
1483 ;;; Syntactic fontification functions.
1484
1485 (defvar font-lock-comment-start-skip nil
1486   "If non-nil, Font Lock mode uses this instead of `comment-start-skip'.")
1487
1488 (defvar font-lock-comment-end-skip nil
1489   "If non-nil, Font Lock mode uses this instead of `comment-end'.")
1490
1491 (defun font-lock-fontify-syntactically-region (start end &optional loudly)
1492   "Put proper face on each string and comment between START and END.
1493 START should be at the beginning of a line."
1494   (syntax-propertize end)  ; Apply any needed syntax-table properties.
1495   (let ((comment-end-regexp
1496          (or font-lock-comment-end-skip
1497              (regexp-quote
1498               (replace-regexp-in-string "^ *" "" comment-end))))
1499         ;; Find the `start' state.
1500         (state (syntax-ppss start))
1501         face beg)
1502     (if loudly (message "Fontifying %s... (syntactically...)" (buffer-name)))
1503     ;;
1504     ;; Find each interesting place between here and `end'.
1505     (while
1506         (progn
1507           (when (or (nth 3 state) (nth 4 state))
1508             (setq face (funcall font-lock-syntactic-face-function state))
1509             (setq beg (max (nth 8 state) start))
1510             (setq state (parse-partial-sexp (point) end nil nil state
1511                                             'syntax-table))
1512             (when face (put-text-property beg (point) 'face face))
1513             (when (and (eq face 'font-lock-comment-face)
1514                        (or font-lock-comment-start-skip
1515                            comment-start-skip))
1516               ;; Find the comment delimiters
1517               ;; and use font-lock-comment-delimiter-face for them.
1518               (save-excursion
1519                 (goto-char beg)
1520                 (if (looking-at (or font-lock-comment-start-skip
1521                                     comment-start-skip))
1522                     (put-text-property beg (match-end 0) 'face
1523                                        font-lock-comment-delimiter-face)))
1524               (if (looking-back comment-end-regexp (point-at-bol) t)
1525                   (put-text-property (match-beginning 0) (point) 'face
1526                                      font-lock-comment-delimiter-face))))
1527           (< (point) end))
1528       (setq state (parse-partial-sexp (point) end nil nil state
1529                                       'syntax-table)))))
1530
1531 ;;; End of Syntactic fontification functions.
1532 \f
1533 ;;; Keyword regexp fontification functions.
1534
1535 (defsubst font-lock-apply-highlight (highlight)
1536   "Apply HIGHLIGHT following a match.
1537 HIGHLIGHT should be of the form MATCH-HIGHLIGHT, see `font-lock-keywords'."
1538   (let* ((match (nth 0 highlight))
1539          (start (match-beginning match)) (end (match-end match))
1540          (override (nth 2 highlight)))
1541     (if (not start)
1542         ;; No match but we might not signal an error.
1543         (or (nth 3 highlight)
1544             (error "No match %d in highlight %S" match highlight))
1545       (let ((val (eval (nth 1 highlight))))
1546         (when (eq (car-safe val) 'face)
1547           (add-text-properties start end (cddr val))
1548           (setq val (cadr val)))
1549         (cond
1550          ((not (or val (eq override t)))
1551           ;; If `val' is nil, don't do anything.  It is important to do it
1552           ;; explicitly, because when adding nil via things like
1553           ;; font-lock-append-text-property, the property is actually
1554           ;; changed from <face> to (<face>) which is undesirable.  --Stef
1555           nil)
1556          ((not override)
1557           ;; Cannot override existing fontification.
1558           (or (text-property-not-all start end 'face nil)
1559               (put-text-property start end 'face val)))
1560          ((eq override t)
1561           ;; Override existing fontification.
1562           (put-text-property start end 'face val))
1563          ((eq override 'prepend)
1564           ;; Prepend to existing fontification.
1565           (font-lock-prepend-text-property start end 'face val))
1566          ((eq override 'append)
1567           ;; Append to existing fontification.
1568           (font-lock-append-text-property start end 'face val))
1569          ((eq override 'keep)
1570           ;; Keep existing fontification.
1571           (font-lock-fillin-text-property start end 'face val)))))))
1572
1573 (defsubst font-lock-fontify-anchored-keywords (keywords limit)
1574   "Fontify according to KEYWORDS until LIMIT.
1575 KEYWORDS should be of the form MATCH-ANCHORED, see `font-lock-keywords',
1576 LIMIT can be modified by the value of its PRE-MATCH-FORM."
1577   (let ((matcher (nth 0 keywords)) (lowdarks (nthcdr 3 keywords)) highlights
1578         (lead-start (match-beginning 0))
1579         ;; Evaluate PRE-MATCH-FORM.
1580         (pre-match-value (eval (nth 1 keywords))))
1581     ;; Set LIMIT to value of PRE-MATCH-FORM or the end of line.
1582     (if (not (and (numberp pre-match-value) (> pre-match-value (point))))
1583         (setq limit (line-end-position))
1584       (setq limit pre-match-value)
1585       (when (and font-lock-multiline (>= limit (line-beginning-position 2)))
1586         ;; this is a multiline anchored match
1587         ;; (setq font-lock-multiline t)
1588         (put-text-property (if (= limit (line-beginning-position 2))
1589                                (1- limit)
1590                              (min lead-start (point)))
1591                            limit
1592                            'font-lock-multiline t)))
1593     (save-match-data
1594       ;; Find an occurrence of `matcher' before `limit'.
1595       (while (and (< (point) limit)
1596                   (if (stringp matcher)
1597                       (re-search-forward matcher limit t)
1598                     (funcall matcher limit)))
1599         ;; Apply each highlight to this instance of `matcher'.
1600         (setq highlights lowdarks)
1601         (while highlights
1602           (font-lock-apply-highlight (car highlights))
1603           (setq highlights (cdr highlights)))))
1604     ;; Evaluate POST-MATCH-FORM.
1605     (eval (nth 2 keywords))))
1606
1607 (defun font-lock-fontify-keywords-region (start end &optional loudly)
1608   "Fontify according to `font-lock-keywords' between START and END.
1609 START should be at the beginning of a line.
1610 LOUDLY, if non-nil, allows progress-meter bar."
1611   (unless (eq (car font-lock-keywords) t)
1612     (setq font-lock-keywords
1613           (font-lock-compile-keywords font-lock-keywords)))
1614   (let ((case-fold-search font-lock-keywords-case-fold-search)
1615         (keywords (cddr font-lock-keywords))
1616         (bufname (buffer-name)) (count 0)
1617         (pos (make-marker))
1618         keyword matcher highlights)
1619     ;;
1620     ;; Fontify each item in `font-lock-keywords' from `start' to `end'.
1621     (while keywords
1622       (if loudly (message "Fontifying %s... (regexps..%s)" bufname
1623                           (make-string (incf count) ?.)))
1624       ;;
1625       ;; Find an occurrence of `matcher' from `start' to `end'.
1626       (setq keyword (car keywords) matcher (car keyword))
1627       (goto-char start)
1628       (while (and (< (point) end)
1629                   (if (stringp matcher)
1630                       (re-search-forward matcher end t)
1631                     (funcall matcher end))
1632                   ;; Beware empty string matches since they will
1633                   ;; loop indefinitely.
1634                   (or (> (point) (match-beginning 0))
1635                       (progn (forward-char 1) t)))
1636         (when (and font-lock-multiline
1637                    (>= (point)
1638                        (save-excursion (goto-char (match-beginning 0))
1639                                        (forward-line 1) (point))))
1640           ;; this is a multiline regexp match
1641           ;; (setq font-lock-multiline t)
1642           (put-text-property (if (= (point)
1643                                     (save-excursion
1644                                       (goto-char (match-beginning 0))
1645                                       (forward-line 1) (point)))
1646                                  (1- (point))
1647                                (match-beginning 0))
1648                              (point)
1649                              'font-lock-multiline t))
1650         ;; Apply each highlight to this instance of `matcher', which may be
1651         ;; specific highlights or more keywords anchored to `matcher'.
1652         (setq highlights (cdr keyword))
1653         (while highlights
1654           (if (numberp (car (car highlights)))
1655               (font-lock-apply-highlight (car highlights))
1656             (set-marker pos (point))
1657             (font-lock-fontify-anchored-keywords (car highlights) end)
1658             ;; Ensure forward progress.  `pos' is a marker because anchored
1659             ;; keyword may add/delete text (this happens e.g. in grep.el).
1660             (if (< (point) pos) (goto-char pos)))
1661           (setq highlights (cdr highlights))))
1662       (setq keywords (cdr keywords)))
1663     (set-marker pos nil)))
1664
1665 ;;; End of Keyword regexp fontification functions.
1666 \f
1667 ;; Various functions.
1668
1669 (defun font-lock-compile-keywords (keywords &optional syntactic-keywords)
1670   "Compile KEYWORDS into the form (t KEYWORDS COMPILED...)
1671 Here each COMPILED is of the form (MATCHER HIGHLIGHT ...) as shown in the
1672 `font-lock-keywords' doc string.
1673 If SYNTACTIC-KEYWORDS is non-nil, it means these keywords are used for
1674 `font-lock-syntactic-keywords' rather than for `font-lock-keywords'."
1675   (if (not font-lock-set-defaults)
1676       ;; This should never happen.  But some external packages sometimes
1677       ;; call font-lock in unexpected and incorrect ways.  It's important to
1678       ;; stop processing at this point, otherwise we may end up changing the
1679       ;; global value of font-lock-keywords and break highlighting in many
1680       ;; other buffers.
1681       (error "Font-lock trying to use keywords before setting them up"))
1682   (if (eq (car-safe keywords) t)
1683       keywords
1684     (setq keywords
1685           (cons t (cons keywords
1686                         (mapcar 'font-lock-compile-keyword keywords))))
1687     (if (and (not syntactic-keywords)
1688              (let ((beg-function
1689                     (or font-lock-beginning-of-syntax-function
1690                         syntax-begin-function)))
1691                (or (eq beg-function 'beginning-of-defun)
1692                    (get beg-function 'font-lock-syntax-paren-check)))
1693              (not beginning-of-defun-function))
1694         ;; Try to detect when a string or comment contains something that
1695         ;; looks like a defun and would thus confuse font-lock.
1696         (nconc keywords
1697                `((,(if defun-prompt-regexp
1698                        (concat "^\\(?:" defun-prompt-regexp "\\)?\\s(")
1699                      "^\\s(")
1700                   (0
1701                    (if (memq (get-text-property (match-beginning 0) 'face)
1702                              '(font-lock-string-face font-lock-doc-face
1703                                font-lock-comment-face))
1704                        (list 'face font-lock-warning-face
1705                              'help-echo "Looks like a toplevel defun: escape the parenthesis"))
1706                    prepend)))))
1707     keywords))
1708
1709 (defun font-lock-compile-keyword (keyword)
1710   (cond ((nlistp keyword)                       ; MATCHER
1711          (list keyword '(0 font-lock-keyword-face)))
1712         ((eq (car keyword) 'eval)               ; (eval . FORM)
1713          (font-lock-compile-keyword (eval (cdr keyword))))
1714         ((eq (car-safe (cdr keyword)) 'quote)   ; (MATCHER . 'FORM)
1715          ;; If FORM is a FACENAME then quote it.  Otherwise ignore the quote.
1716          (if (symbolp (nth 2 keyword))
1717              (list (car keyword) (list 0 (cdr keyword)))
1718            (font-lock-compile-keyword (cons (car keyword) (nth 2 keyword)))))
1719         ((numberp (cdr keyword))                ; (MATCHER . MATCH)
1720          (list (car keyword) (list (cdr keyword) 'font-lock-keyword-face)))
1721         ((symbolp (cdr keyword))                ; (MATCHER . FACENAME)
1722          (list (car keyword) (list 0 (cdr keyword))))
1723         ((nlistp (nth 1 keyword))               ; (MATCHER . HIGHLIGHT)
1724          (list (car keyword) (cdr keyword)))
1725         (t                                      ; (MATCHER HIGHLIGHT ...)
1726          keyword)))
1727
1728 (defun font-lock-eval-keywords (keywords)
1729   "Evalulate KEYWORDS if a function (funcall) or variable (eval) name."
1730   (if (listp keywords)
1731       keywords
1732     (font-lock-eval-keywords (if (fboundp keywords)
1733                                  (funcall keywords)
1734                                (eval keywords)))))
1735
1736 (defun font-lock-value-in-major-mode (alist)
1737   "Return value in ALIST for `major-mode', or ALIST if it is not an alist.
1738 Structure is ((MAJOR-MODE . VALUE) ...) where MAJOR-MODE may be t."
1739   (if (consp alist)
1740       (cdr (or (assq major-mode alist) (assq t alist)))
1741     alist))
1742
1743 (defun font-lock-choose-keywords (keywords level)
1744   "Return LEVELth element of KEYWORDS.
1745 A LEVEL of nil is equal to a LEVEL of 0, a LEVEL of t is equal to
1746 \(1- (length KEYWORDS))."
1747   (cond ((not (and (listp keywords) (symbolp (car keywords))))
1748          keywords)
1749         ((numberp level)
1750          (or (nth level keywords) (car (last keywords))))
1751         ((eq level t)
1752          (car (last keywords)))
1753         (t
1754          (car keywords))))
1755
1756 (defvar font-lock-set-defaults nil)     ; Whether we have set up defaults.
1757
1758 (defun font-lock-refresh-defaults ()
1759   "Restart fontification in current buffer after recomputing from defaults.
1760 Recompute fontification variables using `font-lock-defaults' and
1761 `font-lock-maximum-decoration'.  Then restart fontification.
1762
1763 Use this function when you have changed any of the above
1764 variables directly.
1765
1766 Note: This function will erase modifications done by
1767 `font-lock-add-keywords' or `font-lock-remove-keywords', but will
1768 preserve `hi-lock-mode' highlighting patterns."
1769   (font-lock-mode -1)
1770   (kill-local-variable 'font-lock-set-defaults)
1771   (font-lock-mode 1))
1772
1773 (defvar font-lock-major-mode nil
1774   "Major mode for which the font-lock settings have been setup.")
1775 (make-variable-buffer-local 'font-lock-major-mode)
1776
1777 (defun font-lock-set-defaults ()
1778   "Set fontification defaults appropriately for this mode.
1779 Sets various variables using `font-lock-defaults' and
1780 `font-lock-maximum-decoration'."
1781   ;; Set fontification defaults if not previously set for correct major mode.
1782   (unless (and font-lock-set-defaults
1783                (eq font-lock-major-mode major-mode))
1784     (setq font-lock-major-mode major-mode)
1785     (set (make-local-variable 'font-lock-set-defaults) t)
1786     (make-local-variable 'font-lock-fontified)
1787     (make-local-variable 'font-lock-multiline)
1788     (let* ((defaults font-lock-defaults)
1789            (keywords
1790             (font-lock-choose-keywords (nth 0 defaults)
1791                                        (font-lock-value-in-major-mode font-lock-maximum-decoration)))
1792            (local (cdr (assq major-mode font-lock-keywords-alist)))
1793            (removed-keywords
1794             (cdr-safe (assq major-mode font-lock-removed-keywords-alist))))
1795       (set (make-local-variable 'font-lock-defaults) defaults)
1796       ;; Syntactic fontification?
1797       (if (nth 1 defaults)
1798           (set (make-local-variable 'font-lock-keywords-only) t)
1799         (kill-local-variable 'font-lock-keywords-only))
1800       ;; Case fold during regexp fontification?
1801       (if (nth 2 defaults)
1802           (set (make-local-variable 'font-lock-keywords-case-fold-search) t)
1803         (kill-local-variable 'font-lock-keywords-case-fold-search))
1804       ;; Syntax table for regexp and syntactic fontification?
1805       (if (null (nth 3 defaults))
1806           (kill-local-variable 'font-lock-syntax-table)
1807         (set (make-local-variable 'font-lock-syntax-table)
1808              (copy-syntax-table (syntax-table)))
1809         (dolist (selem (nth 3 defaults))
1810           ;; The character to modify may be a single CHAR or a STRING.
1811           (let ((syntax (cdr selem)))
1812             (dolist (char (if (numberp (car selem))
1813                               (list (car selem))
1814                             (mapcar 'identity (car selem))))
1815               (modify-syntax-entry char syntax font-lock-syntax-table)))))
1816       ;; Syntax function for syntactic fontification?
1817       (if (nth 4 defaults)
1818         (set (make-local-variable 'font-lock-beginning-of-syntax-function)
1819                (nth 4 defaults))
1820         (kill-local-variable 'font-lock-beginning-of-syntax-function))
1821       ;; Variable alist?
1822       (dolist (x (nthcdr 5 defaults))
1823         (set (make-local-variable (car x)) (cdr x)))
1824       ;; Set up `font-lock-keywords' last because its value might depend
1825       ;; on other settings (e.g. font-lock-compile-keywords uses
1826       ;; font-lock-beginning-of-syntax-function).
1827       (set (make-local-variable 'font-lock-keywords)
1828            (font-lock-eval-keywords keywords))
1829       ;; Local fontification?
1830       (while local
1831         (font-lock-add-keywords nil (car (car local)) (cdr (car local)))
1832         (setq local (cdr local)))
1833       (when removed-keywords
1834         (font-lock-remove-keywords nil removed-keywords))
1835       ;; Now compile the keywords.
1836       (unless (eq (car font-lock-keywords) t)
1837         (setq font-lock-keywords
1838               (font-lock-compile-keywords font-lock-keywords))))))
1839 \f
1840 ;;; Color etc. support.
1841
1842 ;; Note that `defface' will not overwrite any faces declared above via
1843 ;; `custom-declare-face'.
1844 (defface font-lock-comment-face
1845   '((((class grayscale) (background light))
1846      (:foreground "DimGray" :weight bold :slant italic))
1847     (((class grayscale) (background dark))
1848      (:foreground "LightGray" :weight bold :slant italic))
1849     (((class color) (min-colors 88) (background light))
1850      (:foreground "Firebrick"))
1851     (((class color) (min-colors 88) (background dark))
1852      (:foreground "chocolate1"))
1853     (((class color) (min-colors 16) (background light))
1854      (:foreground "red"))
1855     (((class color) (min-colors 16) (background dark))
1856      (:foreground "red1"))
1857     (((class color) (min-colors 8) (background light))
1858      (:foreground "red"))
1859     (((class color) (min-colors 8) (background dark))
1860      (:foreground "yellow"))
1861     (t (:weight bold :slant italic)))
1862   "Font Lock mode face used to highlight comments."
1863   :group 'font-lock-faces)
1864
1865 (defface font-lock-comment-delimiter-face
1866   '((default :inherit font-lock-comment-face))
1867   "Font Lock mode face used to highlight comment delimiters."
1868   :group 'font-lock-faces)
1869
1870 (defface font-lock-string-face
1871   '((((class grayscale) (background light)) (:foreground "DimGray" :slant italic))
1872     (((class grayscale) (background dark)) (:foreground "LightGray" :slant italic))
1873     (((class color) (min-colors 88) (background light)) (:foreground "VioletRed4"))
1874     (((class color) (min-colors 88) (background dark)) (:foreground "LightSalmon"))
1875     (((class color) (min-colors 16) (background light)) (:foreground "RosyBrown"))
1876     (((class color) (min-colors 16) (background dark)) (:foreground "LightSalmon"))
1877     (((class color) (min-colors 8)) (:foreground "green"))
1878     (t (:slant italic)))
1879   "Font Lock mode face used to highlight strings."
1880   :group 'font-lock-faces)
1881
1882 (defface font-lock-doc-face
1883   '((t :inherit font-lock-string-face))
1884   "Font Lock mode face used to highlight documentation."
1885   :group 'font-lock-faces)
1886
1887 (defface font-lock-keyword-face
1888   '((((class grayscale) (background light)) (:foreground "LightGray" :weight bold))
1889     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1890     (((class color) (min-colors 88) (background light)) (:foreground "Purple"))
1891     (((class color) (min-colors 88) (background dark)) (:foreground "Cyan1"))
1892     (((class color) (min-colors 16) (background light)) (:foreground "Purple"))
1893     (((class color) (min-colors 16) (background dark)) (:foreground "Cyan"))
1894     (((class color) (min-colors 8)) (:foreground "cyan" :weight bold))
1895     (t (:weight bold)))
1896   "Font Lock mode face used to highlight keywords."
1897   :group 'font-lock-faces)
1898
1899 (defface font-lock-builtin-face
1900   '((((class grayscale) (background light)) (:foreground "LightGray" :weight bold))
1901     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1902     (((class color) (min-colors 88) (background light)) (:foreground "dark slate blue"))
1903     (((class color) (min-colors 88) (background dark)) (:foreground "LightSteelBlue"))
1904     (((class color) (min-colors 16) (background light)) (:foreground "Orchid"))
1905     (((class color) (min-colors 16) (background dark)) (:foreground "LightSteelBlue"))
1906     (((class color) (min-colors 8)) (:foreground "blue" :weight bold))
1907     (t (:weight bold)))
1908   "Font Lock mode face used to highlight builtins."
1909   :group 'font-lock-faces)
1910
1911 (defface font-lock-function-name-face
1912   '((((class color) (min-colors 88) (background light)) (:foreground "Blue1"))
1913     (((class color) (min-colors 88) (background dark)) (:foreground "LightSkyBlue"))
1914     (((class color) (min-colors 16) (background light)) (:foreground "Blue"))
1915     (((class color) (min-colors 16) (background dark)) (:foreground "LightSkyBlue"))
1916     (((class color) (min-colors 8)) (:foreground "blue" :weight bold))
1917     (t (:inverse-video t :weight bold)))
1918   "Font Lock mode face used to highlight function names."
1919   :group 'font-lock-faces)
1920
1921 (defface font-lock-variable-name-face
1922   '((((class grayscale) (background light))
1923      (:foreground "Gray90" :weight bold :slant italic))
1924     (((class grayscale) (background dark))
1925      (:foreground "DimGray" :weight bold :slant italic))
1926     (((class color) (min-colors 88) (background light)) (:foreground "sienna"))
1927     (((class color) (min-colors 88) (background dark)) (:foreground "LightGoldenrod"))
1928     (((class color) (min-colors 16) (background light)) (:foreground "DarkGoldenrod"))
1929     (((class color) (min-colors 16) (background dark)) (:foreground "LightGoldenrod"))
1930     (((class color) (min-colors 8)) (:foreground "yellow" :weight light))
1931     (t (:weight bold :slant italic)))
1932   "Font Lock mode face used to highlight variable names."
1933   :group 'font-lock-faces)
1934
1935 (defface font-lock-type-face
1936   '((((class grayscale) (background light)) (:foreground "Gray90" :weight bold))
1937     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1938     (((class color) (min-colors 88) (background light)) (:foreground "ForestGreen"))
1939     (((class color) (min-colors 88) (background dark)) (:foreground "PaleGreen"))
1940     (((class color) (min-colors 16) (background light)) (:foreground "ForestGreen"))
1941     (((class color) (min-colors 16) (background dark)) (:foreground "PaleGreen"))
1942     (((class color) (min-colors 8)) (:foreground "green"))
1943     (t (:weight bold :underline t)))
1944   "Font Lock mode face used to highlight type and classes."
1945   :group 'font-lock-faces)
1946
1947 (defface font-lock-constant-face
1948   '((((class grayscale) (background light))
1949      (:foreground "LightGray" :weight bold :underline t))
1950     (((class grayscale) (background dark))
1951      (:foreground "Gray50" :weight bold :underline t))
1952     (((class color) (min-colors 88) (background light)) (:foreground "dark cyan"))
1953     (((class color) (min-colors 88) (background dark)) (:foreground "Aquamarine"))
1954     (((class color) (min-colors 16) (background light)) (:foreground "CadetBlue"))
1955     (((class color) (min-colors 16) (background dark)) (:foreground "Aquamarine"))
1956     (((class color) (min-colors 8)) (:foreground "magenta"))
1957     (t (:weight bold :underline t)))
1958   "Font Lock mode face used to highlight constants and labels."
1959   :group 'font-lock-faces)
1960
1961 (defface font-lock-warning-face
1962   '((((class color) (min-colors 88) (background light)) (:foreground "Red1" :weight bold))
1963     (((class color) (min-colors 88) (background dark)) (:foreground "Pink" :weight bold))
1964     (((class color) (min-colors 16) (background light)) (:foreground "Red1" :weight bold))
1965     (((class color) (min-colors 16) (background dark)) (:foreground "Pink" :weight bold))
1966     (((class color) (min-colors 8)) (:foreground "red"))
1967     (t (:inverse-video t :weight bold)))
1968   "Font Lock mode face used to highlight warnings."
1969   :group 'font-lock-faces)
1970
1971 (defface font-lock-negation-char-face
1972   '((t nil))
1973   "Font Lock mode face used to highlight easy to overlook negation."
1974   :group 'font-lock-faces)
1975
1976 (defface font-lock-preprocessor-face
1977   '((t :inherit font-lock-builtin-face))
1978   "Font Lock mode face used to highlight preprocessor directives."
1979   :group 'font-lock-faces)
1980
1981 (defface font-lock-regexp-grouping-backslash
1982   '((t :inherit bold))
1983   "Font Lock mode face for backslashes in Lisp regexp grouping constructs."
1984   :group 'font-lock-faces)
1985
1986 (defface font-lock-regexp-grouping-construct
1987   '((t :inherit bold))
1988   "Font Lock mode face used to highlight grouping constructs in Lisp regexps."
1989   :group 'font-lock-faces)
1990
1991 ;;; End of Color etc. support.
1992 \f
1993 ;;; Menu support.
1994
1995 ;; This section of code is commented out because Emacs does not have real menu
1996 ;; buttons.  (We can mimic them by putting "( ) " or "(X) " at the beginning of
1997 ;; the menu entry text, but with Xt it looks both ugly and embarrassingly
1998 ;; amateur.)  If/When Emacs gets real menus buttons, put in menu-bar.el after
1999 ;; the entry for "Text Properties" something like:
2000 ;;
2001 ;; (define-key menu-bar-edit-menu [font-lock]
2002 ;;   (cons "Syntax Highlighting" font-lock-menu))
2003 ;;
2004 ;; and remove a single ";" from the beginning of each line in the rest of this
2005 ;; section.  Probably the mechanism for telling the menu code what are menu
2006 ;; buttons and when they are on or off needs tweaking.  I have assumed that the
2007 ;; mechanism is via `menu-toggle' and `menu-selected' symbol properties.  sm.
2008
2009 ;;;;;###autoload
2010 ;;(progn
2011 ;;  ;; Make the Font Lock menu.
2012 ;;  (defvar font-lock-menu (make-sparse-keymap "Syntax Highlighting"))
2013 ;;  ;; Add the menu items in reverse order.
2014 ;;  (define-key font-lock-menu [fontify-less]
2015 ;;    '("Less In Current Buffer" . font-lock-fontify-less))
2016 ;;  (define-key font-lock-menu [fontify-more]
2017 ;;    '("More In Current Buffer" . font-lock-fontify-more))
2018 ;;  (define-key font-lock-menu [font-lock-sep]
2019 ;;    '("--"))
2020 ;;  (define-key font-lock-menu [font-lock-mode]
2021 ;;    '("In Current Buffer" . font-lock-mode))
2022 ;;  (define-key font-lock-menu [global-font-lock-mode]
2023 ;;    '("In All Buffers" . global-font-lock-mode)))
2024 ;;
2025 ;;;;;###autoload
2026 ;;(progn
2027 ;;  ;; We put the appropriate `menu-enable' etc. symbol property values on when
2028 ;;  ;; font-lock.el is loaded, so we don't need to autoload the three variables.
2029 ;;  (put 'global-font-lock-mode 'menu-toggle t)
2030 ;;  (put 'font-lock-mode 'menu-toggle t)
2031 ;;  (put 'font-lock-fontify-more 'menu-enable '(identity))
2032 ;;  (put 'font-lock-fontify-less 'menu-enable '(identity)))
2033 ;;
2034 ;; ;; Put the appropriate symbol property values on now.  See above.
2035 ;;(put 'global-font-lock-mode 'menu-selected 'global-font-lock-mode)
2036 ;;(put 'font-lock-mode 'menu-selected 'font-lock-mode)
2037 ;;(put 'font-lock-fontify-more 'menu-enable '(nth 2 font-lock-fontify-level))
2038 ;;(put 'font-lock-fontify-less 'menu-enable '(nth 1 font-lock-fontify-level))
2039 ;;
2040 ;;(defvar font-lock-fontify-level nil)  ; For less/more fontification.
2041 ;;
2042 ;;(defun font-lock-fontify-level (level)
2043 ;;  (let ((font-lock-maximum-decoration level))
2044 ;;    (when font-lock-mode
2045 ;;      (font-lock-mode))
2046 ;;    (font-lock-mode)
2047 ;;    (when font-lock-verbose
2048 ;;      (message "Fontifying %s... level %d" (buffer-name) level))))
2049 ;;
2050 ;;(defun font-lock-fontify-less ()
2051 ;;  "Fontify the current buffer with less decoration.
2052 ;;See `font-lock-maximum-decoration'."
2053 ;;  (interactive)
2054 ;;  ;; Check in case we get called interactively.
2055 ;;  (if (nth 1 font-lock-fontify-level)
2056 ;;      (font-lock-fontify-level (1- (car font-lock-fontify-level)))
2057 ;;    (error "No less decoration")))
2058 ;;
2059 ;;(defun font-lock-fontify-more ()
2060 ;;  "Fontify the current buffer with more decoration.
2061 ;;See `font-lock-maximum-decoration'."
2062 ;;  (interactive)
2063 ;;  ;; Check in case we get called interactively.
2064 ;;  (if (nth 2 font-lock-fontify-level)
2065 ;;      (font-lock-fontify-level (1+ (car font-lock-fontify-level)))
2066 ;;    (error "No more decoration")))
2067 ;;
2068 ;; ;; This should be called by `font-lock-set-defaults'.
2069 ;;(defun font-lock-set-menu ()
2070 ;;  ;; Activate less/more fontification entries if there are multiple levels for
2071 ;;  ;; the current buffer.  Sets `font-lock-fontify-level' to be of the form
2072 ;;  ;; (CURRENT-LEVEL IS-LOWER-LEVEL-P IS-HIGHER-LEVEL-P) for menu activation.
2073 ;;  (let ((keywords (nth 0 font-lock-defaults))
2074 ;;      (level (font-lock-value-in-major-mode font-lock-maximum-decoration)))
2075 ;;    (make-local-variable 'font-lock-fontify-level)
2076 ;;    (if (or (symbolp keywords) (= (length keywords) 1))
2077 ;;      (font-lock-unset-menu)
2078 ;;      (cond ((eq level t)
2079 ;;           (setq level (1- (length keywords))))
2080 ;;          ((or (null level) (zerop level))
2081 ;;           ;; The default level is usually, but not necessarily, level 1.
2082 ;;           (setq level (- (length keywords)
2083 ;;                          (length (member (eval (car keywords))
2084 ;;                                          (mapcar 'eval (cdr keywords))))))))
2085 ;;      (setq font-lock-fontify-level (list level (> level 1)
2086 ;;                                        (< level (1- (length keywords))))))))
2087 ;;
2088 ;; ;; This should be called by `font-lock-unset-defaults'.
2089 ;;(defun font-lock-unset-menu ()
2090 ;;  ;; Deactivate less/more fontification entries.
2091 ;;  (setq font-lock-fontify-level nil))
2092
2093 ;;; End of Menu support.
2094 \f
2095 ;;; Various regexp information shared by several modes.
2096 ;; ;; Information specific to a single mode should go in its load library.
2097
2098 ;; Font Lock support for C, C++, Objective-C and Java modes is now in
2099 ;; cc-fonts.el (and required by cc-mode.el).  However, the below function
2100 ;; should stay in font-lock.el, since it is used by other libraries.  sm.
2101
2102 (defun font-lock-match-c-style-declaration-item-and-skip-to-next (limit)
2103   "Match, and move over, any declaration/definition item after point.
2104 Matches after point, but ignores leading whitespace and `*' characters.
2105 Does not move further than LIMIT.
2106
2107 The expected syntax of a declaration/definition item is `word' (preceded by
2108 optional whitespace and `*' characters and proceeded by optional whitespace)
2109 optionally followed by a `('.  Everything following the item (but belonging to
2110 it) is expected to be skip-able by `scan-sexps', and items are expected to be
2111 separated with a `,' and to be terminated with a `;'.
2112
2113 Thus the regexp matches after point:    word (
2114                                         ^^^^ ^
2115 Where the match subexpressions are:       1  2
2116
2117 The item is delimited by (match-beginning 1) and (match-end 1).
2118 If (match-beginning 2) is non-nil, the item is followed by a `('.
2119
2120 This function could be MATCHER in a MATCH-ANCHORED `font-lock-keywords' item."
2121   (when (looking-at "[ \n\t*]*\\(\\sw+\\)[ \t\n]*\\(((?\\)?")
2122     (when (and (match-end 2) (> (- (match-end 2) (match-beginning 2)) 1))
2123       ;; If `word' is followed by a double open-paren, it's probably
2124       ;; a macro used for "int myfun P_ ((int arg1))".  Let's go back one
2125       ;; word to try and match `myfun' rather than `P_'.
2126       (let ((pos (point)))
2127         (skip-chars-backward " \t\n")
2128         (skip-syntax-backward "w")
2129         (unless (looking-at "\\(\\sw+\\)[ \t\n]*\\sw+[ \t\n]*\\(((?\\)?")
2130           ;; Looks like it was something else, so go back to where we
2131           ;; were and reset the match data by rematching.
2132           (goto-char pos)
2133           (looking-at "[ \n\t*]*\\(\\sw+\\)[ \t\n]*\\(((?\\)?"))))
2134     (save-match-data
2135       (condition-case nil
2136           (save-restriction
2137             ;; Restrict to the LIMIT.
2138             (narrow-to-region (point-min) limit)
2139             (goto-char (match-end 1))
2140             ;; Move over any item value, etc., to the next item.
2141             (while (not (looking-at "[ \t\n]*\\(\\(,\\)\\|;\\|\\'\\)"))
2142               (goto-char (or (scan-sexps (point) 1) (point-max))))
2143             (if (match-end 2)
2144                 (goto-char (match-end 2))))
2145         (error t)))))
2146
2147 ;; C preprocessor(cpp) is used outside of C, C++ and Objective-C source file.
2148 ;; e.g. assembler code and GNU linker script in Linux kernel.
2149 ;; `cpp-font-lock-keywords' is handy for modes for the files.
2150 ;;
2151 ;; Here we cannot use `regexp-opt' because because regex-opt is not preloaded
2152 ;; while font-lock.el is preloaded to emacs. So values pre-calculated with
2153 ;; regexp-opt are used here.
2154
2155 ;; `cpp-font-lock-keywords-source-directives' is calculated from:
2156 ;;
2157 ;;          (regexp-opt
2158 ;;           '("define"  "elif" "else" "endif" "error" "file" "if" "ifdef"
2159 ;;             "ifndef" "import" "include" "line" "pragma" "undef" "warning"))
2160 ;;
2161 (defconst cpp-font-lock-keywords-source-directives
2162   "define\\|e\\(?:l\\(?:if\\|se\\)\\|ndif\\|rror\\)\\|file\\|i\\(?:f\\(?:n?def\\)?\\|mport\\|nclude\\)\\|line\\|pragma\\|undef\\|warning"
2163   "Regular expression used in `cpp-font-lock-keywords'.")
2164
2165 ;; `cpp-font-lock-keywords-source-depth' is calculated from:
2166 ;;
2167 ;;          (regexp-opt-depth (regexp-opt
2168 ;;                     '("define"  "elif" "else" "endif" "error" "file" "if" "ifdef"
2169 ;;                       "ifndef" "import" "include" "line" "pragma" "undef" "warning")))
2170 ;;
2171 (defconst cpp-font-lock-keywords-source-depth 0
2172   "An integer representing regular expression depth of `cpp-font-lock-keywords-source-directives'.
2173 Used in `cpp-font-lock-keywords'.")
2174
2175 (defconst cpp-font-lock-keywords
2176   (let* ((directives cpp-font-lock-keywords-source-directives)
2177          (directives-depth cpp-font-lock-keywords-source-depth))
2178     (list
2179      ;;
2180      ;; Fontify error directives.
2181      '("^#[ \t]*\\(?:error\\|warning\\)[ \t]+\\(.+\\)" 1 font-lock-warning-face prepend)
2182      ;;
2183      ;; Fontify filenames in #include <...> preprocessor directives as strings.
2184      '("^#[ \t]*\\(?:import\\|include\\)[ \t]*\\(<[^>\"\n]*>?\\)"
2185        1 font-lock-string-face prepend)
2186      ;;
2187      ;; Fontify function macro names.
2188      '("^#[ \t]*define[ \t]+\\([[:alpha:]_][[:alnum:]_$]*\\)("
2189        (1 font-lock-function-name-face prepend)
2190        ;;
2191        ;; Macro arguments.
2192        ((lambda (limit)
2193           (re-search-forward
2194            "\\(?:\\([[:alpha:]_][[:alnum:]_]*\\)[,]?\\)"
2195            (or (save-excursion (re-search-forward ")" limit t))
2196                limit)
2197            t))
2198         nil nil (1 font-lock-variable-name-face prepend)))
2199      ;;
2200      ;; Fontify symbol names in #elif or #if ... defined preprocessor directives.
2201      '("^#[ \t]*\\(?:elif\\|if\\)\\>"
2202        ("\\<\\(defined\\)\\>[ \t]*(?\\([[:alpha:]_][[:alnum:]_]*\\)?" nil nil
2203         (1 font-lock-builtin-face prepend) (2 font-lock-variable-name-face prepend t)))
2204      ;;
2205      ;; Fontify otherwise as symbol names, and the preprocessor directive names.
2206      (list
2207       (concat "^\\(#[ \t]*\\(?:" directives
2208               "\\)\\)\\>[ \t!]*\\([[:alpha:]_][[:alnum:]_]*\\)?")
2209       '(1 font-lock-preprocessor-face prepend)
2210       (list (+ 2 directives-depth)
2211             'font-lock-variable-name-face nil t))))
2212   "Font lock keywords for C preprocessor directives.
2213 `c-mode', `c++-mode' and `objc-mode' have their own font lock keywords
2214 for C preprocessor directives.  This definition is for the other modes
2215 in which C preprocessor directives are used. e.g. `asm-mode' and
2216 `ld-script-mode'.")
2217
2218 \f
2219 ;; Lisp.
2220
2221 (defconst lisp-font-lock-keywords-1
2222   (eval-when-compile
2223     `(;; Definitions.
2224       (,(concat "(\\(def\\("
2225                 ;; Function declarations.
2226                 "\\(advice\\|alias\\|generic\\|macro\\*?\\|method\\|"
2227                 "setf\\|subst\\*?\\|un\\*?\\|"
2228                 "ine-\\(condition\\|"
2229                 "\\(?:derived\\|\\(?:global\\(?:ized\\)?-\\)?minor\\|generic\\)-mode\\|"
2230                 "method-combination\\|setf-expander\\|skeleton\\|widget\\|"
2231                 "function\\|\\(compiler\\|modify\\|symbol\\)-macro\\)\\)\\|"
2232                 ;; Variable declarations.
2233                 "\\(const\\(ant\\)?\\|custom\\|varalias\\|face\\|parameter\\|var\\)\\|"
2234                 ;; Structure declarations.
2235                 "\\(class\\|group\\|theme\\|package\\|struct\\|type\\)"
2236                 "\\)\\)\\>"
2237                 ;; Any whitespace and defined object.
2238                 "[ \t'\(]*"
2239                 "\\(setf[ \t]+\\sw+\\|\\sw+\\)?")
2240        (1 font-lock-keyword-face)
2241        (9 (cond ((match-beginning 3) font-lock-function-name-face)
2242                 ((match-beginning 6) font-lock-variable-name-face)
2243                 (t font-lock-type-face))
2244           nil t))
2245       ;; Emacs Lisp autoload cookies.  Supports the slightly different
2246       ;; forms used by mh-e, calendar, etc.
2247       ("^;;;###\\([-a-z]*autoload\\)" 1 font-lock-warning-face prepend)
2248       ;; Regexp negated char group.
2249       ("\\[\\(\\^\\)" 1 font-lock-negation-char-face prepend)))
2250   "Subdued level highlighting for Lisp modes.")
2251
2252 (defconst lisp-font-lock-keywords-2
2253   (append lisp-font-lock-keywords-1
2254    (eval-when-compile
2255      `(;; Control structures.  Emacs Lisp forms.
2256        (,(concat
2257           "(" (regexp-opt
2258                '("cond" "if" "while" "while-no-input" "let" "let*"
2259                  "prog" "progn" "progv" "prog1" "prog2" "prog*"
2260                  "inline" "lambda" "save-restriction" "save-excursion"
2261                  "save-selected-window" "save-window-excursion"
2262                  "save-match-data" "save-current-buffer"
2263                  "combine-after-change-calls" "unwind-protect"
2264                  "condition-case" "condition-case-no-debug"
2265                  "track-mouse" "eval-after-load" "eval-and-compile"
2266                  "eval-when-compile" "eval-when" "eval-next-after-load"
2267                  "with-case-table" "with-category-table"
2268                  "with-current-buffer" "with-demoted-errors"
2269                  "with-electric-help"
2270                  "with-local-quit" "with-no-warnings"
2271                  "with-output-to-string" "with-output-to-temp-buffer"
2272                  "with-selected-window" "with-selected-frame"
2273                  "with-silent-modifications" "with-syntax-table"
2274                  "with-temp-buffer" "with-temp-file" "with-temp-message"
2275                  "with-timeout" "with-timeout-handler") t)
2276           "\\>")
2277           .  1)
2278        ;; Control structures.  Common Lisp forms.
2279        (,(concat
2280           "(" (regexp-opt
2281                '("when" "unless" "case" "ecase" "typecase" "etypecase"
2282                  "ccase" "ctypecase" "handler-case" "handler-bind"
2283                  "restart-bind" "restart-case" "in-package"
2284                  "break" "ignore-errors"
2285                  "loop" "do" "do*" "dotimes" "dolist" "the" "locally"
2286                  "proclaim" "declaim" "declare" "symbol-macrolet" "letf"
2287                  "lexical-let" "lexical-let*" "flet" "labels" "compiler-let"
2288                  "destructuring-bind" "macrolet" "tagbody" "block" "go"
2289                  "multiple-value-bind" "multiple-value-prog1"
2290                  "return" "return-from"
2291                  "with-accessors" "with-compilation-unit"
2292                  "with-condition-restarts" "with-hash-table-iterator"
2293                  "with-input-from-string" "with-open-file"
2294                  "with-open-stream" "with-output-to-string"
2295                  "with-package-iterator" "with-simple-restart"
2296                  "with-slots" "with-standard-io-syntax") t)
2297           "\\>")
2298           . 1)
2299        ;; Exit/Feature symbols as constants.
2300        (,(concat "(\\(catch\\|throw\\|featurep\\|provide\\|require\\)\\>"
2301                  "[ \t']*\\(\\sw+\\)?")
2302         (1 font-lock-keyword-face)
2303         (2 font-lock-constant-face nil t))
2304        ;; Erroneous structures.
2305        ("(\\(abort\\|assert\\|warn\\|check-type\\|cerror\\|error\\|signal\\)\\>" 1 font-lock-warning-face)
2306        ;; Words inside \\[] tend to be for `substitute-command-keys'.
2307        ("\\\\\\\\\\[\\(\\sw+\\)\\]" 1 font-lock-constant-face prepend)
2308        ;; Words inside `' tend to be symbol names.
2309        ("`\\(\\sw\\sw+\\)'" 1 font-lock-constant-face prepend)
2310        ;; Constant values.
2311        ("\\<:\\sw+\\>" 0 font-lock-builtin-face)
2312        ;; ELisp and CLisp `&' keywords as types.
2313        ("\\<\\&\\sw+\\>" . font-lock-type-face)
2314        ;; ELisp regexp grouping constructs
2315        ((lambda (bound)
2316           (catch 'found
2317             ;; The following loop is needed to continue searching after matches
2318             ;; that do not occur in strings.  The associated regexp matches one
2319             ;; of `\\\\' `\\(' `\\(?:' `\\|' `\\)'.  `\\\\' has been included to
2320             ;; avoid highlighting, for example, `\\(' in `\\\\('.
2321             (while (re-search-forward "\\(\\\\\\\\\\)\\(?:\\(\\\\\\\\\\)\\|\\((\\(?:\\?[0-9]*:\\)?\\|[|)]\\)\\)" bound t)
2322               (unless (match-beginning 2)
2323                 (let ((face (get-text-property (1- (point)) 'face)))
2324                   (when (or (and (listp face)
2325                                  (memq 'font-lock-string-face face))
2326                             (eq 'font-lock-string-face face))
2327                     (throw 'found t)))))))
2328         (1 'font-lock-regexp-grouping-backslash prepend)
2329         (3 'font-lock-regexp-grouping-construct prepend))
2330 ;;;  This is too general -- rms.
2331 ;;;  A user complained that he has functions whose names start with `do'
2332 ;;;  and that they get the wrong color.
2333 ;;;      ;; CL `with-' and `do-' constructs
2334 ;;;      ("(\\(\\(do-\\|with-\\)\\(\\s_\\|\\w\\)*\\)" 1 font-lock-keyword-face)
2335       )))
2336   "Gaudy level highlighting for Lisp modes.")
2337
2338 (defvar lisp-font-lock-keywords lisp-font-lock-keywords-1
2339   "Default expressions to highlight in Lisp modes.")
2340 \f
2341 (provide 'font-lock)
2342
2343 ;;; font-lock.el ends here