lisp/dabbrev.el

   1 ;;; dabbrev.el --- dynamic abbreviation package
   2
   3 ;; Copyright (C) 1985, 1986, 1992, 1994, 1996, 1997, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Don Morrison
   7 ;; Maintainer: Lars Lindberg <Lars.Lindberg@sypro.cap.se>
   8 ;; Created: 16 Mars 1992
   9 ;; Lindberg's last update version: 5.7
  10 ;; Keywords: abbrev expand completion convenience
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  27 ;; Boston, MA 02110-1301, USA.
  28
  29 ;;; Commentary:
  30
  31 ;; The purpose with this package is to let you write just a few
  32 ;; characters of words you've written earlier to be able to expand
  33 ;; them.
  34 ;;
  35 ;; To expand a word, just put the point right after the word and press
  36 ;; M-/ (dabbrev-expand) or M-C-/ (dabbrev-completion).
  37 ;;
  38 ;; Check out the customizable variables below to learn about all the
  39 ;; features of this package.
  40
  41 ;;; Hints and tips for major modes writers:
  42
  43 ;; Recommended values           C/Lisp etc      text
  44 ;; dabbrev-case-fold-search     nil             t
  45 ;; dabbrev-case-replace         nil             t
  46 ;;
  47 ;; Set the variables you want special for your mode like this:
  48 ;; (set (make-local-variable 'dabbrev-case-replace) nil)
  49 ;; Then you don't interfere with other modes.
  50 ;;
  51 ;; If your mode handles buffers that refers to other buffers
  52 ;; (i.e. compilation-mode, gud-mode), then try to set
  53 ;; `dabbrev-select-buffers-function' or `dabbrev-friend-buffer-function'
  54 ;; to a function that point out those buffers.
  55
  56 ;; Same goes for major-modes that are connected to other modes.  There
  57 ;; are for instance a number of mail-modes.  One for reading, one for
  58 ;; creating a new mail etc.  Maybe those should be connected.
  59
  60 ;; Example for GNUS (when we write a reply, we want dabbrev to look in
  61 ;; the article for expansion):
  62 ;; (set (make-local-variable 'dabbrev-friend-buffer-function)
  63 ;;      (lambda (buffer)
  64 ;;         (save-excursion
  65 ;;           (set-buffer buffer)
  66 ;;           (memq major-mode '(news-reply-mode gnus-article-mode)))))
  67
  68
  69 ;; Known bugs and limitations.
  70 ;; - Possible to do several levels of `dabbrev-completion' in the
  71 ;;   minibuffer.
  72 ;; - dabbrev-completion doesn't handle resetting the globals variables
  73 ;;   right.  It resets them after finding the abbrev.
  74
  75 ;; Future enhancements
  76 ;;  - Check the tags-files? Like tags-complete?
  77 ;;  - Add the possibility of searching both forward and backward to
  78 ;;    the nearest expansion.
  79 ;;  - Check the kill-ring when everything else fails.  (Maybe something
  80 ;;  for hippie-expand?).  [Bng] <boris@cs.rochester.edu>
  81
  82 ;;; These people gave suggestions:
  83 ;;  [hymie]     Hyman Rosen <marks!hymie@jyacc.jyacc.com>
  84 ;;  [burgett]   Steve Burgett <burgett@bizet.eecs.berkeley.edu>
  85 ;;  [jules]     Julian Gosnell <jules@x.co.uk>
  86 ;;  [kifer]     Michael Kifer <kifer@sbcs.sunysb.edu>
  87 ;;  [ake]       Ake Stenhoff <extaksf@aom.ericsson.se>
  88 ;;  [alon]      Alon Albert <al%imercury@uunet.uu.net>
  89 ;;  [tromey]    Tom Tromey <tromey@busco.lanl.gov>
  90 ;;  [Rolf]      Rolf Schreiber <rolf@mathematik.uni-stuttgart.de>
  91 ;;  [Petri]     Petri Raitio <per@tekla.fi>
  92 ;;  [ejb]       Jay Berkenbilt <ejb@ql.org>
  93 ;;  [hawley]    Bob Hawley <rth1@quartet.mt.att.com>
  94 ;;  ... and to all the people who have participated in the beta tests.
  95
  96 ;;; Code:
  97
  98 ;;----------------------------------------------------------------
  99 ;; Customization variables
 100 ;;----------------------------------------------------------------
 101
 102 (defgroup dabbrev nil
 103   "Dynamic Abbreviations."
 104   :tag "Dynamic Abbreviations"
 105   :group 'abbrev
 106   :group 'convenience)
 107
 108 (defcustom dabbrev-backward-only nil
 109   "*If non-nil, `dabbrev-expand' only looks backwards."
 110   :type 'boolean
 111   :group 'dabbrev)
 112
 113 (defcustom dabbrev-limit nil
 114   "*Limits region searched by `dabbrev-expand' to this many chars away."
 115   :type '(choice (const :tag "off" nil)
 116                  integer)
 117   :group 'dabbrev)
 118
 119 (defcustom dabbrev-abbrev-skip-leading-regexp nil
 120   "*Regexp for skipping leading characters of an abbreviation.
 121
 122 Example: Set this to \"\\\\$\" for programming languages
 123 in which variable names may appear with or without a leading `$'.
 124 \(For example, in Makefiles.\)
 125
 126 Set this to nil if no characters should be skipped."
 127   :type '(choice regexp
 128                  (const :tag "off" nil))
 129   :group 'dabbrev)
 130
 131 (defcustom dabbrev--eliminate-newlines t
 132   "*Non-nil means dabbrev should not insert newlines.
 133 Instead it converts them to spaces."
 134   :type 'boolean
 135   :group 'dabbrev)
 136
 137 (defcustom dabbrev-case-fold-search 'case-fold-search
 138   "*Control whether dabbrev searches should ignore case.
 139 A value of nil means case is significant.
 140 A value of `case-fold-search' means case is significant
 141  if `case-fold-search' is nil.
 142 Any other non-nil version means case is not significant."
 143   :type '(choice (const :tag "off" nil)
 144                  (const :tag "like search" case-fold-search)
 145                  (other :tag "on" t))
 146   :group 'dabbrev)
 147
 148 (defcustom dabbrev-upcase-means-case-search nil
 149   "*The significance of an uppercase character in an abbreviation.
 150 nil means case fold search when searching for possible expansions;
 151 non-nil means case sensitive search.
 152
 153 This variable has an effect only when the value of
 154 `dabbrev-case-fold-search' says to ignore case."
 155   :type 'boolean
 156   :group 'dabbrev)
 157
 158 (defcustom dabbrev-case-distinction 'case-replace
 159   "*Whether dabbrev treats expansions as the same if they differ in case.
 160
 161 A value of nil means treat them as different.
 162 A value of `case-replace' means distinguish them if `case-replace' is nil.
 163 Any other non-nil value means to treat them as the same.
 164
 165 This variable has an effect only when the value of
 166 `dabbrev-case-fold-search' specifies to ignore case."
 167   :type '(choice (const :tag "off" nil)
 168                  (const :tag "based on `case-replace'" case-replace)
 169                  (other :tag "on" t))
 170   :group 'dabbrev
 171   :version "22.1")
 172
 173 (defcustom dabbrev-case-replace 'case-replace
 174   "*Whether dabbrev applies the abbreviations's case pattern to the expansion.
 175
 176 A value of nil means preserve the expansion's case pattern.
 177 A value of `case-replace' means preserve it if `case-replace' is nil.
 178 Any other non-nil value means modify the expansion
 179 by applying the abbreviation's case pattern to it.
 180
 181 This variable has an effect only when the value of
 182 `dabbrev-case-fold-search' specifies to ignore case."
 183   :type '(choice (const :tag "off" nil)
 184                  (const :tag "based on `case-replace'" case-replace)
 185                  (other :tag "on" t))
 186   :group 'dabbrev)
 187
 188 (defcustom dabbrev-abbrev-char-regexp nil
 189   "*Regexp to recognize a character in an abbreviation or expansion.
 190 This regexp will be surrounded with \\\\( ... \\\\) when actually used.
 191
 192 Set this variable to \"\\\\sw\" if you want ordinary words or
 193 \"\\\\sw\\\\|\\\\s_\" if you want symbols (including characters whose
 194 syntax is \"symbol\" as well as those whose syntax is \"word\".
 195
 196 The value nil has a special meaning: the abbreviation is from point to
 197 previous word-start, but the search is for symbols.
 198
 199 For instance, if you are programming in Lisp, `yes-or-no-p' is a symbol,
 200 while `yes', `or', `no' and `p' are considered words.  If this
 201 variable is nil, then expanding `yes-or-no-' looks for a symbol
 202 starting with or containing `no-'.  If you set this variable to
 203 \"\\\\sw\\\\|\\\\s_\", that expansion looks for a symbol starting with
 204 `yes-or-no-'.  Finally, if you set this variable to \"\\\\sw\", then
 205 expanding `yes-or-no-' signals an error because `-' is not part of a word;
 206 but expanding `yes-or-no' looks for a word starting with `no'.
 207
 208 The recommended value is \"\\\\sw\\\\|\\\\s_\"."
 209   :type '(choice (const nil)
 210                  regexp)
 211   :group 'dabbrev)
 212
 213 (defcustom dabbrev-check-all-buffers t
 214   "*Non-nil means dabbrev package should search *all* buffers.
 215
 216 Dabbrev always searches the current buffer first.  Then, if
 217 `dabbrev-check-other-buffers' says so, it searches the buffers
 218 designated by `dabbrev-select-buffers-function'.
 219
 220 Then, if `dabbrev-check-all-buffers' is non-nil, dabbrev searches
 221 all the other buffers, except those named in `dabbrev-ignored-buffer-names',
 222 or matched by `dabbrev-ignored-regexps'."
 223   :type 'boolean
 224   :group 'dabbrev)
 225
 226 (defcustom dabbrev-ignored-buffer-names '("*Messages*" "*Buffer List*")
 227   "*List of buffer names that dabbrev should not check.
 228 See also `dabbrev-ignored-buffer-regexps'."
 229   :type '(repeat (string :tag "Buffer name"))
 230   :group 'dabbrev
 231   :version "20.3")
 232
 233 (defcustom dabbrev-ignored-buffer-regexps nil
 234   "*List of regexps matching names of buffers that dabbrev should not check.
 235 See also `dabbrev-ignored-buffer-names'."
 236   :type '(repeat regexp)
 237   :group 'dabbrev
 238   :version "21.1")
 239
 240 (defcustom dabbrev-check-other-buffers t
 241   "*Should \\[dabbrev-expand] look in other buffers?\
 242
 243 nil: Don't look in other buffers.
 244 t: Also look for expansions in the buffers pointed out by
 245    `dabbrev-select-buffers-function'.
 246 Anything else: When we can't find any more expansions in
 247 the current buffer, then ask the user whether to look in other
 248 buffers too.
 249
 250 The default value is t."
 251   :type '(choice (const :tag "off" nil)
 252                  (const :tag "on" t)
 253                  (other :tag "ask" other))
 254   :group 'dabbrev)
 255
 256 ;; I guess setting this to a function that selects all C- or C++-
 257 ;; mode buffers would be a good choice for a debugging buffer,
 258 ;; when debugging C- or C++-code.
 259 (defvar dabbrev-select-buffers-function 'dabbrev--select-buffers
 260   "A function that selects buffers that should be searched by dabbrev.
 261 The function should take no arguments and return a list of buffers to
 262 search for expansions.  See the source of `dabbrev--select-buffers'
 263 for an example.
 264
 265 A mode setting this variable should make it buffer local.")
 266
 267 (defcustom dabbrev-friend-buffer-function 'dabbrev--same-major-mode-p
 268   "*A function to decide whether dabbrev should search OTHER-BUFFER.
 269 The function should take one argument, OTHER-BUFFER, and return
 270 non-nil if that buffer should be searched.  Have a look at
 271 `dabbrev--same-major-mode-p' for an example.
 272
 273 The value of `dabbrev-friend-buffer-function' has an effect only if
 274 the value of `dabbrev-select-buffers-function' uses it.  The function
 275 `dabbrev--select-buffers' is one function you can use here.
 276
 277 A mode setting this variable should make it buffer local."
 278   :type 'function
 279   :group 'dabbrev)
 280
 281 (defcustom dabbrev-search-these-buffers-only nil
 282   "If non-nil, a list of buffers which dabbrev should search.
 283 If this variable is non-nil, dabbrev will only look in these buffers.
 284 It will not even look in the current buffer if it is not a member of
 285 this list."
 286   :group 'dabbrev)
 287
 288 ;;----------------------------------------------------------------
 289 ;; Internal variables
 290 ;;----------------------------------------------------------------
 291
 292 ;; Last obarray of completions in `dabbrev-completion'
 293 (defvar dabbrev--last-obarray nil)
 294
 295 ;; Table of expansions seen so far
 296 (defvar dabbrev--last-table nil)
 297
 298 ;; Last string we tried to expand.
 299 (defvar dabbrev--last-abbreviation nil)
 300
 301 ;; Location last abbreviation began
 302 (defvar dabbrev--last-abbrev-location nil)
 303
 304 ;; Direction of last dabbrevs search
 305 (defvar dabbrev--last-direction 0)
 306
 307 ;; Last expansion of an abbreviation.
 308 (defvar dabbrev--last-expansion nil)
 309
 310 ;; Location the last expansion was found.
 311 (defvar dabbrev--last-expansion-location nil)
 312
 313 ;; The list of remaining buffers with the same mode as current buffer.
 314 (defvar dabbrev--friend-buffer-list nil)
 315
 316 ;; The buffer we looked in last, not counting the current buffer.
 317 (defvar dabbrev--last-buffer nil)
 318
 319 ;; The buffer we found the expansion last time.
 320 (defvar dabbrev--last-buffer-found nil)
 321
 322 ;; The buffer we last did a completion in.
 323 (defvar dabbrev--last-completion-buffer nil)
 324
 325 ;; If non-nil, a function to use when copying successive words.
 326 ;; It should be `upcase' or `downcase'.
 327 (defvar dabbrev--last-case-pattern nil)
 328
 329 ;; Same as dabbrev-check-other-buffers, but is set for every expand.
 330 (defvar dabbrev--check-other-buffers dabbrev-check-other-buffers)
 331
 332 ;; The regexp for recognizing a character in an abbreviation.
 333 (defvar dabbrev--abbrev-char-regexp nil)
 334
 335 ;;----------------------------------------------------------------
 336 ;; Macros
 337 ;;----------------------------------------------------------------
 338
 339 ;;; Get the buffer that mini-buffer was activated from
 340 (defsubst dabbrev--minibuffer-origin ()
 341   (car (cdr (buffer-list))))
 342
 343 ;; Make a list of some of the elements of LIST.
 344 ;; Check each element of LIST, storing it temporarily in the
 345 ;; variable ELEMENT, and include it in the result
 346 ;; if CONDITION evaluates non-nil.
 347 (defmacro dabbrev-filter-elements (element list condition)
 348   `(let (dabbrev-result dabbrev-tail ,element)
 349     (setq dabbrev-tail ,list)
 350     (while dabbrev-tail
 351       (setq ,element (car dabbrev-tail))
 352       (if ,condition
 353           (setq dabbrev-result (cons ,element dabbrev-result)))
 354       (setq dabbrev-tail (cdr dabbrev-tail)))
 355     (nreverse dabbrev-result)))
 356
 357 ;;----------------------------------------------------------------
 358 ;; Exported functions
 359 ;;----------------------------------------------------------------
 360
 361 ;;;###autoload (define-key esc-map "/" 'dabbrev-expand)
 362 ;;;??? Do we want this?
 363 ;;;###autoload (define-key esc-map [?\C-/] 'dabbrev-completion)
 364
 365 ;;;###autoload
 366 (defun dabbrev-completion (&optional arg)
 367   "Completion on current word.
 368 Like \\[dabbrev-expand] but finds all expansions in the current buffer
 369 and presents suggestions for completion.
 370
 371 With a prefix argument, it searches all buffers accepted by the
 372 function pointed out by `dabbrev-friend-buffer-function' to find the
 373 completions.
 374
 375 If the prefix argument is 16 (which comes from C-u C-u),
 376 then it searches *all* buffers.
 377
 378 With no prefix argument, it reuses an old completion list
 379 if there is a suitable one already."
 380
 381   (interactive "*P")
 382   (dabbrev--reset-global-variables)
 383   (let* ((dabbrev-check-other-buffers (and arg t))
 384          (dabbrev-check-all-buffers
 385           (and arg (= (prefix-numeric-value arg) 16)))
 386          (abbrev (dabbrev--abbrev-at-point))
 387          (ignore-case-p (and (if (eq dabbrev-case-fold-search 'case-fold-search)
 388                                  case-fold-search
 389                                dabbrev-case-fold-search)
 390                              (or (not dabbrev-upcase-means-case-search)
 391                                  (string= abbrev (downcase abbrev)))))
 392          (my-obarray dabbrev--last-obarray)
 393          init)
 394     (save-excursion
 395       (if (and (null arg)
 396                my-obarray
 397                (or (eq dabbrev--last-completion-buffer (current-buffer))
 398                    (and (window-minibuffer-p (selected-window))
 399                         (eq dabbrev--last-completion-buffer
 400                             (dabbrev--minibuffer-origin))))
 401                dabbrev--last-abbreviation
 402                (>= (length abbrev) (length dabbrev--last-abbreviation))
 403                (string= dabbrev--last-abbreviation
 404                         (substring abbrev 0
 405                                    (length dabbrev--last-abbreviation)))
 406                (setq init (try-completion abbrev my-obarray)))
 407           ;; We can reuse the existing completion list.
 408           nil
 409         ;;--------------------------------
 410         ;; New abbreviation to expand.
 411         ;;--------------------------------
 412         (setq dabbrev--last-abbreviation abbrev)
 413         ;; Find all expansion
 414         (let ((completion-list
 415                (dabbrev--find-all-expansions abbrev ignore-case-p))
 416               (completion-ignore-case ignore-case-p))
 417           ;; Make an obarray with all expansions
 418           (setq my-obarray (make-vector (length completion-list) 0))
 419           (or (> (length my-obarray) 0)
 420               (error "No dynamic expansion for \"%s\" found%s"
 421                      abbrev
 422                      (if dabbrev--check-other-buffers "" " in this-buffer")))
 423           (cond
 424            ((or (not ignore-case-p)
 425                 (not dabbrev-case-replace))
 426             (mapc (function (lambda (string)
 427                               (intern string my-obarray)))
 428                     completion-list))
 429            ((string= abbrev (upcase abbrev))
 430             (mapc (function (lambda (string)
 431                               (intern (upcase string) my-obarray)))
 432                     completion-list))
 433            ((string= (substring abbrev 0 1)
 434                      (upcase (substring abbrev 0 1)))
 435             (mapc (function (lambda (string)
 436                               (intern (capitalize string) my-obarray)))
 437                     completion-list))
 438            (t
 439             (mapc (function (lambda (string)
 440                               (intern (downcase string) my-obarray)))
 441                     completion-list)))
 442           (setq dabbrev--last-obarray my-obarray)
 443           (setq dabbrev--last-completion-buffer (current-buffer))
 444           ;; Find the longest common string.
 445           (setq init (try-completion abbrev my-obarray)))))
 446     ;;--------------------------------
 447     ;; Let the user choose between the expansions
 448     ;;--------------------------------
 449     (or (stringp init)
 450         (setq init abbrev))
 451     (cond
 452      ;; * Replace string fragment with matched common substring completion.
 453      ((and (not (string-equal init ""))
 454            (not (string-equal (downcase init) (downcase abbrev))))
 455       (if (> (length (all-completions init my-obarray)) 1)
 456           (message "Repeat `%s' to see all completions"
 457                    (key-description (this-command-keys)))
 458         (message "The only possible completion"))
 459       (dabbrev--substitute-expansion nil abbrev init nil))
 460      (t
 461       ;; * String is a common substring completion already.  Make list.
 462       (message "Making completion list...")
 463       (with-output-to-temp-buffer "*Completions*"
 464         (display-completion-list (all-completions init my-obarray)))
 465       (message "Making completion list...done")))
 466     (and (window-minibuffer-p (selected-window))
 467          (message nil))))
 468
 469 ;;;###autoload
 470 (defun dabbrev-expand (arg)
 471   "Expand previous word \"dynamically\".
 472
 473 Expands to the most recent, preceding word for which this is a prefix.
 474 If no suitable preceding word is found, words following point are
 475 considered.  If still no suitable word is found, then look in the
 476 buffers accepted by the function pointed out by variable
 477 `dabbrev-friend-buffer-function'.
 478
 479 A positive prefix argument, N, says to take the Nth backward *distinct*
 480 possibility.  A negative argument says search forward.
 481
 482 If the cursor has not moved from the end of the previous expansion and
 483 no argument is given, replace the previously-made expansion
 484 with the next possible expansion not yet tried.
 485
 486 The variable `dabbrev-backward-only' may be used to limit the
 487 direction of search to backward if set non-nil.
 488
 489 See also `dabbrev-abbrev-char-regexp' and \\[dabbrev-completion]."
 490   (interactive "*P")
 491   (let (abbrev record-case-pattern
 492                expansion old direction (orig-point (point)))
 493     ;; abbrev -- the abbrev to expand
 494     ;; expansion -- the expansion found (eventually) or nil until then
 495     ;; old -- the text currently in the buffer
 496     ;;    (the abbrev, or the previously-made expansion)
 497     (save-excursion
 498       (if (and (null arg)
 499                (markerp dabbrev--last-abbrev-location)
 500                (marker-position dabbrev--last-abbrev-location)
 501                (or (eq last-command this-command)
 502                    (and (window-minibuffer-p (selected-window))
 503                         (= dabbrev--last-abbrev-location
 504                            (point)))))
 505           ;; Find a different expansion for the same abbrev as last time.
 506           (progn
 507             (setq abbrev dabbrev--last-abbreviation)
 508             (setq old dabbrev--last-expansion)
 509             (setq direction dabbrev--last-direction))
 510         ;; If the user inserts a space after expanding
 511         ;; and then asks to expand again, always fetch the next word.
 512         (if (and (eq (preceding-char) ?\s)
 513                  (markerp dabbrev--last-abbrev-location)
 514                  (marker-position dabbrev--last-abbrev-location)
 515                  (= (point) (1+ dabbrev--last-abbrev-location)))
 516             (progn
 517               ;; The "abbrev" to expand is just the space.
 518               (setq abbrev " ")
 519               (save-excursion
 520                 (save-restriction
 521                   (widen)
 522                   (if dabbrev--last-buffer
 523                       (set-buffer dabbrev--last-buffer))
 524                   ;; Find the end of the last "expansion" word.
 525                   (if (or (eq dabbrev--last-direction 1)
 526                           (and (eq dabbrev--last-direction 0)
 527                                (< dabbrev--last-expansion-location (point))))
 528                       (setq dabbrev--last-expansion-location
 529                             (+ dabbrev--last-expansion-location
 530                                (length dabbrev--last-expansion))))
 531                   (goto-char dabbrev--last-expansion-location)
 532                   ;; Take the following word, with intermediate separators,
 533                   ;; as our expansion this time.
 534                   (re-search-forward
 535                    (concat "\\(?:" dabbrev--abbrev-char-regexp "\\)+"))
 536                   (setq expansion (buffer-substring-no-properties
 537                                    dabbrev--last-expansion-location (point)))
 538
 539                   ;; Record the end of this expansion, in case we repeat this.
 540                   (setq dabbrev--last-expansion-location (point))))
 541               ;; Indicate that dabbrev--last-expansion-location is
 542               ;; at the end of the expansion.
 543               (setq dabbrev--last-direction -1))
 544
 545           ;; We have a different abbrev to expand.
 546           (dabbrev--reset-global-variables)
 547           (setq direction (if (null arg)
 548                               (if dabbrev-backward-only 1 0)
 549                             (prefix-numeric-value arg)))
 550           (setq abbrev (dabbrev--abbrev-at-point))
 551           (setq record-case-pattern t)
 552           (setq old nil)))
 553
 554       ;;--------------------------------
 555       ;; Find the expansion
 556       ;;--------------------------------
 557       (or expansion
 558           (setq expansion
 559                 (dabbrev--find-expansion abbrev direction
 560                                          (and (if (eq dabbrev-case-fold-search 'case-fold-search)
 561                                                   case-fold-search
 562                                                 dabbrev-case-fold-search)
 563                                               (or (not dabbrev-upcase-means-case-search)
 564                                                   (string= abbrev (downcase abbrev))))))))
 565     (cond
 566      ((not expansion)
 567       (dabbrev--reset-global-variables)
 568       (if old
 569           (save-excursion
 570             (setq buffer-undo-list (cons orig-point buffer-undo-list))
 571             ;; Put back the original abbrev with its original case pattern.
 572             (search-backward old)
 573             (insert abbrev)
 574             (delete-region (point) (+ (point) (length old)))))
 575       (error "No%s dynamic expansion for `%s' found"
 576              (if old " further" "") abbrev))
 577      (t
 578       (if (not (or (eq dabbrev--last-buffer dabbrev--last-buffer-found)
 579                    (minibuffer-window-active-p (selected-window))))
 580           (progn
 581             (message "Expansion found in '%s'"
 582                      (buffer-name dabbrev--last-buffer))
 583             (setq dabbrev--last-buffer-found dabbrev--last-buffer))
 584         (message nil))
 585       (if (and (or (eq (current-buffer) dabbrev--last-buffer)
 586                    (null dabbrev--last-buffer))
 587                (numberp dabbrev--last-expansion-location)
 588                (and (> dabbrev--last-expansion-location (point))))
 589           (setq dabbrev--last-expansion-location
 590                 (copy-marker dabbrev--last-expansion-location)))
 591       ;; Success: stick it in and return.
 592       (setq buffer-undo-list (cons orig-point buffer-undo-list))
 593       (dabbrev--substitute-expansion old abbrev expansion
 594                                      record-case-pattern)
 595
 596       ;; Save state for re-expand.
 597       (setq dabbrev--last-expansion expansion)
 598       (setq dabbrev--last-abbreviation abbrev)
 599       (setq dabbrev--last-abbrev-location (point-marker))))))
 600
 601 ;;----------------------------------------------------------------
 602 ;; Local functions
 603 ;;----------------------------------------------------------------
 604
 605 ;;; Checks if OTHER-BUFFER has the same major mode as current buffer.
 606 (defun dabbrev--same-major-mode-p (other-buffer)
 607   (eq major-mode
 608       (save-excursion
 609         (set-buffer other-buffer)
 610         major-mode)))
 611
 612 ;;; Back over all abbrev type characters and then moves forward over
 613 ;;; all skip characters.
 614 (defun dabbrev--goto-start-of-abbrev ()
 615   ;; Move backwards over abbrev chars
 616   (save-match-data
 617     (when (> (point) (minibuffer-prompt-end))
 618       (forward-char -1)
 619       (while (and (looking-at dabbrev--abbrev-char-regexp)
 620                   (> (point) (minibuffer-prompt-end))
 621                   (not (= (point) (field-beginning (point) nil
 622                                                    (1- (point))))))
 623         (forward-char -1))
 624       (or (looking-at dabbrev--abbrev-char-regexp)
 625           (forward-char 1)))
 626     (and dabbrev-abbrev-skip-leading-regexp
 627          (while (looking-at dabbrev-abbrev-skip-leading-regexp)
 628            (forward-char 1)))))
 629
 630 ;;; Extract the symbol at point to serve as abbreviation.
 631 (defun dabbrev--abbrev-at-point ()
 632   ;; Check for error
 633   (if (bobp)
 634       (error "No possible abbreviation preceding point"))
 635   ;; Return abbrev at point
 636   (save-excursion
 637     ;; Record the end of the abbreviation.
 638     (setq dabbrev--last-abbrev-location (point))
 639     ;; If we aren't right after an abbreviation,
 640     ;; move point back to just after one.
 641     ;; This is so the user can get successive words
 642     ;; by typing the punctuation followed by M-/.
 643     (save-match-data
 644       (if (save-excursion
 645             (forward-char -1)
 646             (not (looking-at (concat "\\("
 647                                      (or dabbrev-abbrev-char-regexp
 648                                          "\\sw\\|\\s_")
 649                                      "\\)+"))))
 650           (if (re-search-backward (or dabbrev-abbrev-char-regexp
 651                                       "\\sw\\|\\s_")
 652                                   nil t)
 653               (forward-char 1)
 654             (error "No possible abbreviation preceding point"))))
 655     ;; Now find the beginning of that one.
 656     (dabbrev--goto-start-of-abbrev)
 657     (buffer-substring-no-properties
 658      dabbrev--last-abbrev-location (point))))
 659
 660 ;;; Initializes all global variables
 661 (defun dabbrev--reset-global-variables ()
 662   ;; dabbrev--last-obarray and dabbrev--last-completion-buffer
 663   ;; must not be reset here.
 664   (setq dabbrev--last-table nil
 665         dabbrev--last-abbreviation nil
 666         dabbrev--last-abbrev-location nil
 667         dabbrev--last-direction nil
 668         dabbrev--last-expansion nil
 669         dabbrev--last-expansion-location nil
 670         dabbrev--friend-buffer-list nil
 671         dabbrev--last-buffer nil
 672         dabbrev--last-buffer-found nil
 673         dabbrev--abbrev-char-regexp (or dabbrev-abbrev-char-regexp
 674                                         "\\sw\\|\\s_")
 675         dabbrev--check-other-buffers dabbrev-check-other-buffers))
 676
 677 (defun dabbrev--select-buffers ()
 678   "Return a list of other buffers to search for a possible abbrev.
 679 The current buffer is not included in the list.
 680
 681 This function makes a list of all the buffers returned by `buffer-list',
 682 then discards buffers whose names match `dabbrev-ignored-buffer-names'
 683 or `dabbrev-ignored-buffer-regexps'.  It also discards buffers for which
 684 `dabbrev-friend-buffer-function', if it is bound, returns nil when called
 685 with the buffer as argument.
 686 It returns the list of the buffers that are not discarded."
 687   (dabbrev-filter-elements
 688    buffer (buffer-list)
 689    (and (not (eq (current-buffer) buffer))
 690         (not (dabbrev--ignore-buffer-p buffer))
 691         (boundp 'dabbrev-friend-buffer-function)
 692         (funcall dabbrev-friend-buffer-function buffer))))
 693
 694 (defun dabbrev--try-find (abbrev reverse n ignore-case)
 695   "Search for ABBREV, backwards if REVERSE, N times.
 696 If IGNORE-CASE is non-nil, ignore case while searching.
 697 Return the expansion found, and save the location of the start
 698 of the expansion in `dabbrev--last-expansion-location'."
 699   (save-excursion
 700     (save-restriction
 701       (widen)
 702       (let ((expansion nil))
 703         (and dabbrev--last-expansion-location
 704              (goto-char dabbrev--last-expansion-location))
 705         (let ((case-fold-search ignore-case)
 706               (count n))
 707           (while (and (> count 0)
 708                       (setq expansion (dabbrev--search abbrev
 709                                                        reverse
 710                                                        (and ignore-case
 711                                                             (if (eq dabbrev-case-distinction 'case-replace)
 712                                                                 case-replace
 713                                                               dabbrev-case-distinction))
 714                                                        )))
 715             (setq count (1- count))))
 716         (and expansion
 717              (setq dabbrev--last-expansion-location (point)))
 718         expansion))))
 719
 720 (defun dabbrev--find-all-expansions (abbrev ignore-case)
 721   "Return a list of all possible expansions of ABBREV.
 722 If IGNORE-CASE is non-nil, accept matches which differ in case."
 723   (let ((all-expansions nil)
 724         expansion)
 725     (save-excursion
 726       (goto-char (point-min))
 727       (while (setq expansion (dabbrev--find-expansion abbrev -1 ignore-case))
 728         (setq all-expansions (cons expansion all-expansions))))
 729     all-expansions))
 730
 731 (defun dabbrev--scanning-message ()
 732   (unless (window-minibuffer-p (selected-window))
 733     (message "Scanning `%s'" (buffer-name (current-buffer)))))
 734
 735 (defun dabbrev--ignore-buffer-p (buffer)
 736   "Return non-nil if BUFFER should be ignored by dabbrev."
 737   (let ((bn (buffer-name buffer)))
 738     (or (member bn dabbrev-ignored-buffer-names)
 739         (let ((tail dabbrev-ignored-buffer-regexps)
 740               (match nil))
 741           (while (and tail (not match))
 742             (setq match (string-match (car tail) bn)
 743                   tail (cdr tail)))
 744           match))))
 745
 746 (defun dabbrev--find-expansion (abbrev direction ignore-case)
 747   "Find one occurrence of ABBREV, and return the expansion.
 748 DIRECTION > 0 means look that many times backwards.
 749 DIRECTION < 0 means look that many times forward.
 750 DIRECTION = 0 means try both backward and forward.
 751 IGNORE-CASE non-nil means ignore case when searching.
 752 This sets `dabbrev--last-direction' to 1 or -1 according
 753 to the direction in which the occurrence was actually found.
 754 It sets `dabbrev--last-expansion-location' to the location
 755 of the start of the occurrence."
 756   (save-excursion
 757     ;; If we were scanning something other than the current buffer,
 758     ;; continue scanning there.
 759     (when dabbrev--last-buffer
 760       (set-buffer dabbrev--last-buffer)
 761       (dabbrev--scanning-message))
 762     (or
 763      ;; ------------------------------------------
 764      ;; Look backward in current buffer.
 765      ;; ------------------------------------------
 766      (and (not dabbrev-search-these-buffers-only)
 767           (>= direction 0)
 768           (setq dabbrev--last-direction (min 1 direction))
 769           (dabbrev--try-find abbrev t
 770                              (max 1 direction)
 771                              ignore-case))
 772      ;; ------------------------------------------
 773      ;; Look forward in current buffer
 774      ;; or whatever buffer we were last scanning.
 775      ;; ------------------------------------------
 776      (and (or (not dabbrev-search-these-buffers-only)
 777               dabbrev--last-buffer)
 778           (<= direction 0)
 779           (setq dabbrev--last-direction -1)
 780           (dabbrev--try-find abbrev nil
 781                              (max 1 (- direction))
 782                              ignore-case))
 783      ;; ------------------------------------------
 784      ;; Look in other buffers.
 785      ;; Always start at (point-min) and look forward.
 786      ;; ------------------------------------------
 787      (progn
 788        (setq dabbrev--last-direction -1)
 789        (unless dabbrev--last-buffer
 790          ;; If we have just now begun to search other buffers,
 791          ;; determine which other buffers we should check.
 792          ;; Put that list in dabbrev--friend-buffer-list.
 793          (or dabbrev--friend-buffer-list
 794              (setq dabbrev--friend-buffer-list
 795                    (dabbrev--make-friend-buffer-list))))
 796        ;; Walk through the buffers till we find a match.
 797        (let (expansion)
 798          (while (and (not expansion) dabbrev--friend-buffer-list)
 799            (setq dabbrev--last-buffer (pop dabbrev--friend-buffer-list))
 800            (set-buffer dabbrev--last-buffer)
 801            (dabbrev--scanning-message)
 802            (setq dabbrev--last-expansion-location (point-min))
 803            (setq expansion (dabbrev--try-find abbrev nil 1 ignore-case)))
 804          expansion)))))
 805
 806 ;; Compute the list of buffers to scan.
 807 ;; If dabbrev-search-these-buffers-only, then the current buffer
 808 ;; is included in this list if it should be searched.
 809 ;; Otherwise, the current buffer is searched first specially.,
 810 ;; and it is not included in this list.
 811 (defun dabbrev--make-friend-buffer-list ()
 812   (let ((list (mapcar (function get-buffer)
 813                       dabbrev-search-these-buffers-only)))
 814     (when (and (null dabbrev-search-these-buffers-only)
 815                dabbrev--check-other-buffers
 816                (or (eq dabbrev--check-other-buffers t)
 817                    (setq dabbrev--check-other-buffers
 818                          (y-or-n-p "Scan other buffers also? "))))
 819       (setq list (funcall dabbrev-select-buffers-function))
 820       ;; If dabbrev-check-all-buffers, tack on all the other
 821       ;; buffers at the end of the list, except those which are
 822       ;; specifically to be ignored.
 823       (if dabbrev-check-all-buffers
 824           (setq list
 825                 (append list
 826                         (dabbrev-filter-elements
 827                          buffer (buffer-list)
 828                          (and (not (memq buffer list))
 829                               (not (dabbrev--ignore-buffer-p buffer)))))))
 830       ;; Remove the current buffer.
 831       (setq list (delq (current-buffer) list)))
 832     ;; Move buffers in the list that are visible on the screen
 833     ;; to the front of the list, but don't add anything to the list.
 834     (if list
 835         (walk-windows (lambda (w)
 836                         (unless (eq w (selected-window))
 837                           (if (memq (window-buffer w) list)
 838                               (setq list
 839                                     (cons (window-buffer w)
 840                                           (delq (window-buffer w)
 841                                                 list))))))))
 842     ;; In a minibuffer, search the buffer it was activated from,
 843     ;; first after the minibuffer itself.  Unless we aren't supposed
 844     ;; to search the current buffer either.
 845     (if (and (window-minibuffer-p (selected-window))
 846              (not dabbrev-search-these-buffers-only))
 847         (setq list
 848               (cons (dabbrev--minibuffer-origin)
 849                     (delq (dabbrev--minibuffer-origin) list))))
 850     list))
 851
 852 (defun dabbrev--safe-replace-match (string &optional fixedcase literal)
 853   (if (eq major-mode 'picture-mode)
 854       (with-no-warnings
 855        (picture-replace-match string fixedcase literal))
 856     (replace-match string fixedcase literal)))
 857
 858 ;;;----------------------------------------------------------------
 859 (defun dabbrev--substitute-expansion (old abbrev expansion record-case-pattern)
 860   "Replace OLD with EXPANSION in the buffer.
 861 OLD is text currently in the buffer, perhaps the abbreviation
 862 or perhaps another expansion that was tried previously.
 863 ABBREV is the abbreviation we are expanding.
 864 It is \" \" if we are copying subsequent words.
 865 EXPANSION is the expansion substring to be used this time.
 866 RECORD-CASE-PATTERN, if non-nil, means set `dabbrev--last-case-pattern'
 867 to record whether we upcased the expansion, downcased it, or did neither."
 868   ;;(undo-boundary)
 869   (let ((use-case-replace (and (if (eq dabbrev-case-fold-search 'case-fold-search)
 870                                    case-fold-search
 871                                  dabbrev-case-fold-search)
 872                                (or (not dabbrev-upcase-means-case-search)
 873                                    (string= abbrev (downcase abbrev)))
 874                                (if (eq dabbrev-case-replace 'case-replace)
 875                                    case-replace
 876                                  dabbrev-case-replace))))
 877
 878     ;; If we upcased or downcased the original expansion,
 879     ;; do likewise for the subsequent words when we copy them.
 880     ;; Don't do any of the usual case processing, though.
 881     (when (equal abbrev " ")
 882       (if dabbrev--last-case-pattern
 883           (setq expansion
 884                 (funcall dabbrev--last-case-pattern expansion)))
 885       (setq use-case-replace nil))
 886
 887     ;; If the expansion has mixed case
 888     ;; and it is not simply a capitalized word,
 889     ;; or if the abbrev has mixed case,
 890     ;; and if the given abbrev's case pattern
 891     ;; matches the start of the expansion,
 892     ;; copy the expansion's case
 893     ;; instead of downcasing all the rest.
 894     ;;
 895     ;; Treat a one-capital-letter (possibly with preceding non-letter
 896     ;; characters) abbrev as "not all upper case", so as to force
 897     ;; preservation of the expansion's pattern if the expansion starts
 898     ;; with a capital letter.
 899     (let ((expansion-rest (substring expansion 1))
 900           (first-letter-position (string-match "[[:alpha:]]" abbrev)))
 901       (if (or (null first-letter-position)
 902               (and (not (and (or (string= expansion-rest (downcase expansion-rest))
 903                                  (string= expansion-rest (upcase expansion-rest)))
 904                              (or (string= abbrev (downcase abbrev))
 905                                  (and (string= abbrev (upcase abbrev))
 906                                       (> (- (length abbrev) first-letter-position)
 907                                          1)))))
 908                    (string= abbrev
 909                             (substring expansion 0 (length abbrev)))))
 910           (setq use-case-replace nil)))
 911
 912     ;; If the abbrev and the expansion are both all-lower-case
 913     ;; then don't do any conversion.  The conversion would be a no-op
 914     ;; for this replacement, but it would carry forward to subsequent words.
 915     ;; The goal of this is to prevent that carrying forward.
 916     (if (and (string= expansion (downcase expansion))
 917              (string= abbrev (downcase abbrev)))
 918         (setq use-case-replace nil))
 919
 920     (if use-case-replace
 921         (setq expansion (downcase expansion)))
 922
 923     ;; In case we insert subsequent words,
 924     ;; record if we upcased or downcased the first word,
 925     ;; in order to do likewise for subsequent words.
 926     (and record-case-pattern
 927          (setq dabbrev--last-case-pattern
 928                (and use-case-replace
 929                     (cond ((equal abbrev (upcase abbrev)) 'upcase)
 930                           ((equal abbrev (downcase abbrev)) 'downcase)))))
 931
 932     ;; Convert whitespace to single spaces.
 933     (if dabbrev--eliminate-newlines
 934         ;; Start searching at end of ABBREV so that any whitespace
 935         ;; carried over from the existing text is not changed.
 936         (let ((pos (length abbrev)))
 937           (while (string-match "[\n \t]+" expansion pos)
 938             (setq pos (1+ (match-beginning 0)))
 939             (setq expansion (replace-match " " nil nil expansion)))))
 940
 941     (if old
 942         (save-excursion
 943           (search-backward old))
 944       ;;(set-match-data (list (point-marker) (point-marker)))
 945       (search-backward abbrev)
 946       (search-forward abbrev))
 947
 948     ;; Make case of replacement conform to case of abbreviation
 949     ;; provided (1) that kind of thing is enabled in this buffer
 950     ;; and (2) the replacement itself is all lower case.
 951     (dabbrev--safe-replace-match expansion
 952                                  (not use-case-replace)
 953                                  t)))
 954
 955
 956 ;;;----------------------------------------------------------------
 957 ;;; Search function used by dabbrevs library.
 958
 959
 960 (defun dabbrev--search (abbrev reverse ignore-case)
 961   "Search for something that could be used to expand ABBREV.
 962
 963 Second arg, REVERSE, is t for reverse search, nil for forward.
 964 The variable `dabbrev-limit' controls the maximum search region size.
 965 Third argument IGNORE-CASE non-nil means treat case as insignificant while
 966 looking for a match and when comparing with previous matches.  Also if
 967 that's non-nil and the match is found at the beginning of a sentence
 968 and is in lower case except for the initial then it is converted to
 969 all lower case for return.
 970
 971 Table of expansions already seen is examined in buffer
 972 `dabbrev--last-table' so that only distinct possibilities are found
 973 by dabbrev-re-expand.
 974
 975 Returns the expansion found, or nil if not found.
 976 Leaves point at the location of the start of the expansion."
 977   (save-match-data
 978     (let ((pattern1 (concat (regexp-quote abbrev)
 979                             "\\(" dabbrev--abbrev-char-regexp "\\)"))
 980           (pattern2 (concat (regexp-quote abbrev)
 981                            "\\(\\(" dabbrev--abbrev-char-regexp "\\)+\\)"))
 982           ;; This makes it possible to find matches in minibuffer prompts
 983           ;; even when they are "inviolable".
 984           (inhibit-point-motion-hooks t)
 985           found-string result)
 986       ;; Limited search.
 987       (save-restriction
 988         (and dabbrev-limit
 989              (narrow-to-region dabbrev--last-expansion-location
 990                                (+ (point)
 991                                   (if reverse (- dabbrev-limit) dabbrev-limit))))
 992         ;;--------------------------------
 993         ;; Look for a distinct expansion, using dabbrev--last-table.
 994         ;;--------------------------------
 995         (while (and (not found-string)
 996                     (if reverse
 997                         (re-search-backward pattern1 nil t)
 998                       (re-search-forward pattern1 nil t)))
 999           (goto-char (match-beginning 0))
1000           ;; In case we matched in the middle of a word,
1001           ;; back up to start of word and verify we still match.
1002           (dabbrev--goto-start-of-abbrev)
1003
1004           (if (not (looking-at pattern1))
1005               nil
1006             ;; We have a truly valid match.  Find the end.
1007             (re-search-forward pattern2)
1008             (setq found-string (match-string-no-properties 0))
1009             (setq result found-string)
1010             (and ignore-case (setq found-string (downcase found-string)))
1011             ;; Ignore this match if it's already in the table.
1012             (if (dabbrev-filter-elements
1013                  table-string dabbrev--last-table
1014                  (string= found-string table-string))
1015                 (setq found-string nil)))
1016           ;; Prepare to continue searching.
1017           (goto-char (if reverse (match-beginning 0) (match-end 0))))
1018         ;; If we found something, use it.
1019         (when found-string
1020           ;; Put it into `dabbrev--last-table'
1021           ;; and return it (either downcased, or as is).
1022           (setq dabbrev--last-table
1023                 (cons found-string dabbrev--last-table))
1024           result)))))
1025
1026 (dolist (mess '("^No dynamic expansion for .* found$"
1027                 "^No further dynamic expansion for .* found$"
1028                 "^No possible abbreviation preceding point$"))
1029   (add-to-list 'debug-ignored-errors mess))
1030
1031 (provide 'dabbrev)
1032
1033 ;;; arch-tag: 29e58596-f080-4306-a409-70296cf9d46f
1034 ;;; dabbrev.el ends here