lisp/composite.el

   1 ;;; composite.el --- support character composition
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009, 2010, 2011
   5 ;;   National Institute of Advanced Industrial Science and Technology (AIST)
   6 ;;   Registration Number H14PRO021
   7
   8 ;; Author: Kenichi HANDA <handa@etl.go.jp>
   9 ;; (according to ack.texi)
  10 ;; Keywords: mule, multilingual, character composition
  11 ;; Package: emacs
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (defconst reference-point-alist
  35   '((tl . 0) (tc . 1) (tr . 2)
  36     (Bl . 3) (Bc . 4) (Br . 5)
  37     (bl . 6) (bc . 7) (br . 8)
  38     (cl . 9) (cc . 10) (cr . 11)
  39     (top-left . 0) (top-center . 1) (top-right . 2)
  40     (base-left . 3) (base-center . 4) (base-right . 5)
  41     (bottom-left . 6) (bottom-center . 7) (bottom-right . 8)
  42     (center-left . 9) (center-center . 10) (center-right . 11)
  43     ;; For backward compatibility...
  44     (ml . 3) (mc . 10) (mr . 5)
  45     (mid-left . 3) (mid-center . 10) (mid-right . 5))
  46   "Alist of symbols vs integer codes of glyph reference points.
  47 A glyph reference point symbol is to be used to specify a composition
  48 rule in COMPONENTS argument to such functions as `compose-region'.
  49
  50 The meaning of glyph reference point codes is as follows:
  51
  52     0----1----2 <---- ascent    0:tl or top-left
  53     |         |                 1:tc or top-center
  54     |         |                 2:tr or top-right
  55     |         |                 3:Bl or base-left     9:cl or center-left
  56     9   10   11 <---- center    4:Bc or base-center  10:cc or center-center
  57     |         |                 5:Br or base-right   11:cr or center-right
  58   --3----4----5-- <-- baseline  6:bl or bottom-left
  59     |         |                 7:bc or bottom-center
  60     6----7----8 <---- descent   8:br or bottom-right
  61
  62 Glyph reference point symbols are to be used to specify composition
  63 rule of the form \(GLOBAL-REF-POINT . NEW-REF-POINT), where
  64 GLOBAL-REF-POINT is a reference point in the overall glyphs already
  65 composed, and NEW-REF-POINT is a reference point in the new glyph to
  66 be added.
  67
  68 For instance, if GLOBAL-REF-POINT is `br' (bottom-right) and
  69 NEW-REF-POINT is `tc' (top-center), the overall glyph is updated as
  70 follows (the point `*' corresponds to both reference points):
  71
  72     +-------+--+ <--- new ascent
  73     |       |  |
  74     | global|  |
  75     | glyph |  |
  76  -- |       |  |-- <--- baseline \(doesn't change)
  77     +----+--*--+
  78     |    | new |
  79     |    |glyph|
  80     +----+-----+ <--- new descent
  81
  82 A composition rule may have the form \(GLOBAL-REF-POINT
  83 NEW-REF-POINT XOFF YOFF), where XOFF and YOFF specify how much
  84 to shift NEW-REF-POINT from GLOBAL-REF-POINT.  In this case, XOFF
  85 and YOFF are integers in the range -100..100 representing the
  86 shifting percentage against the font size.")
  87
  88
  89 ;;;###autoload
  90 (defun encode-composition-rule (rule)
  91   "Encode composition rule RULE into an integer value.
  92 RULE is a cons of global and new reference point symbols
  93 \(see `reference-point-alist')."
  94
  95   ;; This must be compatible with C macro COMPOSITION_ENCODE_RULE
  96   ;; defined in composite.h.
  97
  98   (if (and (integerp rule) (< rule 144))
  99       ;; Already encoded.
 100       rule
 101     (if (consp rule)
 102         (let ((gref (car rule))
 103               (nref (cdr rule))
 104               xoff yoff)
 105           (if (consp nref)              ; (GREF NREF XOFF YOFF)
 106               (progn
 107                 (setq xoff (nth 1 nref)
 108                       yoff (nth 2 nref)
 109                       nref (car nref))
 110                 (or (and (>= xoff -100) (<= xoff 100)
 111                          (>= yoff -100) (<= yoff 100))
 112                     (error "Invalid composition rule: %s" rule))
 113                 (setq xoff (+ xoff 128) yoff (+ yoff 128)))
 114             ;; (GREF . NREF)
 115             (setq xoff 0 yoff 0))
 116           (or (integerp gref)
 117               (setq gref (cdr (assq gref reference-point-alist))))
 118           (or (integerp nref)
 119               (setq nref (cdr (assq nref reference-point-alist))))
 120           (or (and (>= gref 0) (< gref 12) (>= nref 0) (< nref 12))
 121               (error "Invalid composition rule: %S" rule))
 122           (logior (lsh xoff 16) (lsh yoff 8) (+ (* gref 12) nref)))
 123       (error "Invalid composition rule: %S" rule))))
 124
 125 ;; Decode encoded composition rule RULE-CODE.  The value is a cons of
 126 ;; global and new reference point symbols.
 127 ;; This must be compatible with C macro COMPOSITION_DECODE_RULE
 128 ;; defined in composite.h.
 129
 130 (defun decode-composition-rule (rule-code)
 131   (or (and (natnump rule-code) (< rule-code #x1000000))
 132       (error "Invalid encoded composition rule: %S" rule-code))
 133   (let ((xoff (lsh rule-code -16))
 134         (yoff (logand (lsh rule-code -8) #xFF))
 135         gref nref)
 136     (setq rule-code (logand rule-code #xFF)
 137           gref (car (rassq (/ rule-code 12) reference-point-alist))
 138           nref (car (rassq (% rule-code 12) reference-point-alist)))
 139     (or (and gref (symbolp gref) nref (symbolp nref))
 140         (error "Invalid composition rule code: %S" rule-code))
 141     (if (and (= xoff 0) (= yoff 0))
 142         (cons gref nref)
 143       (setq xoff (- xoff 128) yoff (- yoff 128))
 144       (list gref xoff yoff nref))))
 145
 146 ;; Encode composition rules in composition components COMPONENTS.  The
 147 ;; value is a copy of COMPONENTS, where composition rules (cons of
 148 ;; global and new glyph reference point symbols) are replaced with
 149 ;; encoded composition rules.  Optional 2nd argument NOCOPY non-nil
 150 ;; means don't make a copy but modify COMPONENTS directly.
 151
 152 (defun encode-composition-components (components &optional nocopy)
 153   (or nocopy
 154       (setq components (copy-sequence components)))
 155   (if (vectorp components)
 156       (let ((len (length components))
 157             (i 1))
 158         (while (< i len)
 159           (aset components i
 160                 (encode-composition-rule (aref components i)))
 161           (setq i (+ i 2))))
 162     (let ((tail (cdr components)))
 163       (while tail
 164         (setcar tail
 165                 (encode-composition-rule (car tail)))
 166         (setq tail (nthcdr 2 tail)))))
 167   components)
 168
 169 ;; Decode composition rule codes in composition components COMPONENTS.
 170 ;; The value is a copy of COMPONENTS, where composition rule codes are
 171 ;; replaced with composition rules (cons of global and new glyph
 172 ;; reference point symbols).  Optional 2nd argument NOCOPY non-nil
 173 ;; means don't make a copy but modify COMPONENTS directly.
 174 ;; It is assumed that COMPONENTS is a vector and is for rule-base
 175 ;; composition, thus (2N+1)th elements are rule codes.
 176
 177 (defun decode-composition-components (components &optional nocopy)
 178   (or nocopy
 179       (setq components (copy-sequence components)))
 180   (let ((len (length components))
 181         (i 1))
 182     (while (< i len)
 183       (aset components i
 184             (decode-composition-rule (aref components i)))
 185       (setq i (+ i 2))))
 186   components)
 187
 188 (defun compose-region (start end &optional components modification-func)
 189   "Compose characters in the current region.
 190
 191 Characters are composed relatively, i.e. composed by overstriking
 192 or stacking depending on ascent, descent and other metrics of
 193 glyphs.
 194
 195 For instance, if the region has three characters \"XYZ\", X is
 196 regarded as BASE glyph, and Y is displayed:
 197   (1) above BASE if Y's descent value is not positive
 198   (2) below BASE if Y's ascent value is not positive
 199   (3) on BASE (i.e. at the BASE position) otherwise
 200 and Z is displayed with the same rule while regarding the whole
 201 XY glyphs as BASE.
 202
 203 When called from a program, expects these four arguments.
 204
 205 First two arguments START and END are positions (integers or markers)
 206 specifying the region.
 207
 208 Optional 3rd argument COMPONENTS, if non-nil, is a character, a string
 209 or a vector or list of integers and rules.
 210
 211 If it is a character, it is an alternate character to display instead
 212 of the text in the region.
 213
 214 If it is a string, the elements are one or more alternate characters.  In
 215 this case, TAB element has a special meaning.  If the first
 216 character is TAB, the glyphs are displayed with left padding space
 217 so that no pixel overlaps with the previous column.  If the last
 218 character is TAB, the glyphs are displayed with right padding
 219 space so that no pixel overlaps with the following column.
 220
 221 If it is a vector or list, it is a sequence of alternate characters and
 222 composition rules, where (2N)th elements are characters and (2N+1)th
 223 elements are composition rules to specify how to compose (2N+2)th
 224 elements with previously composed N glyphs.
 225
 226 A composition rule is a cons of global and new glyph reference point
 227 symbols.  See the documentation of `reference-point-alist' for more
 228 details.
 229
 230 Optional 4th argument MODIFICATION-FUNC is a function to call to
 231 adjust the composition when it gets invalid because of a change of
 232 text in the composition."
 233   (interactive "r")
 234   (let ((modified-p (buffer-modified-p))
 235         (inhibit-read-only t))
 236     (if (or (vectorp components) (listp components))
 237         (setq components (encode-composition-components components))
 238       (if (= (length components) 0)
 239           (error "Invalid composition component: %s" components)))
 240     (compose-region-internal start end components modification-func)
 241     (restore-buffer-modified-p modified-p)))
 242
 243 (defun decompose-region (start end)
 244   "Decompose text in the current region.
 245
 246 When called from a program, expects two arguments,
 247 positions (integers or markers) specifying the region."
 248   (interactive "r")
 249   (let ((modified-p (buffer-modified-p))
 250         (inhibit-read-only t))
 251     (remove-text-properties start end '(composition nil))
 252     (restore-buffer-modified-p modified-p)))
 253
 254 (defun compose-string (string &optional start end components modification-func)
 255   "Compose characters in string STRING.
 256
 257 The return value is STRING with the `composition' property put on all
 258 the characters in it.
 259
 260 Optional 2nd and 3rd arguments START and END specify the range of
 261 STRING to be composed.  They default to the beginning and the end of
 262 STRING respectively.
 263
 264 Optional 4th argument COMPONENTS, if non-nil, is a character or a
 265 sequence (vector, list, or string) of integers.  See the function
 266 `compose-region' for more detail.
 267
 268 Optional 5th argument MODIFICATION-FUNC is a function to call to
 269 adjust the composition when it gets invalid because of a change of
 270 text in the composition."
 271   (if (or (vectorp components) (listp components))
 272       (setq components (encode-composition-components components))
 273     (if (= (length components) 0)
 274         (error "Invalid composition component: %s" components)))
 275   (or start (setq start 0))
 276   (or end (setq end (length string)))
 277   (compose-string-internal string start end components modification-func)
 278   string)
 279
 280 (defun decompose-string (string)
 281   "Return STRING where `composition' property is removed."
 282   (remove-text-properties 0 (length string) '(composition nil) string)
 283   string)
 284
 285 (defun compose-chars (&rest args)
 286   "Return a string from arguments in which all characters are composed.
 287 For relative composition, arguments are characters.
 288 For rule-based composition, Mth \(where M is odd) arguments are
 289 characters, and Nth \(where N is even) arguments are composition rules.
 290 A composition rule is a cons of glyph reference points of the form
 291 \(GLOBAL-REF-POINT . NEW-REF-POINT).  See the documentation of
 292 `reference-point-alist' for more detail."
 293   (let (str components)
 294     (if (consp (car (cdr args)))
 295         ;; Rule-base composition.
 296         (let ((tail (encode-composition-components args 'nocopy)))
 297           (while tail
 298             (setq str (cons (car tail) str))
 299             (setq tail (nthcdr 2 tail)))
 300           (setq str (concat (nreverse str))
 301                 components args))
 302       ;; Relative composition.
 303       (setq str (concat args)))
 304     (compose-string-internal str 0 (length str) components)))
 305
 306 (defun find-composition (pos &optional limit string detail-p)
 307   "Return information about a composition at or near buffer position POS.
 308
 309 If the character at POS has `composition' property, the value is a list
 310 \(FROM TO VALID-P).
 311
 312 FROM and TO specify the range of text that has the same `composition'
 313 property, VALID-P is t if this composition is valid, and nil if not.
 314
 315 If there's no composition at POS, and the optional 2nd argument LIMIT
 316 is non-nil, search for a composition toward the position given by LIMIT.
 317
 318 If no composition is found, return nil.
 319
 320 Optional 3rd argument STRING, if non-nil, is a string to look for a
 321 composition in; nil means the current buffer.
 322
 323 If a valid composition is found and the optional 4th argument DETAIL-P
 324 is non-nil, the return value is a list of the form
 325
 326    (FROM TO COMPONENTS RELATIVE-P MOD-FUNC WIDTH)
 327
 328 COMPONENTS is a vector of integers, the meaning depends on RELATIVE-P.
 329
 330 RELATIVE-P is t if the composition method is relative, else nil.
 331
 332 If RELATIVE-P is t, COMPONENTS is a vector of characters to be
 333 composed.  If RELATIVE-P is nil, COMPONENTS is a vector of characters
 334 and composition rules as described in `compose-region'.
 335
 336 MOD-FUNC is a modification function of the composition.
 337
 338 WIDTH is a number of columns the composition occupies on the screen.
 339
 340 When Automatic Composition mode is on, this function also finds a
 341 chunk of text that is automatically composed.  If such a chunk is
 342 found closer to POS than the position that has `composition'
 343 property, the value is a list of FROM, TO, and a glyph-string
 344 that specifies how the chunk is to be composed.  See the function
 345 `composition-get-gstring' for the format of the glyph-string."
 346   (let ((result (find-composition-internal pos limit string detail-p)))
 347     (if (and detail-p (> (length result) 3) (nth 2 result) (not (nth 3 result)))
 348         ;; This is a valid rule-base composition.
 349         (decode-composition-components (nth 2 result) 'nocopy))
 350     result))
 351
 352 \f
 353 (defun compose-chars-after (pos &optional limit object)
 354   "Compose characters in current buffer after position POS.
 355
 356 It looks up the char-table `composition-function-table' (which
 357 see) by a character at POS, and compose characters after POS
 358 according to the contents of `composition-function-table'.
 359
 360 Optional 2nd arg LIMIT, if non-nil, limits characters to compose.
 361
 362 Optional 3rd arg OBJECT, if non-nil, is a string that contains the
 363 text to compose.  In that case, POS and LIMIT index into the string.
 364
 365 This function is the default value of `compose-chars-after-function'."
 366   (let ((tail (aref composition-function-table (char-after pos)))
 367         (font-obj (and (display-multi-font-p)
 368                        (and (not (stringp object))
 369                             (font-at pos (selected-window)))))
 370         pattern func result)
 371     (or limit
 372         (setq limit (if (stringp object) (length object) (point-max))))
 373     (when (and font-obj tail)
 374       (save-match-data
 375         (save-excursion
 376           (while tail
 377             (if (functionp (car tail))
 378                 (setq pattern nil func (car tail))
 379               (setq pattern (car (car tail))
 380                     func (cdr (car tail))))
 381             (goto-char pos)
 382             (if pattern
 383                 (if (and (if (stringp object)
 384                              (eq (string-match pattern object) 0)
 385                            (looking-at pattern))
 386                          (<= (match-end 0) limit))
 387                     (setq result
 388                           (funcall func pos (match-end 0) font-obj object)))
 389               (setq result (funcall func pos limit font-obj  object)))
 390             (if result (setq tail nil))))))
 391     result))
 392
 393 (defun compose-last-chars (args)
 394   "Compose last characters.
 395 The argument is a parameterized event of the form
 396         \(compose-last-chars N COMPONENTS),
 397 where N is the number of characters before point to compose,
 398 COMPONENTS, if non-nil, is the same as the argument to `compose-region'
 399 \(which see).  If it is nil, `compose-chars-after' is called,
 400 and that function finds a proper rule to compose the target characters.
 401 This function is intended to be used from input methods.
 402 The global keymap binds special event `compose-last-chars' to this
 403 function.  Input method may generate an event (compose-last-chars N COMPONENTS)
 404 after a sequence of character events."
 405   (interactive "e")
 406   (let ((chars (nth 1 args)))
 407     (if (and (numberp chars)
 408              (>= (- (point) (point-min)) chars))
 409         (if (nth 2 args)
 410             (compose-region (- (point) chars) (point) (nth 2 args))
 411           (compose-chars-after (- (point) chars) (point))))))
 412
 413 (global-set-key [compose-last-chars] 'compose-last-chars)
 414
 415 \f
 416 ;;; Automatic character composition.
 417
 418 ;; These macros must match with C macros LGSTRING_XXX and LGLYPH_XXX in font.h
 419 (defsubst lgstring-header (gstring) (aref gstring 0))
 420 (defsubst lgstring-set-header (gstring header) (aset gstring 0 header))
 421 (defsubst lgstring-font (gstring) (aref (lgstring-header gstring) 0))
 422 (defsubst lgstring-char (gstring i) (aref (lgstring-header gstring) (1+ i)))
 423 (defsubst lgstring-char-len (gstring) (1- (length (lgstring-header gstring))))
 424 (defsubst lgstring-shaped-p (gstring) (aref gstring 1))
 425 (defsubst lgstring-set-id (gstring id) (aset gstring 1 id))
 426 (defsubst lgstring-glyph (gstring i) (aref gstring (+ i 2)))
 427 (defsubst lgstring-glyph-len (gstring) (- (length gstring) 2))
 428 (defsubst lgstring-set-glyph (gstring i glyph) (aset gstring (+ i 2) glyph))
 429
 430 (defsubst lglyph-from (glyph) (aref glyph 0))
 431 (defsubst lglyph-to (glyph) (aref glyph 1))
 432 (defsubst lglyph-char (glyph) (aref glyph 2))
 433 (defsubst lglyph-code (glyph) (aref glyph 3))
 434 (defsubst lglyph-width (glyph) (aref glyph 4))
 435 (defsubst lglyph-lbearing (glyph) (aref glyph 5))
 436 (defsubst lglyph-rbearing (glyph) (aref glyph 6))
 437 (defsubst lglyph-ascent (glyph) (aref glyph 7))
 438 (defsubst lglyph-descent (glyph) (aref glyph 8))
 439 (defsubst lglyph-adjustment (glyph) (aref glyph 9))
 440
 441 (defsubst lglyph-set-from-to (glyph from to)
 442   (progn (aset glyph 0 from) (aset glyph 1 to)))
 443 (defsubst lglyph-set-char (glyph char) (aset glyph 2 char))
 444 (defsubst lglyph-set-code (glyph code) (aset glyph 3 code))
 445 (defsubst lglyph-set-width (glyph width) (aset glyph 4 width))
 446 (defsubst lglyph-set-adjustment (glyph &optional xoff yoff wadjust)
 447   (aset glyph 9 (vector (or xoff 0) (or yoff 0) (or wadjust 0))))
 448
 449 (defsubst lglyph-copy (glyph) (copy-sequence glyph))
 450
 451 (defun lgstring-insert-glyph (gstring idx glyph)
 452   (let ((nglyphs (lgstring-glyph-len gstring))
 453         (i idx))
 454     (while (and (< i nglyphs) (lgstring-glyph gstring i))
 455       (setq i (1+ i)))
 456     (if (= i nglyphs)
 457         (setq gstring (vconcat gstring (vector glyph)))
 458       (if (< (1+ i) nglyphs)
 459           (lgstring-set-glyph gstring (1+ i) nil)))
 460     (while (> i idx)
 461       (lgstring-set-glyph gstring i (lgstring-glyph gstring (1- i)))
 462       (setq i (1- i)))
 463     (lgstring-set-glyph gstring i glyph)
 464     gstring))
 465
 466 (defun compose-glyph-string (gstring from to)
 467   (let ((glyph (lgstring-glyph gstring from))
 468         from-pos to-pos)
 469     (setq from-pos (lglyph-from glyph)
 470           to-pos (lglyph-to (lgstring-glyph gstring (1- to))))
 471     (lglyph-set-from-to glyph from-pos to-pos)
 472     (setq from (1+ from))
 473     (while (and (< from to)
 474                 (setq glyph (lgstring-glyph gstring from)))
 475       (lglyph-set-from-to glyph from-pos to-pos)
 476       (let ((xoff (if (<= (lglyph-rbearing glyph) 0) 0
 477                     (- (lglyph-width glyph)))))
 478         (lglyph-set-adjustment glyph xoff 0 0))
 479       (setq from (1+ from)))
 480     gstring))
 481
 482 (defun compose-glyph-string-relative (gstring from to &optional gap)
 483   (let ((font-object (lgstring-font gstring))
 484         (glyph (lgstring-glyph gstring from))
 485         from-pos to-pos
 486         ascent descent)
 487     (if gap
 488         (setq gap (floor (* (font-get font-object :size) gap)))
 489       (setq gap 0))
 490     (setq from-pos (lglyph-from glyph)
 491           to-pos (lglyph-to (lgstring-glyph gstring (1- to)))
 492           ascent (lglyph-ascent glyph)
 493           descent (lglyph-descent glyph))
 494     (lglyph-set-from-to glyph from-pos to-pos)
 495     (setq from (1+ from))
 496     (while (< from to)
 497       (setq glyph (lgstring-glyph gstring from))
 498       (lglyph-set-from-to glyph from-pos to-pos)
 499       (let ((this-ascent (lglyph-ascent glyph))
 500             (this-descent (lglyph-descent glyph))
 501             xoff yoff)
 502         (setq xoff (if (<= (lglyph-rbearing glyph) 0) 0
 503                      (- (lglyph-width glyph))))
 504         (if (> this-ascent 0)
 505             (if (< this-descent 0)
 506                 (setq yoff (- 0 ascent gap this-descent)
 507                       ascent (+ ascent gap this-ascent this-descent))
 508               (setq yoff 0))
 509           (setq yoff (+ descent gap this-ascent)
 510                 descent (+ descent gap this-ascent this-descent)))
 511         (if (or (/= xoff 0) (/= yoff 0))
 512             (lglyph-set-adjustment glyph xoff yoff 0)))
 513       (setq from (1+ from)))
 514     gstring))
 515
 516 (defun compose-gstring-for-graphic (gstring)
 517   "Compose glyph-string GSTRING for graphic display.
 518 Combining characters are composed with the preceding base
 519 character.  If the preceding character is not a base character,
 520 each combining character is composed as a spacing character by
 521 a padding space before and/or after the character.
 522
 523 All non-spacing characters have this function in
 524 `composition-function-table' unless overwritten."
 525   (let ((nchars (lgstring-char-len gstring))
 526         (nglyphs (lgstring-glyph-len gstring))
 527         (glyph (lgstring-glyph gstring 0)))
 528     (cond
 529      ;; A non-spacing character not following a proper base character.
 530      ((= nchars 1)
 531       (let ((lbearing (lglyph-lbearing glyph))
 532             (rbearing (lglyph-rbearing glyph))
 533             (width (lglyph-width glyph))
 534             xoff)
 535         (if (< lbearing 0)
 536             (setq xoff (- lbearing))
 537           (setq xoff 0 lbearing 0))
 538         (if (< rbearing width)
 539             (setq rbearing width))
 540         (lglyph-set-adjustment glyph xoff 0 (- rbearing lbearing))
 541         gstring))
 542
 543      ;; This sequence doesn't start with a proper base character.
 544      ((memq (get-char-code-property (lgstring-char gstring 0)
 545                                     'general-category)
 546             '(Mn Mc Me Zs Zl Zp Cc Cf Cs))
 547       nil)
 548
 549      ;; A base character and the following non-spacing characters.
 550      (t
 551       (let ((gstr (font-shape-gstring gstring)))
 552         (if (and gstr
 553                  (> (lglyph-to (lgstring-glyph gstr 0)) 0))
 554             gstr
 555           ;; The shaper of the font couldn't shape the gstring.
 556           ;; Shape them according to canonical-combining-class.
 557           (lgstring-set-id gstring nil)
 558           (let* ((width (lglyph-width glyph))
 559                  (ascent (lglyph-ascent glyph))
 560                  (descent (lglyph-descent glyph))
 561                  (rbearing (lglyph-rbearing glyph))
 562                  (lbearing (lglyph-lbearing glyph))
 563                  (center (/ (+ lbearing rbearing) 2))
 564                  (gap (round (* (font-get (lgstring-font gstring) :size) 0.1))))
 565             (dotimes (i nchars)
 566               (setq glyph (lgstring-glyph gstring i))
 567               (when (> i 0)
 568                 (let* ((class (get-char-code-property
 569                                (lglyph-char glyph) 'canonical-combining-class))
 570                        (lb (lglyph-lbearing glyph))
 571                        (rb (lglyph-rbearing glyph))
 572                        (as (lglyph-ascent glyph))
 573                        (de (lglyph-descent glyph))
 574                        (ce (/ (+ lb rb) 2))
 575                        xoff yoff)
 576                   (when (and class (>= class 200) (<= class 240))
 577                     (setq xoff 0 yoff 0)
 578                     (cond
 579                      ((= class 200)
 580                       (setq xoff (- lbearing ce)
 581                             yoff (if (> as 0) 0 (+ descent as))))
 582                      ((= class 202)
 583                       (if (> as 0) (setq as 0))
 584                       (setq xoff (- center ce)
 585                             yoff (if (> as 0) 0 (+ descent as))))
 586                      ((= class 204)
 587                       (if (> as 0) (setq as 0))
 588                       (setq xoff (- rbearing ce)
 589                             yoff (if (> as 0) 0 (+ descent as))))
 590                      ((= class 208)
 591                       (setq xoff (- lbearing rb)))
 592                      ((= class 210)
 593                       (setq xoff (- rbearing lb)))
 594                      ((= class 212)
 595                       (setq xoff (- lbearing ce)
 596                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 597                      ((= class 214)
 598                       (setq xoff (- center ce)
 599                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 600                      ((= class 216)
 601                       (setq xoff (- rbearing ce)
 602                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 603                      ((= class 218)
 604                       (setq xoff (- lbearing ce)
 605                             yoff (if (> as 0) 0 (+ descent as gap))))
 606                      ((= class 220)
 607                       (setq xoff (- center ce)
 608                             yoff (if (> as 0) 0 (+ descent as gap))))
 609                      ((= class 222)
 610                       (setq xoff (- rbearing ce)
 611                             yoff (if (> as 0) 0 (+ descent as gap))))
 612                      ((= class 224)
 613                       (setq xoff (- lbearing rb)))
 614                      ((= class 226)
 615                       (setq xoff (- rbearing lb)))
 616                      ((= class 228)
 617                       (setq xoff (- lbearing ce)
 618                             yoff (if (>= de 0) 0 (- (- ascent) de gap))))
 619                      ((= class 230)
 620                       (setq xoff (- center ce)
 621                             yoff (if (>= de 0) 0 (- (- ascent) de gap))))
 622                      ((= class 232)
 623                       (setq xoff (- rbearing ce)
 624                             yoff (if (>= de 0) 0 (- (+ ascent de) gap)))))
 625                     (lglyph-set-adjustment glyph (- xoff width) yoff)
 626                     (setq lb (+ lb xoff)
 627                           rb (+ lb xoff)
 628                           as (- as yoff)
 629                           de (+ de yoff)))
 630                   (if (< ascent as)
 631                       (setq ascent as))
 632                   (if (< descent de)
 633                       (setq descent de))))))
 634           (let ((i 0))
 635             (while (and (< i nglyphs) (setq glyph (lgstring-glyph gstring i)))
 636               (lglyph-set-from-to glyph 0 (1- nchars))
 637               (setq i (1+ i))))
 638           gstring))))))
 639
 640 (let ((elt `([,(purecopy "\\c.\\c^+") 1 compose-gstring-for-graphic]
 641              [nil 0 compose-gstring-for-graphic])))
 642   (map-char-table
 643    #'(lambda (key val)
 644        (if (memq val '(Mn Mc Me))
 645            (set-char-table-range composition-function-table key elt)))
 646    unicode-category-table))
 647
 648 (defun compose-gstring-for-terminal (gstring)
 649   "Compose glyph string GSTRING for terminal display.
 650 Non-spacing characters are composed with the preceding base
 651 character.  If the preceding character is not a base character,
 652 each non-spacing character is composed as a spacing character by
 653 prepending a space before it."
 654   (let ((nglyphs (lgstring-glyph-len gstring))
 655         (i 0)
 656         (coding (lgstring-font gstring))
 657         glyph)
 658     (while (and (< i nglyphs)
 659                 (setq glyph (lgstring-glyph gstring i)))
 660       (if (not (char-charset (lglyph-char glyph) coding))
 661           (progn
 662             ;; As the terminal doesn't support this glyph, return a
 663             ;; gstring in which each glyph is its own grapheme-cluster
 664             ;; of width 1..
 665             (setq i 0)
 666             (while (and (< i nglyphs)
 667                         (setq glyph (lgstring-glyph gstring i)))
 668               (if (< (lglyph-width glyph) 1)
 669                   (lglyph-set-width glyph 1))
 670               (lglyph-set-from-to glyph i i)
 671               (setq i (1+ i))))
 672         (if (= (lglyph-width glyph) 0)
 673             (if (eq (get-char-code-property (lglyph-char glyph)
 674                                             'general-category)
 675                     'Cf)
 676                 (progn
 677                   ;; Compose by replacing with a space.
 678                   (lglyph-set-char glyph 32)
 679                   (lglyph-set-width glyph 1)
 680                   (setq i (1+ i)))
 681               ;; Compose by prepending a space.
 682               (setq gstring (lgstring-insert-glyph gstring i
 683                                                    (lglyph-copy glyph))
 684                     nglyphs (lgstring-glyph-len gstring))
 685               (setq glyph (lgstring-glyph gstring i))
 686               (lglyph-set-char glyph 32)
 687               (lglyph-set-width glyph 1)
 688               (setq i (+ 2)))
 689           (let ((from (lglyph-from glyph))
 690                 (to (lglyph-to glyph))
 691                 (j (1+ i)))
 692             (while (and (< j nglyphs)
 693                         (setq glyph (lgstring-glyph gstring j))
 694                         (char-charset (lglyph-char glyph) coding)
 695                         (= (lglyph-width glyph) 0))
 696               (setq to (lglyph-to glyph)
 697                     j (1+ j)))
 698             (while (< i j)
 699               (setq glyph (lgstring-glyph gstring i))
 700               (lglyph-set-from-to glyph from to)
 701               (setq i (1+ i)))))))
 702     gstring))
 703
 704
 705 (defun auto-compose-chars (func from to font-object string)
 706   "Compose the characters at FROM by FUNC.
 707 FUNC is called with one argument GSTRING which is built for characters
 708 in the region FROM (inclusive) and TO (exclusive).
 709
 710 If the character are composed on a graphic display, FONT-OBJECT
 711 is a font to use.  Otherwise, FONT-OBJECT is nil, and the function
 712 `compose-gstring-for-terminal' is used instead of FUNC.
 713
 714 If STRING is non-nil, it is a string, and FROM and TO are indices
 715 into the string.  In that case, compose characters in the string.
 716
 717 The value is a gstring containing information for shaping the characters.
 718
 719 This function is the default value of `auto-composition-function' (which see)."
 720   (let ((gstring (composition-get-gstring from to font-object string)))
 721     (if (lgstring-shaped-p gstring)
 722         gstring
 723       (or (fontp font-object 'font-object)
 724           (setq func 'compose-gstring-for-terminal))
 725       (funcall func gstring))))
 726
 727 (put 'auto-composition-mode 'permanent-local t)
 728
 729 (make-variable-buffer-local 'auto-composition-function)
 730 (setq-default auto-composition-function 'auto-compose-chars)
 731
 732 ;;;###autoload
 733 (define-minor-mode auto-composition-mode
 734   "Toggle Auto Composition mode.
 735 With a prefix argument ARG, enable Auto Composition mode if ARG
 736 is positive, and disable it otherwise.  If called from Lisp,
 737 enable the mode if ARG is omitted or nil.
 738
 739 When Auto Composition mode is enabled, text characters are
 740 automatically composed by functions registered in
 741 `composition-function-table'.
 742
 743 You can use `global-auto-composition-mode' to turn on
 744 Auto Composition mode in all buffers (this is the default)."
 745   ;; It's defined in C, this stops the d-m-m macro defining it again.
 746   :variable auto-composition-mode)
 747 ;; It's not defined with DEFVAR_PER_BUFFER though.
 748 (make-variable-buffer-local 'auto-composition-mode)
 749
 750 ;;;###autoload
 751 (define-minor-mode global-auto-composition-mode
 752   "Toggle Auto Composition mode in all buffers.
 753 With a prefix argument ARG, enable it if ARG is positive, and
 754 disable it otherwise.  If called from Lisp, enable it if ARG is
 755 omitted or nil.
 756
 757 For more information on Auto Composition mode, see
 758 `auto-composition-mode' ."
 759   :variable (default-value 'auto-composition-mode))
 760
 761 (defalias 'toggle-auto-composition 'auto-composition-mode)
 762
 763 \f
 764
 765 ;;; composite.el ends here