lisp/tar-mode.el

   1 ;;; tar-mode.el --- simple editing of tar files from GNU emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Jamie Zawinski <jwz@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 04 Apr 1990
   9 ;; Keywords: unix
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package attempts to make dealing with Unix 'tar' archives easier.
  31 ;; When this code is loaded, visiting a file whose name ends in '.tar' will
  32 ;; cause the contents of that archive file to be displayed in a Dired-like
  33 ;; listing.  It is then possible to use the customary Dired keybindings to
  34 ;; extract sub-files from that archive, either by reading them into their own
  35 ;; editor buffers, or by copying them directly to arbitrary files on disk.
  36 ;; It is also possible to delete sub-files from within the tar file and write
  37 ;; the modified archive back to disk, or to edit sub-files within the archive
  38 ;; and re-insert the modified files into the archive.  See the documentation
  39 ;; string of tar-mode for more info.
  40
  41 ;; This code now understands the extra fields that GNU tar adds to tar files.
  42
  43 ;; This interacts correctly with "uncompress.el" in the Emacs library,
  44 ;; which you get with
  45 ;;
  46 ;;  (autoload 'uncompress-while-visiting "uncompress")
  47 ;;  (setq auto-mode-alist (cons '("\\.Z$" . uncompress-while-visiting)
  48 ;;                         auto-mode-alist))
  49 ;;
  50 ;; Do not attempt to use tar-mode.el with crypt.el, you will lose.
  51
  52 ;;    ***************   TO DO   ***************
  53 ;;
  54 ;; o  chmod should understand "a+x,og-w".
  55 ;;
  56 ;; o  It's not possible to add a NEW file to a tar archive; not that
  57 ;;    important, but still...
  58 ;;
  59 ;; o  The code is less efficient that it could be - in a lot of places, I
  60 ;;    pull a 512-character string out of the buffer and parse it, when I could
  61 ;;    be parsing it in place, not garbaging a string.  Should redo that.
  62 ;;
  63 ;; o  I'd like a command that searches for a string/regexp in every subfile
  64 ;;    of an archive, where <esc> would leave you in a subfile-edit buffer.
  65 ;;    (Like the Meta-R command of the Zmacs mail reader.)
  66 ;;
  67 ;; o  Sometimes (but not always) reverting the tar-file buffer does not
  68 ;;    re-grind the listing, and you are staring at the binary tar data.
  69 ;;    Typing 'g' again immediately after that will always revert and re-grind
  70 ;;    it, though.  I have no idea why this happens.
  71 ;;
  72 ;; o  Tar-mode interacts poorly with crypt.el and zcat.el because the tar
  73 ;;    write-file-hook actually writes the file.  Instead it should remove the
  74 ;;    header (and conspire to put it back afterwards) so that other write-file
  75 ;;    hooks which frob the buffer have a chance to do their dirty work.  There
  76 ;;    might be a problem if the tar write-file-hook does not come *first* on
  77 ;;    the list.
  78 ;;
  79 ;; o  Block files, sparse files, continuation files, and the various header
  80 ;;    types aren't editable.  Actually I don't know that they work at all.
  81
  82 ;; Rationale:
  83
  84 ;; Why does tar-mode edit the file itself instead of using tar?
  85
  86 ;; That means that you can edit tar files which you don't have room for
  87 ;; on your local disk.
  88
  89 ;; I don't know about recent features in gnu tar, but old versions of tar
  90 ;; can't replace a file in the middle of a tar file with a new version.
  91 ;; Tar-mode can.  I don't think tar can do things like chmod the subfiles.
  92 ;; An implementation which involved unpacking and repacking the file into
  93 ;; some scratch directory would be very wasteful, and wouldn't be able to
  94 ;; preserve the file owners.
  95
  96 ;;; Code:
  97
  98 (defgroup tar nil
  99   "Simple editing of tar files."
 100   :prefix "tar-"
 101   :group 'data)
 102
 103 (defcustom tar-anal-blocksize 20
 104   "The blocksize of tar files written by Emacs, or nil, meaning don't care.
 105 The blocksize of a tar file is not really the size of the blocks; rather, it is
 106 the number of blocks written with one system call.  When tarring to a tape,
 107 this is the size of the *tape* blocks, but when writing to a file, it doesn't
 108 matter much.  The only noticeable difference is that if a tar file does not
 109 have a blocksize of 20, tar will tell you that; all this really controls is
 110 how many null padding bytes go on the end of the tar file."
 111   :type '(choice integer (const nil))
 112   :group 'tar)
 113
 114 (defcustom tar-update-datestamp nil
 115   "Non-nil means Tar mode should play fast and loose with sub-file datestamps.
 116 If this is true, then editing and saving a tar file entry back into its
 117 tar file will update its datestamp.  If false, the datestamp is unchanged.
 118 You may or may not want this - it is good in that you can tell when a file
 119 in a tar archive has been changed, but it is bad for the same reason that
 120 editing a file in the tar archive at all is bad - the changed version of
 121 the file never exists on disk."
 122   :type 'boolean
 123   :group 'tar)
 124
 125 (defcustom tar-mode-show-date nil
 126   "Non-nil means Tar mode should show the date/time of each subfile.
 127 This information is useful, but it takes screen space away from file names."
 128   :type 'boolean
 129   :group 'tar)
 130
 131 (defvar tar-parse-info nil)
 132 (defvar tar-header-offset nil)
 133 (defvar tar-superior-buffer nil)
 134 (defvar tar-superior-descriptor nil)
 135 (defvar tar-subfile-mode nil)
 136 (defvar tar-file-name-coding-system nil)
 137
 138 (put 'tar-parse-info 'permanent-local t)
 139 (put 'tar-header-offset 'permanent-local t)
 140 (put 'tar-superior-buffer 'permanent-local t)
 141 (put 'tar-superior-descriptor 'permanent-local t)
 142 (put 'tar-file-name-coding-system 'permanent-local t)
 143 \f
 144 (defmacro tar-setf (form val)
 145   "A mind-numbingly simple implementation of setf."
 146   (let ((mform (macroexpand form (and (boundp 'byte-compile-macro-environment)
 147                                       byte-compile-macro-environment))))
 148     (cond ((symbolp mform) (list 'setq mform val))
 149           ((not (consp mform)) (error "can't setf %s" form))
 150           ((eq (car mform) 'aref)
 151            (list 'aset (nth 1 mform) (nth 2 mform) val))
 152           ((eq (car mform) 'car)
 153            (list 'setcar (nth 1 mform) val))
 154           ((eq (car mform) 'cdr)
 155            (list 'setcdr (nth 1 mform) val))
 156           (t (error "don't know how to setf %s" form)))))
 157 \f
 158 ;;; down to business.
 159
 160 (defmacro make-tar-header (name mode uid git size date ck lt ln
 161                            magic uname gname devmaj devmin)
 162   (list 'vector name mode uid git size date ck lt ln
 163         magic uname gname devmaj devmin))
 164
 165 (defmacro tar-header-name (x) (list 'aref x 0))
 166 (defmacro tar-header-mode (x) (list 'aref x 1))
 167 (defmacro tar-header-uid  (x) (list 'aref x 2))
 168 (defmacro tar-header-gid  (x) (list 'aref x 3))
 169 (defmacro tar-header-size (x) (list 'aref x 4))
 170 (defmacro tar-header-date (x) (list 'aref x 5))
 171 (defmacro tar-header-checksum  (x) (list 'aref x 6))
 172 (defmacro tar-header-link-type (x) (list 'aref x 7))
 173 (defmacro tar-header-link-name (x) (list 'aref x 8))
 174 (defmacro tar-header-magic (x) (list 'aref x 9))
 175 (defmacro tar-header-uname (x) (list 'aref x 10))
 176 (defmacro tar-header-gname (x) (list 'aref x 11))
 177 (defmacro tar-header-dmaj (x) (list 'aref x 12))
 178 (defmacro tar-header-dmin (x) (list 'aref x 13))
 179
 180 (defmacro make-tar-desc (data-start tokens)
 181   (list 'cons data-start tokens))
 182
 183 (defmacro tar-desc-data-start (x) (list 'car x))
 184 (defmacro tar-desc-tokens     (x) (list 'cdr x))
 185
 186 (defconst tar-name-offset 0)
 187 (defconst tar-mode-offset (+ tar-name-offset 100))
 188 (defconst tar-uid-offset  (+ tar-mode-offset 8))
 189 (defconst tar-gid-offset  (+ tar-uid-offset 8))
 190 (defconst tar-size-offset (+ tar-gid-offset 8))
 191 (defconst tar-time-offset (+ tar-size-offset 12))
 192 (defconst tar-chk-offset  (+ tar-time-offset 12))
 193 (defconst tar-linkp-offset (+ tar-chk-offset 8))
 194 (defconst tar-link-offset (+ tar-linkp-offset 1))
 195 ;;; GNU-tar specific slots.
 196 (defconst tar-magic-offset (+ tar-link-offset 100))
 197 (defconst tar-uname-offset (+ tar-magic-offset 8))
 198 (defconst tar-gname-offset (+ tar-uname-offset 32))
 199 (defconst tar-dmaj-offset (+ tar-gname-offset 32))
 200 (defconst tar-dmin-offset (+ tar-dmaj-offset 8))
 201 (defconst tar-end-offset (+ tar-dmin-offset 8))
 202
 203 (defun tar-header-block-tokenize (string)
 204   "Return a `tar-header' structure.
 205 This is a list of name, mode, uid, gid, size,
 206 write-date, checksum, link-type, and link-name."
 207   (setq string (string-as-unibyte string))
 208   (cond ((< (length string) 512) nil)
 209         (;(some 'plusp string)           ; <-- oops, massive cycle hog!
 210          (or (not (= 0 (aref string 0))) ; This will do.
 211              (not (= 0 (aref string 101))))
 212          (let* ((name-end (1- tar-mode-offset))
 213                 (link-end (1- tar-magic-offset))
 214                 (uname-end (1- tar-gname-offset))
 215                 (gname-end (1- tar-dmaj-offset))
 216                 (link-p (aref string tar-linkp-offset))
 217                 (magic-str (substring string tar-magic-offset (1- tar-uname-offset)))
 218                 (uname-valid-p (or (string= "ustar  " magic-str) (string= "GNUtar " magic-str)))
 219                 name linkname
 220                 (nulsexp   "[^\000]*\000"))
 221            (when (string-match nulsexp string tar-name-offset)
 222              (setq name-end (min name-end (1- (match-end 0)))))
 223            (when (string-match nulsexp string tar-link-offset)
 224              (setq link-end (min link-end (1- (match-end 0)))))
 225            (when (string-match nulsexp string tar-uname-offset)
 226              (setq uname-end (min uname-end (1- (match-end 0)))))
 227            (when (string-match nulsexp string tar-gname-offset)
 228              (setq gname-end (min gname-end (1- (match-end 0)))))
 229            (setq name (substring string tar-name-offset name-end)
 230                  link-p (if (or (= link-p 0) (= link-p ?0))
 231                             nil
 232                           (- link-p ?0)))
 233            (setq linkname (substring string tar-link-offset link-end))
 234            (if default-enable-multibyte-characters
 235                (setq name
 236                      (decode-coding-string name tar-file-name-coding-system)
 237                      linkname
 238                      (decode-coding-string linkname
 239                                            tar-file-name-coding-system)))
 240            (if (and (null link-p) (string-match "/\\'" name)) (setq link-p 5)) ; directory
 241            (make-tar-header
 242              name
 243              (tar-parse-octal-integer string tar-mode-offset tar-uid-offset)
 244              (tar-parse-octal-integer string tar-uid-offset tar-gid-offset)
 245              (tar-parse-octal-integer string tar-gid-offset tar-size-offset)
 246              (tar-parse-octal-integer string tar-size-offset tar-time-offset)
 247              (tar-parse-octal-long-integer string tar-time-offset tar-chk-offset)
 248              (tar-parse-octal-integer string tar-chk-offset tar-linkp-offset)
 249              link-p
 250              linkname
 251              uname-valid-p
 252              (and uname-valid-p (substring string tar-uname-offset uname-end))
 253              (and uname-valid-p (substring string tar-gname-offset gname-end))
 254              (tar-parse-octal-integer string tar-dmaj-offset tar-dmin-offset)
 255              (tar-parse-octal-integer string tar-dmin-offset tar-end-offset)
 256              )))
 257         (t 'empty-tar-block)))
 258
 259
 260 (defun tar-parse-octal-integer (string &optional start end)
 261   (if (null start) (setq start 0))
 262   (if (null end) (setq end (length string)))
 263   (if (= (aref string start) 0)
 264       0
 265     (let ((n 0))
 266       (while (< start end)
 267         (setq n (if (< (aref string start) ?0) n
 268                   (+ (* n 8) (- (aref string start) ?0)))
 269               start (1+ start)))
 270       n)))
 271
 272 (defun tar-parse-octal-long-integer (string &optional start end)
 273   (if (null start) (setq start 0))
 274   (if (null end) (setq end (length string)))
 275   (if (= (aref string start) 0)
 276       (list 0 0)
 277     (let ((lo 0)
 278           (hi 0))
 279       (while (< start end)
 280         (if (>= (aref string start) ?0)
 281             (setq lo (+ (* lo 8) (- (aref string start) ?0))
 282                   hi (+ (* hi 8) (ash lo -16))
 283                   lo (logand lo 65535)))
 284         (setq start (1+ start)))
 285       (list hi lo))))
 286
 287 (defun tar-parse-octal-integer-safe (string)
 288   (if (zerop (length string)) (error "empty string"))
 289   (mapc (lambda (c)
 290           (if (or (< c ?0) (> c ?7))
 291               (error "`%c' is not an octal digit" c)))
 292         string)
 293   (tar-parse-octal-integer string))
 294
 295
 296 (defun tar-header-block-checksum (string)
 297   "Compute and return a tar-acceptable checksum for this block."
 298   (setq string (string-as-unibyte string))
 299   (let* ((chk-field-start tar-chk-offset)
 300          (chk-field-end (+ chk-field-start 8))
 301          (sum 0)
 302          (i 0))
 303     ;; Add up all of the characters except the ones in the checksum field.
 304     ;; Add that field as if it were filled with spaces.
 305     (while (< i chk-field-start)
 306       (setq sum (+ sum (aref string i))
 307             i (1+ i)))
 308     (setq i chk-field-end)
 309     (while (< i 512)
 310       (setq sum (+ sum (aref string i))
 311             i (1+ i)))
 312     (+ sum (* 32 8))))
 313
 314 (defun tar-header-block-check-checksum (hblock desired-checksum file-name)
 315   "Beep and print a warning if the checksum doesn't match."
 316   (if (not (= desired-checksum (tar-header-block-checksum hblock)))
 317       (progn (beep) (message "Invalid checksum for file %s!" file-name))))
 318
 319 (defun tar-clip-time-string (time)
 320   (let ((str (current-time-string time)))
 321     (concat " " (substring str 4 16) (substring str 19 24))))
 322
 323 (defun tar-grind-file-mode (mode)
 324   "Construct a `-rw--r--r--' string indicating MODE.
 325 MODE should be an integer which is a file mode value."
 326   (string
 327    (if (zerop (logand 256 mode)) ?- ?r)
 328    (if (zerop (logand 128 mode)) ?- ?w)
 329    (if (zerop (logand 1024 mode)) (if (zerop (logand  64 mode)) ?- ?x) ?s)
 330    (if (zerop (logand  32 mode)) ?- ?r)
 331    (if (zerop (logand  16 mode)) ?- ?w)
 332    (if (zerop (logand 2048 mode)) (if (zerop (logand   8 mode)) ?- ?x) ?s)
 333    (if (zerop (logand   4 mode)) ?- ?r)
 334    (if (zerop (logand   2 mode)) ?- ?w)
 335    (if (zerop (logand   1 mode)) ?- ?x)))
 336
 337 (defun tar-header-block-summarize (tar-hblock &optional mod-p)
 338   "Return a line similar to the output of `tar -vtf'."
 339   (let ((name (tar-header-name tar-hblock))
 340         (mode (tar-header-mode tar-hblock))
 341         (uid (tar-header-uid tar-hblock))
 342         (gid (tar-header-gid tar-hblock))
 343         (uname (tar-header-uname tar-hblock))
 344         (gname (tar-header-gname tar-hblock))
 345         (size (tar-header-size tar-hblock))
 346         (time (tar-header-date tar-hblock))
 347         ;; (ck (tar-header-checksum tar-hblock))
 348         (type (tar-header-link-type tar-hblock))
 349         (link-name (tar-header-link-name tar-hblock)))
 350     (format "%c%c%s%8s/%-8s%7s%s %s%s"
 351             (if mod-p ?* ? )
 352             (cond ((or (eq type nil) (eq type 0)) ?-)
 353                   ((eq type 1) ?h)      ; link
 354                   ((eq type 2) ?l)      ; symlink
 355                   ((eq type 3) ?c)      ; char special
 356                   ((eq type 4) ?b)      ; block special
 357                   ((eq type 5) ?d)      ; directory
 358                   ((eq type 6) ?p)      ; FIFO/pipe
 359                   ((eq type 20) ?*)     ; directory listing
 360                   ((eq type 28) ?L)     ; next has longname
 361                   ((eq type 29) ?M)     ; multivolume continuation
 362                   ((eq type 35) ?S)     ; sparse
 363                   ((eq type 38) ?V)     ; volume header
 364                   ((eq type 55) ?H)     ; extended pax header
 365                   (t ?\s)
 366                   )
 367             (tar-grind-file-mode mode)
 368             (if (= 0 (length uname)) uid uname)
 369             (if (= 0 (length gname)) gid gname)
 370             size
 371             (if tar-mode-show-date (tar-clip-time-string time) "")
 372             (propertize name
 373                         'mouse-face 'highlight
 374                         'help-echo "mouse-2: extract this file into a buffer")
 375             (if (or (eq type 1) (eq type 2))
 376                 (concat (if (= type 1) " ==> " " --> ") link-name)
 377               ""))))
 378
 379 (defun tar-untar-buffer ()
 380   "Extract all archive members in the tar-file into the current directory."
 381   (interactive)
 382   (let ((multibyte enable-multibyte-characters))
 383     (unwind-protect
 384         (save-restriction
 385           (widen)
 386           (set-buffer-multibyte nil)
 387           (dolist (descriptor tar-parse-info)
 388             (let* ((tokens (tar-desc-tokens descriptor))
 389                    (name (tar-header-name tokens))
 390                    (dir (file-name-directory name))
 391                    (start (+ (tar-desc-data-start descriptor)
 392                              (- tar-header-offset (point-min))))
 393                    (end (+ start (tar-header-size tokens))))
 394               (unless (file-directory-p name)
 395                 (message "Extracting %s" name)
 396                 (if (and dir (not (file-exists-p dir)))
 397                     (make-directory dir t))
 398                 (unless (file-directory-p name)
 399                   (write-region start end name))
 400                 (set-file-modes name (tar-header-mode tokens))))))
 401       (if multibyte
 402           (set-buffer-multibyte 'to)))))
 403
 404 (defun tar-summarize-buffer ()
 405   "Parse the contents of the tar file in the current buffer.
 406 Place a dired-like listing on the front;
 407 then narrow to it, so that only that listing
 408 is visible (and the real data of the buffer is hidden)."
 409   (let ((modified (buffer-modified-p)))
 410     (set-buffer-multibyte nil)
 411     (let* ((result '())
 412            (pos (point-min))
 413            (progress-reporter
 414             (make-progress-reporter "Parsing tar file..."
 415                                     (point-min) (max 1 (- (buffer-size) 1024))))
 416            tokens)
 417       (while (and (<= (+ pos 512) (point-max))
 418                   (not (eq 'empty-tar-block
 419                            (setq tokens
 420                                  (tar-header-block-tokenize
 421                                   (buffer-substring pos (+ pos 512)))))))
 422         (setq pos (+ pos 512))
 423         (progress-reporter-update progress-reporter pos)
 424         (if (memq (tar-header-link-type tokens) '(20 55))
 425             ;; Foo.  There's an extra empty block after these.
 426             (setq pos (+ pos 512)))
 427         (let ((size (tar-header-size tokens)))
 428           (if (< size 0)
 429               (error "%s has size %s - corrupted"
 430                      (tar-header-name tokens) size))
 431           ;;
 432           ;; This is just too slow.  Don't really need it anyway....
 433           ;;(tar-header-block-check-checksum
 434           ;;  hblock (tar-header-block-checksum hblock)
 435           ;;  (tar-header-name tokens))
 436
 437           (push (make-tar-desc pos tokens) result)
 438
 439           (and (null (tar-header-link-type tokens))
 440                (> size 0)
 441                (setq pos
 442                      (+ pos 512 (ash (ash (1- size) -9) 9)) ; this works
 443                      ;;(+ pos (+ size (- 512 (rem (1- size) 512)))) ; this doesn't
 444                      ))))
 445       (make-local-variable 'tar-parse-info)
 446       (setq tar-parse-info (nreverse result))
 447       ;; A tar file should end with a block or two of nulls,
 448       ;; but let's not get a fatal error if it doesn't.
 449       (if (eq tokens 'empty-tar-block)
 450           (progress-reporter-done progress-reporter)
 451         (message "Warning: premature EOF parsing tar file")))
 452     ;; Obey the user's preference for the use of uni/multibytes.
 453     (if default-enable-multibyte-characters
 454         (set-buffer-multibyte 'to))
 455     (goto-char (point-min))
 456     (let ((inhibit-read-only t)
 457           ;; Collect summary lines and insert them all at once since tar files
 458           ;; can be pretty big.
 459           (total-summaries
 460            (mapconcat
 461             (lambda (tar-desc)
 462               (tar-header-block-summarize (tar-desc-tokens tar-desc)))
 463             tar-parse-info
 464             "\n")))
 465       (insert total-summaries "\n"))
 466     (narrow-to-region (point-min) (point))
 467     (set (make-local-variable 'tar-header-offset) (position-bytes (point)))
 468     (goto-char (point-min))
 469     (restore-buffer-modified-p modified)))
 470 \f
 471 (defvar tar-mode-map
 472   (let ((map (make-keymap)))
 473     (suppress-keymap map)
 474     (define-key map " " 'tar-next-line)
 475     (define-key map "C" 'tar-copy)
 476     (define-key map "d" 'tar-flag-deleted)
 477     (define-key map "\^D" 'tar-flag-deleted)
 478     (define-key map "e" 'tar-extract)
 479     (define-key map "f" 'tar-extract)
 480     (define-key map "\C-m" 'tar-extract)
 481     (define-key map [mouse-2] 'tar-mouse-extract)
 482     (define-key map "g" 'revert-buffer)
 483     (define-key map "h" 'describe-mode)
 484     (define-key map "n" 'tar-next-line)
 485     (define-key map "\^N" 'tar-next-line)
 486     (define-key map [down] 'tar-next-line)
 487     (define-key map "o" 'tar-extract-other-window)
 488     (define-key map "p" 'tar-previous-line)
 489     (define-key map "q" 'quit-window)
 490     (define-key map "\^P" 'tar-previous-line)
 491     (define-key map [up] 'tar-previous-line)
 492     (define-key map "R" 'tar-rename-entry)
 493     (define-key map "u" 'tar-unflag)
 494     (define-key map "v" 'tar-view)
 495     (define-key map "x" 'tar-expunge)
 496     (define-key map "\177" 'tar-unflag-backwards)
 497     (define-key map "E" 'tar-extract-other-window)
 498     (define-key map "M" 'tar-chmod-entry)
 499     (define-key map "G" 'tar-chgrp-entry)
 500     (define-key map "O" 'tar-chown-entry)
 501     ;; Let mouse-1 follow the link.
 502     (define-key map [follow-link] 'mouse-face)
 503
 504     ;; Make menu bar items.
 505
 506     ;; Get rid of the Edit menu bar item to save space.
 507     (define-key map [menu-bar edit] 'undefined)
 508
 509     (define-key map [menu-bar immediate]
 510       (cons "Immediate" (make-sparse-keymap "Immediate")))
 511
 512     (define-key map [menu-bar immediate view]
 513       '("View This File" . tar-view))
 514     (define-key map [menu-bar immediate display]
 515       '("Display in Other Window" . tar-display-other-window))
 516     (define-key map [menu-bar immediate find-file-other-window]
 517       '("Find in Other Window" . tar-extract-other-window))
 518     (define-key map [menu-bar immediate find-file]
 519       '("Find This File" . tar-extract))
 520
 521     (define-key map [menu-bar mark]
 522       (cons "Mark" (make-sparse-keymap "Mark")))
 523
 524     (define-key map [menu-bar mark unmark-all]
 525       '("Unmark All" . tar-clear-modification-flags))
 526     (define-key map [menu-bar mark deletion]
 527       '("Flag" . tar-flag-deleted))
 528     (define-key map [menu-bar mark unmark]
 529       '("Unflag" . tar-unflag))
 530
 531     (define-key map [menu-bar operate]
 532       (cons "Operate" (make-sparse-keymap "Operate")))
 533
 534     (define-key map [menu-bar operate chown]
 535       '("Change Owner..." . tar-chown-entry))
 536     (define-key map [menu-bar operate chgrp]
 537       '("Change Group..." . tar-chgrp-entry))
 538     (define-key map [menu-bar operate chmod]
 539       '("Change Mode..." . tar-chmod-entry))
 540     (define-key map [menu-bar operate rename]
 541       '("Rename to..." . tar-rename-entry))
 542     (define-key map [menu-bar operate copy]
 543       '("Copy to..." . tar-copy))
 544     (define-key map [menu-bar operate expunge]
 545       '("Expunge Marked Files" . tar-expunge))
 546     \f
 547     map)
 548   "Local keymap for Tar mode listings.")
 549
 550 \f
 551 ;; tar mode is suitable only for specially formatted data.
 552 (put 'tar-mode 'mode-class 'special)
 553 (put 'tar-subfile-mode 'mode-class 'special)
 554
 555 ;;;###autoload
 556 (define-derived-mode tar-mode nil "Tar"
 557   "Major mode for viewing a tar file as a dired-like listing of its contents.
 558 You can move around using the usual cursor motion commands.
 559 Letters no longer insert themselves.
 560 Type `e' to pull a file out of the tar file and into its own buffer;
 561 or click mouse-2 on the file's line in the Tar mode buffer.
 562 Type `c' to copy an entry from the tar file into another file on disk.
 563
 564 If you edit a sub-file of this archive (as with the `e' command) and
 565 save it with \\[save-buffer], the contents of that buffer will be
 566 saved back into the tar-file buffer; in this way you can edit a file
 567 inside of a tar archive without extracting it and re-archiving it.
 568
 569 See also: variables `tar-update-datestamp' and `tar-anal-blocksize'.
 570 \\{tar-mode-map}"
 571   ;; this is not interactive because you shouldn't be turning this
 572   ;; mode on and off.  You can corrupt things that way.
 573   ;; rms: with permanent locals, it should now be possible to make this work
 574   ;; interactively in some reasonable fashion.
 575   (make-local-variable 'tar-header-offset)
 576   (make-local-variable 'tar-parse-info)
 577   (set (make-local-variable 'require-final-newline) nil) ; binary data, dude...
 578   (set (make-local-variable 'revert-buffer-function) 'tar-mode-revert)
 579   (set (make-local-variable 'local-enable-local-variables) nil)
 580   (set (make-local-variable 'next-line-add-newlines) nil)
 581   (set (make-local-variable 'tar-file-name-coding-system)
 582        (or file-name-coding-system
 583            default-file-name-coding-system
 584            locale-coding-system))
 585   ;; Prevent loss of data when saving the file.
 586   (set (make-local-variable 'file-precious-flag) t)
 587   (auto-save-mode 0)
 588   (set (make-local-variable 'write-contents-functions) '(tar-mode-write-file))
 589   (buffer-disable-undo)
 590   (widen)
 591   (if (and (boundp 'tar-header-offset) tar-header-offset)
 592       (narrow-to-region (point-min) tar-header-offset)
 593     (tar-summarize-buffer)
 594     (tar-next-line 0)))
 595
 596
 597 (defun tar-subfile-mode (p)
 598   "Minor mode for editing an element of a tar-file.
 599 This mode arranges for \"saving\" this buffer to write the data
 600 into the tar-file buffer that it came from.  The changes will actually
 601 appear on disk when you save the tar-file's buffer."
 602   (interactive "P")
 603   (or (and (boundp 'tar-superior-buffer) tar-superior-buffer)
 604       (error "This buffer is not an element of a tar file"))
 605   ;; Don't do this, because it is redundant and wastes mode line space.
 606   ;;  (or (assq 'tar-subfile-mode minor-mode-alist)
 607   ;;      (setq minor-mode-alist (append minor-mode-alist
 608   ;;                                 (list '(tar-subfile-mode " TarFile")))))
 609   (make-local-variable 'tar-subfile-mode)
 610   (setq tar-subfile-mode
 611         (if (null p)
 612             (not tar-subfile-mode)
 613             (> (prefix-numeric-value p) 0)))
 614   (cond (tar-subfile-mode
 615          (add-hook 'write-file-functions 'tar-subfile-save-buffer nil t)
 616          ;; turn off auto-save.
 617          (auto-save-mode -1)
 618          (setq buffer-auto-save-file-name nil)
 619          (run-hooks 'tar-subfile-mode-hook))
 620         (t
 621          (remove-hook 'write-file-functions 'tar-subfile-save-buffer t))))
 622
 623
 624 ;; Revert the buffer and recompute the dired-like listing.
 625 (defun tar-mode-revert (&optional no-auto-save no-confirm)
 626   (let ((revert-buffer-function nil)
 627         (old-offset tar-header-offset)
 628         success)
 629     (setq tar-header-offset nil)
 630     (unwind-protect
 631         (and (revert-buffer t no-confirm)
 632              (progn (widen)
 633                     (setq success t)
 634                     (tar-mode)))
 635       ;; If the revert was canceled,
 636       ;; put back the old value of tar-header-offset.
 637       (or success
 638           (setq tar-header-offset old-offset)))))
 639
 640
 641 (defun tar-next-line (arg)
 642   "Move cursor vertically down ARG lines and to the start of the filename."
 643   (interactive "p")
 644   (forward-line arg)
 645   (if (eobp) nil (forward-char (if tar-mode-show-date 54 36))))
 646
 647 (defun tar-previous-line (arg)
 648   "Move cursor vertically up ARG lines and to the start of the filename."
 649   (interactive "p")
 650   (tar-next-line (- arg)))
 651
 652 (defun tar-current-descriptor (&optional noerror)
 653   "Return the tar-descriptor of the current line, or signals an error."
 654   ;; I wish lines had plists, like in ZMACS...
 655   (or (nth (count-lines (point-min)
 656                         (save-excursion (beginning-of-line) (point)))
 657            tar-parse-info)
 658       (if noerror
 659           nil
 660           (error "This line does not describe a tar-file entry"))))
 661
 662 (defun tar-get-descriptor ()
 663   (let* ((descriptor (tar-current-descriptor))
 664          (tokens (tar-desc-tokens descriptor))
 665          (size (tar-header-size tokens))
 666          (link-p (tar-header-link-type tokens)))
 667     (if link-p
 668         (error "This is %s, not a real file"
 669                (cond ((eq link-p 5) "a directory")
 670                      ((eq link-p 20) "a tar directory header")
 671                      ((eq link-p 28) "a next has longname")
 672                      ((eq link-p 29) "a multivolume-continuation")
 673                      ((eq link-p 35) "a sparse entry")
 674                      ((eq link-p 38) "a volume header")
 675                      ((eq link-p 55) "an extended pax header")
 676                      (t "a link"))))
 677     (if (zerop size) (message "This is a zero-length file"))
 678     descriptor))
 679
 680 (defun tar-mouse-extract (event)
 681   "Extract a file whose tar directory line you click on."
 682   (interactive "e")
 683   (with-current-buffer (window-buffer (posn-window (event-end event)))
 684     (save-excursion
 685       (goto-char (posn-point (event-end event)))
 686       ;; Just make sure this doesn't get an error.
 687       (tar-get-descriptor)))
 688   (select-window (posn-window (event-end event)))
 689   (goto-char (posn-point (event-end event)))
 690   (tar-extract))
 691
 692 (defun tar-file-name-handler (op &rest args)
 693   "Helper function for `tar-extract'."
 694   (or (eq op 'file-exists-p)
 695       (let ((file-name-handler-alist nil))
 696         (apply op args))))
 697
 698 (defun tar-extract (&optional other-window-p)
 699   "In Tar mode, extract this entry of the tar file into its own buffer."
 700   (interactive)
 701   (let* ((view-p (eq other-window-p 'view))
 702          (descriptor (tar-get-descriptor))
 703          (tokens (tar-desc-tokens descriptor))
 704          (name (tar-header-name tokens))
 705          (size (tar-header-size tokens))
 706          (start (+ (tar-desc-data-start descriptor)
 707                    (- tar-header-offset (point-min))))
 708          (end (+ start size)))
 709     (let* ((tar-buffer (current-buffer))
 710            (tarname (buffer-name))
 711            (bufname (concat (file-name-nondirectory name)
 712                             " ("
 713                              tarname
 714                              ")"))
 715            (read-only-p (or buffer-read-only view-p))
 716            (new-buffer-file-name (expand-file-name
 717                                   ;; `:' is not allowed on Windows
 718                                   (concat tarname "!" name)))
 719            (buffer (get-file-buffer new-buffer-file-name))
 720            (just-created nil)
 721            (pos (point))
 722            undo-list)
 723       (unless buffer
 724         (setq buffer (generate-new-buffer bufname))
 725         (with-current-buffer buffer
 726           (setq undo-list buffer-undo-list
 727                 buffer-undo-list t))
 728         (setq bufname (buffer-name buffer))
 729         (setq just-created t)
 730         (unwind-protect
 731             (let (coding)
 732               (narrow-to-region start end)
 733               (goto-char start)
 734               (setq coding (or coding-system-for-read
 735                                (and set-auto-coding-function
 736                                     (funcall set-auto-coding-function
 737                                              name (- end start)))
 738                                ;; The following binding causes
 739                                ;; find-buffer-file-type-coding-system
 740                                ;; (defined on dos-w32.el) to act as if
 741                                ;; the file being extracted existed, so
 742                                ;; that the file's contents' encoding and
 743                                ;; EOL format are auto-detected.
 744                                (let ((file-name-handler-alist
 745                                       '(("" . tar-file-name-handler))))
 746                                  (car (find-operation-coding-system
 747                                        'insert-file-contents
 748                                        (cons name (current-buffer)) t)))))
 749               (if (or (not coding)
 750                       (eq (coding-system-type coding) 'undecided))
 751                   (setq coding (detect-coding-region start end t)))
 752               (if (and default-enable-multibyte-characters
 753                        (coding-system-get coding :for-unibyte))
 754                   (with-current-buffer buffer
 755                     (set-buffer-multibyte nil)))
 756               (widen)
 757               (decode-coding-region start end coding buffer)
 758               (with-current-buffer buffer
 759                 (goto-char (point-min))
 760                 (setq buffer-file-name new-buffer-file-name)
 761                 (setq buffer-file-truename
 762                       (abbreviate-file-name buffer-file-name))
 763                 ;; Force buffer-file-coding-system to what
 764                 ;; decode-coding-region actually used.
 765                 (set-buffer-file-coding-system last-coding-system-used t)
 766                 ;; Set the default-directory to the dir of the
 767                 ;; superior buffer.
 768                 (setq default-directory
 769                       (with-current-buffer tar-buffer
 770                         default-directory))
 771                 (normal-mode)  ; pick a mode.
 772                 (rename-buffer bufname)
 773                 (make-local-variable 'tar-superior-buffer)
 774                 (make-local-variable 'tar-superior-descriptor)
 775                 (setq tar-superior-buffer tar-buffer)
 776                 (setq tar-superior-descriptor descriptor)
 777                 (setq buffer-read-only read-only-p)
 778                 (set-buffer-modified-p nil)
 779                 (setq buffer-undo-list undo-list)
 780                 (tar-subfile-mode 1))
 781               (set-buffer tar-buffer))
 782           (narrow-to-region (point-min) tar-header-offset)
 783           (goto-char pos)))
 784       (if view-p
 785           (view-buffer
 786            buffer (and just-created 'kill-buffer-if-not-modified))
 787         (if (eq other-window-p 'display)
 788             (display-buffer buffer)
 789           (if other-window-p
 790               (switch-to-buffer-other-window buffer)
 791             (switch-to-buffer buffer)))))))
 792
 793
 794 (defun tar-extract-other-window ()
 795   "In Tar mode, find this entry of the tar file in another window."
 796   (interactive)
 797   (tar-extract t))
 798
 799 (defun tar-display-other-window ()
 800   "In Tar mode, display this entry of the tar file in another window."
 801   (interactive)
 802   (tar-extract 'display))
 803
 804 (defun tar-view ()
 805   "In Tar mode, view the tar file entry on this line."
 806   (interactive)
 807   (tar-extract 'view))
 808
 809
 810 (defun tar-read-file-name (&optional prompt)
 811   "Read a file name with this line's entry as the default."
 812   (or prompt (setq prompt "Copy to: "))
 813   (let* ((default-file (expand-file-name
 814                         (tar-header-name (tar-desc-tokens
 815                                           (tar-current-descriptor)))))
 816          (target (expand-file-name
 817                   (read-file-name prompt
 818                                   (file-name-directory default-file)
 819                                   default-file nil))))
 820     (if (or (string= "" (file-name-nondirectory target))
 821             (file-directory-p target))
 822         (setq target (concat (if (string-match "/$" target)
 823                                  (substring target 0 (1- (match-end 0)))
 824                                  target)
 825                              "/"
 826                              (file-name-nondirectory default-file))))
 827     target))
 828
 829
 830 (defun tar-copy (&optional to-file)
 831   "In Tar mode, extract this entry of the tar file into a file on disk.
 832 If TO-FILE is not supplied, it is prompted for, defaulting to the name of
 833 the current tar-entry."
 834   (interactive (list (tar-read-file-name)))
 835   (let* ((descriptor (tar-get-descriptor))
 836          (tokens (tar-desc-tokens descriptor))
 837          (name (tar-header-name tokens))
 838          (size (tar-header-size tokens))
 839          (start (+ (tar-desc-data-start descriptor)
 840                    (- tar-header-offset (point-min))))
 841          (end (+ start size))
 842          (inhibit-file-name-handlers inhibit-file-name-handlers)
 843          (inhibit-file-name-operation inhibit-file-name-operation))
 844     (save-restriction
 845       (widen)
 846       ;; Inhibit compressing a subfile again if *both* name and
 847       ;; to-file are handled by jka-compr
 848       (if (and (eq (find-file-name-handler name 'write-region) 'jka-compr-handler)
 849                (eq (find-file-name-handler to-file 'write-region) 'jka-compr-handler))
 850           (setq inhibit-file-name-handlers
 851                 (cons 'jka-compr-handler
 852                       (and (eq inhibit-file-name-operation 'write-region)
 853                            inhibit-file-name-handlers))
 854                 inhibit-file-name-operation 'write-region))
 855       (let ((coding-system-for-write 'no-conversion))
 856         (write-region start end to-file nil nil nil t)))
 857     (message "Copied tar entry %s to %s" name to-file)))
 858
 859 (defun tar-flag-deleted (p &optional unflag)
 860   "In Tar mode, mark this sub-file to be deleted from the tar file.
 861 With a prefix argument, mark that many files."
 862   (interactive "p")
 863   (beginning-of-line)
 864   (dotimes (i (abs p))
 865     (if (tar-current-descriptor unflag) ; barf if we're not on an entry-line.
 866         (progn
 867           (delete-char 1)
 868           (insert (if unflag " " "D"))))
 869     (forward-line (if (< p 0) -1 1)))
 870   (if (eobp) nil (forward-char 36)))
 871
 872 (defun tar-unflag (p)
 873   "In Tar mode, un-mark this sub-file if it is marked to be deleted.
 874 With a prefix argument, un-mark that many files forward."
 875   (interactive "p")
 876   (tar-flag-deleted p t))
 877
 878 (defun tar-unflag-backwards (p)
 879   "In Tar mode, un-mark this sub-file if it is marked to be deleted.
 880 With a prefix argument, un-mark that many files backward."
 881   (interactive "p")
 882   (tar-flag-deleted (- p) t))
 883
 884
 885 (defun tar-expunge-internal ()
 886   "Expunge the tar-entry specified by the current line."
 887   (let* ((descriptor (tar-current-descriptor))
 888          (tokens (tar-desc-tokens descriptor))
 889          ;; (line (tar-desc-data-start descriptor))
 890          (name (tar-header-name tokens))
 891          (size (tar-header-size tokens))
 892          (link-p (tar-header-link-type tokens))
 893          (start (tar-desc-data-start descriptor))
 894          (following-descs (cdr (memq descriptor tar-parse-info))))
 895     (if link-p (setq size 0)) ; size lies for hard-links.
 896     ;;
 897     ;; delete the current line...
 898     (beginning-of-line)
 899     (let ((line-start (point)))
 900       (end-of-line) (forward-char)
 901       ;; decrement the header-pointer to be in sync...
 902       (setq tar-header-offset (- tar-header-offset (- (point) line-start)))
 903       (delete-region line-start (point)))
 904     ;;
 905     ;; delete the data pointer...
 906     (setq tar-parse-info (delq descriptor tar-parse-info))
 907     ;;
 908     ;; delete the data from inside the file...
 909     (widen)
 910     (let* ((data-start (+ start (- tar-header-offset (point-min)) -512))
 911            (data-end (+ data-start 512 (ash (ash (+ size 511) -9) 9))))
 912       (delete-region data-start data-end)
 913       ;;
 914       ;; and finally, decrement the start-pointers of all following
 915       ;; entries in the archive.  This is a pig when deleting a bunch
 916       ;; of files at once - we could optimize this to only do the
 917       ;; iteration over the files that remain, or only iterate up to
 918       ;; the next file to be deleted.
 919       (let ((data-length (- data-end data-start)))
 920         (dolist (desc following-descs)
 921           (tar-setf (tar-desc-data-start desc)
 922                     (- (tar-desc-data-start desc) data-length))))
 923       ))
 924   (narrow-to-region (point-min) tar-header-offset))
 925
 926
 927 (defun tar-expunge (&optional noconfirm)
 928   "In Tar mode, delete all the archived files flagged for deletion.
 929 This does not modify the disk image; you must save the tar file itself
 930 for this to be permanent."
 931   (interactive)
 932   (if (or noconfirm
 933           (y-or-n-p "Expunge files marked for deletion? "))
 934       (let ((n 0))
 935         (save-excursion
 936           (goto-char (point-min))
 937           (while (not (eobp))
 938             (if (looking-at "D")
 939                 (progn (tar-expunge-internal)
 940                        (setq n (1+ n)))
 941                 (forward-line 1)))
 942           ;; after doing the deletions, add any padding that may be necessary.
 943           (tar-pad-to-blocksize)
 944           (narrow-to-region (point-min) tar-header-offset))
 945         (if (zerop n)
 946             (message "Nothing to expunge.")
 947             (message "%s files expunged.  Be sure to save this buffer." n)))))
 948
 949
 950 (defun tar-clear-modification-flags ()
 951   "Remove the stars at the beginning of each line."
 952   (interactive)
 953   (save-excursion
 954     (goto-char (point-min))
 955     (while (< (point) tar-header-offset)
 956       (if (not (eq (following-char) ?\s))
 957           (progn (delete-char 1) (insert " ")))
 958       (forward-line 1))))
 959
 960
 961 (defun tar-chown-entry (new-uid)
 962   "Change the user-id associated with this entry in the tar file.
 963 If this tar file was written by GNU tar, then you will be able to edit
 964 the user id as a string; otherwise, you must edit it as a number.
 965 You can force editing as a number by calling this with a prefix arg.
 966 This does not modify the disk image; you must save the tar file itself
 967 for this to be permanent."
 968   (interactive (list
 969                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
 970                    (if (or current-prefix-arg
 971                            (not (tar-header-magic tokens)))
 972                        (let (n)
 973                          (while (not (numberp (setq n (read-minibuffer
 974                                                         "New UID number: "
 975                                                         (format "%s" (tar-header-uid tokens)))))))
 976                          n)
 977                        (read-string "New UID string: " (tar-header-uname tokens))))))
 978   (cond ((stringp new-uid)
 979          (tar-setf (tar-header-uname (tar-desc-tokens (tar-current-descriptor)))
 980                    new-uid)
 981          (tar-alter-one-field tar-uname-offset (concat new-uid "\000")))
 982         (t
 983          (tar-setf (tar-header-uid (tar-desc-tokens (tar-current-descriptor)))
 984                    new-uid)
 985          (tar-alter-one-field tar-uid-offset
 986            (concat (substring (format "%6o" new-uid) 0 6) "\000 ")))))
 987
 988
 989 (defun tar-chgrp-entry (new-gid)
 990   "Change the group-id associated with this entry in the tar file.
 991 If this tar file was written by GNU tar, then you will be able to edit
 992 the group id as a string; otherwise, you must edit it as a number.
 993 You can force editing as a number by calling this with a prefix arg.
 994 This does not modify the disk image; you must save the tar file itself
 995 for this to be permanent."
 996   (interactive (list
 997                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
 998                    (if (or current-prefix-arg
 999                            (not (tar-header-magic tokens)))
1000                        (let (n)
1001                          (while (not (numberp (setq n (read-minibuffer
1002                                                         "New GID number: "
1003                                                         (format "%s" (tar-header-gid tokens)))))))
1004                          n)
1005                        (read-string "New GID string: " (tar-header-gname tokens))))))
1006   (cond ((stringp new-gid)
1007          (tar-setf (tar-header-gname (tar-desc-tokens (tar-current-descriptor)))
1008                    new-gid)
1009          (tar-alter-one-field tar-gname-offset
1010            (concat new-gid "\000")))
1011         (t
1012          (tar-setf (tar-header-gid (tar-desc-tokens (tar-current-descriptor)))
1013                    new-gid)
1014          (tar-alter-one-field tar-gid-offset
1015            (concat (substring (format "%6o" new-gid) 0 6) "\000 ")))))
1016
1017 (defun tar-rename-entry (new-name)
1018   "Change the name associated with this entry in the tar file.
1019 This does not modify the disk image; you must save the tar file itself
1020 for this to be permanent."
1021   (interactive
1022     (list (read-string "New name: "
1023             (tar-header-name (tar-desc-tokens (tar-current-descriptor))))))
1024   (if (string= "" new-name) (error "zero length name"))
1025   (let ((encoded-new-name (encode-coding-string new-name
1026                                                 tar-file-name-coding-system)))
1027     (if (> (length encoded-new-name) 98) (error "name too long"))
1028     (tar-setf (tar-header-name (tar-desc-tokens (tar-current-descriptor)))
1029               new-name)
1030     (tar-alter-one-field 0
1031      (substring (concat encoded-new-name (make-string 99 0)) 0 99))))
1032
1033
1034 (defun tar-chmod-entry (new-mode)
1035   "Change the protection bits associated with this entry in the tar file.
1036 This does not modify the disk image; you must save the tar file itself
1037 for this to be permanent."
1038   (interactive (list (tar-parse-octal-integer-safe
1039                        (read-string "New protection (octal): "))))
1040   (tar-setf (tar-header-mode (tar-desc-tokens (tar-current-descriptor)))
1041             new-mode)
1042   (tar-alter-one-field tar-mode-offset
1043     (concat (substring (format "%6o" new-mode) 0 6) "\000 ")))
1044
1045
1046 (defun tar-alter-one-field (data-position new-data-string)
1047   (let* ((descriptor (tar-current-descriptor))
1048          (tokens (tar-desc-tokens descriptor)))
1049     (unwind-protect
1050         (save-excursion
1051           ;;
1052           ;; update the header-line.
1053           (beginning-of-line)
1054           (let ((p (point)))
1055             (forward-line 1)
1056             (delete-region p (point))
1057             (insert (tar-header-block-summarize tokens) "\n")
1058             (setq tar-header-offset (point-max)))
1059
1060           (widen)
1061           (let* ((start (+ (tar-desc-data-start descriptor)
1062                            (- tar-header-offset (point-min))
1063                            -512)))
1064             ;;
1065             ;; delete the old field and insert a new one.
1066             (goto-char (+ start data-position))
1067             (delete-region (point) (+ (point) (length new-data-string))) ; <--
1068
1069             ;; As new-data-string is unibyte, just inserting it will
1070             ;; make eight-bit chars to the corresponding multibyte
1071             ;; chars.  This avoid that conversion, i.e., eight-bit
1072             ;; chars are converted to multibyte form of eight-bit
1073             ;; chars.
1074             (insert (string-to-multibyte new-data-string))
1075             ;;
1076             ;; compute a new checksum and insert it.
1077             (let ((chk (tar-header-block-checksum
1078                         (buffer-substring start (+ start 512)))))
1079               (goto-char (+ start tar-chk-offset))
1080               (delete-region (point) (+ (point) 8))
1081               (insert (format "%6o" chk))
1082               (insert 0)
1083               (insert ? )
1084               (tar-setf (tar-header-checksum tokens) chk)
1085               ;;
1086               ;; ok, make sure we didn't botch it.
1087               (tar-header-block-check-checksum
1088                 (buffer-substring start (+ start 512))
1089                 chk (tar-header-name tokens))
1090               )))
1091       (narrow-to-region (point-min) tar-header-offset)
1092       (tar-next-line 0))))
1093
1094
1095 (defun tar-octal-time (timeval)
1096   ;; Format a timestamp as 11 octal digits.  Ghod, I hope this works...
1097   (let ((hibits (car timeval)) (lobits (car (cdr timeval))))
1098     (format "%05o%01o%05o"
1099             (lsh hibits -2)
1100             (logior (lsh (logand 3 hibits) 1)
1101                     (if (> (logand lobits 32768) 0) 1 0))
1102             (logand 32767 lobits)
1103             )))
1104
1105 (defun tar-subfile-save-buffer ()
1106   "In tar subfile mode, save this buffer into its parent tar-file buffer.
1107 This doesn't write anything to disk; you must save the parent tar-file buffer
1108 to make your changes permanent."
1109   (interactive)
1110   (if (not (and (boundp 'tar-superior-buffer) tar-superior-buffer))
1111     (error "This buffer has no superior tar file buffer"))
1112   (if (not (and (boundp 'tar-superior-descriptor) tar-superior-descriptor))
1113     (error "This buffer doesn't have an index into its superior tar file!"))
1114   (save-excursion
1115   (let ((subfile (current-buffer))
1116         (coding buffer-file-coding-system)
1117         (descriptor tar-superior-descriptor)
1118         subfile-size)
1119     (set-buffer tar-superior-buffer)
1120     (let* ((tokens (tar-desc-tokens descriptor))
1121            (start (tar-desc-data-start descriptor))
1122            (name (tar-header-name tokens))
1123            (size (tar-header-size tokens))
1124            (size-pad (ash (ash (+ size 511) -9) 9))
1125            (head (memq descriptor tar-parse-info))
1126            (following-descs (cdr head)))
1127       (if (not head)
1128         (error "Can't find this tar file entry in its parent tar file!"))
1129       (unwind-protect
1130        (save-excursion
1131         ;; delete the old data...
1132         (let* ((data-start (+ start (- tar-header-offset (point-min))))
1133                (data-end (+ data-start (ash (ash (+ size 511) -9) 9))))
1134           (narrow-to-region data-start data-end)
1135           (delete-region (point-min) (point-max))
1136           ;; insert the new data...
1137           (goto-char data-start)
1138           (with-current-buffer subfile
1139             (save-restriction
1140               (widen)
1141               (encode-coding-region 1 (point-max) coding tar-superior-buffer)))
1142           (setq subfile-size (- (point-max) (point-min)))
1143           ;;
1144           ;; pad the new data out to a multiple of 512...
1145           (let ((subfile-size-pad (ash (ash (+ subfile-size 511) -9) 9)))
1146             (goto-char (point-max))
1147             (insert (make-string (- subfile-size-pad subfile-size) 0))
1148             ;;
1149             ;; update the data pointer of this and all following files...
1150             (tar-setf (tar-header-size tokens) subfile-size)
1151             (let ((difference (- subfile-size-pad size-pad)))
1152               (dolist (desc following-descs)
1153                 (tar-setf (tar-desc-data-start desc)
1154                           (+ (tar-desc-data-start desc) difference))))
1155             ;;
1156             ;; Update the size field in the header block.
1157             (widen)
1158             (let ((header-start (- data-start 512)))
1159               (goto-char (+ header-start tar-size-offset))
1160               (delete-region (point) (+ (point) 12))
1161               (insert (format "%11o" subfile-size))
1162               (insert ? )
1163               ;;
1164               ;; Maybe update the datestamp.
1165               (if (not tar-update-datestamp)
1166                   nil
1167                 (goto-char (+ header-start tar-time-offset))
1168                 (delete-region (point) (+ (point) 12))
1169                 (insert (tar-octal-time (current-time)))
1170                 (insert ? ))
1171               ;;
1172               ;; compute a new checksum and insert it.
1173               (let ((chk (tar-header-block-checksum
1174                           (buffer-substring header-start data-start))))
1175                 (goto-char (+ header-start tar-chk-offset))
1176                 (delete-region (point) (+ (point) 8))
1177                 (insert (format "%6o" chk))
1178                 (insert 0)
1179                 (insert ? )
1180                 (tar-setf (tar-header-checksum tokens) chk)))
1181             ;;
1182             ;; alter the descriptor-line...
1183             ;;
1184             (let ((position (- (length tar-parse-info) (length head))))
1185               (goto-char (point-min))
1186               (forward-line position)
1187               (beginning-of-line)
1188               (let ((p (point))
1189                     after
1190                     (m (set-marker (make-marker) tar-header-offset)))
1191                 (forward-line 1)
1192                 (setq after (point))
1193                 ;; Insert the new text after the old, before deleting,
1194                 ;; to preserve the window start.
1195                 (let ((line (tar-header-block-summarize tokens t)))
1196                   (insert-before-markers line "\n"))
1197                 (delete-region p after)
1198                 (setq tar-header-offset (marker-position m)))
1199               )))
1200         ;; after doing the insertion, add any final padding that may be necessary.
1201         (tar-pad-to-blocksize))
1202        (narrow-to-region (point-min) tar-header-offset)))
1203     (set-buffer-modified-p t)   ; mark the tar file as modified
1204     (tar-next-line 0)
1205     (set-buffer subfile)
1206     (set-buffer-modified-p nil) ; mark the tar subfile as unmodified
1207     (message "Saved into tar-buffer `%s'.  Be sure to save that buffer!"
1208              (buffer-name tar-superior-buffer))
1209     ;; Prevent basic-save-buffer from changing our coding-system.
1210     (setq last-coding-system-used buffer-file-coding-system)
1211     ;; Prevent ordinary saving from happening.
1212     t)))
1213
1214
1215 ;; When this function is called, it is sure that the buffer is unibyte.
1216 (defun tar-pad-to-blocksize ()
1217   "If we are being anal about tar file blocksizes, fix up the current buffer.
1218 Leaves the region wide."
1219   (if (null tar-anal-blocksize)
1220       nil
1221     (widen)
1222     (let* ((last-desc (nth (1- (length tar-parse-info)) tar-parse-info))
1223            (start (tar-desc-data-start last-desc))
1224            (tokens (tar-desc-tokens last-desc))
1225            (link-p (tar-header-link-type tokens))
1226            (size (if link-p 0 (tar-header-size tokens)))
1227            (data-end (+ start size))
1228            (bbytes (ash tar-anal-blocksize 9))
1229            (pad-to (+ bbytes (* bbytes (/ (- data-end (point-min)) bbytes))))
1230            (inhibit-read-only t) ; ##
1231            )
1232       ;; If the padding after the last data is too long, delete some;
1233       ;; else insert some until we are padded out to the right number of blocks.
1234       ;;
1235       (let ((goal-end (+ (or tar-header-offset 0) pad-to)))
1236         (if (> (point-max) goal-end)
1237             (delete-region goal-end (point-max))
1238           (goto-char (point-max))
1239           (insert (make-string (- goal-end (point-max)) ?\0)))))))
1240
1241
1242 ;; Used in write-file-hook to write tar-files out correctly.
1243 (defun tar-mode-write-file ()
1244   (unwind-protect
1245       (save-excursion
1246         (widen)
1247         ;; Doing this here confuses things - the region gets left too wide!
1248         ;; I suppose this is run in a context where changing the buffer is bad.
1249         ;; (tar-pad-to-blocksize)
1250         ;; tar-header-offset turns out to be null for files fetched with W3,
1251         ;; at least.
1252         (let ((coding-system-for-write 'no-conversion))
1253           (write-region (or tar-header-offset
1254                             (point-min))
1255                         (point-max)
1256                         buffer-file-name nil t))
1257         (tar-clear-modification-flags)
1258         (set-buffer-modified-p nil))
1259     (narrow-to-region (point-min) tar-header-offset))
1260   ;; Return t because we've written the file.
1261   t)
1262 \f
1263 (provide 'tar-mode)
1264
1265 ;; arch-tag: 8a585a4a-340e-42c2-89e7-d3b1013a4b78
1266 ;;; tar-mode.el ends here