configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AM_INIT_AUTOMAKE
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 dnl It is important that variables on the RHS not be expanded here,
  35 dnl hence the single quotes.  This is per the GNU coding standards, see
  36 dnl (autoconf) Installation Directory Variables
  37 dnl See also epaths.h below.
  38 lispdir='${datadir}/emacs/${version}/lisp'
  39 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  40 '${datadir}/emacs/site-lisp'
  41 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  42 etcdir='${datadir}/emacs/${version}/etc'
  43 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  44 docdir='${datadir}/emacs/${version}/etc'
  45 gamedir='${localstatedir}/games/emacs'
  46
  47 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  48 dnl Create a new --with option that defaults to being disabled.
  49 dnl NAME is the base name of the option.  The shell variable with_NAME
  50 dnl   will be set to either the user's value (if the option is
  51 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  52 dnl   option is not specified).  Note that the shell variable name is
  53 dnl   constructed as autoconf does, by replacing non-alphanumeric
  54 dnl   characters with "_".
  55 dnl HELP-STRING is the help text for the option.
  56 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  57   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  58     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  59 ])dnl
  60
  61 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  62 dnl Create a new --with option that defaults to being enabled.  NAME
  63 dnl   is the base name of the option.  The shell variable with_NAME
  64 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  65 dnl   'yes' (if the option is not specified).  Note that the shell
  66 dnl   variable name is constructed as autoconf does, by replacing
  67 dnl   non-alphanumeric characters with "_".
  68 dnl HELP-STRING is the help text for the option.
  69 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  70   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  71    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  72 ])dnl
  73
  74 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  75 if test "$with_pop" = yes; then
  76    AC_DEFINE(MAIL_USE_POP)
  77 fi
  78 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  79
  80 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  81 if test "$with_kerberos" != no; then
  82    AC_DEFINE(KERBEROS)
  83 fi
  84 AH_TEMPLATE(KERBEROS,
  85             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  86
  87 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  88 if test "${with_kerberos5}" != no; then
  89   if test "${with_kerberos}" = no; then
  90     with_kerberos=yes
  91     AC_DEFINE(KERBEROS)
  92   fi
  93   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  94 fi
  95
  96 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  97 dnl FIXME hesiod support may not be present, so it seems like an error
  98 dnl to define, or at least use, this unconditionally.
  99 if test "$with_hesiod" != no; then
 100   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 101 fi
 102
 103 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 104 if test "$with_mmdf" != no; then
 105    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 109 if test "$with_mail_unlink" != no; then
 110    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 111 fi
 112
 113 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 114     [string giving default POP mail host])],
 115     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 116
 117 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 118
 119 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 120 if test "$with_sync_input" = yes; then
 121    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 122 fi
 123
 124 dnl FIXME currently it is not the last.
 125 dnl This should be the last --with option, because --with-x is
 126 dnl added later on when we find the path of X, and it's best to
 127 dnl keep them together visually.
 128 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 129  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 130 [         case "${withval}" in
 131             y | ye | yes )      val=gtk ;;
 132             n | no )            val=no  ;;
 133             l | lu | luc | luci | lucid )       val=lucid ;;
 134             a | at | ath | athe | athen | athena )      val=athena ;;
 135             m | mo | mot | moti | motif )       val=motif ;;
 136             g | gt | gtk  )     val=gtk ;;
 137             gtk3  )     val=gtk3 ;;
 138             * )
 139 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 140 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 141 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 142             ;;
 143           esac
 144           with_x_toolkit=$val
 145 ])
 146
 147 dnl _ON results in a '--without' option in the --help output, so
 148 dnl the help text should refer to "don't compile", etc.
 149 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 150 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 151 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 152 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 153 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 154 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 155 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 156 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 157
 158 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 159 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 160 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 161
 162 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 163 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 164 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 165 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 166
 167 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 168 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 169 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 170 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 171 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH(gameuser,dnl
 204 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 205 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 206   && gameuser="${with_gameuser}"
 207 test "X$gameuser" = X && gameuser=games
 208
 209 AC_ARG_WITH([gnustep-conf],dnl
 210 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 211 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 212   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 213 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 214      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 215
 216 AC_ARG_ENABLE(ns-self-contained,
 217 [AS_HELP_STRING([--disable-ns-self-contained],
 218                 [disable self contained build under NeXTstep])],
 219    EN_NS_SELF_CONTAINED=$enableval,
 220    EN_NS_SELF_CONTAINED=yes)
 221
 222 AC_ARG_ENABLE(asserts,
 223 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 224       USE_XASSERTS=$enableval,
 225       USE_XASSERTS=no)
 226
 227 AC_ARG_ENABLE(maintainer-mode,
 228 [AS_HELP_STRING([--enable-maintainer-mode],
 229                 [enable make rules and dependencies not useful (and sometimes
 230                  confusing) to the casual installer])],
 231       USE_MAINTAINER_MODE=$enableval,
 232       USE_MAINTAINER_MODE=yes)
 233 if test $USE_MAINTAINER_MODE = yes; then
 234   MAINT=
 235 else
 236   MAINT=#
 237 fi
 238 AC_SUBST(MAINT)
 239
 240 AC_ARG_ENABLE(locallisppath,
 241 [AS_HELP_STRING([--enable-locallisppath=PATH],
 242                 [directories Emacs should search for lisp files specific
 243                  to this site])],
 244 if test "${enableval}" = "no"; then
 245   locallisppath=
 246 elif test "${enableval}" != "yes"; then
 247   locallisppath=${enableval}
 248 fi)
 249
 250 AC_ARG_ENABLE(checking,
 251 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 252                 [enable expensive run-time checks.  With LIST,
 253                  enable only specific categories of checks.
 254                  Categories are: all,yes,no.
 255                  Flags are: stringbytes, stringoverrun, stringfreelist,
 256                  xmallocoverrun, conslist])],
 257 [ac_checking_flags="${enableval}"],[])
 258 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 259 for check in $ac_checking_flags
 260 do
 261         case $check in
 262         # these set all the flags to specific states
 263         yes)            ac_enable_checking=1 ;;
 264         no)             ac_enable_checking= ;
 265                         ac_gc_check_stringbytes= ;
 266                         ac_gc_check_string_overrun= ;
 267                         ac_gc_check_string_free_list= ;
 268                         ac_xmalloc_overrun= ;
 269                         ac_gc_check_cons_list= ;;
 270         all)            ac_enable_checking=1 ;
 271                         ac_gc_check_stringbytes=1 ;
 272                         ac_gc_check_string_overrun=1 ;
 273                         ac_gc_check_string_free_list=1 ;
 274                         ac_xmalloc_overrun=1 ;
 275                         ac_gc_check_cons_list=1 ;;
 276         # these enable particular checks
 277         stringbytes)    ac_gc_check_stringbytes=1 ;;
 278         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 279         stringfreelist) ac_gc_check_string_free_list=1 ;;
 280         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 281         conslist)       ac_gc_check_cons_list=1 ;;
 282         *)      AC_MSG_ERROR(unknown check category $check) ;;
 283         esac
 284 done
 285 IFS="$ac_save_IFS"
 286
 287 if test x$ac_enable_checking != x ; then
 288   AC_DEFINE(ENABLE_CHECKING, 1,
 289 [Enable expensive run-time checking of data types?])
 290 fi
 291 if test x$ac_gc_check_stringbytes != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 293 [Define this temporarily to hunt a bug.  If defined, the size of
 294    strings is redundantly recorded in sdata structures so that it can
 295    be compared to the sizes recorded in Lisp strings.])
 296 fi
 297 if test x$ac_gc_check_string_overrun != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 299 [Define this to check for short string overrun.])
 300 fi
 301 if test x$ac_gc_check_string_free_list != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 303 [Define this to check the string free list.])
 304 fi
 305 if test x$ac_xmalloc_overrun != x ; then
 306   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 307 [Define this to check for malloc buffer overrun.])
 308 fi
 309 if test x$ac_gc_check_cons_list != x ; then
 310   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 311 [Define this to check for errors in cons list.])
 312 fi
 313
 314 AC_ARG_ENABLE(use-lisp-union-type,
 315 [AS_HELP_STRING([--enable-use-lisp-union-type],
 316                 [use a union for the Lisp_Object data type.
 317                 This is only useful for development for catching certain types of bugs.])],
 318 if test "${enableval}" != "no"; then
 319    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 320    [Define this to use a lisp union for the Lisp_Object data type.])
 321 fi)
 322
 323
 324 AC_ARG_ENABLE(profiling,
 325 [AS_HELP_STRING([--enable-profiling],
 326                 [build emacs with profiling support.
 327                  This might not work on all platforms])],
 328 [ac_enable_profiling="${enableval}"],[])
 329 if test x$ac_enable_profiling != x ; then
 330    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 331 else
 332    PROFILING_CFLAGS=
 333 fi
 334 AC_SUBST(PROFILING_CFLAGS)
 335
 336 AC_ARG_ENABLE(autodepend,
 337 [AS_HELP_STRING([--enable-autodepend],
 338                 [automatically generate dependencies to .h-files.
 339                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 340                  found])],
 341 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 342
 343 #### Make srcdir absolute, if it isn't already.  It's important to
 344 #### avoid running the path through pwd unnecessarily, since pwd can
 345 #### give you automounter prefixes, which can go away.  We do all this
 346 #### so Emacs can find its files when run uninstalled.
 347 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 348 unset CDPATH
 349 case "${srcdir}" in
 350   /* ) ;;
 351   . )
 352     ## We may be able to use the $PWD environment variable to make this
 353     ## absolute.  But sometimes PWD is inaccurate.
 354     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 355     ## but that tested only for a well-formed and valid PWD,
 356     ## it did not object when PWD was well-formed and valid but just wrong.
 357     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 358     then
 359       srcdir="$PWD"
 360     else
 361       srcdir="`(cd ${srcdir}; pwd)`"
 362     fi
 363   ;;
 364   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 365 esac
 366
 367 #### Check if the source directory already has a configured system in it.
 368 if test `pwd` != `(cd ${srcdir} && pwd)` \
 369    && test -f "${srcdir}/src/config.h" ; then
 370   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 371    as a build directory right now; it has been configured in its own
 372    right.  To configure in another directory as well, you MUST
 373    use GNU make.  If you do not have GNU make, then you must
 374    now do `make distclean' in ${srcdir},
 375    and then run $0 again.]])
 376 fi
 377
 378 #### Given the configuration name, set machfile and opsysfile to the
 379 #### names of the m/*.h and s/*.h files we should use.
 380
 381 ### Canonicalize the configuration name.
 382
 383 AC_CANONICAL_HOST
 384 canonical=$host
 385 configuration=${host_alias-${build_alias-$host}}
 386
 387 dnl This used to use changequote, but, apart from `changequote is evil'
 388 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 389 dnl the great gob of text.  Thus it's not processed for possible expansion.
 390 dnl Just make sure the brackets remain balanced.
 391 dnl
 392 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 393 dnl indicated by comments.
 394 dnl quotation begins
 395 [
 396
 397 ### If you add support for a new configuration, add code to this
 398 ### switch statement to recognize your configuration name and select
 399 ### the appropriate operating system and machine description files.
 400
 401 ### You would hope that you could choose an m/*.h file pretty much
 402 ### based on the machine portion of the configuration name, and an s/*.h
 403 ### file based on the operating system portion.  However, it turns out
 404 ### that each m/*.h file is pretty manufacturer-specific - for
 405 ### example mips.h is MIPS
 406 ### So we basically have to have a special case for each
 407 ### configuration name.
 408 ###
 409 ### As far as handling version numbers on operating systems is
 410 ### concerned, make sure things will fail in a fixable way.  If
 411 ### /etc/MACHINES doesn't say anything about version numbers, be
 412 ### prepared to handle anything reasonably.  If version numbers
 413 ### matter, be sure /etc/MACHINES says something about it.
 414
 415 machine='' opsys='' unported=no
 416 case "${canonical}" in
 417
 418   ## GNU/Linux ports
 419   *-*-linux-gnu*)
 420     opsys=gnu-linux
 421     case ${canonical} in
 422       alpha*)   machine=alpha ;;
 423       s390-*)   machine=ibms390 ;;
 424       s390x-*)  machine=ibms390x ;;
 425       powerpc*) machine=macppc ;;
 426       sparc*)   machine=sparc ;;
 427       ia64*)    machine=ia64 ;;
 428       m68k*)    machine=m68k ;;
 429       x86_64*)  machine=amdx86-64 ;;
 430     esac
 431   ;;
 432
 433   ## FreeBSD ports
 434   *-*-freebsd* )
 435     opsys=freebsd
 436     case "${canonical}" in
 437       alpha*)           machine=alpha ;;
 438       amd64-*|x86_64-*) machine=amdx86-64 ;;
 439       ia64-*)           machine=ia64 ;;
 440       i[3456]86-*)      machine=intel386 ;;
 441       powerpc-*)        machine=macppc ;;
 442       sparc-*)          machine=sparc ;;
 443       sparc64-*)        machine=sparc ;;
 444     esac
 445   ;;
 446
 447   ## FreeBSD kernel + glibc based userland
 448   *-*-kfreebsd*gnu* )
 449     opsys=gnu-kfreebsd
 450     case "${canonical}" in
 451       alpha*)           machine=alpha ;;
 452       amd64-*|x86_64-*) machine=amdx86-64 ;;
 453       ia64-*)           machine=ia64 ;;
 454       i[3456]86-*)      machine=intel386 ;;
 455       powerpc-*)        machine=macppc ;;
 456       sparc-*)          machine=sparc ;;
 457       sparc64-*)        machine=sparc ;;
 458     esac
 459   ;;
 460
 461   ## NetBSD ports
 462   *-*-netbsd* )
 463     opsys=netbsd
 464     case "${canonical}" in
 465       alpha*)      machine=alpha ;;
 466       x86_64-*)    machine=amdx86-64 ;;
 467       i[3456]86-*) machine=intel386 ;;
 468       m68k-*)      machine=m68k ;;
 469       powerpc-*)   machine=macppc ;;
 470       sparc*-)     machine=sparc ;;
 471       vax-*)       machine=vax ;;
 472     esac
 473   ;;
 474
 475   ## OpenBSD ports
 476   *-*-openbsd* )
 477     opsys=openbsd
 478     case "${canonical}" in
 479       alpha*)    machine=alpha ;;
 480       x86_64-*)  machine=amdx86-64 ;;
 481       i386-*)    machine=intel386 ;;
 482       powerpc-*) machine=macppc ;;
 483       sparc*)    machine=sparc ;;
 484       vax-*)     machine=vax ;;
 485     esac
 486   ;;
 487
 488   ## Apple Darwin / Mac OS X
 489   *-apple-darwin* )
 490     case "${canonical}" in
 491       i[3456]86-* )  machine=intel386 ;;
 492       powerpc-* )    machine=macppc ;;
 493       x86_64-* )     machine=amdx86-64 ;;
 494       * )            unported=yes ;;
 495     esac
 496     opsys=darwin
 497     # Define CPP as follows to make autoconf work correctly.
 498     CPP="${CC-cc} -E -no-cpp-precomp"
 499     # Use fink packages if available.
 500     if test -d /sw/include && test -d /sw/lib; then
 501       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 502       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 503       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 504     fi
 505   ;;
 506
 507   ## HP 9000 series 700 and 800, running HP/UX
 508   hppa*-hp-hpux10.2* )
 509     opsys=hpux10-20
 510   ;;
 511   hppa*-hp-hpux1[1-9]* )
 512     opsys=hpux11
 513     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 514   ;;
 515
 516   ia64*-hp-hpux1[1-9]* )
 517     machine=hp800 opsys=hpux11
 518     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 519     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 520     CANNOT_DUMP=yes
 521   ;;
 522
 523   hppa*-*-linux-gnu* )
 524     machine=hp800 opsys=gnu-linux
 525   ;;
 526
 527   ## IBM machines
 528   rs6000-ibm-aix4.[23]* )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   powerpc-ibm-aix4.[23]*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534   rs6000-ibm-aix[56]* )
 535     machine=ibmrs6000 opsys=aix4-2
 536   ;;
 537   powerpc-ibm-aix[56]*  )
 538     machine=ibmrs6000 opsys=aix4-2
 539   ;;
 540
 541   ## Silicon Graphics machines
 542   ## Iris 4D
 543   mips-sgi-irix6.5 )
 544     machine=iris4d opsys=irix6-5
 545     # Without defining _LANGUAGE_C, things get masked out in the headers
 546     # so that, for instance, grepping for `free' in stdlib.h fails and
 547     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 548     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 549     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 550   ;;
 551
 552   ## Suns
 553   *-sun-solaris* \
 554     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 555     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 556     case "${canonical}" in
 557       i[3456]86-*-* )     machine=intel386 ;;
 558       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 559       sparc* )          machine=sparc ;;
 560       * )               unported=yes ;;
 561     esac
 562     case "${canonical}" in
 563       *-sunos5.6* | *-solaris2.6* )
 564                 opsys=sol2-6
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 RANLIB="ar -ts"
 567                 ;;
 568       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 569                 opsys=sol2-6
 570                 emacs_check_sunpro_c=yes
 571                 NON_GNU_CPP=/usr/ccs/lib/cpp
 572                 ;;
 573       *-sunos5* | *-solaris* )
 574                 opsys=sol2-10
 575                 emacs_check_sunpro_c=yes
 576                 NON_GNU_CPP=/usr/ccs/lib/cpp
 577                 ;;
 578     esac
 579     ## Watch out for a compiler that we know will not work.
 580     case "${canonical}" in
 581      *-solaris* | *-sunos5* )
 582                 if [ "x$CC" = x/usr/ucb/cc ]; then
 583                   ## /usr/ucb/cc doesn't work;
 584                   ## we should find some other compiler that does work.
 585                   unset CC
 586                 fi
 587                 ;;
 588       *) ;;
 589     esac
 590   ;;
 591
 592   ## Intel 386 machines where we don't care about the manufacturer.
 593   i[3456]86-*-* )
 594     machine=intel386
 595     case "${canonical}" in
 596       *-cygwin )                opsys=cygwin ;;
 597       *-darwin* )               opsys=darwin
 598                                 CPP="${CC-cc} -E -no-cpp-precomp"
 599                                 ;;
 600       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 601       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 602       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 603       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 604     esac
 605   ;;
 606
 607   * )
 608     unported=yes
 609   ;;
 610 esac
 611
 612 ### If the code above didn't choose an operating system, just choose
 613 ### an operating system based on the configuration name.  You really
 614 ### only want to use this when you have no idea what the right
 615 ### operating system is; if you know what operating systems a machine
 616 ### runs, it's cleaner to make it explicit in the case statement
 617 ### above.
 618 if test x"${opsys}" = x; then
 619   case "${canonical}" in
 620     *-gnu* )                            opsys=gnu ;;
 621     * )
 622       unported=yes
 623     ;;
 624   esac
 625 fi
 626
 627 ]
 628 dnl quotation ends
 629
 630 if test $unported = yes; then
 631   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 632 Check `etc/MACHINES' for recognized configuration names.])
 633 fi
 634
 635 if test -n "$machine"; then
 636   machfile="m/${machine}.h"
 637 else
 638   machfile=
 639 fi
 640 opsysfile="s/${opsys}.h"
 641
 642
 643 #### Choose a compiler.
 644 test -n "$CC" && cc_specified=yes
 645
 646 # Save the value of CFLAGS that the user specified.
 647 SPECIFIED_CFLAGS="$CFLAGS"
 648
 649 dnl Sets GCC=yes if using gcc.
 650 AC_PROG_CC
 651 AM_PROG_CC_C_O
 652
 653 # Initialize gnulib right after verifying that the C compiler works.
 654 gl_EARLY
 655
 656 # On Suns, sometimes $CPP names a directory.
 657 if test -n "$CPP" && test -d "$CPP"; then
 658   CPP=
 659 fi
 660
 661 ## If not using gcc, and on Solaris, and no CPP specified, see if
 662 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 663 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 664  test x"$CPP" = x; then
 665   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 666   AC_CACHE_VAL(emacs_cv_sunpro_c,
 667   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 668 [[#ifndef __SUNPRO_C
 669 fail;
 670 #endif
 671 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 672   AC_MSG_RESULT($emacs_cv_sunpro_c)
 673
 674   if test x"$emacs_cv_sunpro_c" = xyes; then
 675     NON_GNU_CPP="$CC -E -Xs"
 676   fi
 677 fi
 678
 679 #### Some systems specify a CPP to use unless we are using GCC.
 680 #### Now that we know whether we are using GCC, we can decide whether
 681 #### to use that one.
 682 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 683 then
 684   CPP="$NON_GNU_CPP"
 685 fi
 686
 687 #### Some systems specify a CC to use unless we are using GCC.
 688 #### Now that we know whether we are using GCC, we can decide whether
 689 #### to use that one.
 690 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 691   test x$cc_specified != xyes
 692 then
 693   CC="$NON_GNU_CC"
 694 fi
 695
 696 if test x$GCC = xyes; then
 697   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 698 else
 699   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 700 fi
 701
 702 ### Use -Wdeclaration-after-statement if the compiler supports it
 703 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 704 SAVE_CFLAGS="$CFLAGS"
 705 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 706 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 707 if test $has_option = yes; then
 708    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 709 fi
 710 AC_MSG_RESULT($has_option)
 711 CFLAGS="$SAVE_CFLAGS"
 712 unset has_option
 713 unset SAVE_CFLAGS
 714
 715 ### Use -Wold-style-definition if the compiler supports it
 716 # This can be removed when conversion to standard C is finished.
 717 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 718 SAVE_CFLAGS="$CFLAGS"
 719 CFLAGS="$CFLAGS -Wold-style-definition"
 720 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 721 if test $has_option = yes; then
 722    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 723 fi
 724 AC_MSG_RESULT($has_option)
 725 CFLAGS="$SAVE_CFLAGS"
 726 unset has_option
 727 unset SAVE_CFLAGS
 728
 729 ### Use -Wimplicit-function-declaration if the compiler supports it
 730 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 733 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 AC_SUBST(C_WARNINGS_SWITCH)
 743
 744
 745 #### Some other nice autoconf tests.
 746
 747 dnl checks for programs
 748 AC_PROG_CPP
 749 AC_PROG_INSTALL
 750 if test "x$RANLIB" = x; then
 751   AC_PROG_RANLIB
 752 fi
 753
 754 ## Although we're running on an amd64 kernel, we're actually compiling for
 755 ## the x86 architecture.  The user should probably have provided an
 756 ## explicit --build to `configure', but if everything else than the kernel
 757 ## is running in i386 mode, we can help them out.
 758 if test "$machine" = "amdx86-64"; then
 759   AC_CHECK_DECL([i386])
 760   if test "$ac_cv_have_decl_i386" = "yes"; then
 761     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 762     machine=intel386
 763     machfile="m/${machine}.h"
 764   fi
 765 fi
 766
 767 AC_PATH_PROG(INSTALL_INFO, install-info)
 768 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 769 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 770 dnl Don't use GZIP, which is used by gzip for additional parameters.
 771 AC_PATH_PROG(GZIP_PROG, gzip)
 772
 773
 774 ## Need makeinfo >= 4.6 (?) to build the manuals.
 775 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 776 dnl By this stage, configure has already checked for egrep and set EGREP,
 777 dnl or exited with an error if no egrep was found.
 778 if test "$MAKEINFO" != "no" && \
 779   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 780    MAKEINFO=no
 781 fi
 782
 783 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 784 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 785 ## therefore in the category of "special tools" not normally required, which
 786 ## configure does not have to check for (eg autoconf itself).
 787 ## In a Bazaar checkout on the other hand, the manuals are not included.
 788 ## So makeinfo is a requirement to build from Bazaar, and configure
 789 ## should test for it as it does for any other build requirement.
 790 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 791 ## with pre-built manuals, from a Bazaar checkout.
 792 HAVE_MAKEINFO=yes
 793
 794 if test "$MAKEINFO" = "no"; then
 795   MAKEINFO=makeinfo
 796   if test "x${with_makeinfo}" = "xno"; then
 797     HAVE_MAKEINFO=no
 798   elif test ! -e $srcdir/info/emacs; then
 799     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 800 source tree does not seem to have pre-built manuals in the `info' directory.
 801 Either install a suitable version of makeinfo, or re-run configure
 802 with the `--without-makeinfo' option to build without the manuals.] )
 803   fi
 804 fi
 805 AC_SUBST(HAVE_MAKEINFO)
 806
 807 dnl Add our options to ac_link now, after it is set up.
 808
 809 if test x$GCC = xyes; then
 810   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 811     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 812 else
 813   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 814     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 815 fi
 816
 817 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 818 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 819 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 820 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 821 dnl if not built to support GNU ld.
 822
 823 late_LDFLAGS=$LDFLAGS
 824 if test x$GCC = xyes; then
 825   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 826 else
 827   LDFLAGS="$LDFLAGS -znocombreloc"
 828 fi
 829
 830 AC_MSG_CHECKING([for -znocombreloc])
 831 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 832   [AC_MSG_RESULT(yes)],
 833   LDFLAGS=$late_LDFLAGS
 834   [AC_MSG_RESULT(no)])
 835
 836
 837 # The value of CPP is a quoted variable reference, so we need to do this
 838 # to get its actual value...
 839 CPP=`eval "echo $CPP"`
 840
 841
 842 dnl The function dump-emacs will not be defined and temacs will do
 843 dnl (load "loadup") automatically unless told otherwise.
 844 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 845 case "$opsys" in
 846   your-opsys-here) CANNOT_DUMP=yes ;;
 847 esac
 848
 849 test "$CANNOT_DUMP" = "yes" && \
 850   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 851
 852 AC_SUBST(CANNOT_DUMP)
 853
 854
 855 UNEXEC_OBJ=unexelf.o
 856 case "$opsys" in
 857   # MSDOS uses unexcoff.o
 858   # MSWindows uses unexw32.o
 859   aix4-2)
 860    UNEXEC_OBJ=unexaix.o
 861    ;;
 862   cygwin)
 863    UNEXEC_OBJ=unexcw.o
 864    ;;
 865   darwin)
 866    UNEXEC_OBJ=unexmacosx.o
 867    ;;
 868   hpux10-20 | hpux11)
 869    UNEXEC_OBJ=unexhp9k800.o
 870    ;;
 871   sol2-10)
 872    # Use the Solaris dldump() function, called from unexsol.c, to dump
 873    # emacs, instead of the generic ELF dump code found in unexelf.c.
 874    # The resulting binary has a complete symbol table, and is better
 875    # for debugging and other observability tools (debuggers, pstack, etc).
 876    #
 877    # If you encounter a problem using dldump(), please consider sending
 878    # a message to the OpenSolaris tools-linking mailing list:
 879    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 880    #
 881    # It is likely that dldump() works with older Solaris too, but this has
 882    # not been tested, so for now this change is for Solaris 10 or newer.
 883    UNEXEC_OBJ=unexsol.o
 884    ;;
 885 esac
 886
 887 LD_SWITCH_SYSTEM=
 888 case "$opsys" in
 889   freebsd)
 890    ## Let `ld' find image libs and similar things in /usr/local/lib.
 891    ## The system compiler, GCC, has apparently been modified to not
 892    ## look there, contrary to what a stock GCC would do.
 893    LD_SWITCH_SYSTEM=-L/usr/local/lib
 894    ;;
 895
 896   gnu-linux)
 897    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 898    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 899    ;;
 900
 901   netbsd)
 902    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 903    ;;
 904
 905   openbsd)
 906    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 907    ## otherwise Emacs dumps core on elf systems.
 908    LD_SWITCH_SYSTEM="-Z"
 909    ;;
 910 esac
 911 AC_SUBST(LD_SWITCH_SYSTEM)
 912
 913 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 914
 915 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 916 ## which has not been defined yet.  When this was handled with cpp,
 917 ## it was expanded to null when configure sourced the s/*.h file.
 918 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 919 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 920 ## (or somesuch), but because it is supposed to go at the _front_
 921 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 922 ## Compare with the gnu-linux case below, which added to the end
 923 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 924 ## LD_SWITCH_SYSTEM_TEMACS.
 925 case "$opsys" in
 926   netbsd|openbsd)
 927    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 928    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 929 esac
 930
 931
 932 C_SWITCH_MACHINE=
 933 if test "$machine" = "alpha"; then
 934   AC_CHECK_DECL([__ELF__])
 935   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 936     ## With ELF, make sure that all common symbols get allocated to in the
 937     ## data section.  Otherwise, the dump of temacs may miss variables in
 938     ## the shared library that have been initialized.  For example, with
 939     ## GNU libc, __malloc_initialized would normally be resolved to the
 940     ## shared library's .bss section, which is fatal.
 941     if test "x$GCC" = "xyes"; then
 942       C_SWITCH_MACHINE="-fno-common"
 943     else
 944       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 945     fi
 946   else
 947     UNEXEC_OBJ=unexalpha.o
 948   fi
 949 fi
 950 AC_SUBST(C_SWITCH_MACHINE)
 951
 952 AC_SUBST(UNEXEC_OBJ)
 953
 954 C_SWITCH_SYSTEM=
 955 ## Some programs in src produce warnings saying certain subprograms
 956 ## are too complex and need a MAXMEM value greater than 2000 for
 957 ## additional optimization.  --nils@exp-math.uni-essen.de
 958 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 959   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 960 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 961 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 962 AC_SUBST(C_SWITCH_SYSTEM)
 963
 964
 965 LIBS_SYSTEM=
 966 case "$opsys" in
 967   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 968   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 969
 970   freebsd) LIBS_SYSTEM="-lutil" ;;
 971
 972   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 973
 974   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 975
 976   ## Motif needs -lgen.
 977   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 978 esac
 979 AC_SUBST(LIBS_SYSTEM)
 980
 981
 982 ### Make sure subsequent tests use flags consistent with the build flags.
 983
 984 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 985   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 986 else
 987   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 988 fi
 989
 990 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 991 AC_DEFUN([AC_TYPE_SIZE_T])
 992
 993 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 994 AC_SYS_LARGEFILE
 995
 996
 997 ## If user specified a crt-dir, use that unconditionally.
 998 if test "X$CRT_DIR" = "X"; then
 999
1000   case "$canonical" in
1001     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1002     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1003     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1004     ## For anything else (eg /usr/lib32), it is up the user to specify
1005     ## the location (bug#5655).
1006     ## Test for crtn.o, not just the directory, because sometimes the
1007     ## directory exists but does not have the relevant files (bug#1287).
1008     ## FIXME better to test for binary compatibility somehow.
1009     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1010     ;;
1011
1012     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1013   esac
1014
1015   case "$opsys" in
1016     hpux10-20) CRT_DIR=/lib ;;
1017   esac
1018
1019   ## Default is /usr/lib.
1020   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1021
1022 else
1023
1024   ## Some platforms don't use any of these files, so it is not
1025   ## appropriate to put this test outside the if block.
1026   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1027     AC_MSG_ERROR([crt*.o not found in specified location.])
1028
1029 fi
1030
1031 AC_SUBST(CRT_DIR)
1032
1033 LIB_MATH=-lm
1034 LIB_STANDARD=
1035 START_FILES=
1036
1037 case $opsys in
1038   cygwin )
1039     LIB_MATH=
1040     START_FILES='pre-crt0.o'
1041     ;;
1042   darwin )
1043     ## Adding -lm confuses the dynamic linker, so omit it.
1044     LIB_MATH=
1045     START_FILES='pre-crt0.o'
1046     ;;
1047   freebsd )
1048     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1049     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1050     ;;
1051   gnu-linux | gnu-kfreebsd )
1052     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1053     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1054     ;;
1055   hpux10-20 | hpux11 )
1056     LIB_STANDARD=-lc
1057     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1058     ;;
1059   netbsd | openbsd )
1060     if test -f $CRT_DIR/crti.o; then
1061         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1062         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1063     else
1064         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1065         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1066     fi
1067     ;;
1068 esac
1069
1070 AC_SUBST(LIB_MATH)
1071 AC_SUBST(START_FILES)
1072
1073 dnl This function definition taken from Gnome 2.0
1074 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1075 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1076 dnl also defines GSTUFF_PKG_ERRORS on error
1077 AC_DEFUN([PKG_CHECK_MODULES], [
1078   succeeded=no
1079
1080   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1081
1082   if test "$PKG_CONFIG" = "no" ; then
1083      ifelse([$4], , [AC_MSG_ERROR([
1084       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1085   else
1086      PKG_CONFIG_MIN_VERSION=0.9.0
1087      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1088         AC_MSG_CHECKING(for $2)
1089
1090         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1091             AC_MSG_RESULT(yes)
1092             succeeded=yes
1093
1094             AC_MSG_CHECKING($1_CFLAGS)
1095             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1096             AC_MSG_RESULT($$1_CFLAGS)
1097
1098             AC_MSG_CHECKING($1_LIBS)
1099             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1100             AC_MSG_RESULT($$1_LIBS)
1101         else
1102             AC_MSG_RESULT(no)
1103             $1_CFLAGS=""
1104             $1_LIBS=""
1105             ## If we have a custom action on failure, don't print errors, but
1106             ## do set a variable so people can do so.
1107             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1108             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1109         fi
1110
1111         AC_SUBST($1_CFLAGS)
1112         AC_SUBST($1_LIBS)
1113      else
1114         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1115         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1116      fi
1117   fi
1118
1119   if test $succeeded = yes; then
1120      ifelse([$3], , :, [$3])
1121   else
1122      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1123   fi
1124 ])
1125
1126
1127 if test "${with_sound}" != "no"; then
1128   # Sound support for GNU/Linux and the free BSDs.
1129   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1130     have_sound_header=yes)
1131   # Emulation library used on NetBSD.
1132   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1133   AC_SUBST(LIBSOUND)
1134
1135   ALSA_REQUIRED=1.0.0
1136   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1137   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1138   if test $HAVE_ALSA = yes; then
1139     SAVE_CFLAGS="$CFLAGS"
1140     SAVE_LDFLAGS="$LDFLAGS"
1141     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1142     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1143     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1144                     emacs_alsa_normal=yes,
1145                     emacs_alsa_normal=no)
1146     if test "$emacs_alsa_normal" != yes; then
1147       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1148                      [[snd_lib_error_set_handler (0);]])],
1149                      emacs_alsa_subdir=yes,
1150                      emacs_alsa_subdir=no)
1151       if test "$emacs_alsa_subdir" != yes; then
1152         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1153       fi
1154       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1155     fi
1156
1157     CFLAGS="$SAVE_CFLAGS"
1158     LDFLAGS="$SAVE_LDFLAGS"
1159     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1160     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1161     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1162   fi
1163
1164   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1165   dnl compiles only on the specified platforms.  For others, it
1166   dnl probably doesn't make sense to try.
1167   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1168      case "$opsys" in
1169        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1170        gnu-linux|freebsd|netbsd)
1171          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1172          ;;
1173      esac
1174   fi
1175
1176   AC_SUBST(CFLAGS_SOUND)
1177 fi
1178
1179 dnl checks for header files
1180 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1181   linux/version.h sys/systeminfo.h limits.h \
1182   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1183   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1184   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1185
1186 AC_MSG_CHECKING(if personality LINUX32 can be set)
1187 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1188                emacs_cv_personality_linux32=yes,
1189                emacs_cv_personality_linux32=no)
1190 AC_MSG_RESULT($emacs_cv_personality_linux32)
1191
1192 if test $emacs_cv_personality_linux32 = yes; then
1193   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1194             [Define to 1 if personality LINUX32 can be set.])
1195 fi
1196
1197 dnl On Solaris 8 there's a compilation warning for term.h because
1198 dnl it doesn't define `bool'.
1199 AC_CHECK_HEADERS(term.h, , , -)
1200 AC_HEADER_STDC
1201 AC_HEADER_TIME
1202 AC_CHECK_DECLS([sys_siglist])
1203 if test $ac_cv_have_decl_sys_siglist != yes; then
1204   # For Tru64, at least:
1205   AC_CHECK_DECLS([__sys_siglist])
1206   if test $ac_cv_have_decl___sys_siglist = yes; then
1207     AC_DEFINE(sys_siglist, __sys_siglist,
1208               [Define to any substitute for sys_siglist.])
1209   fi
1210 fi
1211 AC_HEADER_SYS_WAIT
1212
1213 dnl Some systems have utime.h but don't declare the struct anyplace.
1214 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1215 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1216 #include <sys/time.h>
1217 #include <time.h>
1218 #else
1219 #ifdef HAVE_SYS_TIME_H
1220 #include <sys/time.h>
1221 #else
1222 #include <time.h>
1223 #endif
1224 #endif
1225 #ifdef HAVE_UTIME_H
1226 #include <utime.h>
1227 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1228   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1229 if test $emacs_cv_struct_utimbuf = yes; then
1230   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1231 fi
1232
1233 dnl Check for speed_t typedef.
1234 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1235   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1236     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1237 if test $emacs_cv_speed_t = yes; then
1238   AC_DEFINE(HAVE_SPEED_T, 1,
1239            [Define to 1 if `speed_t' is declared by <termios.h>.])
1240 fi
1241
1242 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1243 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1244 #include <sys/time.h>
1245 #include <time.h>
1246 #else
1247 #ifdef HAVE_SYS_TIME_H
1248 #include <sys/time.h>
1249 #else
1250 #include <time.h>
1251 #endif
1252 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1253   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1254 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1255 if test $emacs_cv_struct_timeval = yes; then
1256   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1257 fi
1258
1259 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1260 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1261 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1262   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1263 HAVE_EXCEPTION=$emacs_cv_struct_exception
1264 if test $emacs_cv_struct_exception != yes; then
1265   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1266 fi
1267
1268 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1269 #if HAVE_SYS_SOCKET_H
1270 #include <sys/socket.h>
1271 #endif])
1272
1273 dnl checks for structure members
1274 AC_STRUCT_TM
1275 AC_STRUCT_TIMEZONE
1276 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1277                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1278                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1279                 [#include <time.h>])
1280 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1281                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1282                   struct ifreq.ifr_addr], , ,
1283                  [AC_INCLUDES_DEFAULT
1284 #if HAVE_SYS_SOCKET_H
1285 #include <sys/socket.h>
1286 #endif
1287 #if HAVE_NET_IF_H
1288 #include <net/if.h>
1289 #endif])
1290
1291 dnl checks for compiler characteristics
1292
1293 dnl Testing __STDC__ to determine prototype support isn't good enough.
1294 dnl DEC C, for instance, doesn't define it with default options, and
1295 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1296 dnl and void *.
1297 AC_C_PROTOTYPES
1298 AC_C_VOLATILE
1299 AC_C_CONST
1300 dnl This isn't useful because we can't turn on use of `inline' unless
1301 dnl the compiler groks `extern inline'.
1302 dnl AC_C_INLINE
1303 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1304   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1305                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1306 if test $emacs_cv_void_star = yes; then
1307   AC_DEFINE(POINTER_TYPE, void)
1308 else
1309   AC_DEFINE(POINTER_TYPE, char)
1310 fi
1311 AH_TEMPLATE(POINTER_TYPE,
1312             [Define as `void' if your compiler accepts `void *'; otherwise
1313              define as `char'.])dnl
1314
1315 dnl Check for endianess
1316 AC_C_BIGENDIAN
1317
1318 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1319   [emacs_cv_attribute_aligned],
1320   [AC_COMPILE_IFELSE(
1321      [AC_LANG_PROGRAM(
1322         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1323         [[]])],
1324      [emacs_cv_attribute_aligned=yes],
1325      [emacs_cv_attribute_aligned=no])])
1326 if test $emacs_cv_attribute_aligned = yes; then
1327   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1328     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1329 fi
1330
1331 dnl check for Make feature
1332 AC_PROG_MAKE_SET
1333
1334 DEPFLAGS=
1335 MKDEPDIR=":"
1336 deps_frag=deps.mk
1337 dnl check for GNU Make if we have GCC and autodepend is on.
1338 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1339    AC_MSG_CHECKING([whether we are using GNU Make])
1340    HAVE_GNU_MAKE=no
1341    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1342    if test "x$testval" != x; then
1343       HAVE_GNU_MAKE=yes
1344    else
1345       ac_enable_autodepend=no
1346    fi
1347    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1348    if test $HAVE_GNU_MAKE = yes; then
1349       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1350       SAVE_CFLAGS="$CFLAGS"
1351       CFLAGS="$CFLAGS -MMD -MF deps.d"
1352       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1353       CFLAGS="$SAVE_CFLAGS"
1354       test -f deps.d || ac_enable_autodepend=no
1355       rm -rf deps.d
1356       AC_MSG_RESULT([$ac_enable_autodepend])
1357    fi
1358    if test $ac_enable_autodepend = yes; then
1359       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1360       ## In parallel builds, another make might create depdir between
1361       ## the first test and mkdir, so stick another test on the end.
1362       ## Or use install-sh -d?  mkdir -p is not portable.
1363       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1364       deps_frag=autodeps.mk
1365    fi
1366 fi
1367 deps_frag=$srcdir/src/$deps_frag
1368 AC_SUBST(MKDEPDIR)
1369 AC_SUBST(DEPFLAGS)
1370 AC_SUBST_FILE(deps_frag)
1371
1372
1373 dnl checks for operating system services
1374 AC_SYS_LONG_FILE_NAMES
1375
1376 #### Choose a window system.
1377
1378 AC_PATH_X
1379 if test "$no_x" = yes; then
1380   window_system=none
1381 else
1382   window_system=x11
1383 fi
1384
1385 ## Workaround for bug in autoconf <= 2.62.
1386 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1387 ## No need to do anything special for these standard directories.
1388 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1389
1390    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1391
1392 fi
1393
1394 LD_SWITCH_X_SITE_AUX=
1395 LD_SWITCH_X_SITE_AUX_RPATH=
1396 if test "${x_libraries}" != NONE; then
1397   if test -n "${x_libraries}"; then
1398     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1399     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1400     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1401   fi
1402   x_default_search_path=""
1403   x_search_path=${x_libraries}
1404   if test -z "${x_search_path}"; then
1405     x_search_path=/usr/lib
1406   fi
1407   for x_library in `echo ${x_search_path}: | \
1408                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1409     x_search_path="\
1410 ${x_library}/X11/%L/%T/%N%C%S:\
1411 ${x_library}/X11/%l/%T/%N%C%S:\
1412 ${x_library}/X11/%T/%N%C%S:\
1413 ${x_library}/X11/%L/%T/%N%S:\
1414 ${x_library}/X11/%l/%T/%N%S:\
1415 ${x_library}/X11/%T/%N%S"
1416     if test x"${x_default_search_path}" = x; then
1417       x_default_search_path=${x_search_path}
1418     else
1419       x_default_search_path="${x_search_path}:${x_default_search_path}"
1420     fi
1421   done
1422 fi
1423 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1424 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1425
1426 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1427   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1428 fi
1429
1430 if test x"${x_includes}" = x; then
1431   bitmapdir=/usr/include/X11/bitmaps
1432 else
1433   # accumulate include directories that have X11 bitmap subdirectories
1434   bmd_acc="dummyval"
1435   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1436     if test -d "${bmd}/X11/bitmaps"; then
1437       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1438     fi
1439     if test -d "${bmd}/bitmaps"; then
1440       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1441     fi
1442   done
1443   if test ${bmd_acc} != "dummyval"; then
1444     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1445   fi
1446 fi
1447
1448 HAVE_NS=no
1449 NS_IMPL_COCOA=no
1450 NS_IMPL_GNUSTEP=no
1451 tmp_CPPFLAGS="$CPPFLAGS"
1452 tmp_CFLAGS="$CFLAGS"
1453 CPPFLAGS="$CPPFLAGS -x objective-c"
1454 CFLAGS="$CFLAGS -x objective-c"
1455 TEMACS_LDFLAGS2="\${LDFLAGS}"
1456 dnl I don't think it's especially important, but src/Makefile.in
1457 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1458 dnl trailing "/" to it, so now we do it here.
1459 if test "${with_ns}" != no; then
1460   if test "${opsys}" = darwin; then
1461      NS_IMPL_COCOA=yes
1462      ns_appdir=`pwd`/nextstep/Emacs.app
1463      ns_appbindir=${ns_appdir}/Contents/MacOS/
1464      ns_appresdir=${ns_appdir}/Contents/Resources
1465      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1466   elif test -f $GNUSTEP_CONFIG_FILE; then
1467      NS_IMPL_GNUSTEP=yes
1468      ns_appdir=`pwd`/nextstep/Emacs.app
1469      ns_appbindir=${ns_appdir}/
1470      ns_appresdir=${ns_appdir}/Resources
1471      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1472      dnl FIXME sourcing this several times in subshells seems inefficient.
1473      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1474      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1475      dnl I seemed to need these as well with GNUstep-startup 0.25.
1476      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1477      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1478      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1479        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1480      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1481        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1482      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1483      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1484      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1485      LIB_STANDARD=
1486      START_FILES=
1487      TEMACS_LDFLAGS2=
1488   fi
1489   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1490                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1491   files are missing or cannot be compiled.])])
1492   NS_HAVE_NSINTEGER=yes
1493   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1494                                      [NSInteger i;])],
1495                     ns_have_nsinteger=yes,
1496                     ns_have_nsinteger=no)
1497   if test $ns_have_nsinteger = no; then
1498     NS_HAVE_NSINTEGER=no
1499   fi
1500 fi
1501 AC_SUBST(TEMACS_LDFLAGS2)
1502
1503 ns_frag=/dev/null
1504 NS_OBJ=
1505 NS_OBJC_OBJ=
1506 NS_SUPPORT=
1507 if test "${HAVE_NS}" = yes; then
1508   window_system=nextstep
1509   with_xft=no
1510   # set up packaging dirs
1511   exec_prefix=${ns_appbindir}
1512   libexecdir=${ns_appbindir}/libexec
1513   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1514      prefix=${ns_appresdir}
1515   fi
1516   ns_frag=$srcdir/src/ns.mk
1517   NS_OBJ="fontset.o fringe.o image.o"
1518   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1519   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1520 fi
1521 CFLAGS="$tmp_CFLAGS"
1522 CPPFLAGS="$tmp_CPPFLAGS"
1523 AC_SUBST(NS_OBJ)
1524 AC_SUBST(NS_OBJC_OBJ)
1525 AC_SUBST(NS_SUPPORT)
1526 AC_SUBST(LIB_STANDARD)
1527 AC_SUBST_FILE(ns_frag)
1528
1529 case "${window_system}" in
1530   x11 )
1531     HAVE_X_WINDOWS=yes
1532     HAVE_X11=yes
1533     case "${with_x_toolkit}" in
1534       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1535       motif ) USE_X_TOOLKIT=MOTIF ;;
1536       gtk ) with_gtk=yes
1537 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1538 dnl USE_X_TOOLKIT is set.
1539             USE_X_TOOLKIT=none ;;
1540       gtk3 ) with_gtk3=yes
1541              USE_X_TOOLKIT=none ;;
1542       no ) USE_X_TOOLKIT=none ;;
1543 dnl If user did not say whether to use a toolkit, make this decision later:
1544 dnl use the toolkit if we have gtk, or X11R5 or newer.
1545       * ) USE_X_TOOLKIT=maybe ;;
1546     esac
1547   ;;
1548   nextstep | none )
1549     HAVE_X_WINDOWS=no
1550     HAVE_X11=no
1551     USE_X_TOOLKIT=none
1552   ;;
1553 esac
1554
1555 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1556    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1557    if test "$HAVE_XSERVER" = true ||
1558       test -n "$DISPLAY" ||
1559       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1560         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1561 were found.  You should install the relevant development files for X
1562 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1563 sure you have development files for image handling, i.e.
1564 tiff, gif, jpeg, png and xpm.
1565 If you are sure you want Emacs compiled without X window support, pass
1566   --without-x
1567 to configure.])
1568    fi
1569 fi
1570
1571 ### If we're using X11, we should use the X menu package.
1572 HAVE_MENUS=no
1573 case ${HAVE_X11} in
1574   yes ) HAVE_MENUS=yes ;;
1575 esac
1576
1577 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1578 # Assume not, until told otherwise.
1579 GNU_MALLOC=yes
1580 doug_lea_malloc=yes
1581 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1582 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1583 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1584                emacs_cv_var___after_morecore_hook,
1585 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1586   emacs_cv_var___after_morecore_hook=yes,
1587   emacs_cv_var___after_morecore_hook=no)])
1588 if test $emacs_cv_var___after_morecore_hook = no; then
1589   doug_lea_malloc=no
1590 fi
1591
1592
1593 dnl See comments in aix4-2.h about maybe using system malloc there.
1594 system_malloc=no
1595 case "$opsys" in
1596   ## darwin ld insists on the use of malloc routines in the System framework.
1597   darwin|sol2-10) system_malloc=yes ;;
1598 esac
1599
1600 if test "${system_malloc}" = "yes"; then
1601   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1602   GNU_MALLOC=no
1603   GNU_MALLOC_reason="
1604     (The GNU allocators don't work with this system configuration.)"
1605   GMALLOC_OBJ=
1606   VMLIMIT_OBJ=
1607 else
1608   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1609   VMLIMIT_OBJ=vm-limit.o
1610 fi
1611 AC_SUBST(GMALLOC_OBJ)
1612 AC_SUBST(VMLIMIT_OBJ)
1613
1614 if test "$doug_lea_malloc" = "yes" ; then
1615   if test "$GNU_MALLOC" = yes ; then
1616     GNU_MALLOC_reason="
1617       (Using Doug Lea's new malloc from the GNU C Library.)"
1618   fi
1619   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1620             [Define to 1 if you are using the GNU C Library.])
1621
1622   ## Use mmap directly for allocating larger buffers.
1623   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1624   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1625   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1626   case "$opsys" in
1627     gnu*) REL_ALLOC=no ;;
1628   esac
1629 fi
1630
1631 if test x"${REL_ALLOC}" = x; then
1632   REL_ALLOC=${GNU_MALLOC}
1633 fi
1634
1635 use_mmap_for_buffers=no
1636 case "$opsys" in
1637   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1638 esac
1639
1640 AC_FUNC_MMAP
1641 if test $use_mmap_for_buffers = yes; then
1642   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1643   REL_ALLOC=no
1644 fi
1645
1646 LIBS="$LIBS_SYSTEM $LIBS"
1647
1648 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1649 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1650 AC_CHECK_LIB(dnet, dnet_ntoa)
1651 dnl This causes -lresolv to get used in subsequent tests,
1652 dnl which causes failures on some systems such as HPUX 9.
1653 dnl AC_CHECK_LIB(resolv, gethostbyname)
1654
1655 dnl FIXME replace main with a function we actually want from this library.
1656 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1657
1658 AC_CHECK_LIB(pthreads, cma_open)
1659
1660 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1661 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1662 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1663 ## added to LIBS in configure would never contain the pthreads part,
1664 ## but the value used in Makefiles might.  FIXME?
1665 ##
1666 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1667 ## be harmless on older versions of X where it happens to exist.
1668 test "$opsys" = "aix4-2" && \
1669   test $ac_cv_lib_pthreads_cma_open = yes && \
1670   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1671
1672 dnl Check for need for bigtoc support on IBM AIX
1673
1674 case ${host_os} in
1675 aix*)
1676   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1677     case $GCC in
1678     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1679     *) gdb_cv_bigtoc=-bbigtoc ;;
1680     esac
1681
1682     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1683     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1684   ])
1685   ;;
1686 esac
1687
1688 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1689 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1690 # REAL_CPPFLAGS later on.
1691
1692 REAL_CFLAGS="$CFLAGS"
1693 REAL_CPPFLAGS="$CPPFLAGS"
1694
1695 if test "${HAVE_X11}" = "yes"; then
1696   DEFS="$C_SWITCH_X_SITE $DEFS"
1697   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1698   LIBS="-lX11 $LIBS"
1699   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1700   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1701
1702   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1703   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1704   # but it's more convenient here to set LD_RUN_PATH
1705   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1706   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1707     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1708     export LD_RUN_PATH
1709   fi
1710
1711   if test "${opsys}" = "gnu-linux"; then
1712     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1713     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1714      [[XOpenDisplay ("foo");]])],
1715      [xlinux_first_failure=no],
1716      [xlinux_first_failure=yes])
1717     if test "${xlinux_first_failure}" = "yes"; then
1718       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1719       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1720       OLD_CPPFLAGS="$CPPFLAGS"
1721       OLD_LIBS="$LIBS"
1722       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1723       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1724       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1725       LIBS="$LIBS -b i486-linuxaout"
1726       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1727        [[XOpenDisplay ("foo");]])],
1728        [xlinux_second_failure=no],
1729        [xlinux_second_failure=yes])
1730       if test "${xlinux_second_failure}" = "yes"; then
1731         # If we get the same failure with -b, there is no use adding -b.
1732         # So take it out.  This plays safe.
1733         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1734         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1735         CPPFLAGS="$OLD_CPPFLAGS"
1736         LIBS="$OLD_LIBS"
1737         AC_MSG_RESULT(no)
1738       else
1739         AC_MSG_RESULT(yes)
1740       fi
1741     else
1742       AC_MSG_RESULT(no)
1743     fi
1744   fi
1745
1746   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1747   # header files included from there.
1748   AC_MSG_CHECKING(for Xkb)
1749   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1750 #include <X11/XKBlib.h>]],
1751         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1752         emacs_xkb=yes, emacs_xkb=no)
1753   AC_MSG_RESULT($emacs_xkb)
1754   if test $emacs_xkb = yes; then
1755     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1756   fi
1757
1758   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1759 XScreenNumberOfScreen XSetWMProtocols)
1760 fi
1761
1762 if test "${window_system}" = "x11"; then
1763   AC_MSG_CHECKING(X11 version 6)
1764   AC_CACHE_VAL(emacs_cv_x11_version_6,
1765   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1766 [[#if XlibSpecificationRelease < 6
1767 fail;
1768 #endif
1769 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1770   if test $emacs_cv_x11_version_6 = yes; then
1771     AC_MSG_RESULT(6 or newer)
1772     AC_DEFINE(HAVE_X11R6, 1,
1773               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1774     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1775     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1776     ## XIM support.
1777     case "$opsys" in
1778       sol2-*) : ;;
1779       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1780            [Define if you have usable X11R6-style XIM support.])
1781          ;;
1782     esac
1783   else
1784     AC_MSG_RESULT(before 6)
1785   fi
1786 fi
1787
1788
1789 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1790 HAVE_RSVG=no
1791 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1792   if test "${with_rsvg}" != "no"; then
1793     RSVG_REQUIRED=2.11.0
1794     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1795
1796     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1797     AC_SUBST(RSVG_CFLAGS)
1798     AC_SUBST(RSVG_LIBS)
1799
1800     if test $HAVE_RSVG = yes; then
1801       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1802       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1803       LIBS="$RSVG_LIBS $LIBS"
1804     fi
1805   fi
1806 fi
1807
1808 HAVE_IMAGEMAGICK=no
1809 if test "${HAVE_X11}" = "yes"; then
1810   if test "${with_imagemagick}" != "no"; then
1811     ## 6.2.8 is the earliest version known to work, but earlier versions
1812     ## might work - let us know if you find one.
1813     ## 6.0.7 does not work.  See bug#7955.
1814     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1815     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1816     AC_SUBST(IMAGEMAGICK_CFLAGS)
1817     AC_SUBST(IMAGEMAGICK_LIBS)
1818
1819     if test $HAVE_IMAGEMAGICK = yes; then
1820       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1821       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1822       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1823       AC_CHECK_FUNCS(MagickExportImagePixels)
1824     fi
1825   fi
1826 fi
1827
1828
1829 HAVE_GTK=no
1830 if test "${with_gtk3}" = "yes"; then
1831   GLIB_REQUIRED=2.28
1832   GTK_REQUIRED=3.0
1833   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1834
1835   dnl Checks for libraries.
1836   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1837   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1838      AC_MSG_ERROR($GTK_PKG_ERRORS)
1839   fi
1840   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1841 fi
1842
1843 if test "$pkg_check_gtk" != "yes"; then
1844   HAVE_GTK=no
1845 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1846   GLIB_REQUIRED=2.6
1847   GTK_REQUIRED=2.6
1848   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1849
1850   dnl Checks for libraries.
1851   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1852   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1853      AC_MSG_ERROR($GTK_PKG_ERRORS)
1854   fi
1855 fi
1856 fi
1857
1858 GTK_OBJ=
1859 if test x"$pkg_check_gtk" = xyes; then
1860
1861   AC_SUBST(GTK_CFLAGS)
1862   AC_SUBST(GTK_LIBS)
1863   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1864   CFLAGS="$CFLAGS $GTK_CFLAGS"
1865   LIBS="$GTK_LIBS $LIBS"
1866   dnl Try to compile a simple GTK program.
1867   GTK_COMPILES=no
1868   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1869   if test "${GTK_COMPILES}" != "yes"; then
1870     if test "$USE_X_TOOLKIT" != "maybe"; then
1871       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1872     fi
1873   else
1874     HAVE_GTK=yes
1875     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1876     GTK_OBJ=gtkutil.o
1877     USE_X_TOOLKIT=none
1878     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1879       :
1880     else
1881       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1882        closing open displays.  This is no problem if you just use
1883        one display, but if you use more than one and close one of them
1884        Emacs may crash.]])
1885       sleep 3
1886     fi
1887   fi
1888
1889 fi
1890 AC_SUBST(GTK_OBJ)
1891
1892
1893 if test "${HAVE_GTK}" = "yes"; then
1894
1895   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1896   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1897   if test "$with_toolkit_scroll_bars" != no; then
1898     with_toolkit_scroll_bars=yes
1899   fi
1900
1901   dnl  Check if we have the old file selection dialog declared and
1902   dnl  in the link library.  In 2.x it may be in the library,
1903   dnl  but not declared if deprecated featured has been selected out.
1904   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1905   HAVE_GTK_FILE_SELECTION=no
1906   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1907                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1908 #include <gtk/gtk.h>])
1909   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1910     AC_CHECK_FUNCS(gtk_file_selection_new)
1911   fi
1912
1913   dnl Check if pthreads are available.  Emacs only needs this when using
1914   dnl gtk_file_chooser under Gnome.
1915     HAVE_GTK_AND_PTHREAD=no
1916     AC_CHECK_HEADERS(pthread.h)
1917     if test "$ac_cv_header_pthread_h"; then
1918       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1919     fi
1920     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1921       case "${canonical}" in
1922         *-hpux*) ;;
1923         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1924       esac
1925       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1926                [Define to 1 if you have GTK and pthread (-lpthread).])
1927     fi
1928
1929   dnl Check for functions introduced in 2.14 and later.
1930   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1931                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1932                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1933                  gtk_orientable_set_orientation)
1934
1935 fi
1936
1937 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1938 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1939 dnl also not configured.
1940 HAVE_DBUS=no
1941 DBUS_OBJ=
1942 if test "${with_dbus}" = "yes"; then
1943    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1944    if test "$HAVE_DBUS" = yes; then
1945      LIBS="$LIBS $DBUS_LIBS"
1946      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1947      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1948      DBUS_OBJ=dbusbind.o
1949    fi
1950 fi
1951 AC_SUBST(DBUS_OBJ)
1952
1953 dnl GConf has been tested under GNU/Linux only.
1954 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1955 HAVE_GCONF=no
1956 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1957    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1958    if test "$HAVE_GCONF" = yes; then
1959       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1960       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1961       AC_CHECK_FUNCS([g_type_init])
1962    fi
1963 fi
1964
1965 dnl SELinux is available for GNU/Linux only.
1966 HAVE_LIBSELINUX=no
1967 LIBSELINUX_LIBS=
1968 if test "${with_selinux}" = "yes"; then
1969    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1970    if test "$HAVE_LIBSELINUX" = yes; then
1971       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1972       LIBSELINUX_LIBS=-lselinux
1973    fi
1974 fi
1975 AC_SUBST(LIBSELINUX_LIBS)
1976
1977 HAVE_GNUTLS=no
1978 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
1979 if test "${with_gnutls}" = "yes" ; then
1980   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.0], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1981   if test "${HAVE_GNUTLS}" = "yes"; then
1982     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1983   fi
1984
1985   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
1986   LIBS="$LIBGNUTLS_LIBS $LIBS"
1987   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
1988
1989   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
1990     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
1991   fi
1992 fi
1993
1994 AC_SUBST(LIBGNUTLS_LIBS)
1995 AC_SUBST(LIBGNUTLS_CFLAGS)
1996
1997 dnl Do not put whitespace before the #include statements below.
1998 dnl Older compilers (eg sunos4 cc) choke on it.
1999 HAVE_XAW3D=no
2000 LUCID_LIBW=
2001 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2002   if test "$with_xaw3d" != no; then
2003     AC_MSG_CHECKING(for xaw3d)
2004     AC_CACHE_VAL(emacs_cv_xaw3d,
2005     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2006 #include <X11/Intrinsic.h>
2007 #include <X11/Xaw3d/Simple.h>]],
2008       [[]])],
2009       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2010                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2011       emacs_cv_xaw3d=no)])
2012   else
2013     emacs_cv_xaw3d=no
2014   fi
2015   if test $emacs_cv_xaw3d = yes; then
2016     AC_MSG_RESULT([yes; using Lucid toolkit])
2017     USE_X_TOOLKIT=LUCID
2018     HAVE_XAW3D=yes
2019     LUCID_LIBW=-lXaw3d
2020     AC_DEFINE(HAVE_XAW3D, 1,
2021               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2022   else
2023     AC_MSG_RESULT(no)
2024     AC_MSG_CHECKING(for libXaw)
2025     AC_CACHE_VAL(emacs_cv_xaw,
2026     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2027 #include <X11/Intrinsic.h>
2028 #include <X11/Xaw/Simple.h>]],
2029       [[]])],
2030       emacs_cv_xaw=yes,
2031       emacs_cv_xaw=no)])
2032     if test $emacs_cv_xaw = yes; then
2033       AC_MSG_RESULT([yes; using Lucid toolkit])
2034       USE_X_TOOLKIT=LUCID
2035       LUCID_LIBW=-lXaw
2036     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2037       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2038     else
2039       AC_MSG_ERROR([No X toolkit could be found.
2040 If you are sure you want Emacs compiled without an X toolkit, pass
2041   --with-x-toolkit=no
2042 to configure.  Otherwise, install the development libraries for the toolkit
2043 that you want to use (e.g. Gtk+) and re-run configure.])
2044     fi
2045   fi
2046 fi
2047
2048 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2049
2050 LIBXTR6=
2051 if test "${USE_X_TOOLKIT}" != "none"; then
2052   AC_MSG_CHECKING(X11 toolkit version)
2053   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2054   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2055 [[#if XtSpecificationRelease < 6
2056 fail;
2057 #endif
2058 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2059   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2060   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2061     AC_MSG_RESULT(6 or newer)
2062     AC_DEFINE(HAVE_X11XTR6, 1,
2063               [Define to 1 if you have the X11R6 or newer version of Xt.])
2064     LIBXTR6="-lSM -lICE"
2065     case "$opsys" in
2066       ## Use libw.a along with X11R6 Xt.
2067       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2068     esac
2069   else
2070     AC_MSG_RESULT(before 6)
2071   fi
2072
2073 dnl If using toolkit, check whether libXmu.a exists.
2074 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2075   OLDLIBS="$LIBS"
2076   if test x$HAVE_X11XTR6 = xyes; then
2077     LIBS="-lXt -lSM -lICE $LIBS"
2078   else
2079     LIBS="-lXt $LIBS"
2080   fi
2081   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2082   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2083 fi
2084 AC_SUBST(LIBXTR6)
2085
2086 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2087 dnl Why not just test for libxmu in the normal way?
2088 LIBXMU=-lXmu
2089 case $opsys in
2090   ## These systems don't supply Xmu.
2091   hpux* | aix4-2 )
2092     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2093     ;;
2094 esac
2095 AC_SUBST(LIBXMU)
2096
2097 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2098 if test "${HAVE_X11}" = "yes"; then
2099   if test "${USE_X_TOOLKIT}" != "none"; then
2100     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2101   fi
2102 fi
2103
2104 LIBXP=
2105 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2106   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2107   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2108     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2109 int x = 5;
2110 #else
2111 Motif version prior to 2.1.
2112 #endif]])],
2113     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2114   if test $emacs_cv_motif_version_2_1 = yes; then
2115     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2116   else
2117     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2118     # We put this in CFLAGS temporarily to precede other -I options
2119     # that might be in CFLAGS temporarily.
2120     # We put this in CPPFLAGS where it precedes the other -I options.
2121     OLD_CPPFLAGS=$CPPFLAGS
2122     OLD_CFLAGS=$CFLAGS
2123     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2124     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2125     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2126       [[int x = 5;]])],
2127       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2128     if test $emacs_cv_lesstif = yes; then
2129       # Make sure this -I option remains in CPPFLAGS after it is set
2130       # back to REAL_CPPFLAGS.
2131       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2132       # have those other -I options anyway.  Ultimately, having this
2133       # directory ultimately in CPPFLAGS will be enough.
2134       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2135       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2136     else
2137       CFLAGS=$OLD_CFLAGS
2138       CPPFLAGS=$OLD_CPPFLAGS
2139     fi
2140   fi
2141 fi
2142
2143 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2144 dnl using Motif or Xaw3d is available, and unless
2145 dnl --with-toolkit-scroll-bars=no was specified.
2146
2147 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2148             [Define to 1 if we should use toolkit scroll bars.])dnl
2149 USE_TOOLKIT_SCROLL_BARS=no
2150 if test "${with_toolkit_scroll_bars}" != "no"; then
2151   if test "${USE_X_TOOLKIT}" != "none"; then
2152     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2153       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2154       HAVE_XAW3D=no
2155       USE_TOOLKIT_SCROLL_BARS=yes
2156     elif test "${HAVE_XAW3D}" = "yes"; then
2157       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2158       USE_TOOLKIT_SCROLL_BARS=yes
2159     fi
2160   elif test "${HAVE_GTK}" = "yes"; then
2161     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2162     USE_TOOLKIT_SCROLL_BARS=yes
2163   elif test "${HAVE_NS}" = "yes"; then
2164     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2165     USE_TOOLKIT_SCROLL_BARS=yes
2166   fi
2167 fi
2168
2169 dnl See if XIM is available.
2170 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2171           #include <X11/Xlib.h>
2172           #include <X11/Xresource.h>]],
2173          [[XIMProc  callback;]])],
2174          [HAVE_XIM=yes
2175          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2176          HAVE_XIM=no)
2177
2178 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2179
2180 if test "${with_xim}" != "no"; then
2181   AC_DEFINE(USE_XIM, 1,
2182             [Define to 1 if we should use XIM, if it is available.])
2183 fi
2184
2185
2186 if test "${HAVE_XIM}" != "no"; then
2187   late_CFLAGS=$CFLAGS
2188   if test "$GCC" = yes; then
2189     CFLAGS="$CFLAGS --pedantic-errors"
2190   fi
2191   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2192 #include <X11/Xlib.h>
2193 #include <X11/Xresource.h>]],
2194 [[Display *display;
2195 XrmDatabase db;
2196 char *res_name;
2197 char *res_class;
2198 XIMProc  callback;
2199 XPointer *client_data;
2200 #ifndef __GNUC__
2201 /* If we're not using GCC, it's probably not XFree86, and this is
2202    probably right, but we can't use something like --pedantic-errors.  */
2203 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2204                                            char*, XIMProc, XPointer*);
2205 #endif
2206 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2207    client_data);]])],
2208     [emacs_cv_arg6_star=yes])
2209   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2210          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2211 either XPointer or XPointer*.])dnl
2212   if test "$emacs_cv_arg6_star" = yes; then
2213     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2214   else
2215     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2216   fi
2217   CFLAGS=$late_CFLAGS
2218 fi
2219
2220 ### Start of font-backend (under any platform) section.
2221 # (nothing here yet -- this is a placeholder)
2222 ### End of font-backend (under any platform) section.
2223
2224 ### Start of font-backend (under X11) section.
2225 if test "${HAVE_X11}" = "yes"; then
2226    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2227
2228    ## Use -lXft if available, unless `--with-xft=no'.
2229    HAVE_XFT=maybe
2230     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2231       with_xft="no";
2232     fi
2233     if test "x${with_xft}" != "xno"; then
2234
2235       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2236       ## Because xftfont.c uses XRenderQueryExtension, we also
2237       ## need to link to -lXrender.
2238       HAVE_XRENDER=no
2239       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2240       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2241         OLD_CPPFLAGS="$CPPFLAGS"
2242         OLD_CFLAGS="$CFLAGS"
2243         OLD_LIBS="$LIBS"
2244         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2245         CFLAGS="$CFLAGS $XFT_CFLAGS"
2246         XFT_LIBS="-lXrender $XFT_LIBS"
2247         LIBS="$XFT_LIBS $LIBS"
2248         AC_CHECK_HEADER(X11/Xft/Xft.h,
2249           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2250
2251         if test "${HAVE_XFT}" = "yes"; then
2252           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2253             AC_SUBST(XFT_LIBS)
2254           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2255         else
2256           CPPFLAGS="$OLD_CPPFLAGS"
2257           CFLAGS="$OLD_CFLAGS"
2258           LIBS="$OLD_LIBS"
2259         fi                        # "${HAVE_XFT}" = "yes"
2260       fi                          # "$HAVE_XFT" != no
2261     fi                            # "x${with_xft}" != "xno"
2262
2263     ## We used to allow building with FreeType and without Xft.
2264     ## However, the ftx font backend driver is not in good shape.
2265     if test "$HAVE_XFT" != "yes"; then
2266        dnl For the "Does Emacs use" message at the end.
2267        HAVE_XFT=no
2268        HAVE_FREETYPE=no
2269     else
2270        dnl Strict linkers fail with
2271        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2272        dnl if -lfreetype is not specified.
2273        dnl The following is needed to set FREETYPE_LIBS.
2274        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2275                          HAVE_FREETYPE=no)
2276
2277        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2278     fi
2279
2280     HAVE_LIBOTF=no
2281     if test "${HAVE_FREETYPE}" = "yes"; then
2282       AC_DEFINE(HAVE_FREETYPE, 1,
2283                 [Define to 1 if using the freetype and fontconfig libraries.])
2284       if test "${with_libotf}" != "no"; then
2285         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2286                           HAVE_LIBOTF=no)
2287         if test "$HAVE_LIBOTF" = "yes"; then
2288           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2289           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2290                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2291                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2292           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2293             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2294                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2295           fi
2296         fi
2297       fi
2298     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2299     dnl Does the new font backend require it, or can it work without it?
2300     fi
2301
2302     HAVE_M17N_FLT=no
2303     if test "${HAVE_LIBOTF}" = yes; then
2304       if test "${with_m17n_flt}" != "no"; then
2305         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2306         if test "$HAVE_M17N_FLT" = "yes"; then
2307           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2308         fi
2309       fi
2310     fi
2311 else
2312     HAVE_XFT=no
2313     HAVE_FREETYPE=no
2314     HAVE_LIBOTF=no
2315     HAVE_M17N_FLT=no
2316 fi
2317
2318 ### End of font-backend (under X11) section.
2319
2320 AC_SUBST(FREETYPE_CFLAGS)
2321 AC_SUBST(FREETYPE_LIBS)
2322 AC_SUBST(FONTCONFIG_CFLAGS)
2323 AC_SUBST(FONTCONFIG_LIBS)
2324 AC_SUBST(LIBOTF_CFLAGS)
2325 AC_SUBST(LIBOTF_LIBS)
2326 AC_SUBST(M17N_FLT_CFLAGS)
2327 AC_SUBST(M17N_FLT_LIBS)
2328
2329 ### Use -lXpm if available, unless `--with-xpm=no'.
2330 HAVE_XPM=no
2331 LIBXPM=
2332 if test "${HAVE_X11}" = "yes"; then
2333   if test "${with_xpm}" != "no"; then
2334     AC_CHECK_HEADER(X11/xpm.h,
2335       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2336     if test "${HAVE_XPM}" = "yes"; then
2337       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2338       AC_EGREP_CPP(no_return_alloc_pixels,
2339       [#include "X11/xpm.h"
2340 #ifndef XpmReturnAllocPixels
2341 no_return_alloc_pixels
2342 #endif
2343       ], HAVE_XPM=no, HAVE_XPM=yes)
2344
2345       if test "${HAVE_XPM}" = "yes"; then
2346         AC_MSG_RESULT(yes)
2347       else
2348         AC_MSG_RESULT(no)
2349       fi
2350     fi
2351   fi
2352
2353   if test "${HAVE_XPM}" = "yes"; then
2354     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2355     LIBXPM=-lXpm
2356   fi
2357 fi
2358 AC_SUBST(LIBXPM)
2359
2360 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2361 HAVE_JPEG=no
2362 LIBJPEG=
2363 if test "${HAVE_X11}" = "yes"; then
2364   if test "${with_jpeg}" != "no"; then
2365     dnl Checking for jpeglib.h can lose because of a redefinition of
2366     dnl  HAVE_STDLIB_H.
2367     AC_CHECK_HEADER(jerror.h,
2368       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2369   fi
2370
2371   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2372   if test "${HAVE_JPEG}" = "yes"; then
2373     AC_DEFINE(HAVE_JPEG)
2374     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2375         [#include <jpeglib.h>
2376          version=JPEG_LIB_VERSION
2377 ],
2378         [AC_DEFINE(HAVE_JPEG)],
2379         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2380         HAVE_JPEG=no])
2381   fi
2382   if test "${HAVE_JPEG}" = "yes"; then
2383     LIBJPEG=-ljpeg
2384   fi
2385 fi
2386 AC_SUBST(LIBJPEG)
2387
2388 ### Use -lpng if available, unless `--with-png=no'.
2389 HAVE_PNG=no
2390 LIBPNG=
2391 if test "${HAVE_X11}" = "yes"; then
2392   if test "${with_png}" != "no"; then
2393     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2394     # in /usr/include/libpng.
2395     AC_CHECK_HEADERS(png.h libpng/png.h)
2396     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2397       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2398     fi
2399   fi
2400
2401   if test "${HAVE_PNG}" = "yes"; then
2402     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2403     LIBPNG="-lpng -lz -lm"
2404   fi
2405 fi
2406 AC_SUBST(LIBPNG)
2407
2408 ### Use -ltiff if available, unless `--with-tiff=no'.
2409 HAVE_TIFF=no
2410 LIBTIFF=
2411 if test "${HAVE_X11}" = "yes"; then
2412   if test "${with_tiff}" != "no"; then
2413     AC_CHECK_HEADER(tiffio.h,
2414       [tifflibs="-lz -lm"
2415       # At least one tiff package requires the jpeg library.
2416       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2417       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2418   fi
2419
2420   if test "${HAVE_TIFF}" = "yes"; then
2421     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2422     dnl FIXME -lz -lm, as per libpng?
2423     LIBTIFF=-ltiff
2424   fi
2425 fi
2426 AC_SUBST(LIBTIFF)
2427
2428 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2429 HAVE_GIF=no
2430 LIBGIF=
2431 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2432   AC_CHECK_HEADER(gif_lib.h,
2433 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2434 # Earlier versions can crash Emacs.
2435     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2436
2437   if test "$HAVE_GIF" = yes; then
2438     LIBGIF=-lgif
2439   elif test "$HAVE_GIF" = maybe; then
2440 # If gif_lib.h but no libgif, try libungif.
2441     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2442     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2443   fi
2444
2445   if test "${HAVE_GIF}" = "yes"; then
2446     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2447   fi
2448 fi
2449 AC_SUBST(LIBGIF)
2450
2451 dnl Check for required libraries.
2452 if test "${HAVE_X11}" = "yes"; then
2453   MISSING=""
2454   WITH_NO=""
2455   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2456     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2457   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2458     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2459   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2460     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2461   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2462     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2463   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2464     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2465
2466   if test "X${MISSING}" != X; then
2467     AC_MSG_ERROR([The following required libraries were not found:
2468     $MISSING
2469 Maybe some development libraries/packages are missing?
2470 If you don't want to link with them give
2471     $WITH_NO
2472 as options to configure])
2473   fi
2474 fi
2475
2476 ### Use -lgpm if available, unless `--with-gpm=no'.
2477 HAVE_GPM=no
2478 LIBGPM=
2479 MOUSE_SUPPORT=
2480 if test "${with_gpm}" != "no"; then
2481   AC_CHECK_HEADER(gpm.h,
2482     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2483
2484   if test "${HAVE_GPM}" = "yes"; then
2485     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2486     LIBGPM=-lgpm
2487     ## May be reset below.
2488     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2489   fi
2490 fi
2491 AC_SUBST(LIBGPM)
2492
2493 dnl Check for malloc/malloc.h on darwin
2494 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2495
2496 C_SWITCH_X_SYSTEM=
2497 ### Use NeXTstep API to implement GUI.
2498 if test "${HAVE_NS}" = "yes"; then
2499   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2500   if test "${NS_IMPL_COCOA}" = "yes"; then
2501     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2502     GNU_OBJC_CFLAGS=
2503   fi
2504   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2505     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2506     # See also .m.o rule in Makefile.in */
2507     # FIXME: are all these flags really needed?  Document here why.  */
2508     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2509     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2510   fi
2511   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2512     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2513   fi
2514   # We also have mouse menus.
2515   HAVE_MENUS=yes
2516   OTHER_FILES=ns-app
2517 fi
2518
2519
2520 ### Use session management (-lSM -lICE) if available
2521 HAVE_X_SM=no
2522 LIBXSM=
2523 if test "${HAVE_X11}" = "yes"; then
2524   AC_CHECK_HEADER(X11/SM/SMlib.h,
2525     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2526
2527   if test "${HAVE_X_SM}" = "yes"; then
2528     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2529     LIBXSM="-lSM -lICE"
2530     case "$LIBS" in
2531       *-lSM*) ;;
2532       *)      LIBS="$LIBXSM $LIBS" ;;
2533     esac
2534   fi
2535 fi
2536 AC_SUBST(LIBXSM)
2537
2538 ### Use libxml (-lxml2) if available
2539 if test "${with_xml2}" != "no"; then
2540   ### I'm not sure what the version number should be, so I just guessed.
2541   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2542   if test "${HAVE_LIBXML2}" = "yes"; then
2543     LIBS="$LIBXML2_LIBS $LIBS"
2544     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2545     if test "${HAVE_LIBXML2}" = "yes"; then
2546       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2547     else
2548       LIBXML2_LIBS=""
2549       LIBXML2_CFLAGS=""
2550     fi
2551   fi
2552 fi
2553 AC_SUBST(LIBXML2_LIBS)
2554 AC_SUBST(LIBXML2_CFLAGS)
2555
2556 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2557 AC_CACHE_CHECK(whether netdb declares h_errno,
2558                emacs_cv_netdb_declares_h_errno,
2559 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2560   [[return h_errno;]])],
2561   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2562 if test $emacs_cv_netdb_declares_h_errno = yes; then
2563   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2564 fi
2565
2566 AC_FUNC_ALLOCA
2567
2568 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2569 dnl FIXME is there an autoconf test that does the right thing, without
2570 dnl needing to call A_M_E afterwards?
2571 if test x"$ac_cv_func_alloca_works" != xyes; then
2572    AC_MSG_ERROR( [a system implementation of alloca is required] )
2573 fi
2574
2575 # fmod, logb, and frexp are found in -lm on most systems.
2576 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2577 AC_CHECK_LIB(m, sqrt)
2578
2579 # Check for mail-locking functions in a "mail" library.  Probably this should
2580 # have the same check as for liblockfile below.
2581 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2582 if test $have_mail = yes; then
2583   LIBS_MAIL=-lmail
2584   LIBS="$LIBS_MAIL $LIBS"
2585   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2586 else
2587   LIBS_MAIL=
2588 fi
2589 dnl Debian, at least:
2590 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2591 if test $have_lockfile = yes; then
2592    LIBS_MAIL=-llockfile
2593    LIBS="$LIBS_MAIL $LIBS"
2594    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2595 else
2596 # If we have the shared liblockfile, assume we must use it for mail
2597 # locking (e.g. Debian).  If we couldn't link against liblockfile
2598 # (no liblockfile.a installed), ensure that we don't need to.
2599   dnl This works for files generally, not just executables.
2600   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2601   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2602                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2603   if test $ac_cv_prog_liblockfile = yes; then
2604     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2605 This probably means that movemail could lose mail.
2606 There may be a `development' package to install containing liblockfile.])
2607   fi
2608 fi
2609 AC_CHECK_FUNCS(touchlock)
2610 AC_CHECK_HEADERS(maillock.h)
2611 AC_SUBST(LIBS_MAIL)
2612
2613 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2614 ## interlock access to the mail spool.  The alternative is a lock file named
2615 ## /usr/spool/mail/$USER.lock.
2616 mail_lock=no
2617 case "$opsys" in
2618   aix4-2) mail_lock="lockf" ;;
2619
2620   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2621
2622   ## On GNU/Linux systems, both methods are used by various mail programs.
2623   ## I assume most people are using newer mailers that have heard of flock.
2624   ## Change this if you need to.
2625   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2626   ## configure gets the right answers, and that means *NOT* using flock.
2627   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2628   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2629   ## Debian maintainer hasn't provided a clean fix for Emacs.
2630   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2631   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2632   ## correct logic.  -- fx
2633   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2634   ## liblockfile is a Free Software replacement for libmail, used on
2635   ## Debian systems and elsewhere. -rfr.
2636   gnu-*)
2637     mail_lock="flock"
2638     if test $have_mail = yes || test $have_lockfile = yes; then
2639       test $ac_cv_header_maillock_h = yes && mail_lock=no
2640     fi
2641     ;;
2642 esac
2643
2644 BLESSMAIL_TARGET=
2645 case "$mail_lock" in
2646   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2647
2648   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2649
2650   *) BLESSMAIL_TARGET="need-blessmail" ;;
2651 esac
2652 AC_SUBST(BLESSMAIL_TARGET)
2653
2654
2655 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2656 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2657 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2658 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2659 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2660 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2661 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2662 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2663 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2664 cfmakeraw cfsetspeed isnan copysign __executable_start)
2665
2666 dnl Cannot use AC_CHECK_FUNCS
2667 AC_CACHE_CHECK([for __builtin_unwind_init],
2668                emacs_cv_func___builtin_unwind_init,
2669 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2670                 emacs_cv_func___builtin_unwind_init=yes,
2671                 emacs_cv_func___builtin_unwind_init=no)])
2672 if test $emacs_cv_func___builtin_unwind_init = yes; then
2673   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2674             [Define to 1 if you have the `__builtin_unwind_init' function.])
2675 fi
2676
2677 AC_CHECK_HEADERS(sys/un.h)
2678
2679 AC_FUNC_FSEEKO
2680
2681 AC_FUNC_GETPGRP
2682
2683 # Configure gnulib.
2684 gl_ASSERT_NO_GNULIB_POSIXCHECK
2685 gl_ASSERT_NO_GNULIB_TESTS
2686 gl_INIT
2687
2688 # UNIX98 PTYs.
2689 AC_CHECK_FUNCS(grantpt)
2690
2691 # PTY-related GNU extensions.
2692 AC_CHECK_FUNCS(getpt)
2693
2694 # Check this now, so that we will NOT find the above functions in ncurses.
2695 # That is because we have not set up to link ncurses in lib-src.
2696 # It's better to believe a function is not available
2697 # than to expect to find it in ncurses.
2698 # Also we need tputs and friends to be able to build at all.
2699 have_tputs_et_al=true
2700 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2701 if test "$have_tputs_et_al" != true; then
2702   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2703 Maybe some development libraries/packages are missing?  Try installing
2704 libncurses-dev(el), libterminfo-dev(el) or similar.])
2705 fi
2706 # Must define this when any termcap library is found.
2707 AC_DEFINE(HAVE_LIBNCURSES, 1,
2708           [Define to 1 if you have the `ncurses' library (-lncurses).])
2709 ## FIXME This was the cpp logic, but I am not sure it is right.
2710 ## The above test has not necessarily found libncurses.
2711 HAVE_LIBNCURSES=yes
2712
2713 ## Use terminfo instead of termcap?
2714 ## Note only system files NOT using terminfo are:
2715 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2716 ## darwin|gnu without ncurses.
2717 TERMINFO=no
2718 LIBS_TERMCAP=
2719 case "$opsys" in
2720   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2721   ## hpux10-20: Use the system provided termcap(3) library.
2722   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2723   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2724   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2725
2726   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2727   ##  The ncurses library has been moved out of the System framework in
2728   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2729   ##  option to use it.
2730   darwin|gnu*)
2731     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2732     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2733       TERMINFO=yes
2734       LIBS_TERMCAP="-lncurses"
2735     fi
2736     ;;
2737
2738   freebsd)
2739     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2740     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2741     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2742 [[#if __FreeBSD_version < 400000
2743 fail;
2744 #endif
2745 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2746
2747     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2748
2749     if test $emacs_cv_freebsd_terminfo = yes; then
2750       TERMINFO=yes
2751       LIBS_TERMCAP="-lncurses"
2752     else
2753       LIBS_TERMCAP="-ltermcap"
2754     fi
2755     ;;
2756
2757   netbsd)
2758     if test $ac_cv_search_tputs = -lterminfo; then
2759       TERMINFO=yes
2760       LIBS_TERMCAP="-lterminfo"
2761     else
2762       LIBS_TERMCAP="-ltermcap"
2763     fi
2764     ;;
2765
2766 esac
2767
2768 case "$opsys" in
2769   ## hpux: Make sure we get select from libc rather than from libcurses
2770   ##  because libcurses on HPUX 10.10 has a broken version of select.
2771   ##  We used to use -lc -lcurses, but this may be cleaner.
2772   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2773
2774   openbsd) LIBS_TERMCAP="-lncurses" ;;
2775
2776   ## Must use system termcap, if we use any termcap.  It does special things.
2777   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2778 esac
2779
2780 TERMCAP_OBJ=tparam.o
2781 if test $TERMINFO = yes; then
2782   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2783
2784   ## Default used to be -ltermcap.  Add a case above if need something else.
2785   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2786
2787   TERMCAP_OBJ=terminfo.o
2788 fi
2789 AC_SUBST(LIBS_TERMCAP)
2790 AC_SUBST(TERMCAP_OBJ)
2791
2792
2793 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2794 resolv=no
2795 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2796 #include <arpa/nameser.h>
2797 #include <resolv.h>]],
2798     [[return res_init();]])],
2799     have_res_init=yes, have_res_init=no)
2800 if test "$have_res_init" = no; then
2801   OLIBS="$LIBS"
2802   LIBS="$LIBS -lresolv"
2803   AC_MSG_CHECKING(for res_init with -lresolv)
2804   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2805 #include <arpa/nameser.h>
2806 #include <resolv.h>]],
2807     [[return res_init();]])],
2808     have_res_init=yes, have_res_init=no)
2809   AC_MSG_RESULT($have_res_init)
2810   if test "$have_res_init" = yes ; then
2811     resolv=yes
2812   fi
2813   LIBS="$OLIBS"
2814 fi
2815
2816 if test "$have_res_init" = yes; then
2817   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2818 fi
2819
2820 # Do we need the Hesiod library to provide the support routines?
2821 LIBHESIOD=
2822 if test "$with_hesiod" != no ; then
2823   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2824   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2825      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2826                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2827   if test "$resolv" = yes ; then
2828     RESOLVLIB=-lresolv
2829   else
2830     RESOLVLIB=
2831   fi
2832   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2833         hesiod=yes, :, $RESOLVLIB)])
2834
2835   if test x"$hesiod" = xyes; then
2836     AC_DEFINE(HAVE_LIBHESIOD, 1,
2837               [Define to 1 if you have the hesiod library (-lhesiod).])
2838     LIBHESIOD=-lhesiod
2839   fi
2840 fi
2841 AC_SUBST(LIBHESIOD)
2842
2843 # Do we need libresolv (due to res_init or Hesiod)?
2844 if test "$resolv" = yes ; then
2845   AC_DEFINE(HAVE_LIBRESOLV, 1,
2846             [Define to 1 if you have the resolv library (-lresolv).])
2847   LIBRESOLV=-lresolv
2848 else
2849   LIBRESOLV=
2850 fi
2851 AC_SUBST(LIBRESOLV)
2852
2853 # These tell us which Kerberos-related libraries to use.
2854 COM_ERRLIB=
2855 CRYPTOLIB=
2856 KRB5LIB=
2857 DESLIB=
2858 KRB4LIB=
2859
2860 if test "${with_kerberos}" != no; then
2861   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2862   if test $have_com_err = yes; then
2863     COM_ERRLIB=-lcom_err
2864     LIBS="$COM_ERRLIB $LIBS"
2865     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2866   fi
2867   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2868   if test $have_crypto = yes; then
2869     CRYPTOLIB=-lcrypto
2870     LIBS="$CRYPTOLIB $LIBS"
2871     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2872   fi
2873   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2874   if test $have_k5crypto = yes; then
2875     CRYPTOLIB=-lk5crypto
2876     LIBS="$CRYPTOLIB $LIBS"
2877     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2878   fi
2879   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2880   if test $have_krb5=yes; then
2881     KRB5LIB=-lkrb5
2882     LIBS="$KRB5LIB $LIBS"
2883     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2884   fi
2885   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2886   if test "${with_kerberos5}" = no; then
2887     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2888     if test $have_des425 = yes; then
2889       DESLIB=-ldes425
2890       LIBS="$DESLIB $LIBS"
2891       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2892     else
2893       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2894       if test $have_des = yes; then
2895         DESLIB=-ldes
2896         LIBS="$DESLIB $LIBS"
2897         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2898       fi
2899     fi
2900     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2901     if test $have_krb4 = yes; then
2902       KRB4LIB=-lkrb4
2903       LIBS="$KRB4LIB $LIBS"
2904       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2905     else
2906       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2907       if test $have_krb = yes; then
2908         KRB4LIB=-lkrb
2909         LIBS="$KRB4LIB $LIBS"
2910         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2911       fi
2912     fi
2913   fi
2914
2915   if test "${with_kerberos5}" != no; then
2916     AC_CHECK_HEADERS(krb5.h,
2917       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2918                         [#include <krb5.h>])])
2919   else
2920     AC_CHECK_HEADERS(des.h,,
2921                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2922                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2923     AC_CHECK_HEADERS(krb.h,,
2924                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2925                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2926   fi
2927   AC_CHECK_HEADERS(com_err.h)
2928 fi
2929
2930 AC_SUBST(COM_ERRLIB)
2931 AC_SUBST(CRYPTOLIB)
2932 AC_SUBST(KRB5LIB)
2933 AC_SUBST(DESLIB)
2934 AC_SUBST(KRB4LIB)
2935
2936 # Solaris requires -lintl if you want strerror (which calls dgettext)
2937 # to return localized messages.
2938 AC_CHECK_LIB(intl, dgettext)
2939
2940 AC_MSG_CHECKING(whether localtime caches TZ)
2941 AC_CACHE_VAL(emacs_cv_localtime_cache,
2942 [if test x$ac_cv_func_tzset = xyes; then
2943 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2944 char TZ_GMT0[] = "TZ=GMT0";
2945 char TZ_PST8[] = "TZ=PST8";
2946 main()
2947 {
2948   time_t now = time ((time_t *) 0);
2949   int hour_GMT0, hour_unset;
2950   if (putenv (TZ_GMT0) != 0)
2951     exit (1);
2952   hour_GMT0 = localtime (&now)->tm_hour;
2953   unsetenv("TZ");
2954   hour_unset = localtime (&now)->tm_hour;
2955   if (putenv (TZ_PST8) != 0)
2956     exit (1);
2957   if (localtime (&now)->tm_hour == hour_GMT0)
2958     exit (1);
2959   unsetenv("TZ");
2960   if (localtime (&now)->tm_hour != hour_unset)
2961     exit (1);
2962   exit (0);
2963 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2964 [# If we have tzset, assume the worst when cross-compiling.
2965 emacs_cv_localtime_cache=yes])
2966 else
2967         # If we lack tzset, report that localtime does not cache TZ,
2968         # since we can't invalidate the cache if we don't have tzset.
2969         emacs_cv_localtime_cache=no
2970 fi])dnl
2971 AC_MSG_RESULT($emacs_cv_localtime_cache)
2972 if test $emacs_cv_localtime_cache = yes; then
2973   AC_DEFINE(LOCALTIME_CACHE, 1,
2974             [Define to 1 if localtime caches TZ.])
2975 fi
2976
2977 if test "x$HAVE_TIMEVAL" = xyes; then
2978   AC_CHECK_FUNCS(gettimeofday)
2979   if test $ac_cv_func_gettimeofday = yes; then
2980     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2981                    emacs_cv_gettimeofday_two_arguments,
2982     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2983 #ifdef TIME_WITH_SYS_TIME
2984 #include <sys/time.h>
2985 #include <time.h>
2986 #else
2987 #ifdef HAVE_SYS_TIME_H
2988 #include <sys/time.h>
2989 #else
2990 #include <time.h>
2991 #endif
2992 #endif]],
2993       [[struct timeval time;
2994        gettimeofday (&time, 0);]])],
2995       emacs_cv_gettimeofday_two_arguments=yes,
2996       emacs_cv_gettimeofday_two_arguments=no)])
2997     if test $emacs_cv_gettimeofday_two_arguments = no; then
2998       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2999                 [Define to 1 if gettimeofday accepts only one argument.])
3000     fi
3001   fi
3002 fi
3003
3004 ok_so_far=yes
3005 AC_CHECK_FUNC(socket, , ok_so_far=no)
3006 if test $ok_so_far = yes; then
3007   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3008 fi
3009 if test $ok_so_far = yes; then
3010   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3011 fi
3012 if test $ok_so_far = yes; then
3013 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3014   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3015             [Define to 1 if you have inet sockets.])
3016 fi
3017
3018 if test -f /usr/lpp/X11/bin/smt.exp; then
3019   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3020             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3021 fi
3022
3023 AC_MSG_CHECKING(whether system supports dynamic ptys)
3024 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3025   AC_MSG_RESULT(yes)
3026   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3027 else
3028   AC_MSG_RESULT(no)
3029 fi
3030
3031 AC_FUNC_FORK
3032
3033 dnl Adapted from Haible's version.
3034 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3035   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3036     [[char* cs = nl_langinfo(CODESET);]])],
3037     emacs_cv_langinfo_codeset=yes,
3038     emacs_cv_langinfo_codeset=no)
3039   ])
3040 if test $emacs_cv_langinfo_codeset = yes; then
3041   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3042     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3043 fi
3044
3045 AC_TYPE_MBSTATE_T
3046
3047 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3048   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3049                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3050 if test "$emacs_cv_c_restrict_arr" = yes; then
3051   AC_DEFINE(__restrict_arr, __restrict,
3052     [Define to compiler's equivalent of C99 restrict keyword in array
3053      declarations.  Define as empty for no equivalent.])
3054 fi
3055
3056 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3057 dnl how the tty code is related to POSIX and/or other versions of termios.
3058 dnl The following looks like a useful start.
3059 dnl
3060 dnl AC_SYS_POSIX_TERMIOS
3061 dnl if test $ac_cv_sys_posix_termios = yes; then
3062 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3063 dnl                                and macros for terminal control.])
3064 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3065 dnl fi
3066
3067 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3068
3069 # Set up the CFLAGS for real compilation, so we can substitute it.
3070 CFLAGS="$REAL_CFLAGS"
3071 CPPFLAGS="$REAL_CPPFLAGS"
3072
3073 ## Hack to detect a buggy GCC version.
3074 if test "x$GCC" = xyes \
3075    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3076    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3077    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3078    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3079 fi
3080
3081 version=$PACKAGE_VERSION
3082
3083 ### Specify what sort of things we'll be editing into Makefile and config.h.
3084 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3085 AC_SUBST(version)
3086 AC_SUBST(configuration)
3087 ## Unused?
3088 AC_SUBST(canonical)
3089 AC_SUBST(srcdir)
3090 AC_SUBST(prefix)
3091 AC_SUBST(exec_prefix)
3092 AC_SUBST(bindir)
3093 AC_SUBST(datadir)
3094 AC_SUBST(sharedstatedir)
3095 AC_SUBST(libexecdir)
3096 AC_SUBST(mandir)
3097 AC_SUBST(infodir)
3098 AC_SUBST(lispdir)
3099 AC_SUBST(locallisppath)
3100 AC_SUBST(lisppath)
3101 AC_SUBST(x_default_search_path)
3102 AC_SUBST(etcdir)
3103 AC_SUBST(archlibdir)
3104 AC_SUBST(docdir)
3105 AC_SUBST(bitmapdir)
3106 AC_SUBST(gamedir)
3107 AC_SUBST(gameuser)
3108 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3109 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3110 ## end of LIBX_BASE, but nothing ever set it.
3111 AC_SUBST(LD_SWITCH_X_SITE)
3112 AC_SUBST(C_SWITCH_X_SITE)
3113 AC_SUBST(C_SWITCH_X_SYSTEM)
3114 AC_SUBST(CFLAGS)
3115 ## Used in lwlib/Makefile.in.
3116 AC_SUBST(X_TOOLKIT_TYPE)
3117 if test -n "${machfile}"; then
3118   M_FILE="\$(srcdir)/${machfile}"
3119 else
3120   M_FILE=
3121 fi
3122 S_FILE="\$(srcdir)/${opsysfile}"
3123 AC_SUBST(M_FILE)
3124 AC_SUBST(S_FILE)
3125 AC_SUBST(ns_appdir)
3126 AC_SUBST(ns_appbindir)
3127 AC_SUBST(ns_appresdir)
3128 AC_SUBST(ns_appsrc)
3129 AC_SUBST(GNU_OBJC_CFLAGS)
3130 AC_SUBST(OTHER_FILES)
3131
3132 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3133                    [Define to the canonical Emacs configuration name.])
3134 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3135                    [Define to the options passed to configure.])
3136 if test -n "$machfile"; then
3137   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3138                      [Define to the used machine dependent file.])
3139 fi
3140 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3141                    [Define to the used os dependent file.])
3142
3143 XMENU_OBJ=
3144 XOBJ=
3145 FONT_OBJ=
3146 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3147   AC_DEFINE(HAVE_X_WINDOWS, 1,
3148             [Define to 1 if you want to use the X window system.])
3149   XMENU_OBJ=xmenu.o
3150   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3151   FONT_OBJ=xfont.o
3152   if test "$HAVE_XFT" = "yes"; then
3153     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3154   elif test "$HAVE_FREETYPE" = "yes"; then
3155     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3156   fi
3157   AC_SUBST(FONT_OBJ)
3158 fi
3159 AC_SUBST(XMENU_OBJ)
3160 AC_SUBST(XOBJ)
3161 AC_SUBST(FONT_OBJ)
3162
3163 WIDGET_OBJ=
3164 MOTIF_LIBW=
3165 if test "${USE_X_TOOLKIT}" != "none" ; then
3166   WIDGET_OBJ=widget.o
3167   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3168   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3169     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3170   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3171     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3172     MOTIF_LIBW=-lXm
3173     case "$opsys" in
3174       gnu-linux)
3175         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3176         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3177         ;;
3178
3179       unixware)
3180         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3181         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3182         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3183         ;;
3184
3185       aix4-2)
3186         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3187         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3188         ;;
3189     esac
3190     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3191   fi
3192 fi
3193 AC_SUBST(WIDGET_OBJ)
3194
3195 TOOLKIT_LIBW=
3196 case "$USE_X_TOOLKIT" in
3197   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3198   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3199   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3200 esac
3201 AC_SUBST(TOOLKIT_LIBW)
3202
3203 if test "$USE_X_TOOLKIT" = "none"; then
3204   LIBXT_OTHER="\$(LIBXSM)"
3205   OLDXMENU_TARGET="really-oldXMenu"
3206 else
3207   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3208   OLDXMENU_TARGET="really-lwlib"
3209 fi
3210 AC_SUBST(LIBXT_OTHER)
3211
3212 ## The X Menu stuff is present in the X10 distribution, but missing
3213 ## from X11.  If we have X10, just use the installed library;
3214 ## otherwise, use our own copy.
3215 if test "${HAVE_X11}" = "yes" ; then
3216   AC_DEFINE(HAVE_X11, 1,
3217             [Define to 1 if you want to use version 11 of X windows.
3218              Otherwise, Emacs expects to use version 10.])
3219
3220   if test "$USE_X_TOOLKIT" = "none"; then
3221     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3222   else
3223     OLDXMENU="\${lwlibdir}/liblw.a"
3224   fi
3225   LIBXMENU="\$(OLDXMENU)"
3226   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3227   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3228 else
3229   ## For a syntactically valid Makefile; not actually used for anything.
3230   ## See comments in src/Makefile.in.
3231   OLDXMENU=nothing
3232   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3233   if test "${HAVE_X_WINDOWS}" = "yes"; then
3234     LIBXMENU="-lXMenu"
3235   else
3236     LIBXMENU=
3237   fi
3238   LIBX_OTHER=
3239   OLDXMENU_DEPS=
3240 fi
3241
3242 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3243   OLDXMENU_TARGET=
3244   OLDXMENU=nothing
3245   LIBXMENU=
3246   OLDXMENU_DEPS=
3247 fi
3248
3249 AC_SUBST(OLDXMENU_TARGET)
3250 AC_SUBST(OLDXMENU)
3251 AC_SUBST(LIBXMENU)
3252 AC_SUBST(LIBX_OTHER)
3253 AC_SUBST(OLDXMENU_DEPS)
3254
3255 if test "${HAVE_MENUS}" = "yes" ; then
3256   AC_DEFINE(HAVE_MENUS, 1,
3257             [Define to 1 if you have mouse menus.
3258              (This is automatic if you use X, but the option to specify it remains.)
3259              It is also defined with other window systems that support xmenu.c.])
3260 fi
3261
3262 if test "${GNU_MALLOC}" = "yes" ; then
3263   AC_DEFINE(GNU_MALLOC, 1,
3264             [Define to 1 if you want to use the GNU memory allocator.])
3265 fi
3266
3267 RALLOC_OBJ=
3268 if test "${REL_ALLOC}" = "yes" ; then
3269   AC_DEFINE(REL_ALLOC, 1,
3270             [Define REL_ALLOC if you want to use the relocating allocator for
3271              buffer space.])
3272
3273   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3274 fi
3275 AC_SUBST(RALLOC_OBJ)
3276
3277 if test "$opsys" = "cygwin"; then
3278   CYGWIN_OBJ="sheap.o"
3279   ## Cygwin differs because of its unexec().
3280   PRE_ALLOC_OBJ=
3281   POST_ALLOC_OBJ=lastfile.o
3282 else
3283   CYGWIN_OBJ=
3284   PRE_ALLOC_OBJ=lastfile.o
3285   POST_ALLOC_OBJ=
3286 fi
3287 AC_SUBST(CYGWIN_OBJ)
3288 AC_SUBST(PRE_ALLOC_OBJ)
3289 AC_SUBST(POST_ALLOC_OBJ)
3290
3291
3292 case "$opsys" in
3293   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3294
3295   darwin)
3296    ## The -headerpad option tells ld (see man page) to leave room at the
3297    ## end of the header for adding load commands.  Needed for dumping.
3298    ## 0x690 is the total size of 30 segment load commands (at 56
3299    ## each); under Cocoa 31 commands are required.
3300    if test "$HAVE_NS" = "yes"; then
3301      libs_nsgui="-framework AppKit"
3302      headerpad_extra=6C8
3303    else
3304      libs_nsgui=
3305      headerpad_extra=690
3306    fi
3307    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3308
3309    ## This is here because src/Makefile.in did some extra fiddling around
3310    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3311    ##   #ifndef LD_SWITCH_SYSTEM
3312    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3313    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3314    ## not using gcc, darwin system not on an alpha (ie darwin, since
3315    ## darwin + alpha does not occur).
3316    ## Because this was done in src/Makefile.in, the resulting part of
3317    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3318    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3319    ## rather than LD_SWITCH_SYSTEM.
3320    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3321      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3322    ;;
3323
3324   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3325   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3326   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3327   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3328   ## had different values in configure (in ac_link) and src/Makefile.in.
3329   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3330   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3331
3332   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3333 esac
3334
3335 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3336   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3337 fi
3338
3339 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3340
3341
3342 LD_FIRSTFLAG=
3343 ORDINARY_LINK=
3344 case "$opsys" in
3345   ## gnu: GNU needs its own crt0.
3346   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3347
3348   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3349   ## library search parth, i.e. it won't search /usr/lib for libc and
3350   ## friends.  Using -nostartfiles instead avoids this problem, and
3351   ## will also work on earlier NetBSD releases.
3352   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3353
3354   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3355   ##   MkLinux/LinuxPPC needs this.
3356   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3357   gnu-*)
3358     case "$machine" in
3359       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3360     esac
3361     ;;
3362 esac
3363
3364
3365 if test "x$ORDINARY_LINK" = "xyes"; then
3366
3367   LD_FIRSTFLAG=""
3368   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3369
3370 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3371 ## freebsd, gnu-* not on macppc|ibms390x.
3372 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3373
3374   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3375   ## places that are difficult to figure out at make time.  Fortunately,
3376   ## these same versions allow you to pass arbitrary flags on to the
3377   ## linker, so there is no reason not to use it as a linker.
3378   ##
3379   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3380   ## searching for libraries in its internal directories, so we have to
3381   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3382   LD_FIRSTFLAG="-nostdlib"
3383 fi
3384
3385 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3386 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3387
3388 AC_SUBST(LD_FIRSTFLAG)
3389
3390
3391 ## FIXME? The logic here is not precisely the same as that above.
3392 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3393 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3394 LIB_GCC=
3395 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3396
3397   case "$opsys" in
3398     freebsd|netbsd|openbsd) LIB_GCC= ;;
3399
3400     gnu-*)
3401       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3402       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3403       case $host_cpu in
3404       arm*)
3405         LIB_GCC="-lgcc_s"
3406         ;;
3407       *)
3408         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3409         ## immediately undefine it again and redefine it to empty.
3410         ## Was the C_SWITCH_X_SITE part really necessary?
3411 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3412         LIB_GCC=
3413         ;;
3414       esac
3415       ;;
3416
3417     ## Ask GCC where to find libgcc.a.
3418     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3419   esac
3420 fi                              dnl if $GCC
3421 AC_SUBST(LIB_GCC)
3422
3423
3424 TOOLTIP_SUPPORT=
3425 WINDOW_SUPPORT=
3426 ## If we're using X11/GNUstep, define some consequences.
3427 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3428   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3429   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3430   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3431   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3432
3433   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3434   test "$HAVE_X_WINDOWS" = "yes" && \
3435     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3436
3437 fi
3438 AC_SUBST(MOUSE_SUPPORT)
3439 AC_SUBST(TOOLTIP_SUPPORT)
3440 AC_SUBST(WINDOW_SUPPORT)
3441
3442
3443 AH_TOP([/* GNU Emacs site configuration template file.
3444
3445 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3446   Free Software Foundation, Inc.
3447
3448 This file is part of GNU Emacs.
3449
3450 GNU Emacs is free software: you can redistribute it and/or modify
3451 it under the terms of the GNU General Public License as published by
3452 the Free Software Foundation, either version 3 of the License, or
3453 (at your option) any later version.
3454
3455 GNU Emacs is distributed in the hope that it will be useful,
3456 but WITHOUT ANY WARRANTY; without even the implied warranty of
3457 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3458 GNU General Public License for more details.
3459
3460 You should have received a copy of the GNU General Public License
3461 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3462
3463
3464 /* No code in Emacs #includes config.h twice, but some bits of code
3465    intended to work with other packages as well (like gmalloc.c)
3466    think they can include it as many times as they like.  */
3467 #ifndef EMACS_CONFIG_H
3468 #define EMACS_CONFIG_H
3469 ])dnl
3470
3471 AH_BOTTOM([
3472 /* Define AMPERSAND_FULL_NAME if you use the convention
3473    that & in the full name stands for the login id.  */
3474 /* Turned on June 1996 supposing nobody will mind it.  */
3475 #define AMPERSAND_FULL_NAME
3476
3477 /* If using GNU, then support inline function declarations.  */
3478 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3479    generally, because even if non-gcc compilers accept `inline', they
3480    may reject `extern inline'.  */
3481 #if defined (__GNUC__)
3482 #define INLINE __inline__
3483 #else
3484 #define INLINE
3485 #endif
3486
3487 /* `subprocesses' should be defined if you want to
3488    have code for asynchronous subprocesses
3489    (as used in M-x compile and M-x shell).
3490    Only MSDOS does not support this (it overrides
3491    this in its config_opsysfile below).  */
3492
3493 #define subprocesses
3494
3495 /* Include the os and machine dependent files.  */
3496 #include config_opsysfile
3497 #ifdef config_machfile
3498 # include config_machfile
3499 #endif
3500
3501 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3502    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3503   (There is probably a better place to do this, but right now the
3504    Cocoa side does this in s/darwin.h and we cannot parallel this
3505    exactly since GNUstep is multi-OS.  */
3506 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3507 #  define SYSTEM_PURESIZE_EXTRA 30000
3508 #endif
3509
3510 #ifdef emacs /* Don't do this for lib-src.  */
3511 /* Tell regex.c to use a type compatible with Emacs.  */
3512 #define RE_TRANSLATE_TYPE Lisp_Object
3513 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3514 #ifdef make_number
3515 /* If make_number is a macro, use it.  */
3516 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3517 #else
3518 /* If make_number is a function, avoid it.  */
3519 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3520 #endif
3521 #endif
3522
3523 /* These default definitions are good for almost all machines.
3524    Any exceptions should override them in m/MACHINE.h.
3525    They must be usable in preprocessor conditionals.  */
3526
3527 #ifndef BITS_PER_CHAR
3528 #define BITS_PER_CHAR 8
3529 #endif
3530
3531 #ifndef BITS_PER_SHORT
3532 #define BITS_PER_SHORT 16
3533 #endif
3534
3535 #ifndef BITS_PER_INT
3536 #define BITS_PER_INT 32
3537 #endif
3538
3539 #ifndef BITS_PER_LONG
3540 #ifdef _LP64
3541 #define BITS_PER_LONG 64
3542 #else
3543 #define BITS_PER_LONG 32
3544 #endif
3545 #endif
3546
3547 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3548 #define BITS_PER_LONG_LONG 64
3549 #endif
3550
3551 /* Define if the compiler supports function prototypes.  It may do so but
3552    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3553 #undef PROTOTYPES
3554
3555 #include <string.h>
3556 #include <stdlib.h>
3557
3558 #ifdef HAVE_ALLOCA_H
3559 # include <alloca.h>
3560 #elif defined __GNUC__
3561 # define alloca __builtin_alloca
3562 #elif defined _AIX
3563 # define alloca __alloca
3564 #else
3565 # include <stddef.h>
3566 # ifdef  __cplusplus
3567 extern "C"
3568 # endif
3569 void *alloca (size_t);
3570 #endif
3571
3572 #ifndef HAVE_STRCHR
3573 #define strchr(a, b) index (a, b)
3574 #endif
3575
3576 #ifndef HAVE_STRRCHR
3577 #define strrchr(a, b) rindex (a, b)
3578 #endif
3579
3580 #if defined __GNUC__ && (__GNUC__ > 2 \
3581                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3582 #define NO_RETURN       __attribute__ ((__noreturn__))
3583 #else
3584 #define NO_RETURN       /* nothing */
3585 #endif
3586
3587 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3588 #define NO_INLINE __attribute__((noinline))
3589 #else
3590 #define NO_INLINE
3591 #endif
3592
3593 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3594 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3595 #else
3596 #define EXTERNALLY_VISIBLE
3597 #endif
3598
3599 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3600 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3601 #else
3602 # define ATTRIBUTE_FORMAT(spec) /* empty */
3603 #endif
3604
3605 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3606 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3607    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3608 #else
3609 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3610    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3611 #endif
3612
3613 /* Some versions of GNU/Linux define noinline in their headers.  */
3614 #ifdef noinline
3615 #undef noinline
3616 #endif
3617
3618 /* These won't be used automatically yet.  We also need to know, at least,
3619    that the stack is continuous.  */
3620 #ifdef __GNUC__
3621 #  ifndef GC_SETJMP_WORKS
3622   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3623 #    define GC_SETJMP_WORKS 1
3624 #  endif
3625 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3626 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3627 #  endif
3628 #endif
3629
3630 #endif /* EMACS_CONFIG_H */
3631
3632 /*
3633 Local Variables:
3634 mode: c
3635 End:
3636 */
3637 ])dnl
3638
3639 #### Report on what we decided to do.
3640 #### Report GTK as a toolkit, even if it doesn't use Xt.
3641 #### It makes printing result more understandable as using GTK sets
3642 #### toolkit_scroll_bars to yes by default.
3643 if test "${HAVE_GTK}" = "yes"; then
3644   USE_X_TOOLKIT=GTK
3645 fi
3646
3647 and_machfile=
3648 if test -n "$machfile"; then
3649   and_machfile=" and \`${machfile}'"
3650 fi
3651
3652 echo "
3653 Configured for \`${canonical}'.
3654
3655   Where should the build process find the source code?    ${srcdir}
3656   What operating system and machine description files should Emacs use?
3657         \`${opsysfile}'${and_machfile}
3658   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3659   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3660   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3661   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3662   What window system should Emacs use?                    ${window_system}
3663   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3664
3665 if test -n "${x_includes}"; then
3666 echo "  Where do we find X Windows header files?                ${x_includes}"
3667 else
3668 echo "  Where do we find X Windows header files?                Standard dirs"
3669 fi
3670 if test -n "${x_libraries}"; then
3671 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3672 else
3673 echo "  Where do we find X Windows libraries?                   Standard dirs"
3674 fi
3675
3676 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3677 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3678 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3679 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3680 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3681 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3682 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3683 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3684
3685 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3686 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3687 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3688 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3689 echo "  Does Emacs use -lgnutls (2.6.x or higher)?              ${HAVE_GNUTLS}"
3690 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3691
3692 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3693 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3694 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3695 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3696
3697 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3698 echo
3699
3700 if test $USE_XASSERTS = yes; then
3701    echo "  Compiling with asserts turned on."
3702    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3703 fi
3704
3705 echo
3706
3707 if test "$HAVE_NS" = "yes"; then
3708    echo
3709    echo "You must run \"make install\" in order to test the built application.
3710 The installed application will go to nextstep/Emacs.app and can be
3711 run or moved from there."
3712    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3713       echo "The application will be fully self-contained."
3714     else
3715       echo "The lisp resources for the application will be installed under ${prefix}.
3716 You may need to run \"make install\" with sudo.  The application will fail
3717 to run if these resources are not installed."
3718    fi
3719    echo
3720 fi
3721
3722
3723 # Remove any trailing slashes in these variables.
3724 [test "${prefix}" != NONE &&
3725   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3726 test "${exec_prefix}" != NONE &&
3727   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3728
3729 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3730         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3731         doc/lispref/Makefile src/Makefile \
3732         lwlib/Makefile lisp/Makefile leim/Makefile test/automated/Makefile])
3733
3734 dnl Make the necessary directories, if they don't exist.
3735 AC_CONFIG_COMMANDS([mkdirs], [
3736 for dir in etc lisp ; do
3737   test -d ${dir} || mkdir ${dir}
3738 done
3739 ])
3740
3741 dnl You might wonder (I did) why epaths.h is generated by running make,
3742 dnl rather than just letting configure generate it from epaths.in.
3743 dnl One reason is that the various paths are not fully expanded (see above);
3744 dnl eg gamedir=${prefix}/var/games/emacs.
3745 dnl Secondly, the GNU Coding standards require that one should be able
3746 dnl to run `make prefix=/some/where/else' and override the values set
3747 dnl by configure.  This also explains the `move-if-change' test and
3748 dnl the use of force in the `epaths-force' rule in Makefile.in.
3749 AC_CONFIG_COMMANDS([epaths], [
3750 echo creating src/epaths.h
3751 ${MAKE-make} epaths-force
3752 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3753
3754 AC_CONFIG_COMMANDS([gdbinit], [
3755 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3756   echo creating src/.gdbinit
3757   echo source $srcdir/src/.gdbinit > src/.gdbinit
3758 fi
3759 ])
3760
3761 AC_OUTPUT
3762
3763 dnl configure.in ends here