HCoop / bpt / coccinelle.git / blob
? search:


05adfa452069b4e7e7f74cb3430f20bdea10e860
[bpt/coccinelle.git] / parsing_c / visitor_c.ml
1 (* Yoann Padioleau
2 *
3 * Copyright (C) 2010, University of Copenhagen DIKU and INRIA.
4 * Copyright (C) 2006, 2007, 2008, 2009 Ecole des Mines de Nantes
5 *
6 * This program is free software; you can redistribute it and/or
7 * modify it under the terms of the GNU General Public License (GPL)
8 * version 2 as published by the Free Software Foundation.
9 *
10 * This program is distributed in the hope that it will be useful,
11 * but WITHOUT ANY WARRANTY; without even the implied warranty of
12 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
13 * file license.txt for more details.
14 *)
15 open Common
16
17
18 open Ast_c
19 module F = Control_flow_c
20
21 (*****************************************************************************)
22 (* Prelude *)
23 (*****************************************************************************)
24
25 (* todo? dont go in Include. Have a visitor flag ? disable_go_include ?
26 * disable_go_type_annotation ?
27 *)
28
29 (*****************************************************************************)
30 (* Wrappers *)
31 (*****************************************************************************)
32 let pr2, pr2_once = Common.mk_pr2_wrappers Flag_parsing_c.verbose_visit
33
34 (*****************************************************************************)
35 (* Functions to visit the Ast, and now also the CFG nodes *)
36 (*****************************************************************************)
37
38 (* Why this module ?
39 *
40 * The problem is that we manipulate the AST of C programs
41 * and some of our analysis need only to specify an action for
42 * specific cases, such as the function call case, and recurse
43 * for the other cases.
44 * Here is a simplification of our AST:
45 *
46 * type ctype =
47 * | Basetype of ...
48 * | Pointer of ctype
49 * | Array of expression option * ctype
50 * | ...
51 * and expression =
52 * | Ident of string
53 * | FunCall of expression * expression list
54 * | Postfix of ...
55 * | RecordAccess of ..
56 * | ...
57 * and statement =
58 * ...
59 * and declaration =
60 * ...
61 * and program =
62 * ...
63 *
64 * What we want is really write code like
65 *
66 * let my_analysis program =
67 * analyze_all_expressions program (fun expr ->
68 * match expr with
69 * | FunCall (e, es) -> do_something()
70 * | _ -> <find_a_way_to_recurse_for_all_the_other_cases>
71 * )
72 *
73 * The problem is how to write analyze_all_expressions
74 * and find_a_way_to_recurse_for_all_the_other_cases.
75 *
76 * Our solution is to mix the ideas of visitor, pattern matching,
77 * and continuation. Here is how it looks like
78 * using our hybrid-visitor API:
79 *
80 * let my_analysis program =
81 * Visitor.visit_iter program {
82 * Visitor.kexpr = (fun k e ->
83 * match e with
84 * | FunCall (e, es) -> do_something()
85 * | _ -> k e
86 * );
87 * }
88 *
89 * You can of course also give action "hooks" for
90 * kstatement, ktype, or kdeclaration. But we don't overuse
91 * visitors and so it would be stupid to provide
92 * kfunction_call, kident, kpostfix hooks as one can just
93 * use pattern matching with kexpr to achieve the same effect.
94 *
95 * Note: when want to apply recursively, always apply the continuator
96 * on the toplevel expression, otherwise may miss some intermediate steps.
97 * Do
98 * match expr with
99 * | FunCall (e, es) -> ...
100 * k expr
101 * Or
102 * match expr with
103 * | FunCall (e, es) -> ...
104 * Visitor_c.vk_expr bigf e
105 * Not
106 * match expr with
107 * | FunCall (e, es) -> ...
108 * k e
109 *
110 *
111 *
112 *
113 *
114 * Alternatives: from the caml mailing list:
115 * "You should have a look at the Camlp4 metaprogramming facilities :
116 * http://brion.inria.fr/gallium/index.php/Camlp4MapGenerator
117 * You would write something like" :
118 * let my_analysis program =
119 * let analysis = object (self)
120 * inherit fold as super
121 * method expr = function
122 * | FunCall (e, es) -> do_something (); self
123 * | other -> super#expr other
124 * end in analysis#expr
125 *
126 * The problem is that you don't have control about what is generated
127 * and in our case we sometimes dont want to visit too much. For instance
128 * our visitor don't recurse on the type annotation of expressions
129 * Ok, this could be worked around, but the pb remains, you
130 * don't have control and at some point you may want. In the same
131 * way we want to enforce a certain order in the visit (ok this is not good,
132 * but it's convenient) of ast elements. For instance first
133 * processing the left part 'e' of a Funcall(e,es), then the arguments 'es'.
134 *
135 *)
136
137 (* Visitor based on continuation. Cleaner than the one based on mutable
138 * pointer functions that I had before.
139 * src: based on a (vague) idea from Remy Douence.
140 *
141 *
142 *
143 * Diff with Julia's visitor ? She does:
144 *
145 * let ident r k i =
146 * ...
147 * let expression r k e =
148 * ...
149 * ... (List.map r.V0.combiner_expression expr_list) ...
150 * ...
151 * let res = V0.combiner bind option_default
152 * mcode mcode mcode mcode mcode mcode mcode mcode mcode mcode mcode
153 * donothing donothing donothing donothing
154 * ident expression typeC donothing parameter declaration statement
155 * donothing in
156 * ...
157 * collect_unitary_nonunitary
158 * (List.concat (List.map res.V0.combiner_top_level t))
159 *
160 *
161 *
162 * So she has to remember at which position you must put the 'expression'
163 * function. I use record which is easier.
164 *
165 * When she calls recursively, her res.V0.combiner_xxx does not take bigf
166 * in param whereas I do
167 * | F.Decl decl -> Visitor_c.vk_decl bigf decl
168 * And with the record she gets, she does not have to do my
169 * multiple defs of function such as 'let al_type = V0.vk_type_s bigf'
170 *
171 * The code of visitor.ml is cleaner with julia because mutual recursive calls
172 * are clean such as ... 'expression e' ... and not 'f (k, bigf) e'
173 * or 'vk_expr bigf e'.
174 *
175 * So it is very dual:
176 * - I give a record but then I must handle bigf.
177 * - She gets a record, and gives a list of function
178 *
179 *)
180
181
182 (* old: first version (only visiting expr)
183
184 let (iter_expr:((expression -> unit) -> expression -> unit) -> expression -> unit)
185 = fun f expr ->
186 let rec k e =
187 match e with
188 | Constant c -> ()
189 | FunCall (e, es) -> f k e; List.iter (f k) es
190 | CondExpr (e1, e2, e3) -> f k e1; f k e2; f k e3
191 | Sequence (e1, e2) -> f k e1; f k e2;
192 | Assignment (e1, op, e2) -> f k e1; f k e2;
193
194 | Postfix (e, op) -> f k e
195 | Infix (e, op) -> f k e
196 | Unary (e, op) -> f k e
197 | Binary (e1, op, e2) -> f k e1; f k e2;
198
199 | ArrayAccess (e1, e2) -> f k e1; f k e2;
200 | RecordAccess (e, s) -> f k e
201 | RecordPtAccess (e, s) -> f k e
202
203 | SizeOfExpr e -> f k e
204 | SizeOfType t -> ()
205 | _ -> failwith "to complete"
206
207 in f k expr
208
209 let ex1 = Sequence (Sequence (Constant (Ident "1"), Constant (Ident "2")),
210 Constant (Ident "4"))
211 let test =
212 iter_expr (fun k e -> match e with
213 | Constant (Ident x) -> Common.pr2 x
214 | rest -> k rest
215 ) ex1
216 ==>
217 1
218 2
219 4
220
221 *)
222
223 (*****************************************************************************)
224 (* Side effect style visitor *)
225 (*****************************************************************************)
226
227 (* Visitors for all langage concept, not just for expression.
228 *
229 * Note that I don't visit necesserally in the order of the token
230 * found in the original file. So don't assume such hypothesis!
231 *
232 * todo? parameter ?
233 *)
234 type visitor_c =
235 {
236 kexpr: (expression -> unit) * visitor_c -> expression -> unit;
237 kstatement: (statement -> unit) * visitor_c -> statement -> unit;
238 ktype: (fullType -> unit) * visitor_c -> fullType -> unit;
239
240 kdecl: (declaration -> unit) * visitor_c -> declaration -> unit;
241 konedecl: (onedecl -> unit) * visitor_c -> onedecl -> unit;
242 kparam: (parameterType -> unit) * visitor_c -> parameterType -> unit;
243 kdef: (definition -> unit) * visitor_c -> definition -> unit;
244 kname : (name -> unit) * visitor_c -> name -> unit;
245
246 kini: (initialiser -> unit) * visitor_c -> initialiser -> unit;
247 kfield: (field -> unit) * visitor_c -> field -> unit;
248
249 kcppdirective: (cpp_directive -> unit) * visitor_c -> cpp_directive -> unit;
250 kdefineval : (define_val -> unit) * visitor_c -> define_val -> unit;
251 kstatementseq: (statement_sequencable -> unit) * visitor_c -> statement_sequencable -> unit;
252
253
254 (* CFG *)
255 knode: (F.node -> unit) * visitor_c -> F.node -> unit;
256 (* AST *)
257 ktoplevel: (toplevel -> unit) * visitor_c -> toplevel -> unit;
258
259 kinfo: (info -> unit) * visitor_c -> info -> unit;
260 }
261
262 let default_visitor_c =
263 { kexpr = (fun (k,_) e -> k e);
264 kstatement = (fun (k,_) st -> k st);
265 ktype = (fun (k,_) t -> k t);
266 kdecl = (fun (k,_) d -> k d);
267 konedecl = (fun (k,_) d -> k d);
268 kparam = (fun (k,_) d -> k d);
269 kdef = (fun (k,_) d -> k d);
270 kini = (fun (k,_) ie -> k ie);
271 kname = (fun (k,_) x -> k x);
272 kinfo = (fun (k,_) ii -> k ii);
273 knode = (fun (k,_) n -> k n);
274 ktoplevel = (fun (k,_) p -> k p);
275 kcppdirective = (fun (k,_) p -> k p);
276 kdefineval = (fun (k,_) p -> k p);
277 kstatementseq = (fun (k,_) p -> k p);
278 kfield = (fun (k,_) p -> k p);
279 }
280
281
282 (* ------------------------------------------------------------------------ *)
283
284
285 let rec vk_expr = fun bigf expr ->
286 let iif ii = vk_ii bigf ii in
287
288 let rec exprf e = bigf.kexpr (k,bigf) e
289 (* !!! dont go in _typ !!! *)
290 and k ((e,_typ), ii) =
291 iif ii;
292 match e with
293 | Ident (name) -> vk_name bigf name
294 | Constant (c) -> ()
295 | FunCall (e, es) ->
296 exprf e;
297 vk_argument_list bigf es;
298 | CondExpr (e1, e2, e3) ->
299 exprf e1; do_option (exprf) e2; exprf e3
300 | Sequence (e1, e2) -> exprf e1; exprf e2;
301 | Assignment (e1, op, e2) -> exprf e1; exprf e2;
302
303 | Postfix (e, op) -> exprf e
304 | Infix (e, op) -> exprf e
305 | Unary (e, op) -> exprf e
306 | Binary (e1, op, e2) -> exprf e1; exprf e2;
307
308 | ArrayAccess (e1, e2) -> exprf e1; exprf e2;
309 | RecordAccess (e, name) -> exprf e; vk_name bigf name
310 | RecordPtAccess (e, name) -> exprf e; vk_name bigf name
311
312 | SizeOfExpr (e) -> exprf e
313 | SizeOfType (t) -> vk_type bigf t
314 | Cast (t, e) -> vk_type bigf t; exprf e
315
316 (* old: | StatementExpr (((declxs, statxs), is)), is2 ->
317 * List.iter (vk_decl bigf) declxs;
318 * List.iter (vk_statement bigf) statxs
319 *)
320 | StatementExpr ((statxs, is)) ->
321 iif is;
322 statxs +> List.iter (vk_statement_sequencable bigf);
323
324 | Constructor (t, initxs) ->
325 vk_type bigf t;
326 initxs +> List.iter (fun (ini, ii) ->
327 vk_ini bigf ini;
328 vk_ii bigf ii;
329 )
330
331 | ParenExpr (e) -> exprf e
332
333
334 in exprf expr
335
336
337 (* ------------------------------------------------------------------------ *)
338 and vk_name = fun bigf ident ->
339 let iif ii = vk_ii bigf ii in
340
341 let rec namef x = bigf.kname (k,bigf) x
342 and k id =
343 match id with
344 | RegularName (s, ii) -> iif ii
345 | CppConcatenatedName xs ->
346 xs +> List.iter (fun ((x,ii1), ii2) ->
347 iif ii2;
348 iif ii1;
349 );
350 | CppVariadicName (s, ii) -> iif ii
351 | CppIdentBuilder ((s,iis), xs) ->
352 iif iis;
353 xs +> List.iter (fun ((x,iix), iicomma) ->
354 iif iicomma;
355 iif iix;
356 )
357 in
358 namef ident
359
360 (* ------------------------------------------------------------------------ *)
361
362
363 and vk_statement = fun bigf (st: Ast_c.statement) ->
364 let iif ii = vk_ii bigf ii in
365
366 let rec statf x = bigf.kstatement (k,bigf) x
367 and k st =
368 let (unwrap_st, ii) = st in
369 iif ii;
370 match unwrap_st with
371 | Labeled (Label (name, st)) ->
372 vk_name bigf name;
373 statf st;
374 | Labeled (Case (e, st)) -> vk_expr bigf e; statf st;
375 | Labeled (CaseRange (e, e2, st)) ->
376 vk_expr bigf e; vk_expr bigf e2; statf st;
377 | Labeled (Default st) -> statf st;
378
379 | Compound statxs ->
380 statxs +> List.iter (vk_statement_sequencable bigf)
381 | ExprStatement (eopt) -> do_option (vk_expr bigf) eopt;
382
383 | Selection (If (e, st1, st2)) ->
384 vk_expr bigf e; statf st1; statf st2;
385 | Selection (Switch (e, st)) ->
386 vk_expr bigf e; statf st;
387 | Iteration (While (e, st)) ->
388 vk_expr bigf e; statf st;
389 | Iteration (DoWhile (st, e)) -> statf st; vk_expr bigf e;
390 | Iteration (For ((e1opt,i1), (e2opt,i2), (e3opt,i3), st)) ->
391 statf (mk_st (ExprStatement (e1opt)) i1);
392 statf (mk_st (ExprStatement (e2opt)) i2);
393 statf (mk_st (ExprStatement (e3opt)) i3);
394 statf st;
395
396 | Iteration (MacroIteration (s, es, st)) ->
397 vk_argument_list bigf es;
398 statf st;
399
400 | Jump (Goto name) -> vk_name bigf name
401 | Jump ((Continue|Break|Return)) -> ()
402 | Jump (ReturnExpr e) -> vk_expr bigf e;
403 | Jump (GotoComputed e) -> vk_expr bigf e;
404
405 | Decl decl -> vk_decl bigf decl
406 | Asm asmbody -> vk_asmbody bigf asmbody
407 | NestedFunc def -> vk_def bigf def
408 | MacroStmt -> ()
409
410 in statf st
411
412 and vk_statement_sequencable = fun bigf stseq ->
413 let f = bigf.kstatementseq in
414
415 let rec k stseq =
416 match stseq with
417 | StmtElem st -> vk_statement bigf st
418 | CppDirectiveStmt directive ->
419 vk_cpp_directive bigf directive
420 | IfdefStmt ifdef ->
421 vk_ifdef_directive bigf ifdef
422 | IfdefStmt2 (ifdef, xxs) ->
423 ifdef +> List.iter (vk_ifdef_directive bigf);
424 xxs +> List.iter (fun xs ->
425 xs +> List.iter (vk_statement_sequencable bigf)
426 )
427
428 in f (k, bigf) stseq
429
430
431
432 and vk_type = fun bigf t ->
433 let iif ii = vk_ii bigf ii in
434
435 let rec typef x = bigf.ktype (k, bigf) x
436 and k t =
437 let (q, t) = t in
438 let (unwrap_q, iiq) = q in
439 let (unwrap_t, iit) = t in
440 iif iiq;
441 iif iit;
442 match unwrap_t with
443 | BaseType _ -> ()
444 | Pointer t -> typef t
445 | Array (eopt, t) ->
446 do_option (vk_expr bigf) eopt;
447 typef t
448 | FunctionType (returnt, paramst) ->
449 typef returnt;
450 (match paramst with
451 | (ts, (b,iihas3dots)) ->
452 iif iihas3dots;
453 vk_param_list bigf ts
454 )
455
456 | Enum (sopt, enumt) ->
457 vk_enum_fields bigf enumt
458
459 | StructUnion (sopt, _su, fields) ->
460 vk_struct_fields bigf fields
461
462 | StructUnionName (s, structunion) -> ()
463 | EnumName s -> ()
464
465 (* dont go in _typ *)
466 | TypeName (name,_typ) ->
467 vk_name bigf name
468
469 | ParenType t -> typef t
470 | TypeOfExpr e -> vk_expr bigf e
471 | TypeOfType t -> typef t
472
473 in typef t
474
475
476 and vk_attribute = fun bigf attr ->
477 let iif ii = vk_ii bigf ii in
478 match attr with
479 | Attribute s, ii ->
480 iif ii
481
482
483 (* ------------------------------------------------------------------------ *)
484
485 and vk_decl = fun bigf d ->
486 let iif ii = vk_ii bigf ii in
487
488 let f = bigf.kdecl in
489 let rec k decl =
490 match decl with
491 | DeclList (xs,ii) ->
492 iif ii;
493 xs +> List.iter (fun (x,ii) ->
494 iif ii;
495 vk_onedecl bigf x;
496 );
497 | MacroDecl ((s, args),ii) ->
498 iif ii;
499 vk_argument_list bigf args;
500 in f (k, bigf) d
501
502
503 and vk_onedecl = fun bigf onedecl ->
504 let iif ii = vk_ii bigf ii in
505 let f = bigf.konedecl in
506 let rec k onedecl =
507 match onedecl with
508 | ({v_namei = var;
509 v_type = t;
510 v_type_bis = tbis;
511 v_storage = _sto;
512 v_attr = attrs}) ->
513
514 vk_type bigf t;
515 (* dont go in tbis *)
516 attrs +> List.iter (vk_attribute bigf);
517 var +> Common.do_option (fun (name, iniopt) ->
518 vk_name bigf name;
519 iniopt +> Common.do_option (fun (info, ini) ->
520 iif [info];
521 vk_ini bigf ini;
522 );
523 )
524 in f (k, bigf) onedecl
525
526 and vk_ini = fun bigf ini ->
527 let iif ii = vk_ii bigf ii in
528
529 let rec inif x = bigf.kini (k, bigf) x
530 and k (ini, iini) =
531 iif iini;
532 match ini with
533 | InitExpr e -> vk_expr bigf e
534 | InitList initxs ->
535 initxs +> List.iter (fun (ini, ii) ->
536 inif ini;
537 iif ii;
538 )
539 | InitDesignators (xs, e) ->
540 xs +> List.iter (vk_designator bigf);
541 inif e
542
543 | InitFieldOld (s, e) -> inif e
544 | InitIndexOld (e1, e) ->
545 vk_expr bigf e1; inif e
546
547
548 in inif ini
549
550
551 and vk_designator = fun bigf design ->
552 let iif ii = vk_ii bigf ii in
553 let (designator, ii) = design in
554 iif ii;
555 match designator with
556 | DesignatorField s -> ()
557 | DesignatorIndex e -> vk_expr bigf e
558 | DesignatorRange (e1, e2) -> vk_expr bigf e1; vk_expr bigf e2
559
560
561 (* ------------------------------------------------------------------------ *)
562
563 and vk_struct_fields = fun bigf fields ->
564 fields +> List.iter (vk_struct_field bigf);
565
566 and vk_struct_field = fun bigf field ->
567 let iif ii = vk_ii bigf ii in
568
569 let f = bigf.kfield in
570 let rec k field =
571
572 match field with
573 | DeclarationField
574 (FieldDeclList (onefield_multivars, iiptvirg)) ->
575 vk_struct_fieldkinds bigf onefield_multivars;
576 iif iiptvirg;
577 | EmptyField info -> iif [info]
578 | MacroDeclField ((s, args),ii) ->
579 iif ii;
580 vk_argument_list bigf args;
581
582 | CppDirectiveStruct directive ->
583 vk_cpp_directive bigf directive
584 | IfdefStruct ifdef ->
585 vk_ifdef_directive bigf ifdef
586 in
587 f (k, bigf) field
588
589
590
591
592 and vk_struct_fieldkinds = fun bigf onefield_multivars ->
593 let iif ii = vk_ii bigf ii in
594 onefield_multivars +> List.iter (fun (field, iicomma) ->
595 iif iicomma;
596 match field with
597 | Simple (nameopt, t) ->
598 Common.do_option (vk_name bigf) nameopt;
599 vk_type bigf t;
600 | BitField (nameopt, t, info, expr) ->
601 Common.do_option (vk_name bigf) nameopt;
602 vk_info bigf info;
603 vk_expr bigf expr;
604 vk_type bigf t
605 )
606
607
608 and vk_enum_fields = fun bigf enumt ->
609 let iif ii = vk_ii bigf ii in
610 enumt +> List.iter (fun ((name, eopt), iicomma) ->
611 vk_oneEnum bigf (name, eopt);
612 iif iicomma)
613
614 and vk_oneEnum = fun bigf (name, eopt) ->
615 let iif ii = vk_ii bigf ii in
616 vk_name bigf name;
617 eopt +> Common.do_option (fun (info, e) ->
618 iif [info];
619 vk_expr bigf e
620 )
621
622 (* ------------------------------------------------------------------------ *)
623
624
625 and vk_def = fun bigf d ->
626 let iif ii = vk_ii bigf ii in
627
628 let f = bigf.kdef in
629 let rec k d =
630 match d with
631 | {f_name = name;
632 f_type = (returnt, (paramst, (b, iib)));
633 f_storage = sto;
634 f_body = statxs;
635 f_attr = attrs;
636 f_old_c_style = oldstyle;
637 }, ii
638 ->
639 iif ii;
640 iif iib;
641 attrs +> List.iter (vk_attribute bigf);
642 vk_type bigf returnt;
643 vk_name bigf name;
644 paramst +> List.iter (fun (param,iicomma) ->
645 vk_param bigf param;
646 iif iicomma;
647 );
648 oldstyle +> Common.do_option (fun decls ->
649 decls +> List.iter (vk_decl bigf);
650 );
651
652 statxs +> List.iter (vk_statement_sequencable bigf)
653 in f (k, bigf) d
654
655
656
657
658 and vk_toplevel = fun bigf p ->
659 let f = bigf.ktoplevel in
660 let iif ii = vk_ii bigf ii in
661 let rec k p =
662 match p with
663 | Declaration decl -> (vk_decl bigf decl)
664 | Definition def -> (vk_def bigf def)
665 | EmptyDef ii -> iif ii
666 | MacroTop (s, xs, ii) ->
667 vk_argument_list bigf xs;
668 iif ii
669
670 | CppTop top -> vk_cpp_directive bigf top
671 | IfdefTop ifdefdir -> vk_ifdef_directive bigf ifdefdir
672
673 | NotParsedCorrectly ii -> iif ii
674 | FinalDef info -> vk_info bigf info
675 in f (k, bigf) p
676
677 and vk_program = fun bigf xs ->
678 xs +> List.iter (vk_toplevel bigf)
679
680 and vk_ifdef_directive bigf directive =
681 let iif ii = vk_ii bigf ii in
682 match directive with
683 | IfdefDirective (ifkind, ii) -> iif ii
684
685
686 and vk_cpp_directive bigf directive =
687 let iif ii = vk_ii bigf ii in
688 let f = bigf.kcppdirective in
689 let rec k directive =
690 match directive with
691 | Include {i_include = (s, ii);
692 i_content = copt;
693 }
694 ->
695 (* go inside ? yes, can be useful, for instance for type_annotater.
696 * The only pb may be that when we want to unparse the code we
697 * don't want to unparse the included file but the unparser
698 * and pretty_print do not use visitor_c so no problem.
699 *)
700 iif ii;
701 copt +> Common.do_option (fun (file, asts) ->
702 vk_program bigf asts
703 );
704 | Define ((s,ii), (defkind, defval)) ->
705 iif ii;
706 vk_define_kind bigf defkind;
707 vk_define_val bigf defval
708 | Undef (s, ii) ->
709 iif ii
710 | PragmaAndCo (ii) ->
711 iif ii
712 in f (k, bigf) directive
713
714
715 and vk_define_kind bigf defkind =
716 match defkind with
717 | DefineVar -> ()
718 | DefineFunc (params, ii) ->
719 vk_ii bigf ii;
720 params +> List.iter (fun ((s,iis), iicomma) ->
721 vk_ii bigf iis;
722 vk_ii bigf iicomma;
723 )
724
725 and vk_define_val bigf defval =
726 let f = bigf.kdefineval in
727
728 let rec k defval =
729 match defval with
730 | DefineExpr e ->
731 vk_expr bigf e
732 | DefineStmt stmt -> vk_statement bigf stmt
733 | DefineDoWhileZero ((stmt, e), ii) ->
734 vk_statement bigf stmt;
735 vk_expr bigf e;
736 vk_ii bigf ii
737 | DefineFunction def -> vk_def bigf def
738 | DefineType ty -> vk_type bigf ty
739 | DefineText (s, ii) -> vk_ii bigf ii
740 | DefineEmpty -> ()
741 | DefineInit ini -> vk_ini bigf ini
742
743 | DefineTodo ->
744 pr2_once "DefineTodo";
745 ()
746 in f (k, bigf) defval
747
748
749
750
751 (* ------------------------------------------------------------------------ *)
752 (* Now keep fullstatement inside the control flow node,
753 * so that can then get in a MetaStmtVar the fullstatement to later
754 * pp back when the S is in a +. But that means that
755 * Exp will match an Ifnode even if there is no such exp
756 * inside the condition of the Ifnode (because the exp may
757 * be deeper, in the then branch). So have to not visit
758 * all inside a node anymore.
759 *
760 * update: j'ai choisi d'accrocher au noeud du CFG a la
761 * fois le fullstatement et le partialstatement et appeler le
762 * visiteur que sur le partialstatement.
763 *)
764
765 and vk_node = fun bigf node ->
766 let iif ii = vk_ii bigf ii in
767 let infof info = vk_info bigf info in
768
769 let f = bigf.knode in
770 let rec k n =
771 match F.unwrap n with
772
773 | F.FunHeader (def) ->
774 assert(null (fst def).f_body);
775 vk_def bigf def;
776
777 | F.Decl decl -> vk_decl bigf decl
778 | F.ExprStatement (st, (eopt, ii)) ->
779 iif ii;
780 eopt +> do_option (vk_expr bigf)
781
782 | F.IfHeader (_, (e,ii))
783 | F.SwitchHeader (_, (e,ii))
784 | F.WhileHeader (_, (e,ii))
785 | F.DoWhileTail (e,ii) ->
786 iif ii;
787 vk_expr bigf e
788
789 | F.ForHeader (_st, (((e1opt,i1), (e2opt,i2), (e3opt,i3)), ii)) ->
790 iif i1; iif i2; iif i3;
791 iif ii;
792 e1opt +> do_option (vk_expr bigf);
793 e2opt +> do_option (vk_expr bigf);
794 e3opt +> do_option (vk_expr bigf);
795 | F.MacroIterHeader (_s, ((s,es), ii)) ->
796 iif ii;
797 vk_argument_list bigf es;
798
799 | F.ReturnExpr (_st, (e,ii)) -> iif ii; vk_expr bigf e
800
801 | F.Case (_st, (e,ii)) -> iif ii; vk_expr bigf e
802 | F.CaseRange (_st, ((e1, e2),ii)) ->
803 iif ii; vk_expr bigf e1; vk_expr bigf e2
804
805
806 | F.CaseNode i -> ()
807
808 | F.DefineExpr e -> vk_expr bigf e
809 | F.DefineType ft -> vk_type bigf ft
810 | F.DefineHeader ((s,ii), (defkind)) ->
811 iif ii;
812 vk_define_kind bigf defkind;
813
814 | F.DefineDoWhileZeroHeader (((),ii)) -> iif ii
815 | F.DefineTodo ->
816 pr2_once "DefineTodo";
817 ()
818
819
820 | F.Include {i_include = (s, ii);} -> iif ii;
821
822 | F.MacroTop (s, args, ii) ->
823 iif ii;
824 vk_argument_list bigf args
825
826 | F.IfdefHeader (info) -> vk_ifdef_directive bigf info
827 | F.IfdefElse (info) -> vk_ifdef_directive bigf info
828 | F.IfdefEndif (info) -> vk_ifdef_directive bigf info
829
830 | F.Break (st,((),ii)) -> iif ii
831 | F.Continue (st,((),ii)) -> iif ii
832 | F.Default (st,((),ii)) -> iif ii
833 | F.Return (st,((),ii)) -> iif ii
834 | F.Goto (st, name, ((),ii)) -> vk_name bigf name; iif ii
835 | F.Label (st, name, ((),ii)) -> vk_name bigf name; iif ii
836
837 | F.DoHeader (st, info) -> infof info
838
839 | F.Else info -> infof info
840 | F.EndStatement iopt -> do_option infof iopt
841
842 | F.SeqEnd (i, info) -> infof info
843 | F.SeqStart (st, i, info) -> infof info
844
845 | F.MacroStmt (st, ((),ii)) -> iif ii
846 | F.Asm (st, (asmbody,ii)) ->
847 iif ii;
848 vk_asmbody bigf asmbody
849
850 | (
851 F.TopNode|F.EndNode|
852 F.ErrorExit|F.Exit|F.Enter|F.LoopFallThroughNode|F.FallThroughNode|
853 F.AfterNode|F.FalseNode|F.TrueNode|F.InLoopNode|
854 F.Fake
855 ) -> ()
856
857
858
859 in
860 f (k, bigf) node
861
862 (* ------------------------------------------------------------------------ *)
863 and vk_info = fun bigf info ->
864 let rec infof ii = bigf.kinfo (k, bigf) ii
865 and k i = ()
866 in
867 infof info
868
869 and vk_ii = fun bigf ii ->
870 List.iter (vk_info bigf) ii
871
872
873 (* ------------------------------------------------------------------------ *)
874 and vk_argument = fun bigf arg ->
875 let rec do_action = function
876 | (ActMisc ii) -> vk_ii bigf ii
877 in
878 match arg with
879 | Left e -> (vk_expr bigf) e
880 | Right (ArgType param) -> vk_param bigf param
881 | Right (ArgAction action) -> do_action action
882
883 and vk_argument_list = fun bigf es ->
884 let iif ii = vk_ii bigf ii in
885 es +> List.iter (fun (e, ii) ->
886 iif ii;
887 vk_argument bigf e
888 )
889
890
891
892 and vk_param = fun bigf param ->
893 let iif ii = vk_ii bigf ii in
894 let f = bigf.kparam in
895 let rec k param =
896 let {p_namei = swrapopt; p_register = (b, iib); p_type=ft} = param in
897 swrapopt +> Common.do_option (vk_name bigf);
898 iif iib;
899 vk_type bigf ft
900 in f (k, bigf) param
901
902 and vk_param_list = fun bigf ts ->
903 let iif ii = vk_ii bigf ii in
904 ts +> List.iter (fun (param,iicomma) ->
905 vk_param bigf param;
906 iif iicomma;
907 )
908
909
910
911 (* ------------------------------------------------------------------------ *)
912 and vk_asmbody = fun bigf (string_list, colon_list) ->
913 let iif ii = vk_ii bigf ii in
914
915 iif string_list;
916 colon_list +> List.iter (fun (Colon xs, ii) ->
917 iif ii;
918 xs +> List.iter (fun (x,iicomma) ->
919 iif iicomma;
920 (match x with
921 | ColonMisc, ii -> iif ii
922 | ColonExpr e, ii ->
923 vk_expr bigf e;
924 iif ii
925 )
926 ))
927
928
929 (* ------------------------------------------------------------------------ *)
930 let vk_splitted element = fun bigf args_splitted ->
931 let iif ii = vk_ii bigf ii in
932 args_splitted +> List.iter (function
933 | Left arg -> element bigf arg
934 | Right ii -> iif ii
935 )
936
937 let vk_args_splitted = vk_splitted vk_argument
938 let vk_define_params_splitted = vk_splitted (fun bigf (_,ii) -> vk_ii bigf ii)
939 let vk_params_splitted = vk_splitted vk_param
940 let vk_enum_fields_splitted = vk_splitted vk_oneEnum
941 let vk_inis_splitted = vk_splitted vk_ini
942
943 (* ------------------------------------------------------------------------ *)
944 let vk_cst = fun bigf (cst, ii) ->
945 let iif ii = vk_ii bigf ii in
946 iif ii;
947 (match cst with
948 | Left cst -> ()
949 | Right s -> ()
950 )
951
952
953
954
955 (*****************************************************************************)
956 (* "syntetisized attributes" style *)
957 (*****************************************************************************)
958
959 (* TODO port the xxs_s to new cpp construct too *)
960
961 type 'a inout = 'a -> 'a
962
963 (* _s for synthetizized attributes
964 *
965 * Note that I don't visit necesserally in the order of the token
966 * found in the original file. So don't assume such hypothesis!
967 *)
968 type visitor_c_s = {
969 kexpr_s: (expression inout * visitor_c_s) -> expression inout;
970 kstatement_s: (statement inout * visitor_c_s) -> statement inout;
971 ktype_s: (fullType inout * visitor_c_s) -> fullType inout;
972
973 kdecl_s: (declaration inout * visitor_c_s) -> declaration inout;
974 kdef_s: (definition inout * visitor_c_s) -> definition inout;
975 kname_s: (name inout * visitor_c_s) -> name inout;
976
977 kini_s: (initialiser inout * visitor_c_s) -> initialiser inout;
978
979 kcppdirective_s: (cpp_directive inout * visitor_c_s) -> cpp_directive inout;
980 kdefineval_s: (define_val inout * visitor_c_s) -> define_val inout;
981 kstatementseq_s: (statement_sequencable inout * visitor_c_s) -> statement_sequencable inout;
982 kstatementseq_list_s: (statement_sequencable list inout * visitor_c_s) -> statement_sequencable list inout;
983
984 knode_s: (F.node inout * visitor_c_s) -> F.node inout;
985
986
987 ktoplevel_s: (toplevel inout * visitor_c_s) -> toplevel inout;
988 kinfo_s: (info inout * visitor_c_s) -> info inout;
989 }
990
991 let default_visitor_c_s =
992 { kexpr_s = (fun (k,_) e -> k e);
993 kstatement_s = (fun (k,_) st -> k st);
994 ktype_s = (fun (k,_) t -> k t);
995 kdecl_s = (fun (k,_) d -> k d);
996 kdef_s = (fun (k,_) d -> k d);
997 kname_s = (fun (k,_) x -> k x);
998 kini_s = (fun (k,_) d -> k d);
999 ktoplevel_s = (fun (k,_) p -> k p);
1000 knode_s = (fun (k,_) n -> k n);
1001 kinfo_s = (fun (k,_) i -> k i);
1002 kdefineval_s = (fun (k,_) x -> k x);
1003 kstatementseq_s = (fun (k,_) x -> k x);
1004 kstatementseq_list_s = (fun (k,_) x -> k x);
1005 kcppdirective_s = (fun (k,_) x -> k x);
1006 }
1007
1008 let rec vk_expr_s = fun bigf expr ->
1009 let iif ii = vk_ii_s bigf ii in
1010 let rec exprf e = bigf.kexpr_s (k, bigf) e
1011 and k e =
1012 let ((unwrap_e, typ), ii) = e in
1013 (* !!! don't analyse optional type !!!
1014 * old: typ +> map_option (vk_type_s bigf) in
1015 *)
1016 let typ' = typ in
1017 let e' =
1018 match unwrap_e with
1019 | Ident (name) -> Ident (vk_name_s bigf name)
1020 | Constant (c) -> Constant (c)
1021 | FunCall (e, es) ->
1022 FunCall (exprf e,
1023 es +> List.map (fun (e,ii) ->
1024 vk_argument_s bigf e, iif ii
1025 ))
1026
1027 | CondExpr (e1, e2, e3) -> CondExpr (exprf e1, fmap exprf e2, exprf e3)
1028 | Sequence (e1, e2) -> Sequence (exprf e1, exprf e2)
1029 | Assignment (e1, op, e2) -> Assignment (exprf e1, op, exprf e2)
1030
1031 | Postfix (e, op) -> Postfix (exprf e, op)
1032 | Infix (e, op) -> Infix (exprf e, op)
1033 | Unary (e, op) -> Unary (exprf e, op)
1034 | Binary (e1, op, e2) -> Binary (exprf e1, op, exprf e2)
1035
1036 | ArrayAccess (e1, e2) -> ArrayAccess (exprf e1, exprf e2)
1037 | RecordAccess (e, name) ->
1038 RecordAccess (exprf e, vk_name_s bigf name)
1039 | RecordPtAccess (e, name) ->
1040 RecordPtAccess (exprf e, vk_name_s bigf name)
1041
1042 | SizeOfExpr (e) -> SizeOfExpr (exprf e)
1043 | SizeOfType (t) -> SizeOfType (vk_type_s bigf t)
1044 | Cast (t, e) -> Cast (vk_type_s bigf t, exprf e)
1045
1046 | StatementExpr (statxs, is) ->
1047 StatementExpr (
1048 vk_statement_sequencable_list_s bigf statxs,
1049 iif is)
1050 | Constructor (t, initxs) ->
1051 Constructor
1052 (vk_type_s bigf t,
1053 (initxs +> List.map (fun (ini, ii) ->
1054 vk_ini_s bigf ini, vk_ii_s bigf ii)
1055 ))
1056
1057 | ParenExpr (e) -> ParenExpr (exprf e)
1058
1059 in
1060 (e', typ'), (iif ii)
1061 in exprf expr
1062
1063
1064 and vk_argument_s bigf argument =
1065 let iif ii = vk_ii_s bigf ii in
1066 let rec do_action = function
1067 | (ActMisc ii) -> ActMisc (iif ii)
1068 in
1069 (match argument with
1070 | Left e -> Left (vk_expr_s bigf e)
1071 | Right (ArgType param) -> Right (ArgType (vk_param_s bigf param))
1072 | Right (ArgAction action) -> Right (ArgAction (do_action action))
1073 )
1074
1075 (* ------------------------------------------------------------------------ *)
1076
1077
1078 and vk_name_s = fun bigf ident ->
1079 let iif ii = vk_ii_s bigf ii in
1080 let rec namef x = bigf.kname_s (k,bigf) x
1081 and k id =
1082 (match id with
1083 | RegularName (s,ii) -> RegularName (s, iif ii)
1084 | CppConcatenatedName xs ->
1085 CppConcatenatedName (xs +> List.map (fun ((x,ii1), ii2) ->
1086 (x, iif ii1), iif ii2
1087 ))
1088 | CppVariadicName (s, ii) -> CppVariadicName (s, iif ii)
1089 | CppIdentBuilder ((s,iis), xs) ->
1090 CppIdentBuilder ((s, iif iis),
1091 xs +> List.map (fun ((x,iix), iicomma) ->
1092 ((x, iif iix), iif iicomma)))
1093 )
1094 in
1095 namef ident
1096
1097 (* ------------------------------------------------------------------------ *)
1098
1099
1100
1101 and vk_statement_s = fun bigf st ->
1102 let rec statf st = bigf.kstatement_s (k, bigf) st
1103 and k st =
1104 let (unwrap_st, ii) = st in
1105 let st' =
1106 match unwrap_st with
1107 | Labeled (Label (name, st)) ->
1108 Labeled (Label (vk_name_s bigf name, statf st))
1109 | Labeled (Case (e, st)) ->
1110 Labeled (Case ((vk_expr_s bigf) e , statf st))
1111 | Labeled (CaseRange (e, e2, st)) ->
1112 Labeled (CaseRange ((vk_expr_s bigf) e,
1113 (vk_expr_s bigf) e2,
1114 statf st))
1115 | Labeled (Default st) -> Labeled (Default (statf st))
1116 | Compound statxs ->
1117 Compound (vk_statement_sequencable_list_s bigf statxs)
1118 | ExprStatement (None) -> ExprStatement (None)
1119 | ExprStatement (Some e) -> ExprStatement (Some ((vk_expr_s bigf) e))
1120 | Selection (If (e, st1, st2)) ->
1121 Selection (If ((vk_expr_s bigf) e, statf st1, statf st2))
1122 | Selection (Switch (e, st)) ->
1123 Selection (Switch ((vk_expr_s bigf) e, statf st))
1124 | Iteration (While (e, st)) ->
1125 Iteration (While ((vk_expr_s bigf) e, statf st))
1126 | Iteration (DoWhile (st, e)) ->
1127 Iteration (DoWhile (statf st, (vk_expr_s bigf) e))
1128 | Iteration (For ((e1opt,i1), (e2opt,i2), (e3opt,i3), st)) ->
1129 let e1opt' = statf (mk_st (ExprStatement (e1opt)) i1) in
1130 let e2opt' = statf (mk_st (ExprStatement (e2opt)) i2) in
1131 let e3opt' = statf (mk_st (ExprStatement (e3opt)) i3) in
1132
1133 let e1' = Ast_c.unwrap_st e1opt' in
1134 let e2' = Ast_c.unwrap_st e2opt' in
1135 let e3' = Ast_c.unwrap_st e3opt' in
1136 let i1' = Ast_c.get_ii_st_take_care e1opt' in
1137 let i2' = Ast_c.get_ii_st_take_care e2opt' in
1138 let i3' = Ast_c.get_ii_st_take_care e3opt' in
1139
1140 (match (e1', e2', e3') with
1141 | ((ExprStatement x1), (ExprStatement x2), ((ExprStatement x3))) ->
1142 Iteration (For ((x1,i1'), (x2,i2'), (x3,i3'), statf st))
1143
1144 | x -> failwith "cant be here if iterator keep ExprStatement as is"
1145 )
1146
1147 | Iteration (MacroIteration (s, es, st)) ->
1148 Iteration
1149 (MacroIteration
1150 (s,
1151 es +> List.map (fun (e, ii) ->
1152 vk_argument_s bigf e, vk_ii_s bigf ii
1153 ),
1154 statf st
1155 ))
1156
1157
1158 | Jump (Goto name) -> Jump (Goto (vk_name_s bigf name))
1159 | Jump (((Continue|Break|Return) as x)) -> Jump (x)
1160 | Jump (ReturnExpr e) -> Jump (ReturnExpr ((vk_expr_s bigf) e))
1161 | Jump (GotoComputed e) -> Jump (GotoComputed (vk_expr_s bigf e));
1162
1163 | Decl decl -> Decl (vk_decl_s bigf decl)
1164 | Asm asmbody -> Asm (vk_asmbody_s bigf asmbody)
1165 | NestedFunc def -> NestedFunc (vk_def_s bigf def)
1166 | MacroStmt -> MacroStmt
1167 in
1168 st', vk_ii_s bigf ii
1169 in statf st
1170
1171
1172 and vk_statement_sequencable_s = fun bigf stseq ->
1173 let f = bigf.kstatementseq_s in
1174 let k stseq =
1175
1176 match stseq with
1177 | StmtElem st ->
1178 StmtElem (vk_statement_s bigf st)
1179 | CppDirectiveStmt directive ->
1180 CppDirectiveStmt (vk_cpp_directive_s bigf directive)
1181 | IfdefStmt ifdef ->
1182 IfdefStmt (vk_ifdef_directive_s bigf ifdef)
1183 | IfdefStmt2 (ifdef, xxs) ->
1184 let ifdef' = List.map (vk_ifdef_directive_s bigf) ifdef in
1185 let xxs' = xxs +> List.map (fun xs ->
1186 xs +> vk_statement_sequencable_list_s bigf
1187 )
1188 in
1189 IfdefStmt2(ifdef', xxs')
1190 in f (k, bigf) stseq
1191
1192 and vk_statement_sequencable_list_s = fun bigf statxs ->
1193 let f = bigf.kstatementseq_list_s in
1194 let k xs =
1195 xs +> List.map (vk_statement_sequencable_s bigf)
1196 in
1197 f (k, bigf) statxs
1198
1199
1200
1201 and vk_asmbody_s = fun bigf (string_list, colon_list) ->
1202 let iif ii = vk_ii_s bigf ii in
1203
1204 iif string_list,
1205 colon_list +> List.map (fun (Colon xs, ii) ->
1206 Colon
1207 (xs +> List.map (fun (x, iicomma) ->
1208 (match x with
1209 | ColonMisc, ii -> ColonMisc, iif ii
1210 | ColonExpr e, ii -> ColonExpr (vk_expr_s bigf e), iif ii
1211 ), iif iicomma
1212 )),
1213 iif ii
1214 )
1215
1216
1217
1218
1219 (* todo? a visitor for qualifier *)
1220 and vk_type_s = fun bigf t ->
1221 let rec typef t = bigf.ktype_s (k,bigf) t
1222 and iif ii = vk_ii_s bigf ii
1223 and k t =
1224 let (q, t) = t in
1225 let (unwrap_q, iiq) = q in
1226 (* strip_info_visitor needs iiq to be processed before iit *)
1227 let iif_iiq = iif iiq in
1228 let q' = unwrap_q in
1229 let (unwrap_t, iit) = t in
1230 let t' =
1231 match unwrap_t with
1232 | BaseType x -> BaseType x
1233 | Pointer t -> Pointer (typef t)
1234 | Array (eopt, t) -> Array (fmap (vk_expr_s bigf) eopt, typef t)
1235 | FunctionType (returnt, paramst) ->
1236 FunctionType
1237 (typef returnt,
1238 (match paramst with
1239 | (ts, (b, iihas3dots)) ->
1240 (ts +> List.map (fun (param,iicomma) ->
1241 (vk_param_s bigf param, iif iicomma)),
1242 (b, iif iihas3dots))
1243 ))
1244
1245 | Enum (sopt, enumt) ->
1246 Enum (sopt, vk_enum_fields_s bigf enumt)
1247 | StructUnion (sopt, su, fields) ->
1248 StructUnion (sopt, su, vk_struct_fields_s bigf fields)
1249
1250
1251 | StructUnionName (s, structunion) -> StructUnionName (s, structunion)
1252 | EnumName s -> EnumName s
1253 | TypeName (name, typ) -> TypeName (vk_name_s bigf name, typ)
1254
1255 | ParenType t -> ParenType (typef t)
1256 | TypeOfExpr e -> TypeOfExpr (vk_expr_s bigf e)
1257 | TypeOfType t -> TypeOfType (typef t)
1258 in
1259 (q', iif_iiq),
1260 (t', iif iit)
1261
1262
1263 in typef t
1264
1265 and vk_attribute_s = fun bigf attr ->
1266 let iif ii = vk_ii_s bigf ii in
1267 match attr with
1268 | Attribute s, ii ->
1269 Attribute s, iif ii
1270
1271
1272
1273 and vk_decl_s = fun bigf d ->
1274 let f = bigf.kdecl_s in
1275 let iif ii = vk_ii_s bigf ii in
1276 let rec k decl =
1277 match decl with
1278 | DeclList (xs, ii) ->
1279 DeclList (List.map aux xs, iif ii)
1280 | MacroDecl ((s, args),ii) ->
1281 MacroDecl
1282 ((s,
1283 args +> List.map (fun (e,ii) -> vk_argument_s bigf e, iif ii)
1284 ),
1285 iif ii)
1286
1287
1288 and aux ({v_namei = var;
1289 v_type = t;
1290 v_type_bis = tbis;
1291 v_storage = sto;
1292 v_local= local;
1293 v_attr = attrs}, iicomma) =
1294 {v_namei =
1295 (var +> map_option (fun (name, iniopt) ->
1296 vk_name_s bigf name,
1297 iniopt +> map_option (fun (info, init) ->
1298 vk_info_s bigf info,
1299 vk_ini_s bigf init
1300 )));
1301 v_type = vk_type_s bigf t;
1302 (* !!! dont go in semantic related stuff !!! *)
1303 v_type_bis = tbis;
1304 v_storage = sto;
1305 v_local = local;
1306 v_attr = attrs +> List.map (vk_attribute_s bigf);
1307 },
1308 iif iicomma
1309
1310 in f (k, bigf) d
1311
1312 and vk_ini_s = fun bigf ini ->
1313 let rec inif ini = bigf.kini_s (k,bigf) ini
1314 and k ini =
1315 let (unwrap_ini, ii) = ini in
1316 let ini' =
1317 match unwrap_ini with
1318 | InitExpr e -> InitExpr (vk_expr_s bigf e)
1319 | InitList initxs ->
1320 InitList (initxs +> List.map (fun (ini, ii) ->
1321 inif ini, vk_ii_s bigf ii)
1322 )
1323
1324
1325 | InitDesignators (xs, e) ->
1326 InitDesignators
1327 (xs +> List.map (vk_designator_s bigf),
1328 inif e
1329 )
1330
1331 | InitFieldOld (s, e) -> InitFieldOld (s, inif e)
1332 | InitIndexOld (e1, e) -> InitIndexOld (vk_expr_s bigf e1, inif e)
1333
1334
1335 in ini', vk_ii_s bigf ii
1336 in inif ini
1337
1338
1339 and vk_designator_s = fun bigf design ->
1340 let iif ii = vk_ii_s bigf ii in
1341 let (designator, ii) = design in
1342 (match designator with
1343 | DesignatorField s -> DesignatorField s
1344 | DesignatorIndex e -> DesignatorIndex (vk_expr_s bigf e)
1345 | DesignatorRange (e1, e2) ->
1346 DesignatorRange (vk_expr_s bigf e1, vk_expr_s bigf e2)
1347 ), iif ii
1348
1349
1350
1351
1352 and vk_struct_fieldkinds_s = fun bigf onefield_multivars ->
1353 let iif ii = vk_ii_s bigf ii in
1354
1355 onefield_multivars +> List.map (fun (field, iicomma) ->
1356 (match field with
1357 | Simple (nameopt, t) ->
1358 Simple (Common.map_option (vk_name_s bigf) nameopt,
1359 vk_type_s bigf t)
1360 | BitField (nameopt, t, info, expr) ->
1361 BitField (Common.map_option (vk_name_s bigf) nameopt,
1362 vk_type_s bigf t,
1363 vk_info_s bigf info,
1364 vk_expr_s bigf expr)
1365 ), iif iicomma
1366 )
1367
1368 and vk_struct_field_s = fun bigf field ->
1369 let iif ii = vk_ii_s bigf ii in
1370
1371 match field with
1372 (DeclarationField (FieldDeclList (onefield_multivars, iiptvirg))) ->
1373 DeclarationField
1374 (FieldDeclList
1375 (vk_struct_fieldkinds_s bigf onefield_multivars, iif iiptvirg))
1376 | EmptyField info -> EmptyField (vk_info_s bigf info)
1377 | MacroDeclField ((s, args),ii) ->
1378 MacroDeclField
1379 ((s,
1380 args +> List.map (fun (e,ii) -> vk_argument_s bigf e, iif ii)
1381 ),
1382 iif ii)
1383
1384 | CppDirectiveStruct directive ->
1385 CppDirectiveStruct (vk_cpp_directive_s bigf directive)
1386 | IfdefStruct ifdef ->
1387 IfdefStruct (vk_ifdef_directive_s bigf ifdef)
1388
1389 and vk_struct_fields_s = fun bigf fields ->
1390 fields +> List.map (vk_struct_field_s bigf)
1391
1392 and vk_enum_fields_s = fun bigf enumt ->
1393 let iif ii = vk_ii_s bigf ii in
1394 enumt +> List.map (fun ((name, eopt), iicomma) ->
1395 vk_oneEnum_s bigf (name, eopt), iif iicomma)
1396
1397 and vk_oneEnum_s = fun bigf oneEnum ->
1398 let (name,eopt) = oneEnum in
1399 (vk_name_s bigf name,
1400 eopt +> Common.fmap (fun (info, e) ->
1401 vk_info_s bigf info,
1402 vk_expr_s bigf e
1403 ))
1404
1405 and vk_def_s = fun bigf d ->
1406 let f = bigf.kdef_s in
1407 let iif ii = vk_ii_s bigf ii in
1408 let rec k d =
1409 match d with
1410 | {f_name = name;
1411 f_type = (returnt, (paramst, (b, iib)));
1412 f_storage = sto;
1413 f_body = statxs;
1414 f_attr = attrs;
1415 f_old_c_style = oldstyle;
1416 }, ii
1417 ->
1418 {f_name = vk_name_s bigf name;
1419 f_type =
1420 (vk_type_s bigf returnt,
1421 (paramst +> List.map (fun (param, iicomma) ->
1422 (vk_param_s bigf param, iif iicomma)
1423 ), (b, iif iib)));
1424 f_storage = sto;
1425 f_body =
1426 vk_statement_sequencable_list_s bigf statxs;
1427 f_attr =
1428 attrs +> List.map (vk_attribute_s bigf);
1429 f_old_c_style =
1430 oldstyle +> Common.map_option (fun decls ->
1431 decls +> List.map (vk_decl_s bigf)
1432 );
1433 },
1434 iif ii
1435
1436 in f (k, bigf) d
1437
1438 and vk_toplevel_s = fun bigf p ->
1439 let f = bigf.ktoplevel_s in
1440 let iif ii = vk_ii_s bigf ii in
1441 let rec k p =
1442 match p with
1443 | Declaration decl -> Declaration (vk_decl_s bigf decl)
1444 | Definition def -> Definition (vk_def_s bigf def)
1445 | EmptyDef ii -> EmptyDef (iif ii)
1446 | MacroTop (s, xs, ii) ->
1447 MacroTop
1448 (s,
1449 xs +> List.map (fun (elem, iicomma) ->
1450 vk_argument_s bigf elem, iif iicomma
1451 ),
1452 iif ii
1453 )
1454 | CppTop top -> CppTop (vk_cpp_directive_s bigf top)
1455 | IfdefTop ifdefdir -> IfdefTop (vk_ifdef_directive_s bigf ifdefdir)
1456
1457 | NotParsedCorrectly ii -> NotParsedCorrectly (iif ii)
1458 | FinalDef info -> FinalDef (vk_info_s bigf info)
1459 in f (k, bigf) p
1460
1461 and vk_program_s = fun bigf xs ->
1462 xs +> List.map (vk_toplevel_s bigf)
1463
1464
1465 and vk_cpp_directive_s = fun bigf top ->
1466 let iif ii = vk_ii_s bigf ii in
1467 let f = bigf.kcppdirective_s in
1468 let rec k top =
1469 match top with
1470 (* go inside ? *)
1471 | Include {i_include = (s, ii);
1472 i_rel_pos = h_rel_pos;
1473 i_is_in_ifdef = b;
1474 i_content = copt;
1475 }
1476 -> Include {i_include = (s, iif ii);
1477 i_rel_pos = h_rel_pos;
1478 i_is_in_ifdef = b;
1479 i_content = copt +> Common.map_option (fun (file, asts) ->
1480 file, vk_program_s bigf asts
1481 );
1482 }
1483 | Define ((s,ii), (defkind, defval)) ->
1484 Define ((s, iif ii),
1485 (vk_define_kind_s bigf defkind, vk_define_val_s bigf defval))
1486 | Undef (s, ii) -> Undef (s, iif ii)
1487 | PragmaAndCo (ii) -> PragmaAndCo (iif ii)
1488
1489 in f (k, bigf) top
1490
1491 and vk_ifdef_directive_s = fun bigf ifdef ->
1492 let iif ii = vk_ii_s bigf ii in
1493 match ifdef with
1494 | IfdefDirective (ifkind, ii) -> IfdefDirective (ifkind, iif ii)
1495
1496
1497
1498 and vk_define_kind_s = fun bigf defkind ->
1499 match defkind with
1500 | DefineVar -> DefineVar
1501 | DefineFunc (params, ii) ->
1502 DefineFunc
1503 (params +> List.map (fun ((s,iis),iicomma) ->
1504 ((s, vk_ii_s bigf iis), vk_ii_s bigf iicomma)
1505 ),
1506 vk_ii_s bigf ii
1507 )
1508
1509
1510 and vk_define_val_s = fun bigf x ->
1511 let f = bigf.kdefineval_s in
1512 let iif ii = vk_ii_s bigf ii in
1513 let rec k x =
1514 match x with
1515 | DefineExpr e -> DefineExpr (vk_expr_s bigf e)
1516 | DefineStmt st -> DefineStmt (vk_statement_s bigf st)
1517 | DefineDoWhileZero ((st,e),ii) ->
1518 let st' = vk_statement_s bigf st in
1519 let e' = vk_expr_s bigf e in
1520 DefineDoWhileZero ((st',e'), iif ii)
1521 | DefineFunction def -> DefineFunction (vk_def_s bigf def)
1522 | DefineType ty -> DefineType (vk_type_s bigf ty)
1523 | DefineText (s, ii) -> DefineText (s, iif ii)
1524 | DefineEmpty -> DefineEmpty
1525 | DefineInit ini -> DefineInit (vk_ini_s bigf ini)
1526
1527 | DefineTodo ->
1528 pr2_once "DefineTodo";
1529 DefineTodo
1530 in
1531 f (k, bigf) x
1532
1533
1534 and vk_info_s = fun bigf info ->
1535 let rec infof ii = bigf.kinfo_s (k, bigf) ii
1536 and k i = i
1537 in
1538 infof info
1539
1540 and vk_ii_s = fun bigf ii ->
1541 List.map (vk_info_s bigf) ii
1542
1543 (* ------------------------------------------------------------------------ *)
1544 and vk_node_s = fun bigf node ->
1545 let iif ii = vk_ii_s bigf ii in
1546 let infof info = vk_info_s bigf info in
1547
1548 let rec nodef n = bigf.knode_s (k, bigf) n
1549 and k node =
1550 F.rewrap node (
1551 match F.unwrap node with
1552 | F.FunHeader (def) ->
1553 assert (null (fst def).f_body);
1554 F.FunHeader (vk_def_s bigf def)
1555
1556 | F.Decl declb -> F.Decl (vk_decl_s bigf declb)
1557 | F.ExprStatement (st, (eopt, ii)) ->
1558 F.ExprStatement (st, (eopt +> map_option (vk_expr_s bigf), iif ii))
1559
1560 | F.IfHeader (st, (e,ii)) ->
1561 F.IfHeader (st, (vk_expr_s bigf e, iif ii))
1562 | F.SwitchHeader (st, (e,ii)) ->
1563 F.SwitchHeader(st, (vk_expr_s bigf e, iif ii))
1564 | F.WhileHeader (st, (e,ii)) ->
1565 F.WhileHeader (st, (vk_expr_s bigf e, iif ii))
1566 | F.DoWhileTail (e,ii) ->
1567 F.DoWhileTail (vk_expr_s bigf e, iif ii)
1568
1569 | F.ForHeader (st, (((e1opt,i1), (e2opt,i2), (e3opt,i3)), ii)) ->
1570 F.ForHeader (st,
1571 (((e1opt +> Common.map_option (vk_expr_s bigf), iif i1),
1572 (e2opt +> Common.map_option (vk_expr_s bigf), iif i2),
1573 (e3opt +> Common.map_option (vk_expr_s bigf), iif i3)),
1574 iif ii))
1575
1576 | F.MacroIterHeader (st, ((s,es), ii)) ->
1577 F.MacroIterHeader
1578 (st,
1579 ((s, es +> List.map (fun (e, ii) -> vk_argument_s bigf e, iif ii)),
1580 iif ii))
1581
1582
1583 | F.ReturnExpr (st, (e,ii)) ->
1584 F.ReturnExpr (st, (vk_expr_s bigf e, iif ii))
1585
1586 | F.Case (st, (e,ii)) -> F.Case (st, (vk_expr_s bigf e, iif ii))
1587 | F.CaseRange (st, ((e1, e2),ii)) ->
1588 F.CaseRange (st, ((vk_expr_s bigf e1, vk_expr_s bigf e2), iif ii))
1589
1590 | F.CaseNode i -> F.CaseNode i
1591
1592 | F.DefineHeader((s,ii), (defkind)) ->
1593 F.DefineHeader ((s, iif ii), (vk_define_kind_s bigf defkind))
1594
1595 | F.DefineExpr e -> F.DefineExpr (vk_expr_s bigf e)
1596 | F.DefineType ft -> F.DefineType (vk_type_s bigf ft)
1597 | F.DefineDoWhileZeroHeader ((),ii) ->
1598 F.DefineDoWhileZeroHeader ((),iif ii)
1599 | F.DefineTodo -> F.DefineTodo
1600
1601 | F.Include {i_include = (s, ii);
1602 i_rel_pos = h_rel_pos;
1603 i_is_in_ifdef = b;
1604 i_content = copt;
1605 }
1606 ->
1607 assert (copt =*= None);
1608 F.Include {i_include = (s, iif ii);
1609 i_rel_pos = h_rel_pos;
1610 i_is_in_ifdef = b;
1611 i_content = copt;
1612 }
1613
1614 | F.MacroTop (s, args, ii) ->
1615 F.MacroTop
1616 (s,
1617 args +> List.map (fun (e, ii) -> vk_argument_s bigf e, iif ii),
1618 iif ii)
1619
1620
1621 | F.MacroStmt (st, ((),ii)) -> F.MacroStmt (st, ((),iif ii))
1622 | F.Asm (st, (body,ii)) -> F.Asm (st, (vk_asmbody_s bigf body,iif ii))
1623
1624 | F.Break (st,((),ii)) -> F.Break (st,((),iif ii))
1625 | F.Continue (st,((),ii)) -> F.Continue (st,((),iif ii))
1626 | F.Default (st,((),ii)) -> F.Default (st,((),iif ii))
1627 | F.Return (st,((),ii)) -> F.Return (st,((),iif ii))
1628 | F.Goto (st, name, ((),ii)) ->
1629 F.Goto (st, vk_name_s bigf name, ((),iif ii))
1630 | F.Label (st, name, ((),ii)) ->
1631 F.Label (st, vk_name_s bigf name, ((),iif ii))
1632 | F.EndStatement iopt -> F.EndStatement (map_option infof iopt)
1633 | F.DoHeader (st, info) -> F.DoHeader (st, infof info)
1634 | F.Else info -> F.Else (infof info)
1635 | F.SeqEnd (i, info) -> F.SeqEnd (i, infof info)
1636 | F.SeqStart (st, i, info) -> F.SeqStart (st, i, infof info)
1637
1638 | F.IfdefHeader (info) -> F.IfdefHeader (vk_ifdef_directive_s bigf info)
1639 | F.IfdefElse (info) -> F.IfdefElse (vk_ifdef_directive_s bigf info)
1640 | F.IfdefEndif (info) -> F.IfdefEndif (vk_ifdef_directive_s bigf info)
1641
1642 | (
1643 (
1644 F.TopNode|F.EndNode|
1645 F.ErrorExit|F.Exit|F.Enter|F.LoopFallThroughNode|F.FallThroughNode|
1646 F.AfterNode|F.FalseNode|F.TrueNode|F.InLoopNode|
1647 F.Fake
1648 ) as x) -> x
1649
1650
1651 )
1652 in
1653 nodef node
1654
1655 (* ------------------------------------------------------------------------ *)
1656 and vk_param_s = fun bigf param ->
1657 let iif ii = vk_ii_s bigf ii in
1658 let {p_namei = swrapopt; p_register = (b, iib); p_type=ft} = param in
1659 { p_namei = swrapopt +> Common.map_option (vk_name_s bigf);
1660 p_register = (b, iif iib);
1661 p_type = vk_type_s bigf ft;
1662 }
1663
1664 let vk_arguments_s = fun bigf args ->
1665 let iif ii = vk_ii_s bigf ii in
1666 args +> List.map (fun (e, ii) -> vk_argument_s bigf e, iif ii)
1667
1668 let vk_params_s = fun bigf args ->
1669 let iif ii = vk_ii_s bigf ii in
1670 args +> List.map (fun (p,ii) -> vk_param_s bigf p, iif ii)
1671
1672 let vk_cst_s = fun bigf (cst, ii) ->
1673 let iif ii = vk_ii_s bigf ii in
1674 (match cst with
1675 | Left cst -> Left cst
1676 | Right s -> Right s
1677 ), iif ii
1678
1679 (* ------------------------------------------------------------------------ *)
1680
1681 let vk_splitted_s element = fun bigf args_splitted ->
1682 let iif ii = vk_ii_s bigf ii in
1683 args_splitted +> List.map (function
1684 | Left arg -> Left (element bigf arg)
1685 | Right ii -> Right (iif ii)
1686 )
1687
1688 let vk_args_splitted_s = vk_splitted_s vk_argument_s
1689 let vk_params_splitted_s = vk_splitted_s vk_param_s
1690 let vk_define_params_splitted_s =
1691 vk_splitted_s (fun bigf (s,ii) -> (s,vk_ii_s bigf ii))
1692 let vk_enum_fields_splitted_s = vk_splitted_s vk_oneEnum_s
1693 let vk_inis_splitted_s = vk_splitted_s vk_ini_s
Unnamed repository; edit this file 'description' to name the repository.