lisp/view.el

   1 ;;; view.el --- peruse file or buffer without editing
   2
   3 ;; Copyright (C) 1985, 1989, 1994-1995, 1997, 2000-2013 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Author: K. Shane Hartman
   7 ;; Maintainer: Inge Frick <inge@nada.kth.se>
   8 ;; Keywords: files
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package provides the `view' minor mode documented in the Emacs
  28 ;; user's manual.
  29 ;; View mode entry and exit is done through the functions view-mode-enter
  30 ;; and view-mode-exit.  Use these functions to enter or exit view-mode from
  31 ;; emacs lisp programs.
  32 ;; We use both view- and View- as prefix for symbols.  View- is used as
  33 ;; prefix for commands that have a key binding.  view- is used for commands
  34 ;; without key binding.  The purpose of this is to make it easier for a
  35 ;; user to use command name completion.
  36
  37 ;;; Suggested key bindings:
  38 ;;
  39 ;; (define-key ctl-x-4-map "v" 'view-file-other-window)  ; ^x4v
  40 ;; (define-key ctl-x-5-map "v" 'view-file-other-frame)  ; ^x5v
  41 ;;
  42 ;; You could also bind view-file, view-buffer, view-buffer-other-window and
  43 ;; view-buffer-other-frame to keys.
  44 \f
  45 ;;; Code:
  46
  47 (defgroup view nil
  48   "Peruse file or buffer without editing."
  49   :link '(function-link view-mode)
  50   :link '(custom-manual "(emacs)Misc File Ops")
  51   :group 'wp)
  52
  53 (defcustom view-highlight-face 'highlight
  54    "The face used for highlighting the match found by View mode search."
  55    :type 'face
  56    :group 'view)
  57
  58 (defcustom view-scroll-auto-exit nil
  59   "Non-nil means scrolling past the end of buffer exits View mode.
  60 A value of nil means attempting to scroll past the end of the buffer,
  61 only rings the bell and gives a message on how to leave."
  62   :type 'boolean
  63   :group 'view)
  64
  65 (defcustom view-try-extend-at-buffer-end nil
  66  "Non-nil means try to load more of file when reaching end of buffer.
  67 This variable is mainly intended to be temporarily set to non-nil by
  68 the F command in view-mode, but you can set it to t if you want the action
  69 for all scroll commands in view mode."
  70   :type 'boolean
  71   :group 'view)
  72
  73 ;;;###autoload
  74 (defcustom view-remove-frame-by-deleting t
  75   "Determine how View mode removes a frame no longer needed.
  76 If nil, make an icon of the frame.  If non-nil, delete the frame."
  77   :type 'boolean
  78   :group 'view
  79   :version "23.1")
  80
  81 (defcustom view-exits-all-viewing-windows nil
  82   "Non-nil means restore all windows used to view buffer.
  83 Commands that restore windows when finished viewing a buffer,
  84 apply to all windows that display the buffer and have restore
  85 information.  If `view-exits-all-viewing-windows' is nil, only
  86 the selected window is considered for restoring."
  87   :type 'boolean
  88   :group 'view)
  89
  90 (defcustom view-inhibit-help-message nil
  91   "Non-nil inhibits the help message shown upon entering View mode."
  92   :type 'boolean
  93   :group 'view
  94   :version "22.1")
  95
  96 ;;;###autoload
  97 (defvar view-mode nil
  98   "Non-nil if View mode is enabled.
  99 Don't change this variable directly, you must change it by one of the
 100 functions that enable or disable view mode.")
 101 ;;;###autoload
 102 (make-variable-buffer-local 'view-mode)
 103
 104 (defcustom view-mode-hook nil
 105   "Normal hook run when starting to view a buffer or file."
 106   :type 'hook
 107   :group 'view)
 108 \f
 109 (defvar view-old-buffer-read-only nil)
 110 (make-variable-buffer-local 'view-old-buffer-read-only)
 111
 112 (defvar view-old-Helper-return-blurb)
 113 (make-variable-buffer-local 'view-old-Helper-return-blurb)
 114
 115 (defvar view-page-size nil
 116   "Default number of lines to scroll by View page commands.
 117 If nil that means use the window size.")
 118 (make-variable-buffer-local 'view-page-size)
 119
 120 (defvar view-half-page-size nil
 121   "Default number of lines to scroll by View half page commands.
 122 If nil that means use half the window size.")
 123 (make-variable-buffer-local 'view-half-page-size)
 124
 125 (defvar view-last-regexp nil)
 126 (make-variable-buffer-local 'view-last-regexp) ; Global is better???
 127
 128 (defvar view-return-to-alist nil
 129   "What to do with used windows and where to go when finished viewing buffer.
 130 This is local in each buffer being viewed.
 131 It is added to by `view-mode-enter' when starting to view a buffer and
 132 subtracted from by `view-mode-exit' when finished viewing the buffer.
 133
 134 See RETURN-TO-ALIST argument of function `view-mode-exit' for the format of
 135 `view-return-to-alist'.")
 136 (make-obsolete-variable
 137  'view-return-to-alist "this variable is no more used." "24.1")
 138 (make-variable-buffer-local 'view-return-to-alist)
 139 (put 'view-return-to-alist 'permanent-local t)
 140
 141 (defvar view-exit-action nil
 142   "If non-nil, a function with one argument (a buffer) called when finished viewing.
 143 Commands like \\[view-file] and \\[view-file-other-window] may
 144 set this to bury or kill the viewed buffer.
 145 Observe that the buffer viewed might not appear in any window at
 146 the time this function is called.")
 147 (make-variable-buffer-local 'view-exit-action)
 148
 149 (defvar view-no-disable-on-exit nil
 150   "If non-nil, View mode \"exit\" commands don't actually disable View mode.
 151 Instead, these commands just switch buffers or windows.
 152 This is set in certain buffers by specialized features such as help commands
 153 that use View mode automatically.")
 154
 155 (defvar view-overlay nil
 156   "Overlay used to display where a search operation found its match.
 157 This is local in each buffer, once it is used.")
 158 (make-variable-buffer-local 'view-overlay)
 159 \f
 160 ;; Define keymap inside defvar to make it easier to load changes.
 161 ;; Some redundant "less"-like key bindings below have been commented out.
 162 (defvar view-mode-map
 163   (let ((map (make-sparse-keymap)))
 164     (define-key map "C" 'View-kill-and-leave)
 165     (define-key map "c" 'View-leave)
 166     (define-key map "Q" 'View-quit-all)
 167     (define-key map "E" 'View-exit-and-edit)
 168     ;; (define-key map "v" 'View-exit)
 169     (define-key map "e" 'View-exit)
 170     (define-key map "q" 'View-quit)
 171     ;; (define-key map "N" 'View-search-last-regexp-backward)
 172     (define-key map "p" 'View-search-last-regexp-backward)
 173     (define-key map "n" 'View-search-last-regexp-forward)
 174     ;; (define-key map "?" 'View-search-regexp-backward) ; Less does this.
 175     (define-key map "\\" 'View-search-regexp-backward)
 176     (define-key map "/" 'View-search-regexp-forward)
 177     (define-key map "r" 'isearch-backward)
 178     (define-key map "s" 'isearch-forward)
 179     (define-key map "m" 'point-to-register)
 180     (define-key map "'" 'register-to-point)
 181     (define-key map "x" 'exchange-point-and-mark)
 182     (define-key map "@" 'View-back-to-mark)
 183     (define-key map "." 'set-mark-command)
 184     (define-key map "%" 'View-goto-percent)
 185     ;; (define-key map "G" 'View-goto-line-last)
 186     (define-key map "g" 'View-goto-line)
 187     (define-key map "=" 'what-line)
 188     (define-key map "F" 'View-revert-buffer-scroll-page-forward)
 189     ;; (define-key map "k" 'View-scroll-line-backward)
 190     (define-key map "y" 'View-scroll-line-backward)
 191     ;; (define-key map "j" 'View-scroll-line-forward)
 192     (define-key map "\n" 'View-scroll-line-forward)
 193     (define-key map "\r" 'View-scroll-line-forward)
 194     (define-key map "u" 'View-scroll-half-page-backward)
 195     (define-key map "d" 'View-scroll-half-page-forward)
 196     (define-key map "z" 'View-scroll-page-forward-set-page-size)
 197     (define-key map "w" 'View-scroll-page-backward-set-page-size)
 198     ;; (define-key map "b" 'View-scroll-page-backward)
 199     (define-key map "\C-?" 'View-scroll-page-backward)
 200     ;; (define-key map "f" 'View-scroll-page-forward)
 201     (define-key map " " 'View-scroll-page-forward)
 202     (define-key map "o" 'View-scroll-to-buffer-end)
 203     (define-key map ">" 'end-of-buffer)
 204     (define-key map "<" 'beginning-of-buffer)
 205     (define-key map "-" 'negative-argument)
 206     (define-key map "9" 'digit-argument)
 207     (define-key map "8" 'digit-argument)
 208     (define-key map "7" 'digit-argument)
 209     (define-key map "6" 'digit-argument)
 210     (define-key map "5" 'digit-argument)
 211     (define-key map "4" 'digit-argument)
 212     (define-key map "3" 'digit-argument)
 213     (define-key map "2" 'digit-argument)
 214     (define-key map "1" 'digit-argument)
 215     (define-key map "0" 'digit-argument)
 216     (define-key map "H" 'describe-mode)
 217     (define-key map "?" 'describe-mode) ; Maybe do as less instead? See above.
 218     (define-key map "h" 'describe-mode)
 219     map))
 220 \f
 221 ;;; Commands that enter or exit view mode.
 222
 223 ;; This is used when view mode is exited, to make sure we don't try to
 224 ;; kill a buffer modified by the user.  A buffer in view mode can
 225 ;; become modified if the user types C-x C-q, edits the buffer, then
 226 ;; types C-x C-q again to return to view mode.
 227 ;;;###autoload
 228 (defun kill-buffer-if-not-modified (buf)
 229   "Like `kill-buffer', but does nothing if the buffer is modified."
 230   (let ((buf (get-buffer buf)))
 231     (and buf (not (buffer-modified-p buf))
 232          (kill-buffer buf))))
 233
 234 ;;;###autoload
 235 (defun view-file (file)
 236   "View FILE in View mode, returning to previous buffer when done.
 237 Emacs commands editing the buffer contents are not available; instead, a
 238 special set of commands (mostly letters and punctuation) are defined for
 239 moving around in the buffer.
 240 Space scrolls forward, Delete scrolls backward.
 241 For a list of all View commands, type H or h while viewing.
 242
 243 This command runs the normal hook `view-mode-hook'."
 244   (interactive "fView file: ")
 245   (unless (file-exists-p file) (error "%s does not exist" file))
 246   (let ((had-a-buf (get-file-buffer file))
 247         (buffer (find-file-noselect file)))
 248     (view-buffer buffer (and (not had-a-buf) 'kill-buffer-if-not-modified))))
 249
 250 ;;;###autoload
 251 (defun view-file-other-window (file)
 252   "View FILE in View mode in another window.
 253 When done, return that window to its previous buffer, and kill the
 254 buffer visiting FILE if unmodified and if it wasn't visited before.
 255
 256 Emacs commands editing the buffer contents are not available; instead,
 257 a special set of commands (mostly letters and punctuation)
 258 are defined for moving around in the buffer.
 259 Space scrolls forward, Delete scrolls backward.
 260 For a list of all View commands, type H or h while viewing.
 261
 262 This command runs the normal hook `view-mode-hook'."
 263   (interactive "fIn other window view file: ")
 264   (unless (file-exists-p file) (error "%s does not exist" file))
 265   (let ((had-a-buf (get-file-buffer file))
 266         (buf-to-view (find-file-noselect file)))
 267     (view-buffer-other-window buf-to-view nil
 268                               (and (not had-a-buf)
 269                                    'kill-buffer-if-not-modified))))
 270
 271 ;;;###autoload
 272 (defun view-file-other-frame (file)
 273   "View FILE in View mode in another frame.
 274 When done, kill the buffer visiting FILE if unmodified and if it wasn't
 275 visited before; also, maybe delete other frame and/or return to previous
 276 buffer.
 277
 278 Emacs commands editing the buffer contents are not available; instead,
 279 a special set of commands (mostly letters and punctuation)
 280 are defined for moving around in the buffer.
 281 Space scrolls forward, Delete scrolls backward.
 282 For a list of all View commands, type H or h while viewing.
 283
 284 This command runs the normal hook `view-mode-hook'."
 285   (interactive "fIn other frame view file: ")
 286   (unless (file-exists-p file) (error "%s does not exist" file))
 287   (let ((had-a-buf (get-file-buffer file))
 288         (buf-to-view (find-file-noselect file)))
 289     (view-buffer-other-frame buf-to-view nil
 290                              (and (not had-a-buf)
 291                                   'kill-buffer-if-not-modified))))
 292
 293
 294 ;;;###autoload
 295 (defun view-buffer (buffer &optional exit-action)
 296   "View BUFFER in View mode, returning to previous buffer when done.
 297 Emacs commands editing the buffer contents are not available; instead, a
 298 special set of commands (mostly letters and punctuation) are defined for
 299 moving around in the buffer.
 300 Space scrolls forward, Delete scrolls backward.
 301 For a list of all View commands, type H or h while viewing.
 302
 303 This command runs the normal hook `view-mode-hook'.
 304
 305 Optional argument EXIT-ACTION is either nil or a function with buffer as
 306 argument.  This function is called when finished viewing buffer.  Use
 307 this argument instead of explicitly setting `view-exit-action'.
 308
 309 Do not set EXIT-ACTION to `kill-buffer' when BUFFER visits a
 310 file: Users may suspend viewing in order to modify the buffer.
 311 Exiting View mode will then discard the user's edits.  Setting
 312 EXIT-ACTION to `kill-buffer-if-not-modified' avoids this.
 313
 314 This function does not enable View mode if the buffer's major-mode
 315 has a `special' mode-class, because such modes usually have their
 316 own View-like bindings."
 317   (interactive "bView buffer: ")
 318   (switch-to-buffer buffer)
 319   (if (eq (get major-mode 'mode-class) 'special)
 320       (message "Not using View mode because the major mode is special")
 321     (view-mode-enter nil exit-action)))
 322
 323 ;;;###autoload
 324 (defun view-buffer-other-window (buffer &optional not-return exit-action)
 325   "View BUFFER in View mode in another window.
 326 Emacs commands editing the buffer contents are not available;
 327 instead, a special set of commands (mostly letters and
 328 punctuation) are defined for moving around in the buffer.
 329 Space scrolls forward, Delete scrolls backward.
 330 For a list of all View commands, type H or h while viewing.
 331
 332 This command runs the normal hook `view-mode-hook'.
 333
 334 Optional argument NOT-RETURN is ignored.
 335
 336 Optional argument EXIT-ACTION is either nil or a function with buffer as
 337 argument.  This function is called when finished viewing buffer.  Use
 338 this argument instead of explicitly setting `view-exit-action'.
 339
 340 This function does not enable View mode if the buffer's major-mode
 341 has a `special' mode-class, because such modes usually have their
 342 own View-like bindings."
 343   (interactive "bIn other window view buffer:\nP")
 344   (let ((pop-up-windows t))
 345     (pop-to-buffer buffer t))
 346   (if (eq (get major-mode 'mode-class) 'special)
 347       (message "Not using View mode because the major mode is special")
 348     (view-mode-enter nil exit-action)))
 349
 350 ;;;###autoload
 351 (defun view-buffer-other-frame (buffer &optional not-return exit-action)
 352   "View BUFFER in View mode in another frame.
 353 Emacs commands editing the buffer contents are not available;
 354 instead, a special set of commands (mostly letters and
 355 punctuation) are defined for moving around in the buffer.
 356 Space scrolls forward, Delete scrolls backward.
 357 For a list of all View commands, type H or h while viewing.
 358
 359 This command runs the normal hook `view-mode-hook'.
 360
 361 Optional argument NOT-RETURN is ignored.
 362
 363 Optional argument EXIT-ACTION is either nil or a function with buffer as
 364 argument.  This function is called when finished viewing buffer.  Use
 365 this argument instead of explicitly setting `view-exit-action'.
 366
 367 This function does not enable View mode if the buffer's major-mode
 368 has a `special' mode-class, because such modes usually have their
 369 own View-like bindings."
 370   (interactive "bView buffer in other frame: \nP")
 371   (let ((pop-up-frames t))
 372     (pop-to-buffer buffer t))
 373   (if (eq (get major-mode 'mode-class) 'special)
 374       (message "Not using View mode because the major mode is special")
 375     (view-mode-enter nil exit-action)))
 376 \f
 377 ;;;###autoload
 378 (define-minor-mode view-mode
 379   ;; In the following documentation string we have to use some explicit key
 380   ;; bindings instead of using the \\[] construction.  The reason for this
 381   ;; is that most commands have more than one key binding.
 382   "Toggle View mode, a minor mode for viewing text but not editing it.
 383 With a prefix argument ARG, enable View mode if ARG is positive,
 384 and disable it otherwise.  If called from Lisp, enable View mode
 385 if ARG is omitted or nil.
 386
 387 When View mode is enabled, commands that do not change the buffer
 388 contents are available as usual.  Kill commands insert text in
 389 kill buffers but do not delete.  Most other commands beep and
 390 tell the user that the buffer is read-only.
 391
 392 \\<view-mode-map>
 393
 394 The following additional commands are provided.  Most commands
 395 take prefix arguments.  Page commands default to \"page size\"
 396 lines which is almost a whole window, or number of lines set by
 397 \\[View-scroll-page-forward-set-page-size] or \\[View-scroll-page-backward-set-page-size].
 398 Half page commands default to and set \"half page size\" lines
 399 which initially is half a window full.  Search commands default
 400 to a repeat count of one.
 401
 402 H, h, ?  This message.
 403 Digits  provide prefix arguments.
 404 \\[negative-argument]   negative prefix argument.
 405 \\[beginning-of-buffer] move to the beginning of buffer.
 406 >       move to the end of buffer.
 407 \\[View-scroll-to-buffer-end]   scroll so that buffer end is at last line of window.
 408 SPC     scroll forward \"page size\" lines.
 409           With prefix scroll forward prefix lines.
 410 DEL     scroll backward \"page size\" lines.
 411           With prefix scroll backward prefix lines.
 412 \\[View-scroll-page-forward-set-page-size]      like  \\[View-scroll-page-forward]  but with prefix sets \"page size\" to prefix.
 413 \\[View-scroll-page-backward-set-page-size]     like  \\[View-scroll-page-backward]  but with prefix sets \"page size\" to prefix.
 414 \\[View-scroll-half-page-forward]       scroll forward \"half page size\" lines.  With prefix, sets
 415           \"half page size\" to prefix lines and scrolls forward that much.
 416 \\[View-scroll-half-page-backward]      scroll backward \"half page size\" lines.  With prefix, sets
 417           \"half page size\" to prefix lines and scrolls backward that much.
 418 RET, LFD  scroll forward one line.  With prefix scroll forward prefix line(s).
 419 y       scroll backward one line.  With prefix scroll backward prefix line(s).
 420 \\[View-revert-buffer-scroll-page-forward]      revert-buffer if necessary and scroll forward.
 421           Use this to view a changing file.
 422 \\[what-line]   prints the current line number.
 423 \\[View-goto-percent]   goes prefix argument (default 100) percent into buffer.
 424 \\[View-goto-line]      goes to line given by prefix argument (default first line).
 425 .       set the mark.
 426 x       exchanges point and mark.
 427 \\[View-back-to-mark]   return to mark and pops mark ring.
 428           Mark ring is pushed at start of every successful search and when
 429           jump to line occurs.  The mark is set on jump to buffer start or end.
 430 \\[point-to-register]   save current position in character register.
 431 '       go to position saved in character register.
 432 s       do forward incremental search.
 433 r       do reverse incremental search.
 434 \\[View-search-regexp-forward]  searches forward for regular expression, starting after current page.
 435           ! and @ have a special meaning at the beginning of the regexp.
 436           ! means search for a line with no match for regexp.  @ means start
 437           search at beginning (end for backward search) of buffer.
 438 \\      searches backward for regular expression, starting before current page.
 439 \\[View-search-last-regexp-forward]     searches forward for last regular expression.
 440 p       searches backward for last regular expression.
 441 \\[View-quit]   quit View mode, restoring this window and buffer to previous state.
 442           \\[View-quit] is the normal way to leave view mode.
 443 \\[View-exit]   exit View mode but stay in current buffer.  Use this if you started
 444           viewing a buffer (file) and find out you want to edit it.
 445           This command restores the previous read-only status of the buffer.
 446 \\[View-exit-and-edit]  exit View mode, and make the current buffer editable
 447           even if it was not editable before entry to View mode.
 448 \\[View-quit-all]       quit View mode, restoring all windows to previous state.
 449 \\[View-leave]  quit View mode and maybe switch buffers, but don't kill this buffer.
 450 \\[View-kill-and-leave] quit View mode, kill current buffer and go back to other buffer.
 451
 452 The effect of \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] depends on how view-mode was entered.  If it was
 453 entered by view-file, view-file-other-window, view-file-other-frame, or
 454 \\[dired-view-file] \(\\[view-file], \\[view-file-other-window],
 455 \\[view-file-other-frame], or the Dired mode v command),
 456 then \\[View-quit] will try to kill the current buffer.
 457 If view-mode was entered from another buffer, by \\[view-buffer],
 458 \\[view-buffer-other-window], \\[view-buffer-other frame], \\[view-file],
 459 \\[view-file-other-window], or \\[view-file-other-frame],
 460 then \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] will return to that buffer.
 461
 462 Entry to view-mode runs the normal hook `view-mode-hook'."
 463   :lighter " View" :keymap view-mode-map
 464   (if view-mode (view-mode-enable) (view-mode-disable)))
 465 \f
 466 (defun view-mode-enable (&optional run-view-mode-hook)
 467   "Turn on View mode.
 468 Run `view-mode-hook' when RUN-VIEW-MODE-HOOK is non-nil."
 469   ;; Always leave view mode before changing major mode.
 470   ;; This is to guarantee that the buffer-read-only variable is restored.
 471   (add-hook 'change-major-mode-hook 'view-mode-disable nil t)
 472   (setq view-mode t
 473         view-page-size nil
 474         view-half-page-size nil
 475         view-old-buffer-read-only buffer-read-only
 476         buffer-read-only t)
 477   (if (boundp 'Helper-return-blurb)
 478       (setq view-old-Helper-return-blurb (and (boundp 'Helper-return-blurb)
 479                                               Helper-return-blurb)
 480             Helper-return-blurb
 481             (format "continue viewing %s"
 482                     (if (buffer-file-name)
 483                         (file-name-nondirectory (buffer-file-name))
 484                       (buffer-name)))))
 485   (force-mode-line-update)
 486   (when run-view-mode-hook
 487     (run-hooks 'view-mode-hook)))
 488
 489 (defun view-mode-disable ()
 490   "Turn off View mode."
 491   (remove-hook 'change-major-mode-hook 'view-mode-disable t)
 492   (and view-overlay (delete-overlay view-overlay))
 493   (force-mode-line-update)
 494   ;; Calling toggle-read-only while View mode is enabled
 495   ;; sets view-read-only to t as a buffer-local variable
 496   ;; after exiting View mode.  That arranges that the next toggle-read-only
 497   ;; will reenable View mode.
 498   ;; Canceling View mode in any other way should cancel that, too,
 499   ;; so that View mode stays off if toggle-read-only is called.
 500   (if (local-variable-p 'view-read-only)
 501       (kill-local-variable 'view-read-only))
 502   (setq view-mode nil)
 503   (if (boundp 'Helper-return-blurb)
 504       (setq Helper-return-blurb view-old-Helper-return-blurb))
 505   (if buffer-read-only
 506       (setq buffer-read-only view-old-buffer-read-only)))
 507
 508 ;;;###autoload
 509 (defun view-return-to-alist-update (buffer &optional item)
 510   "Update `view-return-to-alist' of buffer BUFFER.
 511 Remove from `view-return-to-alist' all entries referencing dead
 512 windows.  Optional argument ITEM non-nil means add ITEM to
 513 `view-return-to-alist' after purging.  For a description of items
 514 that can be added see the RETURN-TO-ALIST argument of the
 515 function `view-mode-exit'.  If `view-return-to-alist' contains an
 516 entry for the selected window, purge that entry from
 517 `view-return-to-alist' before adding ITEM."
 518   (declare (obsolete "this function has no effect." "24.1"))
 519   (with-current-buffer buffer
 520     (when view-return-to-alist
 521       (let* ((list view-return-to-alist)
 522              entry entry-window last)
 523         (while list
 524           (setq entry (car list))
 525           (setq entry-window (car entry))
 526           (if (and (windowp entry-window)
 527                    (or (and item (eq entry-window (selected-window)))
 528                        (not (window-live-p entry-window))))
 529               ;; Remove that entry.
 530               (if last
 531                   (setcdr last (cdr list))
 532                 (setq view-return-to-alist
 533                       (cdr view-return-to-alist)))
 534             ;; Leave entry alone.
 535             (setq last entry))
 536           (setq list (cdr list)))))
 537     ;; Add ITEM.
 538     (when item
 539       (setq view-return-to-alist
 540             (cons item view-return-to-alist)))))
 541
 542 ;;;###autoload
 543 (defun view-mode-enter (&optional quit-restore exit-action)
 544   "Enter View mode and set up exit from view mode depending on optional arguments.
 545 Optional argument QUIT-RESTORE if non-nil must specify a valid
 546 entry for quitting and restoring any window showing the current
 547 buffer.  This entry replaces any parameter installed by
 548 `display-buffer' and is used by `view-mode-exit'.
 549
 550 Optional argument EXIT-ACTION, if non-nil, must specify a
 551 function that takes a buffer as argument.  This function will be
 552 called by `view-mode-exit'.
 553
 554 For a list of all View commands, type H or h while viewing.
 555
 556 This function runs the normal hook `view-mode-hook'."
 557   (when quit-restore
 558     (dolist (window (get-buffer-window-list nil nil t))
 559       (set-window-parameter window 'quit-restore quit-restore)))
 560
 561   (when exit-action
 562     (setq view-exit-action exit-action))
 563
 564   (unless view-mode
 565     (view-mode-enable t)
 566     (force-mode-line-update)
 567     (unless view-inhibit-help-message
 568       (message "%s"
 569                (substitute-command-keys "\
 570 View mode: type \\[help-command] for help, \\[describe-mode] for commands, \\[View-quit] to quit.")))))
 571 \f
 572 ;; This is awful because it assumes that the selected window shows the
 573 ;; current buffer when this is called.
 574 (defun view-mode-exit (&optional exit-only exit-action all-windows)
 575   "Exit View mode in various ways.
 576 If all arguments are nil, remove the current buffer from the
 577 selected window using the `quit-restore' information associated
 578 with the selected window.  If optional argument ALL-WINDOWS or
 579 `view-exits-all-viewing-windows' are non-nil, remove the current
 580 buffer from all windows showing it.
 581
 582 Optional argument EXIT-ONLY non-nil means just exit `view-mode'
 583 \(unless `view-no-disable-on-exit' is non-nil) but do not change
 584 the associations of any windows with the current buffer.
 585
 586 EXIT-ACTION, if non-nil, must specify a function that is called
 587 with the current buffer as argument and is called after disabling
 588 `view-mode' and removing any associations of windows with the
 589 current buffer. "
 590   (when view-mode
 591     (let ((buffer (window-buffer)))
 592       (unless view-no-disable-on-exit
 593         (view-mode-disable))
 594
 595       (unless exit-only
 596         (cond
 597          ((or all-windows view-exits-all-viewing-windows)
 598           (dolist (window (get-buffer-window-list))
 599             (quit-window nil window)))
 600          ((eq (window-buffer) (current-buffer))
 601           (quit-window)))
 602
 603         (when exit-action
 604           (funcall exit-action buffer))
 605         (force-mode-line-update)))))
 606 \f
 607 (defun View-exit ()
 608   "Exit View mode but stay in current buffer."
 609   (interactive)
 610   (view-mode-exit t))
 611
 612 ;;;###autoload
 613 (defun View-exit-and-edit ()
 614   "Exit View mode and make the current buffer editable."
 615   (interactive)
 616   (let ((view-old-buffer-read-only nil)
 617         (view-no-disable-on-exit nil))
 618     (view-mode-exit t)))
 619
 620 (defun View-leave ()
 621   "Quit View mode and maybe switch buffers, but don't kill this buffer."
 622   (interactive)
 623   (view-mode-exit))
 624
 625 (defun View-quit ()
 626   "Quit View mode, trying to restore window and buffer to previous state.
 627 Maybe kill this buffer.  Try to restore selected window to previous state
 628 and go to previous buffer or window."
 629   (interactive)
 630   (view-mode-exit nil view-exit-action))
 631
 632 (defun View-quit-all ()
 633   "Quit View mode, trying to restore windows and buffers to previous state.
 634 Maybe kill current buffer.  Try to restore all windows viewing buffer to
 635 previous state and go to previous buffer or window."
 636   (interactive)
 637   (view-mode-exit nil view-exit-action t))
 638
 639 (defun View-kill-and-leave ()
 640   "Quit View mode, kill current buffer and return to previous buffer."
 641   (interactive)
 642   (view-mode-exit nil (or view-exit-action 'kill-buffer) t))
 643 \f
 644
 645 ;;; Some help routines.
 646
 647 (defun view-window-size ()
 648   ;; Return the height of the current window, excluding the mode line.
 649   ;; Using `window-line-height' accounts for variable-height fonts.
 650   (let ((h (window-line-height -1)))
 651     (if h
 652         (1+ (nth 1 h))
 653       ;; This should not happen, but if `window-line-height' returns
 654       ;; nil, fall back on `window-height'.
 655       (1- (window-height)))))
 656
 657 ;; (defun view-last-command (&optional who what)
 658 ;;  (setq view-last-command-entry this-command)
 659 ;;  (setq view-last-command who)
 660 ;;  (setq view-last-command-argument what))
 661
 662 ;; (defun View-repeat-last-command ()
 663 ;;  "Repeat last command issued in View mode."
 664 ;;  (interactive)
 665 ;;  (if (and view-last-command
 666 ;;         (eq view-last-command-entry last-command))
 667 ;;      (funcall view-last-command view-last-command-argument))
 668 ;;  (setq this-command view-last-command-entry))
 669
 670 (defun view-recenter ()
 671   ;; Recenter point in window and redisplay normally.
 672   (recenter '(1)))
 673
 674 (defun view-page-size-default (lines)
 675   ;; If LINES is nil, 0, or larger than `view-window-size', return nil.
 676   ;; Otherwise, return LINES.
 677   (and lines
 678        (not (zerop (setq lines (prefix-numeric-value lines))))
 679        (<= (abs lines)
 680            (abs (- (view-window-size) next-screen-context-lines)))
 681        (abs lines)))
 682
 683 (defun view-set-half-page-size-default (lines)
 684   ;; Get and maybe set half page size.
 685   (if (not lines) (or view-half-page-size
 686                       (/ (view-window-size) 2))
 687     (setq view-half-page-size
 688           (if (zerop (setq lines (prefix-numeric-value lines)))
 689               (/ (view-window-size) 2)
 690             (view-page-size-default lines)))))
 691
 692
 693 ;;; Commands for moving around in the buffer.
 694
 695 (defun View-goto-percent (&optional percent)
 696   "Move to end (or prefix PERCENT) of buffer in View mode.
 697 Display is centered at point.
 698 Also set the mark at the position where point was."
 699   (interactive "P")
 700   (push-mark)
 701   (goto-char
 702    (if percent
 703        (+ (point-min)
 704           (floor (* (- (point-max) (point-min)) 0.01
 705                     (max 0 (min 100 (prefix-numeric-value percent))))))
 706      (point-max)))
 707   (view-recenter))
 708
 709 ;; (defun View-goto-line-last (&optional line)
 710 ;; "Move to last (or prefix LINE) line in View mode.
 711 ;; Display is centered at LINE.
 712 ;; Sets mark at starting position and pushes mark ring."
 713 ;;  (interactive "P")
 714 ;;  (push-mark)
 715 ;;  (if line (goto-line (prefix-numeric-value line))
 716 ;;    (goto-char (point-max))
 717 ;;    (beginning-of-line))
 718 ;;  (view-recenter))
 719
 720 (defun View-goto-line (&optional line)
 721   "Move to first (or prefix LINE) line in View mode.
 722 Display is centered at LINE.
 723 Also set the mark at the position where point was."
 724   (interactive "p")
 725   (push-mark)
 726   (goto-char (point-min))
 727   (forward-line (1- line))
 728   (view-recenter))
 729
 730 (defun View-back-to-mark (&optional _ignore)
 731   "Return to last mark set in View mode, else beginning of file.
 732 Display that line at the center of the window.
 733 This command pops the mark ring, so that successive
 734 invocations return to earlier marks."
 735   (interactive)
 736   (goto-char (or (mark t) (point-min)))
 737   (pop-mark)
 738   (view-recenter))
 739 \f
 740 (defun view-scroll-lines (lines backward default maxdefault)
 741   ;; This function does the job for all the scrolling commands.
 742   ;; Scroll forward LINES lines.  If BACKWARD is non-nil, scroll backwards.
 743   ;; If LINES is negative scroll in the other direction.
 744   ;; If LINES is 0 or nil, scroll DEFAULT lines (if DEFAULT is nil, scroll
 745   ;; by one page).  If MAXDEFAULT is non-nil, scroll no more than a window.
 746   (if (or (null lines) (zerop (setq lines (prefix-numeric-value lines))))
 747       (setq lines default))
 748   (when (and lines (< lines 0))
 749     (setq backward (not backward) lines (- lines)))
 750   (when (and maxdefault lines (> lines (view-window-size)))
 751     (setq lines nil))
 752   (cond (backward (scroll-down lines))
 753         ((view-really-at-end)
 754          (if view-scroll-auto-exit
 755              (View-quit)
 756            (ding)
 757            (view-end-message)))
 758         (t (scroll-up lines)
 759            (if (view-really-at-end) (view-end-message)))))
 760
 761 (defun view-really-at-end ()
 762   ;; Return true if buffer end visible.  Maybe revert buffer and test.
 763   (and (pos-visible-in-window-p (point-max))
 764        (let ((buf (current-buffer))
 765              (bufname (buffer-name))
 766              (file (buffer-file-name)))
 767          (or (not view-try-extend-at-buffer-end)
 768              (null file)
 769              (verify-visited-file-modtime buf)
 770              (not (file-exists-p file))
 771              (when (buffer-modified-p buf)
 772                (setq file (file-name-nondirectory file))
 773                (not (yes-or-no-p
 774                      (format
 775                       "File %s changed on disk.  Discard your edits%s? "
 776                       file
 777                       (if (string= bufname file) ""
 778                         (concat " in " bufname))))))
 779              (progn
 780                (revert-buffer t t t)
 781                (pos-visible-in-window-p (point-max)))))))
 782
 783 (defun view-end-message ()
 784   ;; Tell that we are at end of buffer.
 785   (goto-char (point-max))
 786   (if (window-parameter nil 'quit-restore)
 787       (message "End of buffer.  Type %s to quit viewing."
 788                (substitute-command-keys
 789                 (if view-scroll-auto-exit "\\[View-scroll-page-forward]"
 790                   "\\[View-quit]")))
 791     (message "End of buffer")))
 792 \f
 793 (defun View-scroll-to-buffer-end ()
 794   "Scroll backward or forward so that buffer end is at last line of window."
 795   (interactive)
 796   (let ((p (if (pos-visible-in-window-p (point-max)) (point))))
 797     (goto-char (point-max))
 798     (recenter -1)
 799     (and p (goto-char p))))
 800
 801 (defun View-scroll-page-forward (&optional lines)
 802   "Scroll \"page size\" or prefix LINES lines forward in View mode.
 803 Exit if end of text is visible and `view-scroll-auto-exit' is non-nil.
 804 \"page size\" is whole window full, or number of lines set by
 805 \\[View-scroll-page-forward-set-page-size] or
 806 \\[View-scroll-page-backward-set-page-size].
 807 If LINES is more than a window-full, only the last window-full is shown."
 808   (interactive "P")
 809   (view-scroll-lines lines nil (view-page-size-default view-page-size) nil))
 810
 811 (defun View-scroll-page-backward (&optional lines)
 812   "Scroll \"page size\" or prefix LINES lines backward in View mode.
 813 See also `View-scroll-page-forward'."
 814   (interactive "P")
 815   (view-scroll-lines lines t (view-page-size-default view-page-size) nil))
 816
 817 (defun View-scroll-page-forward-set-page-size (&optional lines)
 818   "Scroll forward LINES lines in View mode, setting the \"page size\".
 819 This is the number of lines which \\[View-scroll-page-forward] and
 820 \\[View-scroll-page-backward] scroll by default.
 821 If LINES is omitted or = 0, sets \"page size\" to window height and
 822 scrolls forward that much, otherwise scrolls forward LINES lines and sets
 823 \"page size\" to the minimum of window height and the absolute value of LINES.
 824 See also `View-scroll-page-forward'."
 825   (interactive "P")
 826   (view-scroll-lines lines nil
 827                      (setq view-page-size (view-page-size-default lines))
 828                      nil))
 829
 830 (defun View-scroll-page-backward-set-page-size (&optional lines)
 831   "Scroll backward prefix LINES lines in View mode, setting the \"page size\".
 832 See also `View-scroll-page-forward-set-page-size'."
 833   (interactive "P")
 834   (view-scroll-lines lines t
 835                      (setq view-page-size (view-page-size-default lines))
 836                      nil))
 837
 838 (defun View-scroll-line-forward (&optional lines)
 839   "Scroll forward one line (or prefix LINES lines) in View mode.
 840 See also `View-scroll-page-forward', but note that scrolling is limited
 841 to minimum of LINES and one window-full."
 842   (interactive "P")
 843   (view-scroll-lines lines nil 1 t))
 844
 845 (defun View-scroll-line-backward (&optional lines)
 846   "Scroll backward one line (or prefix LINES lines) in View mode.
 847 See also `View-scroll-line-forward'."
 848   (interactive "P")
 849   (view-scroll-lines lines t 1 t))
 850
 851 (defun View-scroll-half-page-forward (&optional lines)
 852   "Scroll forward a \"half page\" (or prefix LINES) lines in View mode.
 853 If LINES is not omitted, the \"half page size\" is set to the minimum of
 854 window height and the absolute value of LINES.
 855 LINES=0 resets \"half page size\" to half window height."
 856   (interactive "P")
 857   (view-scroll-lines lines nil (view-set-half-page-size-default lines) t))
 858
 859 (defun View-scroll-half-page-backward (&optional lines)
 860   "Scroll backward a \"half page\" (or prefix LINES) lines in View mode.
 861 See also `View-scroll-half-page-forward'."
 862   (interactive "P")
 863   (view-scroll-lines lines t (view-set-half-page-size-default lines) t))
 864
 865 (defun View-revert-buffer-scroll-page-forward (&optional lines)
 866   "Scroll forward, reverting buffer if needed, in View mode.
 867 If buffer has not been changed and the corresponding file is newer, first
 868 revert the buffer, then scroll.
 869 This command is useful if you are viewing a changing file.
 870
 871 The prefix argument LINES says how many lines to scroll.
 872 If you don't specify a prefix argument, it uses the number of lines set by
 873 \\[View-scroll-page-forward-set-page-size] or
 874 \\[View-scroll-page-backward-set-page-size].
 875 If LINES is more than a window-full, only the last window-full is shown."
 876   (interactive "P")
 877   (let ((view-scroll-auto-exit nil)
 878         (view-try-extend-at-buffer-end t))
 879     (view-scroll-lines lines nil (view-page-size-default view-page-size) nil)))
 880 \f
 881 (defun View-search-regexp-forward (n regexp)
 882   "Search forward for first (or prefix Nth) occurrence of REGEXP in View mode.
 883
 884 Displays line found at center of window.  Sets mark at starting position and
 885 pushes mark ring.
 886
 887 Characters @ and ! are special at the beginning of REGEXP.  They modify
 888 the search rather than become part of the pattern searched for.
 889 @ means search all the buffer i.e. start search at the beginning of buffer.
 890 ! means search for a line that contains no match for the pattern.
 891 If REGEXP is empty or only consist of these control characters, then
 892 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 893 for use by later search commands.
 894
 895 The variable `view-highlight-face' controls the face that is used
 896 for highlighting the match that is found."
 897   (interactive "p\nsSearch forward (regexp): ")
 898   (view-search n regexp))
 899
 900 (defun View-search-regexp-backward (n regexp)
 901   "Search backward for first (or prefix Nth) occurrence of REGEXP in View mode.
 902
 903 Displays line found at center of window.  Sets mark at starting position and
 904 pushes mark ring.
 905
 906 Characters @ and ! are special at the beginning of REGEXP.  They modify
 907 the search rather than become part of the pattern searched for.
 908 @ means search all the buffer i.e. start search at the end of buffer.
 909 ! means search for a line that contains no match for the pattern.
 910 If REGEXP is empty or only consist of these control characters, then
 911 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 912 for use by later search commands.
 913
 914 The variable `view-highlight-face' controls the face that is used
 915 for highlighting the match that is found."
 916   (interactive "p\nsSearch backward (regexp): ")
 917   (view-search (- n) regexp))
 918
 919 (defun View-search-last-regexp-forward (n) "\
 920 Search forward for first (or prefix Nth) instance of last regexp in View mode.
 921 Displays line found at center of window.  Sets mark at starting position and
 922 pushes mark ring.
 923
 924 The variable `view-highlight-face' controls the face that is used
 925 for highlighting the match that is found."
 926   (interactive "p")
 927   (view-search n nil))
 928
 929 (defun View-search-last-regexp-backward (n) "\
 930 Search backward for first (or prefix Nth) instance of last regexp in View mode.
 931 Displays line found at center of window.  Sets mark at starting position and
 932 pushes mark ring.
 933
 934 The variable `view-highlight-face' controls the face that is used
 935 for highlighting the match that is found."
 936   (interactive "p")
 937   (view-search (- n) nil))
 938
 939 (defun view-search (times regexp)
 940   ;; This function does the job for all the View-search- commands.
 941   ;; Search for the TIMESth match for REGEXP.  If TIMES is negative
 942   ;; search backwards.  If REGEXP is nil use `view-last-regexp'.
 943   ;; Characters "!" and "@" have a special meaning at the beginning of
 944   ;; REGEXP and are removed from REGEXP before the search "!" means
 945   ;; search for lines with no match for REGEXP.  "@" means search in
 946   ;; the whole buffer, don't start searching from the present point.
 947   (let (where no end ln)
 948     (cond
 949      ((and regexp (> (length regexp) 0)
 950            (or (not (memq (string-to-char regexp) '(?! ?@)))
 951                (progn
 952                  (if (member (substring regexp 0 2) '("!@" "@!"))
 953                      (setq end t no t ln 2)
 954                    (setq no (not (setq end (eq ?@ (string-to-char regexp))))
 955                          ln 1))
 956                  (> (length (setq regexp (substring regexp ln))) 0))))
 957       (setq view-last-regexp (if no (list regexp) regexp)))
 958      ((consp view-last-regexp)
 959       (setq regexp (car view-last-regexp))
 960       (unless (setq no (not no)) (setq view-last-regexp regexp)))
 961      (view-last-regexp (setq regexp view-last-regexp)
 962                        (if no (setq view-last-regexp (list regexp))))
 963      (t (error "No previous View-mode search")))
 964     (save-excursion
 965       (if end (goto-char (if (< times 0) (point-max) (point-min)))
 966         (move-to-window-line (if (< times 0) 0 -1)))
 967       (if (if no (view-search-no-match-lines times regexp)
 968             (re-search-forward regexp nil t times))
 969           (setq where (point))))
 970     (if where
 971         (progn
 972           (push-mark)
 973           (goto-char where)
 974           (if view-overlay
 975               (move-overlay view-overlay (match-beginning 0) (match-end 0))
 976             (setq view-overlay
 977                   (make-overlay (match-beginning 0) (match-end 0))))
 978           (overlay-put view-overlay 'face view-highlight-face)
 979           (beginning-of-line)
 980           (view-recenter))
 981       (message "Can't find occurrence %d of %s%s"
 982                times (if no "no " "") regexp)
 983       (sit-for 4))))
 984
 985 ;; This is the dumb approach, looking at each line.  The original
 986 ;; version of this function looked like it might have been trying to
 987 ;; do something clever, but not succeeding:
 988 ;; http://lists.gnu.org/archive/html/bug-gnu-emacs/2007-09/msg00073.html
 989 (defun view-search-no-match-lines (times regexp)
 990   "Search for the TIMESth occurrence of a line with no match for REGEXP.
 991 If such a line is found, return non-nil and set the match-data to that line.
 992 If TIMES is negative, search backwards."
 993   (let ((step (if (>= times 0) 1
 994                 (setq times (- times))
 995                 -1)))
 996     ;; Note that we do not check the current line.
 997     (while (and (> times 0)
 998                 (zerop (forward-line step)))
 999       ;; (forward-line 1) returns 0 on moving within the last line.
1000       (if (eobp)
1001           (setq times -1)
1002         (or (re-search-forward regexp (line-end-position) t)
1003             (setq times (1- times))))))
1004   (and (zerop times)
1005        (looking-at ".*")))
1006
1007 (provide 'view)
1008
1009 ;;; view.el ends here