vimscript/step3_env.vim

   1 source readline.vim
   2 source types.vim
   3 source reader.vim
   4 source printer.vim
   5 source env.vim
   6
   7 function READ(str)
   8   return ReadStr(a:str)
   9 endfunction
  10
  11 function EvalAst(ast, env)
  12   if SymbolQ(a:ast)
  13     let varname = a:ast.val
  14     return a:env.get(varname)
  15   elseif ListQ(a:ast)
  16     let ret = []
  17     for e in a:ast.val
  18       call add(ret, EVAL(e, a:env))
  19     endfor
  20     return ListNew(ret)
  21   elseif VectorQ(a:ast)
  22     let ret = []
  23     for e in a:ast.val
  24       call add(ret, EVAL(e, a:env))
  25     endfor
  26     return VectorNew(ret)
  27   elseif HashQ(a:ast)
  28     let ret = {}
  29     for [k,v] in items(a:ast.val)
  30       let keyobj = HashParseKey(k)
  31       let newkey = EVAL(keyobj, a:env)
  32       let newval = EVAL(v, a:env)
  33       let keystring = HashMakeKey(newkey)
  34       let ret[keystring] = newval
  35     endfor
  36     return HashNew(ret)
  37   else
  38     return a:ast
  39   end
  40 endfunction
  41
  42 function EVAL(ast, env)
  43   if !ListQ(a:ast)
  44     return EvalAst(a:ast, a:env)
  45   end
  46   if EmptyQ(a:ast)
  47     return a:ast
  48   endif
  49
  50   let first_symbol = a:ast.val[0].val
  51   if first_symbol == "def!"
  52     let a1 = a:ast.val[1]
  53     let a2 = a:ast.val[2]
  54     return a:env.set(a1.val, EVAL(a2, a:env))
  55   elseif first_symbol == "let*"
  56     let a1 = a:ast.val[1]
  57     let a2 = a:ast.val[2]
  58     let let_env = NewEnv(a:env)
  59     let let_binds = a1.val
  60     let i = 0
  61     while i < len(let_binds)
  62       call let_env.set(let_binds[i].val, EVAL(let_binds[i+1], let_env))
  63       let i = i + 2
  64     endwhile
  65     return EVAL(a2, let_env)
  66   else
  67     " apply list
  68     let el = EvalAst(a:ast, a:env)
  69     let Fn = el.val[0]
  70     return Fn(el.val[1:-1])
  71   endif
  72
  73 endfunction
  74
  75 function PRINT(exp)
  76   return PrStr(a:exp, 1)
  77 endfunction
  78
  79 function REP(str, env)
  80   return PRINT(EVAL(READ(a:str), a:env))
  81 endfunction
  82
  83 let repl_env = NewEnv("")
  84 call repl_env.set("+", {a -> IntegerNew(a[0].val + a[1].val)})
  85 call repl_env.set("-", {a -> IntegerNew(a[0].val - a[1].val)})
  86 call repl_env.set("*", {a -> IntegerNew(a[0].val * a[1].val)})
  87 call repl_env.set("/", {a -> IntegerNew(a[0].val / a[1].val)})
  88
  89 while 1
  90   let [eof, line] = Readline("user> ")
  91   if eof
  92     break
  93   endif
  94   if line == ""
  95     continue
  96   endif
  97   try
  98     call PrintLn(REP(line, repl_env))
  99   catch
 100     call PrintLn("Error: " . v:exception)
 101   endtry
 102 endwhile
 103 qall!