lisp/vc-bzr.el

   1 ;;; vc-bzr.el --- VC backend for the bzr revision control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;;         Riccardo Murri <riccardo.murri@gmail.com>
   7 ;; Keywords: tools
   8 ;; Created: Sept 2006
   9 ;; Version: 2008-01-04 (Bzr revno 25)
  10 ;; URL: http://launchpad.net/vc-bzr
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; See <URL:http://bazaar-vcs.org/> concerning bzr.  See
  30 ;; <URL:http://launchpad.net/vc-bzr> for alternate development
  31 ;; branches of `vc-bzr'.
  32
  33 ;; Load this library to register bzr support in VC.
  34
  35 ;; Known bugs
  36 ;; ==========
  37
  38 ;; When edititing a symlink and *both* the symlink and its target
  39 ;; are bzr-versioned, `vc-bzr` presently runs `bzr status` on the
  40 ;; symlink, thereby not detecting whether the actual contents
  41 ;; (that is, the target contents) are changed.
  42 ;; See https://bugs.launchpad.net/vc-bzr/+bug/116607
  43
  44 ;; For an up-to-date list of bugs, please see:
  45 ;;   https://bugs.launchpad.net/vc-bzr/+bugs
  46
  47 ;;; Properties of the backend
  48
  49 (defun vc-bzr-revision-granularity () 'repository)
  50 (defun vc-bzr-checkout-model (files) 'implicit)
  51
  52 ;;; Code:
  53
  54 (eval-when-compile
  55   (require 'cl)
  56   (require 'vc)  ;; for vc-exec-after
  57   (require 'vc-dir))
  58
  59 ;; Clear up the cache to force vc-call to check again and discover
  60 ;; new functions when we reload this file.
  61 (put 'Bzr 'vc-functions nil)
  62
  63 (defgroup vc-bzr nil
  64   "VC bzr backend."
  65   :version "22.2"
  66   :group 'vc)
  67
  68 (defcustom vc-bzr-program "bzr"
  69   "Name of the bzr command (excluding any arguments)."
  70   :group 'vc-bzr
  71   :type 'string)
  72
  73 (defcustom vc-bzr-diff-switches nil
  74   "String or list of strings specifying switches for bzr diff under VC.
  75 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  76   :type '(choice (const :tag "Unspecified" nil)
  77                  (const :tag "None" t)
  78                  (string :tag "Argument String")
  79                  (repeat :tag "Argument List" :value ("") string))
  80   :group 'vc-bzr)
  81
  82 (defcustom vc-bzr-log-switches nil
  83   "String or list of strings specifying switches for bzr log under VC."
  84   :type '(choice (const :tag "None" nil)
  85                  (string :tag "Argument String")
  86                  (repeat :tag "Argument List" :value ("") string))
  87   :group 'vc-bzr)
  88
  89 ;; since v0.9, bzr supports removing the progress indicators
  90 ;; by setting environment variable BZR_PROGRESS_BAR to "none".
  91 (defun vc-bzr-command (bzr-command buffer okstatus file-or-list &rest args)
  92   "Wrapper round `vc-do-command' using `vc-bzr-program' as COMMAND.
  93 Invoke the bzr command adding `BZR_PROGRESS_BAR=none' and
  94 `LC_MESSAGES=C' to the environment."
  95   (let ((process-environment
  96          (list* "BZR_PROGRESS_BAR=none" ; Suppress progress output (bzr >=0.9)
  97                 "LC_MESSAGES=C"         ; Force English output
  98                 process-environment)))
  99     (apply 'vc-do-command (or buffer "*vc*") okstatus vc-bzr-program
 100            file-or-list bzr-command args)))
 101
 102
 103 ;;;###autoload
 104 (defconst vc-bzr-admin-dirname ".bzr"
 105   "Name of the directory containing Bzr repository status files.")
 106 ;;;###autoload
 107 (defconst vc-bzr-admin-checkout-format-file
 108   (concat vc-bzr-admin-dirname "/checkout/format"))
 109 (defconst vc-bzr-admin-dirstate
 110   (concat vc-bzr-admin-dirname "/checkout/dirstate"))
 111 (defconst vc-bzr-admin-branch-format-file
 112   (concat vc-bzr-admin-dirname "/branch/format"))
 113 (defconst vc-bzr-admin-revhistory
 114   (concat vc-bzr-admin-dirname "/branch/revision-history"))
 115 (defconst vc-bzr-admin-lastrev
 116   (concat vc-bzr-admin-dirname "/branch/last-revision"))
 117
 118 ;;;###autoload (defun vc-bzr-registered (file)
 119 ;;;###autoload   (if (vc-find-root file vc-bzr-admin-checkout-format-file)
 120 ;;;###autoload       (progn
 121 ;;;###autoload         (load "vc-bzr")
 122 ;;;###autoload         (vc-bzr-registered file))))
 123
 124 (defun vc-bzr-root (file)
 125   "Return the root directory of the bzr repository containing FILE."
 126   ;; Cache technique copied from vc-arch.el.
 127   (or (vc-file-getprop file 'bzr-root)
 128       (let ((root (vc-find-root file vc-bzr-admin-checkout-format-file)))
 129         (when root (vc-file-setprop file 'bzr-root root)))))
 130
 131 (require 'sha1)                         ;For sha1-program
 132
 133 (defun vc-bzr-sha1 (file)
 134   (with-temp-buffer
 135     (set-buffer-multibyte nil)
 136     (let ((prog sha1-program)
 137           (args nil)
 138           process-file-side-effects)
 139       (when (consp prog)
 140         (setq args (cdr prog))
 141         (setq prog (car prog)))
 142       (apply 'process-file prog (file-relative-name file) t nil args)
 143       (buffer-substring (point-min) (+ (point-min) 40)))))
 144
 145 (defun vc-bzr-state-heuristic (file)
 146   "Like `vc-bzr-state' but hopefully without running Bzr."
 147   ;; `bzr status' was excrutiatingly slow with large histories and
 148   ;; pending merges, so try to avoid using it until they fix their
 149   ;; performance problems.
 150   ;; This function tries first to parse Bzr internal file
 151   ;; `checkout/dirstate', but it may fail if Bzr internal file format
 152   ;; has changed.  As a safeguard, the `checkout/dirstate' file is
 153   ;; only parsed if it contains the string `#bazaar dirstate flat
 154   ;; format 3' in the first line.
 155   ;; If the `checkout/dirstate' file cannot be parsed, fall back to
 156   ;; running `vc-bzr-state'."
 157   (lexical-let ((root (vc-bzr-root file)))
 158     (when root    ; Short cut.
 159       ;; This looks at internal files.  May break if they change
 160       ;; their format.
 161       (lexical-let ((dirstate (expand-file-name vc-bzr-admin-dirstate root)))
 162         (condition-case nil
 163             (with-temp-buffer
 164               (insert-file-contents dirstate)
 165               (goto-char (point-min))
 166               (if (not (looking-at "#bazaar dirstate flat format 3"))
 167                   (vc-bzr-state file)   ; Some other unknown format?
 168                 (let* ((relfile (file-relative-name file root))
 169                        (reldir (file-name-directory relfile)))
 170                   (if (re-search-forward
 171                        (concat "^\0"
 172                                (if reldir (regexp-quote
 173                                            (directory-file-name reldir)))
 174                                "\0"
 175                                (regexp-quote (file-name-nondirectory relfile))
 176                                "\0"
 177                                "[^\0]*\0"     ;id?
 178                                "\\([^\0]*\\)\0" ;"a/f/d", a=removed?
 179                                "\\([^\0]*\\)\0" ;sha1 (empty if conflicted)?
 180                                "\\([^\0]*\\)\0" ;size?p
 181                                "[^\0]*\0"       ;"y/n", executable?
 182                                "[^\0]*\0"       ;?
 183                                "\\([^\0]*\\)\0" ;"a/f/d" a=added?
 184                                "\\([^\0]*\\)\0" ;sha1 again?
 185                                "\\([^\0]*\\)\0" ;size again?
 186                                "[^\0]*\0" ;"y/n", executable again?
 187                                "[^\0]*\0" ;last revid?
 188                                ;; There are more fields when merges are pending.
 189                                )
 190                        nil t)
 191                       ;; Apparently the second sha1 is the one we want: when
 192                       ;; there's a conflict, the first sha1 is absent (and the
 193                       ;; first size seems to correspond to the file with
 194                       ;; conflict markers).
 195                       (cond
 196                        ((eq (char-after (match-beginning 1)) ?a) 'removed)
 197                        ((eq (char-after (match-beginning 4)) ?a) 'added)
 198                        ((or (and (eq (string-to-number (match-string 3))
 199                                  (nth 7 (file-attributes file)))
 200                              (equal (match-string 5)
 201                                     (vc-bzr-sha1 file)))
 202                             (and
 203                              ;; It looks like for lightweight
 204                              ;; checkouts \2 is empty and we need to
 205                              ;; look for size in \6.
 206                              (eq (match-beginning 2) (match-end 2))
 207                              (eq (string-to-number (match-string 6))
 208                                  (nth 7 (file-attributes file)))
 209                              (equal (match-string 5)
 210                                     (vc-bzr-sha1 file))))
 211                         'up-to-date)
 212                        (t 'edited))
 213                     'unregistered))))
 214           ;; Either the dirstate file can't be read, or the sha1
 215           ;; executable is missing, or ...
 216           ;; In either case, recent versions of Bzr aren't that slow
 217           ;; any more.
 218           (error (vc-bzr-state file)))))))
 219
 220
 221 (defun vc-bzr-registered (file)
 222   "Return non-nil if FILE is registered with bzr."
 223   (let ((state (vc-bzr-state-heuristic file)))
 224     (not (memq state '(nil unregistered ignored)))))
 225
 226 (defconst vc-bzr-state-words
 227   "added\\|ignored\\|kind changed\\|modified\\|removed\\|renamed\\|unknown"
 228   "Regexp matching file status words as reported in `bzr' output.")
 229
 230 (defun vc-bzr-file-name-relative (filename)
 231   "Return file name FILENAME stripped of the initial Bzr repository path."
 232   (lexical-let*
 233       ((filename* (expand-file-name filename))
 234        (rootdir (vc-bzr-root filename*)))
 235     (when rootdir
 236          (file-relative-name filename* rootdir))))
 237
 238 (defun vc-bzr-status (file)
 239   "Return FILE status according to Bzr.
 240 Return value is a cons (STATUS . WARNING), where WARNING is a
 241 string or nil, and STATUS is one of the symbols: `added',
 242 `ignored', `kindchanged', `modified', `removed', `renamed', `unknown',
 243 which directly correspond to `bzr status' output, or 'unchanged
 244 for files whose copy in the working tree is identical to the one
 245 in the branch repository, or nil for files that are not
 246 registered with Bzr.
 247
 248 If any error occurred in running `bzr status', then return nil."
 249   (with-temp-buffer
 250     (let ((ret (condition-case nil
 251                    (vc-bzr-command "status" t 0 file)
 252                  (file-error nil)))     ; vc-bzr-program not found.
 253           (status 'unchanged))
 254           ;; the only secure status indication in `bzr status' output
 255           ;; is a couple of lines following the pattern::
 256           ;;   | <status>:
 257           ;;   |   <file name>
 258           ;; if the file is up-to-date, we get no status report from `bzr',
 259           ;; so if the regexp search for the above pattern fails, we consider
 260           ;; the file to be up-to-date.
 261           (goto-char (point-min))
 262           (when (re-search-forward
 263                  ;; bzr prints paths relative to the repository root.
 264                  (concat "^\\(" vc-bzr-state-words "\\):[ \t\n]+"
 265                          (regexp-quote (vc-bzr-file-name-relative file))
 266                          ;; Bzr appends a '/' to directory names and
 267                          ;; '*' to executable files
 268                          (if (file-directory-p file) "/?" "\\*?")
 269                          "[ \t\n]*$")
 270                  nil t)
 271             (lexical-let ((statusword (match-string 1)))
 272               ;; Erase the status text that matched.
 273               (delete-region (match-beginning 0) (match-end 0))
 274               (setq status
 275                     (intern (replace-regexp-in-string " " "" statusword)))))
 276           (when status
 277             (goto-char (point-min))
 278             (skip-chars-forward " \n\t") ;Throw away spaces.
 279             (cons status
 280                   ;; "bzr" will output warnings and informational messages to
 281                   ;; stderr; due to Emacs' `vc-do-command' (and, it seems,
 282                   ;; `start-process' itself) limitations, we cannot catch stderr
 283                   ;; and stdout into different buffers.  So, if there's anything
 284                   ;; left in the buffer after removing the above status
 285                   ;; keywords, let us just presume that any other message from
 286                   ;; "bzr" is a user warning, and display it.
 287                   (unless (eobp) (buffer-substring (point) (point-max))))))))
 288
 289 (defun vc-bzr-state (file)
 290   (lexical-let ((result (vc-bzr-status file)))
 291     (when (consp result)
 292       (when (cdr result)
 293         (message "Warnings in `bzr' output: %s" (cdr result)))
 294       (cdr (assq (car result)
 295                  '((added . added)
 296                    (kindchanged . edited)
 297                    (renamed . edited)
 298                    (modified . edited)
 299                    (removed . removed)
 300                    (ignored . ignored)
 301                    (unknown . unregistered)
 302                    (unchanged . up-to-date)))))))
 303
 304 (defun vc-bzr-resolve-when-done ()
 305   "Call \"bzr resolve\" if the conflict markers have been removed."
 306   (save-excursion
 307     (goto-char (point-min))
 308     (unless (re-search-forward "^<<<<<<< " nil t)
 309       (vc-bzr-command "resolve" nil 0 buffer-file-name)
 310       ;; Remove the hook so that it is not called multiple times.
 311       (remove-hook 'after-save-hook 'vc-bzr-resolve-when-done t))))
 312
 313 (defun vc-bzr-find-file-hook ()
 314   (when (and buffer-file-name
 315              ;; FIXME: We should check that "bzr status" says "conflict".
 316              (file-exists-p (concat buffer-file-name ".BASE"))
 317              (file-exists-p (concat buffer-file-name ".OTHER"))
 318              (file-exists-p (concat buffer-file-name ".THIS"))
 319              ;; If "bzr status" says there's a conflict but there are no
 320              ;; conflict markers, it's not clear what we should do.
 321              (save-excursion
 322                (goto-char (point-min))
 323                (re-search-forward "^<<<<<<< " nil t)))
 324     ;; TODO: the merge algorithm used in `bzr merge' is nicely configurable,
 325     ;; but the one in `bzr pull' isn't, so it would be good to provide an
 326     ;; elisp function to remerge from the .BASE/OTHER/THIS files.
 327     (smerge-start-session)
 328     (add-hook 'after-save-hook 'vc-bzr-resolve-when-done nil t)
 329     (message "There are unresolved conflicts in this file")))
 330
 331 (defun vc-bzr-workfile-unchanged-p (file)
 332   (eq 'unchanged (car (vc-bzr-status file))))
 333
 334 (defun vc-bzr-working-revision (file)
 335   ;; Together with the code in vc-state-heuristic, this makes it possible
 336   ;; to get the initial VC state of a Bzr file even if Bzr is not installed.
 337   (lexical-let*
 338       ((rootdir (vc-bzr-root file))
 339        (branch-format-file (expand-file-name vc-bzr-admin-branch-format-file
 340                                              rootdir))
 341        (revhistory-file (expand-file-name vc-bzr-admin-revhistory rootdir))
 342        (lastrev-file (expand-file-name vc-bzr-admin-lastrev rootdir)))
 343     ;; This looks at internal files to avoid forking a bzr process.
 344     ;; May break if they change their format.
 345     (if (and (file-exists-p branch-format-file)
 346              ;; For lightweight checkouts (obtained with bzr checkout --lightweight)
 347              ;; the branch-format-file does not contain the revision
 348              ;; information, we need to look up the branch-format-file
 349              ;; in the place where the lightweight checkout comes
 350              ;; from.  We only do that if it's a local file.
 351              (let ((location-fname (expand-file-name
 352                                     (concat vc-bzr-admin-dirname
 353                                             "/branch/location") rootdir)))
 354                ;; The existence of this file is how we distinguish
 355                ;; lightweight checkouts.
 356                (if (file-exists-p location-fname)
 357                    (with-temp-buffer
 358                      (insert-file-contents location-fname)
 359                      ;; If the lightweight checkout points to a
 360                      ;; location in the local file system, then we can
 361                      ;; look there for the version information.
 362                      (when (re-search-forward "file://\\(.+\\)" nil t)
 363                        (let ((l-c-parent-dir (match-string 1)))
 364                          (when (and (memq system-type '(ms-dos windows-nt))
 365                                     (string-match-p "^/[[:alpha:]]:" l-c-parent-dir))
 366                            ;;; On Windows, file:// URLs often have three slashes,
 367                            ;;; so we must remove the remaining one (bug#5345)
 368                            (setq l-c-parent-dir (substring l-c-parent-dir 1)))
 369                          (setq branch-format-file
 370                                (expand-file-name vc-bzr-admin-branch-format-file
 371                                                  l-c-parent-dir))
 372                          (setq lastrev-file
 373                                (expand-file-name vc-bzr-admin-lastrev l-c-parent-dir))
 374                          ;; FIXME: maybe it's overkill to check if both these files exist.
 375                          (and (file-exists-p branch-format-file)
 376                               (file-exists-p lastrev-file)))))
 377                  t)))
 378         (with-temp-buffer
 379           (insert-file-contents branch-format-file)
 380           (goto-char (point-min))
 381           (cond
 382            ((or
 383              (looking-at "Bazaar-NG branch, format 0.0.4")
 384              (looking-at "Bazaar-NG branch format 5"))
 385             ;; count lines in .bzr/branch/revision-history
 386             (insert-file-contents revhistory-file)
 387             (number-to-string (count-lines (line-end-position) (point-max))))
 388            ((or
 389              (looking-at "Bazaar Branch Format 6 (bzr 0.15)")
 390              (looking-at "Bazaar Branch Format 7 (needs bzr 1.6)"))
 391             ;; revno is the first number in .bzr/branch/last-revision
 392             (insert-file-contents lastrev-file)
 393             (when (re-search-forward "[0-9]+" nil t)
 394               (buffer-substring (match-beginning 0) (match-end 0))))))
 395       ;; fallback to calling "bzr revno"
 396       (lexical-let*
 397           ((result (vc-bzr-command-discarding-stderr
 398                     vc-bzr-program "revno" (file-relative-name file)))
 399            (exitcode (car result))
 400            (output (cdr result)))
 401         (cond
 402          ((eq exitcode 0) (substring output 0 -1))
 403          (t nil))))))
 404
 405 (defun vc-bzr-create-repo ()
 406   "Create a new Bzr repository."
 407   (vc-bzr-command "init" nil 0 nil))
 408
 409 (defun vc-bzr-init-revision (&optional file)
 410   "Always return nil, as Bzr cannot register explicit versions."
 411   nil)
 412
 413 (defun vc-bzr-previous-revision (file rev)
 414   (if (string-match "\\`[0-9]+\\'" rev)
 415       (number-to-string (1- (string-to-number rev)))
 416     (concat "before:" rev)))
 417
 418 (defun vc-bzr-next-revision (file rev)
 419   (if (string-match "\\`[0-9]+\\'" rev)
 420       (number-to-string (1+ (string-to-number rev)))
 421     (error "Don't know how to compute the next revision of %s" rev)))
 422
 423 (defun vc-bzr-register (files &optional rev comment)
 424   "Register FILE under bzr.
 425 Signal an error unless REV is nil.
 426 COMMENT is ignored."
 427   (if rev (error "Can't register explicit revision with bzr"))
 428   (vc-bzr-command "add" nil 0 files))
 429
 430 ;; Could run `bzr status' in the directory and see if it succeeds, but
 431 ;; that's relatively expensive.
 432 (defalias 'vc-bzr-responsible-p 'vc-bzr-root
 433   "Return non-nil if FILE is (potentially) controlled by bzr.
 434 The criterion is that there is a `.bzr' directory in the same
 435 or a superior directory.")
 436
 437 (defun vc-bzr-could-register (file)
 438   "Return non-nil if FILE could be registered under bzr."
 439   (and (vc-bzr-responsible-p file)      ; shortcut
 440        (condition-case ()
 441            (with-temp-buffer
 442              (vc-bzr-command "add" t 0 file "--dry-run")
 443              ;; The command succeeds with no output if file is
 444              ;; registered (in bzr 0.8).
 445              (goto-char (point-min))
 446              (looking-at "added "))
 447          (error))))
 448
 449 (defun vc-bzr-unregister (file)
 450   "Unregister FILE from bzr."
 451   (vc-bzr-command "remove" nil 0 file "--keep"))
 452
 453 (defun vc-bzr-checkin (files rev comment)
 454   "Check FILE in to bzr with log message COMMENT.
 455 REV non-nil gets an error."
 456   (if rev (error "Can't check in a specific revision with bzr"))
 457   (vc-bzr-command "commit" nil 0 files "-m" comment))
 458
 459 (defun vc-bzr-find-revision (file rev buffer)
 460   "Fetch revision REV of file FILE and put it into BUFFER."
 461     (with-current-buffer buffer
 462       (if (and rev (stringp rev) (not (string= rev "")))
 463           (vc-bzr-command "cat" t 0 file "-r" rev)
 464         (vc-bzr-command "cat" t 0 file))))
 465
 466 (defun vc-bzr-checkout (file &optional editable rev)
 467   (if rev (error "Operation not supported")
 468     ;; Else, there's nothing to do.
 469     nil))
 470
 471 (defun vc-bzr-revert (file &optional contents-done)
 472   (unless contents-done
 473     (with-temp-buffer (vc-bzr-command "revert" t 0 file))))
 474
 475 (defvar log-view-message-re)
 476 (defvar log-view-file-re)
 477 (defvar log-view-font-lock-keywords)
 478 (defvar log-view-current-tag-function)
 479 (defvar log-view-per-file-logs)
 480 (defvar vc-short-log)
 481
 482 (define-derived-mode vc-bzr-log-view-mode log-view-mode "Bzr-Log-View"
 483   (remove-hook 'log-view-mode-hook 'vc-bzr-log-view-mode) ;Deactivate the hack.
 484   (require 'add-log)
 485   (set (make-local-variable 'log-view-per-file-logs) nil)
 486   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 487   (set (make-local-variable 'log-view-message-re)
 488        (if vc-short-log
 489            "^ *\\([0-9.]+\\) \\(.*?\\)[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)\\( \\[merge\\]\\)?"
 490          "^ *\\(?:revno: \\([0-9.]+\\)\\|merged: .+\\)"))
 491   (set (make-local-variable 'log-view-font-lock-keywords)
 492        ;; log-view-font-lock-keywords is careful to use the buffer-local
 493        ;; value of log-view-message-re only since Emacs-23.
 494        (if vc-short-log
 495          (append `((,log-view-message-re
 496                     (1 'log-view-message-face)
 497                     (2 'change-log-name)
 498                     (3 'change-log-date)
 499                     (4 'change-log-list nil lax))))
 500          (append `((,log-view-message-re . 'log-view-message-face))
 501                  ;; log-view-font-lock-keywords
 502                  '(("^ *\\(?:committer\\|author\\): \
 503 \\([^<(]+?\\)[  ]*[(<]\\([[:alnum:]_.+-]+@[[:alnum:]_.-]+\\)[>)]"
 504                     (1 'change-log-name)
 505                     (2 'change-log-email))
 506                    ("^ *timestamp: \\(.*\\)" (1 'change-log-date-face)))))))
 507
 508 (defun vc-bzr-print-log (files buffer &optional shortlog start-revision limit)
 509   "Get bzr change log for FILES into specified BUFFER."
 510   ;; `vc-do-command' creates the buffer, but we need it before running
 511   ;; the command.
 512   (vc-setup-buffer buffer)
 513   ;; If the buffer exists from a previous invocation it might be
 514   ;; read-only.
 515   ;; FIXME: `vc-bzr-command' runs `bzr log' with `LC_MESSAGES=C', so
 516   ;; the log display may not what the user wants - but I see no other
 517   ;; way of getting the above regexps working.
 518   (with-current-buffer buffer
 519     (apply 'vc-bzr-command "log" buffer 'async files
 520            (append
 521             (when shortlog '("--short"))
 522             (when start-revision (list (format "-r..%s" start-revision)))
 523             (when limit (list "-l" (format "%s" limit)))
 524             (if (stringp vc-bzr-log-switches)
 525                 (list vc-bzr-log-switches)
 526               vc-bzr-log-switches)))))
 527
 528 (defun vc-bzr-show-log-entry (revision)
 529   "Find entry for patch name REVISION in bzr change log buffer."
 530   (goto-char (point-min))
 531   (when revision
 532     (let (case-fold-search
 533           found)
 534       (if (re-search-forward
 535            ;; "revno:" can appear either at the beginning of a line,
 536            ;; or indented.
 537            (concat "^[ ]*-+\n[ ]*revno: "
 538                    ;; The revision can contain ".", quote it so that it
 539                    ;; does not interfere with regexp matching.
 540                    (regexp-quote revision) "$") nil t)
 541           (progn
 542             (beginning-of-line 0)
 543             (setq found t))
 544         (goto-char (point-min)))
 545       found)))
 546
 547 (defun vc-bzr-diff (files &optional rev1 rev2 buffer)
 548   "VC bzr backend for diff."
 549   ;; `bzr diff' exits with code 1 if diff is non-empty.
 550   (apply #'vc-bzr-command "diff" (or buffer "*vc-diff*")
 551          (if vc-disable-async-diff 1 'async) files
 552          "--diff-options" (mapconcat 'identity
 553                                      (vc-switches 'bzr 'diff)
 554                                      " ")
 555          ;; This `when' is just an optimization because bzr-1.2 is *much*
 556          ;; faster when the revision argument is not given.
 557          (when (or rev1 rev2)
 558            (list "-r" (format "%s..%s"
 559                               (or rev1 "revno:-1")
 560                               (or rev2 ""))))))
 561
 562
 563 ;; FIXME: vc-{next,previous}-revision need fixing in vc.el to deal with
 564 ;; straight integer revisions.
 565
 566 (defun vc-bzr-delete-file (file)
 567   "Delete FILE and delete it in the bzr repository."
 568   (condition-case ()
 569       (delete-file file)
 570     (file-error nil))
 571   (vc-bzr-command "remove" nil 0 file))
 572
 573 (defun vc-bzr-rename-file (old new)
 574   "Rename file from OLD to NEW using `bzr mv'."
 575   (vc-bzr-command "mv" nil 0 new old))
 576
 577 (defvar vc-bzr-annotation-table nil
 578   "Internal use.")
 579 (make-variable-buffer-local 'vc-bzr-annotation-table)
 580
 581 (defun vc-bzr-annotate-command (file buffer &optional revision)
 582   "Prepare BUFFER for `vc-annotate' on FILE.
 583 Each line is tagged with the revision number, which has a `help-echo'
 584 property containing author and date information."
 585   (apply #'vc-bzr-command "annotate" buffer 'async file "--long" "--all"
 586          (if revision (list "-r" revision)))
 587   (lexical-let ((table (make-hash-table :test 'equal)))
 588     (set-process-filter
 589      (get-buffer-process buffer)
 590      (lambda (proc string)
 591        (when (process-buffer proc)
 592          (with-current-buffer (process-buffer proc)
 593            (setq string (concat (process-get proc :vc-left-over) string))
 594            (while (string-match "^\\( *[0-9.]+ *\\) \\([^\n ]+\\) +\\([0-9]\\{8\\}\\)\\( |.*\n\\)" string)
 595              (let* ((rev (match-string 1 string))
 596                     (author (match-string 2 string))
 597                     (date (match-string 3 string))
 598                     (key (substring string (match-beginning 0)
 599                                     (match-beginning 4)))
 600                     (line (match-string 4 string))
 601                     (tag (gethash key table))
 602                     (inhibit-read-only t))
 603                (setq string (substring string (match-end 0)))
 604                (unless tag
 605                  (setq tag
 606                        (propertize
 607                         (format "%s %-7.7s" rev author)
 608                         'help-echo (format "Revision: %d, author: %s, date: %s"
 609                                            (string-to-number rev)
 610                                            author date)
 611                         'mouse-face 'highlight))
 612                  (puthash key tag table))
 613                (goto-char (process-mark proc))
 614                (insert tag line)
 615                (move-marker (process-mark proc) (point))))
 616            (process-put proc :vc-left-over string)))))))
 617
 618 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 619
 620 (defun vc-bzr-annotate-time ()
 621   (when (re-search-forward "^ *[0-9.]+ +[^\n ]* +|" nil t)
 622     (let ((prop (get-text-property (line-beginning-position) 'help-echo)))
 623       (string-match "[0-9]+\\'" prop)
 624       (let ((str (match-string-no-properties 0 prop)))
 625       (vc-annotate-convert-time
 626        (encode-time 0 0 0
 627                       (string-to-number (substring str 6 8))
 628                       (string-to-number (substring str 4 6))
 629                       (string-to-number (substring str 0 4))))))))
 630
 631 (defun vc-bzr-annotate-extract-revision-at-line ()
 632   "Return revision for current line of annoation buffer, or nil.
 633 Return nil if current line isn't annotated."
 634   (save-excursion
 635     (beginning-of-line)
 636     (if (looking-at "^ *\\([0-9.]+\\) +[^\n ]* +|")
 637         (match-string-no-properties 1))))
 638
 639 (defun vc-bzr-command-discarding-stderr (command &rest args)
 640   "Execute shell command COMMAND (with ARGS); return its output and exitcode.
 641 Return value is a cons (EXITCODE . OUTPUT), where EXITCODE is
 642 the (numerical) exit code of the process, and OUTPUT is a string
 643 containing whatever the process sent to its standard output
 644 stream.  Standard error output is discarded."
 645   (with-temp-buffer
 646     (cons
 647      (apply #'process-file command nil (list (current-buffer) nil) nil args)
 648      (buffer-substring (point-min) (point-max)))))
 649
 650 (defstruct (vc-bzr-extra-fileinfo
 651             (:copier nil)
 652             (:constructor vc-bzr-create-extra-fileinfo (extra-name))
 653             (:conc-name vc-bzr-extra-fileinfo->))
 654   extra-name)         ;; original name for rename targets, new name for
 655
 656 (defun vc-bzr-dir-printer (info)
 657   "Pretty-printer for the vc-dir-fileinfo structure."
 658   (let ((extra (vc-dir-fileinfo->extra info)))
 659     (vc-default-dir-printer 'Bzr info)
 660     (when extra
 661       (insert (propertize
 662                (format "   (renamed from %s)"
 663                        (vc-bzr-extra-fileinfo->extra-name extra))
 664                'face 'font-lock-comment-face)))))
 665
 666 ;; FIXME: this needs testing, it's probably incomplete.
 667 (defun vc-bzr-after-dir-status (update-function relative-dir)
 668   (let ((status-str nil)
 669         (translation '(("+N " . added)
 670                        ("-D " . removed)
 671                        (" M " . edited) ;; file text modified
 672                        ("  *" . edited) ;; execute bit changed
 673                        (" M*" . edited) ;; text modified + execute bit changed
 674                        ;; FIXME: what about ignored files?
 675                        (" D " . missing)
 676                        ;; For conflicts, should we list the .THIS/.BASE/.OTHER?
 677                        ("C  " . conflict)
 678                        ("?  " . unregistered)
 679                        ;; No such state, but we need to distinguish this case.
 680                        ("R  " . renamed)
 681                        ;; For a non existent file FOO, the output is:
 682                        ;; bzr: ERROR: Path(s) do not exist: FOO
 683                        ("bzr" . not-found)
 684                        ;; If the tree is not up to date, bzr will print this warning:
 685                        ;; working tree is out of date, run 'bzr update'
 686                        ;; ignore it.
 687                        ;; FIXME: maybe this warning can be put in the vc-dir header...
 688                        ("wor" . not-found)
 689                        ;; Ignore "P " and "P." for pending patches.
 690                        ("P  " . not-found)
 691                        ("P. " . not-found)
 692                        ))
 693         (translated nil)
 694         (result nil))
 695       (goto-char (point-min))
 696       (while (not (eobp))
 697         (setq status-str
 698               (buffer-substring-no-properties (point) (+ (point) 3)))
 699         (setq translated (cdr (assoc status-str translation)))
 700         (cond
 701          ((eq translated 'conflict)
 702           ;; For conflicts the file appears twice in the listing: once
 703           ;; with the M flag and once with the C flag, so take care
 704           ;; not to add it twice to `result'.  Ugly.
 705           (let* ((file
 706                   (buffer-substring-no-properties
 707                    ;;For files with conflicts the format is:
 708                    ;;C   Text conflict in FILENAME
 709                    ;; Bah.
 710                    (+ (point) 21) (line-end-position)))
 711                  (entry (assoc file result)))
 712             (when entry
 713               (setf (nth 1 entry) 'conflict))))
 714          ((eq translated 'renamed)
 715           (re-search-forward "R   \\(.*\\) => \\(.*\\)$" (line-end-position) t)
 716           (let ((new-name (file-relative-name (match-string 2) relative-dir))
 717                 (old-name (file-relative-name (match-string 1) relative-dir)))
 718             (push (list new-name 'edited
 719                       (vc-bzr-create-extra-fileinfo old-name)) result)))
 720          ;; do nothing for non existent files
 721          ((eq translated 'not-found))
 722          (t
 723           (push (list (file-relative-name
 724                        (buffer-substring-no-properties
 725                         (+ (point) 4)
 726                         (line-end-position)) relative-dir)
 727                       translated) result)))
 728         (forward-line))
 729       (funcall update-function result)))
 730
 731 (defun vc-bzr-dir-status (dir update-function)
 732   "Return a list of conses (file . state) for DIR."
 733   (vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S")
 734   (vc-exec-after
 735    `(vc-bzr-after-dir-status (quote ,update-function)
 736                              ;; "bzr status" results are relative to
 737                              ;; the bzr root directory, NOT to the
 738                              ;; directory "bzr status" was invoked in.
 739                              ;; Ugh.
 740                              ;; We pass the relative directory here so
 741                              ;; that `vc-bzr-after-dir-status' can
 742                              ;; frob the results accordingly.
 743                              (file-relative-name ,dir (vc-bzr-root ,dir)))))
 744
 745 (defun vc-bzr-dir-status-files (dir files default-state update-function)
 746   "Return a list of conses (file . state) for DIR."
 747   (apply 'vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S" files)
 748   (vc-exec-after
 749    `(vc-bzr-after-dir-status (quote ,update-function)
 750                              (file-relative-name ,dir (vc-bzr-root ,dir)))))
 751
 752 (defvar vc-bzr-shelve-map
 753   (let ((map (make-sparse-keymap)))
 754     ;; Turn off vc-dir marking
 755     (define-key map [mouse-2] 'ignore)
 756
 757     (define-key map [down-mouse-3] 'vc-bzr-shelve-menu)
 758     (define-key map "\C-k" 'vc-bzr-shelve-delete-at-point)
 759     ;; (define-key map "=" 'vc-bzr-shelve-show-at-point)
 760     ;; (define-key map "\C-m" 'vc-bzr-shelve-show-at-point)
 761     (define-key map "P" 'vc-bzr-shelve-apply-at-point)
 762     map))
 763
 764 (defvar vc-bzr-shelve-menu-map
 765   (let ((map (make-sparse-keymap "Bzr Shelve")))
 766     (define-key map [de]
 767       '(menu-item "Delete shelf" vc-bzr-shelve-delete-at-point
 768                   :help "Delete the current shelf"))
 769     (define-key map [po]
 770       '(menu-item "Apply and remove shelf (pop)" vc-bzr-shelve-apply-at-point
 771                   :help "Apply the current shelf and remove it"))
 772     ;; (define-key map [sh]
 773     ;;   '(menu-item "Show shelve" vc-bzr-shelve-show-at-point
 774     ;;            :help "Show the contents of the current shelve"))
 775     map))
 776
 777 (defvar vc-bzr-extra-menu-map
 778   (let ((map (make-sparse-keymap)))
 779     (define-key map [bzr-sh]
 780       '(menu-item "Shelve..." vc-bzr-shelve
 781                   :help "Shelve changes"))
 782     map))
 783
 784 (defun vc-bzr-extra-menu () vc-bzr-extra-menu-map)
 785
 786 (defun vc-bzr-extra-status-menu () vc-bzr-extra-menu-map)
 787
 788 (defun vc-bzr-dir-extra-headers (dir)
 789   (let*
 790       ((str (with-temp-buffer
 791               (vc-bzr-command "info" t 0 dir)
 792               (buffer-string)))
 793        (shelve (vc-bzr-shelve-list))
 794        (shelve-help-echo "Use M-x vc-bzr-shelve to create shelves")
 795        (light-checkout
 796         (when (string-match ".+light checkout root: \\(.+\\)$" str)
 797           (match-string 1 str)))
 798        (light-checkout-branch
 799         (when light-checkout
 800           (when (string-match ".+checkout of branch: \\(.+\\)$" str)
 801             (match-string 1 str)))))
 802     (concat
 803      (propertize "Parent branch      : " 'face 'font-lock-type-face)
 804      (propertize
 805       (if (string-match "parent branch: \\(.+\\)$" str)
 806           (match-string 1 str)
 807         "None")
 808        'face 'font-lock-variable-name-face)
 809      "\n"
 810       (when light-checkout
 811         (concat
 812          (propertize "Light checkout root: " 'face 'font-lock-type-face)
 813          (propertize light-checkout 'face 'font-lock-variable-name-face)
 814          "\n"))
 815       (when light-checkout-branch
 816         (concat
 817          (propertize "Checkout of branch : " 'face 'font-lock-type-face)
 818          (propertize light-checkout-branch 'face 'font-lock-variable-name-face)
 819          "\n"))
 820      (if shelve
 821          (concat
 822           (propertize "Shelves            :\n" 'face 'font-lock-type-face
 823                       'help-echo shelve-help-echo)
 824           (mapconcat
 825            (lambda (x)
 826              (propertize x
 827                          'face 'font-lock-variable-name-face
 828                          'mouse-face 'highlight
 829                          'help-echo "mouse-3: Show shelve menu\nP: Apply and remove shelf (pop)\nC-k: Delete shelf"
 830                          'keymap vc-bzr-shelve-map))
 831            shelve "\n"))
 832        (concat
 833         (propertize "Shelves            : " 'face 'font-lock-type-face
 834                     'help-echo shelve-help-echo)
 835         (propertize "No shelved changes"
 836                     'help-echo shelve-help-echo
 837                     'face 'font-lock-variable-name-face))))))
 838
 839 (defun vc-bzr-shelve (name)
 840   "Create a shelve."
 841   (interactive "sShelf name: ")
 842   (let ((root (vc-bzr-root default-directory)))
 843     (when root
 844       (vc-bzr-command "shelve" nil 0 nil "--all" "-m" name)
 845       (vc-resynch-buffer root t t))))
 846
 847 ;; (defun vc-bzr-shelve-show (name)
 848 ;;   "Show the contents of shelve NAME."
 849 ;;   (interactive "sShelve name: ")
 850 ;;   (vc-setup-buffer "*vc-bzr-shelve*")
 851 ;;   ;; FIXME: how can you show the contents of a shelf?
 852 ;;   (vc-bzr-command "shelve" "*vc-bzr-shelve*" 'async nil name)
 853 ;;   (set-buffer "*vc-bzr-shelve*")
 854 ;;   (diff-mode)
 855 ;;   (setq buffer-read-only t)
 856 ;;   (pop-to-buffer (current-buffer)))
 857
 858 (defun vc-bzr-shelve-apply (name)
 859   "Apply shelve NAME and remove it afterwards."
 860   (interactive "sApply (and remove) shelf: ")
 861   (vc-bzr-command "unshelve" "*vc-bzr-shelve*" 0 nil "--apply" name)
 862   (vc-resynch-buffer (vc-bzr-root default-directory) t t))
 863
 864 (defun vc-bzr-shelve-list ()
 865   (with-temp-buffer
 866     (vc-bzr-command "shelve" (current-buffer) 1 nil "--list" "-q")
 867     (delete
 868      ""
 869      (split-string
 870       (buffer-substring (point-min) (point-max))
 871       "\n"))))
 872
 873 (defun vc-bzr-shelve-get-at-point (point)
 874   (save-excursion
 875     (goto-char point)
 876     (beginning-of-line)
 877     (if (looking-at "^ +\\([0-9]+\\):")
 878         (match-string 1)
 879       (error "Cannot find shelf at point"))))
 880
 881 (defun vc-bzr-shelve-delete-at-point ()
 882   (interactive)
 883   (let ((shelve (vc-bzr-shelve-get-at-point (point))))
 884     (when (y-or-n-p (format "Remove shelf %s ?" shelve))
 885       (vc-bzr-command "unshelve" nil 0 nil "--delete-only" shelve)
 886       (vc-dir-refresh))))
 887
 888 ;; (defun vc-bzr-shelve-show-at-point ()
 889 ;;   (interactive)
 890 ;;   (vc-bzr-shelve-show (vc-bzr-shelve-get-at-point (point))))
 891
 892 (defun vc-bzr-shelve-apply-at-point ()
 893   (interactive)
 894   (vc-bzr-shelve-apply (vc-bzr-shelve-get-at-point (point))))
 895
 896 (defun vc-bzr-shelve-menu (e)
 897   (interactive "e")
 898   (vc-dir-at-event e (popup-menu vc-bzr-shelve-menu-map e)))
 899
 900 ;;; Revision completion
 901
 902 (eval-and-compile
 903   (defconst vc-bzr-revision-keywords
 904     '("revno" "revid" "last" "before"
 905       "tag" "date" "ancestor" "branch" "submit")))
 906
 907 (defun vc-bzr-revision-completion-table (files)
 908   (lexical-let ((files files))
 909     ;; What about using `files'?!?  --Stef
 910     (lambda (string pred action)
 911       (cond
 912        ((string-match "\\`\\(ancestor\\|branch\\|\\(revno:\\)?[-0-9]+:\\):"
 913                       string)
 914         (completion-table-with-context (substring string 0 (match-end 0))
 915                                        'completion-file-name-table
 916                                        (substring string (match-end 0))
 917                                        ;; Dropping `pred' for no good reason.
 918                                        'file-directory-p
 919                                        action))
 920        ((string-match "\\`\\(before\\):" string)
 921         (completion-table-with-context (substring string 0 (match-end 0))
 922                                        (vc-bzr-revision-completion-table files)
 923                                        (substring string (match-end 0))
 924                                        pred
 925                                        action))
 926        ((string-match "\\`\\(tag\\):" string)
 927         (let ((prefix (substring string 0 (match-end 0)))
 928               (tag (substring string (match-end 0)))
 929               (table nil)
 930               process-file-side-effects)
 931           (with-temp-buffer
 932             ;; "bzr-1.2 tags" is much faster with --show-ids.
 933             (process-file vc-bzr-program nil '(t) nil "tags" "--show-ids")
 934             ;; The output is ambiguous, unless we assume that revids do not
 935             ;; contain spaces.
 936             (goto-char (point-min))
 937             (while (re-search-forward "^\\(.*[^ \n]\\) +[^ \n]*$" nil t)
 938               (push (match-string-no-properties 1) table)))
 939           (completion-table-with-context prefix table tag pred action)))
 940
 941        ((string-match "\\`\\([a-z]+\\):" string)
 942         ;; no actual completion for the remaining keywords.
 943         (completion-table-with-context (substring string 0 (match-end 0))
 944                                        (if (member (match-string 1 string)
 945                                                    vc-bzr-revision-keywords)
 946                                            ;; If it's a valid keyword,
 947                                            ;; use a non-empty table to
 948                                            ;; indicate it.
 949                                            '("") nil)
 950                                        (substring string (match-end 0))
 951                                        pred
 952                                        action))
 953        (t
 954         ;; Could use completion-table-with-terminator, except that it
 955         ;; currently doesn't work right w.r.t pcm and doesn't give
 956         ;; the *Completions* output we want.
 957         (complete-with-action action (eval-when-compile
 958                                        (mapcar (lambda (s) (concat s ":"))
 959                                                vc-bzr-revision-keywords))
 960                               string pred))))))
 961
 962 (eval-after-load "vc"
 963   '(add-to-list 'vc-directory-exclusion-list vc-bzr-admin-dirname t))
 964
 965 (provide 'vc-bzr)
 966 ;; arch-tag: 8101bad8-4e92-4e7d-85ae-d8e08b4e7c06
 967 ;;; vc-bzr.el ends here