[bpt/emacs.git] / lisp / net / goto-addr.el

;;; goto-addr.el --- click to browse URL or to send to e-mail address

;; Copyright (C) 1995, 2000, 2001, 2002, 2003, 2004,
;;   2005 Free Software Foundation, Inc.

;; Author: Eric Ding <ericding@alum.mit.edu>
;; Maintainer: FSF
;; Created: 15 Aug 1995
;; Keywords: mh-e, www, mouse, mail

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; This package allows you to click or hit a key sequence while on a
;; URL or e-mail address, and either load the URL into a browser of
;; your choice using the browse-url package, or if it's an e-mail
;; address, to send an e-mail to that address.  By default, we bind to
;; the [mouse-2] and the [C-c return] key sequences.

;; INSTALLATION
;;
;; To use goto-address in a particular mode (for example, while
;; reading mail in mh-e), add something like this in your .emacs file:
;;
;; (add-hook 'mh-show-mode-hook 'goto-address)
;;
;; The mouse click method is bound to [mouse-2] on highlighted URLs or
;; e-mail addresses only; it functions normally everywhere else.  To bind
;; another mouse click to the function, add the following to your .emacs
;; (for example):
;;
;; (setq goto-address-highlight-keymap
;;   (let ((m (make-sparse-keymap)))
;;     (define-key m [S-mouse-2] 'goto-address-at-point)
;;     m))
;;

;; Known bugs/features:
;; * goto-address-mail-regexp only catches foo@bar.org style addressing,
;;   not stuff like X.400 addresses, etc.
;; * regexp also catches Message-Id line, since it is in the format of
;;   an Internet e-mail address (like Compuserve addresses)
;; * If the buffer is fontified after goto-address-fontify is run
;;   (say, using font-lock-fontify-buffer), then font-lock faces will
;;   override goto-address faces.

;;; Code:

(require 'thingatpt)
(autoload 'browse-url-url-at-point "browse-url")

;; XEmacs needs the following definitions.
(unless (fboundp 'overlays-in)
  (require 'overlay))
(unless (fboundp 'line-beginning-position)
  (defalias 'line-beginning-position 'point-at-bol))
(unless (fboundp 'line-end-position)
  (defalias 'line-end-position 'point-at-eol))
(unless (fboundp 'match-string-no-properties)
  (defalias 'match-string-no-properties 'match-string))

(defgroup goto-address nil
  "Click to browse URL or to send to e-mail address."
  :group 'mouse
  :group 'hypermedia)


;; I don't expect users to want fontify'ing without highlighting.
(defcustom goto-address-fontify-p t
  "*Non-nil means URLs and e-mail addresses in buffer are fontified.
But only if `goto-address-highlight-p' is also non-nil."
  :type 'boolean
  :group 'goto-address)

(defcustom goto-address-highlight-p t
  "*Non-nil means URLs and e-mail addresses in buffer are highlighted."
  :type 'boolean
  :group 'goto-address)

(defcustom goto-address-fontify-maximum-size 30000
  "*Maximum size of file in which to fontify and/or highlight URLs.
A value of t means there is no limit--fontify regardless of the size."
  :type '(choice (integer :tag "Maximum size") (const :tag "No limit" t))
  :group 'goto-address)

(defvar goto-address-mail-regexp
  ;; Actually pretty much any char could appear in the username part.  -stef
  "[-a-zA-Z0-9=._+]+@\\([-a-zA-z0-9_]+\\.\\)+[a-zA-Z0-9]+"
  "A regular expression probably matching an e-mail address.")

(defvar goto-address-url-regexp
  (concat "\\<\\("
	  (mapconcat 'identity
		     (delete "mailto:" (copy-sequence thing-at-point-uri-schemes))
		     "\\|")
	  "\\)"
          thing-at-point-url-path-regexp)
  ;; (concat "\\b\\(s?https?\\|ftp\\|file\\|gopher\\|news\\|"
  ;; 	  "telnet\\|wais\\):\\(//[-a-zA-Z0-9_.]+:"
  ;; 	  "[0-9]*\\)?[-a-zA-Z0-9_=?#$@~`%&*+|\\/.,]*"
  ;; 	  "[-a-zA-Z0-9_=#$@~`%&*+|\\/]")
  "A regular expression probably matching a URL.")

(defvar goto-address-highlight-keymap
  (let ((m (make-sparse-keymap)))
    (define-key m (if (featurep 'xemacs) (kbd "<button2>") (kbd "<mouse-2>"))
      'goto-address-at-point)
    (define-key m (kbd "C-c RET") 'goto-address-at-point)
    m)
  "keymap to hold goto-addr's mouse key defs under highlighted URLs.")

(defcustom goto-address-url-face 'bold
  "Face to use for URLs."
  :type 'face
  :group 'goto-address)

(defcustom goto-address-url-mouse-face 'highlight
  "Face to use for URLs when the mouse is on them."
  :type 'face
  :group 'goto-address)

(defcustom goto-address-mail-face 'italic
  "Face to use for e-mail addresses."
  :type 'face
  :group 'goto-address)

(defcustom goto-address-mail-mouse-face 'secondary-selection
  "Face to use for e-mail addresses when the mouse is on them."
  :type 'face
  :group 'goto-address)

(defun goto-address-fontify ()
  "Fontify the URLs and e-mail addresses in the current buffer.
This function implements `goto-address-highlight-p'
and `goto-address-fontify-p'."
  ;; Clean up from any previous go.
  (dolist (overlay (overlays-in (point-min) (point-max)))
    (if (overlay-get overlay 'goto-address)
	(delete-overlay overlay)))
  (save-excursion
    (let ((inhibit-point-motion-hooks t))
      (goto-char (point-min))
      (if (or (eq t goto-address-fontify-maximum-size)
	      (< (- (point-max) (point)) goto-address-fontify-maximum-size))
	  (progn
	    (while (re-search-forward goto-address-url-regexp nil t)
              (let* ((s (match-beginning 0))
                     (e (match-end 0))
                     (this-overlay (make-overlay s e)))
		(and goto-address-fontify-p
                     (overlay-put this-overlay 'face goto-address-url-face))
                (overlay-put this-overlay 'evaporate t)
		(overlay-put this-overlay
                             'mouse-face goto-address-url-mouse-face)
		(overlay-put this-overlay
			     'help-echo "mouse-2, C-c RET: follow URL")
		(overlay-put this-overlay
                             'keymap goto-address-highlight-keymap)
		(overlay-put this-overlay 'goto-address t)))
	    (goto-char (point-min))
	    (while (re-search-forward goto-address-mail-regexp nil t)
              (let* ((s (match-beginning 0))
                     (e (match-end 0))
                     (this-overlay (make-overlay s e)))
		(and goto-address-fontify-p
                     (overlay-put this-overlay 'face goto-address-mail-face))
                (overlay-put this-overlay 'evaporate t)
                (overlay-put this-overlay 'mouse-face
                             goto-address-mail-mouse-face)
		(overlay-put this-overlay
			     'help-echo "mouse-2, C-c RET: mail this address")
                (overlay-put this-overlay
                             'keymap goto-address-highlight-keymap)
		(overlay-put this-overlay 'goto-address t))))))))

;; code to find and goto addresses; much of this has been blatantly
;; snarfed from browse-url.el

;;;###autoload
(define-obsolete-function-alias
  'goto-address-at-mouse 'goto-address-at-point "22.1")

;;;###autoload
(defun goto-address-at-point (&optional event)
  "Send to the e-mail address or load the URL at point.
Send mail to address at point.  See documentation for
`goto-address-find-address-at-point'.  If no address is found
there, then load the URL at or before point."
  (interactive (list last-input-event))
  (save-excursion
    (if event (mouse-set-point event))
    (let ((address (save-excursion (goto-address-find-address-at-point))))
      (if (and address
	       (save-excursion
		 (goto-char (previous-single-char-property-change
			     (point) 'goto-address nil
			     (line-beginning-position)))
		 (not (looking-at goto-address-url-regexp))))
	  (compose-mail address)
	(let ((url (browse-url-url-at-point)))
	  (if url
	      (browse-url url)
	    (error "No e-mail address or URL found")))))))

(defun goto-address-find-address-at-point ()
  "Find e-mail address around or before point.
Then search backwards to beginning of line for the start of an e-mail
address.  If no e-mail address found, return nil."
  (re-search-backward "[^-_A-z0-9.@]" (line-beginning-position) 'lim)
  (if (or (looking-at goto-address-mail-regexp)	; already at start
	  (and (re-search-forward goto-address-mail-regexp
				  (line-end-position) 'lim)
	       (goto-char (match-beginning 0))))
      (match-string-no-properties 0)))

;;;###autoload
(defun goto-address ()
  "Sets up goto-address functionality in the current buffer.
Allows user to use mouse/keyboard command to click to go to a URL
or to send e-mail.
By default, goto-address binds to mouse-2 and C-c RET.

Also fontifies the buffer appropriately (see `goto-address-fontify-p' and
`goto-address-highlight-p' for more information)."
  (interactive)
  (if goto-address-highlight-p
      (goto-address-fontify)))

(provide 'goto-addr)

;; arch-tag: ca47c505-5661-425d-a471-62bc6e75cf0a
;;; goto-addr.el ends here
Commit	Line	Data
8749abea GM	1	;;; goto-addr.el --- click to browse URL or to send to e-mail address
8749abea GM	2
5fd6d89f TTN	3	;; Copyright (C) 1995, 2000, 2001, 2002, 2003, 2004,
5fd6d89f TTN	4	;; 2005 Free Software Foundation, Inc.
8749abea	5
cf6936a4	6	;; Author: Eric Ding <ericding@alum.mit.edu>
12c74386	7	;; Maintainer: FSF
8749abea GM	8	;; Created: 15 Aug 1995
	9	;; Keywords: mh-e, www, mouse, mail
	10
	11	;; This file is part of GNU Emacs.
	12
	13	;; GNU Emacs is free software; you can redistribute it and/or modify
	14	;; it under the terms of the GNU General Public License as published by
	15	;; the Free Software Foundation; either version 2, or (at your option)
	16	;; any later version.
	17
	18	;; GNU Emacs is distributed in the hope that it will be useful,
	19	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	20	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	21	;; GNU General Public License for more details.
	22
	23	;; You should have received a copy of the GNU General Public License
	24	;; along with GNU Emacs; see the file COPYING. If not, write to the
3a35cf56 LK	25	;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
3a35cf56 LK	26	;; Boston, MA 02110-1301, USA.
8749abea GM	27
	28	;;; Commentary:
	29
	30	;; This package allows you to click or hit a key sequence while on a
	31	;; URL or e-mail address, and either load the URL into a browser of
	32	;; your choice using the browse-url package, or if it's an e-mail
	33	;; address, to send an e-mail to that address. By default, we bind to
	34	;; the [mouse-2] and the [C-c return] key sequences.
	35
	36	;; INSTALLATION
	37	;;
	38	;; To use goto-address in a particular mode (for example, while
	39	;; reading mail in mh-e), add something like this in your .emacs file:
	40	;;
	41	;; (add-hook 'mh-show-mode-hook 'goto-address)
	42	;;
28223a7e	43	;; The mouse click method is bound to [mouse-2] on highlighted URLs or
8749abea GM	44	;; e-mail addresses only; it functions normally everywhere else. To bind
	45	;; another mouse click to the function, add the following to your .emacs
	46	;; (for example):
	47	;;
	48	;; (setq goto-address-highlight-keymap
	49	;; (let ((m (make-sparse-keymap)))
9fd6c528	50	;; (define-key m [S-mouse-2] 'goto-address-at-point)
8749abea GM	51	;; m))
	52	;;
	53
8749abea GM	54	;; Known bugs/features:
	55	;; * goto-address-mail-regexp only catches foo@bar.org style addressing,
	56	;; not stuff like X.400 addresses, etc.
	57	;; * regexp also catches Message-Id line, since it is in the format of
	58	;; an Internet e-mail address (like Compuserve addresses)
51107a70 DL	59	;; * If the buffer is fontified after goto-address-fontify is run
51107a70 DL	60	;; (say, using font-lock-fontify-buffer), then font-lock faces will
8749abea GM	61	;; override goto-address faces.
	62
	63	;;; Code:
	64
f79538c9 DL	65	(require 'thingatpt)
f79538c9 DL	66	(autoload 'browse-url-url-at-point "browse-url")
8749abea	67
67ac0f7a GM	68	;; XEmacs needs the following definitions.
	69	(unless (fboundp 'overlays-in)
	70	(require 'overlay))
	71	(unless (fboundp 'line-beginning-position)
	72	(defalias 'line-beginning-position 'point-at-bol))
	73	(unless (fboundp 'line-end-position)
	74	(defalias 'line-end-position 'point-at-eol))
	75	(unless (fboundp 'match-string-no-properties)
	76	(defalias 'match-string-no-properties 'match-string))
	77
8749abea GM	78	(defgroup goto-address nil
	79	"Click to browse URL or to send to e-mail address."
	80	:group 'mouse
	81	:group 'hypermedia)
	82
	83
d8754ce5	84	;; I don't expect users to want fontify'ing without highlighting.
8749abea	85	(defcustom goto-address-fontify-p t
f79538c9	86	"*Non-nil means URLs and e-mail addresses in buffer are fontified.
8749abea GM	87	But only if `goto-address-highlight-p' is also non-nil."
	88	:type 'boolean
	89	:group 'goto-address)
	90
	91	(defcustom goto-address-highlight-p t
f79538c9	92	"*Non-nil means URLs and e-mail addresses in buffer are highlighted."
8749abea GM	93	:type 'boolean
	94	:group 'goto-address)
	95
	96	(defcustom goto-address-fontify-maximum-size 30000
3e61755b RS	97	"*Maximum size of file in which to fontify and/or highlight URLs.
	98	A value of t means there is no limit--fontify regardless of the size."
	99	:type '(choice (integer :tag "Maximum size") (const :tag "No limit" t))
8749abea GM	100	:group 'goto-address)
	101
	102	(defvar goto-address-mail-regexp
138399e6	103	;; Actually pretty much any char could appear in the username part. -stef
02b6dbd8	104	"[-a-zA-Z0-9=._+]+@\\([-a-zA-z0-9_]+\\.\\)+[a-zA-Z0-9]+"
8749abea GM	105	"A regular expression probably matching an e-mail address.")
8749abea GM	106
019f8c1e RS	107	(defvar goto-address-url-regexp
	108	(concat "\\<\\("
	109	(mapconcat 'identity
	110	(delete "mailto:" (copy-sequence thing-at-point-uri-schemes))
	111	"\\\|")
	112	"\\)"
	113	thing-at-point-url-path-regexp)
d8754ce5 GM	114	;; (concat "\\b\\(s?https?\\\|ftp\\\|file\\\|gopher\\\|news\\\|"
	115	;; "telnet\\\|wais\\):\\(//[-a-zA-Z0-9_.]+:"
	116	;; "[0-9]\\)?[-a-zA-Z0-9_=?#$@~`%&+\|\\/.,]*"
	117	;; "[-a-zA-Z0-9_=#$@~`%&*+\|\\/]")
8749abea GM	118	"A regular expression probably matching a URL.")
	119
	120	(defvar goto-address-highlight-keymap
	121	(let ((m (make-sparse-keymap)))
9fd6c528	122	(define-key m (if (featurep 'xemacs) (kbd "<button2>") (kbd "<mouse-2>"))
64981116	123	'goto-address-at-point)
67ac0f7a	124	(define-key m (kbd "C-c RET") 'goto-address-at-point)
8749abea GM	125	m)
	126	"keymap to hold goto-addr's mouse key defs under highlighted URLs.")
	127
	128	(defcustom goto-address-url-face 'bold
f79538c9	129	"Face to use for URLs."
8749abea GM	130	:type 'face
	131	:group 'goto-address)
	132
	133	(defcustom goto-address-url-mouse-face 'highlight
f79538c9	134	"Face to use for URLs when the mouse is on them."
8749abea GM	135	:type 'face
	136	:group 'goto-address)
	137
	138	(defcustom goto-address-mail-face 'italic
f79538c9	139	"Face to use for e-mail addresses."
8749abea GM	140	:type 'face
	141	:group 'goto-address)
	142
	143	(defcustom goto-address-mail-mouse-face 'secondary-selection
f79538c9	144	"Face to use for e-mail addresses when the mouse is on them."
8749abea GM	145	:type 'face
	146	:group 'goto-address)
	147
	148	(defun goto-address-fontify ()
28223a7e	149	"Fontify the URLs and e-mail addresses in the current buffer.
8749abea GM	150	This function implements `goto-address-highlight-p'
8749abea GM	151	and `goto-address-fontify-p'."
51107a70 DL	152	;; Clean up from any previous go.
	153	(dolist (overlay (overlays-in (point-min) (point-max)))
	154	(if (overlay-get overlay 'goto-address)
	155	(delete-overlay overlay)))
8749abea	156	(save-excursion
51107a70	157	(let ((inhibit-point-motion-hooks t))
8749abea	158	(goto-char (point-min))
3e61755b RS	159	(if (or (eq t goto-address-fontify-maximum-size)
3e61755b RS	160	(< (- (point-max) (point)) goto-address-fontify-maximum-size))
8749abea GM	161	(progn
	162	(while (re-search-forward goto-address-url-regexp nil t)
	163	(let* ((s (match-beginning 0))
	164	(e (match-end 0))
	165	(this-overlay (make-overlay s e)))
	166	(and goto-address-fontify-p
	167	(overlay-put this-overlay 'face goto-address-url-face))
9fd6c528	168	(overlay-put this-overlay 'evaporate t)
8749abea GM	169	(overlay-put this-overlay
8749abea GM	170	'mouse-face goto-address-url-mouse-face)
fa59072a	171	(overlay-put this-overlay
655f2a08	172	'help-echo "mouse-2, C-c RET: follow URL")
8749abea	173	(overlay-put this-overlay
51107a70 DL	174	'keymap goto-address-highlight-keymap)
51107a70 DL	175	(overlay-put this-overlay 'goto-address t)))
8749abea GM	176	(goto-char (point-min))
	177	(while (re-search-forward goto-address-mail-regexp nil t)
	178	(let* ((s (match-beginning 0))
	179	(e (match-end 0))
	180	(this-overlay (make-overlay s e)))
	181	(and goto-address-fontify-p
	182	(overlay-put this-overlay 'face goto-address-mail-face))
9fd6c528	183	(overlay-put this-overlay 'evaporate t)
8749abea GM	184	(overlay-put this-overlay 'mouse-face
8749abea GM	185	goto-address-mail-mouse-face)
fa59072a	186	(overlay-put this-overlay
655f2a08	187	'help-echo "mouse-2, C-c RET: mail this address")
8749abea	188	(overlay-put this-overlay
51107a70 DL	189	'keymap goto-address-highlight-keymap)
51107a70 DL	190	(overlay-put this-overlay 'goto-address t))))))))
8749abea	191
d8754ce5 GM	192	;; code to find and goto addresses; much of this has been blatantly
d8754ce5 GM	193	;; snarfed from browse-url.el
8749abea GM	194
8749abea GM	195	;;;###autoload
9fd6c528 SM	196	(define-obsolete-function-alias
9fd6c528 SM	197	'goto-address-at-mouse 'goto-address-at-point "22.1")
8749abea GM	198
8749abea GM	199	;;;###autoload
9fd6c528	200	(defun goto-address-at-point (&optional event)
8749abea GM	201	"Send to the e-mail address or load the URL at point.
	202	Send mail to address at point. See documentation for
	203	`goto-address-find-address-at-point'. If no address is found
	204	there, then load the URL at or before point."
9fd6c528	205	(interactive (list last-input-event))
8749abea	206	(save-excursion
9fd6c528	207	(if event (mouse-set-point event))
8749abea	208	(let ((address (save-excursion (goto-address-find-address-at-point))))
a1506d29	209	(if (and address
1c66d9fb GM	210	(save-excursion
	211	(goto-char (previous-single-char-property-change
	212	(point) 'goto-address nil
	213	(line-beginning-position)))
	214	(not (looking-at goto-address-url-regexp))))
f79538c9 DL	215	(compose-mail address)
	216	(let ((url (browse-url-url-at-point)))
	217	(if url
	218	(browse-url url)
	219	(error "No e-mail address or URL found")))))))
8749abea GM	220
	221	(defun goto-address-find-address-at-point ()
	222	"Find e-mail address around or before point.
	223	Then search backwards to beginning of line for the start of an e-mail
f79538c9 DL	224	address. If no e-mail address found, return nil."
	225	(re-search-backward "[^-_A-z0-9.@]" (line-beginning-position) 'lim)
	226	(if (or (looking-at goto-address-mail-regexp) ; already at start
	227	(and (re-search-forward goto-address-mail-regexp
	228	(line-end-position) 'lim)
	229	(goto-char (match-beginning 0))))
	230	(match-string-no-properties 0)))
8749abea GM	231
	232	;;;###autoload
	233	(defun goto-address ()
	234	"Sets up goto-address functionality in the current buffer.
	235	Allows user to use mouse/keyboard command to click to go to a URL
	236	or to send e-mail.
	237	By default, goto-address binds to mouse-2 and C-c RET.
	238
	239	Also fontifies the buffer appropriately (see `goto-address-fontify-p' and
	240	`goto-address-highlight-p' for more information)."
	241	(interactive)
8749abea GM	242	(if goto-address-highlight-p
	243	(goto-address-fontify)))
	244
	245	(provide 'goto-addr)
	246
9fd6c528	247	;; arch-tag: ca47c505-5661-425d-a471-62bc6e75cf0a
55535639	248	;;; goto-addr.el ends here