lisp/vc-cvs.el

   1 ;;; vc-cvs.el --- non-resident support for CVS version-control
   2
   3 ;; Copyright (C) 1995, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author:      FSF (see vc.el for full credits)
   7 ;; Maintainer:  Andre Spiegel <spiegel@gnu.org>
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl) (require 'vc))
  29
  30 ;; Clear up the cache to force vc-call to check again and discover
  31 ;; new functions when we reload this file.
  32 (put 'CVS 'vc-functions nil)
  33
  34 ;;; Properties of the backend.
  35
  36 (defun vc-cvs-revision-granularity () 'file)
  37
  38 (defun vc-cvs-checkout-model (files)
  39   "CVS-specific version of `vc-checkout-model'."
  40   (if (getenv "CVSREAD")
  41       'announce
  42     (let* ((file (if (consp files) (car files) files))
  43            (attrib (file-attributes file)))
  44       (or (vc-file-getprop file 'vc-checkout-model)
  45           (vc-file-setprop
  46            file 'vc-checkout-model
  47            (if (and attrib ;; don't check further if FILE doesn't exist
  48                     ;; If the file is not writable (despite CVSREAD being
  49                     ;; undefined), this is probably because the file is being
  50                     ;; "watched" by other developers.
  51                     ;; (If vc-mistrust-permissions was t, we actually shouldn't
  52                     ;; trust this, but there is no other way to learn this from
  53                     ;; CVS at the moment (version 1.9).)
  54                     (string-match "r-..-..-." (nth 8 attrib)))
  55                'announce
  56              'implicit))))))
  57
  58 ;;;
  59 ;;; Customization options
  60 ;;;
  61
  62 (defcustom vc-cvs-global-switches nil
  63   "Global switches to pass to any CVS command."
  64   :type '(choice (const :tag "None" nil)
  65                  (string :tag "Argument String")
  66                  (repeat :tag "Argument List"
  67                          :value ("")
  68                          string))
  69   :version "22.1"
  70   :group 'vc)
  71
  72 (defcustom vc-cvs-register-switches nil
  73   "Switches for registering a file into CVS.
  74 A string or list of strings passed to the checkin program by
  75 \\[vc-register].  If nil, use the value of `vc-register-switches'.
  76 If t, use no switches."
  77   :type '(choice (const :tag "Unspecified" nil)
  78                  (const :tag "None" t)
  79                  (string :tag "Argument String")
  80                  (repeat :tag "Argument List" :value ("") string))
  81   :version "21.1"
  82   :group 'vc)
  83
  84 (defcustom vc-cvs-diff-switches nil
  85   "String or list of strings specifying switches for CVS diff under VC.
  86 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  87   :type '(choice (const :tag "Unspecified" nil)
  88                  (const :tag "None" t)
  89                  (string :tag "Argument String")
  90                  (repeat :tag "Argument List" :value ("") string))
  91   :version "21.1"
  92   :group 'vc)
  93
  94 (defcustom vc-cvs-header (or (cdr (assoc 'CVS vc-header-alist)) '("\$Id\$"))
  95   "Header keywords to be inserted by `vc-insert-headers'."
  96   :version "21.1"
  97   :type '(repeat string)
  98   :group 'vc)
  99
 100 (defcustom vc-cvs-use-edit t
 101   "Non-nil means to use `cvs edit' to \"check out\" a file.
 102 This is only meaningful if you don't use the implicit checkout model
 103 \(i.e. if you have $CVSREAD set)."
 104   :type 'boolean
 105   :version "21.1"
 106   :group 'vc)
 107
 108 (defcustom vc-cvs-stay-local 'only-file
 109   "Non-nil means use local operations when possible for remote repositories.
 110 This avoids slow queries over the network and instead uses heuristics
 111 and past information to determine the current status of a file.
 112
 113 If value is the symbol `only-file' `vc-dir' will connect to the
 114 server, but heuristics will be used to determine the status for
 115 all other VC operations.
 116
 117 The value can also be a regular expression or list of regular
 118 expressions to match against the host name of a repository; then VC
 119 only stays local for hosts that match it.  Alternatively, the value
 120 can be a list of regular expressions where the first element is the
 121 symbol `except'; then VC always stays local except for hosts matched
 122 by these regular expressions."
 123   :type '(choice (const :tag "Always stay local" t)
 124                  (const :tag "Only for file operations" only-file)
 125                  (const :tag "Don't stay local" nil)
 126                  (list :format "\nExamine hostname and %v"
 127                        :tag "Examine hostname ..."
 128                        (set :format "%v" :inline t
 129                             (const :format "%t" :tag "don't" except))
 130                        (regexp :format " stay local,\n%t: %v"
 131                                :tag "if it matches")
 132                        (repeat :format "%v%i\n" :inline t (regexp :tag "or"))))
 133   :version "23.1"
 134   :group 'vc)
 135
 136 (defcustom vc-cvs-sticky-date-format-string "%c"
 137   "Format string for mode-line display of sticky date.
 138 Format is according to `format-time-string'.  Only used if
 139 `vc-cvs-sticky-tag-display' is t."
 140   :type '(string)
 141   :version "22.1"
 142   :group 'vc)
 143
 144 (defcustom vc-cvs-sticky-tag-display t
 145   "Specify the mode-line display of sticky tags.
 146 Value t means default display, nil means no display at all.  If the
 147 value is a function or macro, it is called with the sticky tag and
 148 its' type as parameters, in that order.  TYPE can have three different
 149 values: `symbolic-name' (TAG is a string), `revision-number' (TAG is a
 150 string) and `date' (TAG is a date as returned by `encode-time').  The
 151 return value of the function or macro will be displayed as a string.
 152
 153 Here's an example that will display the formatted date for sticky
 154 dates and the word \"Sticky\" for sticky tag names and revisions.
 155
 156   (lambda (tag type)
 157     (cond ((eq type 'date) (format-time-string
 158                               vc-cvs-sticky-date-format-string tag))
 159           ((eq type 'revision-number) \"Sticky\")
 160           ((eq type 'symbolic-name) \"Sticky\")))
 161
 162 Here's an example that will abbreviate to the first character only,
 163 any text before the first occurrence of `-' for sticky symbolic tags.
 164 If the sticky tag is a revision number, the word \"Sticky\" is
 165 displayed.  Date and time is displayed for sticky dates.
 166
 167    (lambda (tag type)
 168      (cond ((eq type 'date) (format-time-string \"%Y%m%d %H:%M\" tag))
 169            ((eq type 'revision-number) \"Sticky\")
 170            ((eq type 'symbolic-name)
 171             (condition-case nil
 172                 (progn
 173                   (string-match \"\\\\([^-]*\\\\)\\\\(.*\\\\)\" tag)
 174                   (concat (substring (match-string 1 tag) 0 1) \":\"
 175                           (substring (match-string 2 tag) 1 nil)))
 176               (error tag)))))       ; Fall-back to given tag name.
 177
 178 See also variable `vc-cvs-sticky-date-format-string'."
 179   :type '(choice boolean function)
 180   :version "22.1"
 181   :group 'vc)
 182
 183 ;;;
 184 ;;; Internal variables
 185 ;;;
 186
 187
 188 ;;;
 189 ;;; State-querying functions
 190 ;;;
 191
 192 ;;;###autoload (defun vc-cvs-registered (f)
 193 ;;;###autoload   (when (file-readable-p (expand-file-name
 194 ;;;###autoload                    "CVS/Entries" (file-name-directory f)))
 195 ;;;###autoload       (load "vc-cvs")
 196 ;;;###autoload       (vc-cvs-registered f)))
 197
 198 (defun vc-cvs-registered (file)
 199   "Check if FILE is CVS registered."
 200   (let ((dirname (or (file-name-directory file) ""))
 201         (basename (file-name-nondirectory file))
 202         ;; make sure that the file name is searched case-sensitively
 203         (case-fold-search nil))
 204     (if (file-readable-p (expand-file-name "CVS/Entries" dirname))
 205         (or (string= basename "")
 206             (with-temp-buffer
 207               (vc-cvs-get-entries dirname)
 208               (goto-char (point-min))
 209               (cond ((re-search-forward
 210                       (concat "^/" (regexp-quote basename) "/[^/]") nil t)
 211                      (beginning-of-line)
 212                      (vc-cvs-parse-entry file)
 213                      t)
 214                     (t nil))))
 215       nil)))
 216
 217 (defun vc-cvs-state (file)
 218   "CVS-specific version of `vc-state'."
 219   (if (vc-stay-local-p file 'CVS)
 220       (let ((state (vc-file-getprop file 'vc-state)))
 221         ;; If we should stay local, use the heuristic but only if
 222         ;; we don't have a more precise state already available.
 223         (if (memq state '(up-to-date edited nil))
 224             (vc-cvs-state-heuristic file)
 225           state))
 226     (with-temp-buffer
 227       (cd (file-name-directory file))
 228       (vc-cvs-command t 0 file "status")
 229       (vc-cvs-parse-status t))))
 230
 231 (defun vc-cvs-state-heuristic (file)
 232   "CVS-specific state heuristic."
 233   ;; If the file has not changed since checkout, consider it `up-to-date'.
 234   ;; Otherwise consider it `edited'.
 235   (let ((checkout-time (vc-file-getprop file 'vc-checkout-time))
 236         (lastmod (nth 5 (file-attributes file))))
 237     (cond
 238      ((equal checkout-time lastmod) 'up-to-date)
 239      ((string= (vc-working-revision file) "0") 'added)
 240      ((null checkout-time) 'unregistered)
 241      (t 'edited))))
 242
 243 (defun vc-cvs-working-revision (file)
 244   "CVS-specific version of `vc-working-revision'."
 245   ;; There is no need to consult RCS headers under CVS, because we
 246   ;; get the workfile version for free when we recognize that a file
 247   ;; is registered in CVS.
 248   (vc-cvs-registered file)
 249   (vc-file-getprop file 'vc-working-revision))
 250
 251 (defun vc-cvs-mode-line-string (file)
 252   "Return string for placement into the modeline for FILE.
 253 Compared to the default implementation, this function does two things:
 254 Handle the special case of a CVS file that is added but not yet
 255 committed and support display of sticky tags."
 256   (let* ((sticky-tag (vc-file-getprop file 'vc-cvs-sticky-tag))
 257          help-echo
 258          (string
 259           (let ((def-ml (vc-default-mode-line-string 'CVS file)))
 260             (setq help-echo
 261                   (get-text-property 0 'help-echo def-ml))
 262             def-ml)))
 263     (propertize
 264      (if (zerop (length sticky-tag))
 265          string
 266        (setq help-echo (format "%s on the '%s' branch"
 267                                help-echo sticky-tag))
 268        (concat string "[" sticky-tag "]"))
 269      'help-echo help-echo)))
 270
 271
 272 ;;;
 273 ;;; State-changing functions
 274 ;;;
 275
 276 (defun vc-cvs-register (files &optional rev comment)
 277   "Register FILES into the CVS version-control system.
 278 COMMENT can be used to provide an initial description of FILES.
 279 Passes either `vc-cvs-register-switches' or `vc-register-switches'
 280 to the CVS command."
 281   ;; Register the directories if needed.
 282   (let (dirs)
 283     (dolist (file files)
 284       (and (not (vc-cvs-responsible-p file))
 285            (vc-cvs-could-register file)
 286            (push (directory-file-name (file-name-directory file)) dirs)))
 287     (if dirs (vc-cvs-register dirs)))
 288   (apply 'vc-cvs-command nil 0 files
 289          "add"
 290          (and comment (string-match "[^\t\n ]" comment)
 291               (concat "-m" comment))
 292          (vc-switches 'CVS 'register)))
 293
 294 (defun vc-cvs-responsible-p (file)
 295   "Return non-nil if CVS thinks it is responsible for FILE."
 296   (file-directory-p (expand-file-name "CVS"
 297                                       (if (file-directory-p file)
 298                                           file
 299                                         (file-name-directory file)))))
 300
 301 (defun vc-cvs-could-register (file)
 302   "Return non-nil if FILE could be registered in CVS.
 303 This is only possible if CVS is managing FILE's directory or one of
 304 its parents."
 305   (let ((dir file))
 306     (while (and (stringp dir)
 307                 (not (equal dir (setq dir (file-name-directory dir))))
 308                 dir)
 309       (setq dir (if (file-exists-p
 310                      (expand-file-name "CVS/Entries" dir))
 311                     t
 312                   (directory-file-name dir))))
 313     (eq dir t)))
 314
 315 (defun vc-cvs-checkin (files rev comment)
 316   "CVS-specific version of `vc-backend-checkin'."
 317   (unless (or (not rev) (vc-cvs-valid-revision-number-p rev))
 318     (if (not (vc-cvs-valid-symbolic-tag-name-p rev))
 319         (error "%s is not a valid symbolic tag name" rev)
 320       ;; If the input revison is a valid symbolic tag name, we create it
 321       ;; as a branch, commit and switch to it.
 322       (apply 'vc-cvs-command nil 0 files "tag" "-b" (list rev))
 323       (apply 'vc-cvs-command nil 0 files "update" "-r" (list rev))
 324       (mapc (lambda (file) (vc-file-setprop file 'vc-cvs-sticky-tag rev))
 325             files)))
 326   (let ((status (apply 'vc-cvs-command nil 1 files
 327                        "ci" (if rev (concat "-r" rev))
 328                        (concat "-m" comment)
 329                        (vc-switches 'CVS 'checkin))))
 330     (set-buffer "*vc*")
 331     (goto-char (point-min))
 332     (when (not (zerop status))
 333       ;; Check checkin problem.
 334       (cond
 335        ((re-search-forward "Up-to-date check failed" nil t)
 336         (mapc (lambda (file) (vc-file-setprop file 'vc-state 'needs-merge))
 337               files)
 338         (error "%s" (substitute-command-keys
 339                 (concat "Up-to-date check failed: "
 340                         "type \\[vc-next-action] to merge in changes"))))
 341        (t
 342         (pop-to-buffer (current-buffer))
 343         (goto-char (point-min))
 344         (shrink-window-if-larger-than-buffer)
 345         (error "Check-in failed"))))
 346     ;; Single-file commit?  Then update the revision by parsing the buffer.
 347     ;; Otherwise we can't necessarily tell what goes with what; clear
 348     ;; its properties so they have to be refetched.
 349     (if (= (length files) 1)
 350         (vc-file-setprop
 351          (car files) 'vc-working-revision
 352          (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 353       (mapc 'vc-file-clearprops files))
 354     ;; Anyway, forget the checkout model of the file, because we might have
 355     ;; guessed wrong when we found the file.  After commit, we can
 356     ;; tell it from the permissions of the file (see
 357     ;; vc-cvs-checkout-model).
 358     (mapc (lambda (file) (vc-file-setprop file 'vc-checkout-model nil))
 359           files)
 360
 361     ;; if this was an explicit check-in (does not include creation of
 362     ;; a branch), remove the sticky tag.
 363     (if (and rev (not (vc-cvs-valid-symbolic-tag-name-p rev)))
 364         (vc-cvs-command nil 0 files "update" "-A"))))
 365
 366 (defun vc-cvs-find-revision (file rev buffer)
 367   (apply 'vc-cvs-command
 368          buffer 0 file
 369          "-Q"                           ; suppress diagnostic output
 370          "update"
 371          (and rev (not (string= rev ""))
 372               (concat "-r" rev))
 373          "-p"
 374          (vc-switches 'CVS 'checkout)))
 375
 376 (defun vc-cvs-checkout (file &optional editable rev)
 377   "Checkout a revision of FILE into the working area.
 378 EDITABLE non-nil means that the file should be writable.
 379 REV is the revision to check out."
 380   (message "Checking out %s..." file)
 381   ;; Change buffers to get local value of vc-checkout-switches.
 382   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 383     (if (and (file-exists-p file) (not rev))
 384         ;; If no revision was specified, just make the file writable
 385         ;; if necessary (using `cvs-edit' if requested).
 386         (and editable (not (eq (vc-cvs-checkout-model (list file)) 'implicit))
 387              (if vc-cvs-use-edit
 388                  (vc-cvs-command nil 0 file "edit")
 389                (set-file-modes file (logior (file-modes file) 128))
 390                (if (equal file buffer-file-name) (toggle-read-only -1))))
 391       ;; Check out a particular revision (or recreate the file).
 392       (vc-file-setprop file 'vc-working-revision nil)
 393       (apply 'vc-cvs-command nil 0 file
 394              (and editable "-w")
 395              "update"
 396              (when rev
 397                (unless (eq rev t)
 398                  ;; default for verbose checkout: clear the
 399                  ;; sticky tag so that the actual update will
 400                  ;; get the head of the trunk
 401                  (if (string= rev "")
 402                      "-A"
 403                    (concat "-r" rev))))
 404              (vc-switches 'CVS 'checkout)))
 405     (vc-mode-line file 'CVS))
 406   (message "Checking out %s...done" file))
 407
 408 (defun vc-cvs-delete-file (file)
 409   (vc-cvs-command nil 0 file "remove" "-f"))
 410
 411 (defun vc-cvs-revert (file &optional contents-done)
 412   "Revert FILE to the working revision on which it was based."
 413   (vc-default-revert 'CVS file contents-done)
 414   (unless (eq (vc-cvs-checkout-model (list file)) 'implicit)
 415     (if vc-cvs-use-edit
 416         (vc-cvs-command nil 0 file "unedit")
 417       ;; Make the file read-only by switching off all w-bits
 418       (set-file-modes file (logand (file-modes file) 3950)))))
 419
 420 (defun vc-cvs-merge (file first-revision &optional second-revision)
 421   "Merge changes into current working copy of FILE.
 422 The changes are between FIRST-REVISION and SECOND-REVISION."
 423   (vc-cvs-command nil 0 file
 424                  "update" "-kk"
 425                  (concat "-j" first-revision)
 426                  (concat "-j" second-revision))
 427   (vc-file-setprop file 'vc-state 'edited)
 428   (with-current-buffer (get-buffer "*vc*")
 429     (goto-char (point-min))
 430     (if (re-search-forward "conflicts during merge" nil t)
 431         (progn
 432           (vc-file-setprop file 'vc-state 'conflict)
 433           ;; signal error
 434           1)
 435       (vc-file-setprop file 'vc-state 'edited)
 436       ;; signal success
 437       0)))
 438
 439 (defun vc-cvs-merge-news (file)
 440   "Merge in any new changes made to FILE."
 441   (message "Merging changes into %s..." file)
 442   ;; (vc-file-setprop file 'vc-working-revision nil)
 443   (vc-file-setprop file 'vc-checkout-time 0)
 444   (vc-cvs-command nil nil file "update")
 445   ;; Analyze the merge result reported by CVS, and set
 446   ;; file properties accordingly.
 447   (with-current-buffer (get-buffer "*vc*")
 448     (goto-char (point-min))
 449     ;; get new working revision
 450     (if (re-search-forward
 451          "^Merging differences between [0-9.]* and \\([0-9.]*\\) into" nil t)
 452         (vc-file-setprop file 'vc-working-revision (match-string 1))
 453       (vc-file-setprop file 'vc-working-revision nil))
 454     ;; get file status
 455     (prog1
 456         (if (eq (buffer-size) 0)
 457             0 ;; there were no news; indicate success
 458           (if (re-search-forward
 459                (concat "^\\([CMUP] \\)?"
 460                        (regexp-quote
 461                         (substring file (length default-directory)))
 462                        "\\( already contains the differences between \\)?")
 463                nil t)
 464               (cond
 465                ;; Merge successful, we are in sync with repository now
 466                ((or (match-string 2)
 467                     (string= (match-string 1) "U ")
 468                     (string= (match-string 1) "P "))
 469                 (vc-file-setprop file 'vc-state 'up-to-date)
 470                 (vc-file-setprop file 'vc-checkout-time
 471                                  (nth 5 (file-attributes file)))
 472                 0);; indicate success to the caller
 473                ;; Merge successful, but our own changes are still in the file
 474                ((string= (match-string 1) "M ")
 475                 (vc-file-setprop file 'vc-state 'edited)
 476                 0);; indicate success to the caller
 477                ;; Conflicts detected!
 478                (t
 479                 (vc-file-setprop file 'vc-state 'conflict)
 480                 1);; signal the error to the caller
 481                )
 482             (pop-to-buffer "*vc*")
 483             (error "Couldn't analyze cvs update result")))
 484       (message "Merging changes into %s...done" file))))
 485
 486 (defun vc-cvs-modify-change-comment (files rev comment)
 487   "Modify the change comments for FILES on a specified REV.
 488 Will fail unless you have administrative privileges on the repo."
 489   (vc-cvs-command nil 0 files "admin" (concat "-m" rev ":" comment)))
 490
 491 ;;;
 492 ;;; History functions
 493 ;;;
 494
 495 (defun vc-cvs-print-log (files &optional buffer)
 496   "Get change logs associated with FILES."
 497   ;; It's just the catenation of the individual logs.
 498   (vc-cvs-command
 499    buffer
 500    (if (vc-stay-local-p files 'CVS) 'async 0)
 501    files "log"))
 502
 503 (defun vc-cvs-comment-history (file)
 504   "Get comment history of a file."
 505   (vc-call-backend 'RCS 'comment-history file))
 506
 507 (defun vc-cvs-diff (files &optional oldvers newvers buffer)
 508   "Get a difference report using CVS between two revisions of FILE."
 509   (let* ((async (and (not vc-disable-async-diff)
 510                      (vc-stay-local-p files 'CVS)))
 511          (invoke-cvs-diff-list nil)
 512          status)
 513     ;; Look through the file list and see if any files have backups
 514     ;; that can be used to do a plain "diff" instead of "cvs diff".
 515     (dolist (file files)
 516       (let ((ov oldvers)
 517             (nv newvers))
 518         (when (or (not ov) (string-equal ov ""))
 519           (setq ov (vc-working-revision file)))
 520         (when (string-equal nv "")
 521           (setq nv nil))
 522         (let ((file-oldvers (vc-version-backup-file file ov))
 523               (file-newvers (if (not nv)
 524                                 file
 525                               (vc-version-backup-file file nv)))
 526               (coding-system-for-read (vc-coding-system-for-diff file)))
 527           (if (and file-oldvers file-newvers)
 528               (progn
 529                 ;; This used to append diff-switches and vc-diff-switches,
 530                 ;; which was consistent with the vc-diff-switches doc at that
 531                 ;; time, but not with the actual behavior of any other VC diff.
 532                 (apply 'vc-do-command (or buffer "*vc-diff*") 1 "diff" nil
 533                        ;; Not a CVS diff, does not use vc-cvs-diff-switches.
 534                        (append (vc-switches nil 'diff)
 535                                (list (file-relative-name file-oldvers)
 536                                      (file-relative-name file-newvers))))
 537                 (setq status 0))
 538             (push file invoke-cvs-diff-list)))))
 539     (when invoke-cvs-diff-list
 540       (setq status (apply 'vc-cvs-command (or buffer "*vc-diff*")
 541                           (if async 'async 1)
 542                           invoke-cvs-diff-list "diff"
 543                           (and oldvers (concat "-r" oldvers))
 544                           (and newvers (concat "-r" newvers))
 545                           (vc-switches 'CVS 'diff))))
 546     (if async 1 status))) ; async diff, pessimistic assumption
 547
 548 (defconst vc-cvs-annotate-first-line-re "^[0-9]")
 549
 550 (defun vc-cvs-annotate-process-filter (process string)
 551   (setq string (concat (process-get process 'output) string))
 552   (if (not (string-match vc-cvs-annotate-first-line-re string))
 553       ;; Still waiting for the first real line.
 554       (process-put process 'output string)
 555     (let ((vc-filter (process-get process 'vc-filter)))
 556       (set-process-filter process vc-filter)
 557       (funcall vc-filter process (substring string (match-beginning 0))))))
 558
 559 (defun vc-cvs-annotate-command (file buffer &optional revision)
 560   "Execute \"cvs annotate\" on FILE, inserting the contents in BUFFER.
 561 Optional arg REVISION is a revision to annotate from."
 562   (vc-cvs-command buffer
 563                   (if (vc-stay-local-p file 'CVS)
 564                       'async 0)
 565                   file "annotate"
 566                   (if revision (concat "-r" revision)))
 567   ;; Strip the leading few lines.
 568   (let ((proc (get-buffer-process buffer)))
 569     (if proc
 570         ;; If running asynchronously, use a process filter.
 571         (progn
 572           (process-put proc 'vc-filter (process-filter proc))
 573           (set-process-filter proc 'vc-cvs-annotate-process-filter))
 574       (with-current-buffer buffer
 575         (goto-char (point-min))
 576         (re-search-forward vc-cvs-annotate-first-line-re)
 577         (delete-region (point-min) (1- (point)))))))
 578
 579 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 580
 581 (defun vc-cvs-annotate-current-time ()
 582   "Return the current time, based at midnight of the current day, and
 583 encoded as fractional days."
 584   (vc-annotate-convert-time
 585    (apply 'encode-time 0 0 0 (nthcdr 3 (decode-time (current-time))))))
 586
 587 (defun vc-cvs-annotate-time ()
 588   "Return the time of the next annotation (as fraction of days)
 589 systime, or nil if there is none."
 590   (let* ((bol (point))
 591          (cache (get-text-property bol 'vc-cvs-annotate-time))
 592          (inhibit-read-only t)
 593          (inhibit-modification-hooks t))
 594     (cond
 595      (cache)
 596      ((looking-at
 597        "^\\S-+\\s-+\\S-+\\s-+\\([0-9]+\\)-\\(\\sw+\\)-\\([0-9]+\\)): ")
 598       (let ((day (string-to-number (match-string 1)))
 599             (month (cdr (assq (intern (match-string 2))
 600                               '((Jan .  1) (Feb .  2) (Mar .  3)
 601                                 (Apr .  4) (May .  5) (Jun .  6)
 602                                 (Jul .  7) (Aug .  8) (Sep .  9)
 603                                 (Oct . 10) (Nov . 11) (Dec . 12)))))
 604             (year (let ((tmp (string-to-number (match-string 3))))
 605                     ;; Years 0..68 are 2000..2068.
 606                     ;; Years 69..99 are 1969..1999.
 607                     (+ (cond ((> 69 tmp) 2000)
 608                              ((> 100 tmp) 1900)
 609                              (t 0))
 610                        tmp))))
 611         (put-text-property
 612          bol (1+ bol) 'vc-cvs-annotate-time
 613          (setq cache (cons
 614                       ;; Position at end makes for nicer overlay result.
 615                       ;; Don't put actual buffer pos here, but only relative
 616                       ;; distance, so we don't ever move backward in the
 617                       ;; goto-char below, even if the text is moved.
 618                       (- (match-end 0) (match-beginning 0))
 619                       (vc-annotate-convert-time
 620                        (encode-time 0 0 0 day month year))))))))
 621     (when cache
 622       (goto-char (+ bol (car cache)))   ; Fontify from here to eol.
 623       (cdr cache))))                    ; days (float)
 624
 625 (defun vc-cvs-annotate-extract-revision-at-line ()
 626   (save-excursion
 627     (beginning-of-line)
 628     (if (re-search-forward "^\\([0-9]+\\.[0-9]+\\(\\.[0-9]+\\)*\\) +("
 629                            (line-end-position) t)
 630         (match-string-no-properties 1)
 631       nil)))
 632
 633 ;;;
 634 ;;; Tag system
 635 ;;;
 636
 637 (defun vc-cvs-create-tag (dir name branchp)
 638   "Assign to DIR's current revision a given NAME.
 639 If BRANCHP is non-nil, the name is created as a branch (and the current
 640 workspace is immediately moved to that new branch)."
 641   (vc-cvs-command nil 0 dir "tag" "-c" (if branchp "-b") name)
 642   (when branchp (vc-cvs-command nil 0 dir "update" "-r" name)))
 643
 644 (defun vc-cvs-retrieve-tag (dir name update)
 645   "Retrieve a tag at and below DIR.
 646 NAME is the name of the tag; if it is empty, do a `cvs update'.
 647 If UPDATE is non-nil, then update (resynch) any affected buffers."
 648   (with-current-buffer (get-buffer-create "*vc*")
 649     (let ((default-directory dir)
 650           (sticky-tag))
 651       (erase-buffer)
 652       (if (or (not name) (string= name ""))
 653           (vc-cvs-command t 0 nil "update")
 654         (vc-cvs-command t 0 nil "update" "-r" name)
 655         (setq sticky-tag name))
 656       (when update
 657         (goto-char (point-min))
 658         (while (not (eobp))
 659           (if (looking-at "\\([CMUP]\\) \\(.*\\)")
 660               (let* ((file (expand-file-name (match-string 2) dir))
 661                      (state (match-string 1))
 662                      (buffer (find-buffer-visiting file)))
 663                 (when buffer
 664                   (cond
 665                    ((or (string= state "U")
 666                         (string= state "P"))
 667                     (vc-file-setprop file 'vc-state 'up-to-date)
 668                     (vc-file-setprop file 'vc-working-revision nil)
 669                     (vc-file-setprop file 'vc-checkout-time
 670                                      (nth 5 (file-attributes file))))
 671                    ((or (string= state "M")
 672                         (string= state "C"))
 673                     (vc-file-setprop file 'vc-state 'edited)
 674                     (vc-file-setprop file 'vc-working-revision nil)
 675                     (vc-file-setprop file 'vc-checkout-time 0)))
 676                   (vc-file-setprop file 'vc-cvs-sticky-tag sticky-tag)
 677                   (vc-resynch-buffer file t t))))
 678           (forward-line 1))))))
 679
 680
 681 ;;;
 682 ;;; Miscellaneous
 683 ;;;
 684
 685 (defun vc-cvs-make-version-backups-p (file)
 686   "Return non-nil if version backups should be made for FILE."
 687   (vc-stay-local-p file 'CVS))
 688
 689 (defun vc-cvs-check-headers ()
 690   "Check if the current file has any headers in it."
 691   (save-excursion
 692     (goto-char (point-min))
 693     (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 694 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 695
 696
 697 ;;;
 698 ;;; Internal functions
 699 ;;;
 700
 701 (defun vc-cvs-command (buffer okstatus files &rest flags)
 702   "A wrapper around `vc-do-command' for use in vc-cvs.el.
 703 The difference to vc-do-command is that this function always invokes `cvs',
 704 and that it passes `vc-cvs-global-switches' to it before FLAGS."
 705   (apply 'vc-do-command (or buffer "*vc*") okstatus "cvs" files
 706          (if (stringp vc-cvs-global-switches)
 707              (cons vc-cvs-global-switches flags)
 708            (append vc-cvs-global-switches
 709                    flags))))
 710
 711 (defun vc-cvs-stay-local-p (file)  ;Back-compatibility.
 712   (vc-stay-local-p file 'CVS))
 713
 714 (defun vc-cvs-repository-hostname (dirname)
 715   "Hostname of the CVS server associated to workarea DIRNAME."
 716   (let ((rootname (expand-file-name "CVS/Root" dirname)))
 717     (when (file-readable-p rootname)
 718       (with-temp-buffer
 719         (let ((coding-system-for-read
 720                (or file-name-coding-system
 721                    default-file-name-coding-system)))
 722           (vc-insert-file rootname))
 723         (goto-char (point-min))
 724         (nth 2 (vc-cvs-parse-root
 725                 (buffer-substring (point)
 726                                   (line-end-position))))))))
 727
 728 (defun vc-cvs-parse-uhp (path)
 729   "parse user@host/path into (user@host /path)"
 730   (if (string-match "\\([^/]+\\)\\(/.*\\)" path)
 731       (list (match-string 1 path) (match-string 2 path))
 732       (list nil path)))
 733
 734 (defun vc-cvs-parse-root (root)
 735   "Split CVS ROOT specification string into a list of fields.
 736 A CVS root specification of the form
 737   [:METHOD:][[USER@]HOSTNAME]:?/path/to/repository
 738 is converted to a normalized record with the following structure:
 739   \(METHOD USER HOSTNAME CVS-ROOT).
 740 The default METHOD for a CVS root of the form
 741   /path/to/repository
 742 is `local'.
 743 The default METHOD for a CVS root of the form
 744   [USER@]HOSTNAME:/path/to/repository
 745 is `ext'.
 746 For an empty string, nil is returned (invalid CVS root)."
 747   ;; Split CVS root into colon separated fields (0-4).
 748   ;; The `x:' makes sure, that leading colons are not lost;
 749   ;; `HOST:/PATH' is then different from `:METHOD:/PATH'.
 750   (let* ((root-list (cdr (split-string (concat "x:" root) ":")))
 751          (len (length root-list))
 752          ;; All syntactic varieties will get a proper METHOD.
 753          (root-list
 754           (cond
 755            ((= len 0)
 756             ;; Invalid CVS root
 757             nil)
 758            ((= len 1)
 759             (let ((uhp (vc-cvs-parse-uhp (car root-list))))
 760               (cons (if (car uhp) "ext" "local") uhp)))
 761            ((= len 2)
 762             ;; [USER@]HOST:PATH => method `ext'
 763             (and (not (equal (car root-list) ""))
 764                  (cons "ext" root-list)))
 765            ((= len 3)
 766             ;; :METHOD:PATH or :METHOD:USER@HOSTNAME/PATH
 767             (cons (cadr root-list)
 768                   (vc-cvs-parse-uhp (caddr root-list))))
 769            (t
 770             ;; :METHOD:[USER@]HOST:PATH
 771             (cdr root-list)))))
 772     (if root-list
 773         (let ((method (car root-list))
 774               (uhost (or (cadr root-list) ""))
 775               (root (nth 2 root-list))
 776               user host)
 777           ;; Split USER@HOST
 778           (if (string-match "\\(.*\\)@\\(.*\\)" uhost)
 779               (setq user (match-string 1 uhost)
 780                     host (match-string 2 uhost))
 781             (setq host uhost))
 782           ;; Remove empty HOST
 783           (and (equal host "")
 784                (setq host))
 785           ;; Fix windows style CVS root `:local:C:\\project\\cvs\\some\\dir'
 786           (and host
 787                (equal method "local")
 788                (setq root (concat host ":" root) host))
 789           ;; Normalize CVS root record
 790           (list method user host root)))))
 791
 792 ;; XXX: This does not work correctly for subdirectories.  "cvs status"
 793 ;; information is context sensitive, it contains lines like:
 794 ;; cvs status: Examining DIRNAME
 795 ;; and the file entries after that don't show the full path.
 796 ;; Because of this VC directory listings only show changed files
 797 ;; at the top level for CVS.
 798 (defun vc-cvs-parse-status (&optional full)
 799   "Parse output of \"cvs status\" command in the current buffer.
 800 Set file properties accordingly.  Unless FULL is t, parse only
 801 essential information. Note that this can never set the 'ignored
 802 state."
 803   (let (file status missing)
 804     (goto-char (point-min))
 805     (while (looking-at "? \\(.*\\)")
 806       (setq file (expand-file-name (match-string 1)))
 807       (vc-file-setprop file 'vc-state 'unregistered)
 808       (forward-line 1))
 809     (when (re-search-forward "^File: " nil t)
 810       (when (setq missing (looking-at "no file "))
 811         (goto-char (match-end 0)))
 812       (cond
 813        ((re-search-forward "\\=\\([^ \t]+\\)" nil t)
 814         (setq file (expand-file-name (match-string 1)))
 815         (setq status(if (re-search-forward "\\=[ \t]+Status: \\(.*\\)" nil t)
 816                         (match-string 1) "Unknown"))
 817         (when (and full
 818                    (re-search-forward
 819                     "\\(RCS Version\\|RCS Revision\\|Repository revision\\):\
 820 \[\t ]+\\([0-9.]+\\)"
 821                     nil t))
 822             (vc-file-setprop file 'vc-latest-revision (match-string 2)))
 823         (vc-file-setprop
 824          file 'vc-state
 825          (cond
 826           ((string-match "Up-to-date" status)
 827            (vc-file-setprop file 'vc-checkout-time
 828                             (nth 5 (file-attributes file)))
 829            'up-to-date)
 830           ((string-match "Locally Modified" status)             'edited)
 831           ((string-match "Needs Merge" status)                  'needs-merge)
 832           ((string-match "Needs \\(Checkout\\|Patch\\)" status)
 833            (if missing 'missing 'needs-update))
 834           ((string-match "Locally Added" status)                'added)
 835           ((string-match "Locally Removed" status)              'removed)
 836           ((string-match "File had conflicts " status)          'conflict)
 837           ((string-match "Unknown" status)                      'unregistered)
 838           (t 'edited))))))))
 839
 840 (defun vc-cvs-after-dir-status (update-function)
 841   ;; Heavily inspired by vc-cvs-parse-status. AKA a quick hack.
 842   ;; This needs a lot of testing.
 843   (let ((status nil)
 844         (status-str nil)
 845         (file nil)
 846         (result nil)
 847         (missing nil)
 848         (ignore-next nil)
 849         (subdir default-directory))
 850     (goto-char (point-min))
 851     (while
 852         ;; Look for either a file entry, an unregistered file, or a
 853         ;; directory change.
 854         (re-search-forward
 855          "\\(^=+\n\\([^=c?\n].*\n\\|\n\\)+\\)\\|\\(\\(^?? .*\n\\)+\\)\\|\\(^cvs status: \\(Examining\\|nothing\\) .*\n\\)"
 856          nil t)
 857       ;; FIXME: get rid of narrowing here.
 858       (narrow-to-region (match-beginning 0) (match-end 0))
 859       (goto-char (point-min))
 860       ;; The subdir
 861       (when (looking-at "cvs status: Examining \\(.+\\)")
 862         (setq subdir (expand-file-name (match-string 1))))
 863       ;; Unregistered files
 864       (while (looking-at "? \\(.*\\)")
 865         (setq file (file-relative-name
 866                     (expand-file-name (match-string 1) subdir)))
 867         (push (list file 'unregistered) result)
 868         (forward-line 1))
 869       (when (looking-at "cvs status: nothing known about")
 870         ;; We asked about a non existent file.  The output looks like this:
 871
 872         ;; cvs status: nothing known about `lisp/v.diff'
 873         ;; ===================================================================
 874         ;; File: no file v.diff            Status: Unknown
 875         ;;
 876         ;;    Working revision:    No entry for v.diff
 877         ;;    Repository revision: No revision control file
 878         ;;
 879
 880         ;; Due to narrowing in this iteration we only see the "cvs
 881         ;; status:" line, so just set a flag so that we can ignore the
 882         ;; file in the next iteration.
 883         (setq ignore-next t))
 884       ;; A file entry.
 885       (when (re-search-forward "^File: \\(no file \\)?\\(.*[^ \t]\\)[ \t]+Status: \\(.*\\)" nil t)
 886         (setq missing (match-string 1))
 887         (setq file (file-relative-name
 888                     (expand-file-name (match-string 2) subdir)))
 889         (setq status-str (match-string 3))
 890         (setq status
 891               (cond
 892                ((string-match "Up-to-date" status-str) 'up-to-date)
 893                ((string-match "Locally Modified" status-str) 'edited)
 894                ((string-match "Needs Merge" status-str) 'needs-merge)
 895                ((string-match "Needs \\(Checkout\\|Patch\\)" status-str)
 896                 (if missing 'missing 'needs-update))
 897                ((string-match "Locally Added" status-str) 'added)
 898                ((string-match "Locally Removed" status-str) 'removed)
 899                ((string-match "File had conflicts " status-str) 'conflict)
 900                ((string-match "Unknown" status-str) 'unregistered)
 901                (t 'edited)))
 902         (if ignore-next
 903             (setq ignore-next nil)
 904           (unless (eq status 'up-to-date)
 905             (push (list file status) result))))
 906       (goto-char (point-max))
 907       (widen))
 908     (funcall update-function result))
 909   ;; Alternative implementation: use the "update" command instead of
 910   ;; the "status" command.
 911   ;; (let ((result nil)
 912   ;;    (translation '((?? . unregistered)
 913   ;;                   (?A . added)
 914   ;;                   (?C . conflict)
 915   ;;                   (?M . edited)
 916   ;;                   (?P . needs-merge)
 917   ;;                   (?R . removed)
 918   ;;                   (?U . needs-update))))
 919   ;;   (goto-char (point-min))
 920   ;;   (while (not (eobp))
 921   ;;     (if (looking-at "^[ACMPRU?] \\(.*\\)$")
 922   ;;      (push (list (match-string 1)
 923   ;;                  (cdr (assoc (char-after) translation)))
 924   ;;            result)
 925   ;;    (cond
 926   ;;     ((looking-at "cvs update: warning: \\(.*\\) was lost")
 927   ;;      ;; Format is:
 928   ;;      ;; cvs update: warning: FILENAME was lost
 929   ;;      ;; U FILENAME
 930   ;;      (push (list (match-string 1) 'missing) result)
 931   ;;      ;; Skip the "U" line
 932   ;;      (forward-line 1))
 933   ;;     ((looking-at "cvs update: New directory `\\(.*\\)' -- ignored")
 934   ;;      (push (list (match-string 1) 'unregistered) result))))
 935   ;;     (forward-line 1))
 936   ;;   (funcall update-function result)))
 937   )
 938
 939 ;; Based on vc-cvs-dir-state-heuristic from Emacs 22.
 940 (defun vc-cvs-dir-status-heuristic (dir update-function &optional basedir)
 941   "Find the CVS state of all files in DIR, using only local information."
 942   (let (file basename status result dirlist)
 943     (with-temp-buffer
 944       (vc-cvs-get-entries dir)
 945       (goto-char (point-min))
 946       (while (not (eobp))
 947         (if (looking-at "D/\\([^/]*\\)////")
 948             (push (expand-file-name (match-string 1) dir) dirlist)
 949           ;; CVS-removed files are not taken under VC control.
 950           (when (looking-at "/\\([^/]*\\)/[^/-]")
 951             (setq basename (match-string 1)
 952                   file (expand-file-name basename dir)
 953                   status (or (vc-file-getprop file 'vc-state)
 954                              (vc-cvs-parse-entry file t)))
 955             (unless (eq status 'up-to-date)
 956               (push (list (if basedir
 957                               (file-relative-name file basedir)
 958                             basename)
 959                           status) result))))
 960         (forward-line 1)))
 961     (dolist (subdir dirlist)
 962       (setq result (append result
 963                            (vc-cvs-dir-status-heuristic subdir nil
 964                                                         (or basedir dir)))))
 965     (if basedir result
 966       (funcall update-function result))))
 967
 968 (defun vc-cvs-dir-status (dir update-function)
 969   "Create a list of conses (file . state) for DIR."
 970   ;; FIXME check all files in DIR instead?
 971   (let ((local (vc-stay-local-p dir 'CVS)))
 972     (if (and local (not (eq local 'only-file)))
 973         (vc-cvs-dir-status-heuristic dir update-function)
 974       (vc-cvs-command (current-buffer) 'async dir "-f" "status")
 975       ;; Alternative implementation: use the "update" command instead of
 976       ;; the "status" command.
 977       ;; (vc-cvs-command (current-buffer) 'async
 978       ;;                  (file-relative-name dir)
 979       ;;                  "-f" "-n" "update" "-d" "-P")
 980       (vc-exec-after
 981        `(vc-cvs-after-dir-status (quote ,update-function))))))
 982
 983 (defun vc-cvs-dir-status-files (dir files default-state update-function)
 984   "Create a list of conses (file . state) for DIR."
 985   (apply 'vc-cvs-command (current-buffer) 'async dir "-f" "status" files)
 986   (vc-exec-after
 987    `(vc-cvs-after-dir-status (quote ,update-function))))
 988
 989 (defun vc-cvs-file-to-string (file)
 990   "Read the content of FILE and return it as a string."
 991   (condition-case nil
 992       (with-temp-buffer
 993         (insert-file-contents file)
 994         (goto-char (point-min))
 995         (buffer-substring (point) (point-max)))
 996     (file-error nil)))
 997
 998 (defun vc-cvs-dir-extra-headers (dir)
 999   "Extract and represent per-directory properties of a CVS working copy."
1000   (let ((repo
1001          (condition-case nil
1002              (with-temp-buffer
1003                (insert-file-contents "CVS/Root")
1004                (goto-char (point-min))
1005                (and (looking-at ":ext:") (delete-char 5))
1006                (concat (buffer-substring (point) (1- (point-max))) "\n"))
1007            (file-error nil)))
1008         (module
1009          (condition-case nil
1010              (with-temp-buffer
1011                (insert-file-contents "CVS/Repository")
1012                (goto-char (point-min))
1013                (skip-chars-forward "^\n")
1014                (concat (buffer-substring (point-min) (point)) "\n"))
1015            (file-error nil))))
1016     (concat
1017      (cond (repo
1018             (concat (propertize "Repository : " 'face 'font-lock-type-face)
1019                     (propertize repo 'face 'font-lock-variable-name-face)))
1020            (t ""))
1021      (cond (module
1022             (concat (propertize "Module     : " 'face 'font-lock-type-face)
1023                     (propertize module 'face 'font-lock-variable-name-face)))
1024            (t ""))
1025      (if (file-readable-p "CVS/Tag")
1026          (let ((tag (vc-cvs-file-to-string "CVS/Tag")))
1027            (cond
1028             ((string-match "\\`T" tag)
1029              (concat (propertize "Tag        : " 'face 'font-lock-type-face)
1030                      (propertize (substring tag 1)
1031                                  'face 'font-lock-variable-name-face)))
1032             ((string-match "\\`D" tag)
1033              (concat (propertize "Date       : " 'face 'font-lock-type-face)
1034                      (propertize (substring tag 1)
1035                                  'face 'font-lock-variable-name-face)))
1036             (t ""))))
1037
1038      ;; In CVS, branch is a per-file property, not a per-directory property.
1039      ;; We can't really do this here without making dangerous assumptions.
1040      ;;(propertize "Branch:     " 'face 'font-lock-type-face)
1041      ;;(propertize "ADD CODE TO PRINT THE BRANCH NAME\n"
1042      ;;  'face 'font-lock-warning-face)
1043      )))
1044
1045 (defun vc-cvs-get-entries (dir)
1046   "Insert the CVS/Entries file from below DIR into the current buffer.
1047 This function ensures that the correct coding system is used for that,
1048 which may not be the one that is used for the files' contents.
1049 CVS/Entries should only be accessed through this function."
1050   (let ((coding-system-for-read (or file-name-coding-system
1051                                     default-file-name-coding-system)))
1052     (vc-insert-file (expand-file-name "CVS/Entries" dir))))
1053
1054 (defun vc-cvs-valid-symbolic-tag-name-p (tag)
1055   "Return non-nil if TAG is a valid symbolic tag name."
1056   ;; According to the CVS manual, a valid symbolic tag must start with
1057   ;; an uppercase or lowercase letter and can contain uppercase and
1058   ;; lowercase letters, digits, `-', and `_'.
1059   (and (string-match "^[a-zA-Z]" tag)
1060        (not (string-match "[^a-z0-9A-Z-_]" tag))))
1061
1062 (defun vc-cvs-valid-revision-number-p (tag)
1063   "Return non-nil if TAG is a valid revision number."
1064   (and (string-match "^[0-9]" tag)
1065        (not (string-match "[^0-9.]" tag))))
1066
1067 (defun vc-cvs-parse-sticky-tag (match-type match-tag)
1068   "Parse and return the sticky tag as a string.
1069 `match-data' is protected."
1070   (let ((data (match-data))
1071         (tag)
1072         (type (cond ((string= match-type "D") 'date)
1073                     ((string= match-type "T")
1074                      (if (vc-cvs-valid-symbolic-tag-name-p match-tag)
1075                          'symbolic-name
1076                        'revision-number))
1077                     (t nil))))
1078     (unwind-protect
1079         (progn
1080           (cond
1081            ;; Sticky Date tag.  Convert to a proper date value (`encode-time')
1082            ((eq type 'date)
1083             (string-match
1084              "\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)"
1085              match-tag)
1086             (let* ((year-tmp (string-to-number (match-string 1 match-tag)))
1087                    (month    (string-to-number (match-string 2 match-tag)))
1088                    (day      (string-to-number (match-string 3 match-tag)))
1089                    (hour     (string-to-number (match-string 4 match-tag)))
1090                    (min      (string-to-number (match-string 5 match-tag)))
1091                    (sec      (string-to-number (match-string 6 match-tag)))
1092                    ;; Years 0..68 are 2000..2068.
1093                    ;; Years 69..99 are 1969..1999.
1094                    (year (+ (cond ((> 69 year-tmp) 2000)
1095                                   ((> 100 year-tmp) 1900)
1096                                   (t 0))
1097                             year-tmp)))
1098               (setq tag (encode-time sec min hour day month year))))
1099            ;; Sticky Tag name or revision number
1100            ((eq type 'symbolic-name) (setq tag match-tag))
1101            ((eq type 'revision-number) (setq tag match-tag))
1102            ;; Default is no sticky tag at all
1103            (t nil))
1104           (cond ((eq vc-cvs-sticky-tag-display nil) nil)
1105                 ((eq vc-cvs-sticky-tag-display t)
1106                  (cond ((eq type 'date) (format-time-string
1107                                          vc-cvs-sticky-date-format-string
1108                                          tag))
1109                        ((eq type 'symbolic-name) tag)
1110                        ((eq type 'revision-number) tag)
1111                        (t nil)))
1112                 ((functionp vc-cvs-sticky-tag-display)
1113                  (funcall vc-cvs-sticky-tag-display tag type))
1114                 (t nil)))
1115
1116       (set-match-data data))))
1117
1118 (defun vc-cvs-parse-entry (file &optional set-state)
1119   "Parse a line from CVS/Entries.
1120 Compare modification time to that of the FILE, set file properties
1121 accordingly.  However, `vc-state' is set only if optional arg SET-STATE
1122 is non-nil."
1123   (cond
1124    ;; entry for a "locally added" file (not yet committed)
1125    ((looking-at "/[^/]+/0/")
1126     (vc-file-setprop file 'vc-checkout-time 0)
1127     (vc-file-setprop file 'vc-working-revision "0")
1128     (if set-state (vc-file-setprop file 'vc-state 'added)))
1129    ;; normal entry
1130    ((looking-at
1131      (concat "/[^/]+"
1132              ;; revision
1133              "/\\([^/]*\\)"
1134              ;; timestamp and optional conflict field
1135              "/\\([^/]*\\)/"
1136              ;; options
1137              "\\([^/]*\\)/"
1138              ;; sticky tag
1139              "\\(.\\|\\)" ;Sticky tag type (date or tag name, could be empty)
1140              "\\(.*\\)"))               ;Sticky tag
1141     (vc-file-setprop file 'vc-working-revision (match-string 1))
1142     (vc-file-setprop file 'vc-cvs-sticky-tag
1143                      (vc-cvs-parse-sticky-tag (match-string 4)
1144                                               (match-string 5)))
1145     ;; Compare checkout time and modification time.
1146     ;; This is intentionally different from the algorithm that CVS uses
1147     ;; (which is based on textual comparison), because there can be problems
1148     ;; generating a time string that looks exactly like the one from CVS.
1149     (let ((mtime (nth 5 (file-attributes file))))
1150       (require 'parse-time)
1151       (let ((parsed-time
1152              (parse-time-string (concat (match-string 2) " +0000"))))
1153         (cond ((and (not (string-match "\\+" (match-string 2)))
1154                     (car parsed-time)
1155                     (equal mtime (apply 'encode-time parsed-time)))
1156                (vc-file-setprop file 'vc-checkout-time mtime)
1157                (if set-state (vc-file-setprop file 'vc-state 'up-to-date)))
1158               (t
1159                (vc-file-setprop file 'vc-checkout-time 0)
1160                (if set-state (vc-file-setprop file 'vc-state 'edited)))))))))
1161
1162 ;; Completion of revision names.
1163 ;; Just so I don't feel like I'm duplicating code from pcl-cvs, I'll use
1164 ;; `cvs log' so I can list all the revision numbers rather than only
1165 ;; tag names.
1166
1167 (defun vc-cvs-revision-table (file)
1168   (let ((default-directory (file-name-directory file))
1169         (res nil))
1170     (with-temp-buffer
1171       (vc-cvs-command t nil file "log")
1172       (goto-char (point-min))
1173       (when (re-search-forward "^symbolic names:\n" nil t)
1174         (while (looking-at "^   \\(.*\\): \\(.*\\)")
1175           (push (cons (match-string 1) (match-string 2)) res)
1176           (forward-line 1)))
1177       (while (re-search-forward "^revision \\([0-9.]+\\)" nil t)
1178         (push (match-string 1) res))
1179       res)))
1180
1181 (defun vc-cvs-revision-completion-table (files)
1182   (lexical-let ((files files)
1183                 table)
1184     (setq table (lazy-completion-table
1185                  table (lambda () (vc-cvs-revision-table (car files)))))
1186     table))
1187
1188
1189 (provide 'vc-cvs)
1190
1191 ;; arch-tag: 60e1402a-aa53-4607-927a-cf74f144b432
1192 ;;; vc-cvs.el ends here