lisp/indent.el

   1 ;;; indent.el --- indentation commands for Emacs
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; Commands for making and changing indentation in text.  These are
  26 ;; described in the Emacs manual.
  27
  28 ;;; Code:
  29
  30 (defvar standard-indent 4 "\
  31 Default number of columns for margin-changing functions to indent.")
  32
  33 (defvar indent-line-function 'indent-to-left-margin "\
  34 Function to indent current line.")
  35
  36 (defun indent-according-to-mode ()
  37   "Indent line in proper way for current major mode."
  38   (interactive)
  39   (funcall indent-line-function))
  40
  41 (defun indent-for-tab-command ()
  42   "Indent line in proper way for current major mode."
  43   (interactive)
  44   (if (eq indent-line-function 'indent-to-left-margin)
  45       (insert-tab)
  46     (funcall indent-line-function)))
  47
  48 (defun insert-tab ()
  49   (if abbrev-mode
  50       (expand-abbrev))
  51   (if indent-tabs-mode
  52       (insert ?\t)
  53     (indent-to (* tab-width (1+ (/ (current-column) tab-width))))))
  54
  55 (defun indent-rigidly (start end arg)
  56   "Indent all lines starting in the region sideways by ARG columns.
  57 Called from a program, takes three arguments, START, END and ARG."
  58   (interactive "r\np")
  59   (save-excursion
  60     (goto-char end)
  61     (setq end (point-marker))
  62     (goto-char start)
  63     (or (bolp) (forward-line 1))
  64     (while (< (point) end)
  65       (let ((indent (current-indentation))
  66             eol-flag)
  67         (save-excursion
  68           (skip-chars-forward " \t")
  69           (setq eol-flag (eolp)))
  70         (or eol-flag
  71             (indent-to (max 0 (+ indent arg)) 0))
  72         (delete-region (point) (progn (skip-chars-forward " \t") (point))))
  73       (forward-line 1))
  74     (move-marker end nil)))
  75
  76 (defun indent-line-to (column)
  77   "Indent current line to COLUMN.
  78 This function removes or adds spaces and tabs at beginning of line
  79 only if necessary.  It leaves point at end of indentation."
  80   (beginning-of-line)
  81   (let ((bol (point))
  82         (cur-col (current-indentation)))
  83     (cond ((> cur-col column) ; too far right (after tab?)
  84            (let ((beg (progn (move-to-column column t) (point))))
  85              (back-to-indentation)
  86              (delete-region beg (point))))
  87           ((< cur-col column)
  88            (back-to-indentation)
  89            (indent-to column)))))
  90
  91 (defun current-left-margin ()
  92   "Return the left margin to use for this line.
  93 This is the value of the buffer-local variable `left-margin' plus the value
  94 of the `left-margin' text-property at the start of the line."
  95   (save-excursion
  96     (back-to-indentation)
  97     (max 0
  98          (+ left-margin (or (get-text-property (point) 'left-margin) 0)))))
  99
 100 (defun move-to-left-margin (&optional n)
 101   "Move to the left margin of the current line.
 102 With optional argument, move forward N-1 lines first.
 103 The column moved to is the one given by the `left-margin' function, or the
 104 column where text actually starts if the region is centered or right-justified.
 105 When called interactively, this function corrects the line's indentation
 106 if it appears to be incorrect.
 107 When called noninteractively, however, it just moves to the beginning of
 108 the text in this case."
 109   (interactive "p")
 110   (beginning-of-line n)
 111   (skip-chars-forward " \t")
 112   (if (not (memq (current-justification) '(right center)))
 113       (let ((cc (current-column))
 114             (lm (current-left-margin)))
 115         (cond ((> cc lm)
 116                (move-to-column lm t))
 117               ((and (< cc lm) (interactive-p))
 118                (indent-to-left-margin))))))
 119
 120 ;; This is the default indent-line-function,
 121 ;; used in Fundamental Mode, Text Mode, etc.
 122 (defun indent-to-left-margin ()
 123   "Indent current line to `left-margin'."
 124   (indent-line-to (current-left-margin)))
 125
 126 (defun delete-to-left-margin (from to)
 127   "Remove left-margin indentation from region.
 128 This is careful only to delete whitespace, and not to delete any more than
 129 the \(current-left-margin) value for each line."
 130   (save-excursion
 131     (goto-char to)
 132     (setq to (point-marker))
 133     (goto-char from)
 134     (or (bolp) (forward-line 1))
 135     (while (< (point) to)
 136       (delete-region (point) (let ((lm (current-left-margin)))
 137                                (skip-chars-forward " \t")
 138                                (if (> (current-column) lm)
 139                                    (move-to-column lm))
 140                                (point)))
 141       (forward-line 1))
 142     (move-marker to nil)))
 143
 144 (defun set-left-margin (from to lm)
 145   "Set the left margin of the region to WIDTH.
 146 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 147   (interactive "r\nNSet left margin to column: ")
 148   (if (interactive-p) (setq lm (prefix-numeric-value lm)))
 149   (save-excursion
 150     ;; If inside indentation, start from BOL.
 151     (goto-char from)
 152     (skip-chars-backward " \t")
 153     (if (bolp) (setq from (point)))
 154     (goto-char to)
 155     (setq to (point-marker)))
 156   ;; Delete indentation first, so that paragraph indentation is preserved.
 157   (if auto-fill-function (delete-to-left-margin from to))
 158   (put-text-property from to 'left-margin lm)
 159   (if auto-fill-function (fill-region from to nil t t))
 160   (move-marker to nil))
 161
 162 (defun set-right-margin (from to lm)
 163   "Set the right margin of the region to WIDTH.
 164 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 165   (interactive "r\nNSet left margin to column: ")
 166   (if (interactive-p) (setq lm (prefix-numeric-value lm)))
 167   (save-excursion
 168     (goto-char from)
 169     (skip-chars-backward " \t")
 170     (if (bolp) (setq from (point))))
 171   (put-text-property from to 'right-margin lm)
 172   (if auto-fill-function (fill-region from to nil t t)))
 173
 174 (defun alter-text-property (from to prop func &optional object)
 175   "Programmatically change value of a text-property.
 176 For each region between FROM and TO that has a single value for PROPERTY,
 177 apply FUNCTION to that value and sets the property to the function's result.
 178 Optional fifth argument OBJECT specifies the string or buffer to operate on."
 179   (let ((begin from)
 180         end val)
 181     (while (setq val (get-text-property begin prop object)
 182                  end (text-property-not-all begin to prop val object))
 183       (put-text-property begin end prop (funcall func val) object)
 184       (setq begin end))
 185     (if (< begin to)
 186         (put-text-property begin to prop (funcall func val) object))))
 187
 188 (defun increase-left-margin (from to inc)
 189   "Increase or decrease the left-margin of the region.
 190 With no prefix argument, this adds `standard-indent' of indentation.
 191 A prefix arg (optional third arg INC noninteractively) specifies the amount
 192 to change the margin by, in characters.
 193 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 194   (interactive "*r\nP")
 195   (setq inc (if inc (prefix-numeric-value inc) standard-indent))
 196   (save-excursion
 197     (goto-char from)
 198     (skip-chars-backward " \t")
 199     (if (bolp) (setq from (point)))
 200     (goto-char to)
 201     (setq to (point-marker)))
 202   (if auto-fill-function (delete-to-left-margin from to))
 203   (alter-text-property from to 'left-margin
 204                        (lambda (v) (max 0 (+ inc (or v 0)))))
 205   (if auto-fill-function (fill-region from to nil t t))
 206   (move-marker to nil))
 207
 208 (defun decrease-left-margin (from to inc)
 209   "Make the left margin of the region smaller.
 210 With no prefix argument, decrease the indentation by `standard-indent'.
 211 A prefix arg (optional third arg INC noninteractively) specifies the amount
 212 to change the margin by, in characters.
 213 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 214   (interactive "*r\nP")
 215   (setq inc (if inc (prefix-numeric-value inc) standard-indent))
 216   (increase-left-margin from to (- inc)))
 217
 218 (defun increase-right-margin (from to inc)
 219   "Increase the right-margin of the region.
 220 With no prefix argument, increase the right margin by `standard-indent'.
 221 A prefix arg (optional third arg INC noninteractively) specifies the amount
 222 to change the margin by, in characters.  A negative argument decreases
 223 the right margin width.
 224 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 225   (interactive "r\nP")
 226   (if (interactive-p)
 227       (setq inc (if inc (prefix-numeric-value current-prefix-arg)
 228                   standard-indent)))
 229   (save-excursion
 230     (alter-text-property from to 'right-margin
 231        (lambda (v) (max 0 (+ inc (or v 0)))))
 232     (if auto-fill-function
 233         (fill-region from to nil t t))))
 234
 235 (defun decrease-right-margin (from to inc)
 236   "Make the right margin of the region smaller.
 237 With no prefix argument, decrease the right margin by `standard-indent'.
 238 A prefix arg (optional third arg INC noninteractively) specifies the amount
 239 of width to remove, in characters.  A negative argument increases
 240 the right margin width.
 241 If `auto-fill-mode' is active, re-fills region to fit in new margin."
 242   (interactive "*r\nP")
 243   (setq inc (if inc (prefix-numeric-value inc) standard-indent))
 244   (increase-right-margin from to (- inc)))
 245
 246 (defvar indent-region-function nil
 247   "Function which is short cut to indent region using indent-according-to-mode.
 248 A value of nil means really run indent-according-to-mode on each line.")
 249
 250 (defun indent-region (start end column)
 251   "Indent each nonblank line in the region.
 252 With no argument, indent each line using `indent-according-to-mode',
 253 or use `indent-region-function' to do the whole region if that's non-nil.
 254 If there is a fill prefix, make each line start with the fill prefix.
 255 With argument COLUMN, indent each line to that column.
 256 Called from a program, takes three args: START, END and COLUMN."
 257   (interactive "r\nP")
 258   (if (null column)
 259       (if fill-prefix
 260           (save-excursion
 261             (goto-char end)
 262             (setq end (point-marker))
 263             (goto-char start)
 264             (let ((regexp (regexp-quote fill-prefix)))
 265               (while (< (point) end)
 266                 (or (looking-at regexp)
 267                     (and (bolp) (eolp))
 268                     (insert fill-prefix))
 269                 (forward-line 1))))
 270         (if indent-region-function
 271             (funcall indent-region-function start end)
 272           (save-excursion
 273             (goto-char end)
 274             (setq end (point-marker))
 275             (goto-char start)
 276             (or (bolp) (forward-line 1))
 277             (while (< (point) end)
 278               (or (and (bolp) (eolp))
 279                   (funcall indent-line-function))
 280               (forward-line 1))
 281             (move-marker end nil))))
 282     (setq column (prefix-numeric-value column))
 283     (save-excursion
 284       (goto-char end)
 285       (setq end (point-marker))
 286       (goto-char start)
 287       (or (bolp) (forward-line 1))
 288       (while (< (point) end)
 289         (delete-region (point) (progn (skip-chars-forward " \t") (point)))
 290         (or (eolp)
 291             (indent-to column 0))
 292         (forward-line 1))
 293       (move-marker end nil))))
 294
 295 (defun indent-relative-maybe ()
 296   "Indent a new line like previous nonblank line."
 297   (interactive)
 298   (indent-relative t))
 299
 300 (defun indent-relative (&optional unindented-ok)
 301   "Space out to under next indent point in previous nonblank line.
 302 An indent point is a non-whitespace character following whitespace.
 303 If the previous nonblank line has no indent points beyond the
 304 column point starts at, `tab-to-tab-stop' is done instead."
 305   (interactive "P")
 306   (if abbrev-mode (expand-abbrev))
 307   (let ((start-column (current-column))
 308         indent)
 309     (save-excursion
 310       (beginning-of-line)
 311       (if (re-search-backward "^[^\n]" nil t)
 312           (let ((end (save-excursion (forward-line 1) (point))))
 313             (move-to-column start-column)
 314             ;; Is start-column inside a tab on this line?
 315             (if (> (current-column) start-column)
 316                 (backward-char 1))
 317             (or (looking-at "[ \t]")
 318                 unindented-ok
 319                 (skip-chars-forward "^ \t" end))
 320             (skip-chars-forward " \t" end)
 321             (or (= (point) end) (setq indent (current-column))))))
 322     (if indent
 323         (let ((opoint (point-marker)))
 324           (delete-region (point) (progn (skip-chars-backward " \t") (point)))
 325           (indent-to indent 0)
 326           (if (> opoint (point))
 327               (goto-char opoint))
 328           (move-marker opoint nil))
 329       (tab-to-tab-stop))))
 330
 331 (defvar tab-stop-list
 332   '(8 16 24 32 40 48 56 64 72 80 88 96 104 112 120)
 333   "*List of tab stop positions used by `tab-to-tab-stops'.
 334 This should be a list of integers, ordered from smallest to largest.")
 335
 336 (defvar edit-tab-stops-map nil "Keymap used in `edit-tab-stops'.")
 337 (if edit-tab-stops-map
 338     nil
 339   (setq edit-tab-stops-map (make-sparse-keymap))
 340   (define-key edit-tab-stops-map "\C-x\C-s" 'edit-tab-stops-note-changes)
 341   (define-key edit-tab-stops-map "\C-c\C-c" 'edit-tab-stops-note-changes))
 342
 343 (defvar edit-tab-stops-buffer nil
 344   "Buffer whose tab stops are being edited--in case
 345 the variable `tab-stop-list' is local in that buffer.")
 346
 347 (defun edit-tab-stops ()
 348   "Edit the tab stops used by `tab-to-tab-stop'.
 349 Creates a buffer *Tab Stops* containing text describing the tab stops.
 350 A colon indicates a column where there is a tab stop.
 351 You can add or remove colons and then do \\<edit-tab-stops-map>\\[edit-tab-stops-note-changes] to make changes take effect."
 352   (interactive)
 353   (setq edit-tab-stops-buffer (current-buffer))
 354   (switch-to-buffer (get-buffer-create "*Tab Stops*"))
 355   (use-local-map edit-tab-stops-map)
 356   (make-local-variable 'indent-tabs-mode)
 357   (setq indent-tabs-mode nil)
 358   (overwrite-mode 1)
 359   (setq truncate-lines t)
 360   (erase-buffer)
 361   (let ((tabs tab-stop-list))
 362     (while tabs
 363       (indent-to (car tabs) 0)
 364       (insert ?:)
 365       (setq tabs (cdr tabs))))
 366   (let ((count 0))
 367     (insert ?\n)
 368     (while (< count 8)
 369       (insert (+ count ?0))
 370     (insert "         ")
 371       (setq count (1+ count)))
 372     (insert ?\n)
 373     (while (> count 0)
 374       (insert "0123456789")
 375       (setq count (1- count))))
 376   (insert "\nTo install changes, type C-c C-c")
 377   (goto-char (point-min)))
 378
 379 (defun edit-tab-stops-note-changes ()
 380   "Put edited tab stops into effect."
 381   (interactive)
 382     (let (tabs)
 383       (save-excursion
 384         (goto-char 1)
 385         (end-of-line)
 386         (while (search-backward ":" nil t)
 387           (setq tabs (cons (current-column) tabs))))
 388       (bury-buffer (prog1 (current-buffer)
 389                           (switch-to-buffer edit-tab-stops-buffer)))
 390       (setq tab-stop-list tabs))
 391   (message "Tab stops installed"))
 392
 393 (defun tab-to-tab-stop ()
 394   "Insert spaces or tabs to next defined tab-stop column.
 395 The variable `tab-stop-list' is a list of columns at which there are tab stops.
 396 Use \\[edit-tab-stops] to edit them interactively."
 397   (interactive)
 398   (if abbrev-mode (expand-abbrev))
 399   (let ((tabs tab-stop-list))
 400     (while (and tabs (>= (current-column) (car tabs)))
 401       (setq tabs (cdr tabs)))
 402     (if tabs
 403         (let ((opoint (point)))
 404           (skip-chars-backward " \t")
 405           (delete-region (point) opoint)
 406           (indent-to (car tabs)))
 407       (insert ?\ ))))
 408
 409 (defun move-to-tab-stop ()
 410   "Move point to next defined tab-stop column.
 411 The variable `tab-stop-list' is a list of columns at which there are tab stops.
 412 Use \\[edit-tab-stops] to edit them interactively."
 413   (interactive)
 414   (let ((tabs tab-stop-list))
 415     (while (and tabs (>= (current-column) (car tabs)))
 416       (setq tabs (cdr tabs)))
 417     (if tabs
 418         (let ((before (point)))
 419           (move-to-column (car tabs) t)
 420           (save-excursion
 421             (goto-char before)
 422             ;; If we just added a tab, or moved over one,
 423             ;; delete any superfluous spaces before the old point.
 424             (if (and (eq (preceding-char) ?\ )
 425                      (eq (following-char) ?\t))
 426                 (let ((tabend (* (/ (current-column) tab-width) tab-width)))
 427                   (while (and (> (current-column) tabend)
 428                               (eq (preceding-char) ?\ ))
 429                     (forward-char -1))
 430                   (delete-region (point) before))))))))
 431
 432 (define-key global-map "\t" 'indent-for-tab-command)
 433 (define-key esc-map "\034" 'indent-region)
 434 (define-key ctl-x-map "\t" 'indent-rigidly)
 435 (define-key esc-map "i" 'tab-to-tab-stop)
 436
 437 ;;; indent.el ends here