lisp/term/w32-win.el

   1 ;;; w32-win.el --- parse switches controlling interface with W32 window system
   2
   3 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Kevin Gallo
   7 ;; Keywords: terminals
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; w32-win.el:  this file is loaded from ../lisp/startup.el when it recognizes
  27 ;; that W32 windows are to be used.  Command line switches are parsed and those
  28 ;; pertaining to W32 are processed and removed from the command line.  The
  29 ;; W32 display is opened and hooks are set for popping up the initial window.
  30
  31 ;; startup.el will then examine startup files, and eventually call the hooks
  32 ;; which create the first window (s).
  33
  34 ;;; Code:
  35 \f
  36
  37 ;; These are the standard X switches from the Xt Initialize.c file of
  38 ;; Release 4.
  39
  40 ;; Command line         Resource Manager string
  41
  42 ;; +rv                  *reverseVideo
  43 ;; +synchronous         *synchronous
  44 ;; -background          *background
  45 ;; -bd                  *borderColor
  46 ;; -bg                  *background
  47 ;; -bordercolor         *borderColor
  48 ;; -borderwidth         .borderWidth
  49 ;; -bw                  .borderWidth
  50 ;; -display             .display
  51 ;; -fg                  *foreground
  52 ;; -fn                  *font
  53 ;; -font                *font
  54 ;; -foreground          *foreground
  55 ;; -geometry            .geometry
  56 ;; -i                   .iconType
  57 ;; -itype               .iconType
  58 ;; -iconic              .iconic
  59 ;; -name                .name
  60 ;; -reverse             *reverseVideo
  61 ;; -rv                  *reverseVideo
  62 ;; -selectionTimeout    .selectionTimeout
  63 ;; -synchronous         *synchronous
  64 ;; -xrm
  65
  66 ;; An alist of X options and the function which handles them.  See
  67 ;; ../startup.el.
  68
  69 ;; (if (not (eq window-system 'w32))
  70 ;;     (error "%s: Loading w32-win.el but not compiled for w32" (invocation-name)))
  71
  72 (require 'frame)
  73 (require 'mouse)
  74 (require 'scroll-bar)
  75 (require 'faces)
  76 (require 'select)
  77 (require 'menu-bar)
  78 (require 'dnd)
  79 (require 'w32-vars)
  80
  81 ;; Keep an obsolete alias for w32-focus-frame in case it is used by code
  82 ;; outside Emacs.
  83 (define-obsolete-function-alias 'w32-focus-frame 'x-focus-frame "23.1")
  84
  85 (defvar xlfd-regexp-registry-subnum)
  86 (defvar w32-color-map) ;; defined in w32fns.c
  87
  88 (declare-function w32-send-sys-command "w32fns.c")
  89 (declare-function w32-select-font "w32fns.c")
  90 (declare-function set-message-beep "w32console.c")
  91
  92 ;; Conditional on new-fontset so bootstrapping works on non-GUI compiles
  93 (if (fboundp 'new-fontset)
  94     (require 'fontset))
  95
  96 ;; The following definition is used for debugging scroll bar events.
  97 ;(defun w32-handle-scroll-bar-event (event) (interactive "e") (princ event))
  98
  99 (defun w32-drag-n-drop-debug (event)
 100   "Print the drag-n-drop EVENT in a readable form."
 101   (interactive "e")
 102   (princ event))
 103
 104 (defun w32-drag-n-drop (event)
 105   "Edit the files listed in the drag-n-drop EVENT.
 106 Switch to a buffer editing the last file dropped."
 107   (interactive "e")
 108   (save-excursion
 109     ;; Make sure the drop target has positive co-ords
 110     ;; before setting the selected frame - otherwise it
 111     ;; won't work.  <skx@tardis.ed.ac.uk>
 112     (let* ((window (posn-window (event-start event)))
 113            (coords (posn-x-y (event-start event)))
 114            (x (car coords))
 115            (y (cdr coords)))
 116       (if (and (> x 0) (> y 0))
 117           (set-frame-selected-window nil window))
 118       (mapc (lambda (file-name)
 119                 (let ((f (subst-char-in-string ?\\ ?/ file-name))
 120                       (coding (or file-name-coding-system
 121                                   default-file-name-coding-system)))
 122                   (setq file-name
 123                         (mapconcat 'url-hexify-string
 124                                    (split-string (encode-coding-string f coding)
 125                                                  "/")
 126                                    "/")))
 127                 (dnd-handle-one-url window 'private
 128                                     (concat "file:" file-name)))
 129                 (car (cdr (cdr event)))))
 130   (raise-frame)))
 131
 132 (defun w32-drag-n-drop-other-frame (event)
 133   "Edit the files listed in the drag-n-drop EVENT, in other frames.
 134 May create new frames, or reuse existing ones.  The frame editing
 135 the last file dropped is selected."
 136   (interactive "e")
 137   (mapcar 'find-file-other-frame (car (cdr (cdr event)))))
 138
 139 ;; Bind the drag-n-drop event.
 140 (global-set-key [drag-n-drop] 'w32-drag-n-drop)
 141 (global-set-key [C-drag-n-drop] 'w32-drag-n-drop-other-frame)
 142
 143 ;; Keyboard layout/language change events
 144 ;; For now ignore language-change events; in the future
 145 ;; we should switch the Emacs Input Method to match the
 146 ;; new layout/language selected by the user.
 147 (global-set-key [language-change] 'ignore)
 148
 149 (defvar x-invocation-args)
 150
 151 (defvar x-command-line-resources nil)
 152
 153 (defun x-handle-switch (switch)
 154   "Handle SWITCH of the form \"-switch value\" or \"-switch\"."
 155   (let ((aelt (assoc switch command-line-x-option-alist)))
 156     (if aelt
 157         (push (cons (nth 3 aelt) (or (nth 4 aelt) (pop x-invocation-args)))
 158               default-frame-alist))))
 159
 160 (defun x-handle-numeric-switch (switch)
 161   "Handle SWITCH of the form \"-switch n\"."
 162   (let ((aelt (assoc switch command-line-x-option-alist)))
 163     (if aelt
 164         (push (cons (nth 3 aelt) (string-to-number (pop x-invocation-args)))
 165               default-frame-alist))))
 166
 167 ;; Handle options that apply to initial frame only
 168 (defun x-handle-initial-switch (switch)
 169   (let ((aelt (assoc switch command-line-x-option-alist)))
 170     (if aelt
 171         (push (cons (nth 3 aelt) (or (nth 4 aelt) (pop x-invocation-args)))
 172               initial-frame-alist))))
 173
 174 (defun x-handle-iconic (switch)
 175   "Make \"-iconic\" SWITCH apply only to the initial frame."
 176   (push '(visibility . icon) initial-frame-alist))
 177
 178 (defun x-handle-xrm-switch (switch)
 179   "Handle the \"-xrm\" SWITCH."
 180   (or (consp x-invocation-args)
 181       (error "%s: missing argument to `%s' option" (invocation-name) switch))
 182   (setq x-command-line-resources
 183         (if (null x-command-line-resources)
 184             (car x-invocation-args)
 185           (concat x-command-line-resources "\n" (car x-invocation-args))))
 186   (setq x-invocation-args (cdr x-invocation-args)))
 187
 188 (defun x-handle-geometry (switch)
 189   "Handle the \"-geometry\" SWITCH."
 190   (let* ((geo (x-parse-geometry (car x-invocation-args)))
 191          (left (assq 'left geo))
 192          (top (assq 'top geo))
 193          (height (assq 'height geo))
 194          (width (assq 'width geo)))
 195     (if (or height width)
 196         (setq default-frame-alist
 197               (append default-frame-alist
 198                       '((user-size . t))
 199                       (if height (list height))
 200                       (if width (list width)))
 201               initial-frame-alist
 202               (append initial-frame-alist
 203                       '((user-size . t))
 204                       (if height (list height))
 205                       (if width (list width)))))
 206     (if (or left top)
 207         (setq initial-frame-alist
 208               (append initial-frame-alist
 209                       '((user-position . t))
 210                       (if left (list left))
 211                       (if top (list top)))))
 212     (setq x-invocation-args (cdr x-invocation-args))))
 213
 214 (defun x-handle-name-switch (switch)
 215   "Handle the \"-name\" SWITCH."
 216 ;; Handle the -name option.  Set the variable x-resource-name
 217 ;; to the option's operand; set the name of the initial frame, too.
 218   (or (consp x-invocation-args)
 219       (error "%s: missing argument to `%s' option" (invocation-name) switch))
 220   (setq x-resource-name (pop x-invocation-args))
 221   (push (cons 'name x-resource-name) initial-frame-alist))
 222
 223 (defvar x-display-name nil
 224   "The display name specifying server and frame.")
 225
 226 (defun x-handle-display (switch)
 227   "Handle the \"-display\" SWITCH."
 228   (setq x-display-name (pop x-invocation-args)))
 229
 230 (defun x-handle-args (args)
 231   "Process the X-related command line options in ARGS.
 232 This is done before the user's startup file is loaded.  They are copied to
 233 `x-invocation args' from which the X-related things are extracted, first
 234 the switch (e.g., \"-fg\") in the following code, and possible values
 235 \(e.g., \"black\") in the option handler code (e.g., x-handle-switch).
 236 This returns ARGS with the arguments that have been processed removed."
 237   ;; We use ARGS to accumulate the args that we don't handle here, to return.
 238   (setq x-invocation-args args
 239         args nil)
 240   (while (and x-invocation-args
 241               (not (equal (car x-invocation-args) "--")))
 242     (let* ((this-switch (car x-invocation-args))
 243            (orig-this-switch this-switch)
 244            completion argval aelt handler)
 245       (setq x-invocation-args (cdr x-invocation-args))
 246       ;; Check for long options with attached arguments
 247       ;; and separate out the attached option argument into argval.
 248       (if (string-match "^--[^=]*=" this-switch)
 249           (setq argval (substring this-switch (match-end 0))
 250                 this-switch (substring this-switch 0 (1- (match-end 0)))))
 251       ;; Complete names of long options.
 252       (if (string-match "^--" this-switch)
 253           (progn
 254             (setq completion (try-completion this-switch command-line-x-option-alist))
 255             (if (eq completion t)
 256                 ;; Exact match for long option.
 257                 nil
 258               (if (stringp completion)
 259                   (let ((elt (assoc completion command-line-x-option-alist)))
 260                     ;; Check for abbreviated long option.
 261                     (or elt
 262                         (error "Option `%s' is ambiguous" this-switch))
 263                     (setq this-switch completion))))))
 264       (setq aelt (assoc this-switch command-line-x-option-alist))
 265       (if aelt (setq handler (nth 2 aelt)))
 266       (if handler
 267           (if argval
 268               (let ((x-invocation-args
 269                      (cons argval x-invocation-args)))
 270                 (funcall handler this-switch))
 271             (funcall handler this-switch))
 272         (push orig-this-switch args))))
 273   (nconc (nreverse args) x-invocation-args))
 274 \f
 275 ;;
 276 ;; Available colors
 277 ;;
 278 ;; The ordering of the colors is chosen for the user's convenience in
 279 ;; `list-colors-display', which displays the reverse of this list.
 280 ;; Roughly speaking, `list-colors-display' orders by (i) named shades
 281 ;; of grey with hue 0.0, sorted by value (ii) named colors with
 282 ;; saturation 1.0, sorted by hue, (iii) named non-white colors with
 283 ;; saturation less than 1.0, sorted by hue, (iv) other named shades of
 284 ;; white, (v) numbered colors sorted by hue, and (vi) numbered shades
 285 ;; of grey.
 286
 287 (defvar x-colors
 288   '("gray100" "gray99" "gray98" "gray97" "gray96" "gray95" "gray94" "gray93" "gray92"
 289     "gray91" "gray90" "gray89" "gray88" "gray87" "gray86" "gray85" "gray84" "gray83"
 290     "gray82" "gray81" "gray80" "gray79" "gray78" "gray77" "gray76" "gray75" "gray74"
 291     "gray73" "gray72" "gray71" "gray70" "gray69" "gray68" "gray67" "gray66" "gray65"
 292     "gray64" "gray63" "gray62" "gray61" "gray60" "gray59" "gray58" "gray57" "gray56"
 293     "gray55" "gray54" "gray53" "gray52" "gray51" "gray50" "gray49" "gray48" "gray47"
 294     "gray46" "gray45" "gray44" "gray43" "gray42" "gray41" "gray40" "gray39" "gray38"
 295     "gray37" "gray36" "gray35" "gray34" "gray33" "gray32" "gray31" "gray30" "gray29"
 296     "gray28" "gray27" "gray26" "gray25" "gray24" "gray23" "gray22" "gray21" "gray20"
 297     "gray19" "gray18" "gray17" "gray16" "gray15" "gray14" "gray13" "gray12" "gray11"
 298     "gray10" "gray9" "gray8" "gray7" "gray6" "gray5" "gray4" "gray3" "gray2" "gray1"
 299     "gray0" "LightPink1" "LightPink2" "LightPink3" "LightPink4" "pink1" "pink2" "pink3"
 300     "pink4" "PaleVioletRed1" "PaleVioletRed2" "PaleVioletRed3" "PaleVioletRed4"
 301     "LavenderBlush1" "LavenderBlush2" "LavenderBlush3" "LavenderBlush4" "VioletRed1"
 302     "VioletRed2" "VioletRed3" "VioletRed4" "HotPink1" "HotPink2" "HotPink3" "HotPink4"
 303     "DeepPink1" "DeepPink2" "DeepPink3" "DeepPink4" "maroon1" "maroon2" "maroon3"
 304     "maroon4" "orchid1" "orchid2" "orchid3" "orchid4" "plum1" "plum2" "plum3" "plum4"
 305     "thistle1" "thistle2" "thistle3" "thistle4" "MediumOrchid1" "MediumOrchid2"
 306     "MediumOrchid3" "MediumOrchid4" "DarkOrchid1" "DarkOrchid2" "DarkOrchid3"
 307     "DarkOrchid4" "purple1" "purple2" "purple3" "purple4" "MediumPurple1"
 308     "MediumPurple2" "MediumPurple3" "MediumPurple4" "SlateBlue1" "SlateBlue2"
 309     "SlateBlue3" "SlateBlue4" "RoyalBlue1" "RoyalBlue2" "RoyalBlue3" "RoyalBlue4"
 310     "LightSteelBlue1" "LightSteelBlue2" "LightSteelBlue3" "LightSteelBlue4" "SlateGray1"
 311     "SlateGray2" "SlateGray3" "SlateGray4" "DodgerBlue1" "DodgerBlue2" "DodgerBlue3"
 312     "DodgerBlue4" "SteelBlue1" "SteelBlue2" "SteelBlue3" "SteelBlue4" "SkyBlue1"
 313     "SkyBlue2" "SkyBlue3" "SkyBlue4" "LightSkyBlue1" "LightSkyBlue2" "LightSkyBlue3"
 314     "LightSkyBlue4" "LightBlue1" "LightBlue2" "LightBlue3" "LightBlue4" "CadetBlue1"
 315     "CadetBlue2" "CadetBlue3" "CadetBlue4" "azure1" "azure2" "azure3" "azure4"
 316     "LightCyan1" "LightCyan2" "LightCyan3" "LightCyan4" "PaleTurquoise1"
 317     "PaleTurquoise2" "PaleTurquoise3" "PaleTurquoise4" "DarkSlateGray1" "DarkSlateGray2"
 318     "DarkSlateGray3" "DarkSlateGray4" "aquamarine1" "aquamarine2" "aquamarine3"
 319     "aquamarine4" "SeaGreen1" "SeaGreen2" "SeaGreen3" "SeaGreen4" "honeydew1"
 320     "honeydew2" "honeydew3" "honeydew4" "DarkSeaGreen1" "DarkSeaGreen2" "DarkSeaGreen3"
 321     "DarkSeaGreen4" "PaleGreen1" "PaleGreen2" "PaleGreen3" "PaleGreen4"
 322     "DarkOliveGreen1" "DarkOliveGreen2" "DarkOliveGreen3" "DarkOliveGreen4" "OliveDrab1"
 323     "OliveDrab2" "OliveDrab3" "OliveDrab4" "ivory1" "ivory2" "ivory3" "ivory4"
 324     "LightYellow1" "LightYellow2" "LightYellow3" "LightYellow4" "khaki1" "khaki2"
 325     "khaki3" "khaki4" "LemonChiffon1" "LemonChiffon2" "LemonChiffon3" "LemonChiffon4"
 326     "LightGoldenrod1" "LightGoldenrod2" "LightGoldenrod3" "LightGoldenrod4" "cornsilk1"
 327     "cornsilk2" "cornsilk3" "cornsilk4" "goldenrod1" "goldenrod2" "goldenrod3"
 328     "goldenrod4" "DarkGoldenrod1" "DarkGoldenrod2" "DarkGoldenrod3" "DarkGoldenrod4"
 329     "wheat1" "wheat2" "wheat3" "wheat4" "NavajoWhite1" "NavajoWhite2" "NavajoWhite3"
 330     "NavajoWhite4" "burlywood1" "burlywood2" "burlywood3" "burlywood4" "AntiqueWhite1"
 331     "AntiqueWhite2" "AntiqueWhite3" "AntiqueWhite4" "bisque1" "bisque2" "bisque3"
 332     "bisque4" "tan1" "tan2" "tan3" "tan4" "PeachPuff1" "PeachPuff2" "PeachPuff3"
 333     "PeachPuff4" "seashell1" "seashell2" "seashell3" "seashell4" "chocolate1"
 334     "chocolate2" "chocolate3" "chocolate4" "sienna1" "sienna2" "sienna3" "sienna4"
 335     "LightSalmon1" "LightSalmon2" "LightSalmon3" "LightSalmon4" "salmon1" "salmon2"
 336     "salmon3" "salmon4" "coral1" "coral2" "coral3" "coral4" "tomato1" "tomato2"
 337     "tomato3" "tomato4" "MistyRose1" "MistyRose2" "MistyRose3" "MistyRose4" "snow1"
 338     "snow2" "snow3" "snow4" "RosyBrown1" "RosyBrown2" "RosyBrown3" "RosyBrown4"
 339     "IndianRed1" "IndianRed2" "IndianRed3" "IndianRed4" "firebrick1" "firebrick2"
 340     "firebrick3" "firebrick4" "brown1" "brown2" "brown3" "brown4" "magenta1" "magenta2"
 341     "magenta3" "magenta4" "blue1" "blue2" "blue3" "blue4" "DeepSkyBlue1" "DeepSkyBlue2"
 342     "DeepSkyBlue3" "DeepSkyBlue4" "turquoise1" "turquoise2" "turquoise3" "turquoise4"
 343     "cyan1" "cyan2" "cyan3" "cyan4" "SpringGreen1" "SpringGreen2" "SpringGreen3"
 344     "SpringGreen4" "green1" "green2" "green3" "green4" "chartreuse1" "chartreuse2"
 345     "chartreuse3" "chartreuse4" "yellow1" "yellow2" "yellow3" "yellow4" "gold1" "gold2"
 346     "gold3" "gold4" "orange1" "orange2" "orange3" "orange4" "DarkOrange1" "DarkOrange2"
 347     "DarkOrange3" "DarkOrange4" "OrangeRed1" "OrangeRed2" "OrangeRed3" "OrangeRed4"
 348     "red1" "red2" "red3" "red4" "lavender blush" "ghost white" "lavender" "alice blue"
 349     "azure" "light cyan" "mint cream" "honeydew" "ivory" "light goldenrod yellow"
 350     "light yellow" "beige" "floral white" "old lace" "blanched almond" "moccasin"
 351     "papaya whip" "bisque" "antique white" "linen" "peach puff" "seashell" "misty rose"
 352     "snow" "light pink" "pink" "hot pink" "deep pink" "maroon" "pale violet red"
 353     "violet red" "medium violet red" "violet" "plum" "thistle" "orchid" "medium orchid"
 354     "dark orchid" "purple" "blue violet" "medium purple" "light slate blue"
 355     "medium slate blue" "slate blue" "dark slate blue" "midnight blue" "navy"
 356     "dark blue" "light steel blue" "cornflower blue" "dodger blue" "royal blue"
 357     "light slate gray" "slate gray" "dark slate gray" "steel blue" "cadet blue"
 358     "light sky blue" "sky blue" "light blue" "powder blue" "pale turquoise" "turquoise"
 359     "medium turquoise" "dark cyan" "aquamarine" "medium aquamarine" "light sea green"
 360     "medium sea green" "sea green" "dark sea green" "pale green" "lime green"
 361     "forest green" "light green" "green yellow" "yellow green" "olive drab"
 362     "dark olive green" "lemon chiffon" "khaki" "dark khaki" "cornsilk"
 363     "pale goldenrod" "light goldenrod" "goldenrod" "dark goldenrod" "wheat"
 364     "navajo white" "tan" "burlywood" "sandy brown" "peru" "chocolate" "saddle brown"
 365     "sienna" "rosy brown" "dark salmon" "coral" "tomato" "light salmon" "salmon"
 366     "light coral" "indian red" "firebrick" "brown" "dark red" "magenta"
 367     "dark magenta" "dark violet" "medium blue" "blue" "deep sky blue"
 368     "cyan" "medium spring green" "spring green" "green" "lawn green" "chartreuse"
 369     "yellow" "gold" "orange" "dark orange" "orange red" "red" "white" "white smoke"
 370     "gainsboro" "light grey" "gray" "dark grey" "dim gray" "black" )
 371   "The list of X colors from the `rgb.txt' file.
 372 XConsortium: rgb.txt,v 10.41 94/02/20 18:39:36 rws Exp")
 373
 374 (defun xw-defined-colors (&optional frame)
 375   "Internal function called by `defined-colors', which see."
 376   (or frame (setq frame (selected-frame)))
 377   (let ((defined-colors nil))
 378     (dolist (this-color (or (mapcar 'car w32-color-map) x-colors))
 379       (and (color-supported-p this-color frame t)
 380            (push this-color defined-colors)))
 381     defined-colors))
 382 \f
 383 \f
 384 ;;;; Function keys
 385
 386  ;;; make f10 activate the real menubar rather than the mini-buffer menu
 387  ;;; navigation feature.
 388  (defun w32-menu-bar-open (&optional frame)
 389    "Start key navigation of the menu bar in FRAME.
 390
 391 This initially activates the first menu-bar item, and you can then navigate
 392 with the arrow keys, select a menu entry with the Return key or cancel with
 393 the Escape key.  If FRAME has no menu bar, this function does nothing.
 394
 395 If FRAME is nil or not given, use the selected frame.
 396 If FRAME does not have the menu bar enabled, display a text menu using
 397 `tmm-menubar'."
 398    (interactive "i")
 399    (if menu-bar-mode
 400        (w32-send-sys-command ?\xf100 frame)
 401      (with-selected-frame (or frame (selected-frame))
 402        (tmm-menubar))))
 403 \f
 404
 405 ;; W32 systems have different fonts than commonly found on X, so
 406 ;; we define our own standard fontset here.
 407 (defvar w32-standard-fontset-spec
 408  "-*-Courier New-normal-r-*-*-13-*-*-*-c-*-fontset-standard"
 409  "String of fontset spec of the standard fontset.
 410 This defines a fontset consisting of the Courier New variations for
 411 European languages which are distributed with Windows as
 412 \"Multilanguage Support\".
 413
 414 See the documentation of `create-fontset-from-fontset-spec' for the format.")
 415
 416 (defun x-win-suspend-error ()
 417   "Report an error when a suspend is attempted."
 418   (error "Suspending an Emacs running under W32 makes no sense"))
 419
 420
 421 (defun mouse-set-font (&rest fonts)
 422   "Select an Emacs font from a list of known good fonts and fontsets.
 423
 424 If `w32-use-w32-font-dialog' is non-nil (the default), use the Windows
 425 font dialog to display the list of possible fonts.  Otherwise use a
 426 pop-up menu (like Emacs does on other platforms) initialized with
 427 the fonts in `w32-fixed-font-alist'.
 428 If `w32-list-proportional-fonts' is non-nil, add proportional fonts
 429 to the list in the font selection dialog (the fonts listed by the
 430 pop-up menu are unaffected by `w32-list-proportional-fonts')."
 431   (interactive
 432    (if w32-use-w32-font-dialog
 433        (let ((chosen-font (w32-select-font (selected-frame)
 434                                            w32-list-proportional-fonts)))
 435          (and chosen-font (list chosen-font)))
 436      (x-popup-menu
 437       last-nonmenu-event
 438       ;; Append list of fontsets currently defined.
 439       ;; Conditional on new-fontset so bootstrapping works on non-GUI compiles
 440       (if (fboundp 'new-fontset)
 441           (append w32-fixed-font-alist (list (generate-fontset-menu)))))))
 442   (if fonts
 443       (let (font)
 444         (while fonts
 445           (condition-case nil
 446               (progn
 447                 (setq font (car fonts))
 448                 (set-default-font font)
 449                 (setq fonts nil))
 450             (error (setq fonts (cdr fonts)))))
 451         (if (null font)
 452             (error "Font not found")))))
 453
 454 ;;; Set default known names for image libraries
 455 (setq image-library-alist
 456       '((xpm "libxpm.dll" "xpm4.dll" "libXpm-nox4.dll")
 457         (png "libpng12d.dll" "libpng12.dll" "libpng.dll"
 458          ;; these are libpng 1.2.8 from GTK+
 459          "libpng13d.dll" "libpng13.dll")
 460         (jpeg "jpeg62.dll" "libjpeg.dll" "jpeg-62.dll" "jpeg.dll")
 461         (tiff "libtiff3.dll" "libtiff.dll")
 462         (gif "giflib4.dll" "libungif4.dll" "libungif.dll")
 463         (svg "librsvg-2-2.dll")
 464         (gdk-pixbuf "libgdk_pixbuf-2.0-0.dll")
 465         (glib "libglib-2.0-0.dll")))
 466
 467 ;;; multi-tty support
 468 (defvar w32-initialized nil
 469   "Non-nil if the w32 window system has been initialized.")
 470
 471 (defun w32-initialize-window-system ()
 472   "Initialize Emacs for W32 GUI frames."
 473
 474   ;; Do the actual Windows setup here; the above code just defines
 475   ;; functions and variables that we use now.
 476
 477   (setq command-line-args (x-handle-args command-line-args))
 478
 479   ;; Make sure we have a valid resource name.
 480   (or (stringp x-resource-name)
 481       (setq x-resource-name
 482             ;; Change any . or * characters in x-resource-name to hyphens,
 483             ;; so as not to choke when we use it in X resource queries.
 484             (replace-regexp-in-string "[.*]" "-" (invocation-name))))
 485
 486   (x-open-connection "" x-command-line-resources
 487                      ;; Exit with a fatal error if this fails and we
 488                      ;; are the initial display
 489                      (eq initial-window-system 'w32))
 490
 491   ;; Setup the default fontset.
 492   (setup-default-fontset)
 493
 494   ;; Enable Japanese fonts on Windows to be used by default.
 495   (set-fontset-font t (make-char 'katakana-jisx0201)
 496                     '("*" . "JISX0208-SJIS"))
 497   (set-fontset-font t (make-char 'latin-jisx0201)
 498                     '("*" . "JISX0208-SJIS"))
 499   (set-fontset-font t (make-char 'japanese-jisx0208)
 500                     '("*" . "JISX0208-SJIS"))
 501   (set-fontset-font t (make-char 'japanese-jisx0208-1978)
 502                     '("*" . "JISX0208-SJIS"))
 503
 504   ;; Create the standard fontset.
 505   (create-fontset-from-fontset-spec w32-standard-fontset-spec t)
 506   ;; Create fontset specified in X resources "Fontset-N" (N is 0, 1,...).
 507   (create-fontset-from-x-resource)
 508
 509   ;; Apply a geometry resource to the initial frame.  Put it at the end
 510   ;; of the alist, so that anything specified on the command line takes
 511   ;; precedence.
 512   (let* ((res-geometry (x-get-resource "geometry" "Geometry"))
 513          parsed)
 514     (if res-geometry
 515         (progn
 516           (setq parsed (x-parse-geometry res-geometry))
 517           ;; If the resource specifies a position,
 518           ;; call the position and size "user-specified".
 519           (if (or (assq 'top parsed) (assq 'left parsed))
 520               (setq parsed (cons '(user-position . t)
 521                                  (cons '(user-size . t) parsed))))
 522           ;; All geometry parms apply to the initial frame.
 523           (setq initial-frame-alist (append initial-frame-alist parsed))
 524           ;; The size parms apply to all frames.
 525           (if (assq 'height parsed)
 526               (push (cons 'height (cdr (assq 'height parsed)))
 527                     default-frame-alist))
 528           (if (assq 'width parsed)
 529               (push (cons 'width (cdr (assq 'width parsed)))
 530                     default-frame-alist)))))
 531
 532   ;; Check the reverseVideo resource.
 533   (let ((case-fold-search t))
 534     (let ((rv (x-get-resource "reverseVideo" "ReverseVideo")))
 535       (if (and rv (string-match "^\\(true\\|yes\\|on\\)$" rv))
 536           (push '(reverse . t) default-frame-alist))))
 537
 538   ;; Don't let Emacs suspend under w32 gui
 539   (add-hook 'suspend-hook 'x-win-suspend-error)
 540
 541   ;; Turn off window-splitting optimization; w32 is usually fast enough
 542   ;; that this is only annoying.
 543   (setq split-window-keep-point t)
 544
 545   ;; Turn on support for mouse wheels
 546   (mouse-wheel-mode 1)
 547
 548   ;; W32 expects the menu bar cut and paste commands to use the clipboard.
 549   (menu-bar-enable-clipboard)
 550
 551   ;; Don't show the frame name; that's redundant.
 552   (setq-default mode-line-frame-identification "  ")
 553
 554   ;; Set to a system sound if you want a fancy bell.
 555   (set-message-beep 'ok)
 556   (setq w32-initialized t))
 557
 558 (add-to-list 'handle-args-function-alist '(w32 . x-handle-args))
 559 (add-to-list 'frame-creation-function-alist '(w32 . x-create-frame-with-faces))
 560 (add-to-list 'window-system-initialization-alist '(w32 . w32-initialize-window-system))
 561
 562 (provide 'w32-win)
 563
 564 ;; arch-tag: 69fb1701-28c2-4890-b351-3d1fe4b4f166
 565 ;;; w32-win.el ends here