[bpt/emacs.git] / lisp / net / goto-addr.el

;;; goto-addr.el --- click to browse URL or to send to e-mail address

;; Copyright (C) 1995, 2000, 2001 Free Software Foundation, Inc.

;; Author: Eric Ding <ericding@alum.mit.edu>
;; Maintainer: FSF
;; Created: 15 Aug 1995
;; Keywords: mh-e, www, mouse, mail

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; This package allows you to click or hit a key sequence while on a
;; URL or e-mail address, and either load the URL into a browser of
;; your choice using the browse-url package, or if it's an e-mail
;; address, to send an e-mail to that address.  By default, we bind to
;; the [mouse-2] and the [C-c return] key sequences.

;; INSTALLATION
;;
;; To use goto-address in a particular mode (for example, while
;; reading mail in mh-e), add something like this in your .emacs file:
;;
;; (add-hook 'mh-show-mode-hook 'goto-address)
;;
;; The mouse click method is bound to [mouse-2] on highlighted URLs or
;; e-mail addresses only; it functions normally everywhere else.  To bind
;; another mouse click to the function, add the following to your .emacs
;; (for example):
;;
;; (setq goto-address-highlight-keymap
;;   (let ((m (make-sparse-keymap)))
;;     (define-key m [S-mouse-2] 'goto-address-at-mouse)
;;     m))
;;

;; Known bugs/features:
;; * goto-address-mail-regexp only catches foo@bar.org style addressing,
;;   not stuff like X.400 addresses, etc.
;; * regexp also catches Message-Id line, since it is in the format of
;;   an Internet e-mail address (like Compuserve addresses)
;; * If the buffer is fontified after goto-address-fontify is run
;;   (say, using font-lock-fontify-buffer), then font-lock faces will
;;   override goto-address faces.

;;; Code:

(require 'thingatpt)
(autoload 'browse-url-url-at-point "browse-url")

;; XEmacs needs the following definitions.
(unless (fboundp 'overlays-in)
  (require 'overlay))
(unless (fboundp 'line-beginning-position)
  (defalias 'line-beginning-position 'point-at-bol))
(unless (fboundp 'line-end-position)
  (defalias 'line-end-position 'point-at-eol))
(unless (fboundp 'match-string-no-properties)
  (defalias 'match-string-no-properties 'match-string))

(defgroup goto-address nil
  "Click to browse URL or to send to e-mail address."
  :group 'mouse
  :group 'hypermedia)


;;; I don't expect users to want fontify'ing without highlighting.
(defcustom goto-address-fontify-p t
  "*Non-nil means URLs and e-mail addresses in buffer are fontified.
But only if `goto-address-highlight-p' is also non-nil."
  :type 'boolean
  :group 'goto-address)

(defcustom goto-address-highlight-p t
  "*Non-nil means URLs and e-mail addresses in buffer are highlighted."
  :type 'boolean
  :group 'goto-address)

(defcustom goto-address-fontify-maximum-size 30000
  "*Maximum size of file in which to fontify and/or highlight URLs."
  :type 'integer
  :group 'goto-address)

(defvar goto-address-mail-regexp
  "[-a-zA-Z0-9._]+@\\([-a-zA-z0-9_]+\\.\\)+[a-zA-Z0-9]+"
  "A regular expression probably matching an e-mail address.")

(defvar goto-address-url-regexp thing-at-point-url-regexp
;;;   (concat "\\b\\(s?https?\\|ftp\\|file\\|gopher\\|news\\|"
;;; 	  "telnet\\|wais\\):\\(//[-a-zA-Z0-9_.]+:"
;;; 	  "[0-9]*\\)?[-a-zA-Z0-9_=?#$@~`%&*+|\\/.,]*"
;;; 	  "[-a-zA-Z0-9_=#$@~`%&*+|\\/]")
  "A regular expression probably matching a URL.")

(defvar goto-address-highlight-keymap
  (let ((m (make-sparse-keymap)))
    (if (featurep 'xemacs)
	(define-key m (kbd "<button2>") 'goto-address-at-mouse)
      (define-key m (kbd "<mouse-2>") 'goto-address-at-mouse))
    (define-key m (kbd "C-c RET") 'goto-address-at-point)
    m)
  "keymap to hold goto-addr's mouse key defs under highlighted URLs.")

(defcustom goto-address-url-face 'bold
  "Face to use for URLs."
  :type 'face
  :group 'goto-address)

(defcustom goto-address-url-mouse-face 'highlight
  "Face to use for URLs when the mouse is on them."
  :type 'face
  :group 'goto-address)

(defcustom goto-address-mail-face 'italic
  "Face to use for e-mail addresses."
  :type 'face
  :group 'goto-address)

(defcustom goto-address-mail-mouse-face 'secondary-selection
  "Face to use for e-mail addresses when the mouse is on them."
  :type 'face
  :group 'goto-address)

(defun goto-address-fontify ()
  "Fontify the URLs and e-mail addresses in the current buffer.
This function implements `goto-address-highlight-p'
and `goto-address-fontify-p'."
  ;; Clean up from any previous go.
  (dolist (overlay (overlays-in (point-min) (point-max)))
    (if (overlay-get overlay 'goto-address)
	(delete-overlay overlay)))
  (save-excursion
    (let ((inhibit-point-motion-hooks t))
      (goto-char (point-min))
      (if (< (- (point-max) (point)) goto-address-fontify-maximum-size)
	  (progn
	    (while (re-search-forward goto-address-url-regexp nil t)
              (let* ((s (match-beginning 0))
                     (e (match-end 0))
                     (this-overlay (make-overlay s e)))
		(and goto-address-fontify-p
                     (overlay-put this-overlay 'face goto-address-url-face))
		(overlay-put this-overlay
                             'mouse-face goto-address-url-mouse-face)
		(overlay-put this-overlay
			     'help-echo "mouse-2: follow URL")
		(overlay-put this-overlay
                             'keymap goto-address-highlight-keymap)
		(overlay-put this-overlay 'goto-address t)))
	    (goto-char (point-min))
	    (while (re-search-forward goto-address-mail-regexp nil t)
              (let* ((s (match-beginning 0))
                     (e (match-end 0))
                     (this-overlay (make-overlay s e)))
		(and goto-address-fontify-p
                     (overlay-put this-overlay 'face goto-address-mail-face))
                (overlay-put this-overlay 'mouse-face
                             goto-address-mail-mouse-face)
		(overlay-put this-overlay
			     'help-echo "mouse-2: mail this address")
                (overlay-put this-overlay
                             'keymap goto-address-highlight-keymap)
		(overlay-put this-overlay 'goto-address t))))))))

;;; code to find and goto addresses; much of this has been blatantly
;;; snarfed from browse-url.el

;;;###autoload
(defun goto-address-at-mouse (event)
  "Send to the e-mail address or load the URL clicked with the mouse.
Send mail to address at position of mouse click.  See documentation for
`goto-address-find-address-at-point'.  If no address is found
there, then load the URL at or before the position of the mouse click."
  (interactive "e")
  (save-excursion
    (mouse-set-point event)
    (goto-address-at-point)))

;;;###autoload
(defun goto-address-at-point ()
  "Send to the e-mail address or load the URL at point.
Send mail to address at point.  See documentation for
`goto-address-find-address-at-point'.  If no address is found
there, then load the URL at or before point."
  (interactive)
  (save-excursion
    (let ((address (save-excursion (goto-address-find-address-at-point))))
      (if address
	  (compose-mail address)
	(let ((url (browse-url-url-at-point)))
	  (if url
	      (browse-url url)
	    (error "No e-mail address or URL found")))))))

(defun goto-address-find-address-at-point ()
  "Find e-mail address around or before point.
Then search backwards to beginning of line for the start of an e-mail
address.  If no e-mail address found, return nil."
  (re-search-backward "[^-_A-z0-9.@]" (line-beginning-position) 'lim)
  (if (or (looking-at goto-address-mail-regexp)	; already at start
	  (and (re-search-forward goto-address-mail-regexp
				  (line-end-position) 'lim)
	       (goto-char (match-beginning 0))))
      (match-string-no-properties 0)))

;;;###autoload
(defun goto-address ()
  "Sets up goto-address functionality in the current buffer.
Allows user to use mouse/keyboard command to click to go to a URL
or to send e-mail.
By default, goto-address binds to mouse-2 and C-c RET.

Also fontifies the buffer appropriately (see `goto-address-fontify-p' and
`goto-address-highlight-p' for more information)."
  (interactive)
  (if goto-address-highlight-p
      (goto-address-fontify)))

(provide 'goto-addr)

;;; goto-addr.el ends here.
Commit	Line	Data
8749abea GM	1	;;; goto-addr.el --- click to browse URL or to send to e-mail address
8749abea GM	2
67ac0f7a	3	;; Copyright (C) 1995, 2000, 2001 Free Software Foundation, Inc.
8749abea	4
cf6936a4	5	;; Author: Eric Ding <ericding@alum.mit.edu>
12c74386	6	;; Maintainer: FSF
8749abea GM	7	;; Created: 15 Aug 1995
	8	;; Keywords: mh-e, www, mouse, mail
	9
	10	;; This file is part of GNU Emacs.
	11
	12	;; GNU Emacs is free software; you can redistribute it and/or modify
	13	;; it under the terms of the GNU General Public License as published by
	14	;; the Free Software Foundation; either version 2, or (at your option)
	15	;; any later version.
	16
	17	;; GNU Emacs is distributed in the hope that it will be useful,
	18	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	19	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	20	;; GNU General Public License for more details.
	21
	22	;; You should have received a copy of the GNU General Public License
	23	;; along with GNU Emacs; see the file COPYING. If not, write to the
	24	;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
	25	;; Boston, MA 02111-1307, USA.
	26
	27	;;; Commentary:
	28
	29	;; This package allows you to click or hit a key sequence while on a
	30	;; URL or e-mail address, and either load the URL into a browser of
	31	;; your choice using the browse-url package, or if it's an e-mail
	32	;; address, to send an e-mail to that address. By default, we bind to
	33	;; the [mouse-2] and the [C-c return] key sequences.
	34
	35	;; INSTALLATION
	36	;;
	37	;; To use goto-address in a particular mode (for example, while
	38	;; reading mail in mh-e), add something like this in your .emacs file:
	39	;;
	40	;; (add-hook 'mh-show-mode-hook 'goto-address)
	41	;;
28223a7e	42	;; The mouse click method is bound to [mouse-2] on highlighted URLs or
8749abea GM	43	;; e-mail addresses only; it functions normally everywhere else. To bind
	44	;; another mouse click to the function, add the following to your .emacs
	45	;; (for example):
	46	;;
	47	;; (setq goto-address-highlight-keymap
	48	;; (let ((m (make-sparse-keymap)))
	49	;; (define-key m [S-mouse-2] 'goto-address-at-mouse)
	50	;; m))
	51	;;
	52
8749abea GM	53	;; Known bugs/features:
	54	;; * goto-address-mail-regexp only catches foo@bar.org style addressing,
	55	;; not stuff like X.400 addresses, etc.
	56	;; * regexp also catches Message-Id line, since it is in the format of
	57	;; an Internet e-mail address (like Compuserve addresses)
51107a70 DL	58	;; * If the buffer is fontified after goto-address-fontify is run
51107a70 DL	59	;; (say, using font-lock-fontify-buffer), then font-lock faces will
8749abea GM	60	;; override goto-address faces.
	61
	62	;;; Code:
	63
f79538c9 DL	64	(require 'thingatpt)
f79538c9 DL	65	(autoload 'browse-url-url-at-point "browse-url")
8749abea	66
67ac0f7a GM	67	;; XEmacs needs the following definitions.
	68	(unless (fboundp 'overlays-in)
	69	(require 'overlay))
	70	(unless (fboundp 'line-beginning-position)
	71	(defalias 'line-beginning-position 'point-at-bol))
	72	(unless (fboundp 'line-end-position)
	73	(defalias 'line-end-position 'point-at-eol))
	74	(unless (fboundp 'match-string-no-properties)
	75	(defalias 'match-string-no-properties 'match-string))
	76
8749abea GM	77	(defgroup goto-address nil
	78	"Click to browse URL or to send to e-mail address."
	79	:group 'mouse
	80	:group 'hypermedia)
	81
	82
	83	;;; I don't expect users to want fontify'ing without highlighting.
	84	(defcustom goto-address-fontify-p t
f79538c9	85	"*Non-nil means URLs and e-mail addresses in buffer are fontified.
8749abea GM	86	But only if `goto-address-highlight-p' is also non-nil."
	87	:type 'boolean
	88	:group 'goto-address)
	89
	90	(defcustom goto-address-highlight-p t
f79538c9	91	"*Non-nil means URLs and e-mail addresses in buffer are highlighted."
8749abea GM	92	:type 'boolean
	93	:group 'goto-address)
	94
	95	(defcustom goto-address-fontify-maximum-size 30000
28223a7e	96	"*Maximum size of file in which to fontify and/or highlight URLs."
8749abea GM	97	:type 'integer
	98	:group 'goto-address)
	99
	100	(defvar goto-address-mail-regexp
	101	"[-a-zA-Z0-9._]+@\\([-a-zA-z0-9_]+\\.\\)+[a-zA-Z0-9]+"
	102	"A regular expression probably matching an e-mail address.")
	103
f79538c9 DL	104	(defvar goto-address-url-regexp thing-at-point-url-regexp
	105	;;; (concat "\\b\\(s?https?\\\|ftp\\\|file\\\|gopher\\\|news\\\|"
	106	;;; "telnet\\\|wais\\):\\(//[-a-zA-Z0-9_.]+:"
	107	;;; "[0-9]\\)?[-a-zA-Z0-9_=?#$@~`%&+\|\\/.,]*"
	108	;;; "[-a-zA-Z0-9_=#$@~`%&*+\|\\/]")
8749abea GM	109	"A regular expression probably matching a URL.")
	110
	111	(defvar goto-address-highlight-keymap
	112	(let ((m (make-sparse-keymap)))
67ac0f7a GM	113	(if (featurep 'xemacs)
	114	(define-key m (kbd "<button2>") 'goto-address-at-mouse)
	115	(define-key m (kbd "<mouse-2>") 'goto-address-at-mouse))
	116	(define-key m (kbd "C-c RET") 'goto-address-at-point)
8749abea GM	117	m)
	118	"keymap to hold goto-addr's mouse key defs under highlighted URLs.")
	119
	120	(defcustom goto-address-url-face 'bold
f79538c9	121	"Face to use for URLs."
8749abea GM	122	:type 'face
	123	:group 'goto-address)
	124
	125	(defcustom goto-address-url-mouse-face 'highlight
f79538c9	126	"Face to use for URLs when the mouse is on them."
8749abea GM	127	:type 'face
	128	:group 'goto-address)
	129
	130	(defcustom goto-address-mail-face 'italic
f79538c9	131	"Face to use for e-mail addresses."
8749abea GM	132	:type 'face
	133	:group 'goto-address)
	134
	135	(defcustom goto-address-mail-mouse-face 'secondary-selection
f79538c9	136	"Face to use for e-mail addresses when the mouse is on them."
8749abea GM	137	:type 'face
	138	:group 'goto-address)
	139
	140	(defun goto-address-fontify ()
28223a7e	141	"Fontify the URLs and e-mail addresses in the current buffer.
8749abea GM	142	This function implements `goto-address-highlight-p'
8749abea GM	143	and `goto-address-fontify-p'."
51107a70 DL	144	;; Clean up from any previous go.
	145	(dolist (overlay (overlays-in (point-min) (point-max)))
	146	(if (overlay-get overlay 'goto-address)
	147	(delete-overlay overlay)))
8749abea	148	(save-excursion
51107a70	149	(let ((inhibit-point-motion-hooks t))
8749abea GM	150	(goto-char (point-min))
	151	(if (< (- (point-max) (point)) goto-address-fontify-maximum-size)
	152	(progn
	153	(while (re-search-forward goto-address-url-regexp nil t)
	154	(let* ((s (match-beginning 0))
	155	(e (match-end 0))
	156	(this-overlay (make-overlay s e)))
	157	(and goto-address-fontify-p
	158	(overlay-put this-overlay 'face goto-address-url-face))
	159	(overlay-put this-overlay
	160	'mouse-face goto-address-url-mouse-face)
fa59072a DL	161	(overlay-put this-overlay
fa59072a DL	162	'help-echo "mouse-2: follow URL")
8749abea	163	(overlay-put this-overlay
51107a70 DL	164	'keymap goto-address-highlight-keymap)
51107a70 DL	165	(overlay-put this-overlay 'goto-address t)))
8749abea GM	166	(goto-char (point-min))
	167	(while (re-search-forward goto-address-mail-regexp nil t)
	168	(let* ((s (match-beginning 0))
	169	(e (match-end 0))
	170	(this-overlay (make-overlay s e)))
	171	(and goto-address-fontify-p
	172	(overlay-put this-overlay 'face goto-address-mail-face))
	173	(overlay-put this-overlay 'mouse-face
	174	goto-address-mail-mouse-face)
fa59072a	175	(overlay-put this-overlay
f79538c9	176	'help-echo "mouse-2: mail this address")
8749abea	177	(overlay-put this-overlay
51107a70 DL	178	'keymap goto-address-highlight-keymap)
51107a70 DL	179	(overlay-put this-overlay 'goto-address t))))))))
8749abea GM	180
	181	;;; code to find and goto addresses; much of this has been blatantly
	182	;;; snarfed from browse-url.el
	183
	184	;;;###autoload
	185	(defun goto-address-at-mouse (event)
	186	"Send to the e-mail address or load the URL clicked with the mouse.
	187	Send mail to address at position of mouse click. See documentation for
	188	`goto-address-find-address-at-point'. If no address is found
	189	there, then load the URL at or before the position of the mouse click."
	190	(interactive "e")
	191	(save-excursion
f79538c9 DL	192	(mouse-set-point event)
f79538c9 DL	193	(goto-address-at-point)))
8749abea GM	194
	195	;;;###autoload
	196	(defun goto-address-at-point ()
	197	"Send to the e-mail address or load the URL at point.
	198	Send mail to address at point. See documentation for
	199	`goto-address-find-address-at-point'. If no address is found
	200	there, then load the URL at or before point."
	201	(interactive)
	202	(save-excursion
	203	(let ((address (save-excursion (goto-address-find-address-at-point))))
f79538c9 DL	204	(if address
	205	(compose-mail address)
	206	(let ((url (browse-url-url-at-point)))
	207	(if url
	208	(browse-url url)
	209	(error "No e-mail address or URL found")))))))
8749abea GM	210
	211	(defun goto-address-find-address-at-point ()
	212	"Find e-mail address around or before point.
	213	Then search backwards to beginning of line for the start of an e-mail
f79538c9 DL	214	address. If no e-mail address found, return nil."
	215	(re-search-backward "[^-_A-z0-9.@]" (line-beginning-position) 'lim)
	216	(if (or (looking-at goto-address-mail-regexp) ; already at start
	217	(and (re-search-forward goto-address-mail-regexp
	218	(line-end-position) 'lim)
	219	(goto-char (match-beginning 0))))
	220	(match-string-no-properties 0)))
8749abea GM	221
	222	;;;###autoload
	223	(defun goto-address ()
	224	"Sets up goto-address functionality in the current buffer.
	225	Allows user to use mouse/keyboard command to click to go to a URL
	226	or to send e-mail.
	227	By default, goto-address binds to mouse-2 and C-c RET.
	228
	229	Also fontifies the buffer appropriately (see `goto-address-fontify-p' and
	230	`goto-address-highlight-p' for more information)."
	231	(interactive)
8749abea GM	232	(if goto-address-highlight-p
	233	(goto-address-fontify)))
	234
	235	(provide 'goto-addr)
	236
	237	;;; goto-addr.el ends here.