parsing_cocci/test_exps.ml

   1 (*
   2  * Copyright 2010, INRIA, University of Copenhagen
   3  * Julia Lawall, Rene Rydhof Hansen, Gilles Muller, Nicolas Palix
   4  * Copyright 2005-2009, Ecole des Mines de Nantes, University of Copenhagen
   5  * Yoann Padioleau, Julia Lawall, Rene Rydhof Hansen, Henrik Stuart, Gilles Muller, Nicolas Palix
   6  * This file is part of Coccinelle.
   7  *
   8  * Coccinelle is free software: you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License as published by
  10  * the Free Software Foundation, according to version 2 of the License.
  11  *
  12  * Coccinelle is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with Coccinelle.  If not, see <http://www.gnu.org/licenses/>.
  19  *
  20  * The authors reserve the right to distribute this or future versions of
  21  * Coccinelle under other licenses.
  22  *)
  23
  24
  25 module Ast = Ast_cocci
  26 module Ast0 = Ast0_cocci
  27 module V0 = Visitor_ast0
  28 module VT0 = Visitor_ast0_types
  29
  30 (* call set_test_pos on test expressions *)
  31
  32 (* The goal of this is to identify test expressions in the SmPL file, so that
  33 isomorphisms like X != NULL => X are only applied in a test expression context.
  34
  35 There is a related check in cocci_vs_c3.ml that in x || ..., a match
  36 without the || is only accepted in a test expression context.  This uses
  37 the annotations in the C file. *)
  38
  39 let rec process_exp e =
  40   let e = Ast0.set_test_pos e in(* allow test isos *)
  41   let e = Ast0.set_test_exp e in(* require that a test expression is matched *)
  42   match Ast0.unwrap e with
  43     Ast0.Paren(lp,e1,rp) ->
  44       Ast0.rewrap e (Ast0.Paren(lp,process_exp e1,rp))
  45   | _ -> e
  46
  47 let set_test_poss =
  48   let expression r k e =
  49     let e = k e in
  50     match Ast0.unwrap e with
  51       Ast0.CondExpr(e1,q,e2,c,e3) ->
  52         Ast0.rewrap e (Ast0.CondExpr(process_exp e1,q,e2,c,e3))
  53     | Ast0.Binary(e1,op,e2) ->
  54         (match Ast0.unwrap_mcode op with
  55           Ast.Logical(Ast.AndLog) | Ast.Logical(Ast.OrLog) ->
  56             Ast0.rewrap e (Ast0.Binary(process_exp e1,op,process_exp e2))
  57         | _ -> e)
  58     | Ast0.Unary(e1,op) ->
  59         (match Ast0.unwrap_mcode op with
  60           Ast.Not -> Ast0.rewrap e (Ast0.Unary(process_exp e1,op))
  61         | _ -> e)
  62     | _ -> e in
  63
  64   let process_wc = function
  65       Ast0.WhenNotTrue(e) -> Ast0.WhenNotTrue(process_exp e)
  66     | Ast0.WhenNotFalse(e) -> Ast0.WhenNotFalse(process_exp e)
  67     | wc -> wc in
  68
  69   let statement r k s =
  70     let s = k s in
  71     match Ast0.unwrap s with
  72       Ast0.IfThen(i,lp,e,rp,s1,aft) ->
  73         Ast0.rewrap s (Ast0.IfThen(i,lp,process_exp e,rp,s1,aft))
  74     | Ast0.IfThenElse(i,lp,e,rp,s1,e1,s2,aft) ->
  75         Ast0.rewrap s (Ast0.IfThenElse(i,lp,process_exp e,rp,s1,e1,s2,aft))
  76     | Ast0.While(i,lp,e,rp,s1,aft) ->
  77         Ast0.rewrap s (Ast0.While(i,lp,process_exp e,rp,s1,aft))
  78     | Ast0.Do(d,s1,w,lp,e,rp,sc) ->
  79         Ast0.rewrap s (Ast0.Do(d,s1,w,lp,process_exp e,rp,sc))
  80     | Ast0.For(f,lp,e1,sc1,Some e2,sc2,e3,rp,s1,aft) ->
  81         Ast0.rewrap s
  82           (Ast0.For(f,lp,e1,sc1,Some (process_exp e2),sc2,e3,rp,s1,aft))
  83     | Ast0.Dots(d,wc) ->
  84         Ast0.rewrap s (Ast0.Dots(d,List.map process_wc wc))
  85     | Ast0.Nest(l,s1,r,wc,m) ->
  86         Ast0.rewrap s (Ast0.Nest(l,s1,r,List.map process_wc wc,m))
  87     | _ -> s in
  88
  89   V0.rebuilder
  90     {V0.rebuilder_functions with
  91       VT0.rebuilder_exprfn = expression; VT0.rebuilder_stmtfn = statement}
  92
  93 let process = List.map set_test_poss.VT0.rebuilder_rec_top_level
  94
  95 let process_anything = set_test_poss.VT0.rebuilder_rec_anything
  96