[bpt/emacs.git] / lisp / ibuf-macs.el

;;; ibuf-macs.el --- macros for ibuffer

;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.

;; Author: Colin Walters <walters@verbum.org>
;; Maintainer: John Paul Wallington <jpw@gnu.org>
;; Created: 6 Dec 2001
;; Keywords: buffer, convenience

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(eval-when-compile
  (require 'cl))

;; From Paul Graham's "ANSI Common Lisp", adapted for Emacs Lisp here.
(defmacro ibuffer-aif (test true-body &rest false-body)
  "Evaluate TRUE-BODY or FALSE-BODY depending on value of TEST.
If TEST returns non-nil, bind `it' to the value, and evaluate
TRUE-BODY.  Otherwise, evaluate forms in FALSE-BODY as if in `progn'.
Compare with `if'."
  (let ((sym (make-symbol "ibuffer-aif-sym")))
    `(let ((,sym ,test))
       (if ,sym
	   (let ((it ,sym))
	     ,true-body)
	 (progn
	   ,@false-body)))))
;; (put 'ibuffer-aif 'lisp-indent-function 2)

(defmacro ibuffer-awhen (test &rest body)
  "Evaluate BODY if TEST returns non-nil.
During evaluation of body, bind `it' to the value returned by TEST."
  `(ibuffer-aif ,test
       (progn ,@body)
     nil))
;; (put 'ibuffer-awhen 'lisp-indent-function 1)

(defmacro ibuffer-save-marks (&rest body)
  "Save the marked status of the buffers and execute BODY; restore marks."
  (let ((bufsym (make-symbol "bufsym")))
    `(let ((,bufsym (current-buffer))
	   (ibuffer-save-marks-tmp-mark-list (ibuffer-current-state-list)))
       (unwind-protect
	   (progn
	     (save-excursion
	       ,@body))
	 (with-current-buffer ,bufsym
	   (ibuffer-redisplay-engine
	    ;; Get rid of dead buffers
	    (delq nil
		  (mapcar #'(lambda (e) (when (buffer-live-p (car e))
					  e))
			  ibuffer-save-marks-tmp-mark-list)))
	   (ibuffer-redisplay t))))))
;; (put 'ibuffer-save-marks 'lisp-indent-function 0)

;;;###autoload
(defmacro* define-ibuffer-column (symbol (&key name inline props summarizer 
					       header-mouse-map) &rest body)
  "Define a column SYMBOL for use with `ibuffer-formats'.

BODY will be called with `buffer' bound to the buffer object, and
`mark' bound to the current mark on the buffer.  The original ibuffer
buffer will be bound to `ibuffer-buf'.

If NAME is given, it will be used as a title for the column.
Otherwise, the title will default to a capitalized version of the
SYMBOL's name.  PROPS is a plist of additional properties to add to
the text, such as `mouse-face'.  And SUMMARIZER, if given, is a
function which will be passed a list of all the strings in its column;
it should return a string to display at the bottom.

If HEADER-MOUSE-MAP is given, it will be used as a keymap for the
title of the column.

Note that this macro expands into a `defun' for a function named
ibuffer-make-column-NAME.  If INLINE is non-nil, then the form will be
inlined into the compiled format versions.  This means that if you
change its definition, you should explicitly call
`ibuffer-recompile-formats'.

\(fn SYMBOL (&key NAME INLINE PROPS SUMMARIZER) &rest BODY)"
  (let* ((sym (intern (concat "ibuffer-make-column-"
			      (symbol-name symbol))))
	 (bod-1 `(with-current-buffer buffer
		   ,@body))
	 (bod (if props
		 `(propertize
		   ,bod-1
		   ,@props)
		bod-1)))
    `(progn
       ,(if inline
	    `(push '(,sym ,bod) ibuffer-inline-columns)
	  `(defun ,sym (buffer mark)
	     ,bod))
       (put (quote ,sym) 'ibuffer-column-name
	    ,(if (stringp name)
		 name
	       (capitalize (symbol-name symbol))))
       ,(if header-mouse-map `(put (quote ,sym) 'header-mouse-map ,header-mouse-map))
       ,(if summarizer
	    ;; Store the name of the summarizing function.
	    `(put (quote ,sym) 'ibuffer-column-summarizer
		  (quote ,summarizer)))
       ,(if summarizer
	    ;; This will store the actual values of the column
	    ;; summary.
	    `(put (quote ,sym) 'ibuffer-column-summary nil))
       :autoload-end)))
;; (put 'define-ibuffer-column 'lisp-indent-function 'defun)

;;;###autoload
(defmacro* define-ibuffer-sorter (name documentation
				       (&key
					description)
				       &rest body)
  "Define a method of sorting named NAME.
DOCUMENTATION is the documentation of the function, which will be called
`ibuffer-do-sort-by-NAME'.
DESCRIPTION is a short string describing the sorting method.

For sorting, the forms in BODY will be evaluated with `a' bound to one
buffer object, and `b' bound to another.  BODY should return a non-nil
value if and only if `a' is \"less than\" `b'.

\(fn NAME DOCUMENTATION (&key DESCRIPTION) &rest BODY)"
  `(progn
     (defun ,(intern (concat "ibuffer-do-sort-by-" (symbol-name name))) ()
       ,(or documentation "No :documentation specified for this sorting method.")
       (interactive)
       (setq ibuffer-sorting-mode ',name)
       (when (eq ibuffer-sorting-mode ibuffer-last-sorting-mode)
	 (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep)))
       (ibuffer-redisplay t)
       (setq ibuffer-last-sorting-mode ',name))
     (push (list ',name ,description
		 #'(lambda (a b)
		     ,@body))
	   ibuffer-sorting-functions-alist)
     :autoload-end))
;; (put 'define-ibuffer-sorter 'lisp-indent-function 1)

;;;###autoload
(defmacro* define-ibuffer-op (op args
				 documentation
				 (&key
				  interactive
				  mark
				  modifier-p
				  dangerous
				  (opstring "operated on")
				  (active-opstring "Operate on")
				  complex)
				 &rest body)
  "Generate a function which operates on a buffer.
OP becomes the name of the function; if it doesn't begin with
`ibuffer-do-', then that is prepended to it.
When an operation is performed, this function will be called once for
each marked buffer, with that buffer current.

ARGS becomes the formal parameters of the function.
DOCUMENTATION becomes the docstring of the function.
INTERACTIVE becomes the interactive specification of the function.
MARK describes which type of mark (:deletion, or nil) this operation
uses.  :deletion means the function operates on buffers marked for
deletion, otherwise it acts on normally marked buffers.
MODIFIER-P describes how the function modifies buffers.  This is used
to set the modification flag of the Ibuffer buffer itself.  Valid
values are:
 nil - the function never modifiers buffers
 t - the function it always modifies buffers
 :maybe - attempt to discover this information by comparing the
  buffer's modification flag.
DANGEROUS is a boolean which should be set if the user should be
prompted before performing this operation.
OPSTRING is a string which will be displayed to the user after the
operation is complete, in the form:
 \"Operation complete; OPSTRING x buffers\"
ACTIVE-OPSTRING is a string which will be displayed to the user in a
confirmation message, in the form:
 \"Really ACTIVE-OPSTRING x buffers?\"
COMPLEX means this function is special; see the source code of this
macro for exactly what it does.

\(fn OP ARGS DOCUMENTATION (&key INTERACTIVE MARK MODIFIER-P DANGEROUS OPSTRING ACTIVE-OPSTRING COMPLEX) &rest BODY)"
  `(progn
    (defun ,(intern (concat (if (string-match "^ibuffer-do" (symbol-name op))
				"" "ibuffer-do-") (symbol-name op)))
      ,args
     ,(if (stringp documentation)
	  documentation
	(format "%s marked buffers." active-opstring))
     ,(if (not (null interactive))
	  `(interactive ,interactive)
	'(interactive))
     (assert (eq major-mode 'ibuffer-mode))
     (setq ibuffer-did-modification nil)
     (let ((marked-names  (,(case mark
			      (:deletion
			       'ibuffer-deletion-marked-buffer-names)
			      (t
			       'ibuffer-marked-buffer-names)))))
       (when (null marked-names)
	 (setq marked-names (list (buffer-name (ibuffer-current-buffer))))
	 (ibuffer-set-mark ,(case mark
			      (:deletion
			       'ibuffer-deletion-char)
			      (t
			       'ibuffer-marked-char))))
       ,(let* ((finish (append
			'(progn)
			(if (eq modifier-p t)
			    '((setq ibuffer-did-modification t))
			  ())
			`((ibuffer-redisplay t)
			  (message ,(concat "Operation finished; " opstring " %s buffers") count))))
	       (inner-body (if complex
			       `(progn ,@body)
			     `(progn
				(with-current-buffer buf
				  (save-excursion
				    ,@body))
				t)))
	       (body `(let ((count
			     (,(case mark
				 (:deletion
				  'ibuffer-map-deletion-lines)
				 (t
				  'ibuffer-map-marked-lines))
			      #'(lambda (buf mark)
				  ,(if (eq modifier-p :maybe)
				       `(let ((ibuffer-tmp-previous-buffer-modification
					       (buffer-modified-p buf)))
					  (prog1 ,inner-body
					    (when (not (eq ibuffer-tmp-previous-buffer-modification
							   (buffer-modified-p buf)))
					      (setq ibuffer-did-modification t))))
				     inner-body)))))
			,finish)))
	  (if dangerous
	      `(when (ibuffer-confirm-operation-on ,active-opstring marked-names)
		 ,body)
	    body))))
    :autoload-end))
;; (put 'define-ibuffer-op 'lisp-indent-function 2)

;;;###autoload
(defmacro* define-ibuffer-filter (name documentation
				       (&key
					reader
					description)
				       &rest body)
  "Define a filter named NAME.
DOCUMENTATION is the documentation of the function.
READER is a form which should read a qualifier from the user.
DESCRIPTION is a short string describing the filter.

BODY should contain forms which will be evaluated to test whether or
not a particular buffer should be displayed or not.  The forms in BODY
will be evaluated with BUF bound to the buffer object, and QUALIFIER
bound to the current value of the filter.

\(fn NAME DOCUMENTATION (&key READER DESCRIPTION) &rest BODY)"
  (let ((fn-name (intern (concat "ibuffer-filter-by-" (symbol-name name)))))
    `(progn
       (defun ,fn-name (qualifier)
	 ,(concat (or documentation "This filter is not documented."))
	 (interactive (list ,reader))
	 (ibuffer-push-filter (cons ',name qualifier))
	 (message "%s"
	  (format ,(concat (format "Filter by %s added: " description)
			   " %s")
		  qualifier))
	 (ibuffer-update nil t))
       (push (list ',name ,description
		   #'(lambda (buf qualifier)
		       ,@body))
	     ibuffer-filtering-alist)
       :autoload-end)))
;; (put 'define-ibuffer-filter 'lisp-indent-function 2)

(provide 'ibuf-macs)

;; arch-tag: 2748edce-82c9-4cd9-9d9d-bd73e43c20c5
;;; ibuf-macs.el ends here
Commit	Line	Data
25d2f683 CW	1	;;; ibuf-macs.el --- macros for ibuffer
25d2f683 CW	2
0d30b337	3	;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
409cc4a3	4	;; 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
25d2f683 CW	5
25d2f683 CW	6	;; Author: Colin Walters <walters@verbum.org>
4e4a724c	7	;; Maintainer: John Paul Wallington <jpw@gnu.org>
25d2f683	8	;; Created: 6 Dec 2001
25d2f683 CW	9	;; Keywords: buffer, convenience
25d2f683 CW	10
76649361	11	;; This file is part of GNU Emacs.
25d2f683	12
eb3fa2cf GM	13	;; GNU Emacs is free software: you can redistribute it and/or modify
	14	;; it under the terms of the GNU General Public License as published by
	15	;; the Free Software Foundation, either version 3 of the License, or
	16	;; (at your option) any later version.
25d2f683	17
eb3fa2cf GM	18	;; GNU Emacs is distributed in the hope that it will be useful,
	19	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	20	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	21	;; GNU General Public License for more details.
25d2f683 CW	22
25d2f683 CW	23	;; You should have received a copy of the GNU General Public License
eb3fa2cf	24	;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
25d2f683	25
30764597 PJ	26	;;; Commentary:
30764597 PJ	27
25d2f683 CW	28	;;; Code:
25d2f683 CW	29
00332656 CW	30	(eval-when-compile
	31	(require 'cl))
	32
25d2f683 CW	33	;; From Paul Graham's "ANSI Common Lisp", adapted for Emacs Lisp here.
	34	(defmacro ibuffer-aif (test true-body &rest false-body)
	35	"Evaluate TRUE-BODY or FALSE-BODY depending on value of TEST.
	36	If TEST returns non-nil, bind `it' to the value, and evaluate
	37	TRUE-BODY. Otherwise, evaluate forms in FALSE-BODY as if in `progn'.
	38	Compare with `if'."
28528604	39	(let ((sym (make-symbol "ibuffer-aif-sym")))
25d2f683 CW	40	`(let ((,sym ,test))
	41	(if ,sym
	42	(let ((it ,sym))
	43	,true-body)
	44	(progn
	45	,@false-body)))))
	46	;; (put 'ibuffer-aif 'lisp-indent-function 2)
	47
	48	(defmacro ibuffer-awhen (test &rest body)
	49	"Evaluate BODY if TEST returns non-nil.
	50	During evaluation of body, bind `it' to the value returned by TEST."
	51	`(ibuffer-aif ,test
	52	(progn ,@body)
	53	nil))
	54	;; (put 'ibuffer-awhen 'lisp-indent-function 1)
	55
	56	(defmacro ibuffer-save-marks (&rest body)
	57	"Save the marked status of the buffers and execute BODY; restore marks."
28528604	58	(let ((bufsym (make-symbol "bufsym")))
25d2f683 CW	59	`(let ((,bufsym (current-buffer))
	60	(ibuffer-save-marks-tmp-mark-list (ibuffer-current-state-list)))
	61	(unwind-protect
	62	(progn
	63	(save-excursion
	64	,@body))
	65	(with-current-buffer ,bufsym
76649361	66	(ibuffer-redisplay-engine
25d2f683 CW	67	;; Get rid of dead buffers
	68	(delq nil
	69	(mapcar #'(lambda (e) (when (buffer-live-p (car e))
	70	e))
	71	ibuffer-save-marks-tmp-mark-list)))
	72	(ibuffer-redisplay t))))))
	73	;; (put 'ibuffer-save-marks 'lisp-indent-function 0)
	74
	75	;;;###autoload
f0b31589 DN	76	(defmacro* define-ibuffer-column (symbol (&key name inline props summarizer
f0b31589 DN	77	header-mouse-map) &rest body)
25d2f683 CW	78	"Define a column SYMBOL for use with `ibuffer-formats'.
	79
	80	BODY will be called with `buffer' bound to the buffer object, and
1bb57048 CW	81	`mark' bound to the current mark on the buffer. The original ibuffer
1bb57048 CW	82	buffer will be bound to `ibuffer-buf'.
25d2f683 CW	83
	84	If NAME is given, it will be used as a title for the column.
	85	Otherwise, the title will default to a capitalized version of the
	86	SYMBOL's name. PROPS is a plist of additional properties to add to
1255dfe6 CW	87	the text, such as `mouse-face'. And SUMMARIZER, if given, is a
	88	function which will be passed a list of all the strings in its column;
	89	it should return a string to display at the bottom.
25d2f683	90
b641fbd7 DN	91	If HEADER-MOUSE-MAP is given, it will be used as a keymap for the
	92	title of the column.
	93
25d2f683 CW	94	Note that this macro expands into a `defun' for a function named
	95	ibuffer-make-column-NAME. If INLINE is non-nil, then the form will be
	96	inlined into the compiled format versions. This means that if you
	97	change its definition, you should explicitly call
9bb69f45 JB	98	`ibuffer-recompile-formats'.
	99
	100	\(fn SYMBOL (&key NAME INLINE PROPS SUMMARIZER) &rest BODY)"
25d2f683 CW	101	(let* ((sym (intern (concat "ibuffer-make-column-"
25d2f683 CW	102	(symbol-name symbol))))
ceb44935	103	(bod-1 `(with-current-buffer buffer
25d2f683 CW	104	,@body))
	105	(bod (if props
	106	`(propertize
	107	,bod-1
	108	,@props)
	109	bod-1)))
	110	`(progn
	111	,(if inline
	112	`(push '(,sym ,bod) ibuffer-inline-columns)
d62920ca	113	`(defun ,sym (buffer mark)
25d2f683 CW	114	,bod))
	115	(put (quote ,sym) 'ibuffer-column-name
	116	,(if (stringp name)
	117	name
	118	(capitalize (symbol-name symbol))))
f0b31589	119	,(if header-mouse-map `(put (quote ,sym) 'header-mouse-map ,header-mouse-map))
1255dfe6	120	,(if summarizer
ceb44935	121	;; Store the name of the summarizing function.
1255dfe6 CW	122	`(put (quote ,sym) 'ibuffer-column-summarizer
	123	(quote ,summarizer)))
	124	,(if summarizer
ceb44935 CW	125	;; This will store the actual values of the column
	126	;; summary.
	127	`(put (quote ,sym) 'ibuffer-column-summary nil))
25d2f683 CW	128	:autoload-end)))
	129	;; (put 'define-ibuffer-column 'lisp-indent-function 'defun)
	130
	131	;;;###autoload
	132	(defmacro* define-ibuffer-sorter (name documentation
71296446	133	(&key
25d2f683 CW	134	description)
	135	&rest body)
	136	"Define a method of sorting named NAME.
	137	DOCUMENTATION is the documentation of the function, which will be called
	138	`ibuffer-do-sort-by-NAME'.
	139	DESCRIPTION is a short string describing the sorting method.
	140
	141	For sorting, the forms in BODY will be evaluated with `a' bound to one
	142	buffer object, and `b' bound to another. BODY should return a non-nil
9bb69f45 JB	143	value if and only if `a' is \"less than\" `b'.
	144
	145	\(fn NAME DOCUMENTATION (&key DESCRIPTION) &rest BODY)"
25d2f683 CW	146	`(progn
	147	(defun ,(intern (concat "ibuffer-do-sort-by-" (symbol-name name))) ()
	148	,(or documentation "No :documentation specified for this sorting method.")
	149	(interactive)
	150	(setq ibuffer-sorting-mode ',name)
e3b71439 JPW	151	(when (eq ibuffer-sorting-mode ibuffer-last-sorting-mode)
	152	(setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep)))
	153	(ibuffer-redisplay t)
	154	(setq ibuffer-last-sorting-mode ',name))
25d2f683 CW	155	(push (list ',name ,description
	156	#'(lambda (a b)
	157	,@body))
	158	ibuffer-sorting-functions-alist)
	159	:autoload-end))
	160	;; (put 'define-ibuffer-sorter 'lisp-indent-function 1)
	161
	162	;;;###autoload
	163	(defmacro* define-ibuffer-op (op args
	164	documentation
71296446	165	(&key
25d2f683 CW	166	interactive
	167	mark
	168	modifier-p
	169	dangerous
	170	(opstring "operated on")
	171	(active-opstring "Operate on")
	172	complex)
	173	&rest body)
1bb57048 CW	174	"Generate a function which operates on a buffer.
	175	OP becomes the name of the function; if it doesn't begin with
	176	`ibuffer-do-', then that is prepended to it.
25d2f683 CW	177	When an operation is performed, this function will be called once for
	178	each marked buffer, with that buffer current.
	179
	180	ARGS becomes the formal parameters of the function.
	181	DOCUMENTATION becomes the docstring of the function.
	182	INTERACTIVE becomes the interactive specification of the function.
	183	MARK describes which type of mark (:deletion, or nil) this operation
	184	uses. :deletion means the function operates on buffers marked for
	185	deletion, otherwise it acts on normally marked buffers.
	186	MODIFIER-P describes how the function modifies buffers. This is used
	187	to set the modification flag of the Ibuffer buffer itself. Valid
	188	values are:
	189	nil - the function never modifiers buffers
	190	t - the function it always modifies buffers
	191	:maybe - attempt to discover this information by comparing the
	192	buffer's modification flag.
	193	DANGEROUS is a boolean which should be set if the user should be
	194	prompted before performing this operation.
	195	OPSTRING is a string which will be displayed to the user after the
	196	operation is complete, in the form:
	197	\"Operation complete; OPSTRING x buffers\"
	198	ACTIVE-OPSTRING is a string which will be displayed to the user in a
	199	confirmation message, in the form:
	200	\"Really ACTIVE-OPSTRING x buffers?\"
	201	COMPLEX means this function is special; see the source code of this
9bb69f45 JB	202	macro for exactly what it does.
	203
	204	\(fn OP ARGS DOCUMENTATION (&key INTERACTIVE MARK MODIFIER-P DANGEROUS OPSTRING ACTIVE-OPSTRING COMPLEX) &rest BODY)"
25d2f683	205	`(progn
1bb57048 CW	206	(defun ,(intern (concat (if (string-match "^ibuffer-do" (symbol-name op))
	207	"" "ibuffer-do-") (symbol-name op)))
	208	,args
25d2f683 CW	209	,(if (stringp documentation)
	210	documentation
	211	(format "%s marked buffers." active-opstring))
	212	,(if (not (null interactive))
	213	`(interactive ,interactive)
	214	'(interactive))
	215	(assert (eq major-mode 'ibuffer-mode))
	216	(setq ibuffer-did-modification nil)
	217	(let ((marked-names (,(case mark
	218	(:deletion
	219	'ibuffer-deletion-marked-buffer-names)
	220	(t
	221	'ibuffer-marked-buffer-names)))))
	222	(when (null marked-names)
	223	(setq marked-names (list (buffer-name (ibuffer-current-buffer))))
	224	(ibuffer-set-mark ,(case mark
	225	(:deletion
	226	'ibuffer-deletion-char)
	227	(t
	228	'ibuffer-marked-char))))
	229	,(let* ((finish (append
	230	'(progn)
	231	(if (eq modifier-p t)
	232	'((setq ibuffer-did-modification t))
	233	())
	234	`((ibuffer-redisplay t)
	235	(message ,(concat "Operation finished; " opstring " %s buffers") count))))
	236	(inner-body (if complex
	237	`(progn ,@body)
	238	`(progn
	239	(with-current-buffer buf
	240	(save-excursion
	241	,@body))
	242	t)))
	243	(body `(let ((count
	244	(,(case mark
	245	(:deletion
	246	'ibuffer-map-deletion-lines)
	247	(t
	248	'ibuffer-map-marked-lines))
bde57911	249	#'(lambda (buf mark)
25d2f683 CW	250	,(if (eq modifier-p :maybe)
	251	`(let ((ibuffer-tmp-previous-buffer-modification
	252	(buffer-modified-p buf)))
	253	(prog1 ,inner-body
	254	(when (not (eq ibuffer-tmp-previous-buffer-modification
	255	(buffer-modified-p buf)))
	256	(setq ibuffer-did-modification t))))
	257	inner-body)))))
	258	,finish)))
	259	(if dangerous
	260	`(when (ibuffer-confirm-operation-on ,active-opstring marked-names)
	261	,body)
	262	body))))
	263	:autoload-end))
	264	;; (put 'define-ibuffer-op 'lisp-indent-function 2)
	265
	266	;;;###autoload
	267	(defmacro* define-ibuffer-filter (name documentation
71296446	268	(&key
25d2f683 CW	269	reader
	270	description)
	271	&rest body)
	272	"Define a filter named NAME.
	273	DOCUMENTATION is the documentation of the function.
	274	READER is a form which should read a qualifier from the user.
	275	DESCRIPTION is a short string describing the filter.
	276
	277	BODY should contain forms which will be evaluated to test whether or
	278	not a particular buffer should be displayed or not. The forms in BODY
	279	will be evaluated with BUF bound to the buffer object, and QUALIFIER
9bb69f45 JB	280	bound to the current value of the filter.
	281
	282	\(fn NAME DOCUMENTATION (&key READER DESCRIPTION) &rest BODY)"
25d2f683	283	(let ((fn-name (intern (concat "ibuffer-filter-by-" (symbol-name name)))))
71296446	284	`(progn
25d2f683 CW	285	(defun ,fn-name (qualifier)
	286	,(concat (or documentation "This filter is not documented."))
	287	(interactive (list ,reader))
	288	(ibuffer-push-filter (cons ',name qualifier))
8a26c165	289	(message "%s"
25d2f683 CW	290	(format ,(concat (format "Filter by %s added: " description)
	291	" %s")
	292	qualifier))
	293	(ibuffer-update nil t))
	294	(push (list ',name ,description
	295	#'(lambda (buf qualifier)
	296	,@body))
	297	ibuffer-filtering-alist)
	298	:autoload-end)))
	299	;; (put 'define-ibuffer-filter 'lisp-indent-function 2)
	300
	301	(provide 'ibuf-macs)
	302
cbee283d	303	;; arch-tag: 2748edce-82c9-4cd9-9d9d-bd73e43c20c5
25d2f683	304	;;; ibuf-macs.el ends here