configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 150 if test "$with_wide_int" = yes; then
 151   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 152 fi
 153
 154 dnl _ON results in a '--without' option in the --help output, so
 155 dnl the help text should refer to "don't compile", etc.
 156 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 157 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 158 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 159 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 160 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 161 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 162 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 163 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 164
 165 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 166 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 167 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 168
 169 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 170 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 171 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 172 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 173
 174 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 175 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 176 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 177 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 178 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 179 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## Makefile.in needs the cache file name.
 187 AC_SUBST(cache_file)
 188
 189 ## This is an option because I do not know if all info/man support
 190 ## compressed files, nor how to test if they do so.
 191 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 192 if test $with_compress_info = yes; then
 193    GZIP_INFO=yes
 194 else
 195    GZIP_INFO=
 196 fi
 197 AC_SUBST(GZIP_INFO)
 198
 199 AC_ARG_WITH([pkg-config-prog],dnl
 200 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 201                   [path to pkg-config for finding GTK and librsvg])])
 202 if test "X${with_pkg_config_prog}" != X; then
 203    if test "${with_pkg_config_prog}" != yes; then
 204       PKG_CONFIG="${with_pkg_config_prog}"
 205    fi
 206 fi
 207
 208 CRT_DIR=
 209 AC_ARG_WITH([crt-dir],dnl
 210 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 211 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 212 CRT_DIR="${with_crt_dir}"
 213
 214 AC_ARG_WITH(gameuser,dnl
 215 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 216 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 217   && gameuser="${with_gameuser}"
 218 test "X$gameuser" = X && gameuser=games
 219
 220 AC_ARG_WITH([gnustep-conf],dnl
 221 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 222 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 223   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 224 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 225      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 226
 227 AC_ARG_ENABLE(ns-self-contained,
 228 [AS_HELP_STRING([--disable-ns-self-contained],
 229                 [disable self contained build under NeXTstep])],
 230    EN_NS_SELF_CONTAINED=$enableval,
 231    EN_NS_SELF_CONTAINED=yes)
 232
 233 AC_ARG_ENABLE(asserts,
 234 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 235       USE_XASSERTS=$enableval,
 236       USE_XASSERTS=no)
 237
 238 AC_ARG_ENABLE(locallisppath,
 239 [AS_HELP_STRING([--enable-locallisppath=PATH],
 240                 [directories Emacs should search for lisp files specific
 241                  to this site])],
 242 if test "${enableval}" = "no"; then
 243   locallisppath=
 244 elif test "${enableval}" != "yes"; then
 245   locallisppath=${enableval}
 246 fi)
 247
 248 AC_ARG_ENABLE(checking,
 249 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 250                 [enable expensive run-time checks.  With LIST,
 251                  enable only specific categories of checks.
 252                  Categories are: all,yes,no.
 253                  Flags are: stringbytes, stringoverrun, stringfreelist,
 254                  xmallocoverrun, conslist])],
 255 [ac_checking_flags="${enableval}"],[])
 256 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 257 for check in $ac_checking_flags
 258 do
 259         case $check in
 260         # these set all the flags to specific states
 261         yes)            ac_enable_checking=1 ;;
 262         no)             ac_enable_checking= ;
 263                         ac_gc_check_stringbytes= ;
 264                         ac_gc_check_string_overrun= ;
 265                         ac_gc_check_string_free_list= ;
 266                         ac_xmalloc_overrun= ;
 267                         ac_gc_check_cons_list= ;;
 268         all)            ac_enable_checking=1 ;
 269                         ac_gc_check_stringbytes=1 ;
 270                         ac_gc_check_string_overrun=1 ;
 271                         ac_gc_check_string_free_list=1 ;
 272                         ac_xmalloc_overrun=1 ;
 273                         ac_gc_check_cons_list=1 ;;
 274         # these enable particular checks
 275         stringbytes)    ac_gc_check_stringbytes=1 ;;
 276         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 277         stringfreelist) ac_gc_check_string_free_list=1 ;;
 278         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 279         conslist)       ac_gc_check_cons_list=1 ;;
 280         *)      AC_MSG_ERROR(unknown check category $check) ;;
 281         esac
 282 done
 283 IFS="$ac_save_IFS"
 284
 285 if test x$ac_enable_checking != x ; then
 286   AC_DEFINE(ENABLE_CHECKING, 1,
 287 [Enable expensive run-time checking of data types?])
 288 fi
 289 if test x$ac_gc_check_stringbytes != x ; then
 290   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 291 [Define this temporarily to hunt a bug.  If defined, the size of
 292    strings is redundantly recorded in sdata structures so that it can
 293    be compared to the sizes recorded in Lisp strings.])
 294 fi
 295 if test x$ac_gc_check_string_overrun != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 297 [Define this to check for short string overrun.])
 298 fi
 299 if test x$ac_gc_check_string_free_list != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 301 [Define this to check the string free list.])
 302 fi
 303 if test x$ac_xmalloc_overrun != x ; then
 304   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 305 [Define this to check for malloc buffer overrun.])
 306 fi
 307 if test x$ac_gc_check_cons_list != x ; then
 308   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 309 [Define this to check for errors in cons list.])
 310 fi
 311
 312 AC_ARG_ENABLE(check-lisp-object-type,
 313 [AS_HELP_STRING([--enable-check-lisp-object-type],
 314                 [enable compile time checks for the Lisp_Object data type.
 315                 This is useful for development for catching certain types of bugs.])],
 316 if test "${enableval}" != "no"; then
 317    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 318    [Define this to enable compile time checks for the Lisp_Object data type.])
 319 fi)
 320
 321
 322 AC_ARG_ENABLE(profiling,
 323 [AS_HELP_STRING([--enable-profiling],
 324                 [build emacs with profiling support.
 325                  This might not work on all platforms])],
 326 [ac_enable_profiling="${enableval}"],[])
 327 if test x$ac_enable_profiling != x ; then
 328    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 329 else
 330    PROFILING_CFLAGS=
 331 fi
 332 AC_SUBST(PROFILING_CFLAGS)
 333
 334 AC_ARG_ENABLE(autodepend,
 335 [AS_HELP_STRING([--enable-autodepend],
 336                 [automatically generate dependencies to .h-files.
 337                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 338                  found])],
 339 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 340
 341 #### Make srcdir absolute, if it isn't already.  It's important to
 342 #### avoid running the path through pwd unnecessarily, since pwd can
 343 #### give you automounter prefixes, which can go away.  We do all this
 344 #### so Emacs can find its files when run uninstalled.
 345 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 346 unset CDPATH
 347 case "${srcdir}" in
 348   /* ) ;;
 349   . )
 350     ## We may be able to use the $PWD environment variable to make this
 351     ## absolute.  But sometimes PWD is inaccurate.
 352     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 353     ## but that tested only for a well-formed and valid PWD,
 354     ## it did not object when PWD was well-formed and valid but just wrong.
 355     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 356     then
 357       srcdir="$PWD"
 358     else
 359       srcdir="`(cd ${srcdir}; pwd)`"
 360     fi
 361   ;;
 362   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 363 esac
 364
 365 #### Given the configuration name, set opsysfile to the
 366 #### name of s/*.h file we should use.
 367
 368 ### Canonicalize the configuration name.
 369
 370 AC_CANONICAL_HOST
 371 canonical=$host
 372 configuration=${host_alias-${build_alias-$host}}
 373
 374 dnl This used to use changequote, but, apart from `changequote is evil'
 375 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 376 dnl the great gob of text.  Thus it's not processed for possible expansion.
 377 dnl Just make sure the brackets remain balanced.
 378 dnl
 379 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 380 dnl indicated by comments.
 381 dnl quotation begins
 382 [
 383
 384 ### If you add support for a new configuration, add code to this
 385 ### switch statement to recognize your configuration name and select
 386 ### the appropriate operating system file.
 387
 388 ### You would hope that you could choose an s/*.h
 389 ### file based on the operating system portion.  However, it turns out
 390 ### that each s/*.h file is pretty manufacturer-specific.
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## GNU/Linux and similar ports
 404   *-*-linux* )
 405     opsys=gnu-linux
 406   ;;
 407
 408   ## FreeBSD ports
 409   *-*-freebsd* )
 410     opsys=freebsd
 411   ;;
 412
 413   ## FreeBSD kernel + glibc based userland
 414   *-*-kfreebsd*gnu* )
 415     opsys=gnu-kfreebsd
 416   ;;
 417
 418   ## NetBSD ports
 419   *-*-netbsd* )
 420     opsys=netbsd
 421   ;;
 422
 423   ## OpenBSD ports
 424   *-*-openbsd* )
 425     opsys=openbsd
 426   ;;
 427
 428   ## Apple Darwin / Mac OS X
 429   *-apple-darwin* )
 430     case "${canonical}" in
 431       i[3456]86-* )  ;;
 432       powerpc-* )    ;;
 433       x86_64-* )     ;;
 434       * )            unported=yes ;;
 435     esac
 436     opsys=darwin
 437     ## Use fink packages if available.
 438     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 439 ##    if test -d /sw/include && test -d /sw/lib; then
 440 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 441 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 442 ##    fi
 443   ;;
 444
 445   ## HP 9000 series 700 and 800, running HP/UX
 446   hppa*-hp-hpux10.2* )
 447     opsys=hpux10-20
 448   ;;
 449   hppa*-hp-hpux1[1-9]* )
 450     opsys=hpux11
 451     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 452   ;;
 453
 454   ## IBM machines
 455   rs6000-ibm-aix4.[23]* )
 456     opsys=aix4-2
 457   ;;
 458   powerpc-ibm-aix4.[23]*  )
 459     opsys=aix4-2
 460   ;;
 461   rs6000-ibm-aix[56]* )
 462     opsys=aix4-2
 463   ;;
 464   powerpc-ibm-aix[56]*  )
 465     opsys=aix4-2
 466   ;;
 467
 468   ## Silicon Graphics machines
 469   ## Iris 4D
 470   mips-sgi-irix6.5 )
 471     opsys=irix6-5
 472     # Without defining _LANGUAGE_C, things get masked out in the headers
 473     # so that, for instance, grepping for `free' in stdlib.h fails and
 474     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 475     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 476   ;;
 477
 478   ## Suns
 479   *-sun-solaris* \
 480     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 481     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 482     case "${canonical}" in
 483       i[3456]86-*-* )   ;;
 484       amd64-*-*|x86_64-*-*) ;;
 485       sparc* )          ;;
 486       * )               unported=yes ;;
 487     esac
 488     case "${canonical}" in
 489       *-sunos5.6* | *-solaris2.6* )
 490                 opsys=sol2-6
 491                 RANLIB="ar -ts"
 492                 ;;
 493       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 494                 opsys=sol2-6
 495                 emacs_check_sunpro_c=yes
 496                 ;;
 497       *-sunos5* | *-solaris* )
 498                 opsys=sol2-10
 499                 emacs_check_sunpro_c=yes
 500                 ;;
 501     esac
 502     ## Watch out for a compiler that we know will not work.
 503     case "${canonical}" in
 504      *-solaris* | *-sunos5* )
 505                 if [ "x$CC" = x/usr/ucb/cc ]; then
 506                   ## /usr/ucb/cc doesn't work;
 507                   ## we should find some other compiler that does work.
 508                   unset CC
 509                 fi
 510                 ;;
 511       *) ;;
 512     esac
 513   ;;
 514
 515   ## Intel 386 machines where we don't care about the manufacturer.
 516   i[3456]86-*-* )
 517     case "${canonical}" in
 518       *-cygwin )                opsys=cygwin ;;
 519       *-darwin* )               opsys=darwin ;;
 520       *-sysv4.2uw* )            opsys=unixware ;;
 521       *-sysv5uw* )              opsys=unixware ;;
 522       *-sysv5OpenUNIX* )        opsys=unixware ;;
 523       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 524     esac
 525   ;;
 526
 527   * )
 528     unported=yes
 529   ;;
 530 esac
 531
 532 ### If the code above didn't choose an operating system, just choose
 533 ### an operating system based on the configuration name.  You really
 534 ### only want to use this when you have no idea what the right
 535 ### operating system is; if you know what operating systems a machine
 536 ### runs, it's cleaner to make it explicit in the case statement
 537 ### above.
 538 if test x"${opsys}" = x; then
 539   case "${canonical}" in
 540     *-gnu* )                            opsys=gnu ;;
 541     * )
 542       unported=yes
 543     ;;
 544   esac
 545 fi
 546
 547 ]
 548 dnl quotation ends
 549
 550 if test $unported = yes; then
 551   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 552 Check `etc/MACHINES' for recognized configuration names.])
 553 fi
 554
 555 opsysfile="s/${opsys}.h"
 556
 557
 558 #### Choose a compiler.
 559
 560 dnl Sets GCC=yes if using gcc.
 561 AC_PROG_CC
 562 AM_PROG_CC_C_O
 563
 564 if test x$GCC = xyes; then
 565   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 566 else
 567   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 568 fi
 569
 570 # Initialize gnulib right after choosing the compiler.
 571 gl_EARLY
 572
 573 AC_ARG_ENABLE([gcc-warnings],
 574   [AS_HELP_STRING([--enable-gcc-warnings],
 575                   [turn on lots of GCC warnings (for developers)])],
 576   [case $enableval in
 577      yes|no) ;;
 578      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 579    esac
 580    gl_gcc_warnings=$enableval],
 581   [gl_gcc_warnings=no]
 582 )
 583
 584 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 585 # ------------------------------------------------
 586 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 587 # Otherwise, run RUN-IF-NOT-FOUND.
 588 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 589   [AC_PREPROC_IFELSE(
 590     [AC_LANG_PROGRAM(
 591       [[
 592 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 593 /* ok */
 594 #else
 595 # error "your version of gcc is older than $1.$2"
 596 #endif
 597       ]]),
 598     ], [$3], [$4])
 599   ]
 600 )
 601
 602 # When compiling with GCC, prefer -isystem to -I when including system
 603 # include files, to avoid generating useless diagnostics for the files.
 604 if test "$gl_gcc_warnings" != yes; then
 605   isystem='-I'
 606 else
 607   isystem='-isystem '
 608
 609   # This, $nw, is the list of warnings we disable.
 610   nw=
 611
 612   case $with_x_toolkit in
 613     lucid | athena | motif)
 614        # Old toolkits mishandle 'const'.
 615        nw="$nw -Wwrite-strings"
 616        ;;
 617     *)
 618        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 619        ;;
 620   esac
 621   AC_SUBST([WERROR_CFLAGS])
 622
 623   nw="$nw -Waggregate-return"       # anachronistic
 624   nw="$nw -Wlong-long"              # C90 is anachronistic
 625   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 626   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 627   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 628   nw="$nw -Wcast-qual"              # Too many warnings for now
 629   nw="$nw -Wconversion"             # Too many warnings for now
 630   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 631   nw="$nw -Wsign-conversion"        # Too many warnings for now
 632   nw="$nw -Woverlength-strings"     # Not a problem these days
 633   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 634   nw="$nw -Wpadded"                 # Our structs are not padded
 635   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 636   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 637   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 638   nw="$nw -Wvla"                    # warnings in gettext.h
 639   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 640   nw="$nw -Wswitch-enum"            # Too many warnings for now
 641   nw="$nw -Wswitch-default"         # Too many warnings for now
 642   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 643   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 644
 645   # Emacs doesn't care about shadowing; see
 646   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 647   nw="$nw -Wshadow"
 648
 649   # The following lines should be removable at some point.
 650   nw="$nw -Wstack-protector"
 651   nw="$nw -Wstrict-overflow"
 652   nw="$nw -Wsuggest-attribute=const"
 653   nw="$nw -Wsuggest-attribute=pure"
 654
 655   gl_MANYWARN_ALL_GCC([ws])
 656   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 657   for w in $ws; do
 658     gl_WARN_ADD([$w])
 659   done
 660   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 661   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 662   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 663   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 664   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 665   gl_WARN_ADD([-Wno-format-nonliteral])
 666
 667   # In spite of excluding -Wlogical-op above, it is enabled, as of
 668   # gcc 4.5.0 20090517.
 669   gl_WARN_ADD([-Wno-logical-op])
 670
 671   gl_WARN_ADD([-fdiagnostics-show-option])
 672   gl_WARN_ADD([-funit-at-a-time])
 673
 674   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 675   AC_DEFINE([_FORTIFY_SOURCE], [2],
 676     [enable compile-time and run-time bounds-checking, and some warnings])
 677   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 678
 679   # We use a slightly smaller set of warning options for lib/.
 680   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 681   nw=
 682   nw="$nw -Wunused-macros"
 683
 684   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 685   AC_SUBST([GNULIB_WARN_CFLAGS])
 686 fi
 687
 688
 689
 690 dnl Some other nice autoconf tests.
 691 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 692 dnl AC_PROG_INSTALL
 693 dnl AC_PROG_MKDIR_P
 694 dnl if test "x$RANLIB" = x; then
 695 dnl   AC_PROG_RANLIB
 696 dnl fi
 697
 698 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 699   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 700 dnl Don't use GZIP, which is used by gzip for additional parameters.
 701 AC_PATH_PROG(GZIP_PROG, gzip)
 702 AC_PATH_PROG(PAXCTL, paxctl,,
 703   [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 704
 705
 706 ## Need makeinfo >= 4.7 (?) to build the manuals.
 707 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 708 dnl By this stage, configure has already checked for egrep and set EGREP,
 709 dnl or exited with an error if no egrep was found.
 710 if test "$MAKEINFO" != "no" && \
 711   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 712    MAKEINFO=no
 713 fi
 714
 715 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 716 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 717 ## therefore in the category of "special tools" not normally required, which
 718 ## configure does not have to check for (eg autoconf itself).
 719 ## In a Bazaar checkout on the other hand, the manuals are not included.
 720 ## So makeinfo is a requirement to build from Bazaar, and configure
 721 ## should test for it as it does for any other build requirement.
 722 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 723 ## with pre-built manuals, from a Bazaar checkout.
 724 HAVE_MAKEINFO=yes
 725
 726 if test "$MAKEINFO" = "no"; then
 727   MAKEINFO=makeinfo
 728   if test "x${with_makeinfo}" = "xno"; then
 729     HAVE_MAKEINFO=no
 730   elif test ! -e $srcdir/info/emacs; then
 731     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 732 source tree does not seem to have pre-built manuals in the `info' directory.
 733 Either install a suitable version of makeinfo, or re-run configure
 734 with the `--without-makeinfo' option to build without the manuals.] )
 735   fi
 736 fi
 737 AC_SUBST(HAVE_MAKEINFO)
 738
 739 dnl Just so that there is only a single place we need to edit.
 740 INFO_EXT=.info
 741 INFO_OPTS=--no-split
 742 AC_SUBST(INFO_EXT)
 743 AC_SUBST(INFO_OPTS)
 744
 745 dnl Add our options to ac_link now, after it is set up.
 746
 747 if test x$GCC = xyes; then
 748   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 749     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 750 else
 751   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 752     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 753 fi
 754
 755 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 756 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 757 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 758 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 759 dnl if not built to support GNU ld.
 760
 761 late_LDFLAGS=$LDFLAGS
 762 if test x$GCC = xyes; then
 763   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 764 else
 765   LDFLAGS="$LDFLAGS -znocombreloc"
 766 fi
 767
 768 AC_MSG_CHECKING([for -znocombreloc])
 769 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 770   [AC_MSG_RESULT(yes)],
 771   LDFLAGS=$late_LDFLAGS
 772   [AC_MSG_RESULT(no)])
 773
 774
 775 dnl The function dump-emacs will not be defined and temacs will do
 776 dnl (load "loadup") automatically unless told otherwise.
 777 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 778 case "$opsys" in
 779   your-opsys-here) CANNOT_DUMP=yes ;;
 780 esac
 781
 782 test "$CANNOT_DUMP" = "yes" && \
 783   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 784
 785 AC_SUBST(CANNOT_DUMP)
 786
 787
 788 UNEXEC_OBJ=unexelf.o
 789 case "$opsys" in
 790   # MSDOS uses unexcoff.o
 791   # MSWindows uses unexw32.o
 792   aix4-2)
 793    UNEXEC_OBJ=unexaix.o
 794    ;;
 795   cygwin)
 796    UNEXEC_OBJ=unexcw.o
 797    ;;
 798   darwin)
 799    UNEXEC_OBJ=unexmacosx.o
 800    ;;
 801   hpux10-20 | hpux11)
 802    UNEXEC_OBJ=unexhp9k800.o
 803    ;;
 804   sol2-10)
 805    # Use the Solaris dldump() function, called from unexsol.c, to dump
 806    # emacs, instead of the generic ELF dump code found in unexelf.c.
 807    # The resulting binary has a complete symbol table, and is better
 808    # for debugging and other observability tools (debuggers, pstack, etc).
 809    #
 810    # If you encounter a problem using dldump(), please consider sending
 811    # a message to the OpenSolaris tools-linking mailing list:
 812    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 813    #
 814    # It is likely that dldump() works with older Solaris too, but this has
 815    # not been tested, so for now this change is for Solaris 10 or newer.
 816    UNEXEC_OBJ=unexsol.o
 817    ;;
 818 esac
 819
 820 LD_SWITCH_SYSTEM=
 821 case "$opsys" in
 822   freebsd)
 823    ## Let `ld' find image libs and similar things in /usr/local/lib.
 824    ## The system compiler, GCC, has apparently been modified to not
 825    ## look there, contrary to what a stock GCC would do.
 826 ### It's not our place to do this.  See bug#10313#17.
 827 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 828       :
 829    ;;
 830
 831   gnu-linux)
 832    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 833    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 834    ;;
 835
 836   netbsd)
 837 ### It's not our place to do this.  See bug#10313#17.
 838 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 839       :
 840    ;;
 841
 842   openbsd)
 843    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 844    ## otherwise Emacs dumps core on elf systems.
 845    LD_SWITCH_SYSTEM="-Z"
 846    ;;
 847 esac
 848 AC_SUBST(LD_SWITCH_SYSTEM)
 849
 850 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 851
 852 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 853 ## which has not been defined yet.  When this was handled with cpp,
 854 ## it was expanded to null when configure sourced the s/*.h file.
 855 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 856 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 857 ## (or somesuch), but because it is supposed to go at the _front_
 858 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 859 ## Compare with the gnu-linux case below, which added to the end
 860 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 861 ## LD_SWITCH_SYSTEM_TEMACS.
 862 case "$opsys" in
 863   netbsd|openbsd)
 864    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 865 esac
 866
 867
 868 C_SWITCH_MACHINE=
 869 case $canonical in
 870  alpha*)
 871   AC_CHECK_DECL([__ELF__])
 872   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 873     ## With ELF, make sure that all common symbols get allocated to in the
 874     ## data section.  Otherwise, the dump of temacs may miss variables in
 875     ## the shared library that have been initialized.  For example, with
 876     ## GNU libc, __malloc_initialized would normally be resolved to the
 877     ## shared library's .bss section, which is fatal.
 878     if test "x$GCC" = "xyes"; then
 879       C_SWITCH_MACHINE="-fno-common"
 880     else
 881       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 882     fi
 883   else
 884     UNEXEC_OBJ=unexalpha.o
 885   fi
 886   ;;
 887 esac
 888 AC_SUBST(C_SWITCH_MACHINE)
 889
 890 AC_SUBST(UNEXEC_OBJ)
 891
 892 C_SWITCH_SYSTEM=
 893 ## Some programs in src produce warnings saying certain subprograms
 894 ## are too complex and need a MAXMEM value greater than 2000 for
 895 ## additional optimization.  --nils@exp-math.uni-essen.de
 896 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 897   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 898 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 899 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 900 AC_SUBST(C_SWITCH_SYSTEM)
 901
 902
 903 LIBS_SYSTEM=
 904 case "$opsys" in
 905   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 906   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 907
 908   freebsd) LIBS_SYSTEM="-lutil" ;;
 909
 910   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 911
 912   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 913
 914   ## Motif needs -lgen.
 915   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 916 esac
 917 AC_SUBST(LIBS_SYSTEM)
 918
 919
 920 ### Make sure subsequent tests use flags consistent with the build flags.
 921
 922 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 923   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 924 else
 925   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 926 fi
 927
 928 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 929 AC_DEFUN([AC_TYPE_SIZE_T])
 930 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 931 AC_DEFUN([AC_TYPE_UID_T])
 932
 933
 934 LIB_MATH=-lm
 935 LIB_STANDARD=
 936 START_FILES=
 937 dnl Current possibilities handled by sed (aix4-2 -> aix,
 938 dnl gnu-linux -> gnu/linux, etc.):
 939 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 940 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 941 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 942
 943 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 944 case $opsys in
 945   cygwin )
 946     LIB_MATH=
 947     START_FILES='pre-crt0.o'
 948     ;;
 949   darwin )
 950     ## Adding -lm confuses the dynamic linker, so omit it.
 951     LIB_MATH=
 952     START_FILES='pre-crt0.o'
 953     ;;
 954   freebsd )
 955     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 956     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 957     SYSTEM_TYPE=berkeley-unix
 958     ;;
 959   gnu-linux | gnu-kfreebsd )
 960     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 961     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 962     ;;
 963   hpux10-20 | hpux11 )
 964     LIB_STANDARD=-lc
 965     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
 966     ;;
 967   dnl NB this may be adjusted below.
 968   netbsd | openbsd )
 969     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
 970     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
 971     SYSTEM_TYPE=berkeley-unix
 972     ;;
 973
 974   sol2* | unixware )
 975     SYSTEM_TYPE=usg-unix-v
 976     ;;
 977
 978 esac
 979
 980 AC_SUBST(LIB_MATH)
 981 AC_SUBST(START_FILES)
 982 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
 983   [The type of system you are compiling for; sets `system-type'.])
 984
 985 dnl Not all platforms use crtn.o files.  Check if the current one does.
 986 crt_files=
 987
 988 for file in x $LIB_STANDARD $START_FILES; do
 989   case "$file" in
 990     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
 991   esac
 992 done
 993
 994 if test "x$crt_files" != x; then
 995
 996   ## If user specified a crt-dir, use that unconditionally.
 997   crt_gcc=no
 998
 999   if test "X$CRT_DIR" = "X"; then
1000
1001     CRT_DIR=/usr/lib            # default
1002
1003     case "$canonical" in
1004       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1005       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1006       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1007       ## For anything else (eg /usr/lib32), it is up the user to specify
1008       ## the location (bug#5655).
1009       ## Test for crtn.o, not just the directory, because sometimes the
1010       ## directory exists but does not have the relevant files (bug#1287).
1011       ## FIXME better to test for binary compatibility somehow.
1012       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1013       ;;
1014
1015       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1016     esac
1017
1018     case "$opsys" in
1019       hpux10-20) CRT_DIR=/lib ;;
1020     esac
1021
1022     test "x${GCC}" = xyes && crt_gcc=yes
1023
1024   fi                            # CRT_DIR = ""
1025
1026   crt_missing=
1027
1028   for file in $crt_files; do
1029
1030     ## If we're using gcc, try to determine it automatically by asking
1031     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1032     ## system-dependent default from above.]
1033     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1034
1035        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1036        case "$crt_file" in
1037          */*)
1038            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1039            ;;
1040        esac
1041     fi
1042
1043     dnl We expect all the files to be in a single directory, so after the
1044     dnl first there is no point asking gcc.
1045     crt_gcc=no
1046
1047     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1048   done                          # $crt_files
1049
1050   test "x$crt_missing" = x || \
1051     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1052 Try using the --with-crt-dir option.])
1053
1054 fi                              # crt_files != ""
1055
1056 AC_SUBST(CRT_DIR)
1057
1058 case $opsys in
1059   netbsd | openbsd )
1060     if test -f $CRT_DIR/crti.o; then
1061
1062         test -f $CRT_DIR/crtn.o || \
1063           AC_MSG_ERROR([Required file not found: crtn.o])
1064
1065         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1066         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1067     fi
1068     ;;
1069 esac
1070
1071
1072 # Configure gnulib before invoking PKG_CHECK_MODULES, as the latter might
1073 # for example add -lrt to RSVG_LIBS, which would then cause gnulib to
1074 # incorrectly conclude that -lrt is not needed to link clock_gettime.
1075 gl_ASSERT_NO_GNULIB_POSIXCHECK
1076 gl_ASSERT_NO_GNULIB_TESTS
1077 gl_INIT
1078
1079 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1080
1081 dnl This function definition taken from Gnome 2.0
1082 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1083 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1084 dnl also defines GSTUFF_PKG_ERRORS on error
1085 AC_DEFUN([PKG_CHECK_MODULES], [
1086   succeeded=no
1087
1088   if test "$PKG_CONFIG" = "no" ; then
1089      ifelse([$4], , [AC_MSG_ERROR([
1090       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1091   else
1092      PKG_CONFIG_MIN_VERSION=0.9.0
1093      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1094         AC_MSG_CHECKING(for $2)
1095
1096         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1097            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1098            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1099             edit_cflags="
1100               s,///*,/,g
1101               s/^/ /
1102               s/ -I/ $isystem/g
1103               s/^ //
1104             "
1105             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1106             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1107             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1108             succeeded=yes
1109         else
1110             AC_MSG_RESULT(no)
1111             $1_CFLAGS=""
1112             $1_LIBS=""
1113             ## If we have a custom action on failure, don't print errors, but
1114             ## do set a variable so people can do so.
1115             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1116             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1117         fi
1118
1119         AC_SUBST($1_CFLAGS)
1120         AC_SUBST($1_LIBS)
1121      else
1122         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1123         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1124      fi
1125   fi
1126
1127   if test $succeeded = yes; then
1128      ifelse([$3], , :, [$3])
1129   else
1130      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1131   fi
1132 ])
1133
1134
1135 if test "${with_sound}" != "no"; then
1136   # Sound support for GNU/Linux and the free BSDs.
1137   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1138     have_sound_header=yes)
1139   # Emulation library used on NetBSD.
1140   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1141   AC_SUBST(LIBSOUND)
1142
1143   ALSA_REQUIRED=1.0.0
1144   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1145   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1146   if test $HAVE_ALSA = yes; then
1147     SAVE_CFLAGS="$CFLAGS"
1148     SAVE_LIBS="$LIBS"
1149     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1150     LIBS="$ALSA_LIBS $LIBS"
1151     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1152                     emacs_alsa_normal=yes,
1153                     emacs_alsa_normal=no)
1154     if test "$emacs_alsa_normal" != yes; then
1155       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1156                      [[snd_lib_error_set_handler (0);]])],
1157                      emacs_alsa_subdir=yes,
1158                      emacs_alsa_subdir=no)
1159       if test "$emacs_alsa_subdir" != yes; then
1160         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1161       fi
1162       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1163     fi
1164
1165     CFLAGS="$SAVE_CFLAGS"
1166     LIBS="$SAVE_LIBS"
1167     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1168     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1169     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1170   fi
1171
1172   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1173   dnl compiles only on the specified platforms.  For others, it
1174   dnl probably doesn't make sense to try.
1175   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1176      case "$opsys" in
1177        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1178        gnu-linux|freebsd|netbsd)
1179          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1180          ;;
1181      esac
1182   fi
1183
1184   AC_SUBST(CFLAGS_SOUND)
1185 fi
1186
1187 dnl checks for header files
1188 AC_CHECK_HEADERS_ONCE(
1189   sys/select.h sys/time.h utime.h
1190   linux/version.h sys/systeminfo.h
1191   stdio_ext.h fcntl.h coff.h pty.h
1192   sys/vlimit.h sys/resource.h
1193   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1194
1195 AC_MSG_CHECKING(if personality LINUX32 can be set)
1196 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1197                emacs_cv_personality_linux32=yes,
1198                emacs_cv_personality_linux32=no)
1199 AC_MSG_RESULT($emacs_cv_personality_linux32)
1200
1201 if test $emacs_cv_personality_linux32 = yes; then
1202   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1203             [Define to 1 if personality LINUX32 can be set.])
1204 fi
1205
1206 dnl On Solaris 8 there's a compilation warning for term.h because
1207 dnl it doesn't define `bool'.
1208 AC_CHECK_HEADERS(term.h, , , -)
1209 AC_HEADER_TIME
1210 AC_CHECK_DECLS([sys_siglist])
1211 if test $ac_cv_have_decl_sys_siglist != yes; then
1212   # For Tru64, at least:
1213   AC_CHECK_DECLS([__sys_siglist])
1214   if test $ac_cv_have_decl___sys_siglist = yes; then
1215     AC_DEFINE(sys_siglist, __sys_siglist,
1216               [Define to any substitute for sys_siglist.])
1217   fi
1218 fi
1219 AC_HEADER_SYS_WAIT
1220
1221 dnl Check for speed_t typedef.
1222 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1223   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1224     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1225 if test $emacs_cv_speed_t = yes; then
1226   AC_DEFINE(HAVE_SPEED_T, 1,
1227            [Define to 1 if `speed_t' is declared by <termios.h>.])
1228 fi
1229
1230 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1231 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1232 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1233   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1234 HAVE_EXCEPTION=$emacs_cv_struct_exception
1235 if test $emacs_cv_struct_exception != yes; then
1236   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1237 fi
1238
1239 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1240 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1241 #if HAVE_SYS_SOCKET_H
1242 #include <sys/socket.h>
1243 #endif])
1244 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1245 #if HAVE_SYS_SOCKET_H
1246 #include <sys/socket.h>
1247 #endif])
1248 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1249 #if HAVE_SYS_SOCKET_H
1250 #include <sys/socket.h>
1251 #endif])
1252
1253 dnl checks for structure members
1254 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1255                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1256                   struct ifreq.ifr_addr,
1257                   struct ifreq.ifr_addr.sa_len], , ,
1258                  [AC_INCLUDES_DEFAULT
1259 #if HAVE_SYS_SOCKET_H
1260 #include <sys/socket.h>
1261 #endif
1262 #if HAVE_NET_IF_H
1263 #include <net/if.h>
1264 #endif])
1265
1266 dnl Check for endianness.
1267 dnl AC_C_BIGENDIAN is done by gnulib.
1268
1269 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1270   [emacs_cv_attribute_aligned],
1271   [AC_COMPILE_IFELSE(
1272      [AC_LANG_PROGRAM(
1273         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1274         [[]])],
1275      [emacs_cv_attribute_aligned=yes],
1276      [emacs_cv_attribute_aligned=no])])
1277 if test $emacs_cv_attribute_aligned = yes; then
1278   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1279     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1280 fi
1281
1282 dnl check for Make feature
1283 dnl AC_PROG_MAKE_SET is done by Automake.
1284
1285 DEPFLAGS=
1286 MKDEPDIR=":"
1287 deps_frag=deps.mk
1288 dnl check for GNU Make if we have GCC and autodepend is on.
1289 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1290    AC_MSG_CHECKING([whether we are using GNU Make])
1291    HAVE_GNU_MAKE=no
1292    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1293    if test "x$testval" != x; then
1294       HAVE_GNU_MAKE=yes
1295    else
1296       ac_enable_autodepend=no
1297    fi
1298    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1299    if test $HAVE_GNU_MAKE = yes; then
1300       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1301       SAVE_CFLAGS="$CFLAGS"
1302       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1303       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1304       CFLAGS="$SAVE_CFLAGS"
1305       test -f deps.d || ac_enable_autodepend=no
1306       rm -rf deps.d
1307       AC_MSG_RESULT([$ac_enable_autodepend])
1308    fi
1309    if test $ac_enable_autodepend = yes; then
1310       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1311       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1312       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1313       deps_frag=autodeps.mk
1314    fi
1315 fi
1316 deps_frag=$srcdir/src/$deps_frag
1317 AC_SUBST(MKDEPDIR)
1318 AC_SUBST(DEPFLAGS)
1319 AC_SUBST_FILE(deps_frag)
1320
1321
1322 lisp_frag=$srcdir/src/lisp.mk
1323 AC_SUBST_FILE(lisp_frag)
1324
1325
1326 dnl checks for operating system services
1327 AC_SYS_LONG_FILE_NAMES
1328
1329 #### Choose a window system.
1330
1331 AC_PATH_X
1332 if test "$no_x" = yes; then
1333   window_system=none
1334 else
1335   window_system=x11
1336 fi
1337
1338 LD_SWITCH_X_SITE_RPATH=
1339 if test "${x_libraries}" != NONE; then
1340   if test -n "${x_libraries}"; then
1341     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1342     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1343   fi
1344   x_default_search_path=""
1345   x_search_path=${x_libraries}
1346   if test -z "${x_search_path}"; then
1347     x_search_path=/usr/lib
1348   fi
1349   for x_library in `echo ${x_search_path}: | \
1350                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1351     x_search_path="\
1352 ${x_library}/X11/%L/%T/%N%C%S:\
1353 ${x_library}/X11/%l/%T/%N%C%S:\
1354 ${x_library}/X11/%T/%N%C%S:\
1355 ${x_library}/X11/%L/%T/%N%S:\
1356 ${x_library}/X11/%l/%T/%N%S:\
1357 ${x_library}/X11/%T/%N%S"
1358     if test x"${x_default_search_path}" = x; then
1359       x_default_search_path=${x_search_path}
1360     else
1361       x_default_search_path="${x_search_path}:${x_default_search_path}"
1362     fi
1363   done
1364 fi
1365 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1366
1367 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1368   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1369 fi
1370
1371 if test x"${x_includes}" = x; then
1372   bitmapdir=/usr/include/X11/bitmaps
1373 else
1374   # accumulate include directories that have X11 bitmap subdirectories
1375   bmd_acc="dummyval"
1376   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1377     if test -d "${bmd}/X11/bitmaps"; then
1378       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1379     fi
1380     if test -d "${bmd}/bitmaps"; then
1381       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1382     fi
1383   done
1384   if test ${bmd_acc} != "dummyval"; then
1385     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1386   fi
1387 fi
1388
1389 HAVE_NS=no
1390 NS_IMPL_COCOA=no
1391 NS_IMPL_GNUSTEP=no
1392 tmp_CPPFLAGS="$CPPFLAGS"
1393 tmp_CFLAGS="$CFLAGS"
1394 CPPFLAGS="$CPPFLAGS -x objective-c"
1395 CFLAGS="$CFLAGS -x objective-c"
1396 TEMACS_LDFLAGS2="\${LDFLAGS}"
1397 GNU_OBJC_CFLAGS=
1398 if test "${with_ns}" != no; then
1399   if test "${opsys}" = darwin; then
1400      NS_IMPL_COCOA=yes
1401      ns_appdir=`pwd`/nextstep/Emacs.app
1402      ns_appbindir=${ns_appdir}/Contents/MacOS
1403      ns_appresdir=${ns_appdir}/Contents/Resources
1404      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1405   elif test -f $GNUSTEP_CONFIG_FILE; then
1406      NS_IMPL_GNUSTEP=yes
1407      ns_appdir=`pwd`/nextstep/Emacs.app
1408      ns_appbindir=${ns_appdir}
1409      ns_appresdir=${ns_appdir}/Resources
1410      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1411      dnl FIXME sourcing this several times in subshells seems inefficient.
1412      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1413      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1414      dnl I seemed to need these as well with GNUstep-startup 0.25.
1415      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1416      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1417      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1418        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1419      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1420        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1421      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1422      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1423      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1424      LIB_STANDARD=
1425      START_FILES=
1426      TEMACS_LDFLAGS2=
1427      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1428      dnl If they had chosen to either define it or not, we could have
1429      dnl just used AC_CHECK_DECL here.
1430      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1431        emacs_cv_objc_exceptions,
1432 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1433 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1434 1;
1435 #else
1436 fail;
1437 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1438      if test $emacs_cv_objc_exceptions = yes; then
1439        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1440        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1441          [Define if GNUstep uses ObjC exceptions.])
1442        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1443      fi
1444   fi
1445
1446   dnl This is only used while we test the NS headers, it gets reset below.
1447   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1448
1449   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1450                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1451   files are missing or cannot be compiled.])])
1452   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1453                                      [NSInteger i;])],
1454                     ns_have_nsinteger=yes,
1455                     ns_have_nsinteger=no)
1456   if test $ns_have_nsinteger = yes; then
1457     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1458   fi
1459 fi
1460 AC_SUBST(TEMACS_LDFLAGS2)
1461
1462 INSTALL_ARCH_INDEP_EXTRA=install-etc
1463 ns_self_contained=no
1464 ns_frag=/dev/null
1465 NS_OBJ=
1466 NS_OBJC_OBJ=
1467 if test "${HAVE_NS}" = yes; then
1468   if test "$with_toolkit_scroll_bars" = "no"; then
1469     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1470   fi
1471
1472   window_system=nextstep
1473   with_xft=no
1474   # set up packaging dirs
1475   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1476      ns_self_contained=yes
1477      prefix=${ns_appresdir}
1478      exec_prefix=${ns_appbindir}
1479      dnl This one isn't really used, only archlibdir is.
1480      libexecdir="\${ns_appbindir}/libexec"
1481      archlibdir="\${ns_appbindir}/libexec"
1482      docdir="\${ns_appresdir}/etc"
1483      etcdir="\${ns_appresdir}/etc"
1484      dnl FIXME maybe set datarootdir instead.
1485      dnl That would also get applications, icons, man.
1486      infodir="\${ns_appresdir}/info"
1487      mandir="\${ns_appresdir}/man"
1488      lispdir="\${ns_appresdir}/lisp"
1489      leimdir="\${ns_appresdir}/leim"
1490      INSTALL_ARCH_INDEP_EXTRA=
1491   fi
1492   ns_frag=$srcdir/src/ns.mk
1493   NS_OBJ="fontset.o fringe.o image.o"
1494   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1495 fi
1496 CFLAGS="$tmp_CFLAGS"
1497 CPPFLAGS="$tmp_CPPFLAGS"
1498 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1499 AC_SUBST(ns_self_contained)
1500 AC_SUBST(NS_OBJ)
1501 AC_SUBST(NS_OBJC_OBJ)
1502 AC_SUBST(LIB_STANDARD)
1503 AC_SUBST_FILE(ns_frag)
1504
1505 case "${window_system}" in
1506   x11 )
1507     HAVE_X_WINDOWS=yes
1508     HAVE_X11=yes
1509     case "${with_x_toolkit}" in
1510       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1511       motif ) USE_X_TOOLKIT=MOTIF ;;
1512       gtk ) with_gtk=yes
1513 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1514 dnl USE_X_TOOLKIT is set.
1515             USE_X_TOOLKIT=none ;;
1516       gtk3 ) with_gtk3=yes
1517              USE_X_TOOLKIT=none ;;
1518       no ) USE_X_TOOLKIT=none ;;
1519 dnl If user did not say whether to use a toolkit, make this decision later:
1520 dnl use the toolkit if we have gtk, or X11R5 or newer.
1521       * ) USE_X_TOOLKIT=maybe ;;
1522     esac
1523   ;;
1524   nextstep | none )
1525     HAVE_X_WINDOWS=no
1526     HAVE_X11=no
1527     USE_X_TOOLKIT=none
1528   ;;
1529 esac
1530
1531 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1532    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1533    if test "$HAVE_XSERVER" = true ||
1534       test -n "$DISPLAY" ||
1535       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1536         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1537 were found.  You should install the relevant development files for X
1538 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1539 sure you have development files for image handling, i.e.
1540 tiff, gif, jpeg, png and xpm.
1541 If you are sure you want Emacs compiled without X window support, pass
1542   --without-x
1543 to configure.])
1544    fi
1545 fi
1546
1547 ### If we're using X11, we should use the X menu package.
1548 HAVE_MENUS=no
1549 case ${HAVE_X11} in
1550   yes ) HAVE_MENUS=yes ;;
1551 esac
1552
1553 # Does the opsystem file prohibit the use of the GNU malloc?
1554 # Assume not, until told otherwise.
1555 GNU_MALLOC=yes
1556
1557 AC_CACHE_CHECK(
1558   [whether malloc is Doug Lea style],
1559   [emacs_cv_var_doug_lea_malloc],
1560   [AC_LINK_IFELSE(
1561      [AC_LANG_PROGRAM(
1562         [[#include <malloc.h>
1563           static void hook (void) {}]],
1564         [[malloc_set_state (malloc_get_state ());
1565           __after_morecore_hook = hook;
1566           __malloc_initialize_hook = hook;]])],
1567      [emacs_cv_var_doug_lea_malloc=yes],
1568      [emacs_cv_var_doug_lea_malloc=no])])
1569 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1570
1571
1572 dnl See comments in aix4-2.h about maybe using system malloc there.
1573 system_malloc=no
1574 case "$opsys" in
1575   ## darwin ld insists on the use of malloc routines in the System framework.
1576   darwin|sol2-10) system_malloc=yes ;;
1577 esac
1578
1579 if test "${system_malloc}" = "yes"; then
1580   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1581   GNU_MALLOC=no
1582   GNU_MALLOC_reason="
1583     (The GNU allocators don't work with this system configuration.)"
1584   GMALLOC_OBJ=
1585   VMLIMIT_OBJ=
1586 else
1587   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1588   VMLIMIT_OBJ=vm-limit.o
1589 fi
1590 AC_SUBST(GMALLOC_OBJ)
1591 AC_SUBST(VMLIMIT_OBJ)
1592
1593 if test "$doug_lea_malloc" = "yes" ; then
1594   if test "$GNU_MALLOC" = yes ; then
1595     GNU_MALLOC_reason="
1596       (Using Doug Lea's new malloc from the GNU C Library.)"
1597   fi
1598   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1599             [Define to 1 if you are using the GNU C Library.])
1600
1601   ## Use mmap directly for allocating larger buffers.
1602   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1603   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1604   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1605   case "$opsys" in
1606     gnu*) REL_ALLOC=no ;;
1607   esac
1608 fi
1609
1610 if test x"${REL_ALLOC}" = x; then
1611   REL_ALLOC=${GNU_MALLOC}
1612 fi
1613
1614 use_mmap_for_buffers=no
1615 case "$opsys" in
1616   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1617 esac
1618
1619 AC_FUNC_MMAP
1620 if test $use_mmap_for_buffers = yes; then
1621   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1622   REL_ALLOC=no
1623 fi
1624
1625 LIBS="$LIBS_SYSTEM $LIBS"
1626
1627 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1628 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1629 AC_CHECK_LIB(dnet, dnet_ntoa)
1630 dnl This causes -lresolv to get used in subsequent tests,
1631 dnl which causes failures on some systems such as HPUX 9.
1632 dnl AC_CHECK_LIB(resolv, gethostbyname)
1633
1634 dnl FIXME replace main with a function we actually want from this library.
1635 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1636
1637 dnl Check if pthreads is available.
1638 LIB_PTHREAD=
1639 AC_CHECK_HEADERS_ONCE(pthread.h)
1640 if test "$ac_cv_header_pthread_h"; then
1641   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1642   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1643   dnl testing for pthread_self if Emacs uses gmalloc.c.
1644   if test "$GMALLOC_OBJ" = gmalloc.o; then
1645     emacs_pthread_function=pthread_atfork
1646   else
1647     emacs_pthread_function=pthread_self
1648   fi
1649   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1650 fi
1651 if test "$HAVE_PTHREAD" = yes; then
1652   case "${canonical}" in
1653     *-hpux*) ;;
1654     *) LIB_PTHREAD="-lpthread"
1655        LIBS="$LIB_PTHREAD $LIBS" ;;
1656   esac
1657   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1658 fi
1659 AC_SUBST([LIB_PTHREAD])
1660
1661 AC_CHECK_LIB(pthreads, cma_open)
1662
1663 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1664 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1665 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1666 ## added to LIBS in configure would never contain the pthreads part,
1667 ## but the value used in Makefiles might.  FIXME?
1668 ##
1669 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1670 ## be harmless on older versions of X where it happens to exist.
1671 test "$opsys" = "aix4-2" && \
1672   test $ac_cv_lib_pthreads_cma_open = yes && \
1673   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1674
1675 dnl Check for need for bigtoc support on IBM AIX
1676
1677 case ${host_os} in
1678 aix*)
1679   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1680     case $GCC in
1681     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1682     *) gdb_cv_bigtoc=-bbigtoc ;;
1683     esac
1684
1685     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1686     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1687   ])
1688   ;;
1689 esac
1690
1691 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1692 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1693 # REAL_CPPFLAGS later on.
1694
1695 REAL_CFLAGS="$CFLAGS"
1696 REAL_CPPFLAGS="$CPPFLAGS"
1697
1698 if test "${HAVE_X11}" = "yes"; then
1699   DEFS="$C_SWITCH_X_SITE $DEFS"
1700   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1701   LIBS="-lX11 $LIBS"
1702   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1703   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1704
1705   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1706   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1707   # but it's more convenient here to set LD_RUN_PATH since this
1708   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1709   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1710     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1711     export LD_RUN_PATH
1712   fi
1713
1714   if test "${opsys}" = "gnu-linux"; then
1715     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1716     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1717      [[XOpenDisplay ("foo");]])],
1718      [xgnu_linux_first_failure=no],
1719      [xgnu_linux_first_failure=yes])
1720     if test "${xgnu_linux_first_failure}" = "yes"; then
1721       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1722       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1723       OLD_CPPFLAGS="$CPPFLAGS"
1724       OLD_LIBS="$LIBS"
1725       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1726       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1727       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1728       LIBS="$LIBS -b i486-linuxaout"
1729       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1730        [[XOpenDisplay ("foo");]])],
1731        [xgnu_linux_second_failure=no],
1732        [xgnu_linux_second_failure=yes])
1733       if test "${xgnu_linux_second_failure}" = "yes"; then
1734         # If we get the same failure with -b, there is no use adding -b.
1735         # So take it out.  This plays safe.
1736         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1737         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1738         CPPFLAGS="$OLD_CPPFLAGS"
1739         LIBS="$OLD_LIBS"
1740         AC_MSG_RESULT(no)
1741       else
1742         AC_MSG_RESULT(yes)
1743       fi
1744     else
1745       AC_MSG_RESULT(no)
1746     fi
1747   fi
1748
1749   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1750   # header files included from there.
1751   AC_MSG_CHECKING(for Xkb)
1752   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1753 #include <X11/XKBlib.h>]],
1754         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1755         emacs_xkb=yes, emacs_xkb=no)
1756   AC_MSG_RESULT($emacs_xkb)
1757   if test $emacs_xkb = yes; then
1758     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1759   fi
1760
1761   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1762 XScreenNumberOfScreen)
1763 fi
1764
1765 if test "${window_system}" = "x11"; then
1766   AC_MSG_CHECKING(X11 version 6)
1767   AC_CACHE_VAL(emacs_cv_x11_version_6,
1768   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1769 [[#if XlibSpecificationRelease < 6
1770 fail;
1771 #endif
1772 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1773   if test $emacs_cv_x11_version_6 = yes; then
1774     AC_MSG_RESULT(6 or newer)
1775     AC_DEFINE(HAVE_X11R6, 1,
1776               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1777     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1778     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1779     ## XIM support.
1780     case "$opsys" in
1781       sol2-*) : ;;
1782       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1783            [Define if you have usable X11R6-style XIM support.])
1784          ;;
1785     esac
1786   else
1787     AC_MSG_RESULT(before 6)
1788   fi
1789 fi
1790
1791
1792 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1793 HAVE_RSVG=no
1794 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1795   if test "${with_rsvg}" != "no"; then
1796     RSVG_REQUIRED=2.11.0
1797     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1798
1799     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1800     AC_SUBST(RSVG_CFLAGS)
1801     AC_SUBST(RSVG_LIBS)
1802
1803     if test $HAVE_RSVG = yes; then
1804       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1805       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1806       LIBS="$RSVG_LIBS $LIBS"
1807     fi
1808   fi
1809 fi
1810
1811 HAVE_IMAGEMAGICK=no
1812 if test "${HAVE_X11}" = "yes"; then
1813   if test "${with_imagemagick}" != "no"; then
1814     ## 6.2.8 is the earliest version known to work, but earlier versions
1815     ## might work - let us know if you find one.
1816     ## 6.0.7 does not work.  See bug#7955.
1817     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1818     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1819     AC_SUBST(IMAGEMAGICK_CFLAGS)
1820     AC_SUBST(IMAGEMAGICK_LIBS)
1821
1822     if test $HAVE_IMAGEMAGICK = yes; then
1823       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1824       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1825       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1826       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1827     fi
1828   fi
1829 fi
1830
1831
1832 HAVE_GTK=no
1833 GTK_OBJ=
1834 if test "${with_gtk3}" = "yes"; then
1835   GLIB_REQUIRED=2.28
1836   GTK_REQUIRED=3.0
1837   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1838
1839   dnl Checks for libraries.
1840   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1841   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1842      AC_MSG_ERROR($GTK_PKG_ERRORS)
1843   fi
1844   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1845   GTK_OBJ=emacsgtkfixed.o
1846 fi
1847
1848 if test "$pkg_check_gtk" != "yes"; then
1849   HAVE_GTK=no
1850 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1851   GLIB_REQUIRED=2.10
1852   GTK_REQUIRED=2.10
1853   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1854
1855   dnl Checks for libraries.
1856   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1857   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1858      AC_MSG_ERROR($GTK_PKG_ERRORS)
1859   fi
1860 fi
1861 fi
1862
1863 if test x"$pkg_check_gtk" = xyes; then
1864
1865   AC_SUBST(GTK_CFLAGS)
1866   AC_SUBST(GTK_LIBS)
1867   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1868   CFLAGS="$CFLAGS $GTK_CFLAGS"
1869   LIBS="$GTK_LIBS $LIBS"
1870   dnl Try to compile a simple GTK program.
1871   GTK_COMPILES=no
1872   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1873   if test "${GTK_COMPILES}" != "yes"; then
1874     if test "$USE_X_TOOLKIT" != "maybe"; then
1875       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1876     fi
1877   else
1878     HAVE_GTK=yes
1879     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1880     GTK_OBJ="gtkutil.o $GTK_OBJ"
1881     USE_X_TOOLKIT=none
1882     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1883       :
1884     else
1885       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1886        closing open displays.  This is no problem if you just use
1887        one display, but if you use more than one and close one of them
1888        Emacs may crash.]])
1889       sleep 3
1890     fi
1891   fi
1892
1893 fi
1894 AC_SUBST(GTK_OBJ)
1895
1896
1897 if test "${HAVE_GTK}" = "yes"; then
1898
1899   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1900   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1901   if test "$with_toolkit_scroll_bars" != no; then
1902     with_toolkit_scroll_bars=yes
1903   fi
1904
1905   dnl  Check if we have the old file selection dialog declared and
1906   dnl  in the link library.  In 2.x it may be in the library,
1907   dnl  but not declared if deprecated featured has been selected out.
1908   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1909   HAVE_GTK_FILE_SELECTION=no
1910   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1911                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1912 #include <gtk/gtk.h>])
1913   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1914     AC_CHECK_FUNCS(gtk_file_selection_new)
1915   fi
1916
1917
1918   dnl Check for functions introduced in 2.14 and later.
1919   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1920                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1921                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1922                  gtk_orientable_set_orientation \
1923                  gtk_window_set_has_resize_grip)
1924 fi
1925
1926 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1927 dnl other platforms.
1928 HAVE_DBUS=no
1929 DBUS_OBJ=
1930 if test "${with_dbus}" = "yes"; then
1931    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1932    if test "$HAVE_DBUS" = yes; then
1933      LIBS="$LIBS $DBUS_LIBS"
1934      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1935      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1936      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1937      dnl D-Bus 1.5.12.
1938      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1939                     dbus_type_is_valid \
1940                     dbus_validate_bus_name \
1941                     dbus_validate_path \
1942                     dbus_validate_interface \
1943                     dbus_validate_member)
1944      DBUS_OBJ=dbusbind.o
1945    fi
1946 fi
1947 AC_SUBST(DBUS_OBJ)
1948
1949 dnl GSettings has been tested under GNU/Linux only.
1950 HAVE_GSETTINGS=no
1951 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1952    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1953    if test "$HAVE_GSETTINGS" = "yes"; then
1954       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1955       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1956       SETTINGS_LIBS="$GSETTINGS_LIBS"
1957    fi
1958 fi
1959
1960 dnl GConf has been tested under GNU/Linux only.
1961 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1962 HAVE_GCONF=no
1963 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1964    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1965    if test "$HAVE_GCONF" = yes; then
1966       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1967       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1968       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1969       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
1970    fi
1971 fi
1972
1973 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
1974     SAVE_CFLAGS="$CFLAGS"
1975     SAVE_LIBS="$LIBS"
1976     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
1977     LIBS="$SETTINGS_LIBS $LIBS"
1978     AC_CHECK_FUNCS([g_type_init])
1979     CFLAGS="$SAVE_CFLAGS"
1980     LIBS="$SAVE_LIBS"
1981 fi
1982 AC_SUBST(SETTINGS_CFLAGS)
1983 AC_SUBST(SETTINGS_LIBS)
1984
1985
1986 dnl SELinux is available for GNU/Linux only.
1987 HAVE_LIBSELINUX=no
1988 LIBSELINUX_LIBS=
1989 if test "${with_selinux}" = "yes"; then
1990    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1991    if test "$HAVE_LIBSELINUX" = yes; then
1992       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1993       LIBSELINUX_LIBS=-lselinux
1994    fi
1995 fi
1996 AC_SUBST(LIBSELINUX_LIBS)
1997
1998 HAVE_GNUTLS=no
1999 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2000 if test "${with_gnutls}" = "yes" ; then
2001   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2002   if test "${HAVE_GNUTLS}" = "yes"; then
2003     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2004   fi
2005
2006   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2007   LIBS="$LIBGNUTLS_LIBS $LIBS"
2008   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2009
2010   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2011     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2012   fi
2013 fi
2014
2015 AC_SUBST(LIBGNUTLS_LIBS)
2016 AC_SUBST(LIBGNUTLS_CFLAGS)
2017
2018 dnl Do not put whitespace before the #include statements below.
2019 dnl Older compilers (eg sunos4 cc) choke on it.
2020 HAVE_XAW3D=no
2021 LUCID_LIBW=
2022 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2023   if test "$with_xaw3d" != no; then
2024     AC_MSG_CHECKING(for xaw3d)
2025     AC_CACHE_VAL(emacs_cv_xaw3d,
2026     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2027 #include <X11/Intrinsic.h>
2028 #include <X11/Xaw3d/Simple.h>]],
2029       [[]])],
2030       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2031                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2032       emacs_cv_xaw3d=no)])
2033   else
2034     emacs_cv_xaw3d=no
2035   fi
2036   if test $emacs_cv_xaw3d = yes; then
2037     AC_MSG_RESULT([yes; using Lucid toolkit])
2038     USE_X_TOOLKIT=LUCID
2039     HAVE_XAW3D=yes
2040     LUCID_LIBW=-lXaw3d
2041     AC_DEFINE(HAVE_XAW3D, 1,
2042               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2043   else
2044     AC_MSG_RESULT(no)
2045     AC_MSG_CHECKING(for libXaw)
2046     AC_CACHE_VAL(emacs_cv_xaw,
2047     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2048 #include <X11/Intrinsic.h>
2049 #include <X11/Xaw/Simple.h>]],
2050       [[]])],
2051       emacs_cv_xaw=yes,
2052       emacs_cv_xaw=no)])
2053     if test $emacs_cv_xaw = yes; then
2054       AC_MSG_RESULT([yes; using Lucid toolkit])
2055       USE_X_TOOLKIT=LUCID
2056       LUCID_LIBW=-lXaw
2057     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2058       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2059     else
2060       AC_MSG_ERROR([No X toolkit could be found.
2061 If you are sure you want Emacs compiled without an X toolkit, pass
2062   --with-x-toolkit=no
2063 to configure.  Otherwise, install the development libraries for the toolkit
2064 that you want to use (e.g. Gtk+) and re-run configure.])
2065     fi
2066   fi
2067 fi
2068
2069 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2070
2071 LIBXTR6=
2072 if test "${USE_X_TOOLKIT}" != "none"; then
2073   AC_MSG_CHECKING(X11 toolkit version)
2074   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2075   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2076 [[#if XtSpecificationRelease < 6
2077 fail;
2078 #endif
2079 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2080   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2081   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2082     AC_MSG_RESULT(6 or newer)
2083     AC_DEFINE(HAVE_X11XTR6, 1,
2084               [Define to 1 if you have the X11R6 or newer version of Xt.])
2085     LIBXTR6="-lSM -lICE"
2086     case "$opsys" in
2087       ## Use libw.a along with X11R6 Xt.
2088       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2089     esac
2090   else
2091     AC_MSG_RESULT(before 6)
2092   fi
2093
2094 dnl If using toolkit, check whether libXmu.a exists.
2095 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2096   OLDLIBS="$LIBS"
2097   if test x$HAVE_X11XTR6 = xyes; then
2098     LIBS="-lXt -lSM -lICE $LIBS"
2099   else
2100     LIBS="-lXt $LIBS"
2101   fi
2102   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2103   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2104 fi
2105 AC_SUBST(LIBXTR6)
2106
2107 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2108 dnl Why not just test for libxmu in the normal way?
2109 LIBXMU=-lXmu
2110 case $opsys in
2111   ## These systems don't supply Xmu.
2112   hpux* | aix4-2 )
2113     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2114     ;;
2115 esac
2116 AC_SUBST(LIBXMU)
2117
2118 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2119 if test "${HAVE_X11}" = "yes"; then
2120   if test "${USE_X_TOOLKIT}" != "none"; then
2121     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2122   fi
2123 fi
2124
2125 LIBXP=
2126 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2127   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2128   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2129     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2130 int x = 5;
2131 #else
2132 Motif version prior to 2.1.
2133 #endif]])],
2134     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2135   if test $emacs_cv_motif_version_2_1 = yes; then
2136     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2137   else
2138     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2139     # We put this in CFLAGS temporarily to precede other -I options
2140     # that might be in CFLAGS temporarily.
2141     # We put this in CPPFLAGS where it precedes the other -I options.
2142     OLD_CPPFLAGS=$CPPFLAGS
2143     OLD_CFLAGS=$CFLAGS
2144     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2145     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2146     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2147       [[int x = 5;]])],
2148       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2149     if test $emacs_cv_lesstif = yes; then
2150       # Make sure this -I option remains in CPPFLAGS after it is set
2151       # back to REAL_CPPFLAGS.
2152       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2153       # have those other -I options anyway.  Ultimately, having this
2154       # directory ultimately in CPPFLAGS will be enough.
2155       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2156       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2157     else
2158       CFLAGS=$OLD_CFLAGS
2159       CPPFLAGS=$OLD_CPPFLAGS
2160     fi
2161   fi
2162   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2163     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2164 fi
2165
2166 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2167 dnl using Motif or Xaw3d is available, and unless
2168 dnl --with-toolkit-scroll-bars=no was specified.
2169
2170 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2171             [Define to 1 if we should use toolkit scroll bars.])dnl
2172 USE_TOOLKIT_SCROLL_BARS=no
2173 if test "${with_toolkit_scroll_bars}" != "no"; then
2174   if test "${USE_X_TOOLKIT}" != "none"; then
2175     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2176       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2177       HAVE_XAW3D=no
2178       USE_TOOLKIT_SCROLL_BARS=yes
2179     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2180       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2181       USE_TOOLKIT_SCROLL_BARS=yes
2182     fi
2183   elif test "${HAVE_GTK}" = "yes"; then
2184     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2185     USE_TOOLKIT_SCROLL_BARS=yes
2186   elif test "${HAVE_NS}" = "yes"; then
2187     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2188     USE_TOOLKIT_SCROLL_BARS=yes
2189   fi
2190 fi
2191
2192 dnl See if XIM is available.
2193 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2194           #include <X11/Xlib.h>
2195           #include <X11/Xresource.h>]],
2196          [[XIMProc  callback;]])],
2197          [HAVE_XIM=yes
2198          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2199          HAVE_XIM=no)
2200
2201 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2202
2203 if test "${with_xim}" != "no"; then
2204   AC_DEFINE(USE_XIM, 1,
2205             [Define to 1 if we should use XIM, if it is available.])
2206 fi
2207
2208
2209 if test "${HAVE_XIM}" != "no"; then
2210   late_CFLAGS=$CFLAGS
2211   if test "$GCC" = yes; then
2212     CFLAGS="$CFLAGS --pedantic-errors"
2213   fi
2214   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2215 #include <X11/Xlib.h>
2216 #include <X11/Xresource.h>]],
2217 [[Display *display;
2218 XrmDatabase db;
2219 char *res_name;
2220 char *res_class;
2221 XIMProc  callback;
2222 XPointer *client_data;
2223 #ifndef __GNUC__
2224 /* If we're not using GCC, it's probably not XFree86, and this is
2225    probably right, but we can't use something like --pedantic-errors.  */
2226 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2227                                            char*, XIMProc, XPointer*);
2228 #endif
2229 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2230    client_data);]])],
2231     [emacs_cv_arg6_star=yes])
2232   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2233          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2234 either XPointer or XPointer*.])dnl
2235   if test "$emacs_cv_arg6_star" = yes; then
2236     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2237   else
2238     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2239   fi
2240   CFLAGS=$late_CFLAGS
2241 fi
2242
2243 ### Start of font-backend (under any platform) section.
2244 # (nothing here yet -- this is a placeholder)
2245 ### End of font-backend (under any platform) section.
2246
2247 ### Start of font-backend (under X11) section.
2248 if test "${HAVE_X11}" = "yes"; then
2249    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2250
2251    ## Use -lXft if available, unless `--with-xft=no'.
2252    HAVE_XFT=maybe
2253     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2254       with_xft="no";
2255     fi
2256     if test "x${with_xft}" != "xno"; then
2257
2258       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2259       ## Because xftfont.c uses XRenderQueryExtension, we also
2260       ## need to link to -lXrender.
2261       HAVE_XRENDER=no
2262       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2263       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2264         OLD_CPPFLAGS="$CPPFLAGS"
2265         OLD_CFLAGS="$CFLAGS"
2266         OLD_LIBS="$LIBS"
2267         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2268         CFLAGS="$CFLAGS $XFT_CFLAGS"
2269         XFT_LIBS="-lXrender $XFT_LIBS"
2270         LIBS="$XFT_LIBS $LIBS"
2271         AC_CHECK_HEADER(X11/Xft/Xft.h,
2272           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2273
2274         if test "${HAVE_XFT}" = "yes"; then
2275           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2276             AC_SUBST(XFT_LIBS)
2277           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2278         else
2279           CPPFLAGS="$OLD_CPPFLAGS"
2280           CFLAGS="$OLD_CFLAGS"
2281           LIBS="$OLD_LIBS"
2282         fi                        # "${HAVE_XFT}" = "yes"
2283       fi                          # "$HAVE_XFT" != no
2284     fi                            # "x${with_xft}" != "xno"
2285
2286     ## We used to allow building with FreeType and without Xft.
2287     ## However, the ftx font backend driver is not in good shape.
2288     if test "$HAVE_XFT" != "yes"; then
2289        dnl For the "Does Emacs use" message at the end.
2290        HAVE_XFT=no
2291        HAVE_FREETYPE=no
2292     else
2293        dnl Strict linkers fail with
2294        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2295        dnl if -lfreetype is not specified.
2296        dnl The following is needed to set FREETYPE_LIBS.
2297        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2298                          HAVE_FREETYPE=no)
2299
2300        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2301     fi
2302
2303     HAVE_LIBOTF=no
2304     if test "${HAVE_FREETYPE}" = "yes"; then
2305       AC_DEFINE(HAVE_FREETYPE, 1,
2306                 [Define to 1 if using the freetype and fontconfig libraries.])
2307       if test "${with_libotf}" != "no"; then
2308         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2309                           HAVE_LIBOTF=no)
2310         if test "$HAVE_LIBOTF" = "yes"; then
2311           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2312           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2313                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2314                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2315           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2316             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2317                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2318           fi
2319         fi
2320       fi
2321     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2322     dnl Does the new font backend require it, or can it work without it?
2323     fi
2324
2325     HAVE_M17N_FLT=no
2326     if test "${HAVE_LIBOTF}" = yes; then
2327       if test "${with_m17n_flt}" != "no"; then
2328         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2329         if test "$HAVE_M17N_FLT" = "yes"; then
2330           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2331         fi
2332       fi
2333     fi
2334 else
2335     HAVE_XFT=no
2336     HAVE_FREETYPE=no
2337     HAVE_LIBOTF=no
2338     HAVE_M17N_FLT=no
2339 fi
2340
2341 ### End of font-backend (under X11) section.
2342
2343 AC_SUBST(FREETYPE_CFLAGS)
2344 AC_SUBST(FREETYPE_LIBS)
2345 AC_SUBST(FONTCONFIG_CFLAGS)
2346 AC_SUBST(FONTCONFIG_LIBS)
2347 AC_SUBST(LIBOTF_CFLAGS)
2348 AC_SUBST(LIBOTF_LIBS)
2349 AC_SUBST(M17N_FLT_CFLAGS)
2350 AC_SUBST(M17N_FLT_LIBS)
2351
2352 ### Use -lXpm if available, unless `--with-xpm=no'.
2353 HAVE_XPM=no
2354 LIBXPM=
2355 if test "${HAVE_X11}" = "yes"; then
2356   if test "${with_xpm}" != "no"; then
2357     AC_CHECK_HEADER(X11/xpm.h,
2358       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2359     if test "${HAVE_XPM}" = "yes"; then
2360       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2361       AC_EGREP_CPP(no_return_alloc_pixels,
2362       [#include "X11/xpm.h"
2363 #ifndef XpmReturnAllocPixels
2364 no_return_alloc_pixels
2365 #endif
2366       ], HAVE_XPM=no, HAVE_XPM=yes)
2367
2368       if test "${HAVE_XPM}" = "yes"; then
2369         AC_MSG_RESULT(yes)
2370       else
2371         AC_MSG_RESULT(no)
2372       fi
2373     fi
2374   fi
2375
2376   if test "${HAVE_XPM}" = "yes"; then
2377     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2378     LIBXPM=-lXpm
2379   fi
2380 fi
2381 AC_SUBST(LIBXPM)
2382
2383 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2384 HAVE_JPEG=no
2385 LIBJPEG=
2386 if test "${HAVE_X11}" = "yes"; then
2387   if test "${with_jpeg}" != "no"; then
2388     dnl Checking for jpeglib.h can lose because of a redefinition of
2389     dnl  HAVE_STDLIB_H.
2390     AC_CHECK_HEADER(jerror.h,
2391       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2392   fi
2393
2394   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2395   if test "${HAVE_JPEG}" = "yes"; then
2396     AC_DEFINE(HAVE_JPEG)
2397     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2398         [#include <jpeglib.h>
2399          version=JPEG_LIB_VERSION
2400 ],
2401         [AC_DEFINE(HAVE_JPEG)],
2402         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2403         HAVE_JPEG=no])
2404   fi
2405   if test "${HAVE_JPEG}" = "yes"; then
2406     LIBJPEG=-ljpeg
2407   fi
2408 fi
2409 AC_SUBST(LIBJPEG)
2410
2411 ### Use -lpng if available, unless `--with-png=no'.
2412 HAVE_PNG=no
2413 LIBPNG=
2414 if test "${HAVE_X11}" = "yes"; then
2415   if test "${with_png}" != "no"; then
2416     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2417     # in /usr/include/libpng.
2418     AC_CHECK_HEADERS(png.h libpng/png.h)
2419     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2420       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2421     fi
2422   fi
2423
2424   if test "${HAVE_PNG}" = "yes"; then
2425     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2426     LIBPNG="-lpng -lz -lm"
2427   fi
2428 fi
2429 AC_SUBST(LIBPNG)
2430
2431 ### Use -ltiff if available, unless `--with-tiff=no'.
2432 HAVE_TIFF=no
2433 LIBTIFF=
2434 if test "${HAVE_X11}" = "yes"; then
2435   if test "${with_tiff}" != "no"; then
2436     AC_CHECK_HEADER(tiffio.h,
2437       [tifflibs="-lz -lm"
2438       # At least one tiff package requires the jpeg library.
2439       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2440       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2441   fi
2442
2443   if test "${HAVE_TIFF}" = "yes"; then
2444     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2445     dnl FIXME -lz -lm, as per libpng?
2446     LIBTIFF=-ltiff
2447   fi
2448 fi
2449 AC_SUBST(LIBTIFF)
2450
2451 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2452 HAVE_GIF=no
2453 LIBGIF=
2454 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2455   AC_CHECK_HEADER(gif_lib.h,
2456 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2457 # Earlier versions can crash Emacs.
2458     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2459
2460   if test "$HAVE_GIF" = yes; then
2461     LIBGIF=-lgif
2462   elif test "$HAVE_GIF" = maybe; then
2463 # If gif_lib.h but no libgif, try libungif.
2464     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2465     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2466   fi
2467
2468   if test "${HAVE_GIF}" = "yes"; then
2469     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2470   fi
2471 fi
2472 AC_SUBST(LIBGIF)
2473
2474 dnl Check for required libraries.
2475 if test "${HAVE_X11}" = "yes"; then
2476   MISSING=""
2477   WITH_NO=""
2478   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2479     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2480   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2481     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2482   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2483     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2484   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2485     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2486   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2487     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2488
2489   if test "X${MISSING}" != X; then
2490     AC_MSG_ERROR([The following required libraries were not found:
2491     $MISSING
2492 Maybe some development libraries/packages are missing?
2493 If you don't want to link with them give
2494     $WITH_NO
2495 as options to configure])
2496   fi
2497 fi
2498
2499 ### Use -lgpm if available, unless `--with-gpm=no'.
2500 HAVE_GPM=no
2501 LIBGPM=
2502 if test "${with_gpm}" != "no"; then
2503   AC_CHECK_HEADER(gpm.h,
2504     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2505
2506   if test "${HAVE_GPM}" = "yes"; then
2507     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2508     LIBGPM=-lgpm
2509   fi
2510 fi
2511 AC_SUBST(LIBGPM)
2512
2513 dnl Check for malloc/malloc.h on darwin
2514 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2515
2516 GNUSTEP_CFLAGS=
2517 ### Use NeXTstep API to implement GUI.
2518 if test "${HAVE_NS}" = "yes"; then
2519   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2520   if test "${NS_IMPL_COCOA}" = "yes"; then
2521     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2522   fi
2523   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2524     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2525     # See also .m.o rule in Makefile.in */
2526     # FIXME: are all these flags really needed?  Document here why.  */
2527     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2528     ## Extra CFLAGS applied to src/*.m files.
2529     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2530   fi
2531   # We also have mouse menus.
2532   HAVE_MENUS=yes
2533   OTHER_FILES=ns-app
2534 fi
2535
2536
2537 ### Use session management (-lSM -lICE) if available
2538 HAVE_X_SM=no
2539 LIBXSM=
2540 if test "${HAVE_X11}" = "yes"; then
2541   AC_CHECK_HEADER(X11/SM/SMlib.h,
2542     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2543
2544   if test "${HAVE_X_SM}" = "yes"; then
2545     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2546     LIBXSM="-lSM -lICE"
2547     case "$LIBS" in
2548       *-lSM*) ;;
2549       *)      LIBS="$LIBXSM $LIBS" ;;
2550     esac
2551   fi
2552 fi
2553 AC_SUBST(LIBXSM)
2554
2555 ### Use libxml (-lxml2) if available
2556 HAVE_LIBXML2=no
2557 if test "${with_xml2}" != "no"; then
2558   ### I'm not sure what the version number should be, so I just guessed.
2559   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2560   if test "${HAVE_LIBXML2}" = "yes"; then
2561     LIBS="$LIBXML2_LIBS $LIBS"
2562     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2563     if test "${HAVE_LIBXML2}" = "yes"; then
2564       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2565     else
2566       LIBXML2_LIBS=""
2567       LIBXML2_CFLAGS=""
2568     fi
2569   fi
2570 fi
2571 AC_SUBST(LIBXML2_LIBS)
2572 AC_SUBST(LIBXML2_CFLAGS)
2573
2574 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2575 AC_CACHE_CHECK(whether netdb declares h_errno,
2576                emacs_cv_netdb_declares_h_errno,
2577 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2578   [[return h_errno;]])],
2579   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2580 if test $emacs_cv_netdb_declares_h_errno = yes; then
2581   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2582 fi
2583
2584 # fmod, logb, and frexp are found in -lm on most systems.
2585 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2586 AC_CHECK_LIB(m, sqrt)
2587
2588 # Check for mail-locking functions in a "mail" library.  Probably this should
2589 # have the same check as for liblockfile below.
2590 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2591 if test $have_mail = yes; then
2592   LIBS_MAIL=-lmail
2593   LIBS="$LIBS_MAIL $LIBS"
2594   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2595 else
2596   LIBS_MAIL=
2597 fi
2598 dnl Debian, at least:
2599 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2600 if test $have_lockfile = yes; then
2601    LIBS_MAIL=-llockfile
2602    LIBS="$LIBS_MAIL $LIBS"
2603    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2604 else
2605 # If we have the shared liblockfile, assume we must use it for mail
2606 # locking (e.g. Debian).  If we couldn't link against liblockfile
2607 # (no liblockfile.a installed), ensure that we don't need to.
2608   dnl This works for files generally, not just executables.
2609   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2610   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2611                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2612   if test $ac_cv_prog_liblockfile = yes; then
2613     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2614 This probably means that movemail could lose mail.
2615 There may be a `development' package to install containing liblockfile.])
2616   fi
2617 fi
2618 AC_CHECK_HEADERS_ONCE(maillock.h)
2619 AC_SUBST(LIBS_MAIL)
2620
2621 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2622 ## interlock access to the mail spool.  The alternative is a lock file named
2623 ## /usr/spool/mail/$USER.lock.
2624 mail_lock=no
2625 case "$opsys" in
2626   aix4-2) mail_lock="lockf" ;;
2627
2628   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2629
2630   ## On GNU/Linux systems, both methods are used by various mail programs.
2631   ## I assume most people are using newer mailers that have heard of flock.
2632   ## Change this if you need to.
2633   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2634   ## configure gets the right answers, and that means *NOT* using flock.
2635   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2636   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2637   ## Debian maintainer hasn't provided a clean fix for Emacs.
2638   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2639   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2640   ## correct logic.  -- fx
2641   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2642   ## liblockfile is a Free Software replacement for libmail, used on
2643   ## Debian systems and elsewhere. -rfr.
2644   gnu-*)
2645     mail_lock="flock"
2646     if test $have_mail = yes || test $have_lockfile = yes; then
2647       test $ac_cv_header_maillock_h = yes && mail_lock=no
2648     fi
2649     ;;
2650 esac
2651
2652 BLESSMAIL_TARGET=
2653 case "$mail_lock" in
2654   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2655
2656   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2657
2658   *) BLESSMAIL_TARGET="need-blessmail" ;;
2659 esac
2660 AC_SUBST(BLESSMAIL_TARGET)
2661
2662
2663 AC_CHECK_FUNCS(gethostname \
2664 rename closedir mkdir rmdir getrusage get_current_dir_name \
2665 random lrand48 logb frexp fmod rint cbrt setsid \
2666 strerror fpathconf select euidaccess getpagesize setlocale \
2667 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2668 __fpending strsignal setitimer \
2669 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2670 gai_strerror mkstemp getline getdelim fsync sync \
2671 difftime posix_memalign \
2672 getpwent endpwent getgrent endgrent \
2673 touchlock \
2674 cfmakeraw cfsetspeed copysign __executable_start)
2675
2676 dnl Cannot use AC_CHECK_FUNCS
2677 AC_CACHE_CHECK([for __builtin_unwind_init],
2678                emacs_cv_func___builtin_unwind_init,
2679 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2680                 emacs_cv_func___builtin_unwind_init=yes,
2681                 emacs_cv_func___builtin_unwind_init=no)])
2682 if test $emacs_cv_func___builtin_unwind_init = yes; then
2683   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2684             [Define to 1 if you have the `__builtin_unwind_init' function.])
2685 fi
2686
2687 AC_CHECK_HEADERS_ONCE(sys/un.h)
2688
2689 AC_FUNC_FSEEKO
2690
2691 AC_FUNC_GETPGRP
2692
2693 # UNIX98 PTYs.
2694 AC_CHECK_FUNCS(grantpt)
2695
2696 # PTY-related GNU extensions.
2697 AC_CHECK_FUNCS(getpt)
2698
2699 # Check this now, so that we will NOT find the above functions in ncurses.
2700 # That is because we have not set up to link ncurses in lib-src.
2701 # It's better to believe a function is not available
2702 # than to expect to find it in ncurses.
2703 # Also we need tputs and friends to be able to build at all.
2704 AC_MSG_CHECKING([for library containing tputs])
2705 # Run a test program that contains a call to tputs, a call that is
2706 # never executed.  This tests whether a pre-'main' dynamic linker
2707 # works with the library.  It's too much trouble to actually call
2708 # tputs in the test program, due to portability hassles.  When
2709 # cross-compiling, assume the test program will run if it links.
2710 AC_DEFUN([tputs_link_source], [
2711   AC_LANG_SOURCE(
2712      [[extern void tputs (const char *, int, int (*)(int));
2713        int main (int argc, char **argv)
2714        {
2715           if (argc == 10000)
2716             tputs (argv[0], 0, 0);
2717           return 0;
2718        }]])
2719 ])
2720 # Maybe curses should be tried earlier?
2721 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2722 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2723   OLIBS=$LIBS
2724   if test -z "$tputs_library"; then
2725     LIBS_TERMCAP=
2726     msg='none required'
2727   else
2728     LIBS_TERMCAP=-l$tputs_library
2729     msg=$LIBS_TERMCAP
2730     LIBS="$LIBS_TERMCAP $LIBS"
2731   fi
2732   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2733     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2734   LIBS=$OLIBS
2735   if test "X$msg" != Xno; then
2736     break
2737   fi
2738 done
2739 AC_MSG_RESULT([$msg])
2740 if test "X$msg" = Xno; then
2741   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2742 The following libraries were tried (in order):
2743   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2744 Please try installing whichever of these libraries is most appropriate
2745 for your system, together with its header files.
2746 For example, a libncurses-dev(el) or similar package.])
2747 fi
2748
2749 ## Use termcap instead of terminfo?
2750 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2751 TERMINFO=yes
2752 ## FIXME?  In the cases below where we unconditionally set
2753 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2754 ## if that was found above to have tputs.
2755 ## Should we use the gnu* logic everywhere?
2756 case "$opsys" in
2757   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2758   ##  The ncurses library has been moved out of the System framework in
2759   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2760   ##  option to use it.
2761   darwin) LIBS_TERMCAP="-lncurses" ;;
2762
2763   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2764
2765   freebsd)
2766     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2767     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2768     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2769 [[#if __FreeBSD_version < 400000
2770 fail;
2771 #endif
2772 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2773
2774     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2775
2776     if test $emacs_cv_freebsd_terminfo = yes; then
2777       LIBS_TERMCAP="-lncurses"
2778     else
2779       TERMINFO=no
2780       LIBS_TERMCAP="-ltermcap"
2781     fi
2782     ;;
2783
2784   netbsd)
2785     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2786       TERMINFO=no
2787       LIBS_TERMCAP="-ltermcap"
2788     fi
2789     ;;
2790
2791   openbsd) LIBS_TERMCAP="-lncurses" ;;
2792
2793   ## hpux: Make sure we get select from libc rather than from libcurses
2794   ##  because libcurses on HPUX 10.10 has a broken version of select.
2795   ##  We used to use -lc -lcurses, but this may be cleaner.
2796   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2797   # set that way, now it uses the default).  Isn't this a contradiction?
2798   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2799
2800 esac
2801
2802 TERMCAP_OBJ=tparam.o
2803 if test $TERMINFO = yes; then
2804   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2805   TERMCAP_OBJ=terminfo.o
2806 fi
2807 AC_SUBST(LIBS_TERMCAP)
2808 AC_SUBST(TERMCAP_OBJ)
2809
2810
2811 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2812 resolv=no
2813 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2814 #include <arpa/nameser.h>
2815 #include <resolv.h>]],
2816     [[return res_init();]])],
2817     have_res_init=yes, have_res_init=no)
2818 if test "$have_res_init" = no; then
2819   OLIBS="$LIBS"
2820   LIBS="$LIBS -lresolv"
2821   AC_MSG_CHECKING(for res_init with -lresolv)
2822   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2823 #include <arpa/nameser.h>
2824 #include <resolv.h>]],
2825     [[return res_init();]])],
2826     have_res_init=yes, have_res_init=no)
2827   AC_MSG_RESULT($have_res_init)
2828   if test "$have_res_init" = yes ; then
2829     resolv=yes
2830   fi
2831   LIBS="$OLIBS"
2832 fi
2833
2834 if test "$have_res_init" = yes; then
2835   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2836 fi
2837
2838 # Do we need the Hesiod library to provide the support routines?
2839 LIBHESIOD=
2840 if test "$with_hesiod" != no ; then
2841   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2842   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2843      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2844                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2845   if test "$resolv" = yes ; then
2846     RESOLVLIB=-lresolv
2847   else
2848     RESOLVLIB=
2849   fi
2850   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2851         hesiod=yes, :, $RESOLVLIB)])
2852
2853   if test x"$hesiod" = xyes; then
2854     AC_DEFINE(HAVE_LIBHESIOD, 1,
2855               [Define to 1 if you have the hesiod library (-lhesiod).])
2856     LIBHESIOD=-lhesiod
2857   fi
2858 fi
2859 AC_SUBST(LIBHESIOD)
2860
2861 # Do we need libresolv (due to res_init or Hesiod)?
2862 if test "$resolv" = yes ; then
2863   AC_DEFINE(HAVE_LIBRESOLV, 1,
2864             [Define to 1 if you have the resolv library (-lresolv).])
2865   LIBRESOLV=-lresolv
2866 else
2867   LIBRESOLV=
2868 fi
2869 AC_SUBST(LIBRESOLV)
2870
2871 # These tell us which Kerberos-related libraries to use.
2872 COM_ERRLIB=
2873 CRYPTOLIB=
2874 KRB5LIB=
2875 DESLIB=
2876 KRB4LIB=
2877
2878 if test "${with_kerberos}" != no; then
2879   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2880   if test $have_com_err = yes; then
2881     COM_ERRLIB=-lcom_err
2882     LIBS="$COM_ERRLIB $LIBS"
2883     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2884   fi
2885   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2886   if test $have_crypto = yes; then
2887     CRYPTOLIB=-lcrypto
2888     LIBS="$CRYPTOLIB $LIBS"
2889     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2890   fi
2891   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2892   if test $have_k5crypto = yes; then
2893     CRYPTOLIB=-lk5crypto
2894     LIBS="$CRYPTOLIB $LIBS"
2895     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2896   fi
2897   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2898   if test $have_krb5=yes; then
2899     KRB5LIB=-lkrb5
2900     LIBS="$KRB5LIB $LIBS"
2901     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2902   fi
2903   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2904   if test "${with_kerberos5}" = no; then
2905     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2906     if test $have_des425 = yes; then
2907       DESLIB=-ldes425
2908       LIBS="$DESLIB $LIBS"
2909       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2910     else
2911       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2912       if test $have_des = yes; then
2913         DESLIB=-ldes
2914         LIBS="$DESLIB $LIBS"
2915         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2916       fi
2917     fi
2918     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2919     if test $have_krb4 = yes; then
2920       KRB4LIB=-lkrb4
2921       LIBS="$KRB4LIB $LIBS"
2922       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2923     else
2924       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2925       if test $have_krb = yes; then
2926         KRB4LIB=-lkrb
2927         LIBS="$KRB4LIB $LIBS"
2928         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2929       fi
2930     fi
2931   fi
2932
2933   if test "${with_kerberos5}" != no; then
2934     AC_CHECK_HEADERS(krb5.h,
2935       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2936                         [#include <krb5.h>])])
2937   else
2938     AC_CHECK_HEADERS(des.h,,
2939                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2940                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2941     AC_CHECK_HEADERS(krb.h,,
2942                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2943                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2944   fi
2945   AC_CHECK_HEADERS(com_err.h)
2946 fi
2947
2948 AC_SUBST(COM_ERRLIB)
2949 AC_SUBST(CRYPTOLIB)
2950 AC_SUBST(KRB5LIB)
2951 AC_SUBST(DESLIB)
2952 AC_SUBST(KRB4LIB)
2953
2954 AC_CHECK_FUNCS(tzset)
2955 AC_MSG_CHECKING(whether localtime caches TZ)
2956 AC_CACHE_VAL(emacs_cv_localtime_cache,
2957 [if test x$ac_cv_func_tzset = xyes; then
2958 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2959 char TZ_GMT0[] = "TZ=GMT0";
2960 char TZ_PST8[] = "TZ=PST8";
2961 main()
2962 {
2963   time_t now = time ((time_t *) 0);
2964   int hour_GMT0, hour_unset;
2965   if (putenv (TZ_GMT0) != 0)
2966     exit (1);
2967   hour_GMT0 = localtime (&now)->tm_hour;
2968   unsetenv("TZ");
2969   hour_unset = localtime (&now)->tm_hour;
2970   if (putenv (TZ_PST8) != 0)
2971     exit (1);
2972   if (localtime (&now)->tm_hour == hour_GMT0)
2973     exit (1);
2974   unsetenv("TZ");
2975   if (localtime (&now)->tm_hour != hour_unset)
2976     exit (1);
2977   exit (0);
2978 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2979 [# If we have tzset, assume the worst when cross-compiling.
2980 emacs_cv_localtime_cache=yes])
2981 else
2982         # If we lack tzset, report that localtime does not cache TZ,
2983         # since we can't invalidate the cache if we don't have tzset.
2984         emacs_cv_localtime_cache=no
2985 fi])dnl
2986 AC_MSG_RESULT($emacs_cv_localtime_cache)
2987 if test $emacs_cv_localtime_cache = yes; then
2988   AC_DEFINE(LOCALTIME_CACHE, 1,
2989             [Define to 1 if localtime caches TZ.])
2990 fi
2991
2992 ok_so_far=yes
2993 AC_CHECK_FUNC(socket, , ok_so_far=no)
2994 if test $ok_so_far = yes; then
2995   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2996 fi
2997 if test $ok_so_far = yes; then
2998   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2999 fi
3000 if test $ok_so_far = yes; then
3001 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3002   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3003             [Define to 1 if you have inet sockets.])
3004 fi
3005
3006 if test -f /usr/lpp/X11/bin/smt.exp; then
3007   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3008             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3009 fi
3010
3011 AC_MSG_CHECKING(whether system supports dynamic ptys)
3012 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3013   AC_MSG_RESULT(yes)
3014   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3015 else
3016   AC_MSG_RESULT(no)
3017 fi
3018
3019 AC_FUNC_FORK
3020
3021 AC_CHECK_FUNCS(snprintf)
3022
3023 dnl Adapted from Haible's version.
3024 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3025   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3026     [[char* cs = nl_langinfo(CODESET);]])],
3027     emacs_cv_langinfo_codeset=yes,
3028     emacs_cv_langinfo_codeset=no)
3029   ])
3030 if test $emacs_cv_langinfo_codeset = yes; then
3031   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3032     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3033 fi
3034
3035 AC_TYPE_MBSTATE_T
3036
3037 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3038   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3039                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3040 if test "$emacs_cv_c_restrict_arr" = yes; then
3041   AC_DEFINE(__restrict_arr, __restrict,
3042     [Define to compiler's equivalent of C99 restrict keyword in array
3043      declarations.  Define as empty for no equivalent.])
3044 fi
3045
3046 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3047 dnl how the tty code is related to POSIX and/or other versions of termios.
3048 dnl The following looks like a useful start.
3049 dnl
3050 dnl AC_SYS_POSIX_TERMIOS
3051 dnl if test $ac_cv_sys_posix_termios = yes; then
3052 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3053 dnl                                and macros for terminal control.])
3054 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3055 dnl fi
3056
3057 case $opsys in
3058   darwin | gnu | hpux* | *bsd )
3059     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3060   ;;
3061 esac
3062
3063 dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3064 dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3065 case $opsys in
3066   hpux* | irix6-5 | openbsd | sol2* | unixware )
3067     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3068   ;;
3069 esac
3070
3071 case $opsys in
3072   gnu-* | sol2-10 )
3073     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3074     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3075   ;;
3076 esac
3077
3078 case $opsys in
3079    gnu-kfreebsd) opsysfile="s/gnu-linux.h" ;;
3080
3081    hpux11)
3082      dnl SA_RESTART resets the timeout of `select', so don't use it.
3083      AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should not
3084        be used.])
3085      dnl It works to open the pty's tty in the parent (Emacs), then
3086      dnl close and reopen it in the child.
3087      AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3088        works to open a pty's tty in the parent process, then close and
3089        reopen it in the child.])
3090
3091      opsysfile="s/hpux10-20.h"
3092    ;;
3093
3094    openbsd) opsysfile="s/netbsd.h" ;;
3095
3096    sol2-10)
3097      AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3098        on Solaris.])
3099      opsysfile="s/sol2-6.h"
3100    ;;
3101 esac
3102
3103 # Set up the CFLAGS for real compilation, so we can substitute it.
3104 CFLAGS="$REAL_CFLAGS"
3105 CPPFLAGS="$REAL_CPPFLAGS"
3106
3107 ## Hack to detect a buggy GCC version.
3108 if test "x$GCC" = xyes \
3109    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3110    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3111    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3112    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3113 fi
3114
3115 version=$PACKAGE_VERSION
3116
3117 ### Specify what sort of things we'll be editing into Makefile and config.h.
3118 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3119 AC_SUBST(version)
3120 AC_SUBST(configuration)
3121 ## Unused?
3122 AC_SUBST(canonical)
3123 AC_SUBST(srcdir)
3124 AC_SUBST(prefix)
3125 AC_SUBST(exec_prefix)
3126 AC_SUBST(bindir)
3127 AC_SUBST(datadir)
3128 AC_SUBST(sharedstatedir)
3129 AC_SUBST(libexecdir)
3130 AC_SUBST(mandir)
3131 AC_SUBST(infodir)
3132 AC_SUBST(lispdir)
3133 AC_SUBST(leimdir)
3134 AC_SUBST(locallisppath)
3135 AC_SUBST(lisppath)
3136 AC_SUBST(x_default_search_path)
3137 AC_SUBST(etcdir)
3138 AC_SUBST(archlibdir)
3139 AC_SUBST(docdir)
3140 AC_SUBST(bitmapdir)
3141 AC_SUBST(gamedir)
3142 AC_SUBST(gameuser)
3143 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3144 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3145 ## end of LIBX_BASE, but nothing ever set it.
3146 AC_SUBST(LD_SWITCH_X_SITE)
3147 AC_SUBST(C_SWITCH_X_SITE)
3148 AC_SUBST(GNUSTEP_CFLAGS)
3149 AC_SUBST(CFLAGS)
3150 ## Used in lwlib/Makefile.in.
3151 AC_SUBST(X_TOOLKIT_TYPE)
3152 if test -n "${opsysfile}"; then
3153   S_FILE="\$(srcdir)/${opsysfile}"
3154 else
3155   S_FILE=
3156 fi
3157 AC_SUBST(S_FILE)
3158 AC_SUBST(ns_appdir)
3159 AC_SUBST(ns_appbindir)
3160 AC_SUBST(ns_appresdir)
3161 AC_SUBST(ns_appsrc)
3162 AC_SUBST(GNU_OBJC_CFLAGS)
3163 AC_SUBST(OTHER_FILES)
3164
3165 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3166                    [Define to the canonical Emacs configuration name.])
3167 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3168                    [Define to the options passed to configure.])
3169 if test -n "$opsysfile"; then
3170   AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3171                      [Define to the used os dependent file.])
3172 fi
3173
3174 XMENU_OBJ=
3175 XOBJ=
3176 FONT_OBJ=
3177 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3178   AC_DEFINE(HAVE_X_WINDOWS, 1,
3179             [Define to 1 if you want to use the X window system.])
3180   XMENU_OBJ=xmenu.o
3181   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3182   FONT_OBJ=xfont.o
3183   if test "$HAVE_XFT" = "yes"; then
3184     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3185   elif test "$HAVE_FREETYPE" = "yes"; then
3186     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3187   fi
3188   AC_SUBST(FONT_OBJ)
3189 fi
3190 AC_SUBST(XMENU_OBJ)
3191 AC_SUBST(XOBJ)
3192 AC_SUBST(FONT_OBJ)
3193
3194 WIDGET_OBJ=
3195 MOTIF_LIBW=
3196 if test "${USE_X_TOOLKIT}" != "none" ; then
3197   WIDGET_OBJ=widget.o
3198   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3199   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3200     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3201   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3202     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3203     MOTIF_LIBW=-lXm
3204     case "$opsys" in
3205       gnu-linux)
3206         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3207         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3208         ;;
3209
3210       unixware)
3211         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3212         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3213         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3214         ;;
3215
3216       aix4-2)
3217         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3218         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3219         ;;
3220     esac
3221     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3222   fi
3223 fi
3224 AC_SUBST(WIDGET_OBJ)
3225
3226 TOOLKIT_LIBW=
3227 case "$USE_X_TOOLKIT" in
3228   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3229   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3230   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3231 esac
3232 AC_SUBST(TOOLKIT_LIBW)
3233
3234 if test "$USE_X_TOOLKIT" = "none"; then
3235   LIBXT_OTHER="\$(LIBXSM)"
3236   OLDXMENU_TARGET="really-oldXMenu"
3237 else
3238   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3239   OLDXMENU_TARGET="really-lwlib"
3240 fi
3241 AC_SUBST(LIBXT_OTHER)
3242
3243 ## The X Menu stuff is present in the X10 distribution, but missing
3244 ## from X11.  If we have X10, just use the installed library;
3245 ## otherwise, use our own copy.
3246 if test "${HAVE_X11}" = "yes" ; then
3247   AC_DEFINE(HAVE_X11, 1,
3248             [Define to 1 if you want to use version 11 of X windows.
3249              Otherwise, Emacs expects to use version 10.])
3250
3251   if test "$USE_X_TOOLKIT" = "none"; then
3252     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3253   else
3254     OLDXMENU="\${lwlibdir}/liblw.a"
3255   fi
3256   LIBXMENU="\$(OLDXMENU)"
3257   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3258   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3259 else
3260   ## For a syntactically valid Makefile; not actually used for anything.
3261   ## See comments in src/Makefile.in.
3262   OLDXMENU=nothing
3263   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3264   if test "${HAVE_X_WINDOWS}" = "yes"; then
3265     LIBXMENU="-lXMenu"
3266   else
3267     LIBXMENU=
3268   fi
3269   LIBX_OTHER=
3270   OLDXMENU_DEPS=
3271 fi
3272
3273 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3274   OLDXMENU_TARGET=
3275   OLDXMENU=nothing
3276   LIBXMENU=
3277   OLDXMENU_DEPS=
3278 fi
3279
3280 AC_SUBST(OLDXMENU_TARGET)
3281 AC_SUBST(OLDXMENU)
3282 AC_SUBST(LIBXMENU)
3283 AC_SUBST(LIBX_OTHER)
3284 AC_SUBST(OLDXMENU_DEPS)
3285
3286 if test "${HAVE_MENUS}" = "yes" ; then
3287   AC_DEFINE(HAVE_MENUS, 1,
3288             [Define to 1 if you have mouse menus.
3289              (This is automatic if you use X, but the option to specify it remains.)
3290              It is also defined with other window systems that support xmenu.c.])
3291 fi
3292
3293 if test "${GNU_MALLOC}" = "yes" ; then
3294   AC_DEFINE(GNU_MALLOC, 1,
3295             [Define to 1 if you want to use the GNU memory allocator.])
3296 fi
3297
3298 RALLOC_OBJ=
3299 if test "${REL_ALLOC}" = "yes" ; then
3300   AC_DEFINE(REL_ALLOC, 1,
3301             [Define REL_ALLOC if you want to use the relocating allocator for
3302              buffer space.])
3303
3304   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3305 fi
3306 AC_SUBST(RALLOC_OBJ)
3307
3308 if test "$opsys" = "cygwin"; then
3309   CYGWIN_OBJ="sheap.o"
3310   ## Cygwin differs because of its unexec().
3311   PRE_ALLOC_OBJ=
3312   POST_ALLOC_OBJ=lastfile.o
3313 else
3314   CYGWIN_OBJ=
3315   PRE_ALLOC_OBJ=lastfile.o
3316   POST_ALLOC_OBJ=
3317 fi
3318 AC_SUBST(CYGWIN_OBJ)
3319 AC_SUBST(PRE_ALLOC_OBJ)
3320 AC_SUBST(POST_ALLOC_OBJ)
3321
3322 case "$opsys" in
3323   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3324
3325   darwin)
3326    ## The -headerpad option tells ld (see man page) to leave room at the
3327    ## end of the header for adding load commands.  Needed for dumping.
3328    ## 0x690 is the total size of 30 segment load commands (at 56
3329    ## each); under Cocoa 31 commands are required.
3330    if test "$HAVE_NS" = "yes"; then
3331      libs_nsgui="-framework AppKit"
3332      headerpad_extra=6C8
3333    else
3334      libs_nsgui=
3335      headerpad_extra=690
3336    fi
3337    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3338
3339    ## This is here because src/Makefile.in did some extra fiddling around
3340    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3341    ##   #ifndef LD_SWITCH_SYSTEM
3342    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3343    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3344    ## not using gcc, darwin.
3345    ## Because this was done in src/Makefile.in, the resulting part of
3346    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3347    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3348    ## rather than LD_SWITCH_SYSTEM.
3349    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3350      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3351    ;;
3352
3353   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3354   ## find X at run-time.
3355   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3356   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3357   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3358   ## had different values in configure (in ac_link) and src/Makefile.in.
3359   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3360   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3361
3362   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3363 esac
3364
3365 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3366   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3367 fi
3368
3369 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3370
3371
3372 LD_FIRSTFLAG=
3373 ORDINARY_LINK=
3374 case "$opsys" in
3375   ## gnu: GNU needs its own crt0.
3376   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3377
3378   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3379   ## library search parth, i.e. it won't search /usr/lib for libc and
3380   ## friends.  Using -nostartfiles instead avoids this problem, and
3381   ## will also work on earlier NetBSD releases.
3382   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3383
3384   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3385   ##   MkLinux/LinuxPPC needs this.
3386   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3387   gnu-*)
3388     case "$canonical" in
3389       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3390     esac
3391     ;;
3392 esac
3393
3394
3395 if test "x$ORDINARY_LINK" = "xyes"; then
3396
3397   LD_FIRSTFLAG=""
3398   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3399
3400 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3401 ## freebsd, gnu-* not on powerpc*|s390x*.
3402 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3403
3404   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3405   ## places that are difficult to figure out at make time.  Fortunately,
3406   ## these same versions allow you to pass arbitrary flags on to the
3407   ## linker, so there is no reason not to use it as a linker.
3408   ##
3409   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3410   ## searching for libraries in its internal directories, so we have to
3411   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3412   LD_FIRSTFLAG="-nostdlib"
3413 fi
3414
3415 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3416 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3417
3418 AC_SUBST(LD_FIRSTFLAG)
3419
3420
3421 ## FIXME? The logic here is not precisely the same as that above.
3422 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3423 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3424 LIB_GCC=
3425 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3426
3427   case "$opsys" in
3428     freebsd|netbsd|openbsd) LIB_GCC= ;;
3429
3430     gnu-*)
3431       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3432       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3433       case $host_cpu in
3434       arm*)
3435         LIB_GCC="-lgcc_s"
3436         ;;
3437       *)
3438         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3439         ## immediately undefine it again and redefine it to empty.
3440         ## Was the C_SWITCH_X_SITE part really necessary?
3441 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3442         LIB_GCC=
3443         ;;
3444       esac
3445       ;;
3446
3447     ## Ask GCC where to find libgcc.a.
3448     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3449   esac
3450 fi                              dnl if $GCC
3451 AC_SUBST(LIB_GCC)
3452
3453
3454 ## If we're using X11/GNUstep, define some consequences.
3455 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3456   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3457   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3458 fi
3459
3460
3461 AH_TOP([/* GNU Emacs site configuration template file.
3462
3463 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3464   Free Software Foundation, Inc.
3465
3466 This file is part of GNU Emacs.
3467
3468 GNU Emacs is free software: you can redistribute it and/or modify
3469 it under the terms of the GNU General Public License as published by
3470 the Free Software Foundation, either version 3 of the License, or
3471 (at your option) any later version.
3472
3473 GNU Emacs is distributed in the hope that it will be useful,
3474 but WITHOUT ANY WARRANTY; without even the implied warranty of
3475 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3476 GNU General Public License for more details.
3477
3478 You should have received a copy of the GNU General Public License
3479 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3480
3481
3482 /* No code in Emacs #includes config.h twice, but some bits of code
3483    intended to work with other packages as well (like gmalloc.c)
3484    think they can include it as many times as they like.  */
3485 #ifndef EMACS_CONFIG_H
3486 #define EMACS_CONFIG_H
3487 ])dnl
3488
3489 AH_BOTTOM([
3490 /* On AIX 3 this must be included before any other include file.  */
3491 #include <alloca.h>
3492 #if ! HAVE_ALLOCA
3493 # error "alloca not available on this machine"
3494 #endif
3495
3496 /* Define AMPERSAND_FULL_NAME if you use the convention
3497    that & in the full name stands for the login id.  */
3498 /* Turned on June 1996 supposing nobody will mind it.  */
3499 #define AMPERSAND_FULL_NAME
3500
3501 /* `subprocesses' should be defined if you want to
3502    have code for asynchronous subprocesses
3503    (as used in M-x compile and M-x shell).
3504    Only MSDOS does not support this (it overrides
3505    this in its config_opsysfile below).  */
3506
3507 #define subprocesses
3508
3509 /* Include the os dependent file.  */
3510 #ifdef config_opsysfile
3511 # include config_opsysfile
3512 #endif
3513
3514 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3515    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3516   (There is probably a better place to do this, but right now the
3517    Cocoa side does this in s/darwin.h and we cannot parallel this
3518    exactly since GNUstep is multi-OS.  */
3519 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3520 #  define SYSTEM_PURESIZE_EXTRA 30000
3521 #endif
3522
3523 #ifdef emacs /* Don't do this for lib-src.  */
3524 /* Tell regex.c to use a type compatible with Emacs.  */
3525 #define RE_TRANSLATE_TYPE Lisp_Object
3526 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3527 #ifdef make_number
3528 /* If make_number is a macro, use it.  */
3529 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3530 #else
3531 /* If make_number is a function, avoid it.  */
3532 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3533 #endif
3534 #endif
3535
3536 #include <string.h>
3537 #include <stdlib.h>
3538
3539 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3540 #define NO_INLINE __attribute__((noinline))
3541 #else
3542 #define NO_INLINE
3543 #endif
3544
3545 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3546 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3547 #else
3548 #define EXTERNALLY_VISIBLE
3549 #endif
3550
3551 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3552 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3553 #else
3554 # define ATTRIBUTE_FORMAT(spec) /* empty */
3555 #endif
3556
3557 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3558 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3559    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3560 #else
3561 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3562    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3563 #endif
3564
3565 /* Some versions of GNU/Linux define noinline in their headers.  */
3566 #ifdef noinline
3567 #undef noinline
3568 #endif
3569
3570 /* These won't be used automatically yet.  We also need to know, at least,
3571    that the stack is continuous.  */
3572 #ifdef __GNUC__
3573 #  ifndef GC_SETJMP_WORKS
3574   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3575 #    define GC_SETJMP_WORKS 1
3576 #  endif
3577 #endif
3578
3579 #endif /* EMACS_CONFIG_H */
3580
3581 /*
3582 Local Variables:
3583 mode: c
3584 End:
3585 */
3586 ])dnl
3587
3588 #### Report on what we decided to do.
3589 #### Report GTK as a toolkit, even if it doesn't use Xt.
3590 #### It makes printing result more understandable as using GTK sets
3591 #### toolkit_scroll_bars to yes by default.
3592 if test "${HAVE_GTK}" = "yes"; then
3593   USE_X_TOOLKIT=GTK
3594 fi
3595
3596 echo "
3597 Configured for \`${canonical}'.
3598
3599   Where should the build process find the source code?    ${srcdir}
3600   What operating system file should Emacs use?            ${opsysfile-none}
3601   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3602   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3603   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3604   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3605   What window system should Emacs use?                    ${window_system}
3606   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3607
3608 if test -n "${x_includes}"; then
3609 echo "  Where do we find X Windows header files?                ${x_includes}"
3610 else
3611 echo "  Where do we find X Windows header files?                Standard dirs"
3612 fi
3613 if test -n "${x_libraries}"; then
3614 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3615 else
3616 echo "  Where do we find X Windows libraries?                   Standard dirs"
3617 fi
3618
3619 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3620 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3621 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3622 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3623 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3624 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3625 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3626 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3627
3628 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3629 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3630 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3631 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3632 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3633 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3634 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3635
3636 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3637 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3638 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3639 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3640
3641 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3642 echo
3643
3644 if test -n "${EMACSDATA}"; then
3645    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3646 fi
3647 if test -n "${EMACSDOC}"; then
3648    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3649 fi
3650
3651 if test $USE_XASSERTS = yes; then
3652    echo "  Compiling with asserts turned on."
3653    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3654 fi
3655
3656 echo
3657
3658 if test "$HAVE_NS" = "yes"; then
3659    echo
3660    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3661 The installed application will go to nextstep/Emacs.app and can be
3662 run or moved from there."
3663    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3664       echo "The application will be fully self-contained."
3665     else
3666       echo "The lisp resources for the application will be installed under ${prefix}.
3667 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3668 to run if these resources are not installed."
3669    fi
3670    echo
3671 fi
3672
3673 if test "${opsys}" = "cygwin"; then
3674   case `uname -r` in
3675     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3676            echo
3677            ;;
3678   esac
3679 fi
3680
3681 # Remove any trailing slashes in these variables.
3682 [test "${prefix}" != NONE &&
3683   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3684 test "${exec_prefix}" != NONE &&
3685   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3686
3687 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3688 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3689 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3690 dnl (else you get "no `Makefile.am' found for any configure output").
3691 dnl This will work, but you get a config.status that is not quite right
3692 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3693 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3694 dnl it seems better to just live with the duplication.
3695 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3696
3697 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3698        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3699        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3700        leim/Makefile])
3701
3702 dnl test/ is not present in release tarfiles.
3703 opt_makefile=test/automated/Makefile
3704
3705 if test -f $srcdir/${opt_makefile}.in; then
3706   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3707   dnl Again, it's best not to use a variable.  Though you can add
3708   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3709   AC_CONFIG_FILES([test/automated/Makefile])
3710 fi
3711
3712
3713 dnl admin/ may or may not be present.
3714 opt_makefile=admin/unidata/Makefile
3715
3716 if test -f $srcdir/${opt_makefile}.in; then
3717   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3718   AC_CONFIG_FILES([admin/unidata/Makefile])
3719 fi
3720
3721
3722 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3723
3724 AC_SUBST(SUBDIR_MAKEFILES_IN)
3725
3726 dnl Make the necessary directories, if they don't exist.
3727 AC_CONFIG_COMMANDS([mkdirs], [
3728 for dir in etc lisp ; do
3729   test -d ${dir} || mkdir ${dir}
3730 done
3731 ])
3732
3733 dnl You might wonder (I did) why epaths.h is generated by running make,
3734 dnl rather than just letting configure generate it from epaths.in.
3735 dnl One reason is that the various paths are not fully expanded (see above);
3736 dnl eg gamedir=${prefix}/var/games/emacs.
3737 dnl Secondly, the GNU Coding standards require that one should be able
3738 dnl to run `make prefix=/some/where/else' and override the values set
3739 dnl by configure.  This also explains the `move-if-change' test and
3740 dnl the use of force in the `epaths-force' rule in Makefile.in.
3741 AC_CONFIG_COMMANDS([epaths], [
3742 echo creating src/epaths.h
3743 ${MAKE-make} epaths-force
3744 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3745
3746 AC_CONFIG_COMMANDS([gdbinit], [
3747 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3748   echo creating src/.gdbinit
3749   echo source $srcdir/src/.gdbinit > src/.gdbinit
3750 fi
3751 ])
3752
3753 AC_OUTPUT
3754
3755 dnl configure.in ends here