configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 dnl _ON results in a '--without' option in the --help output, so
 149 dnl the help text should refer to "don't compile", etc.
 150 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 151 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 152 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 153 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 154 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 155 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 156 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 157 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 158
 159 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 160 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 161 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 162
 163 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 164 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 165 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 166 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 167
 168 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 169 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 170 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 171 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 172 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 173
 174 ## For the times when you want to build Emacs but don't have
 175 ## a suitable makeinfo, and can live without the manuals.
 176 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 177 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 178
 179 ## This is an option because I do not know if all info/man support
 180 ## compressed files, nor how to test if they do so.
 181 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 182 if test $with_compress_info = yes; then
 183    GZIP_INFO=yes
 184 else
 185    GZIP_INFO=
 186 fi
 187 AC_SUBST(GZIP_INFO)
 188
 189 AC_ARG_WITH([pkg-config-prog],dnl
 190 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 191                   [path to pkg-config for finding GTK and librsvg])])
 192 if test "X${with_pkg_config_prog}" != X; then
 193    if test "${with_pkg_config_prog}" != yes; then
 194       PKG_CONFIG="${with_pkg_config_prog}"
 195    fi
 196 fi
 197
 198 CRT_DIR=
 199 AC_ARG_WITH([crt-dir],dnl
 200 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 201 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 202 CRT_DIR="${with_crt_dir}"
 203
 204 AC_ARG_WITH(gameuser,dnl
 205 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 206 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 207   && gameuser="${with_gameuser}"
 208 test "X$gameuser" = X && gameuser=games
 209
 210 AC_ARG_WITH([gnustep-conf],dnl
 211 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 212 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 213   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 214 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 215      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 216
 217 AC_ARG_ENABLE(ns-self-contained,
 218 [AS_HELP_STRING([--disable-ns-self-contained],
 219                 [disable self contained build under NeXTstep])],
 220    EN_NS_SELF_CONTAINED=$enableval,
 221    EN_NS_SELF_CONTAINED=yes)
 222
 223 AC_ARG_ENABLE(asserts,
 224 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 225       USE_XASSERTS=$enableval,
 226       USE_XASSERTS=no)
 227
 228 AC_ARG_ENABLE(maintainer-mode,
 229 [AS_HELP_STRING([--enable-maintainer-mode],
 230                 [enable make rules and dependencies not useful (and sometimes
 231                  confusing) to the casual installer])],
 232       USE_MAINTAINER_MODE=$enableval,
 233       USE_MAINTAINER_MODE=no)
 234 if test $USE_MAINTAINER_MODE = yes; then
 235   MAINT=
 236 else
 237   MAINT=#
 238 fi
 239 AC_SUBST(MAINT)
 240
 241 AC_ARG_ENABLE(locallisppath,
 242 [AS_HELP_STRING([--enable-locallisppath=PATH],
 243                 [directories Emacs should search for lisp files specific
 244                  to this site])],
 245 if test "${enableval}" = "no"; then
 246   locallisppath=
 247 elif test "${enableval}" != "yes"; then
 248   locallisppath=${enableval}
 249 fi)
 250
 251 AC_ARG_ENABLE(checking,
 252 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 253                 [enable expensive run-time checks.  With LIST,
 254                  enable only specific categories of checks.
 255                  Categories are: all,yes,no.
 256                  Flags are: stringbytes, stringoverrun, stringfreelist,
 257                  xmallocoverrun, conslist])],
 258 [ac_checking_flags="${enableval}"],[])
 259 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 260 for check in $ac_checking_flags
 261 do
 262         case $check in
 263         # these set all the flags to specific states
 264         yes)            ac_enable_checking=1 ;;
 265         no)             ac_enable_checking= ;
 266                         ac_gc_check_stringbytes= ;
 267                         ac_gc_check_string_overrun= ;
 268                         ac_gc_check_string_free_list= ;
 269                         ac_xmalloc_overrun= ;
 270                         ac_gc_check_cons_list= ;;
 271         all)            ac_enable_checking=1 ;
 272                         ac_gc_check_stringbytes=1 ;
 273                         ac_gc_check_string_overrun=1 ;
 274                         ac_gc_check_string_free_list=1 ;
 275                         ac_xmalloc_overrun=1 ;
 276                         ac_gc_check_cons_list=1 ;;
 277         # these enable particular checks
 278         stringbytes)    ac_gc_check_stringbytes=1 ;;
 279         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 280         stringfreelist) ac_gc_check_string_free_list=1 ;;
 281         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 282         conslist)       ac_gc_check_cons_list=1 ;;
 283         *)      AC_MSG_ERROR(unknown check category $check) ;;
 284         esac
 285 done
 286 IFS="$ac_save_IFS"
 287
 288 if test x$ac_enable_checking != x ; then
 289   AC_DEFINE(ENABLE_CHECKING, 1,
 290 [Enable expensive run-time checking of data types?])
 291 fi
 292 if test x$ac_gc_check_stringbytes != x ; then
 293   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 294 [Define this temporarily to hunt a bug.  If defined, the size of
 295    strings is redundantly recorded in sdata structures so that it can
 296    be compared to the sizes recorded in Lisp strings.])
 297 fi
 298 if test x$ac_gc_check_stringoverrun != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 300 [Define this to check for short string overrun.])
 301 fi
 302 if test x$ac_gc_check_string_free_list != x ; then
 303   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 304 [Define this to check the string free list.])
 305 fi
 306 if test x$ac_xmalloc_overrun != x ; then
 307   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 308 [Define this to check for malloc buffer overrun.])
 309 fi
 310 if test x$ac_gc_check_cons_list != x ; then
 311   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 312 [Define this to check for errors in cons list.])
 313 fi
 314
 315 AC_ARG_ENABLE(use-lisp-union-type,
 316 [AS_HELP_STRING([--enable-use-lisp-union-type],
 317                 [use a union for the Lisp_Object data type.
 318                 This is only useful for development for catching certain types of bugs.])],
 319 if test "${enableval}" != "no"; then
 320    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 321    [Define this to use a lisp union for the Lisp_Object data type.])
 322 fi)
 323
 324
 325 AC_ARG_ENABLE(profiling,
 326 [AS_HELP_STRING([--enable-profiling],
 327                 [build emacs with profiling support.
 328                  This might not work on all platforms])],
 329 [ac_enable_profiling="${enableval}"],[])
 330 if test x$ac_enable_profiling != x ; then
 331    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 332 else
 333    PROFILING_CFLAGS=
 334 fi
 335 AC_SUBST(PROFILING_CFLAGS)
 336
 337 AC_ARG_ENABLE(autodepend,
 338 [AS_HELP_STRING([--enable-autodepend],
 339                 [automatically generate dependencies to .h-files.
 340                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 341                  found])],
 342 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 343
 344 #### Make srcdir absolute, if it isn't already.  It's important to
 345 #### avoid running the path through pwd unnecessarily, since pwd can
 346 #### give you automounter prefixes, which can go away.  We do all this
 347 #### so Emacs can find its files when run uninstalled.
 348 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 349 unset CDPATH
 350 case "${srcdir}" in
 351   /* ) ;;
 352   . )
 353     ## We may be able to use the $PWD environment variable to make this
 354     ## absolute.  But sometimes PWD is inaccurate.
 355     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 356     ## but that tested only for a well-formed and valid PWD,
 357     ## it did not object when PWD was well-formed and valid but just wrong.
 358     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 359     then
 360       srcdir="$PWD"
 361     else
 362       srcdir="`(cd ${srcdir}; pwd)`"
 363     fi
 364   ;;
 365   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 366 esac
 367
 368 #### Check if the source directory already has a configured system in it.
 369 if test `pwd` != `(cd ${srcdir} && pwd)` \
 370    && test -f "${srcdir}/src/config.h" ; then
 371   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 372    as a build directory right now; it has been configured in its own
 373    right.  To configure in another directory as well, you MUST
 374    use GNU make.  If you do not have GNU make, then you must
 375    now do `make distclean' in ${srcdir},
 376    and then run $0 again.]])
 377 fi
 378
 379 #### Given the configuration name, set machfile and opsysfile to the
 380 #### names of the m/*.h and s/*.h files we should use.
 381
 382 ### Canonicalize the configuration name.
 383
 384 AC_CANONICAL_HOST
 385 canonical=$host
 386 configuration=${host_alias-${build_alias-$host}}
 387
 388 dnl This used to use changequote, but, apart from `changequote is evil'
 389 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 390 dnl the great gob of text.  Thus it's not processed for possible expansion.
 391 dnl Just make sure the brackets remain balanced.
 392 dnl
 393 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 394 dnl indicated by comments.
 395 dnl quotation begins
 396 [
 397
 398 ### If you add support for a new configuration, add code to this
 399 ### switch statement to recognize your configuration name and select
 400 ### the appropriate operating system and machine description files.
 401
 402 ### You would hope that you could choose an m/*.h file pretty much
 403 ### based on the machine portion of the configuration name, and an s/*.h
 404 ### file based on the operating system portion.  However, it turns out
 405 ### that each m/*.h file is pretty manufacturer-specific - for
 406 ### example mips.h is MIPS
 407 ### So we basically have to have a special case for each
 408 ### configuration name.
 409 ###
 410 ### As far as handling version numbers on operating systems is
 411 ### concerned, make sure things will fail in a fixable way.  If
 412 ### /etc/MACHINES doesn't say anything about version numbers, be
 413 ### prepared to handle anything reasonably.  If version numbers
 414 ### matter, be sure /etc/MACHINES says something about it.
 415
 416 machine='' opsys='' unported=no
 417 case "${canonical}" in
 418
 419   ## GNU/Linux ports
 420   *-*-linux-gnu*)
 421     opsys=gnu-linux
 422     case ${canonical} in
 423       alpha*)   machine=alpha ;;
 424       s390-*)   machine=ibms390 ;;
 425       s390x-*)  machine=ibms390x ;;
 426       powerpc*) machine=macppc ;;
 427       sparc*)   machine=sparc ;;
 428       ia64*)    machine=ia64 ;;
 429       m68k*)    machine=m68k ;;
 430       x86_64*)  machine=amdx86-64 ;;
 431     esac
 432   ;;
 433
 434   ## FreeBSD ports
 435   *-*-freebsd* )
 436     opsys=freebsd
 437     case "${canonical}" in
 438       alpha*)           machine=alpha ;;
 439       amd64-*|x86_64-*) machine=amdx86-64 ;;
 440       ia64-*)           machine=ia64 ;;
 441       i[3456]86-*)      machine=intel386 ;;
 442       powerpc-*)        machine=macppc ;;
 443       sparc-*)          machine=sparc ;;
 444       sparc64-*)        machine=sparc ;;
 445     esac
 446   ;;
 447
 448   ## FreeBSD kernel + glibc based userland
 449   *-*-kfreebsd*gnu* )
 450     opsys=gnu-kfreebsd
 451     case "${canonical}" in
 452       alpha*)           machine=alpha ;;
 453       amd64-*|x86_64-*) machine=amdx86-64 ;;
 454       ia64-*)           machine=ia64 ;;
 455       i[3456]86-*)      machine=intel386 ;;
 456       powerpc-*)        machine=macppc ;;
 457       sparc-*)          machine=sparc ;;
 458       sparc64-*)        machine=sparc ;;
 459     esac
 460   ;;
 461
 462   ## NetBSD ports
 463   *-*-netbsd* )
 464     opsys=netbsd
 465     case "${canonical}" in
 466       alpha*)      machine=alpha ;;
 467       x86_64-*)    machine=amdx86-64 ;;
 468       i[3456]86-*) machine=intel386 ;;
 469       m68k-*)      machine=m68k ;;
 470       powerpc-*)   machine=macppc ;;
 471       sparc*-)     machine=sparc ;;
 472       vax-*)       machine=vax ;;
 473     esac
 474   ;;
 475
 476   ## OpenBSD ports
 477   *-*-openbsd* )
 478     opsys=openbsd
 479     case "${canonical}" in
 480       alpha*)    machine=alpha ;;
 481       x86_64-*)  machine=amdx86-64 ;;
 482       i386-*)    machine=intel386 ;;
 483       powerpc-*) machine=macppc ;;
 484       sparc*)    machine=sparc ;;
 485       vax-*)     machine=vax ;;
 486     esac
 487   ;;
 488
 489   ## Apple Darwin / Mac OS X
 490   *-apple-darwin* )
 491     case "${canonical}" in
 492       i[3456]86-* )  machine=intel386 ;;
 493       powerpc-* )    machine=macppc ;;
 494       x86_64-* )     machine=amdx86-64 ;;
 495       * )            unported=yes ;;
 496     esac
 497     opsys=darwin
 498     # Define CPP as follows to make autoconf work correctly.
 499     CPP="${CC-cc} -E -no-cpp-precomp"
 500     # Use fink packages if available.
 501     if test -d /sw/include && test -d /sw/lib; then
 502       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 503       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 504       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 505     fi
 506   ;;
 507
 508   ## HP 9000 series 700 and 800, running HP/UX
 509   hppa*-hp-hpux10.2* )
 510     opsys=hpux10-20
 511   ;;
 512   hppa*-hp-hpux1[1-9]* )
 513     opsys=hpux11
 514     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 515   ;;
 516
 517   ## IBM machines
 518   rs6000-ibm-aix4.[23]* )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   powerpc-ibm-aix4.[23]*  )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524   rs6000-ibm-aix[56]* )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527   powerpc-ibm-aix[56]*  )
 528     machine=ibmrs6000 opsys=aix4-2
 529   ;;
 530
 531   ## Silicon Graphics machines
 532   ## Iris 4D
 533   mips-sgi-irix6.5 )
 534     machine=iris4d opsys=irix6-5
 535     # Without defining _LANGUAGE_C, things get masked out in the headers
 536     # so that, for instance, grepping for `free' in stdlib.h fails and
 537     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 538     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 539     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 540   ;;
 541
 542   ## Suns
 543   *-sun-solaris* \
 544     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 545     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 546     case "${canonical}" in
 547       i[3456]86-*-* )     machine=intel386 ;;
 548       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 549       sparc* )          machine=sparc ;;
 550       * )               unported=yes ;;
 551     esac
 552     case "${canonical}" in
 553       *-sunos5.6* | *-solaris2.6* )
 554                 opsys=sol2-6
 555                 NON_GNU_CPP=/usr/ccs/lib/cpp
 556                 RANLIB="ar -ts"
 557                 ;;
 558       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 559                 opsys=sol2-6
 560                 emacs_check_sunpro_c=yes
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 ;;
 563       *-sunos5* | *-solaris* )
 564                 opsys=sol2-10
 565                 emacs_check_sunpro_c=yes
 566                 NON_GNU_CPP=/usr/ccs/lib/cpp
 567                 ;;
 568     esac
 569     ## Watch out for a compiler that we know will not work.
 570     case "${canonical}" in
 571      *-solaris* | *-sunos5* )
 572                 if [ "x$CC" = x/usr/ucb/cc ]; then
 573                   ## /usr/ucb/cc doesn't work;
 574                   ## we should find some other compiler that does work.
 575                   unset CC
 576                 fi
 577                 ;;
 578       *) ;;
 579     esac
 580   ;;
 581
 582   ## Intel 386 machines where we don't care about the manufacturer.
 583   i[3456]86-*-* )
 584     machine=intel386
 585     case "${canonical}" in
 586       *-cygwin )                opsys=cygwin ;;
 587       *-darwin* )               opsys=darwin
 588                                 CPP="${CC-cc} -E -no-cpp-precomp"
 589                                 ;;
 590       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 591       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 592       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 593       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 594     esac
 595   ;;
 596
 597   * )
 598     unported=yes
 599   ;;
 600 esac
 601
 602 ### If the code above didn't choose an operating system, just choose
 603 ### an operating system based on the configuration name.  You really
 604 ### only want to use this when you have no idea what the right
 605 ### operating system is; if you know what operating systems a machine
 606 ### runs, it's cleaner to make it explicit in the case statement
 607 ### above.
 608 if test x"${opsys}" = x; then
 609   case "${canonical}" in
 610     *-gnu* )                            opsys=gnu ;;
 611     * )
 612       unported=yes
 613     ;;
 614   esac
 615 fi
 616
 617 ]
 618 dnl quotation ends
 619
 620 if test $unported = yes; then
 621   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 622 Check `etc/MACHINES' for recognized configuration names.])
 623 fi
 624
 625 if test -n "$machine"; then
 626   machfile="m/${machine}.h"
 627 else
 628   machfile=
 629 fi
 630 opsysfile="s/${opsys}.h"
 631
 632
 633 #### Choose a compiler.
 634 test -n "$CC" && cc_specified=yes
 635
 636 # Save the value of CFLAGS that the user specified.
 637 SPECIFIED_CFLAGS="$CFLAGS"
 638
 639 dnl Sets GCC=yes if using gcc.
 640 AC_PROG_CC
 641
 642 # On Suns, sometimes $CPP names a directory.
 643 if test -n "$CPP" && test -d "$CPP"; then
 644   CPP=
 645 fi
 646
 647 ## If not using gcc, and on Solaris, and no CPP specified, see if
 648 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 649 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 650  test x"$CPP" = x; then
 651   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 652   AC_CACHE_VAL(emacs_cv_sunpro_c,
 653   [AC_TRY_LINK([],
 654 [#ifndef __SUNPRO_C
 655 fail;
 656 #endif
 657 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 658   AC_MSG_RESULT($emacs_cv_sunpro_c)
 659
 660   if test x"$emacs_cv_sunpro_c" = xyes; then
 661     NON_GNU_CPP="$CC -E -Xs"
 662   fi
 663 fi
 664
 665 #### Some systems specify a CPP to use unless we are using GCC.
 666 #### Now that we know whether we are using GCC, we can decide whether
 667 #### to use that one.
 668 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 669 then
 670   CPP="$NON_GNU_CPP"
 671 fi
 672
 673 #### Some systems specify a CC to use unless we are using GCC.
 674 #### Now that we know whether we are using GCC, we can decide whether
 675 #### to use that one.
 676 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 677   test x$cc_specified != xyes
 678 then
 679   CC="$NON_GNU_CC"
 680 fi
 681
 682 if test x$GCC = xyes; then
 683   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 684 else
 685   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 686 fi
 687
 688 dnl checks for Unix variants
 689 AC_USE_SYSTEM_EXTENSIONS
 690
 691 ### Use -Wno-pointer-sign if the compiler supports it
 692 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 693 SAVE_CFLAGS="$CFLAGS"
 694 CFLAGS="$CFLAGS -Wno-pointer-sign"
 695 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 696 if test $has_option = yes; then
 697    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 698 fi
 699 AC_MSG_RESULT($has_option)
 700 CFLAGS="$SAVE_CFLAGS"
 701 unset has_option
 702 unset SAVE_CFLAGS
 703
 704 ### Use -Wdeclaration-after-statement if the compiler supports it
 705 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 706 SAVE_CFLAGS="$CFLAGS"
 707 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 708 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 709 if test $has_option = yes; then
 710    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 711 fi
 712 AC_MSG_RESULT($has_option)
 713 CFLAGS="$SAVE_CFLAGS"
 714 unset has_option
 715 unset SAVE_CFLAGS
 716
 717 ### Use -Wold-style-definition if the compiler supports it
 718 # This can be removed when conversion to standard C is finished.
 719 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 720 SAVE_CFLAGS="$CFLAGS"
 721 CFLAGS="$CFLAGS -Wold-style-definition"
 722 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 723 if test $has_option = yes; then
 724    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 725 fi
 726 AC_MSG_RESULT($has_option)
 727 CFLAGS="$SAVE_CFLAGS"
 728 unset has_option
 729 unset SAVE_CFLAGS
 730
 731 ### Use -Wimplicit-function-declaration if the compiler supports it
 732 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 733 SAVE_CFLAGS="$CFLAGS"
 734 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 735 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 736 if test $has_option = yes; then
 737    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 738 fi
 739 AC_MSG_RESULT($has_option)
 740 CFLAGS="$SAVE_CFLAGS"
 741 unset has_option
 742 unset SAVE_CFLAGS
 743
 744 AC_SUBST(C_WARNINGS_SWITCH)
 745
 746
 747 #### Some other nice autoconf tests.
 748
 749 dnl checks for programs
 750 AC_PROG_CPP
 751 AC_PROG_INSTALL
 752 if test "x$RANLIB" = x; then
 753   AC_PROG_RANLIB
 754 fi
 755
 756 ## Although we're running on an amd64 kernel, we're actually compiling for
 757 ## the x86 architecture.  The user should probably have provided an
 758 ## explicit --build to `configure', but if everything else than the kernel
 759 ## is running in i386 mode, we can help them out.
 760 if test "$machine" = "amdx86-64"; then
 761   AC_CHECK_DECL([i386])
 762   if test "$ac_cv_have_decl_i386" = "yes"; then
 763     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 764     machine=intel386
 765     machfile="m/${machine}.h"
 766   fi
 767 fi
 768
 769 AC_PATH_PROG(INSTALL_INFO, install-info)
 770 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 771 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 772 dnl Don't use GZIP, which is used by gzip for additional parameters.
 773 AC_PATH_PROG(GZIP_PROG, gzip)
 774
 775
 776 ## Need makeinfo >= 4.6 (?) to build the manuals.
 777 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 778 dnl By this stage, configure has already checked for egrep and set EGREP,
 779 dnl or exited with an error if no egrep was found.
 780 if test "$MAKEINFO" != "no" && \
 781   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 782    MAKEINFO=no
 783 fi
 784
 785 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 786 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 787 ## therefore in the category of "special tools" not normally required, which
 788 ## configure does not have to check for (eg autoconf itself).
 789 ## In a Bazaar checkout on the other hand, the manuals are not included.
 790 ## So makeinfo is a requirement to build from Bazaar, and configure
 791 ## should test for it as it does for any other build requirement.
 792 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 793 ## with pre-built manuals, from a Bazaar checkout.
 794 if test "$MAKEINFO" = "no"; then
 795   if test "x${with_makeinfo}" = "xno"; then
 796     MAKEINFO=off
 797   elif test ! -e $srcdir/info/emacs; then
 798     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 799 source tree does not seem to have pre-built manuals in the `info' directory.
 800 Either install a suitable version of makeinfo, or re-run configure
 801 with the `--without-makeinfo' option to build without the manuals.] )
 802   fi
 803 fi
 804
 805 dnl Add our options to ac_link now, after it is set up.
 806
 807 if test x$GCC = xyes; then
 808   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 809     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 810 else
 811   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 812     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 813 fi
 814
 815 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 816 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 817 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 818 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 819 dnl if not built to support GNU ld.
 820
 821 late_LDFLAGS=$LDFLAGS
 822 if test x$GCC = xyes; then
 823   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 824 else
 825   LDFLAGS="$LDFLAGS -znocombreloc"
 826 fi
 827
 828 AC_MSG_CHECKING([for -znocombreloc])
 829 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 830   [AC_MSG_RESULT(yes)],
 831   LDFLAGS=$late_LDFLAGS
 832   [AC_MSG_RESULT(no)])
 833
 834
 835 # The value of CPP is a quoted variable reference, so we need to do this
 836 # to get its actual value...
 837 CPP=`eval "echo $CPP"`
 838
 839
 840 dnl Not used by any currently supported platform.
 841 dnl The function dump-emacs will not be defined and temacs will do
 842 dnl (load "loadup") automatically unless told otherwise.
 843 CANNOT_DUMP=no
 844 case "$opsys" in
 845   your-opsys-here)
 846    CANNOT_DUMP=yes
 847    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 848   ;;
 849 esac
 850 AC_SUBST(CANNOT_DUMP)
 851
 852
 853 UNEXEC_OBJ=unexelf.o
 854 case "$opsys" in
 855   # MSDOS uses unexcoff.o
 856   # MSWindows uses unexw32.o
 857   aix4-2)
 858    UNEXEC_OBJ=unexaix.o
 859    ;;
 860   cygwin)
 861    UNEXEC_OBJ=unexcw.o
 862    ;;
 863   darwin)
 864    UNEXEC_OBJ=unexmacosx.o
 865    ;;
 866   hpux10-20 | hpux11)
 867    UNEXEC_OBJ=unexhp9k800.o
 868    ;;
 869   sol2-10)
 870    # Use the Solaris dldump() function, called from unexsol.c, to dump
 871    # emacs, instead of the generic ELF dump code found in unexelf.c.
 872    # The resulting binary has a complete symbol table, and is better
 873    # for debugging and other observability tools (debuggers, pstack, etc).
 874    #
 875    # If you encounter a problem using dldump(), please consider sending
 876    # a message to the OpenSolaris tools-linking mailing list:
 877    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 878    #
 879    # It is likely that dldump() works with older Solaris too, but this has
 880    # not been tested, so for now this change is for Solaris 10 or newer.
 881    UNEXEC_OBJ=unexsol.o
 882    ;;
 883 esac
 884
 885 LD_SWITCH_SYSTEM=
 886 case "$opsys" in
 887   freebsd)
 888    ## Let `ld' find image libs and similar things in /usr/local/lib.
 889    ## The system compiler, GCC, has apparently been modified to not
 890    ## look there, contrary to what a stock GCC would do.
 891    LD_SWITCH_SYSTEM=-L/usr/local/lib
 892    ;;
 893
 894   gnu-linux)
 895    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 896    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 897    ;;
 898
 899   netbsd)
 900    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 901    ;;
 902
 903   openbsd)
 904    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 905    ## otherwise Emacs dumps core on elf systems.
 906    LD_SWITCH_SYSTEM="-Z"
 907    ;;
 908 esac
 909 AC_SUBST(LD_SWITCH_SYSTEM)
 910
 911 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 912
 913 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 914 ## which has not been defined yet.  When this was handled with cpp,
 915 ## it was expanded to null when configure sourced the s/*.h file.
 916 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 917 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 918 ## (or somesuch), but because it is supposed to go at the _front_
 919 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 920 ## Compare with the gnu-linux case below, which added to the end
 921 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 922 ## LD_SWITCH_SYSTEM_TEMACS.
 923 case "$opsys" in
 924   netbsd|openbsd)
 925    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 926    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 927 esac
 928
 929
 930 C_SWITCH_MACHINE=
 931 if test "$machine" = "alpha"; then
 932   AC_CHECK_DECL([__ELF__])
 933   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 934     ## With ELF, make sure that all common symbols get allocated to in the
 935     ## data section.  Otherwise, the dump of temacs may miss variables in
 936     ## the shared library that have been initialized.  For example, with
 937     ## GNU libc, __malloc_initialized would normally be resolved to the
 938     ## shared library's .bss section, which is fatal.
 939     if test "x$GCC" = "xyes"; then
 940       C_SWITCH_MACHINE="-fno-common"
 941     else
 942       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 943     fi
 944   else
 945     UNEXEC_OBJ=unexalpha.o
 946   fi
 947 fi
 948 AC_SUBST(C_SWITCH_MACHINE)
 949
 950 AC_SUBST(UNEXEC_OBJ)
 951
 952 C_SWITCH_SYSTEM=
 953 ## Some programs in src produce warnings saying certain subprograms
 954 ## are too complex and need a MAXMEM value greater than 2000 for
 955 ## additional optimization.  --nils@exp-math.uni-essen.de
 956 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 957   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 958 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 959 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 960 AC_SUBST(C_SWITCH_SYSTEM)
 961
 962
 963 LIBS_SYSTEM=
 964 case "$opsys" in
 965   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 966   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 967
 968   freebsd) LIBS_SYSTEM="-lutil" ;;
 969
 970   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 971
 972   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
 973
 974   ## Motif needs -lgen.
 975   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 976 esac
 977 AC_SUBST(LIBS_SYSTEM)
 978
 979
 980 ### Make sure subsequent tests use flags consistent with the build flags.
 981
 982 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 983   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 984 else
 985   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 986 fi
 987
 988 dnl For AC_FUNC_GETLOADAVG, at least:
 989 AC_CONFIG_LIBOBJ_DIR(src)
 990
 991 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 992 AC_SYS_LARGEFILE
 993
 994
 995 ## If user specified a crt-dir, use that unconditionally.
 996 if test "X$CRT_DIR" = "X"; then
 997
 998   case "$canonical" in
 999     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1000     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1001     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1002     ## For anything else (eg /usr/lib32), it is up the user to specify
1003     ## the location (bug#5655).
1004     ## Test for crtn.o, not just the directory, because sometimes the
1005     ## directory exists but does not have the relevant files (bug#1287).
1006     ## FIXME better to test for binary compatibility somehow.
1007     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1008     ;;
1009
1010     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1011   esac
1012
1013   case "$opsys" in
1014     hpux10-20) CRT_DIR=/lib ;;
1015   esac
1016
1017   ## Default is /usr/lib.
1018   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1019
1020 else
1021
1022   ## Some platforms don't use any of these files, so it is not
1023   ## appropriate to put this test outside the if block.
1024   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1025     AC_MSG_ERROR([crt*.o not found in specified location.])
1026
1027 fi
1028
1029 AC_SUBST(CRT_DIR)
1030
1031 LIB_MATH=-lm
1032 LIB_STANDARD=
1033 START_FILES=
1034
1035 case $opsys in
1036   cygwin )
1037     LIB_MATH=
1038     START_FILES='pre-crt0.o'
1039     ;;
1040   darwin )
1041     ## Adding -lm confuses the dynamic linker, so omit it.
1042     LIB_MATH=
1043     START_FILES='pre-crt0.o'
1044     ;;
1045   freebsd )
1046     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1047     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1048     ;;
1049   gnu-linux | gnu-kfreebsd )
1050     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1051     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1052     ;;
1053   hpux10-20 | hpux11 )
1054     LIB_STANDARD=-lc
1055     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1056     ;;
1057   netbsd | openbsd )
1058     if test -f $CRT_DIR/crti.o; then
1059         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1060         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1061     else
1062         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1063         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1064     fi
1065     ;;
1066 esac
1067
1068 AC_SUBST(LIB_MATH)
1069 AC_SUBST(START_FILES)
1070
1071 dnl This function definition taken from Gnome 2.0
1072 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1073 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1074 dnl also defines GSTUFF_PKG_ERRORS on error
1075 AC_DEFUN([PKG_CHECK_MODULES], [
1076   succeeded=no
1077
1078   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1079
1080   if test "$PKG_CONFIG" = "no" ; then
1081      ifelse([$4], , [AC_MSG_ERROR([
1082       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1083   else
1084      PKG_CONFIG_MIN_VERSION=0.9.0
1085      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1086         AC_MSG_CHECKING(for $2)
1087
1088         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1089             AC_MSG_RESULT(yes)
1090             succeeded=yes
1091
1092             AC_MSG_CHECKING($1_CFLAGS)
1093             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1094             AC_MSG_RESULT($$1_CFLAGS)
1095
1096             AC_MSG_CHECKING($1_LIBS)
1097             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1098             AC_MSG_RESULT($$1_LIBS)
1099         else
1100             AC_MSG_RESULT(no)
1101             $1_CFLAGS=""
1102             $1_LIBS=""
1103             ## If we have a custom action on failure, don't print errors, but
1104             ## do set a variable so people can do so.
1105             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1106             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1107         fi
1108
1109         AC_SUBST($1_CFLAGS)
1110         AC_SUBST($1_LIBS)
1111      else
1112         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1113         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1114      fi
1115   fi
1116
1117   if test $succeeded = yes; then
1118      ifelse([$3], , :, [$3])
1119   else
1120      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1121   fi
1122 ])
1123
1124
1125 if test "${with_sound}" != "no"; then
1126   # Sound support for GNU/Linux and the free BSDs.
1127   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1128     have_sound_header=yes)
1129   # Emulation library used on NetBSD.
1130   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1131   AC_SUBST(LIBSOUND)
1132
1133   ALSA_REQUIRED=1.0.0
1134   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1135   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1136   if test $HAVE_ALSA = yes; then
1137     SAVE_CFLAGS="$CFLAGS"
1138     SAVE_LDFLAGS="$LDFLAGS"
1139     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1140     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1141     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1142                     emacs_alsa_normal=yes,
1143                     emacs_alsa_normal=no)
1144     if test "$emacs_alsa_normal" != yes; then
1145       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1146                      [snd_lib_error_set_handler (0);],
1147                      emacs_alsa_subdir=yes,
1148                      emacs_alsa_subdir=no)
1149       if test "$emacs_alsa_subdir" != yes; then
1150         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1151       fi
1152       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1153     fi
1154
1155     CFLAGS="$SAVE_CFLAGS"
1156     LDFLAGS="$SAVE_LDFLAGS"
1157     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1158     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1159     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1160   fi
1161
1162   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1163   dnl compiles only on the specified platforms.  For others, it
1164   dnl probably doesn't make sense to try.
1165   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1166      case "$opsys" in
1167        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1168        gnu-linux|freebsd|netbsd)
1169          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1170          ;;
1171      esac
1172   fi
1173
1174   AC_SUBST(CFLAGS_SOUND)
1175 fi
1176
1177 dnl checks for header files
1178 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1179   linux/version.h sys/systeminfo.h limits.h \
1180   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1181   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1182   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1183
1184 AC_MSG_CHECKING(if personality LINUX32 can be set)
1185 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1186                emacs_cv_personality_linux32=yes,
1187                emacs_cv_personality_linux32=no)
1188 AC_MSG_RESULT($emacs_cv_personality_linux32)
1189
1190 if test $emacs_cv_personality_linux32 = yes; then
1191   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1192             [Define to 1 if personality LINUX32 can be set.])
1193 fi
1194
1195 dnl On Solaris 8 there's a compilation warning for term.h because
1196 dnl it doesn't define `bool'.
1197 AC_CHECK_HEADERS(term.h, , , -)
1198 AC_HEADER_STDC
1199 AC_HEADER_TIME
1200 AC_CHECK_DECLS([sys_siglist])
1201 if test $ac_cv_have_decl_sys_siglist != yes; then
1202   # For Tru64, at least:
1203   AC_CHECK_DECLS([__sys_siglist])
1204   if test $ac_cv_have_decl___sys_siglist = yes; then
1205     AC_DEFINE(sys_siglist, __sys_siglist,
1206               [Define to any substitute for sys_siglist.])
1207   fi
1208 fi
1209 AC_HEADER_SYS_WAIT
1210
1211 dnl Some systems have utime.h but don't declare the struct anyplace.
1212 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1213 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1214 #include <sys/time.h>
1215 #include <time.h>
1216 #else
1217 #ifdef HAVE_SYS_TIME_H
1218 #include <sys/time.h>
1219 #else
1220 #include <time.h>
1221 #endif
1222 #endif
1223 #ifdef HAVE_UTIME_H
1224 #include <utime.h>
1225 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1226   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1227 if test $emacs_cv_struct_utimbuf = yes; then
1228   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1229 fi
1230
1231 dnl checks for typedefs
1232 AC_TYPE_SIGNAL
1233
1234 dnl Check for speed_t typedef.
1235 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1236   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1237     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1238 if test $emacs_cv_speed_t = yes; then
1239   AC_DEFINE(HAVE_SPEED_T, 1,
1240            [Define to 1 if `speed_t' is declared by <termios.h>.])
1241 fi
1242
1243 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1244 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1245 #include <sys/time.h>
1246 #include <time.h>
1247 #else
1248 #ifdef HAVE_SYS_TIME_H
1249 #include <sys/time.h>
1250 #else
1251 #include <time.h>
1252 #endif
1253 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1254   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1255 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1256 if test $emacs_cv_struct_timeval = yes; then
1257   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1258 fi
1259
1260 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1261 AC_TRY_COMPILE([#include <math.h>],
1262 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1263   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1264 HAVE_EXCEPTION=$emacs_cv_struct_exception
1265 if test $emacs_cv_struct_exception != yes; then
1266   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1267 fi
1268
1269 AC_CHECK_HEADERS(sys/socket.h)
1270 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1271 #if HAVE_SYS_SOCKET_H
1272 #include <sys/socket.h>
1273 #endif])
1274
1275 dnl checks for structure members
1276 AC_STRUCT_TM
1277 AC_STRUCT_TIMEZONE
1278 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1279                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1280                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1281                 [#include <time.h>])
1282 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1283                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1284                   struct ifreq.ifr_addr], , ,
1285                  [AC_INCLUDES_DEFAULT
1286 #if HAVE_SYS_SOCKET_H
1287 #include <sys/socket.h>
1288 #endif
1289 #if HAVE_NET_IF_H
1290 #include <net/if.h>
1291 #endif])
1292
1293 dnl checks for compiler characteristics
1294
1295 dnl Testing __STDC__ to determine prototype support isn't good enough.
1296 dnl DEC C, for instance, doesn't define it with default options, and
1297 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1298 dnl and void *.
1299 AC_C_PROTOTYPES
1300 AC_C_VOLATILE
1301 AC_C_CONST
1302 dnl This isn't useful because we can't turn on use of `inline' unless
1303 dnl the compiler groks `extern inline'.
1304 dnl AC_C_INLINE
1305 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1306   [AC_TRY_COMPILE(, [void * foo;],
1307                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1308 if test $emacs_cv_void_star = yes; then
1309   AC_DEFINE(POINTER_TYPE, void)
1310 else
1311   AC_DEFINE(POINTER_TYPE, char)
1312 fi
1313 AH_TEMPLATE(POINTER_TYPE,
1314             [Define as `void' if your compiler accepts `void *'; otherwise
1315              define as `char'.])dnl
1316
1317 dnl Check for endianess
1318 AC_C_BIGENDIAN
1319
1320 dnl check for Make feature
1321 AC_PROG_MAKE_SET
1322
1323 DEPFLAGS=
1324 MKDEPDIR=":"
1325 deps_frag=deps.mk
1326 dnl check for GNU Make if we have GCC and autodepend is on.
1327 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1328    AC_MSG_CHECKING([whether we are using GNU Make])
1329    HAVE_GNU_MAKE=no
1330    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1331    if test "x$testval" != x; then
1332       HAVE_GNU_MAKE=yes
1333    else
1334       ac_enable_autodepend=no
1335    fi
1336    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1337    if test $HAVE_GNU_MAKE = yes; then
1338       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1339       SAVE_CFLAGS="$CFLAGS"
1340       CFLAGS="$CFLAGS -MMD -MF deps.d"
1341       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1342       CFLAGS="$SAVE_CFLAGS"
1343       test -f deps.d || ac_enable_autodepend=no
1344       rm -rf deps.d
1345       AC_MSG_RESULT([$ac_enable_autodepend])
1346    fi
1347    if test $ac_enable_autodepend = yes; then
1348       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1349       ## In parallel builds, another make might create depdir between
1350       ## the first test and mkdir, so stick another test on the end.
1351       ## Or use mkinstalldirs?  mkdir -p is not portable.
1352       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1353       deps_frag=autodeps.mk
1354    fi
1355 fi
1356 deps_frag=$srcdir/src/$deps_frag
1357 AC_SUBST(MKDEPDIR)
1358 AC_SUBST(DEPFLAGS)
1359 AC_SUBST_FILE(deps_frag)
1360
1361
1362 dnl checks for operating system services
1363 AC_SYS_LONG_FILE_NAMES
1364
1365 #### Choose a window system.
1366
1367 AC_PATH_X
1368 if test "$no_x" = yes; then
1369   window_system=none
1370 else
1371   window_system=x11
1372 fi
1373
1374 ## Workaround for bug in autoconf <= 2.62.
1375 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1376 ## No need to do anything special for these standard directories.
1377 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1378
1379    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1380
1381 fi
1382
1383 LD_SWITCH_X_SITE_AUX=
1384 LD_SWITCH_X_SITE_AUX_RPATH=
1385 if test "${x_libraries}" != NONE; then
1386   if test -n "${x_libraries}"; then
1387     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1388     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1389     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1390   fi
1391   x_default_search_path=""
1392   x_search_path=${x_libraries}
1393   if test -z "${x_search_path}"; then
1394     x_search_path=/usr/lib
1395   fi
1396   for x_library in `echo ${x_search_path}: | \
1397                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1398     x_search_path="\
1399 ${x_library}/X11/%L/%T/%N%C%S:\
1400 ${x_library}/X11/%l/%T/%N%C%S:\
1401 ${x_library}/X11/%T/%N%C%S:\
1402 ${x_library}/X11/%L/%T/%N%S:\
1403 ${x_library}/X11/%l/%T/%N%S:\
1404 ${x_library}/X11/%T/%N%S"
1405     if test x"${x_default_search_path}" = x; then
1406       x_default_search_path=${x_search_path}
1407     else
1408       x_default_search_path="${x_search_path}:${x_default_search_path}"
1409     fi
1410   done
1411 fi
1412 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1413 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1414
1415 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1416   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1417 fi
1418
1419 if test x"${x_includes}" = x; then
1420   bitmapdir=/usr/include/X11/bitmaps
1421 else
1422   # accumulate include directories that have X11 bitmap subdirectories
1423   bmd_acc="dummyval"
1424   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1425     if test -d "${bmd}/X11/bitmaps"; then
1426       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1427     fi
1428     if test -d "${bmd}/bitmaps"; then
1429       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1430     fi
1431   done
1432   if test ${bmd_acc} != "dummyval"; then
1433     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1434   fi
1435 fi
1436
1437 HAVE_NS=no
1438 NS_IMPL_COCOA=no
1439 NS_IMPL_GNUSTEP=no
1440 tmp_CPPFLAGS="$CPPFLAGS"
1441 tmp_CFLAGS="$CFLAGS"
1442 CPPFLAGS="$CPPFLAGS -x objective-c"
1443 CFLAGS="$CFLAGS -x objective-c"
1444 TEMACS_LDFLAGS2="\${LDFLAGS}"
1445 dnl I don't think it's especially important, but src/Makefile.in
1446 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1447 dnl trailing "/" to it, so now we do it here.
1448 if test "${with_ns}" != no; then
1449   if test "${opsys}" = darwin; then
1450      NS_IMPL_COCOA=yes
1451      ns_appdir=`pwd`/nextstep/Emacs.app
1452      ns_appbindir=${ns_appdir}/Contents/MacOS/
1453      ns_appresdir=${ns_appdir}/Contents/Resources
1454      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1455   elif test -f $GNUSTEP_CONFIG_FILE; then
1456      NS_IMPL_GNUSTEP=yes
1457      ns_appdir=`pwd`/nextstep/Emacs.app
1458      ns_appbindir=${ns_appdir}/
1459      ns_appresdir=${ns_appdir}/Resources
1460      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1461      dnl FIXME sourcing this several times in subshells seems inefficient.
1462      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1463      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1464      dnl I seemed to need these as well with GNUstep-startup 0.25.
1465      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1466      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1467      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1468        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1469      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1470        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1471      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1472      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1473      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1474      LIB_STANDARD=
1475      START_FILES=
1476      TEMACS_LDFLAGS2=
1477   fi
1478   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1479                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1480   files are missing or cannot be compiled.])])
1481   NS_HAVE_NSINTEGER=yes
1482   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1483                                      [NSInteger i;])],
1484                     ns_have_nsinteger=yes,
1485                     ns_have_nsinteger=no)
1486   if test $ns_have_nsinteger = no; then
1487     NS_HAVE_NSINTEGER=no
1488   fi
1489 fi
1490 AC_SUBST(TEMACS_LDFLAGS2)
1491
1492 ns_frag=/dev/null
1493 NS_OBJ=
1494 NS_SUPPORT=
1495 if test "${HAVE_NS}" = yes; then
1496   window_system=nextstep
1497   with_xft=no
1498   # set up packaging dirs
1499   exec_prefix=${ns_appbindir}
1500   libexecdir=${ns_appbindir}/libexec
1501   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1502      prefix=${ns_appresdir}
1503   fi
1504   ns_frag=$srcdir/src/ns.mk
1505   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1506   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1507 fi
1508 CFLAGS="$tmp_CFLAGS"
1509 CPPFLAGS="$tmp_CPPFLAGS"
1510 AC_SUBST(NS_OBJ)
1511 AC_SUBST(NS_SUPPORT)
1512 AC_SUBST(LIB_STANDARD)
1513 AC_SUBST_FILE(ns_frag)
1514
1515 case "${window_system}" in
1516   x11 )
1517     HAVE_X_WINDOWS=yes
1518     HAVE_X11=yes
1519     case "${with_x_toolkit}" in
1520       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1521       motif ) USE_X_TOOLKIT=MOTIF ;;
1522       gtk ) with_gtk=yes
1523 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1524 dnl USE_X_TOOLKIT is set.
1525             USE_X_TOOLKIT=none ;;
1526       gtk3 ) with_gtk3=yes
1527              USE_X_TOOLKIT=none ;;
1528       no ) USE_X_TOOLKIT=none ;;
1529 dnl If user did not say whether to use a toolkit, make this decision later:
1530 dnl use the toolkit if we have gtk, or X11R5 or newer.
1531       * ) USE_X_TOOLKIT=maybe ;;
1532     esac
1533   ;;
1534   nextstep | none )
1535     HAVE_X_WINDOWS=no
1536     HAVE_X11=no
1537     USE_X_TOOLKIT=none
1538   ;;
1539 esac
1540
1541 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1542    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1543    if test "$HAVE_XSERVER" = true ||
1544       test -n "$DISPLAY" ||
1545       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1546         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1547 were found.  You should install the relevant development files for X
1548 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1549 sure you have development files for image handling, i.e.
1550 tiff, gif, jpeg, png and xpm.
1551 If you are sure you want Emacs compiled without X window support, pass
1552   --without-x
1553 to configure.])
1554    fi
1555 fi
1556
1557 ### If we're using X11, we should use the X menu package.
1558 HAVE_MENUS=no
1559 case ${HAVE_X11} in
1560   yes ) HAVE_MENUS=yes ;;
1561 esac
1562
1563 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1564 # Assume not, until told otherwise.
1565 GNU_MALLOC=yes
1566 doug_lea_malloc=yes
1567 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1568 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1569 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1570                emacs_cv_var___after_morecore_hook,
1571 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1572   emacs_cv_var___after_morecore_hook=yes,
1573   emacs_cv_var___after_morecore_hook=no)])
1574 if test $emacs_cv_var___after_morecore_hook = no; then
1575   doug_lea_malloc=no
1576 fi
1577
1578
1579 dnl See comments in aix4-2.h about maybe using system malloc there.
1580 system_malloc=no
1581 case "$opsys" in
1582   ## darwin ld insists on the use of malloc routines in the System framework.
1583   darwin|sol2-10) system_malloc=yes ;;
1584 esac
1585
1586 if test "${system_malloc}" = "yes"; then
1587   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1588   GNU_MALLOC=no
1589   GNU_MALLOC_reason="
1590     (The GNU allocators don't work with this system configuration.)"
1591   GMALLOC_OBJ=
1592   VMLIMIT_OBJ=
1593 else
1594   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1595   VMLIMIT_OBJ=vm-limit.o
1596 fi
1597 AC_SUBST(GMALLOC_OBJ)
1598 AC_SUBST(VMLIMIT_OBJ)
1599
1600 if test "$doug_lea_malloc" = "yes" ; then
1601   if test "$GNU_MALLOC" = yes ; then
1602     GNU_MALLOC_reason="
1603       (Using Doug Lea's new malloc from the GNU C Library.)"
1604   fi
1605   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1606             [Define to 1 if you are using the GNU C Library.])
1607
1608   ## Use mmap directly for allocating larger buffers.
1609   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1610   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1611   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1612   case "$opsys" in
1613     gnu*) REL_ALLOC=no ;;
1614   esac
1615 fi
1616
1617 if test x"${REL_ALLOC}" = x; then
1618   REL_ALLOC=${GNU_MALLOC}
1619 fi
1620
1621 use_mmap_for_buffers=no
1622 case "$opsys" in
1623   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1624 esac
1625
1626 AC_FUNC_MMAP
1627 if test $use_mmap_for_buffers = yes; then
1628   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1629   REL_ALLOC=no
1630 fi
1631
1632 LIBS="$LIBS_SYSTEM $LIBS"
1633
1634 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1635 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1636 AC_CHECK_LIB(dnet, dnet_ntoa)
1637 dnl This causes -lresolv to get used in subsequent tests,
1638 dnl which causes failures on some systems such as HPUX 9.
1639 dnl AC_CHECK_LIB(resolv, gethostbyname)
1640
1641 dnl FIXME replace main with a function we actually want from this library.
1642 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1643
1644 AC_CHECK_LIB(pthreads, cma_open)
1645
1646 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1647 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1648 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1649 ## added to LIBS in configure would never contain the pthreads part,
1650 ## but the value used in Makefiles might.  FIXME?
1651 ##
1652 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1653 ## be harmless on older versions of X where it happens to exist.
1654 test "$opsys" = "aix4-2" && \
1655   test $ac_cv_lib_pthreads_cma_open = yes && \
1656   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1657
1658 dnl Check for need for bigtoc support on IBM AIX
1659
1660 case ${host_os} in
1661 aix*)
1662   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1663     case $GCC in
1664     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1665     *) gdb_cv_bigtoc=-bbigtoc ;;
1666     esac
1667
1668     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1669     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1670   ])
1671   ;;
1672 esac
1673
1674 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1675 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1676 # REAL_CPPFLAGS later on.
1677
1678 REAL_CFLAGS="$CFLAGS"
1679 REAL_CPPFLAGS="$CPPFLAGS"
1680
1681 if test "${HAVE_X11}" = "yes"; then
1682   DEFS="$C_SWITCH_X_SITE $DEFS"
1683   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1684   LIBS="-lX11 $LIBS"
1685   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1686   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1687
1688   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1689   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1690   # but it's more convenient here to set LD_RUN_PATH
1691   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1692   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1693     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1694     export LD_RUN_PATH
1695   fi
1696
1697   if test "${opsys}" = "gnu-linux"; then
1698     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1699     AC_TRY_LINK([],
1700      [XOpenDisplay ("foo");],
1701      [xlinux_first_failure=no],
1702      [xlinux_first_failure=yes])
1703     if test "${xlinux_first_failure}" = "yes"; then
1704       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1705       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1706       OLD_CPPFLAGS="$CPPFLAGS"
1707       OLD_LIBS="$LIBS"
1708       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1709       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1710       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1711       LIBS="$LIBS -b i486-linuxaout"
1712       AC_TRY_LINK([],
1713        [XOpenDisplay ("foo");],
1714        [xlinux_second_failure=no],
1715        [xlinux_second_failure=yes])
1716       if test "${xlinux_second_failure}" = "yes"; then
1717         # If we get the same failure with -b, there is no use adding -b.
1718         # So take it out.  This plays safe.
1719         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1720         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1721         CPPFLAGS="$OLD_CPPFLAGS"
1722         LIBS="$OLD_LIBS"
1723         AC_MSG_RESULT(no)
1724       else
1725         AC_MSG_RESULT(yes)
1726       fi
1727     else
1728       AC_MSG_RESULT(no)
1729     fi
1730   fi
1731
1732   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1733   # header files included from there.
1734   AC_MSG_CHECKING(for Xkb)
1735   AC_TRY_LINK([#include <X11/Xlib.h>
1736 #include <X11/XKBlib.h>],
1737         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1738         emacs_xkb=yes, emacs_xkb=no)
1739   AC_MSG_RESULT($emacs_xkb)
1740   if test $emacs_xkb = yes; then
1741     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1742   fi
1743
1744   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1745 XScreenNumberOfScreen XSetWMProtocols)
1746 fi
1747
1748 if test "${window_system}" = "x11"; then
1749   AC_MSG_CHECKING(X11 version 6)
1750   AC_CACHE_VAL(emacs_cv_x11_version_6,
1751   [AC_TRY_LINK([#include <X11/Xlib.h>],
1752 [#if XlibSpecificationRelease < 6
1753 fail;
1754 #endif
1755 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1756   if test $emacs_cv_x11_version_6 = yes; then
1757     AC_MSG_RESULT(6 or newer)
1758     AC_DEFINE(HAVE_X11R6, 1,
1759               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1760     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1761     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1762     ## XIM support.
1763     case "$opsys" in
1764       sol2-*) : ;;
1765       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1766            [Define if you have usable X11R6-style XIM support.])
1767          ;;
1768     esac
1769   else
1770     AC_MSG_RESULT(before 6)
1771   fi
1772 fi
1773
1774
1775 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1776 HAVE_RSVG=no
1777 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1778   if test "${with_rsvg}" != "no"; then
1779     RSVG_REQUIRED=2.11.0
1780     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1781
1782     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1783     AC_SUBST(RSVG_CFLAGS)
1784     AC_SUBST(RSVG_LIBS)
1785
1786     if test $HAVE_RSVG = yes; then
1787       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1788       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1789       LIBS="$RSVG_LIBS $LIBS"
1790     fi
1791   fi
1792 fi
1793
1794 HAVE_IMAGEMAGICK=no
1795 if test "${HAVE_X11}" = "yes"; then
1796   if test "${with_imagemagick}" != "no"; then
1797     IMAGEMAGICK_MODULE="Wand"
1798     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1799     AC_SUBST(IMAGEMAGICK_CFLAGS)
1800     AC_SUBST(IMAGEMAGICK_LIBS)
1801
1802     if test $HAVE_IMAGEMAGICK = yes; then
1803       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1804       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1805       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1806       AC_CHECK_FUNCS(MagickExportImagePixels)
1807     fi
1808   fi
1809 fi
1810
1811
1812 HAVE_GTK=no
1813 if test "${with_gtk3}" = "yes"; then
1814   GLIB_REQUIRED=2.6
1815   GTK_REQUIRED=2.90
1816   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1817
1818   dnl Checks for libraries.
1819   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1820   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1821      AC_MSG_ERROR($GTK_PKG_ERRORS)
1822   fi
1823 fi
1824
1825 if test "$pkg_check_gtk" != "yes"; then
1826   HAVE_GTK=no
1827 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1828   GLIB_REQUIRED=2.6
1829   GTK_REQUIRED=2.6
1830   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1831
1832   dnl Checks for libraries.
1833   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1834   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1835      AC_MSG_ERROR($GTK_PKG_ERRORS)
1836   fi
1837 fi
1838 fi
1839
1840 GTK_OBJ=
1841 if test x"$pkg_check_gtk" = xyes; then
1842
1843   AC_SUBST(GTK_CFLAGS)
1844   AC_SUBST(GTK_LIBS)
1845   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1846   CFLAGS="$CFLAGS $GTK_CFLAGS"
1847   LIBS="$GTK_LIBS $LIBS"
1848   dnl Try to compile a simple GTK program.
1849   GTK_COMPILES=no
1850   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1851   if test "${GTK_COMPILES}" != "yes"; then
1852     if test "$USE_X_TOOLKIT" != "maybe"; then
1853       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1854     fi
1855   else
1856     HAVE_GTK=yes
1857     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1858     GTK_OBJ=gtkutil.o
1859     USE_X_TOOLKIT=none
1860     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1861       :
1862     else
1863       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1864        closing open displays.  This is no problem if you just use
1865        one display, but if you use more than one and close one of them
1866        Emacs may crash.]])
1867       sleep 3
1868     fi
1869   fi
1870
1871 fi
1872 AC_SUBST(GTK_OBJ)
1873
1874
1875 if test "${HAVE_GTK}" = "yes"; then
1876
1877   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1878   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1879   if test "$with_toolkit_scroll_bars" != no; then
1880     with_toolkit_scroll_bars=yes
1881   fi
1882
1883   dnl  Check if we have the old file selection dialog declared and
1884   dnl  in the link library.  In 2.x it may be in the library,
1885   dnl  but not declared if deprecated featured has been selected out.
1886   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1887   HAVE_GTK_FILE_SELECTION=no
1888   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1889                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1890 #include <gtk/gtk.h>])
1891   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1892     AC_CHECK_FUNCS(gtk_file_selection_new)
1893   fi
1894
1895   dnl Check if pthreads are available.  Emacs only needs this when using
1896   dnl gtk_file_chooser under Gnome.
1897     HAVE_GTK_AND_PTHREAD=no
1898     AC_CHECK_HEADERS(pthread.h)
1899     if test "$ac_cv_header_pthread_h"; then
1900       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1901     fi
1902     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1903       case "${canonical}" in
1904         *-hpux*) ;;
1905         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1906       esac
1907       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1908                [Define to 1 if you have GTK and pthread (-lpthread).])
1909     fi
1910
1911   dnl Check for functions introduced in 2.14 and later.
1912   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1913                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1914                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1915                  gtk_orientable_set_orientation)
1916
1917 fi
1918
1919 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1920 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1921 dnl also not configured.
1922 HAVE_DBUS=no
1923 DBUS_OBJ=
1924 if test "${with_dbus}" = "yes"; then
1925    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1926    if test "$HAVE_DBUS" = yes; then
1927      LIBS="$LIBS $DBUS_LIBS"
1928      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1929      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1930      DBUS_OBJ=dbusbind.o
1931    fi
1932 fi
1933 AC_SUBST(DBUS_OBJ)
1934
1935 dnl GConf has been tested under GNU/Linux only.
1936 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1937 HAVE_GCONF=no
1938 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1939    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1940    if test "$HAVE_GCONF" = yes; then
1941       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1942       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1943       AC_CHECK_FUNCS([g_type_init])
1944    fi
1945 fi
1946
1947 dnl SELinux is available for GNU/Linux only.
1948 HAVE_LIBSELINUX=no
1949 LIBSELINUX_LIBS=
1950 if test "${with_selinux}" = "yes"; then
1951    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1952    if test "$HAVE_LIBSELINUX" = yes; then
1953       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1954       LIBSELINUX_LIBS=-lselinux
1955    fi
1956 fi
1957 AC_SUBST(LIBSELINUX_LIBS)
1958
1959 HAVE_GNUTLS=no
1960 if test "${with_gnutls}" = "yes" ; then
1961   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1962   if test "${HAVE_GNUTLS}" = "yes"; then
1963     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1964   fi
1965 fi
1966 AC_SUBST(LIBGNUTLS_LIBS)
1967 AC_SUBST(LIBGNUTLS_CFLAGS)
1968
1969 dnl Do not put whitespace before the #include statements below.
1970 dnl Older compilers (eg sunos4 cc) choke on it.
1971 HAVE_XAW3D=no
1972 LUCID_LIBW=
1973 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1974   if test "$with_xaw3d" != no; then
1975     AC_MSG_CHECKING(for xaw3d)
1976     AC_CACHE_VAL(emacs_cv_xaw3d,
1977     [AC_TRY_LINK([
1978 #include <X11/Intrinsic.h>
1979 #include <X11/Xaw3d/Simple.h>],
1980       [],
1981       emacs_cv_xaw3d=yes,
1982       emacs_cv_xaw3d=no)])
1983   else
1984     emacs_cv_xaw3d=no
1985   fi
1986   if test $emacs_cv_xaw3d = yes; then
1987     AC_MSG_RESULT([yes; using Lucid toolkit])
1988     USE_X_TOOLKIT=LUCID
1989     HAVE_XAW3D=yes
1990     LUCID_LIBW=-lXaw3d
1991     AC_DEFINE(HAVE_XAW3D, 1,
1992               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1993   else
1994     AC_MSG_RESULT(no)
1995     AC_MSG_CHECKING(for libXaw)
1996     AC_CACHE_VAL(emacs_cv_xaw,
1997     [AC_TRY_LINK([
1998 #include <X11/Intrinsic.h>
1999 #include <X11/Xaw/Simple.h>],
2000       [],
2001       emacs_cv_xaw=yes,
2002       emacs_cv_xaw=no)])
2003     if test $emacs_cv_xaw = yes; then
2004       AC_MSG_RESULT([yes; using Lucid toolkit])
2005       USE_X_TOOLKIT=LUCID
2006       LUCID_LIBW=-lXaw
2007     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2008       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2009     else
2010       AC_MSG_RESULT([no; do not use toolkit by default])
2011       USE_X_TOOLKIT=none
2012     fi
2013   fi
2014 fi
2015
2016 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2017
2018 LIBXTR6=
2019 if test "${USE_X_TOOLKIT}" != "none"; then
2020   AC_MSG_CHECKING(X11 toolkit version)
2021   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2022   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2023 [#if XtSpecificationRelease < 6
2024 fail;
2025 #endif
2026 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2027   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2028   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2029     AC_MSG_RESULT(6 or newer)
2030     AC_DEFINE(HAVE_X11XTR6, 1,
2031               [Define to 1 if you have the X11R6 or newer version of Xt.])
2032     LIBXTR6="-lSM -lICE"
2033     case "$opsys" in
2034       ## Use libw.a along with X11R6 Xt.
2035       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2036     esac
2037   else
2038     AC_MSG_RESULT(before 6)
2039   fi
2040
2041 dnl If using toolkit, check whether libXmu.a exists.
2042 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2043   OLDLIBS="$LIBS"
2044   if test x$HAVE_X11XTR6 = xyes; then
2045     LIBS="-lXt -lSM -lICE $LIBS"
2046   else
2047     LIBS="-lXt $LIBS"
2048   fi
2049   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2050   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2051 fi
2052 AC_SUBST(LIBXTR6)
2053
2054 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2055 dnl Why not just test for libxmu in the normal way?
2056 LIBXMU=-lXmu
2057 case $opsys in
2058   ## These systems don't supply Xmu.
2059   hpux* | aix4-2 )
2060     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2061     ;;
2062 esac
2063 AC_SUBST(LIBXMU)
2064
2065 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2066 if test "${HAVE_X11}" = "yes"; then
2067   if test "${USE_X_TOOLKIT}" != "none"; then
2068     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2069   fi
2070 fi
2071
2072 LIBXP=
2073 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2074   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2075   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2076     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2077 int x = 5;
2078 #else
2079 Motif version prior to 2.1.
2080 #endif],
2081     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2082   if test $emacs_cv_motif_version_2_1 = yes; then
2083     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2084   else
2085     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2086     # We put this in CFLAGS temporarily to precede other -I options
2087     # that might be in CFLAGS temporarily.
2088     # We put this in CPPFLAGS where it precedes the other -I options.
2089     OLD_CPPFLAGS=$CPPFLAGS
2090     OLD_CFLAGS=$CFLAGS
2091     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2092     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2093     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2094       [int x = 5;],
2095       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2096     if test $emacs_cv_lesstif = yes; then
2097       # Make sure this -I option remains in CPPFLAGS after it is set
2098       # back to REAL_CPPFLAGS.
2099       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2100       # have those other -I options anyway.  Ultimately, having this
2101       # directory ultimately in CPPFLAGS will be enough.
2102       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2103       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2104     else
2105       CFLAGS=$OLD_CFLAGS
2106       CPPFLAGS=$OLD_CPPFLAGS
2107     fi
2108   fi
2109 fi
2110
2111 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2112 dnl using Motif or Xaw3d is available, and unless
2113 dnl --with-toolkit-scroll-bars=no was specified.
2114
2115 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2116             [Define to 1 if we should use toolkit scroll bars.])dnl
2117 USE_TOOLKIT_SCROLL_BARS=no
2118 if test "${with_toolkit_scroll_bars}" != "no"; then
2119   if test "${USE_X_TOOLKIT}" != "none"; then
2120     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2121       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2122       HAVE_XAW3D=no
2123       USE_TOOLKIT_SCROLL_BARS=yes
2124     elif test "${HAVE_XAW3D}" = "yes"; then
2125       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2126       USE_TOOLKIT_SCROLL_BARS=yes
2127     fi
2128   elif test "${HAVE_GTK}" = "yes"; then
2129     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2130     USE_TOOLKIT_SCROLL_BARS=yes
2131   elif test "${HAVE_NS}" = "yes"; then
2132     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2133     USE_TOOLKIT_SCROLL_BARS=yes
2134   fi
2135 fi
2136
2137 dnl See if XIM is available.
2138 AC_TRY_COMPILE([
2139           #include <X11/Xlib.h>
2140           #include <X11/Xresource.h>],
2141          [XIMProc  callback;],
2142          [HAVE_XIM=yes
2143          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2144          HAVE_XIM=no)
2145
2146 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2147
2148 if test "${with_xim}" != "no"; then
2149   AC_DEFINE(USE_XIM, 1,
2150             [Define to 1 if we should use XIM, if it is available.])
2151 fi
2152
2153
2154 if test "${HAVE_XIM}" != "no"; then
2155   late_CFLAGS=$CFLAGS
2156   if test "$GCC" = yes; then
2157     CFLAGS="$CFLAGS --pedantic-errors"
2158   fi
2159   AC_TRY_COMPILE([
2160 #include <X11/Xlib.h>
2161 #include <X11/Xresource.h>],
2162 [Display *display;
2163 XrmDatabase db;
2164 char *res_name;
2165 char *res_class;
2166 XIMProc  callback;
2167 XPointer *client_data;
2168 #ifndef __GNUC__
2169 /* If we're not using GCC, it's probably not XFree86, and this is
2170    probably right, but we can't use something like --pedantic-errors.  */
2171 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2172                                            char*, XIMProc, XPointer*);
2173 #endif
2174 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2175    client_data);],
2176     [emacs_cv_arg6_star=yes])
2177   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2178          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2179 either XPointer or XPointer*.])dnl
2180   if test "$emacs_cv_arg6_star" = yes; then
2181     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2182   else
2183     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2184   fi
2185   CFLAGS=$late_CFLAGS
2186 fi
2187
2188 ### Start of font-backend (under any platform) section.
2189 # (nothing here yet -- this is a placeholder)
2190 ### End of font-backend (under any platform) section.
2191
2192 ### Start of font-backend (under X11) section.
2193 if test "${HAVE_X11}" = "yes"; then
2194    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2195
2196    ## Use -lXft if available, unless `--with-xft=no'.
2197    HAVE_XFT=maybe
2198     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2199       with_xft="no";
2200     fi
2201     if test "x${with_xft}" != "xno"; then
2202
2203       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2204       ## Because xftfont.c uses XRenderQueryExtension, we also
2205       ## need to link to -lXrender.
2206       HAVE_XRENDER=no
2207       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2208       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2209         OLD_CPPFLAGS="$CPPFLAGS"
2210         OLD_CFLAGS="$CFLAGS"
2211         OLD_LIBS="$LIBS"
2212         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2213         CFLAGS="$CFLAGS $XFT_CFLAGS"
2214         XFT_LIBS="-lXrender $XFT_LIBS"
2215         LIBS="$XFT_LIBS $LIBS"
2216         AC_CHECK_HEADER(X11/Xft/Xft.h,
2217           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2218
2219         if test "${HAVE_XFT}" = "yes"; then
2220           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2221             AC_SUBST(XFT_LIBS)
2222           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2223         else
2224           CPPFLAGS="$OLD_CPPFLAGS"
2225           CFLAGS="$OLD_CFLAGS"
2226           LIBS="$OLD_LIBS"
2227         fi                        # "${HAVE_XFT}" = "yes"
2228       fi                          # "$HAVE_XFT" != no
2229     fi                            # "x${with_xft}" != "xno"
2230
2231     dnl For the "Does Emacs use" message at the end.
2232     if test "$HAVE_XFT" != "yes"; then
2233        HAVE_XFT=no
2234     fi
2235
2236
2237     HAVE_FREETYPE=no
2238     ## We used to allow building with FreeType and without Xft.
2239     ## However, the ftx font backend driver is not in good shape.
2240     if test "${HAVE_XFT}" = "yes"; then
2241       dnl As we use Xft, we anyway use freetype.
2242       dnl There's no need for additional CFLAGS and LIBS.
2243       HAVE_FREETYPE=yes
2244       FONTCONFIG_CFLAGS=
2245       FONTCONFIG_LIBS=
2246     fi
2247
2248     HAVE_LIBOTF=no
2249     if test "${HAVE_FREETYPE}" = "yes"; then
2250       AC_DEFINE(HAVE_FREETYPE, 1,
2251                 [Define to 1 if using the freetype and fontconfig libraries.])
2252       if test "${with_libotf}" != "no"; then
2253         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2254                           HAVE_LIBOTF=no)
2255         if test "$HAVE_LIBOTF" = "yes"; then
2256           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2257           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2258                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2259                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2260           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2261             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2262                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2263           fi
2264         fi
2265       fi
2266     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2267     dnl Does the new font backend require it, or can it work without it?
2268     fi
2269
2270     HAVE_M17N_FLT=no
2271     if test "${HAVE_LIBOTF}" = yes; then
2272       if test "${with_m17n_flt}" != "no"; then
2273         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2274         if test "$HAVE_M17N_FLT" = "yes"; then
2275           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2276         fi
2277       fi
2278     fi
2279 else
2280     HAVE_XFT=no
2281     HAVE_FREETYPE=no
2282     HAVE_LIBOTF=no
2283     HAVE_M17N_FLT=no
2284 fi
2285
2286 ### End of font-backend (under X11) section.
2287
2288 AC_SUBST(FREETYPE_CFLAGS)
2289 AC_SUBST(FREETYPE_LIBS)
2290 AC_SUBST(FONTCONFIG_CFLAGS)
2291 AC_SUBST(FONTCONFIG_LIBS)
2292 AC_SUBST(LIBOTF_CFLAGS)
2293 AC_SUBST(LIBOTF_LIBS)
2294 AC_SUBST(M17N_FLT_CFLAGS)
2295 AC_SUBST(M17N_FLT_LIBS)
2296
2297 ### Use -lXpm if available, unless `--with-xpm=no'.
2298 HAVE_XPM=no
2299 LIBXPM=
2300 if test "${HAVE_X11}" = "yes"; then
2301   if test "${with_xpm}" != "no"; then
2302     AC_CHECK_HEADER(X11/xpm.h,
2303       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2304     if test "${HAVE_XPM}" = "yes"; then
2305       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2306       AC_EGREP_CPP(no_return_alloc_pixels,
2307       [#include "X11/xpm.h"
2308 #ifndef XpmReturnAllocPixels
2309 no_return_alloc_pixels
2310 #endif
2311       ], HAVE_XPM=no, HAVE_XPM=yes)
2312
2313       if test "${HAVE_XPM}" = "yes"; then
2314         AC_MSG_RESULT(yes)
2315       else
2316         AC_MSG_RESULT(no)
2317       fi
2318     fi
2319   fi
2320
2321   if test "${HAVE_XPM}" = "yes"; then
2322     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2323     LIBXPM=-lXpm
2324   fi
2325 fi
2326 AC_SUBST(LIBXPM)
2327
2328 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2329 HAVE_JPEG=no
2330 LIBJPEG=
2331 if test "${HAVE_X11}" = "yes"; then
2332   if test "${with_jpeg}" != "no"; then
2333     dnl Checking for jpeglib.h can lose because of a redefinition of
2334     dnl  HAVE_STDLIB_H.
2335     AC_CHECK_HEADER(jerror.h,
2336       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2337   fi
2338
2339   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2340   if test "${HAVE_JPEG}" = "yes"; then
2341     AC_DEFINE(HAVE_JPEG)
2342     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2343         [#include <jpeglib.h>
2344          version=JPEG_LIB_VERSION
2345 ],
2346         [AC_DEFINE(HAVE_JPEG)],
2347         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2348         HAVE_JPEG=no])
2349   fi
2350   if test "${HAVE_JPEG}" = "yes"; then
2351     LIBJPEG=-ljpeg
2352   fi
2353 fi
2354 AC_SUBST(LIBJPEG)
2355
2356 ### Use -lpng if available, unless `--with-png=no'.
2357 HAVE_PNG=no
2358 LIBPNG=
2359 if test "${HAVE_X11}" = "yes"; then
2360   if test "${with_png}" != "no"; then
2361     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2362     # in /usr/include/libpng.
2363     AC_CHECK_HEADERS(png.h libpng/png.h)
2364     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2365       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2366     fi
2367   fi
2368
2369   if test "${HAVE_PNG}" = "yes"; then
2370     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2371     LIBPNG="-lpng -lz -lm"
2372   fi
2373 fi
2374 AC_SUBST(LIBPNG)
2375
2376 ### Use -ltiff if available, unless `--with-tiff=no'.
2377 HAVE_TIFF=no
2378 LIBTIFF=
2379 if test "${HAVE_X11}" = "yes"; then
2380   if test "${with_tiff}" != "no"; then
2381     AC_CHECK_HEADER(tiffio.h,
2382       [tifflibs="-lz -lm"
2383       # At least one tiff package requires the jpeg library.
2384       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2385       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2386   fi
2387
2388   if test "${HAVE_TIFF}" = "yes"; then
2389     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2390     dnl FIXME -lz -lm, as per libpng?
2391     LIBTIFF=-ltiff
2392   fi
2393 fi
2394 AC_SUBST(LIBTIFF)
2395
2396 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2397 HAVE_GIF=no
2398 LIBGIF=
2399 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2400   AC_CHECK_HEADER(gif_lib.h,
2401 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2402 # Earlier versions can crash Emacs.
2403     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2404
2405   if test "$HAVE_GIF" = yes; then
2406     LIBGIF=-lgif
2407   elif test "$HAVE_GIF" = maybe; then
2408 # If gif_lib.h but no libgif, try libungif.
2409     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2410     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2411   fi
2412
2413   if test "${HAVE_GIF}" = "yes"; then
2414     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2415   fi
2416 fi
2417 AC_SUBST(LIBGIF)
2418
2419 dnl Check for required libraries.
2420 if test "${HAVE_X11}" = "yes"; then
2421   MISSING=""
2422   WITH_NO=""
2423   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2424     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2425   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2426     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2427   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2428     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2429   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2430     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2431   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2432     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2433
2434   if test "X${MISSING}" != X; then
2435     AC_MSG_ERROR([The following required libraries were not found:
2436     $MISSING
2437 Maybe some development libraries/packages are missing?
2438 If you don't want to link with them give
2439     $WITH_NO
2440 as options to configure])
2441   fi
2442 fi
2443
2444 ### Use -lgpm if available, unless `--with-gpm=no'.
2445 HAVE_GPM=no
2446 LIBGPM=
2447 MOUSE_SUPPORT=
2448 if test "${with_gpm}" != "no"; then
2449   AC_CHECK_HEADER(gpm.h,
2450     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2451
2452   if test "${HAVE_GPM}" = "yes"; then
2453     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2454     LIBGPM=-lgpm
2455     ## May be reset below.
2456     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2457   fi
2458 fi
2459 AC_SUBST(LIBGPM)
2460
2461 dnl Check for malloc/malloc.h on darwin
2462 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2463
2464 C_SWITCH_X_SYSTEM=
2465 ### Use NeXTstep API to implement GUI.
2466 if test "${HAVE_NS}" = "yes"; then
2467   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2468   if test "${NS_IMPL_COCOA}" = "yes"; then
2469     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2470     GNU_OBJC_CFLAGS=
2471   fi
2472   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2473     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2474     # See also .m.o rule in Makefile.in */
2475     # FIXME: are all these flags really needed?  Document here why.  */
2476     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2477     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2478   fi
2479   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2480     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2481   fi
2482   # We also have mouse menus.
2483   HAVE_MENUS=yes
2484   OTHER_FILES=ns-app
2485 fi
2486
2487
2488 ### Use session management (-lSM -lICE) if available
2489 HAVE_X_SM=no
2490 LIBXSM=
2491 if test "${HAVE_X11}" = "yes"; then
2492   AC_CHECK_HEADER(X11/SM/SMlib.h,
2493     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2494
2495   if test "${HAVE_X_SM}" = "yes"; then
2496     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2497     LIBXSM="-lSM -lICE"
2498     case "$LIBS" in
2499       *-lSM*) ;;
2500       *)      LIBS="$LIBXSM $LIBS" ;;
2501     esac
2502   fi
2503 fi
2504 AC_SUBST(LIBXSM)
2505
2506 ### Use libxml (-lxml2) if available
2507 if test "${with_xml2}" != "no"; then
2508   ### I'm not sure what the version number should be, so I just guessed.
2509   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.2.0, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2510   if test "${HAVE_LIBXML2}" = "yes"; then
2511     LIBS="$LIBXML2_LIBS $LIBS"
2512     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2513     if test "${HAVE_LIBXML2}" = "yes"; then
2514       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2515     else
2516       LIBXML2_LIBS=""
2517       LIBXML2_CFLAGS=""
2518     fi
2519   fi
2520 fi
2521 AC_SUBST(LIBXML2_LIBS)
2522 AC_SUBST(LIBXML2_CFLAGS)
2523
2524 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2525 AC_CACHE_CHECK(whether netdb declares h_errno,
2526                emacs_cv_netdb_declares_h_errno,
2527 [AC_TRY_LINK([#include <netdb.h>],
2528   [return h_errno;],
2529   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2530 if test $emacs_cv_netdb_declares_h_errno = yes; then
2531   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2532 fi
2533
2534 AC_FUNC_ALLOCA
2535
2536 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2537 dnl FIXME is there an autoconf test that does the right thing, without
2538 dnl needing to call A_M_E afterwards?
2539 if test x"$ac_cv_func_alloca_works" != xyes; then
2540    AC_MSG_ERROR( [a system implementation of alloca is required] )
2541 fi
2542
2543 # fmod, logb, and frexp are found in -lm on most systems.
2544 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2545 AC_CHECK_LIB(m, sqrt)
2546
2547 # Check for mail-locking functions in a "mail" library.  Probably this should
2548 # have the same check as for liblockfile below.
2549 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2550 if test $have_mail = yes; then
2551   LIBS_MAIL=-lmail
2552   LIBS="$LIBS_MAIL $LIBS"
2553   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2554 else
2555   LIBS_MAIL=
2556 fi
2557 dnl Debian, at least:
2558 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2559 if test $have_lockfile = yes; then
2560    LIBS_MAIL=-llockfile
2561    LIBS="$LIBS_MAIL $LIBS"
2562    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2563 else
2564 # If we have the shared liblockfile, assume we must use it for mail
2565 # locking (e.g. Debian).  If we couldn't link against liblockfile
2566 # (no liblockfile.a installed), ensure that we don't need to.
2567   dnl This works for files generally, not just executables.
2568   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2569   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2570                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2571   if test $ac_cv_prog_liblockfile = yes; then
2572     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2573 This probably means that movemail could lose mail.
2574 There may be a `development' package to install containing liblockfile.])
2575   fi
2576 fi
2577 AC_CHECK_FUNCS(touchlock)
2578 AC_CHECK_HEADERS(maillock.h)
2579 AC_SUBST(LIBS_MAIL)
2580
2581 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2582 ## interlock access to the mail spool.  The alternative is a lock file named
2583 ## /usr/spool/mail/$USER.lock.
2584 mail_lock=no
2585 case "$opsys" in
2586   aix4-2) mail_lock="lockf" ;;
2587
2588   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2589
2590   ## On GNU/Linux systems, both methods are used by various mail programs.
2591   ## I assume most people are using newer mailers that have heard of flock.
2592   ## Change this if you need to.
2593   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2594   ## configure gets the right answers, and that means *NOT* using flock.
2595   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2596   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2597   ## Debian maintainer hasn't provided a clean fix for Emacs.
2598   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2599   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2600   ## correct logic.  -- fx
2601   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2602   ## liblockfile is a Free Software replacement for libmail, used on
2603   ## Debian systems and elsewhere. -rfr.
2604   gnu-*)
2605     mail_lock="flock"
2606     if test $have_mail = yes || test $have_lockfile = yes; then
2607       test $ac_cv_header_maillock_h = yes && mail_lock=no
2608     fi
2609     ;;
2610 esac
2611
2612 BLESSMAIL_TARGET=
2613 case "$mail_lock" in
2614   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2615
2616   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2617
2618   *) BLESSMAIL_TARGET="need-blessmail" ;;
2619 esac
2620 AC_SUBST(BLESSMAIL_TARGET)
2621
2622
2623 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2624 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2625 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2626 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2627 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2628 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2629 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2630 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2631 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2632 cfmakeraw cfsetspeed isnan copysign __executable_start)
2633
2634 AC_CHECK_HEADERS(sys/un.h)
2635
2636 AC_FUNC_MKTIME
2637 if test "$ac_cv_func_working_mktime" = no; then
2638   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2639 fi
2640
2641 AC_FUNC_GETLOADAVG
2642
2643 AC_FUNC_FSEEKO
2644
2645 # Configure getopt.
2646 m4_include([m4/getopt.m4])
2647 gl_GETOPT_IFELSE([
2648   gl_GETOPT_SUBSTITUTE_HEADER
2649   gl_PREREQ_GETOPT
2650   GETOPTOBJS='getopt.o getopt1.o'
2651 ])
2652 AC_SUBST(GETOPTOBJS)
2653
2654 AC_FUNC_GETPGRP
2655
2656 AC_FUNC_STRFTIME
2657
2658 # UNIX98 PTYs.
2659 AC_CHECK_FUNCS(grantpt)
2660
2661 # PTY-related GNU extensions.
2662 AC_CHECK_FUNCS(getpt)
2663
2664 # Check this now, so that we will NOT find the above functions in ncurses.
2665 # That is because we have not set up to link ncurses in lib-src.
2666 # It's better to believe a function is not available
2667 # than to expect to find it in ncurses.
2668 # Also we need tputs and friends to be able to build at all.
2669 have_tputs_et_al=true
2670 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2671 if test "$have_tputs_et_al" != true; then
2672   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2673 Maybe some development libraries/packages are missing?  Try installing
2674 libncurses-dev(el), libterminfo-dev(el) or similar.])
2675 fi
2676 # Must define this when any termcap library is found.
2677 AC_DEFINE(HAVE_LIBNCURSES, 1,
2678           [Define to 1 if you have the `ncurses' library (-lncurses).])
2679 ## FIXME This was the cpp logic, but I am not sure it is right.
2680 ## The above test has not necessarily found libncurses.
2681 HAVE_LIBNCURSES=yes
2682
2683 ## Use terminfo instead of termcap?
2684 ## Note only system files NOT using terminfo are:
2685 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2686 ## darwin|gnu without ncurses.
2687 TERMINFO=no
2688 LIBS_TERMCAP=
2689 case "$opsys" in
2690   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2691   ## hpux10-20: Use the system provided termcap(3) library.
2692   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2693   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2694   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2695
2696   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2697   ##  The ncurses library has been moved out of the System framework in
2698   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2699   ##  option to use it.
2700   darwin|gnu*)
2701     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2702     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2703       TERMINFO=yes
2704       LIBS_TERMCAP="-lncurses"
2705     fi
2706     ;;
2707
2708   freebsd)
2709     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2710     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2711     [AC_TRY_LINK([#include <osreldate.h>],
2712 [#if __FreeBSD_version < 400000
2713 fail;
2714 #endif
2715 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2716
2717     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2718
2719     if test $emacs_cv_freebsd_terminfo = yes; then
2720       TERMINFO=yes
2721       LIBS_TERMCAP="-lncurses"
2722     else
2723       LIBS_TERMCAP="-ltermcap"
2724     fi
2725     ;;
2726
2727   netbsd)
2728     if test $ac_cv_search_tputs = -lterminfo; then
2729       TERMINFO=yes
2730       LIBS_TERMCAP="-lterminfo"
2731     else
2732       LIBS_TERMCAP="-ltermcap"
2733     fi
2734     ;;
2735
2736 esac
2737
2738 case "$opsys" in
2739   ## hpux: Make sure we get select from libc rather than from libcurses
2740   ##  because libcurses on HPUX 10.10 has a broken version of select.
2741   ##  We used to use -lc -lcurses, but this may be cleaner.
2742   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2743
2744   openbsd) LIBS_TERMCAP="-lncurses" ;;
2745
2746   ## Must use system termcap, if we use any termcap.  It does special things.
2747   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2748 esac
2749
2750 TERMCAP_OBJ=tparam.o
2751 if test $TERMINFO = yes; then
2752   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2753
2754   ## Default used to be -ltermcap.  Add a case above if need something else.
2755   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2756
2757   TERMCAP_OBJ=terminfo.o
2758 fi
2759 AC_SUBST(LIBS_TERMCAP)
2760 AC_SUBST(TERMCAP_OBJ)
2761
2762
2763 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2764 resolv=no
2765 AC_TRY_LINK([#include <netinet/in.h>
2766 #include <arpa/nameser.h>
2767 #include <resolv.h>],
2768     [return res_init();],
2769     have_res_init=yes, have_res_init=no)
2770 if test "$have_res_init" = no; then
2771   OLIBS="$LIBS"
2772   LIBS="$LIBS -lresolv"
2773   AC_MSG_CHECKING(for res_init with -lresolv)
2774   AC_TRY_LINK([#include <netinet/in.h>
2775 #include <arpa/nameser.h>
2776 #include <resolv.h>],
2777     [return res_init();],
2778     have_res_init=yes, have_res_init=no)
2779   AC_MSG_RESULT($have_res_init)
2780   if test "$have_res_init" = yes ; then
2781     resolv=yes
2782   fi
2783   LIBS="$OLIBS"
2784 fi
2785
2786 if test "$have_res_init" = yes; then
2787   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2788 fi
2789
2790 # Do we need the Hesiod library to provide the support routines?
2791 LIBHESIOD=
2792 if test "$with_hesiod" != no ; then
2793   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2794   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2795      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2796                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2797   if test "$resolv" = yes ; then
2798     RESOLVLIB=-lresolv
2799   else
2800     RESOLVLIB=
2801   fi
2802   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2803         hesiod=yes, :, $RESOLVLIB)])
2804
2805   if test x"$hesiod" = xyes; then
2806     AC_DEFINE(HAVE_LIBHESIOD, 1,
2807               [Define to 1 if you have the hesiod library (-lhesiod).])
2808     LIBHESIOD=-lhesiod
2809   fi
2810 fi
2811 AC_SUBST(LIBHESIOD)
2812
2813 # Do we need libresolv (due to res_init or Hesiod)?
2814 if test "$resolv" = yes ; then
2815   AC_DEFINE(HAVE_LIBRESOLV, 1,
2816             [Define to 1 if you have the resolv library (-lresolv).])
2817   LIBRESOLV=-lresolv
2818 else
2819   LIBRESOLV=
2820 fi
2821 AC_SUBST(LIBRESOLV)
2822
2823 # These tell us which Kerberos-related libraries to use.
2824 COM_ERRLIB=
2825 CRYPTOLIB=
2826 KRB5LIB=
2827 DESLIB=
2828 KRB4LIB=
2829
2830 if test "${with_kerberos}" != no; then
2831   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2832   if test $have_com_err = yes; then
2833     COM_ERRLIB=-lcom_err
2834     LIBS="$COM_ERRLIB $LIBS"
2835     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2836   fi
2837   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2838   if test $have_crypto = yes; then
2839     CRYPTOLIB=-lcrypto
2840     LIBS="$CRYPTOLIB $LIBS"
2841     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2842   fi
2843   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2844   if test $have_k5crypto = yes; then
2845     CRYPTOLIB=-lk5crypto
2846     LIBS="$CRYPTOLIB $LIBS"
2847     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2848   fi
2849   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2850   if test $have_krb5=yes; then
2851     KRB5LIB=-lkrb5
2852     LIBS="$KRB5LIB $LIBS"
2853     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2854   fi
2855   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2856   if test "${with_kerberos5}" = no; then
2857     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2858     if test $have_des425 = yes; then
2859       DESLIB=-ldes425
2860       LIBS="$DESLIB $LIBS"
2861       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2862     else
2863       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2864       if test $have_des = yes; then
2865         DESLIB=-ldes
2866         LIBS="$DESLIB $LIBS"
2867         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2868       fi
2869     fi
2870     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2871     if test $have_krb4 = yes; then
2872       KRB4LIB=-lkrb4
2873       LIBS="$KRB4LIB $LIBS"
2874       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2875     else
2876       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2877       if test $have_krb = yes; then
2878         KRB4LIB=-lkrb
2879         LIBS="$KRB4LIB $LIBS"
2880         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2881       fi
2882     fi
2883   fi
2884
2885   if test "${with_kerberos5}" != no; then
2886     AC_CHECK_HEADERS(krb5.h,
2887       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2888                         [#include <krb5.h>])])
2889   else
2890     AC_CHECK_HEADERS(des.h,,
2891                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2892                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2893     AC_CHECK_HEADERS(krb.h,,
2894                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2895                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2896   fi
2897   AC_CHECK_HEADERS(com_err.h)
2898 fi
2899
2900 AC_SUBST(COM_ERRLIB)
2901 AC_SUBST(CRYPTOLIB)
2902 AC_SUBST(KRB5LIB)
2903 AC_SUBST(DESLIB)
2904 AC_SUBST(KRB4LIB)
2905
2906 # Solaris requires -lintl if you want strerror (which calls dgettext)
2907 # to return localized messages.
2908 AC_CHECK_LIB(intl, dgettext)
2909
2910 AC_MSG_CHECKING(whether localtime caches TZ)
2911 AC_CACHE_VAL(emacs_cv_localtime_cache,
2912 [if test x$ac_cv_func_tzset = xyes; then
2913 AC_TRY_RUN([#include <time.h>
2914 char TZ_GMT0[] = "TZ=GMT0";
2915 char TZ_PST8[] = "TZ=PST8";
2916 main()
2917 {
2918   time_t now = time ((time_t *) 0);
2919   int hour_GMT0, hour_unset;
2920   if (putenv (TZ_GMT0) != 0)
2921     exit (1);
2922   hour_GMT0 = localtime (&now)->tm_hour;
2923   unsetenv("TZ");
2924   hour_unset = localtime (&now)->tm_hour;
2925   if (putenv (TZ_PST8) != 0)
2926     exit (1);
2927   if (localtime (&now)->tm_hour == hour_GMT0)
2928     exit (1);
2929   unsetenv("TZ");
2930   if (localtime (&now)->tm_hour != hour_unset)
2931     exit (1);
2932   exit (0);
2933 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2934 [# If we have tzset, assume the worst when cross-compiling.
2935 emacs_cv_localtime_cache=yes])
2936 else
2937         # If we lack tzset, report that localtime does not cache TZ,
2938         # since we can't invalidate the cache if we don't have tzset.
2939         emacs_cv_localtime_cache=no
2940 fi])dnl
2941 AC_MSG_RESULT($emacs_cv_localtime_cache)
2942 if test $emacs_cv_localtime_cache = yes; then
2943   AC_DEFINE(LOCALTIME_CACHE, 1,
2944             [Define to 1 if localtime caches TZ.])
2945 fi
2946
2947 if test "x$HAVE_TIMEVAL" = xyes; then
2948   AC_CHECK_FUNCS(gettimeofday)
2949   if test $ac_cv_func_gettimeofday = yes; then
2950     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2951                    emacs_cv_gettimeofday_two_arguments,
2952     [AC_TRY_COMPILE([
2953 #ifdef TIME_WITH_SYS_TIME
2954 #include <sys/time.h>
2955 #include <time.h>
2956 #else
2957 #ifdef HAVE_SYS_TIME_H
2958 #include <sys/time.h>
2959 #else
2960 #include <time.h>
2961 #endif
2962 #endif],
2963       [struct timeval time;
2964        gettimeofday (&time, 0);],
2965       emacs_cv_gettimeofday_two_arguments=yes,
2966       emacs_cv_gettimeofday_two_arguments=no)])
2967     if test $emacs_cv_gettimeofday_two_arguments = no; then
2968       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2969                 [Define to 1 if gettimeofday accepts only one argument.])
2970     fi
2971   fi
2972 fi
2973
2974 ok_so_far=yes
2975 AC_CHECK_FUNC(socket, , ok_so_far=no)
2976 if test $ok_so_far = yes; then
2977   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2978 fi
2979 if test $ok_so_far = yes; then
2980   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2981 fi
2982 if test $ok_so_far = yes; then
2983 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2984   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2985             [Define to 1 if you have inet sockets.])
2986 fi
2987
2988 if test -f /usr/lpp/X11/bin/smt.exp; then
2989   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2990             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2991 fi
2992
2993 AC_MSG_CHECKING(whether system supports dynamic ptys)
2994 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2995   AC_MSG_RESULT(yes)
2996   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2997 else
2998   AC_MSG_RESULT(no)
2999 fi
3000
3001 AC_FUNC_FORK
3002
3003 dnl Adapted from Haible's version.
3004 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3005   [AC_TRY_LINK([#include <langinfo.h>],
3006     [char* cs = nl_langinfo(CODESET);],
3007     emacs_cv_langinfo_codeset=yes,
3008     emacs_cv_langinfo_codeset=no)
3009   ])
3010 if test $emacs_cv_langinfo_codeset = yes; then
3011   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3012     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3013 fi
3014
3015 AC_CHECK_TYPES(size_t)
3016
3017 AC_TYPE_MBSTATE_T
3018
3019 dnl Restrict could probably be used effectively other than in regex.c.
3020 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3021   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3022                   emacs_cv_c_restrict=yes,
3023                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3024                                   emacs_cv_c_restrict=__restrict,
3025                                   emacs_cv_c_restrict=no)])])
3026 case "$emacs_cv_c_restrict" in
3027   yes) emacs_restrict=restrict;;
3028   no) emacs_restrict="";;
3029   *) emacs_restrict="$emacs_cv_c_restrict";;
3030 esac
3031 if test "$emacs_restrict" != __restrict; then
3032   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3033     [Define to compiler's equivalent of C99 restrict keyword.
3034      Don't define if equivalent is `__restrict'.])
3035 fi
3036
3037 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3038   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3039                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3040 if test "$emacs_cv_c_restrict_arr" = yes; then
3041   AC_DEFINE(__restrict_arr, __restrict,
3042     [Define to compiler's equivalent of C99 restrict keyword in array
3043      declarations.  Define as empty for no equivalent.])
3044 fi
3045
3046 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3047 dnl how the tty code is related to POSIX and/or other versions of termios.
3048 dnl The following looks like a useful start.
3049 dnl
3050 dnl AC_SYS_POSIX_TERMIOS
3051 dnl if test $ac_cv_sys_posix_termios = yes; then
3052 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3053 dnl                                and macros for terminal control.])
3054 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3055 dnl fi
3056
3057 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3058
3059 # Set up the CFLAGS for real compilation, so we can substitute it.
3060 CFLAGS="$REAL_CFLAGS"
3061 CPPFLAGS="$REAL_CPPFLAGS"
3062
3063 ## Hack to detect a buggy GCC version.
3064 if test "x$GCC" = xyes \
3065    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3066    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3067    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3068    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3069 fi
3070
3071 #### Find out which version of Emacs this is.
3072 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3073          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3074 if test x"${version}" = x; then
3075   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3076 fi
3077 if test x"${version}" != x"$PACKAGE_VERSION"; then
3078   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3079 fi
3080
3081 ### Specify what sort of things we'll be editing into Makefile and config.h.
3082 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3083 AC_SUBST(version)
3084 AC_SUBST(configuration)
3085 ## Unused?
3086 AC_SUBST(canonical)
3087 AC_SUBST(srcdir)
3088 AC_SUBST(prefix)
3089 AC_SUBST(exec_prefix)
3090 AC_SUBST(bindir)
3091 AC_SUBST(datadir)
3092 AC_SUBST(sharedstatedir)
3093 AC_SUBST(libexecdir)
3094 AC_SUBST(mandir)
3095 AC_SUBST(infodir)
3096 AC_SUBST(lispdir)
3097 AC_SUBST(locallisppath)
3098 AC_SUBST(lisppath)
3099 AC_SUBST(x_default_search_path)
3100 AC_SUBST(etcdir)
3101 AC_SUBST(archlibdir)
3102 AC_SUBST(docdir)
3103 AC_SUBST(bitmapdir)
3104 AC_SUBST(gamedir)
3105 AC_SUBST(gameuser)
3106 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3107 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3108 ## end of LIBX_BASE, but nothing ever set it.
3109 AC_SUBST(LD_SWITCH_X_SITE)
3110 AC_SUBST(C_SWITCH_X_SITE)
3111 AC_SUBST(C_SWITCH_X_SYSTEM)
3112 AC_SUBST(CFLAGS)
3113 ## Used in lwlib/Makefile.in.
3114 AC_SUBST(X_TOOLKIT_TYPE)
3115 if test -n "${machfile}"; then
3116   M_FILE="\$(srcdir)/${machfile}"
3117 else
3118   M_FILE=
3119 fi
3120 S_FILE="\$(srcdir)/${opsysfile}"
3121 AC_SUBST(M_FILE)
3122 AC_SUBST(S_FILE)
3123 AC_SUBST(GETLOADAVG_LIBS)
3124 AC_SUBST(ns_appdir)
3125 AC_SUBST(ns_appbindir)
3126 AC_SUBST(ns_appresdir)
3127 AC_SUBST(ns_appsrc)
3128 AC_SUBST(GNU_OBJC_CFLAGS)
3129 AC_SUBST(OTHER_FILES)
3130
3131 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3132                    [Define to the canonical Emacs configuration name.])
3133 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3134                    [Define to the options passed to configure.])
3135 if test -n "$machfile"; then
3136   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3137                      [Define to the used machine dependent file.])
3138 fi
3139 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3140                    [Define to the used os dependent file.])
3141
3142 XMENU_OBJ=
3143 XOBJ=
3144 FONT_OBJ=
3145 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3146   AC_DEFINE(HAVE_X_WINDOWS, 1,
3147             [Define to 1 if you want to use the X window system.])
3148   XMENU_OBJ=xmenu.o
3149   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3150   FONT_OBJ=xfont.o
3151   if test "$HAVE_XFT" = "yes"; then
3152     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3153   elif test "$HAVE_FREETYPE" = "yes"; then
3154     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3155   fi
3156   AC_SUBST(FONT_OBJ)
3157 fi
3158 AC_SUBST(XMENU_OBJ)
3159 AC_SUBST(XOBJ)
3160 AC_SUBST(FONT_OBJ)
3161
3162 WIDGET_OBJ=
3163 MOTIF_LIBW=
3164 if test "${USE_X_TOOLKIT}" != "none" ; then
3165   WIDGET_OBJ=widget.o
3166   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3167   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3168     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3169   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3170     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3171     MOTIF_LIBW=-lXm
3172     case "$opsys" in
3173       gnu-linux)
3174         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3175         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3176         ;;
3177
3178       unixware)
3179         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3180         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3181         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3182         ;;
3183
3184       aix4-2)
3185         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3186         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3187         ;;
3188     esac
3189     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3190   fi
3191 fi
3192 AC_SUBST(WIDGET_OBJ)
3193
3194 TOOLKIT_LIBW=
3195 case "$USE_X_TOOLKIT" in
3196   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3197   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3198   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3199 esac
3200 AC_SUBST(TOOLKIT_LIBW)
3201
3202 if test "$USE_X_TOOLKIT" = "none"; then
3203   LIBXT_OTHER="\$(LIBXSM)"
3204   OLDXMENU_TARGET="really-oldXMenu"
3205 else
3206   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3207   OLDXMENU_TARGET="really-lwlib"
3208 fi
3209 AC_SUBST(LIBXT_OTHER)
3210
3211 ## The X Menu stuff is present in the X10 distribution, but missing
3212 ## from X11.  If we have X10, just use the installed library;
3213 ## otherwise, use our own copy.
3214 if test "${HAVE_X11}" = "yes" ; then
3215   AC_DEFINE(HAVE_X11, 1,
3216             [Define to 1 if you want to use version 11 of X windows.
3217              Otherwise, Emacs expects to use version 10.])
3218
3219   if test "$USE_X_TOOLKIT" = "none"; then
3220     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3221   else
3222     OLDXMENU="\${lwlibdir}/liblw.a"
3223   fi
3224   LIBXMENU="\$(OLDXMENU)"
3225   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3226   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3227 else
3228   ## For a syntactically valid Makefile; not actually used for anything.
3229   ## See comments in src/Makefile.in.
3230   OLDXMENU=nothing
3231   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3232   if test "${HAVE_X_WINDOWS}" = "yes"; then
3233     LIBXMENU="-lXMenu"
3234   else
3235     LIBXMENU=
3236   fi
3237   LIBX_OTHER=
3238   OLDXMENU_DEPS=
3239 fi
3240
3241 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3242   OLDXMENU_TARGET=
3243   OLDXMENU=nothing
3244   LIBXMENU=
3245   OLDXMENU_DEPS=
3246 fi
3247
3248 AC_SUBST(OLDXMENU_TARGET)
3249 AC_SUBST(OLDXMENU)
3250 AC_SUBST(LIBXMENU)
3251 AC_SUBST(LIBX_OTHER)
3252 AC_SUBST(OLDXMENU_DEPS)
3253
3254 if test "${HAVE_MENUS}" = "yes" ; then
3255   AC_DEFINE(HAVE_MENUS, 1,
3256             [Define to 1 if you have mouse menus.
3257              (This is automatic if you use X, but the option to specify it remains.)
3258              It is also defined with other window systems that support xmenu.c.])
3259 fi
3260
3261 if test "${GNU_MALLOC}" = "yes" ; then
3262   AC_DEFINE(GNU_MALLOC, 1,
3263             [Define to 1 if you want to use the GNU memory allocator.])
3264 fi
3265
3266 RALLOC_OBJ=
3267 if test "${REL_ALLOC}" = "yes" ; then
3268   AC_DEFINE(REL_ALLOC, 1,
3269             [Define REL_ALLOC if you want to use the relocating allocator for
3270              buffer space.])
3271
3272   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3273 fi
3274 AC_SUBST(RALLOC_OBJ)
3275
3276 if test "$opsys" = "cygwin"; then
3277   CYGWIN_OBJ="sheap.o"
3278   ## Cygwin differs because of its unexec().
3279   PRE_ALLOC_OBJ=
3280   POST_ALLOC_OBJ=lastfile.o
3281 else
3282   CYGWIN_OBJ=
3283   PRE_ALLOC_OBJ=lastfile.o
3284   POST_ALLOC_OBJ=
3285 fi
3286 AC_SUBST(CYGWIN_OBJ)
3287 AC_SUBST(PRE_ALLOC_OBJ)
3288 AC_SUBST(POST_ALLOC_OBJ)
3289
3290
3291 case "$opsys" in
3292   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3293
3294   darwin)
3295    ## The -headerpad option tells ld (see man page) to leave room at the
3296    ## end of the header for adding load commands.  Needed for dumping.
3297    ## 0x690 is the total size of 30 segment load commands (at 56
3298    ## each); under Cocoa 31 commands are required.
3299    if test "$HAVE_NS" = "yes"; then
3300      libs_nsgui="-framework AppKit"
3301      headerpad_extra=6C8
3302    else
3303      libs_nsgui=
3304      headerpad_extra=690
3305    fi
3306    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3307
3308    ## This is here because src/Makefile.in did some extra fiddling around
3309    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3310    ##   #ifndef LD_SWITCH_SYSTEM
3311    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3312    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3313    ## not using gcc, darwin system not on an alpha (ie darwin, since
3314    ## darwin + alpha does not occur).
3315    ## Because this was done in src/Makefile.in, the resulting part of
3316    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3317    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3318    ## rather than LD_SWITCH_SYSTEM.
3319    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3320      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3321    ;;
3322
3323   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3324   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3325   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3326   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3327   ## had different values in configure (in ac_link) and src/Makefile.in.
3328   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3329   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3330
3331   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3332 esac
3333
3334 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3335   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3336 fi
3337
3338 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3339
3340
3341 LD_FIRSTFLAG=
3342 ORDINARY_LINK=
3343 case "$opsys" in
3344   ## gnu: GNU needs its own crt0.
3345   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3346
3347   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3348   ## library search parth, i.e. it won't search /usr/lib for libc and
3349   ## friends.  Using -nostartfiles instead avoids this problem, and
3350   ## will also work on earlier NetBSD releases.
3351   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3352
3353   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3354   ##   MkLinux/LinuxPPC needs this.
3355   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3356   gnu-*)
3357     case "$machine" in
3358       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3359     esac
3360     ;;
3361 esac
3362
3363
3364 if test "x$ORDINARY_LINK" = "xyes"; then
3365
3366   LD_FIRSTFLAG=""
3367   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3368
3369 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3370 ## freebsd, gnu-* not on macppc|ibms390x.
3371 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3372
3373   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3374   ## places that are difficult to figure out at make time.  Fortunately,
3375   ## these same versions allow you to pass arbitrary flags on to the
3376   ## linker, so there is no reason not to use it as a linker.
3377   ##
3378   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3379   ## searching for libraries in its internal directories, so we have to
3380   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3381   LD_FIRSTFLAG="-nostdlib"
3382 fi
3383
3384 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3385 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3386
3387 AC_SUBST(LD_FIRSTFLAG)
3388
3389
3390 ## FIXME? The logic here is not precisely the same as that above.
3391 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3392 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3393 LIB_GCC=
3394 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3395
3396   case "$opsys" in
3397     freebsd|netbsd|openbsd) LIB_GCC= ;;
3398
3399     gnu-*)
3400       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3401       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3402       case $host_cpu in
3403       arm*)
3404         LIB_GCC="-lgcc_s"
3405         ;;
3406       *)
3407         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3408         ## immediately undefine it again and redefine it to empty.
3409         ## Was the C_SWITCH_X_SITE part really necessary?
3410 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3411         LIB_GCC=
3412         ;;
3413       esac
3414       ;;
3415
3416     ## Ask GCC where to find libgcc.a.
3417     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3418   esac
3419 fi                              dnl if $GCC
3420 AC_SUBST(LIB_GCC)
3421
3422
3423 TOOLTIP_SUPPORT=
3424 WINDOW_SUPPORT=
3425 ## If we're using X11/GNUstep, define some consequences.
3426 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3427   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3428   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3429   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3430   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3431
3432   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3433   test "$HAVE_X_WINDOWS" = "yes" && \
3434     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3435
3436 fi
3437 AC_SUBST(MOUSE_SUPPORT)
3438 AC_SUBST(TOOLTIP_SUPPORT)
3439 AC_SUBST(WINDOW_SUPPORT)
3440
3441
3442 AH_TOP([/* GNU Emacs site configuration template file.
3443    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3444      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3445
3446 This file is part of GNU Emacs.
3447
3448 GNU Emacs is free software: you can redistribute it and/or modify
3449 it under the terms of the GNU General Public License as published by
3450 the Free Software Foundation, either version 3 of the License, or
3451 (at your option) any later version.
3452
3453 GNU Emacs is distributed in the hope that it will be useful,
3454 but WITHOUT ANY WARRANTY; without even the implied warranty of
3455 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3456 GNU General Public License for more details.
3457
3458 You should have received a copy of the GNU General Public License
3459 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3460
3461
3462 /* No code in Emacs #includes config.h twice, but some bits of code
3463    intended to work with other packages as well (like gmalloc.c)
3464    think they can include it as many times as they like.  */
3465 #ifndef EMACS_CONFIG_H
3466 #define EMACS_CONFIG_H
3467 ])dnl
3468
3469 AH_BOTTOM([
3470 /* Define AMPERSAND_FULL_NAME if you use the convention
3471    that & in the full name stands for the login id.  */
3472 /* Turned on June 1996 supposing nobody will mind it.  */
3473 #define AMPERSAND_FULL_NAME
3474
3475 /* If using GNU, then support inline function declarations.  */
3476 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3477    generally, because even if non-gcc compilers accept `inline', they
3478    may reject `extern inline'.  */
3479 #if defined (__GNUC__)
3480 #define INLINE __inline__
3481 #else
3482 #define INLINE
3483 #endif
3484
3485 /* `subprocesses' should be defined if you want to
3486    have code for asynchronous subprocesses
3487    (as used in M-x compile and M-x shell).
3488    Only MSDOS does not support this (it overrides
3489    this in its config_opsysfile below).  */
3490
3491 #define subprocesses
3492
3493 /* Include the os and machine dependent files.  */
3494 #include config_opsysfile
3495 #ifdef config_machfile
3496 # include config_machfile
3497 #endif
3498
3499 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3500    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3501   (There is probably a better place to do this, but right now the
3502    Cocoa side does this in s/darwin.h and we cannot parallel this
3503    exactly since GNUstep is multi-OS.  */
3504 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3505 #  define SYSTEM_PURESIZE_EXTRA 30000
3506 #endif
3507
3508 /* SIGTYPE is the macro we actually use.  */
3509 #ifndef SIGTYPE
3510 #define SIGTYPE RETSIGTYPE
3511 #endif
3512
3513 #ifdef emacs /* Don't do this for lib-src.  */
3514 /* Tell regex.c to use a type compatible with Emacs.  */
3515 #define RE_TRANSLATE_TYPE Lisp_Object
3516 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3517 #ifdef make_number
3518 /* If make_number is a macro, use it.  */
3519 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3520 #else
3521 /* If make_number is a function, avoid it.  */
3522 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3523 #endif
3524 #endif
3525
3526 /* Avoid link-time collision with system mktime if we will use our own.  */
3527 #if ! HAVE_MKTIME || BROKEN_MKTIME
3528 #define mktime emacs_mktime
3529 #endif
3530
3531 #define my_strftime nstrftime   /* for strftime.c */
3532
3533 /* These default definitions are good for almost all machines.
3534    The exceptions override them in m/MACHINE.h.  */
3535
3536 #ifndef BITS_PER_CHAR
3537 #define BITS_PER_CHAR 8
3538 #endif
3539
3540 #ifndef BITS_PER_SHORT
3541 #define BITS_PER_SHORT 16
3542 #endif
3543
3544 /* Note that lisp.h uses this in a preprocessor conditional, so it
3545    would not work to use sizeof.  That being so, we do all of them
3546    without sizeof, for uniformity's sake.  */
3547 #ifndef BITS_PER_INT
3548 #define BITS_PER_INT 32
3549 #endif
3550
3551 #ifndef BITS_PER_LONG
3552 #ifdef _LP64
3553 #define BITS_PER_LONG 64
3554 #else
3555 #define BITS_PER_LONG 32
3556 #endif
3557 #endif
3558
3559 /* Define if the compiler supports function prototypes.  It may do so but
3560    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3561 #undef PROTOTYPES
3562
3563 #include <string.h>
3564 #include <stdlib.h>
3565
3566 #ifdef HAVE_ALLOCA_H
3567 # include <alloca.h>
3568 #elif defined __GNUC__
3569 # define alloca __builtin_alloca
3570 #elif defined _AIX
3571 # define alloca __alloca
3572 #else
3573 # include <stddef.h>
3574 # ifdef  __cplusplus
3575 extern "C"
3576 # endif
3577 void *alloca (size_t);
3578 #endif
3579
3580 #ifndef HAVE_SIZE_T
3581 typedef unsigned size_t;
3582 #endif
3583
3584 #ifndef HAVE_STRCHR
3585 #define strchr(a, b) index (a, b)
3586 #endif
3587
3588 #ifndef HAVE_STRRCHR
3589 #define strrchr(a, b) rindex (a, b)
3590 #endif
3591
3592 #if defined __GNUC__ && (__GNUC__ > 2 \
3593                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3594 #define NO_RETURN       __attribute__ ((__noreturn__))
3595 #else
3596 #define NO_RETURN       /* nothing */
3597 #endif
3598
3599 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3600 #define NO_INLINE __attribute__((noinline))
3601 #else
3602 #define NO_INLINE
3603 #endif
3604
3605 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3606 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3607 #else
3608 #define EXTERNALLY_VISIBLE
3609 #endif
3610
3611 /* Some versions of GNU/Linux define noinline in their headers.  */
3612 #ifdef noinline
3613 #undef noinline
3614 #endif
3615
3616 /* These won't be used automatically yet.  We also need to know, at least,
3617    that the stack is continuous.  */
3618 #ifdef __GNUC__
3619 #  ifndef GC_SETJMP_WORKS
3620   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3621 #    define GC_SETJMP_WORKS 1
3622 #  endif
3623 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3624 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3625 #  endif
3626 #endif
3627
3628 #endif /* EMACS_CONFIG_H */
3629
3630 /*
3631 Local Variables:
3632 mode: c
3633 End:
3634 */
3635 ])dnl
3636
3637 #### Report on what we decided to do.
3638 #### Report GTK as a toolkit, even if it doesn't use Xt.
3639 #### It makes printing result more understandable as using GTK sets
3640 #### toolkit_scroll_bars to yes by default.
3641 if test "${HAVE_GTK}" = "yes"; then
3642   USE_X_TOOLKIT=GTK
3643 fi
3644
3645 and_machfile=
3646 if test -n "$machfile"; then
3647   and_machfile=" and \`${machfile}'"
3648 fi
3649
3650 echo "
3651 Configured for \`${canonical}'.
3652
3653   Where should the build process find the source code?    ${srcdir}
3654   What operating system and machine description files should Emacs use?
3655         \`${opsysfile}'${and_machfile}
3656   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3657   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3658   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3659   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3660   What window system should Emacs use?                    ${window_system}
3661   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3662
3663 if test -n "${x_includes}"; then
3664 echo "  Where do we find X Windows header files?                ${x_includes}"
3665 else
3666 echo "  Where do we find X Windows header files?                Standard dirs"
3667 fi
3668 if test -n "${x_libraries}"; then
3669 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3670 else
3671 echo "  Where do we find X Windows libraries?                   Standard dirs"
3672 fi
3673
3674 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3675 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3676 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3677 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3678 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3679 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3680 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3681 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3682
3683 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3684 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3685 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3686 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3687 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3688 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3689
3690 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3691 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3692 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3693 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3694
3695 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3696 echo
3697
3698 if test $USE_XASSERTS = yes; then
3699    echo "  Compiling with asserts turned on."
3700    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3701 fi
3702
3703 echo
3704
3705 if test "$HAVE_NS" = "yes"; then
3706    echo
3707    echo "You must run \"make install\" in order to test the built application.
3708 The installed application will go to nextstep/Emacs.app and can be
3709 run or moved from there."
3710    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3711       echo "The application will be fully self-contained."
3712     else
3713       echo "The lisp resources for the application will be installed under ${prefix}.
3714 You may need to run \"make install\" with sudo.  The application will fail
3715 to run if these resources are not installed."
3716    fi
3717    echo
3718 fi
3719
3720
3721 # Remove any trailing slashes in these variables.
3722 [test "${prefix}" != NONE &&
3723   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3724 test "${exec_prefix}" != NONE &&
3725   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3726
3727 dnl You might wonder (I did) why epaths.h is generated by running make,
3728 dnl rather than just letting configure generate it from epaths.in.
3729 dnl One reason is that the various paths are not fully expanded (see above);
3730 dnl eg gamedir=${prefix}/var/games/emacs.
3731 dnl Secondly, the GNU Coding standards require that one should be able
3732 dnl to run `make prefix=/some/where/else' and override the values set
3733 dnl by configure.  This also explains the `move-if-change' test and
3734 dnl the use of force in the `epaths-force' rule in Makefile.in.
3735 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3736         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3737         doc/lispref/Makefile src/Makefile \
3738         lwlib/Makefile lisp/Makefile leim/Makefile, [
3739
3740 ### Make the necessary directories, if they don't exist.
3741 for dir in etc lisp ; do
3742   test -d ${dir} || mkdir ${dir}
3743 done
3744
3745 echo creating src/epaths.h
3746 ${MAKE-make} epaths-force
3747
3748 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3749   echo creating src/.gdbinit
3750   echo source $srcdir/src/.gdbinit > src/.gdbinit
3751 fi
3752
3753 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3754