pike/step4_if_fn_do.pike

   1 import .Env;
   2 import .Printer;
   3 import .Reader;
   4 import .Readline;
   5 import .Types;
   6
   7 Val READ(string str)
   8 {
   9   return read_str(str);
  10 }
  11
  12 Val eval_ast(Val ast, Env env)
  13 {
  14   switch(ast.mal_type)
  15   {
  16     case MALTYPE_SYMBOL:
  17       return env.get(ast);
  18     case MALTYPE_LIST:
  19       return List(map(ast.data, lambda(Val e) { return EVAL(e, env); }));
  20     case MALTYPE_VECTOR:
  21       return Vector(map(ast.data, lambda(Val e) { return EVAL(e, env); }));
  22     case MALTYPE_MAP:
  23       array(Val) elements = ({ });
  24       foreach(ast.data; Val k; Val v)
  25       {
  26         elements += ({ k, EVAL(v, env) });
  27       }
  28       return Map(elements);
  29     default:
  30       return ast;
  31   }
  32 }
  33
  34 Val EVAL(Val ast, Env env)
  35 {
  36   if(ast.mal_type != MALTYPE_LIST) return eval_ast(ast, env);
  37   if(ast.emptyp()) return ast;
  38   if(ast.data[0].mal_type == MALTYPE_SYMBOL) {
  39     switch(ast.data[0].value)
  40     {
  41       case "def!":
  42         return env.set(ast.data[1], EVAL(ast.data[2], env));
  43       case "let*":
  44         Env let_env = Env(env);
  45         Val ast1 = ast.data[1];
  46         for(int i = 0; i < sizeof(ast1.data); i += 2)
  47         {
  48           let_env.set(ast1.data[i], EVAL(ast1.data[i + 1], let_env));
  49         }
  50         return EVAL(ast.data[2], let_env);
  51       case "do":
  52         Val result;
  53         foreach(ast.data[1..], Val element)
  54         {
  55           result = EVAL(element, env);
  56         }
  57         return result;
  58       case "if":
  59         Val cond = EVAL(ast.data[1], env);
  60         if(cond.mal_type == MALTYPE_FALSE || cond.mal_type == MALTYPE_NIL)
  61         {
  62           if(sizeof(ast.data) > 3)
  63             return EVAL(ast.data[3], env);
  64           else
  65             return MAL_NIL;
  66         }
  67         else
  68           return EVAL(ast.data[2], env);
  69       case "fn*":
  70         return lambda(Val ... a) { return EVAL(ast.data[2], Env(env, ast.data[1], List(a))); };
  71     }
  72   }
  73   Val evaled_ast = eval_ast(ast, env);
  74   Val f = evaled_ast.data[0];
  75   return f(@evaled_ast.data[1..]);
  76 }
  77
  78 string PRINT(Val exp)
  79 {
  80   return pr_str(exp, true);
  81 }
  82
  83 string rep(string str, Env env)
  84 {
  85   return PRINT(EVAL(READ(str), env));
  86 }
  87
  88 int main()
  89 {
  90   Env repl_env = Env(0);
  91   foreach(.Core.NS(); Val k; Val v) repl_env.set(k, v);
  92   rep("(def! not (fn* (a) (if a false true)))", repl_env);
  93   while(1)
  94   {
  95     string line = readline("user> ");
  96     if(!line) break;
  97     if(strlen(line) == 0) continue;
  98     if(mixed err = catch { write(({ rep(line, repl_env), "\n" })); } )
  99     {
 100       if(arrayp(err)) err = err[0];
 101       write(({ "Error: ", err, "\n" }));
 102     }
 103   }
 104   write("\n");
 105   return 0;
 106 }