lisp/help.el

   1 ;;; help.el --- help commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1993 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: help, internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This code implements GNU Emac's on-line help system, the one invoked by
  27 ;;`M-x help-for-help'.
  28
  29 ;;; Code:
  30
  31 ;; Get the macro make-help-screen when this is compiled,
  32 ;; or run interpreted, but not when the compiled code is loaded.
  33 (eval-when-compile (require 'help-macro))
  34
  35 (defvar help-map (make-sparse-keymap)
  36   "Keymap for characters following the Help key.")
  37
  38 (define-key global-map (char-to-string help-char) 'help-command)
  39 (fset 'help-command help-map)
  40
  41 (define-key help-map (char-to-string help-char) 'help-for-help)
  42 (define-key help-map "?" 'help-for-help)
  43
  44 (define-key help-map "\C-c" 'describe-copying)
  45 (define-key help-map "\C-d" 'describe-distribution)
  46 (define-key help-map "\C-w" 'describe-no-warranty)
  47 (define-key help-map "\C-p" 'describe-project)
  48 (define-key help-map "a" 'command-apropos)
  49
  50 (define-key help-map "b" 'describe-bindings)
  51
  52 (define-key help-map "c" 'describe-key-briefly)
  53 (define-key help-map "k" 'describe-key)
  54
  55 (define-key help-map "d" 'describe-function)
  56 (define-key help-map "f" 'describe-function)
  57
  58 (define-key help-map "i" 'info)
  59 (define-key help-map "\C-f" 'Info-goto-emacs-command-node)
  60 (define-key help-map "\C-k" 'Info-goto-emacs-key-command-node)
  61
  62 (define-key help-map "l" 'view-lossage)
  63
  64 (define-key help-map "m" 'describe-mode)
  65
  66 (define-key help-map "\C-n" 'view-emacs-news)
  67 (define-key help-map "n" 'view-emacs-news)
  68
  69 (define-key help-map "p" 'finder-by-keyword)
  70 (autoload 'finder-by-keyword "finder")
  71
  72 (define-key help-map "s" 'describe-syntax)
  73
  74 (define-key help-map "t" 'help-with-tutorial)
  75
  76 (define-key help-map "w" 'where-is)
  77
  78 (define-key help-map "v" 'describe-variable)
  79
  80 (define-key help-map "q" 'help-quit)
  81
  82 (defun help-quit ()
  83   (interactive)
  84   nil)
  85
  86 (defun help-with-tutorial ()
  87   "Select the Emacs learn-by-doing tutorial."
  88   (interactive)
  89   (let ((file (expand-file-name "~/TUTORIAL")))
  90     (delete-other-windows)
  91     (if (get-file-buffer file)
  92         (switch-to-buffer (get-file-buffer file))
  93       (switch-to-buffer (create-file-buffer file))
  94       (setq buffer-file-name file)
  95       (setq default-directory (expand-file-name "~/"))
  96       (setq buffer-auto-save-file-name nil)
  97       (insert-file-contents (expand-file-name "TUTORIAL" data-directory))
  98       (goto-char (point-min))
  99       (search-forward "\n<<")
 100       (beginning-of-line)
 101       (delete-region (point) (progn (end-of-line) (point)))
 102       (let ((n (- (window-height (selected-window))
 103                   (count-lines (point-min) (point))
 104                   6)))
 105         (if (< n 12)
 106             (newline n)
 107           ;; Some people get confused by the large gap.
 108           (newline (/ n 2))
 109           (insert "[Middle of page left blank for didactic purposes.  "
 110                   "Text continues below]")
 111           (newline (- n (/ n 2)))))
 112       (goto-char (point-min))
 113       (set-buffer-modified-p nil))))
 114
 115 (defun describe-key-briefly (key)
 116   "Print the name of the function KEY invokes.  KEY is a string."
 117   (interactive "kDescribe key briefly: ")
 118   ;; If this key seq ends with a down event, discard the
 119   ;; following click or drag event.  Otherwise that would
 120   ;; erase the message.
 121   (let ((type (aref key (1- (length key)))))
 122     (if (listp type) (setq type (car type)))
 123     (and (symbolp type)
 124          (memq 'down (event-modifiers type))
 125          (read-event)))
 126   (let ((defn (key-binding key)))
 127     (if (or (null defn) (integerp defn))
 128         (message "%s is undefined" (key-description key))
 129       (message "%s runs the command %s"
 130                (key-description key)
 131                (if (symbolp defn) defn (prin1-to-string defn))))))
 132
 133 (defun print-help-return-message (&optional function)
 134   "Display or return message saying how to restore windows after help command.
 135 Computes a message and applies the optional argument FUNCTION to it.
 136 If FUNCTION is nil, applies `message' to it, thus printing it."
 137   (and (not (get-buffer-window standard-output))
 138        (funcall (or function 'message)
 139                 (concat
 140                  (substitute-command-keys
 141                   (if (one-window-p t)
 142                       (if pop-up-windows
 143                           "Type \\[delete-other-windows] to remove help window."
 144                         "Type \\[switch-to-buffer] RET to remove help window.")
 145                     "Type \\[switch-to-buffer-other-window] RET to restore the other window."))
 146                  (substitute-command-keys
 147                   "  \\[scroll-other-window] to scroll the help.")))))
 148
 149 (defun describe-key (key)
 150   "Display documentation of the function invoked by KEY.  KEY is a string."
 151   (interactive "kDescribe key: ")
 152   ;; If this key seq ends with a down event, discard the
 153   ;; following click or drag event.  Otherwise that would
 154   ;; erase the message.
 155   (let ((type (aref key (1- (length key)))))
 156     (if (listp type) (setq type (car type)))
 157     (and (symbolp type)
 158          (memq 'down (event-modifiers type))
 159          (read-event)))
 160   (let ((defn (key-binding key)))
 161     (if (or (null defn) (integerp defn))
 162         (message "%s is undefined" (key-description key))
 163       (with-output-to-temp-buffer "*Help*"
 164         (prin1 defn)
 165         (princ ":\n")
 166         (if (documentation defn)
 167             (princ (documentation defn))
 168           (princ "not documented"))
 169         (print-help-return-message)))))
 170
 171 (defun describe-mode (&optional minor)
 172   "Display documentation of current major mode.
 173 If optional MINOR is non-nil (or prefix argument is given if interactive),
 174 display documentation of active minor modes as well.
 175 For this to work correctly for a minor mode, the mode's indicator variable
 176 \(listed in `minor-mode-alist') must also be a function whose documentation
 177 describes the minor mode."
 178   (interactive)
 179   (with-output-to-temp-buffer "*Help*"
 180     (princ mode-name)
 181     (princ " Mode:\n")
 182     (princ (documentation major-mode))
 183     (let ((minor-modes minor-mode-alist)
 184           (locals (buffer-local-variables)))
 185       (while minor-modes
 186         (let* ((minor-mode (car (car minor-modes)))
 187                (indicator (car (cdr (car minor-modes))))
 188                (local-binding (assq minor-mode locals)))
 189           ;; Document a minor mode if it is listed in minor-mode-alist,
 190           ;; bound locally in this buffer, non-nil, and has a function
 191           ;; definition.
 192           (if (and local-binding
 193                    (cdr local-binding)
 194                    (fboundp minor-mode))
 195               (progn
 196                 (princ (format "\n\n\n%s minor mode (indicator%s):\n"
 197                                minor-mode indicator))
 198                 (princ (documentation minor-mode)))))
 199         (setq minor-modes (cdr minor-modes))))
 200     (print-help-return-message)))
 201
 202 ;; So keyboard macro definitions are documented correctly
 203 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 204
 205 (defun describe-distribution ()
 206   "Display info on how to obtain the latest version of GNU Emacs."
 207   (interactive)
 208   (find-file-read-only
 209    (expand-file-name "DISTRIB" data-directory)))
 210
 211 (defun describe-copying ()
 212   "Display info on how you may redistribute copies of GNU Emacs."
 213   (interactive)
 214   (find-file-read-only
 215    (expand-file-name "COPYING" data-directory))
 216   (goto-char (point-min)))
 217
 218 (defun describe-project ()
 219   "Display info on the GNU project."
 220   (interactive)
 221   (find-file-read-only
 222    (expand-file-name "GNU" data-directory))
 223   (goto-char (point-min)))
 224
 225 (defun describe-no-warranty ()
 226   "Display info on all the kinds of warranty Emacs does NOT have."
 227   (interactive)
 228   (describe-copying)
 229   (let (case-fold-search)
 230     (search-forward "NO WARRANTY")
 231     (recenter 0)))
 232
 233 (defun describe-prefix-bindings ()
 234   "Describe the bindings of the prefix used to reach this command.
 235 The prefix described consists of all but the last event
 236 of the key sequence that ran this command."
 237   (interactive)
 238   (let* ((key (this-command-keys))
 239          (prefix (make-vector (1- (length key)) nil))
 240          i)
 241     (setq i 0)
 242     (while (< i (length prefix))
 243       (aset prefix i (aref key i))
 244       (setq i (1+ i)))
 245     (describe-bindings prefix)))
 246 ;; Make C-h after a prefix, when not specifically bound,
 247 ;; run describe-prefix-bindings.
 248 (setq prefix-help-command 'describe-prefix-bindings)
 249
 250 (defun view-emacs-news ()
 251   "Display info on recent changes to Emacs."
 252   (interactive)
 253   (find-file-read-only (expand-file-name "NEWS" data-directory)))
 254
 255 (defun view-lossage ()
 256   "Display last 100 input keystrokes."
 257   (interactive)
 258   (with-output-to-temp-buffer "*Help*"
 259     (princ (key-description (recent-keys)))
 260     (save-excursion
 261       (set-buffer standard-output)
 262       (goto-char (point-min))
 263       (while (progn (move-to-column 50) (not (eobp)))
 264         (search-forward " " nil t)
 265         (insert "\n")))
 266     (print-help-return-message)))
 267
 268 (defalias 'help 'help-for-help)
 269 (make-help-screen help-for-help
 270   "a b c f C-f i k C-k l m n p s t v w C-c C-d C-n C-w, or ? for more help:"
 271   "You have typed \\[help-command], the help character.  Type a Help option:
 272 \(Use \\<help-map>\\[scroll-up] or \\[scroll-down] to scroll through this text.
 273 Type \\<help-map>\\[help-quit] to exit the Help command.)
 274
 275 a  command-apropos.  Give a substring, and see a list of commands
 276         (functions interactively callable) that contain
 277         that substring.  See also the  apropos  command.
 278 b  describe-bindings.  Display table of all key bindings.
 279 c  describe-key-briefly.  Type a command key sequence;
 280         it prints the function name that sequence runs.
 281 f  describe-function.  Type a function name and get documentation of it.
 282 C-f Info-goto-emacs-command-node.  Type a function name;
 283         it takes you to the Info node for that command.
 284 i  info. The  info  documentation reader.
 285 k  describe-key.  Type a command key sequence;
 286         it displays the full documentation.
 287 C-k Info-goto-emacs-key-command-node.  Type a command key sequence;
 288         it takes you to the Info node for the command bound to that key.
 289 l  view-lossage.  Shows last 100 characters you typed.
 290 m  describe-mode.  Print documentation of current major mode,
 291         which describes the commands peculiar to it.
 292 n  view-emacs-news.  Shows emacs news file.
 293 p  finder-by-keyword. Find packages matching a given topic keyword.
 294 s  describe-syntax.  Display contents of syntax table, plus explanations
 295 t  help-with-tutorial.  Select the Emacs learn-by-doing tutorial.
 296 v  describe-variable.  Type name of a variable;
 297         it displays the variable's documentation and value.
 298 w  where-is.  Type command name; it prints which keystrokes
 299         invoke that command.
 300 C-c print Emacs copying permission (General Public License).
 301 C-d print Emacs ordering information.
 302 C-n print news of recent Emacs changes.
 303 C-p print information about the GNU project.
 304 C-w print information on absence of warranty for GNU Emacs."
 305   help-map)
 306
 307 ;; Return a function which is called by the list containing point.
 308 ;; If that gives no function, return a function whose name is around point.
 309 ;; If that doesn't give a function, return nil.
 310 (defun function-called-at-point ()
 311   (or (condition-case ()
 312           (save-excursion
 313             (save-restriction
 314               (narrow-to-region (max (point-min) (- (point) 1000)) (point-max))
 315               (backward-up-list 1)
 316               (forward-char 1)
 317               (let (obj)
 318                 (setq obj (read (current-buffer)))
 319                 (and (symbolp obj) (fboundp obj) obj))))
 320         (error nil))
 321       (condition-case ()
 322           (save-excursion
 323             (forward-sexp -1)
 324             (skip-chars-forward "'")
 325             (let ((obj (read (current-buffer))))
 326               (and (symbolp obj) (fboundp obj) obj)))
 327         (error nil))))
 328
 329 (defun describe-function (function)
 330   "Display the full documentation of FUNCTION (a symbol)."
 331   (interactive
 332    (let ((fn (function-called-at-point))
 333          (enable-recursive-minibuffers t)
 334          val)
 335      (setq val (completing-read (if fn
 336                                     (format "Describe function (default %s): " fn)
 337                                   "Describe function: ")
 338                                 obarray 'fboundp t))
 339      (list (if (equal val "")
 340                fn (intern val)))))
 341   (with-output-to-temp-buffer "*Help*"
 342     (prin1 function)
 343     (princ ": ")
 344     (let* ((def (symbol-function function))
 345            (beg (if (commandp def) "an interactive " "a ")))
 346       (princ (cond ((or (stringp def)
 347                         (vectorp def))
 348                     "a keyboard macro.")
 349                    ((subrp def)
 350                     (concat beg "built-in function."))
 351                    ((byte-code-function-p def)
 352                     (concat beg "compiled Lisp function."))
 353                    ((symbolp def)
 354                     (format "alias for `%s'." def))
 355                    ((eq (car-safe def) 'lambda)
 356                     (concat beg "Lisp function."))
 357                    ((eq (car-safe def) 'macro)
 358                     "a Lisp macro.")
 359                    ((eq (car-safe def) 'mocklisp)
 360                     "a mocklisp function.")
 361                    ((eq (car-safe def) 'autoload)
 362                     (format "%s autoloaded Lisp %s."
 363                             (if (commandp def) "an interactive" "an")
 364                             (if (nth 4 def) "macro" "function")
 365 ;;; Including the file name made this line too long.
 366 ;;;                         (nth 1 def)
 367                             ))
 368                    (t "")))
 369       (terpri)
 370       (let ((arglist (cond ((byte-code-function-p def)
 371                             (car (append def nil)))
 372                            ((eq (car-safe def) 'lambda)
 373                             (nth 1 def))
 374                            (t t))))
 375         (if (listp arglist)
 376             (progn
 377               (princ (cons function
 378                            (mapcar (lambda (arg)
 379                                      (if (memq arg '(&optional &rest))
 380                                          arg
 381                                        (intern (upcase (symbol-name arg)))))
 382                                    arglist)))
 383               (terpri))))
 384       (if (documentation function)
 385           (progn (terpri)
 386                  (princ (documentation function)))
 387         (princ "not documented"))
 388       )
 389     (print-help-return-message)
 390     ;; Return the text we displayed.
 391     (save-excursion (set-buffer standard-output) (buffer-string))))
 392
 393 (defun variable-at-point ()
 394   (condition-case ()
 395       (save-excursion
 396         (forward-sexp -1)
 397         (skip-chars-forward "'")
 398         (let ((obj (read (current-buffer))))
 399           (and (symbolp obj) (boundp obj) obj)))
 400     (error nil)))
 401
 402 (defun describe-variable (variable)
 403   "Display the full documentation of VARIABLE (a symbol).
 404 Returns the documentation as a string, also."
 405   (interactive
 406    (let ((v (variable-at-point))
 407          (enable-recursive-minibuffers t)
 408          val)
 409      (setq val (completing-read (if v
 410                                     (format "Describe variable (default %s): " v)
 411                                   "Describe variable: ")
 412                                 obarray 'boundp t))
 413      (list (if (equal val "")
 414                v (intern val)))))
 415   (with-output-to-temp-buffer "*Help*"
 416     (prin1 variable)
 417     (princ "'s value is ")
 418     (if (not (boundp variable))
 419         (princ "void.")
 420       (prin1 (symbol-value variable)))
 421     (terpri) (terpri)
 422     (princ "Documentation:")
 423     (terpri)
 424     (let ((doc (documentation-property variable 'variable-documentation)))
 425       (if doc
 426           (princ (substitute-command-keys doc))
 427         (princ "not documented as a variable.")))
 428     (print-help-return-message)
 429     ;; Return the text we displayed.
 430     (save-excursion (set-buffer standard-output) (buffer-string))))
 431
 432 (defun where-is (definition)
 433   "Print message listing key sequences that invoke specified command.
 434 Argument is a command definition, usually a symbol with a function definition."
 435   (interactive
 436    (let ((fn (function-called-at-point))
 437          (enable-recursive-minibuffers t)
 438          val)
 439      (setq val (completing-read (if fn
 440                                     (format "Where is command (default %s): " fn)
 441                                   "Where is command: ")
 442                                 obarray 'fboundp t))
 443      (list (if (equal val "")
 444                fn (intern val)))))
 445   (let* ((keys (where-is-internal definition overriding-local-map nil nil))
 446          (keys1 (mapconcat 'key-description keys ", ")))
 447     (if (> (length keys1) 0)
 448         (message "%s is on %s" definition keys1)
 449       (message "%s is not on any key" definition)))
 450   nil)
 451
 452 (defun command-apropos (string)
 453   "Like apropos but lists only symbols that are names of commands
 454 \(interactively callable functions).  Argument REGEXP is a regular expression
 455 that is matched against command symbol names.  Returns list of symbols and
 456 documentation found."
 457   (interactive "sCommand apropos (regexp): ")
 458   (let ((message
 459          (let ((standard-output (get-buffer-create "*Help*")))
 460            (print-help-return-message 'identity))))
 461     (if (apropos string t 'commandp)
 462         (and message (message message)))))
 463
 464 (defun locate-library (library &optional nosuffix)
 465   "Show the full path name of Emacs library LIBRARY.
 466 This command searches the directories in `load-path' like `M-x load-library'
 467 to find the file that `M-x load-library RET LIBRARY RET' would load.
 468 Optional second arg NOSUFFIX non-nil means don't add suffixes `.elc' or `.el'
 469 to the specified name LIBRARY (a la calling `load' instead of `load-library')."
 470   (interactive "sLocate library: ")
 471   (catch 'answer
 472     (mapcar
 473      '(lambda (dir)
 474         (mapcar
 475          '(lambda (suf)
 476             (let ((try (expand-file-name (concat library suf) dir)))
 477               (and (file-readable-p try)
 478                    (null (file-directory-p try))
 479                    (progn
 480                      (message "Library is file %s" try)
 481                      (throw 'answer try)))))
 482          (if nosuffix '("") '(".elc" ".el" ""))))
 483      load-path)
 484     (message "No library %s in search path" library)
 485     nil))
 486
 487 ;;; help.el ends here