wasm/stepA_mal.wam

   1 (module $stepA_mal
   2
   3   (global $repl_env (mut i32) (i32.const 0))
   4
   5   ;; READ
   6   (func $READ (param $str i32) (result i32)
   7     ($read_str $str)
   8   )
   9
  10   ;; EVAL
  11   (func $is_pair (param $ast i32) (result i32)
  12     (LET $type ($TYPE $ast))
  13     (AND (OR (i32.eq $type (global.get $LIST_T))
  14              (i32.eq $type (global.get $VECTOR_T)))
  15          (i32.ne ($VAL0 $ast) 0))
  16   )
  17
  18   (func $QUASIQUOTE (param $ast i32) (result i32)
  19     (LET $res 0 $sym 0 $second 0 $third 0)
  20     (if (i32.eqz ($is_pair $ast)) ;; QQ_QUOTE
  21       (then
  22         (local.set $sym ($STRING (global.get $SYMBOL_T) "quote"))
  23         ;; ['quote ast]
  24         (local.set $res ($LIST2 $sym $ast))
  25         ($RELEASE $sym))
  26       (else
  27         (local.set $res ($MEM_VAL1_ptr $ast))
  28         (if (AND (i32.eq ($TYPE $res) (global.get $SYMBOL_T))
  29                  (i32.eqz ($strcmp "unquote" ($to_String $res))))
  30           (then
  31             ;; ast[1]
  32             (local.set $res ($INC_REF ($MEM_VAL1_ptr ($MEM_VAL0_ptr $ast)))))
  33         (else (if (AND ($is_pair $res)
  34                        (i32.eq ($TYPE ($MEM_VAL1_ptr $res))
  35                                (global.get $SYMBOL_T))
  36                        (i32.eqz ($strcmp "splice-unquote"
  37                                          ($to_String ($MEM_VAL1_ptr $res)))))
  38           (then
  39             ;; ['concat, ast[0][1], quasiquote(ast[1..])]
  40             (local.set $sym ($STRING (global.get $SYMBOL_T) "concat"))
  41             (local.set $second
  42                        ($MEM_VAL1_ptr ($MEM_VAL0_ptr ($MEM_VAL1_ptr $ast))))
  43             (local.set $third ($QUASIQUOTE ($MEM_VAL0_ptr $ast)))
  44             (local.set $res ($LIST3 $sym $second $third))
  45             ;; release inner quasiquoted since outer list take ownership
  46             ($RELEASE $third)
  47             ($RELEASE $sym))
  48           (else
  49             ;; ['cons, quasiquote(ast[0]), quasiquote(ast[1..])]
  50             (local.set $sym ($STRING (global.get $SYMBOL_T) "cons"))
  51             (local.set $second ($QUASIQUOTE ($MEM_VAL1_ptr $ast)))
  52             (local.set $third ($QUASIQUOTE ($MEM_VAL0_ptr $ast)))
  53             (local.set $res ($LIST3 $sym $second $third))
  54             ;; release inner quasiquoted since outer list takes ownership
  55             ($RELEASE $third)
  56             ($RELEASE $second)
  57             ($RELEASE $sym)))))))
  58     $res
  59   )
  60
  61   (global $mac_stack (mut i32) (i32.const 0))
  62   (global $mac_stack_top (mut i32) (i32.const -1))
  63
  64   (func $MACROEXPAND (param $orig_ast i32 $env i32) (result i32)
  65     (local $mac_env i64)
  66     (LET $ast $orig_ast
  67          $mac 0)
  68     (global.set $mac_stack (STATIC_ARRAY 2048)) ;; 512 * 4, TODO: move to init
  69     (block $done
  70       (loop $loop
  71         (br_if $done
  72                (OR (i32.ne ($TYPE $ast) (global.get $LIST_T)) ;; a list
  73                    (i32.eqz ($VAL0 $ast))                     ;; non-empty
  74                    (i32.ne ($TYPE ($MEM_VAL1_ptr $ast))       ;; leading symbol
  75                            (global.get $SYMBOL_T))))
  76         (local.set $mac_env ($ENV_FIND $env ($MEM_VAL1_ptr $ast)))
  77         (local.set $mac (i32.wrap_i64 (i64.shr_u $mac_env (i64.const 32))))
  78         (br_if $done (OR (i32.eqz (i32.wrap_i64 $mac_env))    ;; defined in env
  79                          (i32.ne ($TYPE $mac)                 ;; a macro
  80                                  (global.get $MACRO_T))))
  81
  82         (local.set $ast ($APPLY $mac ($MEM_VAL0_ptr $ast)))
  83         ;; PEND_A_LV
  84         ;; if ast is not the first ast that was passed in, then add it
  85         ;; to the pending release list.
  86         (if (i32.ne $ast $orig_ast)
  87           (then
  88             (global.set $mac_stack_top
  89                         (i32.add (global.get $mac_stack_top) 1))
  90             (if (i32.ge_s (i32.mul (global.get $mac_stack_top) 4) 2048) ;; 512 * 4
  91               ($fatal 7 "Exhausted mac_stack!\n"))
  92             (i32.store (i32.add
  93                          (global.get $mac_stack)
  94                          (i32.mul (global.get $mac_stack_top) 4))
  95               $ast)))
  96         (br_if $done (global.get $error_type))
  97
  98         (br $loop)
  99       )
 100     )
 101     $ast
 102   )
 103
 104   (func $EVAL_AST (param $ast i32 $env i32 $skiplast i32) (result i32)
 105     (LET $res 0 $val2 0 $val3 0 $type 0 $found 0
 106          $ret 0 $empty 0 $current 0)
 107
 108     (if (global.get $error_type) (return 0))
 109     (local.set $type ($TYPE $ast))
 110
 111     ;;($PR_VALUE ">>> EVAL_AST ast: '%s'\n" $ast)
 112
 113     ;;; switch(type)
 114     (block $done
 115       (block $default (block (block
 116       (br_table 2 2 2 2 2 0 1 1 1 2 2 2 2 2 2 2 $type))
 117       ;; symbol
 118       ;; found/res returned as hi 32/lo 32 of i64
 119       (local.set $res ($ENV_GET $env $ast))
 120       (br $done))
 121       ;; list, vector, hashmap
 122       ;; MAP_LOOP_START
 123       (local.set $res ($MAP_LOOP_START $type))
 124       ;; push MAP_LOOP stack
 125       ;;; empty = current = ret = res
 126       (local.set $ret $res)
 127       (local.set $current $res)
 128       (local.set $empty $res)
 129
 130       (block $done
 131         (loop $loop
 132           ;; check if we are done evaluating the source sequence
 133           (br_if $done (i32.eq ($VAL0 $ast) 0))
 134
 135           (if $skiplast
 136             (br_if $done (i32.eqz ($VAL0 ($MEM_VAL0_ptr $ast)))))
 137
 138           (if (i32.eq $type (global.get $HASHMAP_T))
 139             (then
 140               (local.set $res ($EVAL ($MEM_VAL2_ptr $ast) $env)))
 141             (else
 142               (local.set $res ($EVAL ($MEM_VAL1_ptr $ast) $env))))
 143           (local.set $val2 $res)
 144
 145           ;; if error, release the unattached element
 146           (if (global.get $error_type)
 147             (then
 148               ($RELEASE $res)
 149               (local.set $res 0)
 150               (br $done)))
 151
 152           ;; for hash-maps, copy the key (inc ref since we are going
 153           ;; to release it below)
 154           (if (i32.eq $type (global.get $HASHMAP_T))
 155             (then
 156               (local.set $val3 $val2)
 157               (local.set $val2 ($MEM_VAL1_ptr $ast))
 158               (drop ($INC_REF $val2))))
 159
 160           ;; MAP_LOOP_UPDATE
 161           (local.set $res ($MAP_LOOP_UPDATE $type $empty $current $val2 $val3))
 162           (if (i32.le_u $current (global.get $EMPTY_HASHMAP))
 163             ;; if first element, set return to new element
 164             (local.set $ret $res))
 165           ;; update current to point to new element
 166           (local.set $current $res)
 167
 168           (local.set $ast ($MEM_VAL0_ptr $ast))
 169
 170           (br $loop)
 171         )
 172       )
 173       ;; MAP_LOOP_DONE
 174       (local.set $res $ret)
 175       ;; EVAL_AST_RETURN: nothing to do
 176       (br $done))
 177       ;; default
 178       (local.set $res ($INC_REF $ast))
 179     )
 180
 181     $res
 182   )
 183
 184   (func $MAL_GET_A1 (param $ast i32) (result i32)
 185     ($MEM_VAL1_ptr ($MEM_VAL0_ptr $ast)))
 186   (func $MAL_GET_A2 (param $ast i32) (result i32)
 187     ($MEM_VAL1_ptr ($MEM_VAL0_ptr ($MEM_VAL0_ptr $ast))))
 188   (func $MAL_GET_A3 (param $ast i32) (result i32)
 189     ($MEM_VAL1_ptr ($MEM_VAL0_ptr ($MEM_VAL0_ptr ($MEM_VAL0_ptr $ast)))))
 190
 191   (func $EVAL (param $orig_ast i32 $orig_env i32) (result i32)
 192     (LET $ast $orig_ast
 193          $env $orig_env
 194          $orig_mac_stack_top (global.get $mac_stack_top)
 195          $prev_ast 0 $prev_env 0 $res 0 $el 0
 196          $ftype 0 $f_args 0 $f 0 $args 0
 197          $a0 0 $a0sym 0 $a1 0 $a2 0
 198          $err 0)
 199
 200     (block $EVAL_return
 201     (loop $TCO_loop
 202
 203     (local.set $f_args 0)
 204     (local.set $f 0)
 205     (local.set $args 0)
 206
 207     (if (global.get $error_type)
 208       (then
 209         (local.set $res 0)
 210         (br $EVAL_return)))
 211
 212     ;;($PR_VALUE ">>> EVAL ast: '%s'\n" $ast)
 213
 214     (if (i32.ne ($TYPE $ast) (global.get $LIST_T))
 215       (then
 216         (local.set $res ($EVAL_AST $ast $env 0))
 217         (br $EVAL_return)))
 218
 219     ;; APPLY_LIST
 220     (local.set $ast ($MACROEXPAND $ast $env))
 221     ;;($PR_VALUE ">>> >>> EVAL ast: '%s'\n" $ast)
 222
 223     (if (i32.ne ($TYPE $ast) (global.get $LIST_T))
 224       (then
 225         (local.set $res ($EVAL_AST $ast $env 0))
 226         (br $EVAL_return)))
 227
 228     (if ($EMPTY_Q $ast)
 229       (then
 230         (local.set $res ($INC_REF $ast))
 231         (br $EVAL_return)))
 232
 233     (local.set $a0 ($MEM_VAL1_ptr $ast))
 234     (local.set $a0sym "")
 235     (if (i32.eq ($TYPE $a0) (global.get $SYMBOL_T))
 236       (local.set $a0sym ($to_String $a0)))
 237
 238     (if (i32.eqz ($strcmp "def!" $a0sym))
 239       (then
 240         (local.set $a1 ($MAL_GET_A1 $ast))
 241         (local.set $a2 ($MAL_GET_A2 $ast))
 242         (local.set $res ($EVAL $a2 $env))
 243         (br_if $EVAL_return (global.get $error_type))
 244
 245         ;; set a1 in env to a2
 246         (local.set $res ($ENV_SET $env $a1 $res))
 247         (br $EVAL_return))
 248     (else (if (i32.eqz ($strcmp "let*" $a0sym))
 249       (then
 250         (local.set $a1 ($MAL_GET_A1 $ast))
 251         (local.set $a2 ($MAL_GET_A2 $ast))
 252
 253         ;; create new environment with outer as current environment
 254         (local.set $prev_env $env) ;; save env for later release
 255         (local.set $env ($ENV_NEW $env))
 256
 257         (block $done
 258           (loop $loop
 259             (br_if $done (i32.eqz ($VAL0 $a1)))
 260             ;; eval current A1 odd element
 261             (local.set $res ($EVAL ($MEM_VAL1_ptr ($MEM_VAL0_ptr $a1)) $env))
 262
 263             (br_if $done (global.get $error_type))
 264
 265             ;; set key/value in the let environment
 266             (local.set $res ($ENV_SET $env ($MEM_VAL1_ptr $a1) $res))
 267             ;; release our use, ENV_SET took ownership
 268             ($RELEASE $res)
 269
 270             ;; skip to the next pair of a1 elements
 271             (local.set $a1 ($MEM_VAL0_ptr ($MEM_VAL0_ptr $a1)))
 272             (br $loop)
 273           )
 274         )
 275
 276         ;; release previous environment if not the current EVAL env
 277         (if (i32.ne $prev_env $orig_env)
 278           (then
 279             ($RELEASE $prev_env)
 280             (local.set $prev_env 0)))
 281
 282         (local.set $ast $a2)
 283         (br $TCO_loop))
 284     (else (if (i32.eqz ($strcmp "do" $a0sym))
 285       (then
 286         ;; EVAL the rest through second to last
 287         (local.set $el ($EVAL_AST ($MEM_VAL0_ptr $ast) $env 1))
 288         (local.set $ast ($LAST $ast))
 289         ($RELEASE $ast) ;; we already own it via ast
 290         ($RELEASE $el)
 291         (br $TCO_loop))
 292     (else (if (i32.eqz ($strcmp "quote" $a0sym))
 293       (then
 294         (local.set $res ($INC_REF ($MEM_VAL1_ptr ($MEM_VAL0_ptr $ast))))
 295         (br $EVAL_return))
 296     (else (if (i32.eqz ($strcmp "quasiquote" $a0sym))
 297       (then
 298         (local.set $ast ($QUASIQUOTE ($MEM_VAL1_ptr ($MEM_VAL0_ptr $ast))))
 299
 300         ;; if we have already been here via TCO, release previous ast
 301         (if $prev_ast ($RELEASE $prev_ast))
 302         (local.set $prev_ast $ast)
 303         (br $TCO_loop))
 304     (else (if (i32.eqz ($strcmp "defmacro!" $a0sym))
 305       (then
 306         (local.set $a1 ($MAL_GET_A1 $ast))
 307         (local.set $a2 ($MAL_GET_A2 $ast))
 308         (local.set $res ($EVAL $a2 $env))
 309         ($SET_TYPE $res (global.get $MACRO_T))
 310         (br_if $EVAL_return (global.get $error_type))
 311
 312         ;; set a1 in env to a2
 313         (local.set $res ($ENV_SET $env $a1 $res))
 314         (br $EVAL_return))
 315     (else (if (i32.eqz ($strcmp "macroexpand" $a0sym))
 316       (then
 317         ;; since we are returning it unevaluated, inc the ref cnt
 318         (local.set $res ($INC_REF ($MACROEXPAND
 319                                     ($MEM_VAL1_ptr ($MEM_VAL0_ptr $ast))
 320                                     $env))))
 321     (else (if (i32.eqz ($strcmp "try*" $a0sym))
 322       (then
 323         (local.set $a1 ($MAL_GET_A1 $ast))
 324         (local.set $res ($EVAL $a1 $env))
 325
 326         ;; if there is no error, return
 327         (br_if $EVAL_return (i32.eqz (global.get $error_type)))
 328         ;; if there is an error and res is set, we need to free it
 329         ($RELEASE $res)
 330         ;; if there is no catch block then return
 331         (br_if $EVAL_return
 332                (i32.eqz ($VAL0 ($MEM_VAL0_ptr ($MEM_VAL0_ptr $ast)))))
 333
 334         ;; save the current environment for release
 335         (local.set $prev_env $env)
 336         ;; create environment for the catch block eval
 337         (local.set $env ($ENV_NEW $env))
 338
 339         ;; set a1 and a2 from the catch block
 340         (local.set $a1 ($MAL_GET_A1 ($MAL_GET_A2 $ast)))
 341         (local.set $a2 ($MAL_GET_A2 ($MAL_GET_A2 $ast)))
 342
 343         ;; create object for string errors
 344         (if (i32.eq (global.get $error_type) 1)
 345           (then
 346             (local.set $err ($STRING (global.get $STRING_T)
 347                                      (global.get $error_str))))
 348           (else
 349             (local.set $err (global.get $error_val))))
 350         ;; bind the catch symbol to the error object
 351         (drop ($ENV_SET $env $a1 $err))
 352         ;; release our use, env took ownership
 353         ($RELEASE $err)
 354
 355         ;; unset error for catch eval
 356         (global.set $error_type 0)
 357         (i32.store (global.get $error_str) (CHR "\x00"))
 358
 359         ;; release previous environment if not the current EVAL env
 360         (if (i32.ne $prev_env $orig_env)
 361           (then
 362             ($RELEASE $prev_env)
 363             (local.set $prev_env 0)))
 364
 365         (local.set $ast $a2)
 366         (br $TCO_loop))
 367     (else (if (i32.eqz ($strcmp "if" $a0sym))
 368       (then
 369         (local.set $a1 ($MAL_GET_A1 $ast))
 370         (local.set $res ($EVAL $a1 $env))
 371
 372         (if (global.get $error_type)
 373           (then (nop))
 374         (else (if (OR (i32.eq $res (global.get $NIL))
 375                       (i32.eq $res (global.get $FALSE)))
 376           (then
 377             ($RELEASE $res)
 378             ;; if no false case (A3), return nil
 379             (if (i32.lt_u ($COUNT $ast) 4)
 380               (then
 381                 (local.set $res ($INC_REF (global.get $NIL)))
 382                 (br $EVAL_return))
 383               (else
 384                 (local.set $ast ($MAL_GET_A3 $ast)))))
 385         (else
 386           ($RELEASE $res)
 387           (local.set $ast ($MAL_GET_A2 $ast))))))
 388         (br $TCO_loop))
 389     (else (if (i32.eqz ($strcmp "fn*" $a0sym))
 390       (then
 391         (local.set $a1 ($MAL_GET_A1 $ast))
 392         (local.set $a2 ($MAL_GET_A2 $ast))
 393         (local.set $res ($MALFUNC $a2 $a1 $env))
 394         (br $EVAL_return))
 395     (else
 396       ;; EVAL_INVOKE
 397       (local.set $res ($EVAL_AST $ast $env 0))
 398       (local.set $f_args $res)
 399
 400       ;; if error, return f/args for release by caller
 401       (if (global.get $error_type)
 402        (then
 403          (local.set $res $f_args)
 404          (br $EVAL_return)))
 405
 406       (local.set $args ($MEM_VAL0_ptr $f_args)) ;; rest
 407       (local.set $f ($DEREF_META ($MEM_VAL1_ptr $f_args))) ;; value
 408
 409       (local.set $ftype ($TYPE $f))
 410       (if (i32.eq $ftype (global.get $FUNCTION_T))
 411         (then
 412           (if (i32.eq ($VAL0 $f) 0) ;; eval
 413             (then
 414               (local.set $res ($EVAL ($MEM_VAL1_ptr $args)
 415                                      (global.get $repl_env))))
 416             (else
 417               (local.set $res (call_indirect (type $fnT) $args ($VAL0 $f)))))
 418           ;; release f/args
 419           ($RELEASE $f_args)
 420           (br $EVAL_return))
 421       (else (if (i32.eq $ftype (global.get $MALFUNC_T))
 422         (then
 423           ;; save the current environment for release
 424           (local.set $prev_env $env)
 425           ;; create new environment using env and params stored in function
 426           (local.set $env ($ENV_NEW_BINDS ($MEM_VAL2_ptr $f)
 427                                           ($MEM_VAL1_ptr $f) $args))
 428
 429           ;; release previous environment if not the current EVAL env
 430           ;; because our new env refers to it and we no longer need to
 431           ;; track it (since we are TCO recurring)
 432           (if (i32.ne $prev_env $orig_env)
 433             (then
 434               ($RELEASE $prev_env)
 435               (local.set $prev_env 0)))
 436
 437           ;; claim the AST before releasing the list containing it
 438           (local.set $ast ($MEM_VAL0_ptr $f))
 439           (drop ($INC_REF $ast))
 440
 441           ;; if we have already been here via TCO, release previous
 442           ;; ast
 443           ;; PEND_A_LV
 444           (if $prev_ast ($RELEASE $prev_ast))
 445           (local.set $prev_ast $ast)
 446
 447           ;; release f/args
 448           ($RELEASE $f_args)
 449
 450           (br $TCO_loop))
 451       (else
 452         ($THROW_STR_1 "apply of non-function type: %d\n" $ftype)
 453         (local.set $res 0)
 454         ($RELEASE $f_args)
 455         (br $EVAL_return)))))))))))))))))))))))))
 456
 457     ) ;; end of TCO_loop
 458     ) ;; end of EVAL_return
 459
 460     ;; EVAL_RETURN
 461     (if (i32.ne $env $orig_env) ($RELEASE $env))
 462     (if $prev_ast ($RELEASE $prev_ast))
 463
 464     ;; release memory from MACROEXPAND
 465     ;; TODO: needs to happen here so self-hosting doesn't leak
 466     (block $done
 467       (loop $loop
 468         (br_if $done (i32.le_s (global.get $mac_stack_top) $orig_mac_stack_top))
 469         ($RELEASE (i32.load (i32.add
 470                               (global.get $mac_stack)
 471                               (i32.mul (global.get $mac_stack_top) 4))))
 472         (global.set $mac_stack_top
 473                     (i32.sub (global.get $mac_stack_top) 1))
 474         (br $loop)
 475       )
 476     )
 477
 478     $res
 479   )
 480
 481   ;; PRINT
 482   (func $PRINT (param $ast i32) (result i32)
 483     ($pr_str $ast 1)
 484   )
 485
 486   ;; REPL
 487   (func $RE (param $line i32 $env i32) (result i32)
 488     (LET $mv1 0 $res 0)
 489     (block $done
 490       (local.set $mv1 ($READ $line))
 491       (br_if $done (global.get $error_type))
 492
 493       (local.set $res ($EVAL $mv1 $env))
 494     )
 495
 496     ;; release memory from MAL_READ
 497     ($RELEASE $mv1)
 498     $res
 499   )
 500
 501   (func $REP (param $line i32 $env i32) (result i32)
 502     (LET $mv2 0 $ms 0)
 503     (block $done
 504       (local.set $mv2 ($RE $line $env))
 505       (br_if $done (global.get $error_type))
 506
 507 ;;      ($PR_MEMORY -1 -1)
 508       (local.set $ms ($PRINT $mv2))
 509     )
 510
 511     ;; release memory from RE
 512     ($RELEASE $mv2)
 513     $ms
 514   )
 515
 516   (func $main (param $argc i32 $argv i32) (result i32)
 517     (LET $line (STATIC_ARRAY 201)
 518          $res 0 $repl_env 0 $ms 0
 519          ;; argument processing
 520          $i 0 $ret 0 $empty 0 $current 0 $val2 0)
 521
 522     ;; DEBUG
 523 ;;    ($printf_1 "argc: 0x%x\n" $argc)
 524 ;;    ($printf_1 "memoryBase: 0x%x\n" (global.get $memoryBase))
 525 ;;    ($printf_1 "heap_start: 0x%x\n" (global.get $heap_start))
 526 ;;    ($printf_1 "heap_end: 0x%x\n" (global.get $heap_end))
 527 ;;    ($printf_1 "mem: 0x%x\n" (global.get $mem))
 528 ;;    ($printf_1 "string_mem: %d\n" (global.get $string_mem))
 529
 530     (global.set $repl_env ($ENV_NEW (global.get $NIL)))
 531     (local.set $repl_env (global.get $repl_env))
 532
 533     ;; core.EXT: defined in wasm
 534     ($add_core_ns $repl_env)
 535     (drop ($ENV_SET_S $repl_env "eval" ($FUNCTION 0)))
 536
 537     ($checkpoint_user_memory)
 538
 539     ;; core.mal: defined using the language itself
 540     ($RELEASE ($RE "(def! *host-language* \"WebAssembly\")" $repl_env))
 541     ($RELEASE ($RE "(def! not (fn* (a) (if a false true)))" $repl_env))
 542     ($RELEASE ($RE "(def! load-file (fn* (f) (eval (read-string (str \"(do \" (slurp f) \"\nnil)\")))))" $repl_env))
 543     ($RELEASE ($RE "(defmacro! cond (fn* (& xs) (if (> (count xs) 0) (list 'if (first xs) (if (> (count xs) 1) (nth xs 1) (throw \"odd number of forms to cond\")) (cons 'cond (rest (rest xs)))))))" $repl_env))
 544
 545     ;; Command line arguments
 546     (local.set $res ($MAP_LOOP_START (global.get $LIST_T)))
 547     ;; push MAP_LOP stack
 548     ;; empty = current = ret = res
 549     (local.set $ret $res)
 550     (local.set $current $res)
 551     (local.set $empty $res)
 552
 553     (local.set $i 2)
 554     (block $done
 555       (loop $loop
 556         (br_if $done (i32.ge_u $i $argc))
 557
 558         (local.set $val2 ($STRING (global.get $STRING_T)
 559                                   (i32.load (i32.add $argv (i32.mul $i 4)))))
 560
 561         ;; MAP_LOOP_UPDATE
 562         (local.set $res ($MAP_LOOP_UPDATE
 563                           (global.get $LIST_T) $empty $current $val2 0))
 564         (if (i32.le_u $current (global.get $EMPTY_HASHMAP))
 565           ;; if first element, set return to new element
 566           (local.set $ret $res))
 567         ;; update current to point to new element
 568         (local.set $current $res)
 569
 570         (local.set $i (i32.add $i 1))
 571         (br $loop)
 572       )
 573     )
 574     (drop ($ENV_SET_S $repl_env "*ARGV*" $ret))
 575
 576
 577     ;;($PR_MEMORY -1 -1)
 578
 579     (if (i32.gt_u $argc 1)
 580       (then
 581         (drop ($ENV_SET_S $repl_env
 582                           "*FILE*" ($STRING (global.get $STRING_T)
 583                                             (i32.load (i32.add $argv 4)))))
 584         ($RELEASE ($RE "(load-file *FILE*)" $repl_env))
 585         (if (global.get $error_type)
 586           (then
 587             ($printf_1 "Error: %s\n" (global.get $error_str))
 588             (return 1))
 589           (else
 590             (return 0)))))
 591
 592     ($RELEASE ($RE "(println (str \"Mal [\" *host-language* \"]\"))" $repl_env))
 593
 594     ;; Start REPL
 595     (block $repl_done
 596       (loop $repl_loop
 597         (br_if $repl_done (i32.eqz ($readline "user> " $line)))
 598         (br_if $repl_loop (i32.eq (i32.load8_u $line) 0))
 599         (local.set $res ($REP $line $repl_env))
 600         (if (global.get $error_type)
 601           (then
 602             (if (i32.eq 2 (global.get $error_type))
 603               (then
 604                 (local.set $ms ($pr_str (global.get $error_val) 1))
 605                 ($printf_1 "Error: %s\n" ($to_String $ms))
 606                 ($RELEASE $ms)
 607                 ($RELEASE (global.get $error_val)))
 608               (else
 609                 ($printf_1 "Error: %s\n" (global.get $error_str))))
 610             (global.set $error_type 0))
 611           (else
 612             ($printf_1 "%s\n" ($to_String $res))))
 613         ($RELEASE $res)
 614         ;;($PR_MEMORY_SUMMARY_SMALL)
 615         (br $repl_loop)
 616       )
 617     )
 618
 619     ($print "\n")
 620     ;;($PR_MEMORY -1 -1)
 621     0
 622   )
 623
 624 )
 625