configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 150 if test "$with_wide_int" = yes; then
 151   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 152 fi
 153
 154 dnl _ON results in a '--without' option in the --help output, so
 155 dnl the help text should refer to "don't compile", etc.
 156 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 157 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 158 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 159 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 160 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 161 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 162 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 163 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 164
 165 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 166 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 167 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 168
 169 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 170 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 171 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 172 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 173
 174 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 175 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 176 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 177 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 178 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 179 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## Makefile.in needs the cache file name.
 187 AC_SUBST(cache_file)
 188
 189 ## This is an option because I do not know if all info/man support
 190 ## compressed files, nor how to test if they do so.
 191 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 192 if test $with_compress_info = yes; then
 193    GZIP_INFO=yes
 194 else
 195    GZIP_INFO=
 196 fi
 197 AC_SUBST(GZIP_INFO)
 198
 199 AC_ARG_WITH([pkg-config-prog],dnl
 200 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 201                   [path to pkg-config for finding GTK and librsvg])])
 202 if test "X${with_pkg_config_prog}" != X; then
 203    if test "${with_pkg_config_prog}" != yes; then
 204       PKG_CONFIG="${with_pkg_config_prog}"
 205    fi
 206 fi
 207
 208 CRT_DIR=
 209 AC_ARG_WITH([crt-dir],dnl
 210 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 211 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 212 CRT_DIR="${with_crt_dir}"
 213
 214 AC_ARG_WITH(gameuser,dnl
 215 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 216 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 217   && gameuser="${with_gameuser}"
 218 test "X$gameuser" = X && gameuser=games
 219
 220 AC_ARG_WITH([gnustep-conf],dnl
 221 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 222 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 223   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 224 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 225      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 226
 227 AC_ARG_ENABLE(ns-self-contained,
 228 [AS_HELP_STRING([--disable-ns-self-contained],
 229                 [disable self contained build under NeXTstep])],
 230    EN_NS_SELF_CONTAINED=$enableval,
 231    EN_NS_SELF_CONTAINED=yes)
 232
 233 AC_ARG_ENABLE(asserts,
 234 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 235       USE_XASSERTS=$enableval,
 236       USE_XASSERTS=no)
 237
 238 AC_ARG_ENABLE(locallisppath,
 239 [AS_HELP_STRING([--enable-locallisppath=PATH],
 240                 [directories Emacs should search for lisp files specific
 241                  to this site])],
 242 if test "${enableval}" = "no"; then
 243   locallisppath=
 244 elif test "${enableval}" != "yes"; then
 245   locallisppath=${enableval}
 246 fi)
 247
 248 AC_ARG_ENABLE(checking,
 249 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 250                 [enable expensive run-time checks.  With LIST,
 251                  enable only specific categories of checks.
 252                  Categories are: all,yes,no.
 253                  Flags are: stringbytes, stringoverrun, stringfreelist,
 254                  xmallocoverrun, conslist])],
 255 [ac_checking_flags="${enableval}"],[])
 256 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 257 for check in $ac_checking_flags
 258 do
 259         case $check in
 260         # these set all the flags to specific states
 261         yes)            ac_enable_checking=1 ;;
 262         no)             ac_enable_checking= ;
 263                         ac_gc_check_stringbytes= ;
 264                         ac_gc_check_string_overrun= ;
 265                         ac_gc_check_string_free_list= ;
 266                         ac_xmalloc_overrun= ;
 267                         ac_gc_check_cons_list= ;;
 268         all)            ac_enable_checking=1 ;
 269                         ac_gc_check_stringbytes=1 ;
 270                         ac_gc_check_string_overrun=1 ;
 271                         ac_gc_check_string_free_list=1 ;
 272                         ac_xmalloc_overrun=1 ;
 273                         ac_gc_check_cons_list=1 ;;
 274         # these enable particular checks
 275         stringbytes)    ac_gc_check_stringbytes=1 ;;
 276         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 277         stringfreelist) ac_gc_check_string_free_list=1 ;;
 278         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 279         conslist)       ac_gc_check_cons_list=1 ;;
 280         *)      AC_MSG_ERROR(unknown check category $check) ;;
 281         esac
 282 done
 283 IFS="$ac_save_IFS"
 284
 285 if test x$ac_enable_checking != x ; then
 286   AC_DEFINE(ENABLE_CHECKING, 1,
 287 [Enable expensive run-time checking of data types?])
 288 fi
 289 if test x$ac_gc_check_stringbytes != x ; then
 290   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 291 [Define this temporarily to hunt a bug.  If defined, the size of
 292    strings is redundantly recorded in sdata structures so that it can
 293    be compared to the sizes recorded in Lisp strings.])
 294 fi
 295 if test x$ac_gc_check_string_overrun != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 297 [Define this to check for short string overrun.])
 298 fi
 299 if test x$ac_gc_check_string_free_list != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 301 [Define this to check the string free list.])
 302 fi
 303 if test x$ac_xmalloc_overrun != x ; then
 304   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 305 [Define this to check for malloc buffer overrun.])
 306 fi
 307 if test x$ac_gc_check_cons_list != x ; then
 308   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 309 [Define this to check for errors in cons list.])
 310 fi
 311
 312 AC_ARG_ENABLE(use-lisp-union-type,
 313 [AS_HELP_STRING([--enable-use-lisp-union-type],
 314                 [use a union for the Lisp_Object data type.
 315                 This is only useful for development for catching certain types of bugs.])],
 316 if test "${enableval}" != "no"; then
 317    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 318    [Define this to use a lisp union for the Lisp_Object data type.])
 319 fi)
 320
 321
 322 AC_ARG_ENABLE(profiling,
 323 [AS_HELP_STRING([--enable-profiling],
 324                 [build emacs with profiling support.
 325                  This might not work on all platforms])],
 326 [ac_enable_profiling="${enableval}"],[])
 327 if test x$ac_enable_profiling != x ; then
 328    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 329 else
 330    PROFILING_CFLAGS=
 331 fi
 332 AC_SUBST(PROFILING_CFLAGS)
 333
 334 AC_ARG_ENABLE(autodepend,
 335 [AS_HELP_STRING([--enable-autodepend],
 336                 [automatically generate dependencies to .h-files.
 337                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 338                  found])],
 339 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 340
 341 #### Make srcdir absolute, if it isn't already.  It's important to
 342 #### avoid running the path through pwd unnecessarily, since pwd can
 343 #### give you automounter prefixes, which can go away.  We do all this
 344 #### so Emacs can find its files when run uninstalled.
 345 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 346 unset CDPATH
 347 case "${srcdir}" in
 348   /* ) ;;
 349   . )
 350     ## We may be able to use the $PWD environment variable to make this
 351     ## absolute.  But sometimes PWD is inaccurate.
 352     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 353     ## but that tested only for a well-formed and valid PWD,
 354     ## it did not object when PWD was well-formed and valid but just wrong.
 355     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 356     then
 357       srcdir="$PWD"
 358     else
 359       srcdir="`(cd ${srcdir}; pwd)`"
 360     fi
 361   ;;
 362   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 363 esac
 364
 365 #### Given the configuration name, set opsysfile to the
 366 #### name of s/*.h file we should use.
 367
 368 ### Canonicalize the configuration name.
 369
 370 AC_CANONICAL_HOST
 371 canonical=$host
 372 configuration=${host_alias-${build_alias-$host}}
 373
 374 dnl This used to use changequote, but, apart from `changequote is evil'
 375 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 376 dnl the great gob of text.  Thus it's not processed for possible expansion.
 377 dnl Just make sure the brackets remain balanced.
 378 dnl
 379 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 380 dnl indicated by comments.
 381 dnl quotation begins
 382 [
 383
 384 ### If you add support for a new configuration, add code to this
 385 ### switch statement to recognize your configuration name and select
 386 ### the appropriate operating system file.
 387
 388 ### You would hope that you could choose an s/*.h
 389 ### file based on the operating system portion.  However, it turns out
 390 ### that each s/*.h file is pretty manufacturer-specific.
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## GNU/Linux and similar ports
 404   *-*-linux* )
 405     opsys=gnu-linux
 406   ;;
 407
 408   ## FreeBSD ports
 409   *-*-freebsd* )
 410     opsys=freebsd
 411   ;;
 412
 413   ## FreeBSD kernel + glibc based userland
 414   *-*-kfreebsd*gnu* )
 415     opsys=gnu-kfreebsd
 416   ;;
 417
 418   ## NetBSD ports
 419   *-*-netbsd* )
 420     opsys=netbsd
 421   ;;
 422
 423   ## OpenBSD ports
 424   *-*-openbsd* )
 425     opsys=openbsd
 426   ;;
 427
 428   ## Apple Darwin / Mac OS X
 429   *-apple-darwin* )
 430     case "${canonical}" in
 431       i[3456]86-* )  ;;
 432       powerpc-* )    ;;
 433       x86_64-* )     ;;
 434       * )            unported=yes ;;
 435     esac
 436     opsys=darwin
 437     ## Use fink packages if available.
 438     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 439 ##    if test -d /sw/include && test -d /sw/lib; then
 440 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 441 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 442 ##    fi
 443   ;;
 444
 445   ## HP 9000 series 700 and 800, running HP/UX
 446   hppa*-hp-hpux10.2* )
 447     opsys=hpux10-20
 448   ;;
 449   hppa*-hp-hpux1[1-9]* )
 450     opsys=hpux11
 451     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 452   ;;
 453
 454   ## IBM machines
 455   rs6000-ibm-aix4.[23]* )
 456     opsys=aix4-2
 457   ;;
 458   powerpc-ibm-aix4.[23]*  )
 459     opsys=aix4-2
 460   ;;
 461   rs6000-ibm-aix[56]* )
 462     opsys=aix4-2
 463   ;;
 464   powerpc-ibm-aix[56]*  )
 465     opsys=aix4-2
 466   ;;
 467
 468   ## Silicon Graphics machines
 469   ## Iris 4D
 470   mips-sgi-irix6.5 )
 471     opsys=irix6-5
 472     # Without defining _LANGUAGE_C, things get masked out in the headers
 473     # so that, for instance, grepping for `free' in stdlib.h fails and
 474     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 475     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 476   ;;
 477
 478   ## Suns
 479   *-sun-solaris* \
 480     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 481     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 482     case "${canonical}" in
 483       i[3456]86-*-* )   ;;
 484       amd64-*-*|x86_64-*-*) ;;
 485       sparc* )          ;;
 486       * )               unported=yes ;;
 487     esac
 488     case "${canonical}" in
 489       *-sunos5.6* | *-solaris2.6* )
 490                 opsys=sol2-6
 491                 RANLIB="ar -ts"
 492                 ;;
 493       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 494                 opsys=sol2-6
 495                 emacs_check_sunpro_c=yes
 496                 ;;
 497       *-sunos5* | *-solaris* )
 498                 opsys=sol2-10
 499                 emacs_check_sunpro_c=yes
 500                 ;;
 501     esac
 502     ## Watch out for a compiler that we know will not work.
 503     case "${canonical}" in
 504      *-solaris* | *-sunos5* )
 505                 if [ "x$CC" = x/usr/ucb/cc ]; then
 506                   ## /usr/ucb/cc doesn't work;
 507                   ## we should find some other compiler that does work.
 508                   unset CC
 509                 fi
 510                 ;;
 511       *) ;;
 512     esac
 513   ;;
 514
 515   ## Intel 386 machines where we don't care about the manufacturer.
 516   i[3456]86-*-* )
 517     case "${canonical}" in
 518       *-cygwin )                opsys=cygwin ;;
 519       *-darwin* )               opsys=darwin ;;
 520       *-sysv4.2uw* )            opsys=unixware ;;
 521       *-sysv5uw* )              opsys=unixware ;;
 522       *-sysv5OpenUNIX* )        opsys=unixware ;;
 523       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 524     esac
 525   ;;
 526
 527   * )
 528     unported=yes
 529   ;;
 530 esac
 531
 532 ### If the code above didn't choose an operating system, just choose
 533 ### an operating system based on the configuration name.  You really
 534 ### only want to use this when you have no idea what the right
 535 ### operating system is; if you know what operating systems a machine
 536 ### runs, it's cleaner to make it explicit in the case statement
 537 ### above.
 538 if test x"${opsys}" = x; then
 539   case "${canonical}" in
 540     *-gnu* )                            opsys=gnu ;;
 541     * )
 542       unported=yes
 543     ;;
 544   esac
 545 fi
 546
 547 ]
 548 dnl quotation ends
 549
 550 if test $unported = yes; then
 551   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 552 Check `etc/MACHINES' for recognized configuration names.])
 553 fi
 554
 555 opsysfile="s/${opsys}.h"
 556
 557
 558 #### Choose a compiler.
 559
 560 dnl Sets GCC=yes if using gcc.
 561 AC_PROG_CC
 562 AM_PROG_CC_C_O
 563
 564 if test x$GCC = xyes; then
 565   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 566 else
 567   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 568 fi
 569
 570 # Initialize gnulib right after choosing the compiler.
 571 gl_EARLY
 572
 573 AC_ARG_ENABLE([gcc-warnings],
 574   [AS_HELP_STRING([--enable-gcc-warnings],
 575                   [turn on lots of GCC warnings (for developers)])],
 576   [case $enableval in
 577      yes|no) ;;
 578      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 579    esac
 580    gl_gcc_warnings=$enableval],
 581   [gl_gcc_warnings=no]
 582 )
 583
 584 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 585 # ------------------------------------------------
 586 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 587 # Otherwise, run RUN-IF-NOT-FOUND.
 588 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 589   [AC_PREPROC_IFELSE(
 590     [AC_LANG_PROGRAM(
 591       [[
 592 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 593 /* ok */
 594 #else
 595 # error "your version of gcc is older than $1.$2"
 596 #endif
 597       ]]),
 598     ], [$3], [$4])
 599   ]
 600 )
 601
 602 # When compiling with GCC, prefer -isystem to -I when including system
 603 # include files, to avoid generating useless diagnostics for the files.
 604 if test "$gl_gcc_warnings" != yes; then
 605   isystem='-I'
 606 else
 607   isystem='-isystem '
 608
 609   # This, $nw, is the list of warnings we disable.
 610   nw=
 611
 612   case $with_x_toolkit in
 613     lucid | athena | motif)
 614        # Old toolkits mishandle 'const'.
 615        nw="$nw -Wwrite-strings"
 616        ;;
 617     *)
 618        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 619        ;;
 620   esac
 621   AC_SUBST([WERROR_CFLAGS])
 622
 623   nw="$nw -Waggregate-return"       # anachronistic
 624   nw="$nw -Wlong-long"              # C90 is anachronistic
 625   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 626   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 627   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 628   nw="$nw -Wcast-qual"              # Too many warnings for now
 629   nw="$nw -Wconversion"             # Too many warnings for now
 630   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 631   nw="$nw -Wsign-conversion"        # Too many warnings for now
 632   nw="$nw -Woverlength-strings"     # Not a problem these days
 633   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 634   nw="$nw -Wpadded"                 # Our structs are not padded
 635   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 636   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 637   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 638   nw="$nw -Wvla"                    # warnings in gettext.h
 639   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 640   nw="$nw -Wswitch-enum"            # Too many warnings for now
 641   nw="$nw -Wswitch-default"         # Too many warnings for now
 642   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 643   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 644
 645   # Emacs doesn't care about shadowing; see
 646   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 647   nw="$nw -Wshadow"
 648
 649   # The following lines should be removable at some point.
 650   nw="$nw -Wstack-protector"
 651   nw="$nw -Wstrict-overflow"
 652   nw="$nw -Wsuggest-attribute=const"
 653   nw="$nw -Wsuggest-attribute=pure"
 654
 655   gl_MANYWARN_ALL_GCC([ws])
 656   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 657   for w in $ws; do
 658     gl_WARN_ADD([$w])
 659   done
 660   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 661   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 662   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 663   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 664   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 665   gl_WARN_ADD([-Wno-format-nonliteral])
 666
 667   # In spite of excluding -Wlogical-op above, it is enabled, as of
 668   # gcc 4.5.0 20090517.
 669   gl_WARN_ADD([-Wno-logical-op])
 670
 671   gl_WARN_ADD([-fdiagnostics-show-option])
 672   gl_WARN_ADD([-funit-at-a-time])
 673
 674   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 675   AC_DEFINE([_FORTIFY_SOURCE], [2],
 676     [enable compile-time and run-time bounds-checking, and some warnings])
 677   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 678
 679   # We use a slightly smaller set of warning options for lib/.
 680   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 681   nw=
 682   nw="$nw -Wunused-macros"
 683
 684   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 685   AC_SUBST([GNULIB_WARN_CFLAGS])
 686 fi
 687
 688
 689
 690 dnl Some other nice autoconf tests.
 691 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 692 dnl AC_PROG_INSTALL
 693 dnl AC_PROG_MKDIR_P
 694 dnl if test "x$RANLIB" = x; then
 695 dnl   AC_PROG_RANLIB
 696 dnl fi
 697
 698 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 699   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 700 dnl Don't use GZIP, which is used by gzip for additional parameters.
 701 AC_PATH_PROG(GZIP_PROG, gzip)
 702 AC_PATH_PROG(PAXCTL, paxctl,,
 703   [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 704
 705
 706 ## Need makeinfo >= 4.7 (?) to build the manuals.
 707 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 708 dnl By this stage, configure has already checked for egrep and set EGREP,
 709 dnl or exited with an error if no egrep was found.
 710 if test "$MAKEINFO" != "no" && \
 711   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 712    MAKEINFO=no
 713 fi
 714
 715 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 716 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 717 ## therefore in the category of "special tools" not normally required, which
 718 ## configure does not have to check for (eg autoconf itself).
 719 ## In a Bazaar checkout on the other hand, the manuals are not included.
 720 ## So makeinfo is a requirement to build from Bazaar, and configure
 721 ## should test for it as it does for any other build requirement.
 722 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 723 ## with pre-built manuals, from a Bazaar checkout.
 724 HAVE_MAKEINFO=yes
 725
 726 if test "$MAKEINFO" = "no"; then
 727   MAKEINFO=makeinfo
 728   if test "x${with_makeinfo}" = "xno"; then
 729     HAVE_MAKEINFO=no
 730   elif test ! -e $srcdir/info/emacs; then
 731     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 732 source tree does not seem to have pre-built manuals in the `info' directory.
 733 Either install a suitable version of makeinfo, or re-run configure
 734 with the `--without-makeinfo' option to build without the manuals.] )
 735   fi
 736 fi
 737 AC_SUBST(HAVE_MAKEINFO)
 738
 739 dnl Just so that there is only a single place we need to edit.
 740 INFO_EXT=.info
 741 INFO_OPTS=--no-split
 742 AC_SUBST(INFO_EXT)
 743 AC_SUBST(INFO_OPTS)
 744
 745 dnl Add our options to ac_link now, after it is set up.
 746
 747 if test x$GCC = xyes; then
 748   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 749     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 750 else
 751   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 752     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 753 fi
 754
 755 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 756 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 757 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 758 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 759 dnl if not built to support GNU ld.
 760
 761 late_LDFLAGS=$LDFLAGS
 762 if test x$GCC = xyes; then
 763   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 764 else
 765   LDFLAGS="$LDFLAGS -znocombreloc"
 766 fi
 767
 768 AC_MSG_CHECKING([for -znocombreloc])
 769 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 770   [AC_MSG_RESULT(yes)],
 771   LDFLAGS=$late_LDFLAGS
 772   [AC_MSG_RESULT(no)])
 773
 774
 775 dnl The function dump-emacs will not be defined and temacs will do
 776 dnl (load "loadup") automatically unless told otherwise.
 777 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 778 case "$opsys" in
 779   your-opsys-here) CANNOT_DUMP=yes ;;
 780 esac
 781
 782 test "$CANNOT_DUMP" = "yes" && \
 783   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 784
 785 AC_SUBST(CANNOT_DUMP)
 786
 787
 788 UNEXEC_OBJ=unexelf.o
 789 case "$opsys" in
 790   # MSDOS uses unexcoff.o
 791   # MSWindows uses unexw32.o
 792   aix4-2)
 793    UNEXEC_OBJ=unexaix.o
 794    ;;
 795   cygwin)
 796    UNEXEC_OBJ=unexcw.o
 797    ;;
 798   darwin)
 799    UNEXEC_OBJ=unexmacosx.o
 800    ;;
 801   hpux10-20 | hpux11)
 802    UNEXEC_OBJ=unexhp9k800.o
 803    ;;
 804   sol2-10)
 805    # Use the Solaris dldump() function, called from unexsol.c, to dump
 806    # emacs, instead of the generic ELF dump code found in unexelf.c.
 807    # The resulting binary has a complete symbol table, and is better
 808    # for debugging and other observability tools (debuggers, pstack, etc).
 809    #
 810    # If you encounter a problem using dldump(), please consider sending
 811    # a message to the OpenSolaris tools-linking mailing list:
 812    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 813    #
 814    # It is likely that dldump() works with older Solaris too, but this has
 815    # not been tested, so for now this change is for Solaris 10 or newer.
 816    UNEXEC_OBJ=unexsol.o
 817    ;;
 818 esac
 819
 820 LD_SWITCH_SYSTEM=
 821 case "$opsys" in
 822   freebsd)
 823    ## Let `ld' find image libs and similar things in /usr/local/lib.
 824    ## The system compiler, GCC, has apparently been modified to not
 825    ## look there, contrary to what a stock GCC would do.
 826 ### It's not our place to do this.  See bug#10313#17.
 827 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 828       :
 829    ;;
 830
 831   gnu-linux)
 832    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 833    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 834    ;;
 835
 836   netbsd)
 837 ### It's not our place to do this.  See bug#10313#17.
 838 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 839       :
 840    ;;
 841
 842   openbsd)
 843    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 844    ## otherwise Emacs dumps core on elf systems.
 845    LD_SWITCH_SYSTEM="-Z"
 846    ;;
 847 esac
 848 AC_SUBST(LD_SWITCH_SYSTEM)
 849
 850 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 851
 852 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 853 ## which has not been defined yet.  When this was handled with cpp,
 854 ## it was expanded to null when configure sourced the s/*.h file.
 855 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 856 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 857 ## (or somesuch), but because it is supposed to go at the _front_
 858 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 859 ## Compare with the gnu-linux case below, which added to the end
 860 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 861 ## LD_SWITCH_SYSTEM_TEMACS.
 862 case "$opsys" in
 863   netbsd|openbsd)
 864    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 865 esac
 866
 867
 868 C_SWITCH_MACHINE=
 869 case $canonical in
 870  alpha*)
 871   AC_CHECK_DECL([__ELF__])
 872   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 873     ## With ELF, make sure that all common symbols get allocated to in the
 874     ## data section.  Otherwise, the dump of temacs may miss variables in
 875     ## the shared library that have been initialized.  For example, with
 876     ## GNU libc, __malloc_initialized would normally be resolved to the
 877     ## shared library's .bss section, which is fatal.
 878     if test "x$GCC" = "xyes"; then
 879       C_SWITCH_MACHINE="-fno-common"
 880     else
 881       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 882     fi
 883   else
 884     UNEXEC_OBJ=unexalpha.o
 885   fi
 886   ;;
 887 esac
 888 AC_SUBST(C_SWITCH_MACHINE)
 889
 890 AC_SUBST(UNEXEC_OBJ)
 891
 892 C_SWITCH_SYSTEM=
 893 ## Some programs in src produce warnings saying certain subprograms
 894 ## are too complex and need a MAXMEM value greater than 2000 for
 895 ## additional optimization.  --nils@exp-math.uni-essen.de
 896 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 897   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 898 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 899 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 900 AC_SUBST(C_SWITCH_SYSTEM)
 901
 902
 903 LIBS_SYSTEM=
 904 case "$opsys" in
 905   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 906   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 907
 908   freebsd) LIBS_SYSTEM="-lutil" ;;
 909
 910   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 911
 912   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 913
 914   ## Motif needs -lgen.
 915   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 916 esac
 917 AC_SUBST(LIBS_SYSTEM)
 918
 919
 920 ### Make sure subsequent tests use flags consistent with the build flags.
 921
 922 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 923   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 924 else
 925   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 926 fi
 927
 928 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 929 AC_DEFUN([AC_TYPE_SIZE_T])
 930 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 931 AC_DEFUN([AC_TYPE_UID_T])
 932
 933
 934 LIB_MATH=-lm
 935 LIB_STANDARD=
 936 START_FILES=
 937 dnl Current possibilities handled by sed (aix4-2 -> aix,
 938 dnl gnu-linux -> gnu/linux, etc.):
 939 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 940 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 941 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 942
 943 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 944 case $opsys in
 945   cygwin )
 946     LIB_MATH=
 947     START_FILES='pre-crt0.o'
 948     ;;
 949   darwin )
 950     ## Adding -lm confuses the dynamic linker, so omit it.
 951     LIB_MATH=
 952     START_FILES='pre-crt0.o'
 953     ;;
 954   freebsd )
 955     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 956     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 957     SYSTEM_TYPE=berkeley-unix
 958     ;;
 959   gnu-linux | gnu-kfreebsd )
 960     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 961     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 962     ;;
 963   hpux10-20 | hpux11 )
 964     LIB_STANDARD=-lc
 965     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
 966     ;;
 967   dnl NB this may be adjusted below.
 968   netbsd | openbsd )
 969     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
 970     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
 971     SYSTEM_TYPE=berkeley-unix
 972     ;;
 973
 974   sol2* | unixware )
 975     SYSTEM_TYPE=usg-unix-v
 976     ;;
 977
 978 esac
 979
 980 AC_SUBST(LIB_MATH)
 981 AC_SUBST(START_FILES)
 982 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
 983   [The type of system you are compiling for; sets `system-type'.])
 984
 985 dnl Not all platforms use crtn.o files.  Check if the current one does.
 986 crt_files=
 987
 988 for file in x $LIB_STANDARD $START_FILES; do
 989   case "$file" in
 990     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
 991   esac
 992 done
 993
 994 if test "x$crt_files" != x; then
 995
 996   ## If user specified a crt-dir, use that unconditionally.
 997   crt_gcc=no
 998
 999   if test "X$CRT_DIR" = "X"; then
1000
1001     CRT_DIR=/usr/lib            # default
1002
1003     case "$canonical" in
1004       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1005       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1006       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1007       ## For anything else (eg /usr/lib32), it is up the user to specify
1008       ## the location (bug#5655).
1009       ## Test for crtn.o, not just the directory, because sometimes the
1010       ## directory exists but does not have the relevant files (bug#1287).
1011       ## FIXME better to test for binary compatibility somehow.
1012       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1013       ;;
1014
1015       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1016     esac
1017
1018     case "$opsys" in
1019       hpux10-20) CRT_DIR=/lib ;;
1020     esac
1021
1022     test "x${GCC}" = xyes && crt_gcc=yes
1023
1024   fi                            # CRT_DIR = ""
1025
1026   crt_missing=
1027
1028   for file in $crt_files; do
1029
1030     ## If we're using gcc, try to determine it automatically by asking
1031     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1032     ## system-dependent default from above.]
1033     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1034
1035        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1036        case "$crt_file" in
1037          */*)
1038            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1039            ;;
1040        esac
1041     fi
1042
1043     dnl We expect all the files to be in a single directory, so after the
1044     dnl first there is no point asking gcc.
1045     crt_gcc=no
1046
1047     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1048   done                          # $crt_files
1049
1050   test "x$crt_missing" = x || \
1051     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1052 Try using the --with-crt-dir option.])
1053
1054 fi                              # crt_files != ""
1055
1056 AC_SUBST(CRT_DIR)
1057
1058 case $opsys in
1059   netbsd | openbsd )
1060     if test -f $CRT_DIR/crti.o; then
1061
1062         test -f $CRT_DIR/crtn.o || \
1063           AC_MSG_ERROR([Required file not found: crtn.o])
1064
1065         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1066         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1067     fi
1068     ;;
1069 esac
1070
1071
1072 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1073
1074 dnl This function definition taken from Gnome 2.0
1075 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1076 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1077 dnl also defines GSTUFF_PKG_ERRORS on error
1078 AC_DEFUN([PKG_CHECK_MODULES], [
1079   succeeded=no
1080
1081   if test "$PKG_CONFIG" = "no" ; then
1082      ifelse([$4], , [AC_MSG_ERROR([
1083       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1084   else
1085      PKG_CONFIG_MIN_VERSION=0.9.0
1086      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1087         AC_MSG_CHECKING(for $2)
1088
1089         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1090            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1091            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1092             edit_cflags="
1093               s,///*,/,g
1094               s/^/ /
1095               s/ -I/ $isystem/g
1096               s/^ //
1097             "
1098             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1099             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1100             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1101             succeeded=yes
1102         else
1103             AC_MSG_RESULT(no)
1104             $1_CFLAGS=""
1105             $1_LIBS=""
1106             ## If we have a custom action on failure, don't print errors, but
1107             ## do set a variable so people can do so.
1108             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1109             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1110         fi
1111
1112         AC_SUBST($1_CFLAGS)
1113         AC_SUBST($1_LIBS)
1114      else
1115         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1116         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1117      fi
1118   fi
1119
1120   if test $succeeded = yes; then
1121      ifelse([$3], , :, [$3])
1122   else
1123      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1124   fi
1125 ])
1126
1127
1128 if test "${with_sound}" != "no"; then
1129   # Sound support for GNU/Linux and the free BSDs.
1130   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1131     have_sound_header=yes)
1132   # Emulation library used on NetBSD.
1133   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1134   AC_SUBST(LIBSOUND)
1135
1136   ALSA_REQUIRED=1.0.0
1137   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1138   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1139   if test $HAVE_ALSA = yes; then
1140     SAVE_CFLAGS="$CFLAGS"
1141     SAVE_LIBS="$LIBS"
1142     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1143     LIBS="$ALSA_LIBS $LIBS"
1144     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1145                     emacs_alsa_normal=yes,
1146                     emacs_alsa_normal=no)
1147     if test "$emacs_alsa_normal" != yes; then
1148       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1149                      [[snd_lib_error_set_handler (0);]])],
1150                      emacs_alsa_subdir=yes,
1151                      emacs_alsa_subdir=no)
1152       if test "$emacs_alsa_subdir" != yes; then
1153         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1154       fi
1155       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1156     fi
1157
1158     CFLAGS="$SAVE_CFLAGS"
1159     LIBS="$SAVE_LIBS"
1160     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1161     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1162     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1163   fi
1164
1165   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1166   dnl compiles only on the specified platforms.  For others, it
1167   dnl probably doesn't make sense to try.
1168   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1169      case "$opsys" in
1170        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1171        gnu-linux|freebsd|netbsd)
1172          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1173          ;;
1174      esac
1175   fi
1176
1177   AC_SUBST(CFLAGS_SOUND)
1178 fi
1179
1180 dnl checks for header files
1181 AC_CHECK_HEADERS_ONCE(
1182   sys/select.h sys/time.h utime.h
1183   linux/version.h sys/systeminfo.h
1184   stdio_ext.h fcntl.h coff.h pty.h
1185   sys/vlimit.h sys/resource.h
1186   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1187
1188 AC_MSG_CHECKING(if personality LINUX32 can be set)
1189 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1190                emacs_cv_personality_linux32=yes,
1191                emacs_cv_personality_linux32=no)
1192 AC_MSG_RESULT($emacs_cv_personality_linux32)
1193
1194 if test $emacs_cv_personality_linux32 = yes; then
1195   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1196             [Define to 1 if personality LINUX32 can be set.])
1197 fi
1198
1199 dnl On Solaris 8 there's a compilation warning for term.h because
1200 dnl it doesn't define `bool'.
1201 AC_CHECK_HEADERS(term.h, , , -)
1202 AC_HEADER_TIME
1203 AC_CHECK_DECLS([sys_siglist])
1204 if test $ac_cv_have_decl_sys_siglist != yes; then
1205   # For Tru64, at least:
1206   AC_CHECK_DECLS([__sys_siglist])
1207   if test $ac_cv_have_decl___sys_siglist = yes; then
1208     AC_DEFINE(sys_siglist, __sys_siglist,
1209               [Define to any substitute for sys_siglist.])
1210   fi
1211 fi
1212 AC_HEADER_SYS_WAIT
1213
1214 dnl Some systems have utime.h but don't declare the struct anyplace.
1215 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1216 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1217 #include <sys/time.h>
1218 #include <time.h>
1219 #else
1220 #ifdef HAVE_SYS_TIME_H
1221 #include <sys/time.h>
1222 #else
1223 #include <time.h>
1224 #endif
1225 #endif
1226 #ifdef HAVE_UTIME_H
1227 #include <utime.h>
1228 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1229   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1230 if test $emacs_cv_struct_utimbuf = yes; then
1231   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1232 fi
1233
1234 dnl Check for speed_t typedef.
1235 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1236   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1237     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1238 if test $emacs_cv_speed_t = yes; then
1239   AC_DEFINE(HAVE_SPEED_T, 1,
1240            [Define to 1 if `speed_t' is declared by <termios.h>.])
1241 fi
1242
1243 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1244 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1245 #include <sys/time.h>
1246 #include <time.h>
1247 #else
1248 #ifdef HAVE_SYS_TIME_H
1249 #include <sys/time.h>
1250 #else
1251 #include <time.h>
1252 #endif
1253 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1254   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1255 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1256 if test $emacs_cv_struct_timeval = yes; then
1257   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1258 fi
1259
1260 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1261 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1262 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1263   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1264 HAVE_EXCEPTION=$emacs_cv_struct_exception
1265 if test $emacs_cv_struct_exception != yes; then
1266   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1267 fi
1268
1269 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1270 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1271 #if HAVE_SYS_SOCKET_H
1272 #include <sys/socket.h>
1273 #endif])
1274 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1275 #if HAVE_SYS_SOCKET_H
1276 #include <sys/socket.h>
1277 #endif])
1278 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1279 #if HAVE_SYS_SOCKET_H
1280 #include <sys/socket.h>
1281 #endif])
1282
1283 dnl checks for structure members
1284 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1285                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1286                   struct ifreq.ifr_addr,
1287                   struct ifreq.ifr_addr.sa_len], , ,
1288                  [AC_INCLUDES_DEFAULT
1289 #if HAVE_SYS_SOCKET_H
1290 #include <sys/socket.h>
1291 #endif
1292 #if HAVE_NET_IF_H
1293 #include <net/if.h>
1294 #endif])
1295
1296 dnl Check for endianness.
1297 dnl AC_C_BIGENDIAN is done by gnulib.
1298
1299 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1300   [emacs_cv_attribute_aligned],
1301   [AC_COMPILE_IFELSE(
1302      [AC_LANG_PROGRAM(
1303         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1304         [[]])],
1305      [emacs_cv_attribute_aligned=yes],
1306      [emacs_cv_attribute_aligned=no])])
1307 if test $emacs_cv_attribute_aligned = yes; then
1308   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1309     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1310 fi
1311
1312 dnl check for Make feature
1313 dnl AC_PROG_MAKE_SET is done by Automake.
1314
1315 DEPFLAGS=
1316 MKDEPDIR=":"
1317 deps_frag=deps.mk
1318 dnl check for GNU Make if we have GCC and autodepend is on.
1319 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1320    AC_MSG_CHECKING([whether we are using GNU Make])
1321    HAVE_GNU_MAKE=no
1322    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1323    if test "x$testval" != x; then
1324       HAVE_GNU_MAKE=yes
1325    else
1326       ac_enable_autodepend=no
1327    fi
1328    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1329    if test $HAVE_GNU_MAKE = yes; then
1330       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1331       SAVE_CFLAGS="$CFLAGS"
1332       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1333       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1334       CFLAGS="$SAVE_CFLAGS"
1335       test -f deps.d || ac_enable_autodepend=no
1336       rm -rf deps.d
1337       AC_MSG_RESULT([$ac_enable_autodepend])
1338    fi
1339    if test $ac_enable_autodepend = yes; then
1340       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1341       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1342       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1343       deps_frag=autodeps.mk
1344    fi
1345 fi
1346 deps_frag=$srcdir/src/$deps_frag
1347 AC_SUBST(MKDEPDIR)
1348 AC_SUBST(DEPFLAGS)
1349 AC_SUBST_FILE(deps_frag)
1350
1351
1352 lisp_frag=$srcdir/src/lisp.mk
1353 AC_SUBST_FILE(lisp_frag)
1354
1355
1356 dnl checks for operating system services
1357 AC_SYS_LONG_FILE_NAMES
1358
1359 #### Choose a window system.
1360
1361 AC_PATH_X
1362 if test "$no_x" = yes; then
1363   window_system=none
1364 else
1365   window_system=x11
1366 fi
1367
1368 LD_SWITCH_X_SITE_RPATH=
1369 if test "${x_libraries}" != NONE; then
1370   if test -n "${x_libraries}"; then
1371     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1372     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1373   fi
1374   x_default_search_path=""
1375   x_search_path=${x_libraries}
1376   if test -z "${x_search_path}"; then
1377     x_search_path=/usr/lib
1378   fi
1379   for x_library in `echo ${x_search_path}: | \
1380                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1381     x_search_path="\
1382 ${x_library}/X11/%L/%T/%N%C%S:\
1383 ${x_library}/X11/%l/%T/%N%C%S:\
1384 ${x_library}/X11/%T/%N%C%S:\
1385 ${x_library}/X11/%L/%T/%N%S:\
1386 ${x_library}/X11/%l/%T/%N%S:\
1387 ${x_library}/X11/%T/%N%S"
1388     if test x"${x_default_search_path}" = x; then
1389       x_default_search_path=${x_search_path}
1390     else
1391       x_default_search_path="${x_search_path}:${x_default_search_path}"
1392     fi
1393   done
1394 fi
1395 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1396
1397 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1398   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1399 fi
1400
1401 if test x"${x_includes}" = x; then
1402   bitmapdir=/usr/include/X11/bitmaps
1403 else
1404   # accumulate include directories that have X11 bitmap subdirectories
1405   bmd_acc="dummyval"
1406   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1407     if test -d "${bmd}/X11/bitmaps"; then
1408       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1409     fi
1410     if test -d "${bmd}/bitmaps"; then
1411       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1412     fi
1413   done
1414   if test ${bmd_acc} != "dummyval"; then
1415     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1416   fi
1417 fi
1418
1419 HAVE_NS=no
1420 NS_IMPL_COCOA=no
1421 NS_IMPL_GNUSTEP=no
1422 tmp_CPPFLAGS="$CPPFLAGS"
1423 tmp_CFLAGS="$CFLAGS"
1424 CPPFLAGS="$CPPFLAGS -x objective-c"
1425 CFLAGS="$CFLAGS -x objective-c"
1426 TEMACS_LDFLAGS2="\${LDFLAGS}"
1427 GNU_OBJC_CFLAGS=
1428 if test "${with_ns}" != no; then
1429   if test "${opsys}" = darwin; then
1430      NS_IMPL_COCOA=yes
1431      ns_appdir=`pwd`/nextstep/Emacs.app
1432      ns_appbindir=${ns_appdir}/Contents/MacOS
1433      ns_appresdir=${ns_appdir}/Contents/Resources
1434      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1435   elif test -f $GNUSTEP_CONFIG_FILE; then
1436      NS_IMPL_GNUSTEP=yes
1437      ns_appdir=`pwd`/nextstep/Emacs.app
1438      ns_appbindir=${ns_appdir}
1439      ns_appresdir=${ns_appdir}/Resources
1440      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1441      dnl FIXME sourcing this several times in subshells seems inefficient.
1442      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1443      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1444      dnl I seemed to need these as well with GNUstep-startup 0.25.
1445      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1446      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1447      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1448        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1449      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1450        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1451      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1452      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1453      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1454      LIB_STANDARD=
1455      START_FILES=
1456      TEMACS_LDFLAGS2=
1457      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1458      dnl If they had chosen to either define it or not, we could have
1459      dnl just used AC_CHECK_DECL here.
1460      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1461        emacs_cv_objc_exceptions,
1462 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1463 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1464 1;
1465 #else
1466 fail;
1467 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1468      if test $emacs_cv_objc_exceptions = yes; then
1469        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1470        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1471          [Define if GNUstep uses ObjC exceptions.])
1472        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1473      fi
1474   fi
1475
1476   dnl This is only used while we test the NS headers, it gets reset below.
1477   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1478
1479   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1480                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1481   files are missing or cannot be compiled.])])
1482   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1483                                      [NSInteger i;])],
1484                     ns_have_nsinteger=yes,
1485                     ns_have_nsinteger=no)
1486   if test $ns_have_nsinteger = yes; then
1487     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1488   fi
1489 fi
1490 AC_SUBST(TEMACS_LDFLAGS2)
1491
1492 INSTALL_ARCH_INDEP_EXTRA=install-etc
1493 ns_self_contained=no
1494 ns_frag=/dev/null
1495 NS_OBJ=
1496 NS_OBJC_OBJ=
1497 if test "${HAVE_NS}" = yes; then
1498   if test "$with_toolkit_scroll_bars" = "no"; then
1499     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1500   fi
1501
1502   window_system=nextstep
1503   with_xft=no
1504   # set up packaging dirs
1505   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1506      ns_self_contained=yes
1507      prefix=${ns_appresdir}
1508      exec_prefix=${ns_appbindir}
1509      dnl This one isn't really used, only archlibdir is.
1510      libexecdir="\${ns_appbindir}/libexec"
1511      archlibdir="\${ns_appbindir}/libexec"
1512      docdir="\${ns_appresdir}/etc"
1513      etcdir="\${ns_appresdir}/etc"
1514      dnl FIXME maybe set datarootdir instead.
1515      dnl That would also get applications, icons, man.
1516      infodir="\${ns_appresdir}/info"
1517      mandir="\${ns_appresdir}/man"
1518      lispdir="\${ns_appresdir}/lisp"
1519      leimdir="\${ns_appresdir}/leim"
1520      INSTALL_ARCH_INDEP_EXTRA=
1521   fi
1522   ns_frag=$srcdir/src/ns.mk
1523   NS_OBJ="fontset.o fringe.o image.o"
1524   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1525 fi
1526 CFLAGS="$tmp_CFLAGS"
1527 CPPFLAGS="$tmp_CPPFLAGS"
1528 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1529 AC_SUBST(ns_self_contained)
1530 AC_SUBST(NS_OBJ)
1531 AC_SUBST(NS_OBJC_OBJ)
1532 AC_SUBST(LIB_STANDARD)
1533 AC_SUBST_FILE(ns_frag)
1534
1535 case "${window_system}" in
1536   x11 )
1537     HAVE_X_WINDOWS=yes
1538     HAVE_X11=yes
1539     case "${with_x_toolkit}" in
1540       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1541       motif ) USE_X_TOOLKIT=MOTIF ;;
1542       gtk ) with_gtk=yes
1543 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1544 dnl USE_X_TOOLKIT is set.
1545             USE_X_TOOLKIT=none ;;
1546       gtk3 ) with_gtk3=yes
1547              USE_X_TOOLKIT=none ;;
1548       no ) USE_X_TOOLKIT=none ;;
1549 dnl If user did not say whether to use a toolkit, make this decision later:
1550 dnl use the toolkit if we have gtk, or X11R5 or newer.
1551       * ) USE_X_TOOLKIT=maybe ;;
1552     esac
1553   ;;
1554   nextstep | none )
1555     HAVE_X_WINDOWS=no
1556     HAVE_X11=no
1557     USE_X_TOOLKIT=none
1558   ;;
1559 esac
1560
1561 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1562    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1563    if test "$HAVE_XSERVER" = true ||
1564       test -n "$DISPLAY" ||
1565       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1566         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1567 were found.  You should install the relevant development files for X
1568 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1569 sure you have development files for image handling, i.e.
1570 tiff, gif, jpeg, png and xpm.
1571 If you are sure you want Emacs compiled without X window support, pass
1572   --without-x
1573 to configure.])
1574    fi
1575 fi
1576
1577 ### If we're using X11, we should use the X menu package.
1578 HAVE_MENUS=no
1579 case ${HAVE_X11} in
1580   yes ) HAVE_MENUS=yes ;;
1581 esac
1582
1583 # Does the opsystem file prohibit the use of the GNU malloc?
1584 # Assume not, until told otherwise.
1585 GNU_MALLOC=yes
1586
1587 AC_CACHE_CHECK(
1588   [whether malloc is Doug Lea style],
1589   [emacs_cv_var_doug_lea_malloc],
1590   [AC_LINK_IFELSE(
1591      [AC_LANG_PROGRAM(
1592         [[#include <malloc.h>
1593           static void hook (void) {}]],
1594         [[malloc_set_state (malloc_get_state ());
1595           __after_morecore_hook = hook;
1596           __malloc_initialize_hook = hook;]])],
1597      [emacs_cv_var_doug_lea_malloc=yes],
1598      [emacs_cv_var_doug_lea_malloc=no])])
1599 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1600
1601
1602 dnl See comments in aix4-2.h about maybe using system malloc there.
1603 system_malloc=no
1604 case "$opsys" in
1605   ## darwin ld insists on the use of malloc routines in the System framework.
1606   darwin|sol2-10) system_malloc=yes ;;
1607 esac
1608
1609 if test "${system_malloc}" = "yes"; then
1610   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1611   GNU_MALLOC=no
1612   GNU_MALLOC_reason="
1613     (The GNU allocators don't work with this system configuration.)"
1614   GMALLOC_OBJ=
1615   VMLIMIT_OBJ=
1616 else
1617   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1618   VMLIMIT_OBJ=vm-limit.o
1619 fi
1620 AC_SUBST(GMALLOC_OBJ)
1621 AC_SUBST(VMLIMIT_OBJ)
1622
1623 if test "$doug_lea_malloc" = "yes" ; then
1624   if test "$GNU_MALLOC" = yes ; then
1625     GNU_MALLOC_reason="
1626       (Using Doug Lea's new malloc from the GNU C Library.)"
1627   fi
1628   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1629             [Define to 1 if you are using the GNU C Library.])
1630
1631   ## Use mmap directly for allocating larger buffers.
1632   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1633   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1634   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1635   case "$opsys" in
1636     gnu*) REL_ALLOC=no ;;
1637   esac
1638 fi
1639
1640 if test x"${REL_ALLOC}" = x; then
1641   REL_ALLOC=${GNU_MALLOC}
1642 fi
1643
1644 use_mmap_for_buffers=no
1645 case "$opsys" in
1646   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1647 esac
1648
1649 AC_FUNC_MMAP
1650 if test $use_mmap_for_buffers = yes; then
1651   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1652   REL_ALLOC=no
1653 fi
1654
1655 LIBS="$LIBS_SYSTEM $LIBS"
1656
1657 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1658 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1659 AC_CHECK_LIB(dnet, dnet_ntoa)
1660 dnl This causes -lresolv to get used in subsequent tests,
1661 dnl which causes failures on some systems such as HPUX 9.
1662 dnl AC_CHECK_LIB(resolv, gethostbyname)
1663
1664 dnl FIXME replace main with a function we actually want from this library.
1665 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1666
1667 dnl Check if pthreads is available.
1668 LIB_PTHREAD=
1669 AC_CHECK_HEADERS_ONCE(pthread.h)
1670 if test "$ac_cv_header_pthread_h"; then
1671   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1672   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1673   dnl testing for pthread_self if Emacs uses gmalloc.c.
1674   if test "$GMALLOC_OBJ" = gmalloc.o; then
1675     emacs_pthread_function=pthread_atfork
1676   else
1677     emacs_pthread_function=pthread_self
1678   fi
1679   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1680 fi
1681 if test "$HAVE_PTHREAD" = yes; then
1682   case "${canonical}" in
1683     *-hpux*) ;;
1684     *) LIB_PTHREAD="-lpthread"
1685        LIBS="$LIB_PTHREAD $LIBS" ;;
1686   esac
1687   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1688 fi
1689 AC_SUBST([LIB_PTHREAD])
1690
1691 AC_CHECK_LIB(pthreads, cma_open)
1692
1693 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1694 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1695 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1696 ## added to LIBS in configure would never contain the pthreads part,
1697 ## but the value used in Makefiles might.  FIXME?
1698 ##
1699 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1700 ## be harmless on older versions of X where it happens to exist.
1701 test "$opsys" = "aix4-2" && \
1702   test $ac_cv_lib_pthreads_cma_open = yes && \
1703   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1704
1705 dnl Check for need for bigtoc support on IBM AIX
1706
1707 case ${host_os} in
1708 aix*)
1709   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1710     case $GCC in
1711     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1712     *) gdb_cv_bigtoc=-bbigtoc ;;
1713     esac
1714
1715     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1716     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1717   ])
1718   ;;
1719 esac
1720
1721 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1722 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1723 # REAL_CPPFLAGS later on.
1724
1725 REAL_CFLAGS="$CFLAGS"
1726 REAL_CPPFLAGS="$CPPFLAGS"
1727
1728 if test "${HAVE_X11}" = "yes"; then
1729   DEFS="$C_SWITCH_X_SITE $DEFS"
1730   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1731   LIBS="-lX11 $LIBS"
1732   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1733   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1734
1735   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1736   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1737   # but it's more convenient here to set LD_RUN_PATH since this
1738   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1739   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1740     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1741     export LD_RUN_PATH
1742   fi
1743
1744   if test "${opsys}" = "gnu-linux"; then
1745     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1746     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1747      [[XOpenDisplay ("foo");]])],
1748      [xgnu_linux_first_failure=no],
1749      [xgnu_linux_first_failure=yes])
1750     if test "${xgnu_linux_first_failure}" = "yes"; then
1751       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1752       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1753       OLD_CPPFLAGS="$CPPFLAGS"
1754       OLD_LIBS="$LIBS"
1755       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1756       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1757       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1758       LIBS="$LIBS -b i486-linuxaout"
1759       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1760        [[XOpenDisplay ("foo");]])],
1761        [xgnu_linux_second_failure=no],
1762        [xgnu_linux_second_failure=yes])
1763       if test "${xgnu_linux_second_failure}" = "yes"; then
1764         # If we get the same failure with -b, there is no use adding -b.
1765         # So take it out.  This plays safe.
1766         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1767         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1768         CPPFLAGS="$OLD_CPPFLAGS"
1769         LIBS="$OLD_LIBS"
1770         AC_MSG_RESULT(no)
1771       else
1772         AC_MSG_RESULT(yes)
1773       fi
1774     else
1775       AC_MSG_RESULT(no)
1776     fi
1777   fi
1778
1779   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1780   # header files included from there.
1781   AC_MSG_CHECKING(for Xkb)
1782   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1783 #include <X11/XKBlib.h>]],
1784         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1785         emacs_xkb=yes, emacs_xkb=no)
1786   AC_MSG_RESULT($emacs_xkb)
1787   if test $emacs_xkb = yes; then
1788     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1789   fi
1790
1791   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1792 XScreenNumberOfScreen)
1793 fi
1794
1795 if test "${window_system}" = "x11"; then
1796   AC_MSG_CHECKING(X11 version 6)
1797   AC_CACHE_VAL(emacs_cv_x11_version_6,
1798   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1799 [[#if XlibSpecificationRelease < 6
1800 fail;
1801 #endif
1802 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1803   if test $emacs_cv_x11_version_6 = yes; then
1804     AC_MSG_RESULT(6 or newer)
1805     AC_DEFINE(HAVE_X11R6, 1,
1806               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1807     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1808     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1809     ## XIM support.
1810     case "$opsys" in
1811       sol2-*) : ;;
1812       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1813            [Define if you have usable X11R6-style XIM support.])
1814          ;;
1815     esac
1816   else
1817     AC_MSG_RESULT(before 6)
1818   fi
1819 fi
1820
1821
1822 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1823 HAVE_RSVG=no
1824 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1825   if test "${with_rsvg}" != "no"; then
1826     RSVG_REQUIRED=2.11.0
1827     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1828
1829     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1830     AC_SUBST(RSVG_CFLAGS)
1831     AC_SUBST(RSVG_LIBS)
1832
1833     if test $HAVE_RSVG = yes; then
1834       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1835       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1836       LIBS="$RSVG_LIBS $LIBS"
1837     fi
1838   fi
1839 fi
1840
1841 HAVE_IMAGEMAGICK=no
1842 if test "${HAVE_X11}" = "yes"; then
1843   if test "${with_imagemagick}" != "no"; then
1844     ## 6.2.8 is the earliest version known to work, but earlier versions
1845     ## might work - let us know if you find one.
1846     ## 6.0.7 does not work.  See bug#7955.
1847     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1848     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1849     AC_SUBST(IMAGEMAGICK_CFLAGS)
1850     AC_SUBST(IMAGEMAGICK_LIBS)
1851
1852     if test $HAVE_IMAGEMAGICK = yes; then
1853       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1854       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1855       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1856       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1857     fi
1858   fi
1859 fi
1860
1861
1862 HAVE_GTK=no
1863 GTK_OBJ=
1864 if test "${with_gtk3}" = "yes"; then
1865   GLIB_REQUIRED=2.28
1866   GTK_REQUIRED=3.0
1867   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1868
1869   dnl Checks for libraries.
1870   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1871   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1872      AC_MSG_ERROR($GTK_PKG_ERRORS)
1873   fi
1874   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1875   GTK_OBJ=emacsgtkfixed.o
1876 fi
1877
1878 if test "$pkg_check_gtk" != "yes"; then
1879   HAVE_GTK=no
1880 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1881   GLIB_REQUIRED=2.10
1882   GTK_REQUIRED=2.10
1883   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1884
1885   dnl Checks for libraries.
1886   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1887   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1888      AC_MSG_ERROR($GTK_PKG_ERRORS)
1889   fi
1890 fi
1891 fi
1892
1893 if test x"$pkg_check_gtk" = xyes; then
1894
1895   AC_SUBST(GTK_CFLAGS)
1896   AC_SUBST(GTK_LIBS)
1897   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1898   CFLAGS="$CFLAGS $GTK_CFLAGS"
1899   LIBS="$GTK_LIBS $LIBS"
1900   dnl Try to compile a simple GTK program.
1901   GTK_COMPILES=no
1902   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1903   if test "${GTK_COMPILES}" != "yes"; then
1904     if test "$USE_X_TOOLKIT" != "maybe"; then
1905       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1906     fi
1907   else
1908     HAVE_GTK=yes
1909     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1910     GTK_OBJ="gtkutil.o $GTK_OBJ"
1911     USE_X_TOOLKIT=none
1912     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1913       :
1914     else
1915       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1916        closing open displays.  This is no problem if you just use
1917        one display, but if you use more than one and close one of them
1918        Emacs may crash.]])
1919       sleep 3
1920     fi
1921   fi
1922
1923 fi
1924 AC_SUBST(GTK_OBJ)
1925
1926
1927 if test "${HAVE_GTK}" = "yes"; then
1928
1929   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1930   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1931   if test "$with_toolkit_scroll_bars" != no; then
1932     with_toolkit_scroll_bars=yes
1933   fi
1934
1935   dnl  Check if we have the old file selection dialog declared and
1936   dnl  in the link library.  In 2.x it may be in the library,
1937   dnl  but not declared if deprecated featured has been selected out.
1938   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1939   HAVE_GTK_FILE_SELECTION=no
1940   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1941                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1942 #include <gtk/gtk.h>])
1943   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1944     AC_CHECK_FUNCS(gtk_file_selection_new)
1945   fi
1946
1947
1948   dnl Check for functions introduced in 2.14 and later.
1949   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1950                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1951                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1952                  gtk_orientable_set_orientation \
1953                  gtk_window_set_has_resize_grip)
1954 fi
1955
1956 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1957 dnl other platforms.
1958 HAVE_DBUS=no
1959 DBUS_OBJ=
1960 if test "${with_dbus}" = "yes"; then
1961    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1962    if test "$HAVE_DBUS" = yes; then
1963      LIBS="$LIBS $DBUS_LIBS"
1964      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1965      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1966      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1967      dnl D-Bus 1.5.12.
1968      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1969                     dbus_type_is_valid \
1970                     dbus_validate_bus_name \
1971                     dbus_validate_path \
1972                     dbus_validate_interface \
1973                     dbus_validate_member)
1974      DBUS_OBJ=dbusbind.o
1975    fi
1976 fi
1977 AC_SUBST(DBUS_OBJ)
1978
1979 dnl GSettings has been tested under GNU/Linux only.
1980 HAVE_GSETTINGS=no
1981 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1982    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1983    if test "$HAVE_GSETTINGS" = "yes"; then
1984       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1985       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1986       SETTINGS_LIBS="$GSETTINGS_LIBS"
1987    fi
1988 fi
1989
1990 dnl GConf has been tested under GNU/Linux only.
1991 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1992 HAVE_GCONF=no
1993 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1994    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1995    if test "$HAVE_GCONF" = yes; then
1996       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1997       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1998       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1999       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2000    fi
2001 fi
2002
2003 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2004     SAVE_CFLAGS="$CFLAGS"
2005     SAVE_LIBS="$LIBS"
2006     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2007     LIBS="$SETTINGS_LIBS $LIBS"
2008     AC_CHECK_FUNCS([g_type_init])
2009     CFLAGS="$SAVE_CFLAGS"
2010     LIBS="$SAVE_LIBS"
2011 fi
2012 AC_SUBST(SETTINGS_CFLAGS)
2013 AC_SUBST(SETTINGS_LIBS)
2014
2015
2016 dnl SELinux is available for GNU/Linux only.
2017 HAVE_LIBSELINUX=no
2018 LIBSELINUX_LIBS=
2019 if test "${with_selinux}" = "yes"; then
2020    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2021    if test "$HAVE_LIBSELINUX" = yes; then
2022       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2023       LIBSELINUX_LIBS=-lselinux
2024    fi
2025 fi
2026 AC_SUBST(LIBSELINUX_LIBS)
2027
2028 HAVE_GNUTLS=no
2029 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2030 if test "${with_gnutls}" = "yes" ; then
2031   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2032   if test "${HAVE_GNUTLS}" = "yes"; then
2033     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2034   fi
2035
2036   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2037   LIBS="$LIBGNUTLS_LIBS $LIBS"
2038   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2039
2040   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2041     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2042   fi
2043 fi
2044
2045 AC_SUBST(LIBGNUTLS_LIBS)
2046 AC_SUBST(LIBGNUTLS_CFLAGS)
2047
2048 dnl Do not put whitespace before the #include statements below.
2049 dnl Older compilers (eg sunos4 cc) choke on it.
2050 HAVE_XAW3D=no
2051 LUCID_LIBW=
2052 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2053   if test "$with_xaw3d" != no; then
2054     AC_MSG_CHECKING(for xaw3d)
2055     AC_CACHE_VAL(emacs_cv_xaw3d,
2056     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2057 #include <X11/Intrinsic.h>
2058 #include <X11/Xaw3d/Simple.h>]],
2059       [[]])],
2060       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2061                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2062       emacs_cv_xaw3d=no)])
2063   else
2064     emacs_cv_xaw3d=no
2065   fi
2066   if test $emacs_cv_xaw3d = yes; then
2067     AC_MSG_RESULT([yes; using Lucid toolkit])
2068     USE_X_TOOLKIT=LUCID
2069     HAVE_XAW3D=yes
2070     LUCID_LIBW=-lXaw3d
2071     AC_DEFINE(HAVE_XAW3D, 1,
2072               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2073   else
2074     AC_MSG_RESULT(no)
2075     AC_MSG_CHECKING(for libXaw)
2076     AC_CACHE_VAL(emacs_cv_xaw,
2077     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2078 #include <X11/Intrinsic.h>
2079 #include <X11/Xaw/Simple.h>]],
2080       [[]])],
2081       emacs_cv_xaw=yes,
2082       emacs_cv_xaw=no)])
2083     if test $emacs_cv_xaw = yes; then
2084       AC_MSG_RESULT([yes; using Lucid toolkit])
2085       USE_X_TOOLKIT=LUCID
2086       LUCID_LIBW=-lXaw
2087     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2088       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2089     else
2090       AC_MSG_ERROR([No X toolkit could be found.
2091 If you are sure you want Emacs compiled without an X toolkit, pass
2092   --with-x-toolkit=no
2093 to configure.  Otherwise, install the development libraries for the toolkit
2094 that you want to use (e.g. Gtk+) and re-run configure.])
2095     fi
2096   fi
2097 fi
2098
2099 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2100
2101 LIBXTR6=
2102 if test "${USE_X_TOOLKIT}" != "none"; then
2103   AC_MSG_CHECKING(X11 toolkit version)
2104   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2105   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2106 [[#if XtSpecificationRelease < 6
2107 fail;
2108 #endif
2109 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2110   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2111   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2112     AC_MSG_RESULT(6 or newer)
2113     AC_DEFINE(HAVE_X11XTR6, 1,
2114               [Define to 1 if you have the X11R6 or newer version of Xt.])
2115     LIBXTR6="-lSM -lICE"
2116     case "$opsys" in
2117       ## Use libw.a along with X11R6 Xt.
2118       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2119     esac
2120   else
2121     AC_MSG_RESULT(before 6)
2122   fi
2123
2124 dnl If using toolkit, check whether libXmu.a exists.
2125 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2126   OLDLIBS="$LIBS"
2127   if test x$HAVE_X11XTR6 = xyes; then
2128     LIBS="-lXt -lSM -lICE $LIBS"
2129   else
2130     LIBS="-lXt $LIBS"
2131   fi
2132   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2133   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2134 fi
2135 AC_SUBST(LIBXTR6)
2136
2137 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2138 dnl Why not just test for libxmu in the normal way?
2139 LIBXMU=-lXmu
2140 case $opsys in
2141   ## These systems don't supply Xmu.
2142   hpux* | aix4-2 )
2143     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2144     ;;
2145 esac
2146 AC_SUBST(LIBXMU)
2147
2148 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2149 if test "${HAVE_X11}" = "yes"; then
2150   if test "${USE_X_TOOLKIT}" != "none"; then
2151     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2152   fi
2153 fi
2154
2155 LIBXP=
2156 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2157   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2158   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2159     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2160 int x = 5;
2161 #else
2162 Motif version prior to 2.1.
2163 #endif]])],
2164     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2165   if test $emacs_cv_motif_version_2_1 = yes; then
2166     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2167   else
2168     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2169     # We put this in CFLAGS temporarily to precede other -I options
2170     # that might be in CFLAGS temporarily.
2171     # We put this in CPPFLAGS where it precedes the other -I options.
2172     OLD_CPPFLAGS=$CPPFLAGS
2173     OLD_CFLAGS=$CFLAGS
2174     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2175     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2176     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2177       [[int x = 5;]])],
2178       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2179     if test $emacs_cv_lesstif = yes; then
2180       # Make sure this -I option remains in CPPFLAGS after it is set
2181       # back to REAL_CPPFLAGS.
2182       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2183       # have those other -I options anyway.  Ultimately, having this
2184       # directory ultimately in CPPFLAGS will be enough.
2185       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2186       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2187     else
2188       CFLAGS=$OLD_CFLAGS
2189       CPPFLAGS=$OLD_CPPFLAGS
2190     fi
2191   fi
2192   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2193     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2194 fi
2195
2196 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2197 dnl using Motif or Xaw3d is available, and unless
2198 dnl --with-toolkit-scroll-bars=no was specified.
2199
2200 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2201             [Define to 1 if we should use toolkit scroll bars.])dnl
2202 USE_TOOLKIT_SCROLL_BARS=no
2203 if test "${with_toolkit_scroll_bars}" != "no"; then
2204   if test "${USE_X_TOOLKIT}" != "none"; then
2205     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2206       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2207       HAVE_XAW3D=no
2208       USE_TOOLKIT_SCROLL_BARS=yes
2209     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2210       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2211       USE_TOOLKIT_SCROLL_BARS=yes
2212     fi
2213   elif test "${HAVE_GTK}" = "yes"; then
2214     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2215     USE_TOOLKIT_SCROLL_BARS=yes
2216   elif test "${HAVE_NS}" = "yes"; then
2217     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2218     USE_TOOLKIT_SCROLL_BARS=yes
2219   fi
2220 fi
2221
2222 dnl See if XIM is available.
2223 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2224           #include <X11/Xlib.h>
2225           #include <X11/Xresource.h>]],
2226          [[XIMProc  callback;]])],
2227          [HAVE_XIM=yes
2228          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2229          HAVE_XIM=no)
2230
2231 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2232
2233 if test "${with_xim}" != "no"; then
2234   AC_DEFINE(USE_XIM, 1,
2235             [Define to 1 if we should use XIM, if it is available.])
2236 fi
2237
2238
2239 if test "${HAVE_XIM}" != "no"; then
2240   late_CFLAGS=$CFLAGS
2241   if test "$GCC" = yes; then
2242     CFLAGS="$CFLAGS --pedantic-errors"
2243   fi
2244   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2245 #include <X11/Xlib.h>
2246 #include <X11/Xresource.h>]],
2247 [[Display *display;
2248 XrmDatabase db;
2249 char *res_name;
2250 char *res_class;
2251 XIMProc  callback;
2252 XPointer *client_data;
2253 #ifndef __GNUC__
2254 /* If we're not using GCC, it's probably not XFree86, and this is
2255    probably right, but we can't use something like --pedantic-errors.  */
2256 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2257                                            char*, XIMProc, XPointer*);
2258 #endif
2259 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2260    client_data);]])],
2261     [emacs_cv_arg6_star=yes])
2262   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2263          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2264 either XPointer or XPointer*.])dnl
2265   if test "$emacs_cv_arg6_star" = yes; then
2266     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2267   else
2268     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2269   fi
2270   CFLAGS=$late_CFLAGS
2271 fi
2272
2273 ### Start of font-backend (under any platform) section.
2274 # (nothing here yet -- this is a placeholder)
2275 ### End of font-backend (under any platform) section.
2276
2277 ### Start of font-backend (under X11) section.
2278 if test "${HAVE_X11}" = "yes"; then
2279    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2280
2281    ## Use -lXft if available, unless `--with-xft=no'.
2282    HAVE_XFT=maybe
2283     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2284       with_xft="no";
2285     fi
2286     if test "x${with_xft}" != "xno"; then
2287
2288       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2289       ## Because xftfont.c uses XRenderQueryExtension, we also
2290       ## need to link to -lXrender.
2291       HAVE_XRENDER=no
2292       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2293       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2294         OLD_CPPFLAGS="$CPPFLAGS"
2295         OLD_CFLAGS="$CFLAGS"
2296         OLD_LIBS="$LIBS"
2297         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2298         CFLAGS="$CFLAGS $XFT_CFLAGS"
2299         XFT_LIBS="-lXrender $XFT_LIBS"
2300         LIBS="$XFT_LIBS $LIBS"
2301         AC_CHECK_HEADER(X11/Xft/Xft.h,
2302           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2303
2304         if test "${HAVE_XFT}" = "yes"; then
2305           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2306             AC_SUBST(XFT_LIBS)
2307           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2308         else
2309           CPPFLAGS="$OLD_CPPFLAGS"
2310           CFLAGS="$OLD_CFLAGS"
2311           LIBS="$OLD_LIBS"
2312         fi                        # "${HAVE_XFT}" = "yes"
2313       fi                          # "$HAVE_XFT" != no
2314     fi                            # "x${with_xft}" != "xno"
2315
2316     ## We used to allow building with FreeType and without Xft.
2317     ## However, the ftx font backend driver is not in good shape.
2318     if test "$HAVE_XFT" != "yes"; then
2319        dnl For the "Does Emacs use" message at the end.
2320        HAVE_XFT=no
2321        HAVE_FREETYPE=no
2322     else
2323        dnl Strict linkers fail with
2324        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2325        dnl if -lfreetype is not specified.
2326        dnl The following is needed to set FREETYPE_LIBS.
2327        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2328                          HAVE_FREETYPE=no)
2329
2330        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2331     fi
2332
2333     HAVE_LIBOTF=no
2334     if test "${HAVE_FREETYPE}" = "yes"; then
2335       AC_DEFINE(HAVE_FREETYPE, 1,
2336                 [Define to 1 if using the freetype and fontconfig libraries.])
2337       if test "${with_libotf}" != "no"; then
2338         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2339                           HAVE_LIBOTF=no)
2340         if test "$HAVE_LIBOTF" = "yes"; then
2341           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2342           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2343                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2344                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2345           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2346             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2347                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2348           fi
2349         fi
2350       fi
2351     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2352     dnl Does the new font backend require it, or can it work without it?
2353     fi
2354
2355     HAVE_M17N_FLT=no
2356     if test "${HAVE_LIBOTF}" = yes; then
2357       if test "${with_m17n_flt}" != "no"; then
2358         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2359         if test "$HAVE_M17N_FLT" = "yes"; then
2360           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2361         fi
2362       fi
2363     fi
2364 else
2365     HAVE_XFT=no
2366     HAVE_FREETYPE=no
2367     HAVE_LIBOTF=no
2368     HAVE_M17N_FLT=no
2369 fi
2370
2371 ### End of font-backend (under X11) section.
2372
2373 AC_SUBST(FREETYPE_CFLAGS)
2374 AC_SUBST(FREETYPE_LIBS)
2375 AC_SUBST(FONTCONFIG_CFLAGS)
2376 AC_SUBST(FONTCONFIG_LIBS)
2377 AC_SUBST(LIBOTF_CFLAGS)
2378 AC_SUBST(LIBOTF_LIBS)
2379 AC_SUBST(M17N_FLT_CFLAGS)
2380 AC_SUBST(M17N_FLT_LIBS)
2381
2382 ### Use -lXpm if available, unless `--with-xpm=no'.
2383 HAVE_XPM=no
2384 LIBXPM=
2385 if test "${HAVE_X11}" = "yes"; then
2386   if test "${with_xpm}" != "no"; then
2387     AC_CHECK_HEADER(X11/xpm.h,
2388       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2389     if test "${HAVE_XPM}" = "yes"; then
2390       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2391       AC_EGREP_CPP(no_return_alloc_pixels,
2392       [#include "X11/xpm.h"
2393 #ifndef XpmReturnAllocPixels
2394 no_return_alloc_pixels
2395 #endif
2396       ], HAVE_XPM=no, HAVE_XPM=yes)
2397
2398       if test "${HAVE_XPM}" = "yes"; then
2399         AC_MSG_RESULT(yes)
2400       else
2401         AC_MSG_RESULT(no)
2402       fi
2403     fi
2404   fi
2405
2406   if test "${HAVE_XPM}" = "yes"; then
2407     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2408     LIBXPM=-lXpm
2409   fi
2410 fi
2411 AC_SUBST(LIBXPM)
2412
2413 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2414 HAVE_JPEG=no
2415 LIBJPEG=
2416 if test "${HAVE_X11}" = "yes"; then
2417   if test "${with_jpeg}" != "no"; then
2418     dnl Checking for jpeglib.h can lose because of a redefinition of
2419     dnl  HAVE_STDLIB_H.
2420     AC_CHECK_HEADER(jerror.h,
2421       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2422   fi
2423
2424   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2425   if test "${HAVE_JPEG}" = "yes"; then
2426     AC_DEFINE(HAVE_JPEG)
2427     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2428         [#include <jpeglib.h>
2429          version=JPEG_LIB_VERSION
2430 ],
2431         [AC_DEFINE(HAVE_JPEG)],
2432         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2433         HAVE_JPEG=no])
2434   fi
2435   if test "${HAVE_JPEG}" = "yes"; then
2436     LIBJPEG=-ljpeg
2437   fi
2438 fi
2439 AC_SUBST(LIBJPEG)
2440
2441 ### Use -lpng if available, unless `--with-png=no'.
2442 HAVE_PNG=no
2443 LIBPNG=
2444 if test "${HAVE_X11}" = "yes"; then
2445   if test "${with_png}" != "no"; then
2446     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2447     # in /usr/include/libpng.
2448     AC_CHECK_HEADERS(png.h libpng/png.h)
2449     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2450       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2451     fi
2452   fi
2453
2454   if test "${HAVE_PNG}" = "yes"; then
2455     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2456     LIBPNG="-lpng -lz -lm"
2457   fi
2458 fi
2459 AC_SUBST(LIBPNG)
2460
2461 ### Use -ltiff if available, unless `--with-tiff=no'.
2462 HAVE_TIFF=no
2463 LIBTIFF=
2464 if test "${HAVE_X11}" = "yes"; then
2465   if test "${with_tiff}" != "no"; then
2466     AC_CHECK_HEADER(tiffio.h,
2467       [tifflibs="-lz -lm"
2468       # At least one tiff package requires the jpeg library.
2469       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2470       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2471   fi
2472
2473   if test "${HAVE_TIFF}" = "yes"; then
2474     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2475     dnl FIXME -lz -lm, as per libpng?
2476     LIBTIFF=-ltiff
2477   fi
2478 fi
2479 AC_SUBST(LIBTIFF)
2480
2481 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2482 HAVE_GIF=no
2483 LIBGIF=
2484 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2485   AC_CHECK_HEADER(gif_lib.h,
2486 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2487 # Earlier versions can crash Emacs.
2488     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2489
2490   if test "$HAVE_GIF" = yes; then
2491     LIBGIF=-lgif
2492   elif test "$HAVE_GIF" = maybe; then
2493 # If gif_lib.h but no libgif, try libungif.
2494     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2495     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2496   fi
2497
2498   if test "${HAVE_GIF}" = "yes"; then
2499     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2500   fi
2501 fi
2502 AC_SUBST(LIBGIF)
2503
2504 dnl Check for required libraries.
2505 if test "${HAVE_X11}" = "yes"; then
2506   MISSING=""
2507   WITH_NO=""
2508   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2509     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2510   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2511     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2512   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2513     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2514   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2515     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2516   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2517     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2518
2519   if test "X${MISSING}" != X; then
2520     AC_MSG_ERROR([The following required libraries were not found:
2521     $MISSING
2522 Maybe some development libraries/packages are missing?
2523 If you don't want to link with them give
2524     $WITH_NO
2525 as options to configure])
2526   fi
2527 fi
2528
2529 ### Use -lgpm if available, unless `--with-gpm=no'.
2530 HAVE_GPM=no
2531 LIBGPM=
2532 if test "${with_gpm}" != "no"; then
2533   AC_CHECK_HEADER(gpm.h,
2534     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2535
2536   if test "${HAVE_GPM}" = "yes"; then
2537     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2538     LIBGPM=-lgpm
2539   fi
2540 fi
2541 AC_SUBST(LIBGPM)
2542
2543 dnl Check for malloc/malloc.h on darwin
2544 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2545
2546 GNUSTEP_CFLAGS=
2547 ### Use NeXTstep API to implement GUI.
2548 if test "${HAVE_NS}" = "yes"; then
2549   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2550   if test "${NS_IMPL_COCOA}" = "yes"; then
2551     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2552   fi
2553   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2554     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2555     # See also .m.o rule in Makefile.in */
2556     # FIXME: are all these flags really needed?  Document here why.  */
2557     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2558     ## Extra CFLAGS applied to src/*.m files.
2559     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2560   fi
2561   # We also have mouse menus.
2562   HAVE_MENUS=yes
2563   OTHER_FILES=ns-app
2564 fi
2565
2566
2567 ### Use session management (-lSM -lICE) if available
2568 HAVE_X_SM=no
2569 LIBXSM=
2570 if test "${HAVE_X11}" = "yes"; then
2571   AC_CHECK_HEADER(X11/SM/SMlib.h,
2572     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2573
2574   if test "${HAVE_X_SM}" = "yes"; then
2575     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2576     LIBXSM="-lSM -lICE"
2577     case "$LIBS" in
2578       *-lSM*) ;;
2579       *)      LIBS="$LIBXSM $LIBS" ;;
2580     esac
2581   fi
2582 fi
2583 AC_SUBST(LIBXSM)
2584
2585 ### Use libxml (-lxml2) if available
2586 HAVE_LIBXML2=no
2587 if test "${with_xml2}" != "no"; then
2588   ### I'm not sure what the version number should be, so I just guessed.
2589   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2590   if test "${HAVE_LIBXML2}" = "yes"; then
2591     LIBS="$LIBXML2_LIBS $LIBS"
2592     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2593     if test "${HAVE_LIBXML2}" = "yes"; then
2594       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2595     else
2596       LIBXML2_LIBS=""
2597       LIBXML2_CFLAGS=""
2598     fi
2599   fi
2600 fi
2601 AC_SUBST(LIBXML2_LIBS)
2602 AC_SUBST(LIBXML2_CFLAGS)
2603
2604 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2605 AC_CACHE_CHECK(whether netdb declares h_errno,
2606                emacs_cv_netdb_declares_h_errno,
2607 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2608   [[return h_errno;]])],
2609   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2610 if test $emacs_cv_netdb_declares_h_errno = yes; then
2611   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2612 fi
2613
2614 # fmod, logb, and frexp are found in -lm on most systems.
2615 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2616 AC_CHECK_LIB(m, sqrt)
2617
2618 # Check for mail-locking functions in a "mail" library.  Probably this should
2619 # have the same check as for liblockfile below.
2620 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2621 if test $have_mail = yes; then
2622   LIBS_MAIL=-lmail
2623   LIBS="$LIBS_MAIL $LIBS"
2624   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2625 else
2626   LIBS_MAIL=
2627 fi
2628 dnl Debian, at least:
2629 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2630 if test $have_lockfile = yes; then
2631    LIBS_MAIL=-llockfile
2632    LIBS="$LIBS_MAIL $LIBS"
2633    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2634 else
2635 # If we have the shared liblockfile, assume we must use it for mail
2636 # locking (e.g. Debian).  If we couldn't link against liblockfile
2637 # (no liblockfile.a installed), ensure that we don't need to.
2638   dnl This works for files generally, not just executables.
2639   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2640   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2641                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2642   if test $ac_cv_prog_liblockfile = yes; then
2643     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2644 This probably means that movemail could lose mail.
2645 There may be a `development' package to install containing liblockfile.])
2646   fi
2647 fi
2648 AC_CHECK_HEADERS_ONCE(maillock.h)
2649 AC_SUBST(LIBS_MAIL)
2650
2651 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2652 ## interlock access to the mail spool.  The alternative is a lock file named
2653 ## /usr/spool/mail/$USER.lock.
2654 mail_lock=no
2655 case "$opsys" in
2656   aix4-2) mail_lock="lockf" ;;
2657
2658   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2659
2660   ## On GNU/Linux systems, both methods are used by various mail programs.
2661   ## I assume most people are using newer mailers that have heard of flock.
2662   ## Change this if you need to.
2663   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2664   ## configure gets the right answers, and that means *NOT* using flock.
2665   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2666   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2667   ## Debian maintainer hasn't provided a clean fix for Emacs.
2668   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2669   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2670   ## correct logic.  -- fx
2671   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2672   ## liblockfile is a Free Software replacement for libmail, used on
2673   ## Debian systems and elsewhere. -rfr.
2674   gnu-*)
2675     mail_lock="flock"
2676     if test $have_mail = yes || test $have_lockfile = yes; then
2677       test $ac_cv_header_maillock_h = yes && mail_lock=no
2678     fi
2679     ;;
2680 esac
2681
2682 BLESSMAIL_TARGET=
2683 case "$mail_lock" in
2684   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2685
2686   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2687
2688   *) BLESSMAIL_TARGET="need-blessmail" ;;
2689 esac
2690 AC_SUBST(BLESSMAIL_TARGET)
2691
2692
2693 AC_CHECK_FUNCS_ONCE(gethostname \
2694 rename closedir mkdir rmdir getrusage get_current_dir_name \
2695 random lrand48 logb frexp fmod rint cbrt setsid \
2696 strerror fpathconf select euidaccess getpagesize setlocale \
2697 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2698 __fpending strsignal setitimer \
2699 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2700 gai_strerror mkstemp getline getdelim fsync sync \
2701 difftime posix_memalign \
2702 getpwent endpwent getgrent endgrent \
2703 touchlock \
2704 cfmakeraw cfsetspeed copysign __executable_start)
2705
2706 dnl Cannot use AC_CHECK_FUNCS
2707 AC_CACHE_CHECK([for __builtin_unwind_init],
2708                emacs_cv_func___builtin_unwind_init,
2709 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2710                 emacs_cv_func___builtin_unwind_init=yes,
2711                 emacs_cv_func___builtin_unwind_init=no)])
2712 if test $emacs_cv_func___builtin_unwind_init = yes; then
2713   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2714             [Define to 1 if you have the `__builtin_unwind_init' function.])
2715 fi
2716
2717 AC_CHECK_HEADERS_ONCE(sys/un.h)
2718
2719 AC_FUNC_FSEEKO
2720
2721 AC_FUNC_GETPGRP
2722
2723 # UNIX98 PTYs.
2724 AC_CHECK_FUNCS_ONCE(grantpt)
2725
2726 # PTY-related GNU extensions.
2727 AC_CHECK_FUNCS_ONCE(getpt)
2728
2729 # Check this now, so that we will NOT find the above functions in ncurses.
2730 # That is because we have not set up to link ncurses in lib-src.
2731 # It's better to believe a function is not available
2732 # than to expect to find it in ncurses.
2733 # Also we need tputs and friends to be able to build at all.
2734 AC_MSG_CHECKING([for library containing tputs])
2735 # Run a test program that contains a call to tputs, a call that is
2736 # never executed.  This tests whether a pre-'main' dynamic linker
2737 # works with the library.  It's too much trouble to actually call
2738 # tputs in the test program, due to portability hassles.  When
2739 # cross-compiling, assume the test program will run if it links.
2740 AC_DEFUN([tputs_link_source], [
2741   AC_LANG_SOURCE(
2742      [[extern void tputs (const char *, int, int (*)(int));
2743        int main (int argc, char **argv)
2744        {
2745           if (argc == 10000)
2746             tputs (argv[0], 0, 0);
2747           return 0;
2748        }]])
2749 ])
2750 # Maybe curses should be tried earlier?
2751 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2752 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2753   OLIBS=$LIBS
2754   if test -z "$tputs_library"; then
2755     LIBS_TERMCAP=
2756     msg='none required'
2757   else
2758     LIBS_TERMCAP=-l$tputs_library
2759     msg=$LIBS_TERMCAP
2760     LIBS="$LIBS_TERMCAP $LIBS"
2761   fi
2762   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2763     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2764   LIBS=$OLIBS
2765   if test "X$msg" != Xno; then
2766     break
2767   fi
2768 done
2769 AC_MSG_RESULT([$msg])
2770 if test "X$msg" = Xno; then
2771   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2772 The following libraries were tried (in order):
2773   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2774 Please try installing whichever of these libraries is most appropriate
2775 for your system, together with its header files.
2776 For example, a libncurses-dev(el) or similar package.])
2777 fi
2778
2779 ## Use termcap instead of terminfo?
2780 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2781 TERMINFO=yes
2782 ## FIXME?  In the cases below where we unconditionally set
2783 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2784 ## if that was found above to have tputs.
2785 ## Should we use the gnu* logic everywhere?
2786 case "$opsys" in
2787   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2788   ##  The ncurses library has been moved out of the System framework in
2789   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2790   ##  option to use it.
2791   darwin) LIBS_TERMCAP="-lncurses" ;;
2792
2793   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2794
2795   freebsd)
2796     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2797     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2798     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2799 [[#if __FreeBSD_version < 400000
2800 fail;
2801 #endif
2802 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2803
2804     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2805
2806     if test $emacs_cv_freebsd_terminfo = yes; then
2807       LIBS_TERMCAP="-lncurses"
2808     else
2809       TERMINFO=no
2810       LIBS_TERMCAP="-ltermcap"
2811     fi
2812     ;;
2813
2814   netbsd)
2815     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2816       TERMINFO=no
2817       LIBS_TERMCAP="-ltermcap"
2818     fi
2819     ;;
2820
2821   openbsd) LIBS_TERMCAP="-lncurses" ;;
2822
2823   ## hpux: Make sure we get select from libc rather than from libcurses
2824   ##  because libcurses on HPUX 10.10 has a broken version of select.
2825   ##  We used to use -lc -lcurses, but this may be cleaner.
2826   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2827   # set that way, now it uses the default).  Isn't this a contradiction?
2828   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2829
2830 esac
2831
2832 TERMCAP_OBJ=tparam.o
2833 if test $TERMINFO = yes; then
2834   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2835   TERMCAP_OBJ=terminfo.o
2836 fi
2837 AC_SUBST(LIBS_TERMCAP)
2838 AC_SUBST(TERMCAP_OBJ)
2839
2840
2841 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2842 resolv=no
2843 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2844 #include <arpa/nameser.h>
2845 #include <resolv.h>]],
2846     [[return res_init();]])],
2847     have_res_init=yes, have_res_init=no)
2848 if test "$have_res_init" = no; then
2849   OLIBS="$LIBS"
2850   LIBS="$LIBS -lresolv"
2851   AC_MSG_CHECKING(for res_init with -lresolv)
2852   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2853 #include <arpa/nameser.h>
2854 #include <resolv.h>]],
2855     [[return res_init();]])],
2856     have_res_init=yes, have_res_init=no)
2857   AC_MSG_RESULT($have_res_init)
2858   if test "$have_res_init" = yes ; then
2859     resolv=yes
2860   fi
2861   LIBS="$OLIBS"
2862 fi
2863
2864 if test "$have_res_init" = yes; then
2865   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2866 fi
2867
2868 # Do we need the Hesiod library to provide the support routines?
2869 LIBHESIOD=
2870 if test "$with_hesiod" != no ; then
2871   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2872   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2873      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2874                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2875   if test "$resolv" = yes ; then
2876     RESOLVLIB=-lresolv
2877   else
2878     RESOLVLIB=
2879   fi
2880   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2881         hesiod=yes, :, $RESOLVLIB)])
2882
2883   if test x"$hesiod" = xyes; then
2884     AC_DEFINE(HAVE_LIBHESIOD, 1,
2885               [Define to 1 if you have the hesiod library (-lhesiod).])
2886     LIBHESIOD=-lhesiod
2887   fi
2888 fi
2889 AC_SUBST(LIBHESIOD)
2890
2891 # Do we need libresolv (due to res_init or Hesiod)?
2892 if test "$resolv" = yes ; then
2893   AC_DEFINE(HAVE_LIBRESOLV, 1,
2894             [Define to 1 if you have the resolv library (-lresolv).])
2895   LIBRESOLV=-lresolv
2896 else
2897   LIBRESOLV=
2898 fi
2899 AC_SUBST(LIBRESOLV)
2900
2901 # These tell us which Kerberos-related libraries to use.
2902 COM_ERRLIB=
2903 CRYPTOLIB=
2904 KRB5LIB=
2905 DESLIB=
2906 KRB4LIB=
2907
2908 if test "${with_kerberos}" != no; then
2909   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2910   if test $have_com_err = yes; then
2911     COM_ERRLIB=-lcom_err
2912     LIBS="$COM_ERRLIB $LIBS"
2913     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2914   fi
2915   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2916   if test $have_crypto = yes; then
2917     CRYPTOLIB=-lcrypto
2918     LIBS="$CRYPTOLIB $LIBS"
2919     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2920   fi
2921   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2922   if test $have_k5crypto = yes; then
2923     CRYPTOLIB=-lk5crypto
2924     LIBS="$CRYPTOLIB $LIBS"
2925     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2926   fi
2927   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2928   if test $have_krb5=yes; then
2929     KRB5LIB=-lkrb5
2930     LIBS="$KRB5LIB $LIBS"
2931     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2932   fi
2933   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2934   if test "${with_kerberos5}" = no; then
2935     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2936     if test $have_des425 = yes; then
2937       DESLIB=-ldes425
2938       LIBS="$DESLIB $LIBS"
2939       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2940     else
2941       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2942       if test $have_des = yes; then
2943         DESLIB=-ldes
2944         LIBS="$DESLIB $LIBS"
2945         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2946       fi
2947     fi
2948     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2949     if test $have_krb4 = yes; then
2950       KRB4LIB=-lkrb4
2951       LIBS="$KRB4LIB $LIBS"
2952       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2953     else
2954       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2955       if test $have_krb = yes; then
2956         KRB4LIB=-lkrb
2957         LIBS="$KRB4LIB $LIBS"
2958         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2959       fi
2960     fi
2961   fi
2962
2963   if test "${with_kerberos5}" != no; then
2964     AC_CHECK_HEADERS(krb5.h,
2965       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2966                         [#include <krb5.h>])])
2967   else
2968     AC_CHECK_HEADERS(des.h,,
2969                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2970                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2971     AC_CHECK_HEADERS(krb.h,,
2972                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2973                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2974   fi
2975   AC_CHECK_HEADERS(com_err.h)
2976 fi
2977
2978 AC_SUBST(COM_ERRLIB)
2979 AC_SUBST(CRYPTOLIB)
2980 AC_SUBST(KRB5LIB)
2981 AC_SUBST(DESLIB)
2982 AC_SUBST(KRB4LIB)
2983
2984 AC_CHECK_FUNCS_ONCE(tzset)
2985 AC_MSG_CHECKING(whether localtime caches TZ)
2986 AC_CACHE_VAL(emacs_cv_localtime_cache,
2987 [if test x$ac_cv_func_tzset = xyes; then
2988 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2989 char TZ_GMT0[] = "TZ=GMT0";
2990 char TZ_PST8[] = "TZ=PST8";
2991 main()
2992 {
2993   time_t now = time ((time_t *) 0);
2994   int hour_GMT0, hour_unset;
2995   if (putenv (TZ_GMT0) != 0)
2996     exit (1);
2997   hour_GMT0 = localtime (&now)->tm_hour;
2998   unsetenv("TZ");
2999   hour_unset = localtime (&now)->tm_hour;
3000   if (putenv (TZ_PST8) != 0)
3001     exit (1);
3002   if (localtime (&now)->tm_hour == hour_GMT0)
3003     exit (1);
3004   unsetenv("TZ");
3005   if (localtime (&now)->tm_hour != hour_unset)
3006     exit (1);
3007   exit (0);
3008 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3009 [# If we have tzset, assume the worst when cross-compiling.
3010 emacs_cv_localtime_cache=yes])
3011 else
3012         # If we lack tzset, report that localtime does not cache TZ,
3013         # since we can't invalidate the cache if we don't have tzset.
3014         emacs_cv_localtime_cache=no
3015 fi])dnl
3016 AC_MSG_RESULT($emacs_cv_localtime_cache)
3017 if test $emacs_cv_localtime_cache = yes; then
3018   AC_DEFINE(LOCALTIME_CACHE, 1,
3019             [Define to 1 if localtime caches TZ.])
3020 fi
3021
3022 if test "x$HAVE_TIMEVAL" = xyes; then
3023   AC_CHECK_FUNCS(gettimeofday)
3024   if test $ac_cv_func_gettimeofday = yes; then
3025     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3026                    emacs_cv_gettimeofday_two_arguments,
3027     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3028 #ifdef TIME_WITH_SYS_TIME
3029 #include <sys/time.h>
3030 #include <time.h>
3031 #else
3032 #ifdef HAVE_SYS_TIME_H
3033 #include <sys/time.h>
3034 #else
3035 #include <time.h>
3036 #endif
3037 #endif]],
3038       [[struct timeval time;
3039        gettimeofday (&time, 0);]])],
3040       emacs_cv_gettimeofday_two_arguments=yes,
3041       emacs_cv_gettimeofday_two_arguments=no)])
3042     if test $emacs_cv_gettimeofday_two_arguments = no; then
3043       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3044                 [Define to 1 if gettimeofday accepts only one argument.])
3045     fi
3046   fi
3047 fi
3048
3049 ok_so_far=yes
3050 AC_CHECK_FUNC(socket, , ok_so_far=no)
3051 if test $ok_so_far = yes; then
3052   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3053 fi
3054 if test $ok_so_far = yes; then
3055   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3056 fi
3057 if test $ok_so_far = yes; then
3058 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3059   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3060             [Define to 1 if you have inet sockets.])
3061 fi
3062
3063 if test -f /usr/lpp/X11/bin/smt.exp; then
3064   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3065             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3066 fi
3067
3068 AC_MSG_CHECKING(whether system supports dynamic ptys)
3069 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3070   AC_MSG_RESULT(yes)
3071   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3072 else
3073   AC_MSG_RESULT(no)
3074 fi
3075
3076 AC_FUNC_FORK
3077
3078 AC_CHECK_FUNCS_ONCE(snprintf)
3079
3080 dnl Adapted from Haible's version.
3081 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3082   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3083     [[char* cs = nl_langinfo(CODESET);]])],
3084     emacs_cv_langinfo_codeset=yes,
3085     emacs_cv_langinfo_codeset=no)
3086   ])
3087 if test $emacs_cv_langinfo_codeset = yes; then
3088   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3089     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3090 fi
3091
3092 AC_TYPE_MBSTATE_T
3093
3094 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3095   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3096                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3097 if test "$emacs_cv_c_restrict_arr" = yes; then
3098   AC_DEFINE(__restrict_arr, __restrict,
3099     [Define to compiler's equivalent of C99 restrict keyword in array
3100      declarations.  Define as empty for no equivalent.])
3101 fi
3102
3103 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3104 dnl how the tty code is related to POSIX and/or other versions of termios.
3105 dnl The following looks like a useful start.
3106 dnl
3107 dnl AC_SYS_POSIX_TERMIOS
3108 dnl if test $ac_cv_sys_posix_termios = yes; then
3109 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3110 dnl                                and macros for terminal control.])
3111 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3112 dnl fi
3113
3114 case $opsys in
3115   darwin | gnu | hpux* | *bsd )
3116     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3117   ;;
3118 esac
3119
3120 dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3121 dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3122 case $opsys in
3123   hpux* | irix6-5 | openbsd | sol2* | unixware )
3124     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3125   ;;
3126 esac
3127
3128 case $opsys in
3129   gnu-kfreebsd) opsysfile="s/gnu-linux.h" ;;
3130   openbsd) opsysfile="s/netbsd.h" ;;
3131 esac
3132
3133 # Set up the CFLAGS for real compilation, so we can substitute it.
3134 CFLAGS="$REAL_CFLAGS"
3135 CPPFLAGS="$REAL_CPPFLAGS"
3136
3137 ## Hack to detect a buggy GCC version.
3138 if test "x$GCC" = xyes \
3139    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3140    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3141    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3142    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3143 fi
3144
3145 version=$PACKAGE_VERSION
3146
3147 ### Specify what sort of things we'll be editing into Makefile and config.h.
3148 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3149 AC_SUBST(version)
3150 AC_SUBST(configuration)
3151 ## Unused?
3152 AC_SUBST(canonical)
3153 AC_SUBST(srcdir)
3154 AC_SUBST(prefix)
3155 AC_SUBST(exec_prefix)
3156 AC_SUBST(bindir)
3157 AC_SUBST(datadir)
3158 AC_SUBST(sharedstatedir)
3159 AC_SUBST(libexecdir)
3160 AC_SUBST(mandir)
3161 AC_SUBST(infodir)
3162 AC_SUBST(lispdir)
3163 AC_SUBST(leimdir)
3164 AC_SUBST(locallisppath)
3165 AC_SUBST(lisppath)
3166 AC_SUBST(x_default_search_path)
3167 AC_SUBST(etcdir)
3168 AC_SUBST(archlibdir)
3169 AC_SUBST(docdir)
3170 AC_SUBST(bitmapdir)
3171 AC_SUBST(gamedir)
3172 AC_SUBST(gameuser)
3173 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3174 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3175 ## end of LIBX_BASE, but nothing ever set it.
3176 AC_SUBST(LD_SWITCH_X_SITE)
3177 AC_SUBST(C_SWITCH_X_SITE)
3178 AC_SUBST(GNUSTEP_CFLAGS)
3179 AC_SUBST(CFLAGS)
3180 ## Used in lwlib/Makefile.in.
3181 AC_SUBST(X_TOOLKIT_TYPE)
3182 if test -n "${opsysfile}"; then
3183   S_FILE="\$(srcdir)/${opsysfile}"
3184 else
3185   S_FILE=
3186 fi
3187 AC_SUBST(S_FILE)
3188 AC_SUBST(ns_appdir)
3189 AC_SUBST(ns_appbindir)
3190 AC_SUBST(ns_appresdir)
3191 AC_SUBST(ns_appsrc)
3192 AC_SUBST(GNU_OBJC_CFLAGS)
3193 AC_SUBST(OTHER_FILES)
3194
3195 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3196                    [Define to the canonical Emacs configuration name.])
3197 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3198                    [Define to the options passed to configure.])
3199 if test -n "$opsysfile"; then
3200   AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3201                      [Define to the used os dependent file.])
3202 fi
3203
3204 XMENU_OBJ=
3205 XOBJ=
3206 FONT_OBJ=
3207 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3208   AC_DEFINE(HAVE_X_WINDOWS, 1,
3209             [Define to 1 if you want to use the X window system.])
3210   XMENU_OBJ=xmenu.o
3211   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3212   FONT_OBJ=xfont.o
3213   if test "$HAVE_XFT" = "yes"; then
3214     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3215   elif test "$HAVE_FREETYPE" = "yes"; then
3216     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3217   fi
3218   AC_SUBST(FONT_OBJ)
3219 fi
3220 AC_SUBST(XMENU_OBJ)
3221 AC_SUBST(XOBJ)
3222 AC_SUBST(FONT_OBJ)
3223
3224 WIDGET_OBJ=
3225 MOTIF_LIBW=
3226 if test "${USE_X_TOOLKIT}" != "none" ; then
3227   WIDGET_OBJ=widget.o
3228   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3229   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3230     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3231   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3232     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3233     MOTIF_LIBW=-lXm
3234     case "$opsys" in
3235       gnu-linux)
3236         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3237         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3238         ;;
3239
3240       unixware)
3241         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3242         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3243         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3244         ;;
3245
3246       aix4-2)
3247         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3248         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3249         ;;
3250     esac
3251     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3252   fi
3253 fi
3254 AC_SUBST(WIDGET_OBJ)
3255
3256 TOOLKIT_LIBW=
3257 case "$USE_X_TOOLKIT" in
3258   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3259   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3260   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3261 esac
3262 AC_SUBST(TOOLKIT_LIBW)
3263
3264 if test "$USE_X_TOOLKIT" = "none"; then
3265   LIBXT_OTHER="\$(LIBXSM)"
3266   OLDXMENU_TARGET="really-oldXMenu"
3267 else
3268   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3269   OLDXMENU_TARGET="really-lwlib"
3270 fi
3271 AC_SUBST(LIBXT_OTHER)
3272
3273 ## The X Menu stuff is present in the X10 distribution, but missing
3274 ## from X11.  If we have X10, just use the installed library;
3275 ## otherwise, use our own copy.
3276 if test "${HAVE_X11}" = "yes" ; then
3277   AC_DEFINE(HAVE_X11, 1,
3278             [Define to 1 if you want to use version 11 of X windows.
3279              Otherwise, Emacs expects to use version 10.])
3280
3281   if test "$USE_X_TOOLKIT" = "none"; then
3282     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3283   else
3284     OLDXMENU="\${lwlibdir}/liblw.a"
3285   fi
3286   LIBXMENU="\$(OLDXMENU)"
3287   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3288   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3289 else
3290   ## For a syntactically valid Makefile; not actually used for anything.
3291   ## See comments in src/Makefile.in.
3292   OLDXMENU=nothing
3293   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3294   if test "${HAVE_X_WINDOWS}" = "yes"; then
3295     LIBXMENU="-lXMenu"
3296   else
3297     LIBXMENU=
3298   fi
3299   LIBX_OTHER=
3300   OLDXMENU_DEPS=
3301 fi
3302
3303 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3304   OLDXMENU_TARGET=
3305   OLDXMENU=nothing
3306   LIBXMENU=
3307   OLDXMENU_DEPS=
3308 fi
3309
3310 AC_SUBST(OLDXMENU_TARGET)
3311 AC_SUBST(OLDXMENU)
3312 AC_SUBST(LIBXMENU)
3313 AC_SUBST(LIBX_OTHER)
3314 AC_SUBST(OLDXMENU_DEPS)
3315
3316 if test "${HAVE_MENUS}" = "yes" ; then
3317   AC_DEFINE(HAVE_MENUS, 1,
3318             [Define to 1 if you have mouse menus.
3319              (This is automatic if you use X, but the option to specify it remains.)
3320              It is also defined with other window systems that support xmenu.c.])
3321 fi
3322
3323 if test "${GNU_MALLOC}" = "yes" ; then
3324   AC_DEFINE(GNU_MALLOC, 1,
3325             [Define to 1 if you want to use the GNU memory allocator.])
3326 fi
3327
3328 RALLOC_OBJ=
3329 if test "${REL_ALLOC}" = "yes" ; then
3330   AC_DEFINE(REL_ALLOC, 1,
3331             [Define REL_ALLOC if you want to use the relocating allocator for
3332              buffer space.])
3333
3334   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3335 fi
3336 AC_SUBST(RALLOC_OBJ)
3337
3338 if test "$opsys" = "cygwin"; then
3339   CYGWIN_OBJ="sheap.o"
3340   ## Cygwin differs because of its unexec().
3341   PRE_ALLOC_OBJ=
3342   POST_ALLOC_OBJ=lastfile.o
3343 else
3344   CYGWIN_OBJ=
3345   PRE_ALLOC_OBJ=lastfile.o
3346   POST_ALLOC_OBJ=
3347 fi
3348 AC_SUBST(CYGWIN_OBJ)
3349 AC_SUBST(PRE_ALLOC_OBJ)
3350 AC_SUBST(POST_ALLOC_OBJ)
3351
3352 # Configure gnulib here, now that we know LIBS.
3353 gl_ASSERT_NO_GNULIB_POSIXCHECK
3354 gl_ASSERT_NO_GNULIB_TESTS
3355 gl_INIT
3356
3357 case "$opsys" in
3358   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3359
3360   darwin)
3361    ## The -headerpad option tells ld (see man page) to leave room at the
3362    ## end of the header for adding load commands.  Needed for dumping.
3363    ## 0x690 is the total size of 30 segment load commands (at 56
3364    ## each); under Cocoa 31 commands are required.
3365    if test "$HAVE_NS" = "yes"; then
3366      libs_nsgui="-framework AppKit"
3367      headerpad_extra=6C8
3368    else
3369      libs_nsgui=
3370      headerpad_extra=690
3371    fi
3372    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3373
3374    ## This is here because src/Makefile.in did some extra fiddling around
3375    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3376    ##   #ifndef LD_SWITCH_SYSTEM
3377    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3378    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3379    ## not using gcc, darwin.
3380    ## Because this was done in src/Makefile.in, the resulting part of
3381    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3382    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3383    ## rather than LD_SWITCH_SYSTEM.
3384    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3385      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3386    ;;
3387
3388   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3389   ## find X at run-time.
3390   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3391   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3392   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3393   ## had different values in configure (in ac_link) and src/Makefile.in.
3394   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3395   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3396
3397   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3398 esac
3399
3400 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3401   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3402 fi
3403
3404 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3405
3406
3407 LD_FIRSTFLAG=
3408 ORDINARY_LINK=
3409 case "$opsys" in
3410   ## gnu: GNU needs its own crt0.
3411   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3412
3413   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3414   ## library search parth, i.e. it won't search /usr/lib for libc and
3415   ## friends.  Using -nostartfiles instead avoids this problem, and
3416   ## will also work on earlier NetBSD releases.
3417   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3418
3419   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3420   ##   MkLinux/LinuxPPC needs this.
3421   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3422   gnu-*)
3423     case "$canonical" in
3424       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3425     esac
3426     ;;
3427 esac
3428
3429
3430 if test "x$ORDINARY_LINK" = "xyes"; then
3431
3432   LD_FIRSTFLAG=""
3433   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3434
3435 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3436 ## freebsd, gnu-* not on powerpc*|s390x*.
3437 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3438
3439   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3440   ## places that are difficult to figure out at make time.  Fortunately,
3441   ## these same versions allow you to pass arbitrary flags on to the
3442   ## linker, so there is no reason not to use it as a linker.
3443   ##
3444   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3445   ## searching for libraries in its internal directories, so we have to
3446   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3447   LD_FIRSTFLAG="-nostdlib"
3448 fi
3449
3450 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3451 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3452
3453 AC_SUBST(LD_FIRSTFLAG)
3454
3455
3456 ## FIXME? The logic here is not precisely the same as that above.
3457 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3458 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3459 LIB_GCC=
3460 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3461
3462   case "$opsys" in
3463     freebsd|netbsd|openbsd) LIB_GCC= ;;
3464
3465     gnu-*)
3466       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3467       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3468       case $host_cpu in
3469       arm*)
3470         LIB_GCC="-lgcc_s"
3471         ;;
3472       *)
3473         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3474         ## immediately undefine it again and redefine it to empty.
3475         ## Was the C_SWITCH_X_SITE part really necessary?
3476 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3477         LIB_GCC=
3478         ;;
3479       esac
3480       ;;
3481
3482     ## Ask GCC where to find libgcc.a.
3483     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3484   esac
3485 fi                              dnl if $GCC
3486 AC_SUBST(LIB_GCC)
3487
3488
3489 ## If we're using X11/GNUstep, define some consequences.
3490 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3491   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3492   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3493 fi
3494
3495
3496 AH_TOP([/* GNU Emacs site configuration template file.
3497
3498 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3499   Free Software Foundation, Inc.
3500
3501 This file is part of GNU Emacs.
3502
3503 GNU Emacs is free software: you can redistribute it and/or modify
3504 it under the terms of the GNU General Public License as published by
3505 the Free Software Foundation, either version 3 of the License, or
3506 (at your option) any later version.
3507
3508 GNU Emacs is distributed in the hope that it will be useful,
3509 but WITHOUT ANY WARRANTY; without even the implied warranty of
3510 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3511 GNU General Public License for more details.
3512
3513 You should have received a copy of the GNU General Public License
3514 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3515
3516
3517 /* No code in Emacs #includes config.h twice, but some bits of code
3518    intended to work with other packages as well (like gmalloc.c)
3519    think they can include it as many times as they like.  */
3520 #ifndef EMACS_CONFIG_H
3521 #define EMACS_CONFIG_H
3522 ])dnl
3523
3524 AH_BOTTOM([
3525 /* On AIX 3 this must be included before any other include file.  */
3526 #include <alloca.h>
3527 #if ! HAVE_ALLOCA
3528 # error "alloca not available on this machine"
3529 #endif
3530
3531 /* Define AMPERSAND_FULL_NAME if you use the convention
3532    that & in the full name stands for the login id.  */
3533 /* Turned on June 1996 supposing nobody will mind it.  */
3534 #define AMPERSAND_FULL_NAME
3535
3536 /* `subprocesses' should be defined if you want to
3537    have code for asynchronous subprocesses
3538    (as used in M-x compile and M-x shell).
3539    Only MSDOS does not support this (it overrides
3540    this in its config_opsysfile below).  */
3541
3542 #define subprocesses
3543
3544 /* Include the os dependent file.  */
3545 #ifdef config_opsysfile
3546 # include config_opsysfile
3547 #endif
3548
3549 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3550    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3551   (There is probably a better place to do this, but right now the
3552    Cocoa side does this in s/darwin.h and we cannot parallel this
3553    exactly since GNUstep is multi-OS.  */
3554 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3555 #  define SYSTEM_PURESIZE_EXTRA 30000
3556 #endif
3557
3558 #ifdef emacs /* Don't do this for lib-src.  */
3559 /* Tell regex.c to use a type compatible with Emacs.  */
3560 #define RE_TRANSLATE_TYPE Lisp_Object
3561 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3562 #ifdef make_number
3563 /* If make_number is a macro, use it.  */
3564 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3565 #else
3566 /* If make_number is a function, avoid it.  */
3567 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3568 #endif
3569 #endif
3570
3571 #include <string.h>
3572 #include <stdlib.h>
3573
3574 #if defined __GNUC__ && (__GNUC__ > 2 \
3575                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3576 #define NO_RETURN       __attribute__ ((__noreturn__))
3577 #else
3578 #define NO_RETURN       /* nothing */
3579 #endif
3580
3581 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3582 #define NO_INLINE __attribute__((noinline))
3583 #else
3584 #define NO_INLINE
3585 #endif
3586
3587 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3588 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3589 #else
3590 #define EXTERNALLY_VISIBLE
3591 #endif
3592
3593 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3594 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3595 #else
3596 # define ATTRIBUTE_FORMAT(spec) /* empty */
3597 #endif
3598
3599 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3600 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3601    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3602 #else
3603 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3604    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3605 #endif
3606
3607 /* Some versions of GNU/Linux define noinline in their headers.  */
3608 #ifdef noinline
3609 #undef noinline
3610 #endif
3611
3612 /* These won't be used automatically yet.  We also need to know, at least,
3613    that the stack is continuous.  */
3614 #ifdef __GNUC__
3615 #  ifndef GC_SETJMP_WORKS
3616   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3617 #    define GC_SETJMP_WORKS 1
3618 #  endif
3619 #endif
3620
3621 #endif /* EMACS_CONFIG_H */
3622
3623 /*
3624 Local Variables:
3625 mode: c
3626 End:
3627 */
3628 ])dnl
3629
3630 #### Report on what we decided to do.
3631 #### Report GTK as a toolkit, even if it doesn't use Xt.
3632 #### It makes printing result more understandable as using GTK sets
3633 #### toolkit_scroll_bars to yes by default.
3634 if test "${HAVE_GTK}" = "yes"; then
3635   USE_X_TOOLKIT=GTK
3636 fi
3637
3638 echo "
3639 Configured for \`${canonical}'.
3640
3641   Where should the build process find the source code?    ${srcdir}
3642   What operating system file should Emacs use?           \`${opsysfile-none}'
3643   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3644   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3645   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3646   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3647   What window system should Emacs use?                    ${window_system}
3648   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3649
3650 if test -n "${x_includes}"; then
3651 echo "  Where do we find X Windows header files?                ${x_includes}"
3652 else
3653 echo "  Where do we find X Windows header files?                Standard dirs"
3654 fi
3655 if test -n "${x_libraries}"; then
3656 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3657 else
3658 echo "  Where do we find X Windows libraries?                   Standard dirs"
3659 fi
3660
3661 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3662 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3663 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3664 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3665 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3666 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3667 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3668 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3669
3670 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3671 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3672 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3673 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3674 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3675 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3676 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3677
3678 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3679 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3680 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3681 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3682
3683 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3684 echo
3685
3686 if test -n "${EMACSDATA}"; then
3687    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3688 fi
3689 if test -n "${EMACSDOC}"; then
3690    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3691 fi
3692
3693 if test $USE_XASSERTS = yes; then
3694    echo "  Compiling with asserts turned on."
3695    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3696 fi
3697
3698 echo
3699
3700 if test "$HAVE_NS" = "yes"; then
3701    echo
3702    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3703 The installed application will go to nextstep/Emacs.app and can be
3704 run or moved from there."
3705    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3706       echo "The application will be fully self-contained."
3707     else
3708       echo "The lisp resources for the application will be installed under ${prefix}.
3709 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3710 to run if these resources are not installed."
3711    fi
3712    echo
3713 fi
3714
3715 if test "${opsys}" = "cygwin"; then
3716   case `uname -r` in
3717     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3718            echo
3719            ;;
3720   esac
3721 fi
3722
3723 # Remove any trailing slashes in these variables.
3724 [test "${prefix}" != NONE &&
3725   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3726 test "${exec_prefix}" != NONE &&
3727   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3728
3729 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3730 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3731 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3732 dnl (else you get "no `Makefile.am' found for any configure output").
3733 dnl This will work, but you get a config.status that is not quite right
3734 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3735 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3736 dnl it seems better to just live with the duplication.
3737 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3738
3739 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3740        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3741        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3742        leim/Makefile])
3743
3744 dnl test/ is not present in release tarfiles.
3745 opt_makefile=test/automated/Makefile
3746
3747 if test -f $srcdir/${opt_makefile}.in; then
3748   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3749   dnl Again, it's best not to use a variable.  Though you can add
3750   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3751   AC_CONFIG_FILES([test/automated/Makefile])
3752 fi
3753
3754
3755 dnl admin/ may or may not be present.
3756 opt_makefile=admin/unidata/Makefile
3757
3758 if test -f $srcdir/${opt_makefile}.in; then
3759   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3760   AC_CONFIG_FILES([admin/unidata/Makefile])
3761 fi
3762
3763
3764 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3765
3766 AC_SUBST(SUBDIR_MAKEFILES_IN)
3767
3768 dnl Make the necessary directories, if they don't exist.
3769 AC_CONFIG_COMMANDS([mkdirs], [
3770 for dir in etc lisp ; do
3771   test -d ${dir} || mkdir ${dir}
3772 done
3773 ])
3774
3775 dnl You might wonder (I did) why epaths.h is generated by running make,
3776 dnl rather than just letting configure generate it from epaths.in.
3777 dnl One reason is that the various paths are not fully expanded (see above);
3778 dnl eg gamedir=${prefix}/var/games/emacs.
3779 dnl Secondly, the GNU Coding standards require that one should be able
3780 dnl to run `make prefix=/some/where/else' and override the values set
3781 dnl by configure.  This also explains the `move-if-change' test and
3782 dnl the use of force in the `epaths-force' rule in Makefile.in.
3783 AC_CONFIG_COMMANDS([epaths], [
3784 echo creating src/epaths.h
3785 ${MAKE-make} epaths-force
3786 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3787
3788 AC_CONFIG_COMMANDS([gdbinit], [
3789 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3790   echo creating src/.gdbinit
3791   echo source $srcdir/src/.gdbinit > src/.gdbinit
3792 fi
3793 ])
3794
3795 AC_OUTPUT
3796
3797 dnl configure.in ends here