[bpt/emacs.git] / lisp / ibuf-macs.el

;;; ibuf-macs.el --- macros for ibuffer

;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
;;   2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.

;; Author: Colin Walters <walters@verbum.org>
;; Maintainer: John Paul Wallington <jpw@gnu.org>
;; Created: 6 Dec 2001
;; Keywords: buffer, convenience
;; Package: ibuffer

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(eval-when-compile
  (require 'cl))

;; From Paul Graham's "ANSI Common Lisp", adapted for Emacs Lisp here.
(defmacro ibuffer-aif (test true-body &rest false-body)
  "Evaluate TRUE-BODY or FALSE-BODY depending on value of TEST.
If TEST returns non-nil, bind `it' to the value, and evaluate
TRUE-BODY.  Otherwise, evaluate forms in FALSE-BODY as if in `progn'.
Compare with `if'."
  (declare (indent 2))
  (let ((sym (make-symbol "ibuffer-aif-sym")))
    `(let ((,sym ,test))
       (if ,sym
	   (let ((it ,sym))
	     ,true-body)
	 (progn
	   ,@false-body)))))

(defmacro ibuffer-awhen (test &rest body)
  "Evaluate BODY if TEST returns non-nil.
During evaluation of body, bind `it' to the value returned by TEST."
  (declare (indent 1))
  `(ibuffer-aif ,test
       (progn ,@body)
     nil))

(defmacro ibuffer-save-marks (&rest body)
  "Save the marked status of the buffers and execute BODY; restore marks."
  (declare (indent 0))
  (let ((bufsym (make-symbol "bufsym")))
    `(let ((,bufsym (current-buffer))
	   (ibuffer-save-marks-tmp-mark-list (ibuffer-current-state-list)))
       (unwind-protect
	   (progn
	     (save-excursion
	       ,@body))
	 (with-current-buffer ,bufsym
	   (ibuffer-redisplay-engine
	    ;; Get rid of dead buffers
	    (delq nil
		  (mapcar #'(lambda (e) (when (buffer-live-p (car e))
					  e))
			  ibuffer-save-marks-tmp-mark-list)))
	   (ibuffer-redisplay t))))))

;;;###autoload
(defmacro* define-ibuffer-column (symbol (&key name inline props summarizer
					       header-mouse-map) &rest body)
  "Define a column SYMBOL for use with `ibuffer-formats'.

BODY will be called with `buffer' bound to the buffer object, and
`mark' bound to the current mark on the buffer.  The original ibuffer
buffer will be bound to `ibuffer-buf'.

If NAME is given, it will be used as a title for the column.
Otherwise, the title will default to a capitalized version of the
SYMBOL's name.  PROPS is a plist of additional properties to add to
the text, such as `mouse-face'.  And SUMMARIZER, if given, is a
function which will be passed a list of all the strings in its column;
it should return a string to display at the bottom.

If HEADER-MOUSE-MAP is given, it will be used as a keymap for the
title of the column.

Note that this macro expands into a `defun' for a function named
ibuffer-make-column-NAME.  If INLINE is non-nil, then the form will be
inlined into the compiled format versions.  This means that if you
change its definition, you should explicitly call
`ibuffer-recompile-formats'.

\(fn SYMBOL (&key NAME INLINE PROPS SUMMARIZER) &rest BODY)"
  (declare (indent defun))
  (let* ((sym (intern (concat "ibuffer-make-column-"
			      (symbol-name symbol))))
	 (bod-1 `(with-current-buffer buffer
		   ,@body))
	 (bod (if props
		  `(propertize
		    ,bod-1
		    ,@props)
		bod-1)))
    `(progn
       ,(if inline
	    `(push '(,sym ,bod) ibuffer-inline-columns)
	  `(defun ,sym (buffer mark)
	     ,bod))
       (put (quote ,sym) 'ibuffer-column-name
	    ,(if (stringp name)
		 name
	       (capitalize (symbol-name symbol))))
       ,(if header-mouse-map `(put (quote ,sym) 'header-mouse-map ,header-mouse-map))
       ,(if summarizer
	    ;; Store the name of the summarizing function.
	    `(put (quote ,sym) 'ibuffer-column-summarizer
		  (quote ,summarizer)))
       ,(if summarizer
	    ;; This will store the actual values of the column
	    ;; summary.
	    `(put (quote ,sym) 'ibuffer-column-summary nil))
       :autoload-end)))

;;;###autoload
(defmacro* define-ibuffer-sorter (name documentation
				       (&key
					description)
				       &rest body)
  "Define a method of sorting named NAME.
DOCUMENTATION is the documentation of the function, which will be called
`ibuffer-do-sort-by-NAME'.
DESCRIPTION is a short string describing the sorting method.

For sorting, the forms in BODY will be evaluated with `a' bound to one
buffer object, and `b' bound to another.  BODY should return a non-nil
value if and only if `a' is \"less than\" `b'.

\(fn NAME DOCUMENTATION (&key DESCRIPTION) &rest BODY)"
  (declare (indent 1))
  `(progn
     (defun ,(intern (concat "ibuffer-do-sort-by-" (symbol-name name))) ()
       ,(or documentation "No :documentation specified for this sorting method.")
       (interactive)
       (setq ibuffer-sorting-mode ',name)
       (when (eq ibuffer-sorting-mode ibuffer-last-sorting-mode)
	 (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep)))
       (ibuffer-redisplay t)
       (setq ibuffer-last-sorting-mode ',name))
     (push (list ',name ,description
		 #'(lambda (a b)
		     ,@body))
	   ibuffer-sorting-functions-alist)
     :autoload-end))

;;;###autoload
(defmacro* define-ibuffer-op (op args
				 documentation
				 (&key
				  interactive
				  mark
				  modifier-p
				  dangerous
				  (opstring "operated on")
				  (active-opstring "Operate on")
				  complex)
				 &rest body)
  "Generate a function which operates on a buffer.
OP becomes the name of the function; if it doesn't begin with
`ibuffer-do-', then that is prepended to it.
When an operation is performed, this function will be called once for
each marked buffer, with that buffer current.

ARGS becomes the formal parameters of the function.
DOCUMENTATION becomes the docstring of the function.
INTERACTIVE becomes the interactive specification of the function.
MARK describes which type of mark (:deletion, or nil) this operation
uses.  :deletion means the function operates on buffers marked for
deletion, otherwise it acts on normally marked buffers.
MODIFIER-P describes how the function modifies buffers.  This is used
to set the modification flag of the Ibuffer buffer itself.  Valid
values are:
 nil - the function never modifiers buffers
 t - the function it always modifies buffers
 :maybe - attempt to discover this information by comparing the
  buffer's modification flag.
DANGEROUS is a boolean which should be set if the user should be
prompted before performing this operation.
OPSTRING is a string which will be displayed to the user after the
operation is complete, in the form:
 \"Operation complete; OPSTRING x buffers\"
ACTIVE-OPSTRING is a string which will be displayed to the user in a
confirmation message, in the form:
 \"Really ACTIVE-OPSTRING x buffers?\"
COMPLEX means this function is special; see the source code of this
macro for exactly what it does.

\(fn OP ARGS DOCUMENTATION (&key INTERACTIVE MARK MODIFIER-P DANGEROUS OPSTRING ACTIVE-OPSTRING COMPLEX) &rest BODY)"
  (declare (indent 2))
  `(progn
     (defun ,(intern (concat (if (string-match "^ibuffer-do" (symbol-name op))
				 "" "ibuffer-do-") (symbol-name op)))
       ,args
       ,(if (stringp documentation)
	    documentation
	  (format "%s marked buffers." active-opstring))
       ,(if (not (null interactive))
	    `(interactive ,interactive)
	  '(interactive))
       (assert (derived-mode-p 'ibuffer-mode))
       (setq ibuffer-did-modification nil)
       (let ((marked-names  (,(case mark
				(:deletion
				 'ibuffer-deletion-marked-buffer-names)
				(t
				 'ibuffer-marked-buffer-names)))))
	 (when (null marked-names)
	   (setq marked-names (list (buffer-name (ibuffer-current-buffer))))
	   (ibuffer-set-mark ,(case mark
				(:deletion
				 'ibuffer-deletion-char)
				(t
				 'ibuffer-marked-char))))
	 ,(let* ((finish (append
			  '(progn)
			  (if (eq modifier-p t)
			      '((setq ibuffer-did-modification t))
			    ())
			  `((ibuffer-redisplay t)
			    (message ,(concat "Operation finished; " opstring " %s buffers") count))))
		 (inner-body (if complex
				 `(progn ,@body)
			       `(progn
				  (with-current-buffer buf
				    (save-excursion
				      ,@body))
				  t)))
		 (body `(let ((count
			       (,(case mark
				   (:deletion
				    'ibuffer-map-deletion-lines)
				   (t
				    'ibuffer-map-marked-lines))
				#'(lambda (buf mark)
				    ,(if (eq modifier-p :maybe)
					 `(let ((ibuffer-tmp-previous-buffer-modification
						 (buffer-modified-p buf)))
					    (prog1 ,inner-body
					      (when (not (eq ibuffer-tmp-previous-buffer-modification
							     (buffer-modified-p buf)))
						(setq ibuffer-did-modification t))))
				       inner-body)))))
			  ,finish)))
	    (if dangerous
		`(when (ibuffer-confirm-operation-on ,active-opstring marked-names)
		   ,body)
	      body))))
     :autoload-end))

;;;###autoload
(defmacro* define-ibuffer-filter (name documentation
				       (&key
					reader
					description)
				       &rest body)
  "Define a filter named NAME.
DOCUMENTATION is the documentation of the function.
READER is a form which should read a qualifier from the user.
DESCRIPTION is a short string describing the filter.

BODY should contain forms which will be evaluated to test whether or
not a particular buffer should be displayed or not.  The forms in BODY
will be evaluated with BUF bound to the buffer object, and QUALIFIER
bound to the current value of the filter.

\(fn NAME DOCUMENTATION (&key READER DESCRIPTION) &rest BODY)"
  (declare (indent 2))
  (let ((fn-name (intern (concat "ibuffer-filter-by-" (symbol-name name)))))
    `(progn
       (defun ,fn-name (qualifier)
	 ,(or documentation "This filter is not documented.")
	 (interactive (list ,reader))
	 (ibuffer-push-filter (cons ',name qualifier))
	 (message "%s"
		  (format ,(concat (format "Filter by %s added: " description)
				   " %s")
			  qualifier))
	 (ibuffer-update nil t))
       (push (list ',name ,description
		   #'(lambda (buf qualifier)
		       ,@body))
	     ibuffer-filtering-alist)
       :autoload-end)))

(provide 'ibuf-macs)

;;; ibuf-macs.el ends here
Commit	Line	Data
25d2f683 CW	1	;;; ibuf-macs.el --- macros for ibuffer
25d2f683 CW	2
0d30b337	3	;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
5df4f04c	4	;; 2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
25d2f683 CW	5
25d2f683 CW	6	;; Author: Colin Walters <walters@verbum.org>
4e4a724c	7	;; Maintainer: John Paul Wallington <jpw@gnu.org>
25d2f683	8	;; Created: 6 Dec 2001
25d2f683	9	;; Keywords: buffer, convenience
aad4679e	10	;; Package: ibuffer
25d2f683	11
76649361	12	;; This file is part of GNU Emacs.
25d2f683	13
eb3fa2cf GM	14	;; GNU Emacs is free software: you can redistribute it and/or modify
	15	;; it under the terms of the GNU General Public License as published by
	16	;; the Free Software Foundation, either version 3 of the License, or
	17	;; (at your option) any later version.
25d2f683	18
eb3fa2cf GM	19	;; GNU Emacs is distributed in the hope that it will be useful,
	20	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	21	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	22	;; GNU General Public License for more details.
25d2f683 CW	23
25d2f683 CW	24	;; You should have received a copy of the GNU General Public License
eb3fa2cf	25	;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
25d2f683	26
30764597 PJ	27	;;; Commentary:
30764597 PJ	28
25d2f683 CW	29	;;; Code:
25d2f683 CW	30
00332656 CW	31	(eval-when-compile
	32	(require 'cl))
	33
25d2f683 CW	34	;; From Paul Graham's "ANSI Common Lisp", adapted for Emacs Lisp here.
	35	(defmacro ibuffer-aif (test true-body &rest false-body)
	36	"Evaluate TRUE-BODY or FALSE-BODY depending on value of TEST.
	37	If TEST returns non-nil, bind `it' to the value, and evaluate
	38	TRUE-BODY. Otherwise, evaluate forms in FALSE-BODY as if in `progn'.
	39	Compare with `if'."
4e02f55c	40	(declare (indent 2))
28528604	41	(let ((sym (make-symbol "ibuffer-aif-sym")))
25d2f683 CW	42	`(let ((,sym ,test))
	43	(if ,sym
	44	(let ((it ,sym))
	45	,true-body)
	46	(progn
	47	,@false-body)))))
25d2f683 CW	48
	49	(defmacro ibuffer-awhen (test &rest body)
	50	"Evaluate BODY if TEST returns non-nil.
	51	During evaluation of body, bind `it' to the value returned by TEST."
4e02f55c	52	(declare (indent 1))
25d2f683 CW	53	`(ibuffer-aif ,test
	54	(progn ,@body)
	55	nil))
25d2f683 CW	56
	57	(defmacro ibuffer-save-marks (&rest body)
	58	"Save the marked status of the buffers and execute BODY; restore marks."
4e02f55c	59	(declare (indent 0))
28528604	60	(let ((bufsym (make-symbol "bufsym")))
25d2f683 CW	61	`(let ((,bufsym (current-buffer))
	62	(ibuffer-save-marks-tmp-mark-list (ibuffer-current-state-list)))
	63	(unwind-protect
	64	(progn
	65	(save-excursion
	66	,@body))
	67	(with-current-buffer ,bufsym
76649361	68	(ibuffer-redisplay-engine
25d2f683 CW	69	;; Get rid of dead buffers
	70	(delq nil
	71	(mapcar #'(lambda (e) (when (buffer-live-p (car e))
	72	e))
	73	ibuffer-save-marks-tmp-mark-list)))
	74	(ibuffer-redisplay t))))))
25d2f683 CW	75
25d2f683 CW	76	;;;###autoload
4e02f55c	77	(defmacro* define-ibuffer-column (symbol (&key name inline props summarizer
f0b31589	78	header-mouse-map) &rest body)
25d2f683 CW	79	"Define a column SYMBOL for use with `ibuffer-formats'.
	80
	81	BODY will be called with `buffer' bound to the buffer object, and
1bb57048 CW	82	`mark' bound to the current mark on the buffer. The original ibuffer
1bb57048 CW	83	buffer will be bound to `ibuffer-buf'.
25d2f683 CW	84
	85	If NAME is given, it will be used as a title for the column.
	86	Otherwise, the title will default to a capitalized version of the
	87	SYMBOL's name. PROPS is a plist of additional properties to add to
1255dfe6 CW	88	the text, such as `mouse-face'. And SUMMARIZER, if given, is a
	89	function which will be passed a list of all the strings in its column;
	90	it should return a string to display at the bottom.
25d2f683	91
b641fbd7 DN	92	If HEADER-MOUSE-MAP is given, it will be used as a keymap for the
	93	title of the column.
	94
25d2f683 CW	95	Note that this macro expands into a `defun' for a function named
	96	ibuffer-make-column-NAME. If INLINE is non-nil, then the form will be
	97	inlined into the compiled format versions. This means that if you
	98	change its definition, you should explicitly call
9bb69f45 JB	99	`ibuffer-recompile-formats'.
	100
	101	\(fn SYMBOL (&key NAME INLINE PROPS SUMMARIZER) &rest BODY)"
4e02f55c	102	(declare (indent defun))
25d2f683 CW	103	(let* ((sym (intern (concat "ibuffer-make-column-"
25d2f683 CW	104	(symbol-name symbol))))
ceb44935	105	(bod-1 `(with-current-buffer buffer
25d2f683 CW	106	,@body))
25d2f683 CW	107	(bod (if props
4e02f55c JPW	108	`(propertize
	109	,bod-1
	110	,@props)
25d2f683 CW	111	bod-1)))
	112	`(progn
	113	,(if inline
	114	`(push '(,sym ,bod) ibuffer-inline-columns)
d62920ca	115	`(defun ,sym (buffer mark)
25d2f683 CW	116	,bod))
	117	(put (quote ,sym) 'ibuffer-column-name
	118	,(if (stringp name)
	119	name
	120	(capitalize (symbol-name symbol))))
f0b31589	121	,(if header-mouse-map `(put (quote ,sym) 'header-mouse-map ,header-mouse-map))
1255dfe6	122	,(if summarizer
ceb44935	123	;; Store the name of the summarizing function.
1255dfe6 CW	124	`(put (quote ,sym) 'ibuffer-column-summarizer
	125	(quote ,summarizer)))
	126	,(if summarizer
ceb44935 CW	127	;; This will store the actual values of the column
	128	;; summary.
	129	`(put (quote ,sym) 'ibuffer-column-summary nil))
25d2f683	130	:autoload-end)))
25d2f683 CW	131
	132	;;;###autoload
	133	(defmacro* define-ibuffer-sorter (name documentation
71296446	134	(&key
25d2f683 CW	135	description)
	136	&rest body)
	137	"Define a method of sorting named NAME.
	138	DOCUMENTATION is the documentation of the function, which will be called
	139	`ibuffer-do-sort-by-NAME'.
	140	DESCRIPTION is a short string describing the sorting method.
	141
	142	For sorting, the forms in BODY will be evaluated with `a' bound to one
	143	buffer object, and `b' bound to another. BODY should return a non-nil
9bb69f45 JB	144	value if and only if `a' is \"less than\" `b'.
	145
	146	\(fn NAME DOCUMENTATION (&key DESCRIPTION) &rest BODY)"
4e02f55c	147	(declare (indent 1))
25d2f683 CW	148	`(progn
	149	(defun ,(intern (concat "ibuffer-do-sort-by-" (symbol-name name))) ()
	150	,(or documentation "No :documentation specified for this sorting method.")
	151	(interactive)
	152	(setq ibuffer-sorting-mode ',name)
e3b71439 JPW	153	(when (eq ibuffer-sorting-mode ibuffer-last-sorting-mode)
	154	(setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep)))
	155	(ibuffer-redisplay t)
	156	(setq ibuffer-last-sorting-mode ',name))
25d2f683 CW	157	(push (list ',name ,description
	158	#'(lambda (a b)
	159	,@body))
	160	ibuffer-sorting-functions-alist)
	161	:autoload-end))
25d2f683 CW	162
	163	;;;###autoload
	164	(defmacro* define-ibuffer-op (op args
	165	documentation
71296446	166	(&key
25d2f683 CW	167	interactive
	168	mark
	169	modifier-p
	170	dangerous
	171	(opstring "operated on")
	172	(active-opstring "Operate on")
	173	complex)
	174	&rest body)
1bb57048 CW	175	"Generate a function which operates on a buffer.
	176	OP becomes the name of the function; if it doesn't begin with
	177	`ibuffer-do-', then that is prepended to it.
25d2f683 CW	178	When an operation is performed, this function will be called once for
	179	each marked buffer, with that buffer current.
	180
	181	ARGS becomes the formal parameters of the function.
	182	DOCUMENTATION becomes the docstring of the function.
	183	INTERACTIVE becomes the interactive specification of the function.
	184	MARK describes which type of mark (:deletion, or nil) this operation
	185	uses. :deletion means the function operates on buffers marked for
	186	deletion, otherwise it acts on normally marked buffers.
	187	MODIFIER-P describes how the function modifies buffers. This is used
	188	to set the modification flag of the Ibuffer buffer itself. Valid
	189	values are:
	190	nil - the function never modifiers buffers
	191	t - the function it always modifies buffers
	192	:maybe - attempt to discover this information by comparing the
	193	buffer's modification flag.
	194	DANGEROUS is a boolean which should be set if the user should be
	195	prompted before performing this operation.
	196	OPSTRING is a string which will be displayed to the user after the
	197	operation is complete, in the form:
	198	\"Operation complete; OPSTRING x buffers\"
	199	ACTIVE-OPSTRING is a string which will be displayed to the user in a
	200	confirmation message, in the form:
	201	\"Really ACTIVE-OPSTRING x buffers?\"
	202	COMPLEX means this function is special; see the source code of this
9bb69f45 JB	203	macro for exactly what it does.
	204
	205	\(fn OP ARGS DOCUMENTATION (&key INTERACTIVE MARK MODIFIER-P DANGEROUS OPSTRING ACTIVE-OPSTRING COMPLEX) &rest BODY)"
4e02f55c	206	(declare (indent 2))
25d2f683	207	`(progn
4e02f55c JPW	208	(defun ,(intern (concat (if (string-match "^ibuffer-do" (symbol-name op))
	209	"" "ibuffer-do-") (symbol-name op)))
	210	,args
	211	,(if (stringp documentation)
	212	documentation
	213	(format "%s marked buffers." active-opstring))
	214	,(if (not (null interactive))
	215	`(interactive ,interactive)
	216	'(interactive))
	217	(assert (derived-mode-p 'ibuffer-mode))
	218	(setq ibuffer-did-modification nil)
	219	(let ((marked-names (,(case mark
	220	(:deletion
	221	'ibuffer-deletion-marked-buffer-names)
	222	(t
	223	'ibuffer-marked-buffer-names)))))
	224	(when (null marked-names)
	225	(setq marked-names (list (buffer-name (ibuffer-current-buffer))))
	226	(ibuffer-set-mark ,(case mark
	227	(:deletion
	228	'ibuffer-deletion-char)
	229	(t
	230	'ibuffer-marked-char))))
	231	,(let* ((finish (append
	232	'(progn)
	233	(if (eq modifier-p t)
	234	'((setq ibuffer-did-modification t))
	235	())
	236	`((ibuffer-redisplay t)
	237	(message ,(concat "Operation finished; " opstring " %s buffers") count))))
	238	(inner-body (if complex
	239	`(progn ,@body)
	240	`(progn
	241	(with-current-buffer buf
	242	(save-excursion
	243	,@body))
	244	t)))
	245	(body `(let ((count
	246	(,(case mark
	247	(:deletion
	248	'ibuffer-map-deletion-lines)
	249	(t
	250	'ibuffer-map-marked-lines))
	251	#'(lambda (buf mark)
	252	,(if (eq modifier-p :maybe)
	253	`(let ((ibuffer-tmp-previous-buffer-modification
	254	(buffer-modified-p buf)))
	255	(prog1 ,inner-body
	256	(when (not (eq ibuffer-tmp-previous-buffer-modification
	257	(buffer-modified-p buf)))
	258	(setq ibuffer-did-modification t))))
	259	inner-body)))))
	260	,finish)))
	261	(if dangerous
	262	`(when (ibuffer-confirm-operation-on ,active-opstring marked-names)
	263	,body)
	264	body))))
	265	:autoload-end))
25d2f683 CW	266
	267	;;;###autoload
	268	(defmacro* define-ibuffer-filter (name documentation
71296446	269	(&key
25d2f683 CW	270	reader
	271	description)
	272	&rest body)
	273	"Define a filter named NAME.
	274	DOCUMENTATION is the documentation of the function.
	275	READER is a form which should read a qualifier from the user.
	276	DESCRIPTION is a short string describing the filter.
	277
	278	BODY should contain forms which will be evaluated to test whether or
	279	not a particular buffer should be displayed or not. The forms in BODY
	280	will be evaluated with BUF bound to the buffer object, and QUALIFIER
9bb69f45 JB	281	bound to the current value of the filter.
	282
	283	\(fn NAME DOCUMENTATION (&key READER DESCRIPTION) &rest BODY)"
4e02f55c	284	(declare (indent 2))
25d2f683	285	(let ((fn-name (intern (concat "ibuffer-filter-by-" (symbol-name name)))))
71296446	286	`(progn
25d2f683	287	(defun ,fn-name (qualifier)
4e02f55c	288	,(or documentation "This filter is not documented.")
25d2f683 CW	289	(interactive (list ,reader))
25d2f683 CW	290	(ibuffer-push-filter (cons ',name qualifier))
8a26c165	291	(message "%s"
4e02f55c JPW	292	(format ,(concat (format "Filter by %s added: " description)
	293	" %s")
	294	qualifier))
25d2f683 CW	295	(ibuffer-update nil t))
	296	(push (list ',name ,description
	297	#'(lambda (buf qualifier)
	298	,@body))
	299	ibuffer-filtering-alist)
	300	:autoload-end)))
25d2f683 CW	301
	302	(provide 'ibuf-macs)
	303
	304	;;; ibuf-macs.el ends here