lisp/outline.el

   1 ;;; outline.el --- outline mode commands for Emacs
   2
   3 ;; Copyright (C) 1986, 1993, 1994, 1995, 1997, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: outlines
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package is a major mode for editing outline-format documents.
  29 ;; An outline can be `abstracted' to show headers at any given level,
  30 ;; with all stuff below hidden.  See the Emacs manual for details.
  31
  32 ;;; Todo:
  33
  34 ;; - subtree-terminators
  35 ;; - better handle comments before function bodies (i.e. heading)
  36 ;; - don't bother hiding whitespace
  37
  38 ;;; Code:
  39
  40 (defvar font-lock-warning-face)
  41
  42
  43 (defgroup outlines nil
  44   "Support for hierarchical outlining."
  45   :prefix "outline-"
  46   :group 'editing)
  47
  48 (defcustom outline-regexp "[*\^L]+"
  49   "Regular expression to match the beginning of a heading.
  50 Any line whose beginning matches this regexp is considered to start a heading.
  51 Note that Outline mode only checks this regexp at the start of a line,
  52 so the regexp need not (and usually does not) start with `^'.
  53 The recommended way to set this is with a Local Variables: list
  54 in the file it applies to.  See also `outline-heading-end-regexp'."
  55   :type '(choice regexp (const nil))
  56   :group 'outlines)
  57 ;;;###autoload(put 'outline-regexp 'safe-local-variable 'string-or-null-p)
  58
  59 (defcustom outline-heading-end-regexp "\n"
  60   "Regular expression to match the end of a heading line.
  61 You can assume that point is at the beginning of a heading when this
  62 regexp is searched for.  The heading ends at the end of the match.
  63 The recommended way to set this is with a `Local Variables:' list
  64 in the file it applies to."
  65   :type 'regexp
  66   :group 'outlines)
  67
  68 (defvar outline-mode-prefix-map
  69   (let ((map (make-sparse-keymap)))
  70     (define-key map "@" 'outline-mark-subtree)
  71     (define-key map "\C-n" 'outline-next-visible-heading)
  72     (define-key map "\C-p" 'outline-previous-visible-heading)
  73     (define-key map "\C-i" 'show-children)
  74     (define-key map "\C-s" 'show-subtree)
  75     (define-key map "\C-d" 'hide-subtree)
  76     (define-key map "\C-u" 'outline-up-heading)
  77     (define-key map "\C-f" 'outline-forward-same-level)
  78     (define-key map "\C-b" 'outline-backward-same-level)
  79     (define-key map "\C-t" 'hide-body)
  80     (define-key map "\C-a" 'show-all)
  81     (define-key map "\C-c" 'hide-entry)
  82     (define-key map "\C-e" 'show-entry)
  83     (define-key map "\C-l" 'hide-leaves)
  84     (define-key map "\C-k" 'show-branches)
  85     (define-key map "\C-q" 'hide-sublevels)
  86     (define-key map "\C-o" 'hide-other)
  87     (define-key map "\C-^" 'outline-move-subtree-up)
  88     (define-key map "\C-v" 'outline-move-subtree-down)
  89     (define-key map [(control ?<)] 'outline-promote)
  90     (define-key map [(control ?>)] 'outline-demote)
  91     (define-key map "\C-m" 'outline-insert-heading)
  92     ;; Where to bind outline-cycle ?
  93     map))
  94
  95 (defvar outline-mode-menu-bar-map
  96   (let ((map (make-sparse-keymap)))
  97
  98     (define-key map [hide] (cons "Hide" (make-sparse-keymap "Hide")))
  99
 100     (define-key map [hide hide-other] '("Hide Other" . hide-other))
 101     (define-key map [hide hide-sublevels] '("Hide Sublevels" . hide-sublevels))
 102     (define-key map [hide hide-subtree] '("Hide Subtree" . hide-subtree))
 103     (define-key map [hide hide-entry] '("Hide Entry" . hide-entry))
 104     (define-key map [hide hide-body] '("Hide Body" . hide-body))
 105     (define-key map [hide hide-leaves] '("Hide Leaves" . hide-leaves))
 106
 107     (define-key map [show] (cons "Show" (make-sparse-keymap "Show")))
 108
 109     (define-key map [show show-subtree] '("Show Subtree" . show-subtree))
 110     (define-key map [show show-children] '("Show Children" . show-children))
 111     (define-key map [show show-branches] '("Show Branches" . show-branches))
 112     (define-key map [show show-entry] '("Show Entry" . show-entry))
 113     (define-key map [show show-all] '("Show All" . show-all))
 114
 115     (define-key map [headings]
 116       (cons "Headings" (make-sparse-keymap "Headings")))
 117
 118     (define-key map [headings demote-subtree]
 119       '(menu-item "Demote subtree" outline-demote))
 120     (define-key map [headings promote-subtree]
 121       '(menu-item "Promote subtree" outline-promote))
 122     (define-key map [headings move-subtree-down]
 123       '(menu-item "Move subtree down" outline-move-subtree-down))
 124     (define-key map [headings move-subtree-up]
 125       '(menu-item "Move subtree up" outline-move-subtree-up))
 126     (define-key map [headings copy]
 127       '(menu-item "Copy to kill ring" outline-headers-as-kill
 128         :enable mark-active))
 129     (define-key map [headings outline-insert-heading]
 130       '("New heading" . outline-insert-heading))
 131     (define-key map [headings outline-backward-same-level]
 132       '("Previous Same Level" . outline-backward-same-level))
 133     (define-key map [headings outline-forward-same-level]
 134       '("Next Same Level" . outline-forward-same-level))
 135     (define-key map [headings outline-previous-visible-heading]
 136       '("Previous" . outline-previous-visible-heading))
 137     (define-key map [headings outline-next-visible-heading]
 138       '("Next" . outline-next-visible-heading))
 139     (define-key map [headings outline-up-heading]
 140       '("Up" . outline-up-heading))
 141     map))
 142
 143 (defvar outline-minor-mode-menu-bar-map
 144   (let ((map (make-sparse-keymap)))
 145     (define-key map [outline]
 146       (cons "Outline"
 147             (nconc (make-sparse-keymap "Outline")
 148                    ;; Remove extra separator
 149                    (cdr
 150                     ;; Flatten the major mode's menus into a single menu.
 151                     (apply 'append
 152                            (mapcar (lambda (x)
 153                                      (if (consp x)
 154                                          ;; Add a separator between each
 155                                          ;; part of the unified menu.
 156                                          (cons '(--- "---") (cdr x))))
 157                                    outline-mode-menu-bar-map))))))
 158     map))
 159
 160
 161 (defvar outline-mode-map
 162   (let ((map (make-sparse-keymap)))
 163     (define-key map "\C-c" outline-mode-prefix-map)
 164     (define-key map [menu-bar] outline-mode-menu-bar-map)
 165     map))
 166
 167 (defvar outline-font-lock-keywords
 168   '(;;
 169     ;; Highlight headings according to the level.
 170     (eval . (list (concat "^\\(?:" outline-regexp "\\).+")
 171                   0 '(outline-font-lock-face) nil t)))
 172   "Additional expressions to highlight in Outline mode.")
 173
 174 (defface outline-1
 175   '((t :inherit font-lock-function-name-face))
 176   "Level 1."
 177   :group 'outlines)
 178
 179 (defface outline-2
 180   '((t :inherit font-lock-variable-name-face))
 181   "Level 2."
 182   :group 'outlines)
 183
 184 (defface outline-3
 185   '((t :inherit font-lock-keyword-face))
 186   "Level 3."
 187   :group 'outlines)
 188
 189 (defface outline-4
 190   '((t :inherit font-lock-comment-face))
 191   "Level 4."
 192   :group 'outlines)
 193
 194 (defface outline-5
 195   '((t :inherit font-lock-type-face))
 196   "Level 5."
 197   :group 'outlines)
 198
 199 (defface outline-6
 200   '((t :inherit font-lock-constant-face))
 201   "Level 6."
 202   :group 'outlines)
 203
 204 (defface outline-7
 205   '((t :inherit font-lock-builtin-face))
 206   "Level 7."
 207   :group 'outlines)
 208
 209 (defface outline-8
 210   '((t :inherit font-lock-string-face))
 211   "Level 8."
 212   :group 'outlines)
 213
 214 (defvar outline-font-lock-faces
 215   [outline-1 outline-2 outline-3 outline-4
 216    outline-5 outline-6 outline-7 outline-8])
 217
 218 ;; (defvar outline-font-lock-levels nil)
 219 ;; (make-variable-buffer-local 'outline-font-lock-levels)
 220
 221 (defun outline-font-lock-face ()
 222   ;; (save-excursion
 223   ;;   (outline-back-to-heading t)
 224   ;;   (let* ((count 0)
 225   ;;       (start-level (funcall outline-level))
 226   ;;       (level start-level)
 227   ;;       face-level)
 228   ;;     (while (not (setq face-level
 229   ;;                    (if (or (bobp) (eq level 1)) 0
 230   ;;                      (cdr (assq level outline-font-lock-levels)))))
 231   ;;    (outline-up-heading 1 t)
 232   ;;    (setq count (1+ count))
 233   ;;    (setq level (funcall outline-level)))
 234   ;;     ;; Remember for later.
 235   ;;     (unless (zerop count)
 236   ;;    (setq face-level (+ face-level count))
 237   ;;    (push (cons start-level face-level) outline-font-lock-levels))
 238   ;;     (condition-case nil
 239   ;;      (aref outline-font-lock-faces face-level)
 240   ;;    (error font-lock-warning-face))))
 241   (save-excursion
 242     (goto-char (match-beginning 0))
 243     (looking-at outline-regexp)
 244     (aref outline-font-lock-faces (% (1- (funcall outline-level)) (length outline-font-lock-faces)))))
 245
 246 (defvar outline-view-change-hook nil
 247   "Normal hook to be run after outline visibility changes.")
 248
 249 (defvar outline-mode-hook nil
 250   "*This hook is run when outline mode starts.")
 251
 252 (defvar outline-blank-line nil
 253   "*Non-nil means to leave unhidden blank line before heading.")
 254
 255 ;;;###autoload
 256 (define-derived-mode outline-mode text-mode "Outline"
 257   "Set major mode for editing outlines with selective display.
 258 Headings are lines which start with asterisks: one for major headings,
 259 two for subheadings, etc.  Lines not starting with asterisks are body lines.
 260
 261 Body text or subheadings under a heading can be made temporarily
 262 invisible, or visible again.  Invisible lines are attached to the end
 263 of the heading, so they move with it, if the line is killed and yanked
 264 back.  A heading with text hidden under it is marked with an ellipsis (...).
 265
 266 Commands:\\<outline-mode-map>
 267 \\[outline-next-visible-heading]   outline-next-visible-heading      move by visible headings
 268 \\[outline-previous-visible-heading]   outline-previous-visible-heading
 269 \\[outline-forward-same-level]   outline-forward-same-level        similar but skip subheadings
 270 \\[outline-backward-same-level]   outline-backward-same-level
 271 \\[outline-up-heading]   outline-up-heading                 move from subheading to heading
 272
 273 \\[hide-body]   make all text invisible (not headings).
 274 \\[show-all]    make everything in buffer visible.
 275 \\[hide-sublevels]  make only the first N levels of headers visible.
 276
 277 The remaining commands are used when point is on a heading line.
 278 They apply to some of the body or subheadings of that heading.
 279 \\[hide-subtree]   hide-subtree make body and subheadings invisible.
 280 \\[show-subtree]   show-subtree make body and subheadings visible.
 281 \\[show-children]   show-children       make direct subheadings visible.
 282                  No effect on body, or subheadings 2 or more levels down.
 283                  With arg N, affects subheadings N levels down.
 284 \\[hide-entry]     make immediately following body invisible.
 285 \\[show-entry]     make it visible.
 286 \\[hide-leaves]    make body under heading and under its subheadings invisible.
 287                      The subheadings remain visible.
 288 \\[show-branches]  make all subheadings at all levels visible.
 289
 290 The variable `outline-regexp' can be changed to control what is a heading.
 291 A line is a heading if `outline-regexp' matches something at the
 292 beginning of the line.  The longer the match, the deeper the level.
 293
 294 Turning on outline mode calls the value of `text-mode-hook' and then of
 295 `outline-mode-hook', if they are non-nil."
 296   (make-local-variable 'line-move-ignore-invisible)
 297   (setq line-move-ignore-invisible t)
 298   ;; Cause use of ellipses for invisible text.
 299   (add-to-invisibility-spec '(outline . t))
 300   (set (make-local-variable 'paragraph-start)
 301        (concat paragraph-start "\\|\\(?:" outline-regexp "\\)"))
 302   ;; Inhibit auto-filling of header lines.
 303   (set (make-local-variable 'auto-fill-inhibit-regexp) outline-regexp)
 304   (set (make-local-variable 'paragraph-separate)
 305        (concat paragraph-separate "\\|\\(?:" outline-regexp "\\)"))
 306   (set (make-local-variable 'font-lock-defaults)
 307        '(outline-font-lock-keywords t nil nil backward-paragraph))
 308   (setq imenu-generic-expression
 309         (list (list nil (concat "^\\(?:" outline-regexp "\\).*$") 0)))
 310   (add-hook 'change-major-mode-hook 'show-all nil t))
 311
 312 (defcustom outline-minor-mode-prefix "\C-c@"
 313   "*Prefix key to use for Outline commands in Outline minor mode.
 314 The value of this variable is checked as part of loading Outline mode.
 315 After that, changing the prefix key requires manipulating keymaps."
 316   :type 'string
 317   :group 'outlines)
 318
 319 ;;;###autoload
 320 (define-minor-mode outline-minor-mode
 321   "Toggle Outline minor mode.
 322 With arg, turn Outline minor mode on if arg is positive, off otherwise.
 323 See the command `outline-mode' for more information on this mode."
 324   nil " Outl" (list (cons [menu-bar] outline-minor-mode-menu-bar-map)
 325                     (cons outline-minor-mode-prefix outline-mode-prefix-map))
 326   :group 'outlines
 327   (if outline-minor-mode
 328       (progn
 329         ;; Turn off this mode if we change major modes.
 330         (add-hook 'change-major-mode-hook
 331                   (lambda () (outline-minor-mode -1))
 332                   nil t)
 333         (set (make-local-variable 'line-move-ignore-invisible) t)
 334         ;; Cause use of ellipses for invisible text.
 335         (add-to-invisibility-spec '(outline . t)))
 336     (setq line-move-ignore-invisible nil)
 337     ;; Cause use of ellipses for invisible text.
 338     (remove-from-invisibility-spec '(outline . t))
 339     ;; When turning off outline mode, get rid of any outline hiding.
 340     (show-all)))
 341 \f
 342 (defvar outline-level 'outline-level
 343   "*Function of no args to compute a header's nesting level in an outline.
 344 It can assume point is at the beginning of a header line and that the match
 345 data reflects the `outline-regexp'.")
 346
 347 (defvar outline-heading-alist ()
 348   "Alist associating a heading for every possible level.
 349 Each entry is of the form (HEADING . LEVEL).
 350 This alist is used two ways: to find the heading corresponding to
 351 a given level and to find the level of a given heading.
 352 If a mode or document needs several sets of outline headings (for example
 353 numbered and unnumbered sections), list them set by set and sorted by level
 354 within each set.  For example in texinfo mode:
 355
 356      (setq outline-heading-alist
 357       '((\"@chapter\" . 2) (\"@section\" . 3) (\"@subsection\" . 4)
 358            (\"@subsubsection\" . 5)
 359         (\"@unnumbered\" . 2) (\"@unnumberedsec\" . 3)
 360            (\"@unnumberedsubsec\" . 4)  (\"@unnumberedsubsubsec\" . 5)
 361         (\"@appendix\" . 2) (\"@appendixsec\" . 3)...
 362            (\"@appendixsubsec\" . 4) (\"@appendixsubsubsec\" . 5) ..))
 363
 364 Instead of sorting the entries in each set, you can also separate the
 365 sets with nil.")
 366 (make-variable-buffer-local 'outline-heading-alist)
 367
 368 ;; This used to count columns rather than characters, but that made ^L
 369 ;; appear to be at level 2 instead of 1.  Columns would be better for
 370 ;; tab handling, but the default regexp doesn't use tabs, and anyone
 371 ;; who changes the regexp can also redefine the outline-level variable
 372 ;; as appropriate.
 373 (defun outline-level ()
 374   "Return the depth to which a statement is nested in the outline.
 375 Point must be at the beginning of a header line.
 376 This is actually either the level specified in `outline-heading-alist'
 377 or else the number of characters matched by `outline-regexp'."
 378   (or (cdr (assoc (match-string 0) outline-heading-alist))
 379       (- (match-end 0) (match-beginning 0))))
 380
 381 (defun outline-next-preface ()
 382   "Skip forward to just before the next heading line.
 383 If there's no following heading line, stop before the newline
 384 at the end of the buffer."
 385   (if (re-search-forward (concat "\n\\(?:" outline-regexp "\\)")
 386                          nil 'move)
 387       (goto-char (match-beginning 0)))
 388   (if (and (bolp) (or outline-blank-line (eobp)) (not (bobp)))
 389       (forward-char -1)))
 390
 391 (defun outline-next-heading ()
 392   "Move to the next (possibly invisible) heading line."
 393   (interactive)
 394   ;; Make sure we don't match the heading we're at.
 395   (if (and (bolp) (not (eobp))) (forward-char 1))
 396   (if (re-search-forward (concat "^\\(?:" outline-regexp "\\)")
 397                          nil 'move)
 398       (goto-char (match-beginning 0))))
 399
 400 (defun outline-previous-heading ()
 401   "Move to the previous (possibly invisible) heading line."
 402   (interactive)
 403   (re-search-backward (concat "^\\(?:" outline-regexp "\\)")
 404                       nil 'move))
 405
 406 (defsubst outline-invisible-p (&optional pos)
 407   "Non-nil if the character after point is invisible."
 408   (get-char-property (or pos (point)) 'invisible))
 409
 410 (defun outline-visible ()
 411   (not (outline-invisible-p)))
 412 (make-obsolete 'outline-visible 'outline-invisible-p)
 413
 414 (defun outline-back-to-heading (&optional invisible-ok)
 415   "Move to previous heading line, or beg of this line if it's a heading.
 416 Only visible heading lines are considered, unless INVISIBLE-OK is non-nil."
 417   (beginning-of-line)
 418   (or (outline-on-heading-p invisible-ok)
 419       (let (found)
 420         (save-excursion
 421           (while (not found)
 422             (or (re-search-backward (concat "^\\(?:" outline-regexp "\\)")
 423                                     nil t)
 424                 (error "before first heading"))
 425             (setq found (and (or invisible-ok (not (outline-invisible-p)))
 426                              (point)))))
 427         (goto-char found)
 428         found)))
 429
 430 (defun outline-on-heading-p (&optional invisible-ok)
 431   "Return t if point is on a (visible) heading line.
 432 If INVISIBLE-OK is non-nil, an invisible heading line is ok too."
 433   (save-excursion
 434     (beginning-of-line)
 435     (and (bolp) (or invisible-ok (not (outline-invisible-p)))
 436          (looking-at outline-regexp))))
 437
 438 (defun outline-insert-heading ()
 439   "Insert a new heading at same depth at point."
 440   (interactive)
 441   (let ((head (save-excursion
 442                 (condition-case nil
 443                     (outline-back-to-heading)
 444                   (error (outline-next-heading)))
 445                 (if (eobp)
 446                     (or (caar outline-heading-alist) "")
 447                   (match-string 0)))))
 448     (unless (or (string-match "[ \t]\\'" head)
 449                 (not (string-match (concat "\\`\\(?:" outline-regexp "\\)")
 450                                    (concat head " "))))
 451       (setq head (concat head " ")))
 452     (unless (bolp) (end-of-line) (newline))
 453     (insert head)
 454     (unless (eolp)
 455       (save-excursion (newline-and-indent)))
 456     (run-hooks 'outline-insert-heading-hook)))
 457
 458 (defun outline-invent-heading (head up)
 459   (save-match-data
 460     ;; Let's try to invent one by repeating or deleting the last char.
 461     (let ((new-head (if up (substring head 0 -1)
 462                       (concat head (substring head -1)))))
 463       (if (string-match (concat "\\`\\(?:" outline-regexp "\\)")
 464                         new-head)
 465           ;; Why bother checking that it is indeed higher/lower level ?
 466           new-head
 467         ;; Didn't work, so ask what to do.
 468         (read-string (format "%s heading for `%s': "
 469                              (if up "Parent" "Demoted") head)
 470                      head nil nil t)))))
 471
 472 (defun outline-promote (&optional which)
 473   "Promote headings higher up the tree.
 474 If transient-mark-mode is on, and mark is active, promote headings in
 475 the region (from a Lisp program, pass `region' for WHICH).  Otherwise:
 476 without prefix argument, promote current heading and all headings in the
 477 subtree (from a Lisp program, pass `subtree' for WHICH); with prefix
 478 argument, promote just the current heading (from a Lisp program, pass
 479 nil for WHICH, or do not pass any argument)."
 480   (interactive
 481    (list (if (and transient-mark-mode mark-active) 'region
 482            (outline-back-to-heading)
 483            (if current-prefix-arg nil 'subtree))))
 484   (cond
 485    ((eq which 'region)
 486     (outline-map-region 'outline-promote (region-beginning) (region-end)))
 487    (which
 488     (outline-map-region 'outline-promote
 489                         (point)
 490                         (save-excursion (outline-get-next-sibling) (point))))
 491    (t
 492     (outline-back-to-heading t)
 493     (let* ((head (match-string-no-properties 0))
 494            (level (save-match-data (funcall outline-level)))
 495            (up-head (or (outline-head-from-level (1- level) head)
 496                         ;; Use the parent heading, if it is really
 497                         ;; one level less.
 498                         (save-excursion
 499                           (save-match-data
 500                             (outline-up-heading 1 t)
 501                             (and (= (1- level) (funcall outline-level))
 502                                  (match-string-no-properties 0))))
 503                         ;; Bummer!! There is no lower level heading.
 504                         (outline-invent-heading head 'up))))
 505
 506       (unless (rassoc level outline-heading-alist)
 507         (push (cons head level) outline-heading-alist))
 508
 509       (replace-match up-head nil t)))))
 510
 511 (defun outline-demote (&optional which)
 512   "Demote headings lower down the tree.
 513 If transient-mark-mode is on, and mark is active, demote headings in
 514 the region (from a Lisp program, pass `region' for WHICH).  Otherwise:
 515 without prefix argument, demote current heading and all headings in the
 516 subtree (from a Lisp program, pass `subtree' for WHICH); with prefix
 517 argument, demote just the current heading (from a Lisp program, pass
 518 nil for WHICH, or do not pass any argument)."
 519   (interactive
 520    (list (if (and transient-mark-mode mark-active) 'region
 521            (outline-back-to-heading)
 522            (if current-prefix-arg nil 'subtree))))
 523   (cond
 524    ((eq which 'region)
 525     (outline-map-region 'outline-demote (region-beginning) (region-end)))
 526    (which
 527     (outline-map-region 'outline-demote
 528                         (point)
 529                         (save-excursion (outline-get-next-sibling) (point))))
 530    (t
 531     (let* ((head (match-string-no-properties 0))
 532            (level (save-match-data (funcall outline-level)))
 533            (down-head
 534             (or (outline-head-from-level (1+ level) head)
 535                 (save-excursion
 536                   (save-match-data
 537                     (while (and (progn (outline-next-heading) (not (eobp)))
 538                                 (<= (funcall outline-level) level)))
 539                     (when (eobp)
 540                       ;; Try again from the beginning of the buffer.
 541                       (goto-char (point-min))
 542                       (while (and (progn (outline-next-heading) (not (eobp)))
 543                                   (<= (funcall outline-level) level))))
 544                     (unless (eobp)
 545                       (looking-at outline-regexp)
 546                       (match-string-no-properties 0))))
 547                 ;; Bummer!! There is no higher-level heading in the buffer.
 548                 (outline-invent-heading head nil))))
 549
 550       (unless (rassoc level outline-heading-alist)
 551         (push (cons head level) outline-heading-alist))
 552       (replace-match down-head nil t)))))
 553
 554 (defun outline-head-from-level (level head &optional alist)
 555   "Get new heading with level LEVEL from ALIST.
 556 If there are no such entries, return nil.
 557 ALIST defaults to `outline-heading-alist'.
 558 Similar to (car (rassoc LEVEL ALIST)).
 559 If there are several different entries with same new level, choose
 560 the one with the smallest distance to the assocation of HEAD in the alist.
 561 This makes it possible for promotion to work in modes with several
 562 independent sets of headings (numbered, unnumbered, appendix...)"
 563   (unless alist (setq alist outline-heading-alist))
 564   (let ((l (rassoc level alist))
 565         ll h hl l2 l2l)
 566     (cond
 567      ((null l) nil)
 568      ;; If there's no HEAD after L, any other entry for LEVEL after L
 569      ;; can't be much better than L.
 570      ((null (setq h (assoc head (setq ll (memq l alist))))) (car l))
 571      ;; If there's no other entry for LEVEL, just keep L.
 572      ((null (setq l2 (rassoc level (cdr ll)))) (car l))
 573      ;; Now we have L, L2, and H: see if L2 seems better than L.
 574      ;; If H is after L2, L2 is better.
 575      ((memq h (setq l2l (memq l2 (cdr ll))))
 576       (outline-head-from-level level head l2l))
 577      ;; Now we have H between L and L2.
 578      ;; If there's a separator between L and H, prefer L2.
 579      ((memq h (memq nil ll))
 580       (outline-head-from-level level head l2l))
 581      ;; If there's a separator between L2 and H, prefer L.
 582      ((memq l2 (memq nil (setq hl (memq h ll)))) (car l))
 583      ;; No separator between L and L2, check the distance.
 584      ((< (* 2 (length hl)) (+ (length ll) (length l2l)))
 585       (outline-head-from-level level head l2l))
 586      ;; If all else fails, just keep L.
 587      (t (car l)))))
 588
 589 (defun outline-map-region (fun beg end)
 590   "Call FUN for every heading between BEG and END.
 591 When FUN is called, point is at the beginning of the heading and
 592 the match data is set appropriately."
 593   (save-excursion
 594     (setq end (copy-marker end))
 595     (goto-char beg)
 596     (when (re-search-forward (concat "^\\(?:" outline-regexp "\\)") end t)
 597       (goto-char (match-beginning 0))
 598       (funcall fun)
 599       (while (and (progn
 600                     (outline-next-heading)
 601                     (< (point) end))
 602                   (not (eobp)))
 603         (funcall fun)))))
 604
 605 ;; Vertical tree motion
 606
 607 (defun outline-move-subtree-up (&optional arg)
 608   "Move the currrent subtree up past ARG headlines of the same level."
 609   (interactive "p")
 610   (outline-move-subtree-down (- arg)))
 611
 612 (defun outline-move-subtree-down (&optional arg)
 613   "Move the currrent subtree down past ARG headlines of the same level."
 614   (interactive "p")
 615   (let ((movfunc (if (> arg 0) 'outline-get-next-sibling
 616                    'outline-get-last-sibling))
 617         (ins-point (make-marker))
 618         (cnt (abs arg))
 619         beg end folded)
 620     ;; Select the tree
 621     (outline-back-to-heading)
 622     (setq beg (point))
 623     (save-match-data
 624       (save-excursion (outline-end-of-heading)
 625                       (setq folded (outline-invisible-p)))
 626       (outline-end-of-subtree))
 627     (if (= (char-after) ?\n) (forward-char 1))
 628     (setq end (point))
 629     ;; Find insertion point, with error handling
 630     (goto-char beg)
 631     (while (> cnt 0)
 632       (or (funcall movfunc)
 633           (progn (goto-char beg)
 634                  (error "Cannot move past superior level")))
 635       (setq cnt (1- cnt)))
 636     (if (> arg 0)
 637         ;; Moving forward - still need to move over subtree
 638         (progn (outline-end-of-subtree)
 639                (if (= (char-after) ?\n) (forward-char 1))))
 640     (move-marker ins-point (point))
 641     (insert (delete-and-extract-region beg end))
 642     (goto-char ins-point)
 643     (if folded (hide-subtree))
 644     (move-marker ins-point nil)))
 645
 646 (defun outline-end-of-heading ()
 647   (if (re-search-forward outline-heading-end-regexp nil 'move)
 648       (forward-char -1)))
 649
 650 (defun outline-next-visible-heading (arg)
 651   "Move to the next visible heading line.
 652 With argument, repeats or can move backward if negative.
 653 A heading line is one that starts with a `*' (or that
 654 `outline-regexp' matches)."
 655   (interactive "p")
 656   (if (< arg 0)
 657       (beginning-of-line)
 658     (end-of-line))
 659   (let (found-heading-p)
 660     (while (and (not (bobp)) (< arg 0))
 661       (while (and (not (bobp))
 662                   (setq found-heading-p
 663                         (re-search-backward
 664                          (concat "^\\(?:" outline-regexp "\\)")
 665                          nil 'move))
 666                   (outline-invisible-p)))
 667       (setq arg (1+ arg)))
 668     (while (and (not (eobp)) (> arg 0))
 669       (while (and (not (eobp))
 670                   (setq found-heading-p
 671                         (re-search-forward
 672                          (concat "^\\(?:" outline-regexp "\\)")
 673                          nil 'move))
 674                   (outline-invisible-p (match-beginning 0))))
 675       (setq arg (1- arg)))
 676     (if found-heading-p (beginning-of-line))))
 677
 678 (defun outline-previous-visible-heading (arg)
 679   "Move to the previous heading line.
 680 With argument, repeats or can move forward if negative.
 681 A heading line is one that starts with a `*' (or that
 682 `outline-regexp' matches)."
 683   (interactive "p")
 684   (outline-next-visible-heading (- arg)))
 685
 686 (defun outline-mark-subtree ()
 687   "Mark the current subtree in an outlined document.
 688 This puts point at the start of the current subtree, and mark at the end."
 689   (interactive)
 690   (let ((beg))
 691     (if (outline-on-heading-p)
 692         ;; we are already looking at a heading
 693         (beginning-of-line)
 694       ;; else go back to previous heading
 695       (outline-previous-visible-heading 1))
 696     (setq beg (point))
 697     (outline-end-of-subtree)
 698     (push-mark (point) nil t)
 699     (goto-char beg)))
 700 \f
 701
 702 (defvar outline-isearch-open-invisible-function nil
 703   "Function called if `isearch' finishes in an invisible overlay.
 704 The function is called with the overlay as its only argument.
 705 If nil, `show-entry' is called to reveal the invisible text.")
 706
 707 (put 'outline 'reveal-toggle-invisible 'outline-reveal-toggle-invisible)
 708 (defun outline-flag-region (from to flag)
 709   "Hide or show lines from FROM to TO, according to FLAG.
 710 If FLAG is nil then text is shown, while if FLAG is t the text is hidden."
 711   (remove-overlays from to 'invisible 'outline)
 712   (when flag
 713     ;; We use `front-advance' here because the invisible text begins at the
 714     ;; very end of the heading, before the newline, so text inserted at FROM
 715     ;; belongs to the heading rather than to the entry.
 716     (let ((o (make-overlay from to nil 'front-advance)))
 717       (overlay-put o 'invisible 'outline)
 718       (overlay-put o 'isearch-open-invisible
 719                    (or outline-isearch-open-invisible-function
 720                        'outline-isearch-open-invisible))))
 721   ;; Seems only used by lazy-lock.  I.e. obsolete.
 722   (run-hooks 'outline-view-change-hook))
 723
 724 (defun outline-reveal-toggle-invisible (o hidep)
 725   (save-excursion
 726     (goto-char (overlay-start o))
 727     (if hidep
 728         ;; When hiding the area again, we could just clean it up and let
 729         ;; reveal do the rest, by simply doing:
 730         ;; (remove-overlays (overlay-start o) (overlay-end o)
 731         ;;                  'invisible 'outline)
 732         ;;
 733         ;; That works fine as long as everything is in sync, but if the
 734         ;; structure of the document is changed while revealing parts of it,
 735         ;; the resulting behavior can be ugly.  I.e. we need to make
 736         ;; sure that we hide exactly a subtree.
 737         (progn
 738           (let ((end (overlay-end o)))
 739             (delete-overlay o)
 740             (while (progn
 741                      (hide-subtree)
 742                      (outline-next-visible-heading 1)
 743                      (and (not (eobp)) (< (point) end))))))
 744
 745       ;; When revealing, we just need to reveal sublevels.  If point is
 746       ;; inside one of the sublevels, reveal will call us again.
 747       ;; But we need to preserve the original overlay.
 748       (let ((o1 (copy-overlay o)))
 749         (overlay-put o 'invisible nil)  ;Show (most of) the text.
 750         (while (progn
 751                  (show-entry)
 752                  (show-children)
 753                  ;; Normally just the above is needed.
 754                  ;; But in odd cases, the above might fail to show anything.
 755                  ;; To avoid an infinite loop, we have to make sure that
 756                  ;; *something* gets shown.
 757                  (and (equal (overlay-start o) (overlay-start o1))
 758                       (< (point) (overlay-end o))
 759                       (= 0 (forward-line 1)))))
 760         ;; If still nothing was shown, just kill the damn thing.
 761         (when (equal (overlay-start o) (overlay-start o1))
 762           ;; I've seen it happen at the end of buffer.
 763           (delete-overlay o1))))))
 764
 765 ;; Function to be set as an outline-isearch-open-invisible' property
 766 ;; to the overlay that makes the outline invisible (see
 767 ;; `outline-flag-region').
 768 (defun outline-isearch-open-invisible (overlay)
 769   ;; We rely on the fact that isearch places point on the matched text.
 770   (show-entry))
 771 \f
 772 (defun hide-entry ()
 773   "Hide the body directly following this heading."
 774   (interactive)
 775   (save-excursion
 776     (outline-back-to-heading)
 777     (outline-end-of-heading)
 778     (outline-flag-region (point) (progn (outline-next-preface) (point)) t)))
 779
 780 (defun show-entry ()
 781   "Show the body directly following this heading.
 782 Show the heading too, if it is currently invisible."
 783   (interactive)
 784   (save-excursion
 785     (outline-back-to-heading t)
 786     (outline-flag-region (1- (point))
 787                          (progn (outline-next-preface) (point)) nil)))
 788
 789 (defun hide-body ()
 790   "Hide all body lines in buffer, leaving all headings visible."
 791   (interactive)
 792   (hide-region-body (point-min) (point-max)))
 793
 794 (defun hide-region-body (start end)
 795   "Hide all body lines in the region, but not headings."
 796   ;; Nullify the hook to avoid repeated calls to `outline-flag-region'
 797   ;; wasting lots of time running `lazy-lock-fontify-after-outline'
 798   ;; and run the hook finally.
 799   (let (outline-view-change-hook)
 800     (save-excursion
 801       (save-restriction
 802         (narrow-to-region start end)
 803         (goto-char (point-min))
 804         (if (outline-on-heading-p)
 805             (outline-end-of-heading)
 806           (outline-next-preface))
 807         (while (not (eobp))
 808           (outline-flag-region (point)
 809                                (progn (outline-next-preface) (point)) t)
 810           (unless (eobp)
 811             (forward-char (if (looking-at "\n\n") 2 1))
 812             (outline-end-of-heading))))))
 813   (run-hooks 'outline-view-change-hook))
 814
 815 (defun show-all ()
 816   "Show all of the text in the buffer."
 817   (interactive)
 818   (outline-flag-region (point-min) (point-max) nil))
 819
 820 (defun hide-subtree ()
 821   "Hide everything after this heading at deeper levels."
 822   (interactive)
 823   (outline-flag-subtree t))
 824
 825 (defun hide-leaves ()
 826   "Hide the body after this heading and at deeper levels."
 827   (interactive)
 828   (save-excursion
 829     (outline-back-to-heading)
 830 ;; Turned off to fix bug reported by Otto Maddox on 22 Nov 2005.
 831 ;;    (outline-end-of-heading)
 832     (hide-region-body (point) (progn (outline-end-of-subtree) (point)))))
 833
 834 (defun show-subtree ()
 835   "Show everything after this heading at deeper levels."
 836   (interactive)
 837   (outline-flag-subtree nil))
 838
 839 (defun outline-show-heading ()
 840   "Show the current heading and move to its end."
 841   (outline-flag-region (- (point)
 842                           (if (bobp) 0
 843                             (if (and outline-blank-line
 844                                      (eq (char-before (1- (point))) ?\n))
 845                                 2 1)))
 846                        (progn (outline-end-of-heading) (point))
 847                        nil))
 848
 849 (defun hide-sublevels (levels)
 850   "Hide everything but the top LEVELS levels of headers, in whole buffer."
 851   (interactive (list
 852                 (cond
 853                  (current-prefix-arg (prefix-numeric-value current-prefix-arg))
 854                  ((save-excursion (beginning-of-line)
 855                                   (looking-at outline-regexp))
 856                   (funcall outline-level))
 857                  (t 1))))
 858   (if (< levels 1)
 859       (error "Must keep at least one level of headers"))
 860   (save-excursion
 861     (let* (outline-view-change-hook
 862            (beg (progn
 863                   (goto-char (point-min))
 864                   ;; Skip the prelude, if any.
 865                   (unless (outline-on-heading-p t) (outline-next-heading))
 866                   (point)))
 867            (end (progn
 868                   (goto-char (point-max))
 869                   ;; Keep empty last line, if available.
 870                   (if (bolp) (1- (point)) (point)))))
 871       ;; First hide everything.
 872       (outline-flag-region beg end t)
 873       ;; Then unhide the top level headers.
 874       (outline-map-region
 875        (lambda ()
 876          (if (<= (funcall outline-level) levels)
 877              (outline-show-heading)))
 878        beg end)))
 879   (run-hooks 'outline-view-change-hook))
 880
 881 (defun hide-other ()
 882   "Hide everything except current body and parent and top-level headings."
 883   (interactive)
 884   (hide-sublevels 1)
 885   (let (outline-view-change-hook)
 886     (save-excursion
 887       (outline-back-to-heading t)
 888       (show-entry)
 889       (while (condition-case nil (progn (outline-up-heading 1 t) (not (bobp)))
 890                (error nil))
 891         (outline-flag-region (1- (point))
 892                              (save-excursion (forward-line 1) (point))
 893                              nil))))
 894   (run-hooks 'outline-view-change-hook))
 895
 896 (defun outline-toggle-children ()
 897   "Show or hide the current subtree depending on its current state."
 898   (interactive)
 899   (save-excursion
 900     (outline-back-to-heading)
 901     (if (not (outline-invisible-p (line-end-position)))
 902         (hide-subtree)
 903       (show-children)
 904       (show-entry))))
 905
 906 (defun outline-flag-subtree (flag)
 907   (save-excursion
 908     (outline-back-to-heading)
 909     (outline-end-of-heading)
 910     (outline-flag-region (point)
 911                           (progn (outline-end-of-subtree) (point))
 912                           flag)))
 913
 914 (defun outline-end-of-subtree ()
 915   (outline-back-to-heading)
 916   (let ((first t)
 917         (level (funcall outline-level)))
 918     (while (and (not (eobp))
 919                 (or first (> (funcall outline-level) level)))
 920       (setq first nil)
 921       (outline-next-heading))
 922     (if (and (bolp) (not (eolp)))
 923         ;; We stopped at a nonempty line (the next heading).
 924         (progn
 925           ;; Go to end of line before heading
 926           (forward-char -1)
 927           (if (and outline-blank-line (bolp))
 928               ;; leave blank line before heading
 929               (forward-char -1))))))
 930 \f
 931 (defun show-branches ()
 932   "Show all subheadings of this heading, but not their bodies."
 933   (interactive)
 934   (show-children 1000))
 935
 936 (defun show-children (&optional level)
 937   "Show all direct subheadings of this heading.
 938 Prefix arg LEVEL is how many levels below the current level should be shown.
 939 Default is enough to cause the following heading to appear."
 940   (interactive "P")
 941   (setq level
 942         (if level (prefix-numeric-value level)
 943           (save-excursion
 944             (outline-back-to-heading)
 945             (let ((start-level (funcall outline-level)))
 946               (outline-next-heading)
 947               (if (eobp)
 948                   1
 949                 (max 1 (- (funcall outline-level) start-level)))))))
 950   (let (outline-view-change-hook)
 951     (save-excursion
 952       (outline-back-to-heading)
 953       (setq level (+ level (funcall outline-level)))
 954       (outline-map-region
 955        (lambda ()
 956          (if (<= (funcall outline-level) level)
 957              (outline-show-heading)))
 958        (point)
 959        (progn (outline-end-of-subtree)
 960               (if (eobp) (point-max) (1+ (point)))))))
 961   (run-hooks 'outline-view-change-hook))
 962
 963 \f
 964
 965 (defun outline-up-heading (arg &optional invisible-ok)
 966   "Move to the visible heading line of which the present line is a subheading.
 967 With argument, move up ARG levels.
 968 If INVISIBLE-OK is non-nil, also consider invisible lines."
 969   (interactive "p")
 970   (and (eq this-command 'outline-up-heading)
 971        (or (eq last-command 'outline-up-heading) (push-mark)))
 972   (outline-back-to-heading invisible-ok)
 973   (let ((start-level (funcall outline-level)))
 974     (when (<= start-level 1)
 975       (error "Already at top level of the outline"))
 976     (while (and (> start-level 1) (> arg 0) (not (bobp)))
 977       (let ((level start-level))
 978         (while (not (or (< level start-level) (bobp)))
 979           (if invisible-ok
 980               (outline-previous-heading)
 981             (outline-previous-visible-heading 1))
 982           (setq level (funcall outline-level)))
 983         (setq start-level level))
 984       (setq arg (- arg 1))))
 985   (looking-at outline-regexp))
 986
 987 (defun outline-forward-same-level (arg)
 988   "Move forward to the ARG'th subheading at same level as this one.
 989 Stop at the first and last subheadings of a superior heading."
 990   (interactive "p")
 991   (outline-back-to-heading)
 992   (while (> arg 0)
 993     (let ((point-to-move-to (save-excursion
 994                               (outline-get-next-sibling))))
 995       (if point-to-move-to
 996           (progn
 997             (goto-char point-to-move-to)
 998             (setq arg (1- arg)))
 999         (progn
1000           (setq arg 0)
1001           (error "No following same-level heading"))))))
1002
1003 (defun outline-get-next-sibling ()
1004   "Move to next heading of the same level, and return point.
1005 If there is no such heading, return nil."
1006   (let ((level (funcall outline-level)))
1007     (outline-next-visible-heading 1)
1008     (while (and (not (eobp)) (> (funcall outline-level) level))
1009       (outline-next-visible-heading 1))
1010     (if (or (eobp) (< (funcall outline-level) level))
1011         nil
1012       (point))))
1013
1014 (defun outline-backward-same-level (arg)
1015   "Move backward to the ARG'th subheading at same level as this one.
1016 Stop at the first and last subheadings of a superior heading."
1017   (interactive "p")
1018   (outline-back-to-heading)
1019   (while (> arg 0)
1020     (let ((point-to-move-to (save-excursion
1021                               (outline-get-last-sibling))))
1022       (if point-to-move-to
1023           (progn
1024             (goto-char point-to-move-to)
1025             (setq arg (1- arg)))
1026         (progn
1027           (setq arg 0)
1028           (error "No previous same-level heading"))))))
1029
1030 (defun outline-get-last-sibling ()
1031   "Move to previous heading of the same level, and return point.
1032 If there is no such heading, return nil."
1033   (let ((opoint (point))
1034         (level (funcall outline-level)))
1035     (outline-previous-visible-heading 1)
1036     (when (and (/= (point) opoint) (outline-on-heading-p))
1037       (while (and (> (funcall outline-level) level)
1038                   (not (bobp)))
1039         (outline-previous-visible-heading 1))
1040       (if (< (funcall outline-level) level)
1041           nil
1042         (point)))))
1043 \f
1044 (defun outline-headers-as-kill (beg end)
1045   "Save the visible outline headers in region at the start of the kill ring.
1046
1047 Text shown between the headers isn't copied.  Two newlines are
1048 inserted between saved headers.  Yanking the result may be a
1049 convenient way to make a table of contents of the buffer."
1050   (interactive "r")
1051   (save-excursion
1052     (save-restriction
1053       (narrow-to-region beg end)
1054       (goto-char (point-min))
1055       (let ((buffer (current-buffer))
1056             start end)
1057         (with-temp-buffer
1058           (with-current-buffer buffer
1059             ;; Boundary condition: starting on heading:
1060             (when (outline-on-heading-p)
1061               (outline-back-to-heading)
1062               (setq start (point)
1063                     end (progn (outline-end-of-heading)
1064                                (point)))
1065               (insert-buffer-substring buffer start end)
1066               (insert "\n\n")))
1067           (let ((temp-buffer (current-buffer)))
1068             (with-current-buffer buffer
1069               (while (outline-next-heading)
1070                 (unless (outline-invisible-p)
1071                   (setq start (point)
1072                         end (progn (outline-end-of-heading) (point)))
1073                   (with-current-buffer temp-buffer
1074                     (insert-buffer-substring buffer start end)
1075                     (insert "\n\n"))))))
1076           (kill-new (buffer-string)))))))
1077
1078 (provide 'outline)
1079 (provide 'noutline)
1080
1081 ;; arch-tag: 1724410e-7d4d-4f46-b801-49e18171e874
1082 ;;; outline.el ends here