xslt/reader.xslt

   1 <?xml version="1.0" encoding="UTF-8"?>
   2 <xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/02/xpath-functions" exclude-result-prefixes="xsl xs fn">
   3     <!-- Expects a "tokens" in current scope -->
   4     <xsl:template name="malreader-peek">
   5         <!-- <xsl:message>PEEK <xsl:sequence select=".">
   6
   7             </xsl:sequence>
   8
   9         ;</xsl:message> -->
  10       <xsl:variable name="context">
  11         <tokens>
  12             <xsl:sequence select="tokens/*" />
  13         </tokens>
  14         <value>
  15             <xsl:for-each select="tokens/token[1]">
  16                 <xsl:sequence select="."></xsl:sequence>
  17             </xsl:for-each>
  18         </value>
  19         <xsl:sequence select="lvalue"></xsl:sequence>
  20         <xsl:sequence select="error"></xsl:sequence>
  21       </xsl:variable>
  22       <xsl:for-each select="$context"><xsl:sequence select="." /></xsl:for-each>
  23     </xsl:template>
  24
  25
  26     <xsl:template name="malreader-next">
  27         <!-- <xsl:message>NEXT <xsl:sequence select=".">
  28
  29             </xsl:sequence>
  30
  31         ;
  32         </xsl:message> -->
  33       <xsl:variable name="context">
  34         <tokens>
  35             <xsl:for-each select="tokens/token[position() != 1]">
  36                 <xsl:sequence select="." />
  37             </xsl:for-each>
  38         </tokens>
  39         <value>
  40             <xsl:for-each select="tokens/token[1]">
  41                 <xsl:sequence select="."></xsl:sequence>
  42             </xsl:for-each>
  43         </value>
  44         <xsl:sequence select="lvalue"></xsl:sequence>
  45         <xsl:sequence select="error"></xsl:sequence>
  46       </xsl:variable>
  47       <xsl:for-each select="$context"><xsl:sequence select="./*" /></xsl:for-each>
  48     </xsl:template>
  49
  50     <xsl:template name="malreader-read_str">
  51         <xsl:variable name="context">
  52             <input value="{str}"/>
  53             <tokens>
  54                 <xsl:call-template name="malreader-tokenize"></xsl:call-template>
  55             </tokens>
  56         </xsl:variable>
  57         <xsl:for-each select="$context">
  58             <xsl:call-template name="malreader-read_form"></xsl:call-template>
  59         </xsl:for-each>
  60         <!-- <xsl:sequence select="$context" /> -->
  61     </xsl:template>
  62
  63     <xsl:template name="malreader-tokenize">
  64         <xsl:analyze-string select="str" regex="[\s,]*(~@|[\[\]{{}}()'`~^@]|&quot;(?:\\.|[^\\&quot;])*&quot;?|;.*|[^\s\[\]{{}}('&quot;`,;)]+)" flags=";j">
  65             <xsl:matching-substring>
  66                 <xsl:variable name="match">
  67                   <xsl:sequence select="regex-group(1)" />
  68                 </xsl:variable>
  69                 <xsl:if test="string-length($match) > 0">
  70                     <xsl:choose>
  71                         <xsl:when test="starts-with($match, '&quot;')">
  72                             <xsl:choose>
  73                                 <xsl:when test="fn:check_string($match)">
  74                                     <token type="error" text="EOF while reading string or invalid escape in string"></token>
  75                                 </xsl:when>
  76                                 <xsl:when test="ends-with($match, '&quot;')">
  77                                     <token type="string" text="{fn:process-string(replace($match, '&quot;(.*)&quot;', '$1'))}"> </token>
  78                                 </xsl:when>
  79                                 <xsl:otherwise>
  80                                     <token type="error" text="EOF while reading string"></token>
  81                                 </xsl:otherwise>
  82                             </xsl:choose>
  83                         </xsl:when>
  84                         <xsl:when test="starts-with($match, ':')">
  85                             <token type="keyword" text="{replace($match, ':(.*)', '$1')}"/>
  86                         </xsl:when>
  87                         <xsl:when test="starts-with($match, ';')">
  88                           <!-- ignore comments -->
  89                         </xsl:when>
  90                         <xsl:when test="starts-with($match, '~@')">
  91                             <token type="special" text="~@" />
  92                         </xsl:when>
  93                         <xsl:when test="matches($match, '[\[\]\{\}()''`~^@]')">
  94                             <token type="special" text="{$match}"></token>
  95                         </xsl:when>
  96                         <xsl:otherwise>
  97                             <xsl:choose>
  98                                 <xsl:when test="$match = 'false'">
  99                                     <token type="false"></token>
 100                                 </xsl:when>
 101                                 <xsl:when test="$match = 'true'">
 102                                     <token type="true"></token>
 103                                 </xsl:when>
 104                                 <xsl:when test="$match = 'nil'">
 105                                     <token type="nil"></token>
 106                                 </xsl:when>
 107                                 <xsl:when test="matches($match, '^-?\d+$')">
 108                                     <token type="number" text="{$match}"></token>
 109                                 </xsl:when>
 110                                 <xsl:otherwise>
 111                                     <token type="symbol" text="{$match}"></token>
 112                                 </xsl:otherwise>
 113                             </xsl:choose>
 114                         </xsl:otherwise>
 115                     </xsl:choose>
 116                 </xsl:if>
 117             </xsl:matching-substring>
 118         </xsl:analyze-string>
 119     </xsl:template>
 120
 121     <xsl:template name="malreader-read_form">
 122         <xsl:variable name="peek">
 123             <xsl:call-template name="malreader-peek"></xsl:call-template>
 124         </xsl:variable>
 125         <xsl:variable name="next">
 126             <xsl:call-template name="malreader-next"></xsl:call-template>
 127         </xsl:variable>
 128         <xsl:for-each select="$peek">
 129             <xsl:choose>
 130                 <xsl:when test="value/token/@type = 'error'">
 131                   <error><malval kind="error"><xsl:value-of select="value/token/@text"/></malval></error>
 132                 </xsl:when>
 133                 <xsl:when test="contains('([{', value/token/@text) and value/token/@type = 'special'">
 134                     <xsl:variable name="next">
 135                         <xsl:call-template name="malreader-next"></xsl:call-template>
 136                     </xsl:variable>
 137                     <xsl:for-each select="$next">
 138                         <xsl:variable name="listkind">
 139                             <xsl:value-of select="value/token/@text" /> <!-- listkind [/(/{ -->
 140                         </xsl:variable>
 141                         <xsl:call-template name="malreader-read_list"><xsl:with-param name="listkind" select="$listkind"/></xsl:call-template>
 142                     </xsl:for-each>
 143                 </xsl:when>
 144                 <xsl:when test="value/token/@text = &quot;'&quot; and value/token/@type = 'special'">
 145                     <xsl:for-each select="$next">
 146                         <xsl:variable name="inner">
 147                             <xsl:variable name="ctx">
 148                                 <xsl:sequence select="tokens"/>
 149                             </xsl:variable>
 150                             <xsl:for-each select="$ctx">
 151                                 <xsl:call-template name="malreader-read_form"></xsl:call-template>
 152                             </xsl:for-each>
 153                         </xsl:variable>
 154                         <xsl:for-each select="$inner">
 155                             <value>
 156                                 <malval kind="list">
 157                                     <lvalue>
 158                                         <malval kind="symbol" value="quote"></malval>
 159                                         <xsl:sequence select="/value/malval" />
 160                                     </lvalue>
 161                                 </malval>
 162                             </value>
 163                             <xsl:sequence select="tokens"/>
 164                             <xsl:sequence select="error"/>
 165                         </xsl:for-each>
 166                         <xsl:sequence select="lvalue"/> <!-- preserve previous list (if any) -->
 167                     </xsl:for-each>
 168                 </xsl:when>
 169                 <xsl:when test="value/token/@text = '`' and value/token/@type = 'special'">
 170                     <xsl:for-each select="$next">
 171                         <xsl:variable name="inner">
 172                             <xsl:variable name="ctx">
 173                                 <xsl:sequence select="tokens"/>
 174                             </xsl:variable>
 175                             <xsl:for-each select="$ctx">
 176                                 <xsl:call-template name="malreader-read_form"></xsl:call-template>
 177                             </xsl:for-each>
 178                         </xsl:variable>
 179                         <xsl:for-each select="$inner">
 180                             <value>
 181                                 <malval kind="list">
 182                                     <lvalue>
 183                                         <malval kind="symbol" value="quasiquote"></malval>
 184                                         <xsl:sequence select="/value/malval" />
 185                                     </lvalue>
 186                                 </malval>
 187                             </value>
 188                             <xsl:sequence select="tokens"/>
 189                             <xsl:sequence select="error"/>
 190                         </xsl:for-each>
 191                         <xsl:sequence select="lvalue"/> <!-- preserve previous list (if any) -->
 192                     </xsl:for-each>
 193                 </xsl:when>
 194                 <xsl:when test="value/token/@text = '~' and value/token/@type = 'special'">
 195                     <xsl:for-each select="$next">
 196                         <xsl:variable name="inner">
 197                             <xsl:variable name="ctx">
 198                                 <xsl:sequence select="tokens"/>
 199                             </xsl:variable>
 200                             <xsl:for-each select="$ctx">
 201                                 <xsl:call-template name="malreader-read_form"></xsl:call-template>
 202                             </xsl:for-each>
 203                         </xsl:variable>
 204                         <xsl:for-each select="$inner">
 205                             <value>
 206                                 <malval kind="list">
 207                                     <lvalue>
 208                                         <malval kind="symbol" value="unquote"></malval>
 209                                         <xsl:sequence select="/value/malval" />
 210                                     </lvalue>
 211                                 </malval>
 212                             </value>
 213                             <xsl:sequence select="tokens"/>
 214                             <xsl:sequence select="error"/>
 215                         </xsl:for-each>
 216                         <xsl:sequence select="lvalue"/> <!-- preserve previous list (if any) -->
 217                     </xsl:for-each>
 218                 </xsl:when>
 219                 <xsl:when test="value/token/@text = '~@' and value/token/@type = 'special'">
 220                     <xsl:for-each select="$next">
 221                         <xsl:variable name="inner">
 222                             <xsl:variable name="ctx">
 223                                 <xsl:sequence select="tokens"/>
 224                             </xsl:variable>
 225                             <xsl:for-each select="$ctx">
 226                                 <xsl:call-template name="malreader-read_form"></xsl:call-template>
 227                             </xsl:for-each>
 228                         </xsl:variable>
 229                         <xsl:for-each select="$inner">
 230                             <value>
 231                                 <malval kind="list">
 232                                     <lvalue>
 233                                         <malval kind="symbol" value="splice-unquote"></malval>
 234                                         <xsl:sequence select="/value/malval" />
 235                                     </lvalue>
 236                                 </malval>
 237                             </value>
 238                             <xsl:sequence select="tokens"/>
 239                             <xsl:sequence select="error"/>
 240                         </xsl:for-each>
 241                         <xsl:sequence select="lvalue"/> <!-- preserve previous list (if any) -->
 242                     </xsl:for-each>
 243                 </xsl:when>
 244                 <xsl:when test="value/token/@text = '@' and value/token/@type = 'special'">
 245                     <xsl:for-each select="$next">
 246                         <xsl:variable name="inner">
 247                             <xsl:variable name="ctx">
 248                                 <xsl:sequence select="tokens"/>
 249                             </xsl:variable>
 250                             <xsl:for-each select="$ctx">
 251                                 <xsl:call-template name="malreader-read_form"></xsl:call-template>
 252                             </xsl:for-each>
 253                         </xsl:variable>
 254                         <xsl:for-each select="$inner">
 255                             <value>
 256                                 <malval kind="list">
 257                                     <lvalue>
 258                                         <malval kind="symbol" value="deref"></malval>
 259                                         <xsl:sequence select="/value/malval" />
 260                                     </lvalue>
 261                                 </malval>
 262                             </value>
 263                             <xsl:sequence select="tokens"/>
 264                             <xsl:sequence select="error"/>
 265                         </xsl:for-each>
 266                         <xsl:sequence select="lvalue"/> <!-- preserve previous list (if any) -->
 267                     </xsl:for-each>
 268                 </xsl:when>
 269                 <xsl:when test="value/token/@text = '^' and value/token/@type = 'special'">
 270                     <xsl:for-each select="$next">
 271                         <xsl:variable name="meta">
 272                             <xsl:variable name="ctx">
 273                                 <xsl:sequence select="tokens"/>
 274                             </xsl:variable>
 275                             <xsl:for-each select="$ctx">
 276                                 <xsl:call-template name="malreader-read_form"></xsl:call-template>
 277                             </xsl:for-each>
 278                         </xsl:variable>
 279                         <xsl:variable name="form">
 280                             <xsl:for-each select="$meta">
 281                                 <xsl:variable name="ctx">
 282                                     <xsl:sequence select="tokens"/>
 283                                 </xsl:variable>
 284                                 <xsl:for-each select="$ctx">
 285                                     <xsl:call-template name="malreader-read_form"></xsl:call-template>
 286                                 </xsl:for-each>
 287                             </xsl:for-each>
 288                         </xsl:variable>
 289                         <xsl:for-each select="$form">
 290                             <value>
 291                                 <malval kind="list">
 292                                     <lvalue>
 293                                         <malval kind="symbol" value="with-meta"></malval>
 294                                         <xsl:sequence select="/value/malval" />
 295                                         <xsl:for-each select="$meta">
 296                                             <xsl:sequence select="/value/malval"/>
 297                                         </xsl:for-each>
 298                                     </lvalue>
 299                                 </malval>
 300                             </value>
 301                             <xsl:sequence select="tokens"/>
 302                             <xsl:sequence select="error"/>
 303                         </xsl:for-each>
 304                         <xsl:sequence select="lvalue"/> <!-- preserve previous list (if any) -->
 305                     </xsl:for-each>
 306                 </xsl:when>
 307                 <xsl:otherwise>
 308                     <xsl:call-template name="malreader-read_atom"></xsl:call-template>
 309                 </xsl:otherwise>
 310             </xsl:choose>
 311         </xsl:for-each>
 312     </xsl:template>
 313
 314     <xsl:template name="malreader-read_list">
 315       <xsl:param name="listkind" as="xs:string" />
 316       <xsl:variable name="prev_lvalue">
 317         <xsl:copy-of select="lvalue"/>
 318       </xsl:variable>
 319       <xsl:variable name="value">
 320         <xsl:variable name="ctx">
 321           <xsl:sequence select="tokens"/>
 322         </xsl:variable>
 323         <xsl:for-each select="$ctx">
 324             <xsl:call-template name="malreader-read_list_helper"><xsl:with-param name="listkind" select="$listkind"/></xsl:call-template>
 325         </xsl:for-each>
 326       </xsl:variable>
 327       <xsl:for-each select="$value">
 328         <xsl:sequence select="tokens" />
 329         <xsl:variable name="value">
 330             <value>
 331                 <malval kind="{fn:list-kind($listkind)}">
 332                     <xsl:sequence select="lvalue[1]"/>
 333                 </malval>
 334             </value>
 335         </xsl:variable>
 336         <xsl:choose>
 337             <xsl:when test="$listkind = '{'">
 338                 <xsl:choose>
 339                     <xsl:when test="count($value/value/malval/lvalue/malval) mod 2 = 1">
 340                         <error><malval kind="error">Odd number of values to hash</malval></error>
 341                     </xsl:when>
 342                     <xsl:otherwise>
 343                         <xsl:sequence select="$value"/>
 344                     </xsl:otherwise>
 345                 </xsl:choose>
 346             </xsl:when>
 347             <xsl:otherwise>
 348                 <xsl:sequence select="$value"/>
 349                 <xsl:sequence select="error" />
 350             </xsl:otherwise>
 351         </xsl:choose>
 352         <xsl:sequence select="$prev_lvalue"/>
 353       </xsl:for-each>
 354     </xsl:template>
 355
 356     <xsl:template name="malreader-read_list_helper">
 357         <xsl:param name="listkind" as="xs:string" />
 358         <xsl:choose>
 359           <xsl:when test="count(tokens/*) > 0">
 360             <xsl:variable name="peek">
 361                 <xsl:call-template name="malreader-peek"></xsl:call-template>
 362             </xsl:variable>
 363             <xsl:for-each select="$peek">
 364                 <xsl:choose>
 365                     <xsl:when test="value/token/@text = fn:list-ender($listkind) and value/token/@type = 'special'">
 366                         <!-- ok -->
 367                         <xsl:variable name="next">
 368                             <xsl:call-template name="malreader-next"></xsl:call-template>
 369                         </xsl:variable>
 370                         <xsl:sequence select="lvalue" />
 371                         <xsl:sequence select="$next/tokens" />
 372                         <xsl:sequence select="error" />
 373                     </xsl:when>
 374                     <xsl:otherwise>
 375                         <xsl:variable name="form">
 376                             <xsl:call-template name="malreader-read_form"></xsl:call-template>
 377                         </xsl:variable>
 378                         <xsl:variable name="context">
 379                             <xsl:for-each select="$form">
 380                             <!-- <xsl:message>READ_FORM <xsl:sequence select=".">
 381
 382                                 </xsl:sequence>
 383
 384                             ;</xsl:message> -->
 385                                 <xsl:sequence select="tokens" />
 386                                 <lvalue>
 387                                     <xsl:for-each select="lvalue/malval"><xsl:sequence select="." /></xsl:for-each>
 388                                     <xsl:for-each select="value/malval"><xsl:sequence select="."/></xsl:for-each>
 389                                 </lvalue>
 390                             </xsl:for-each>
 391                         </xsl:variable>
 392                         <xsl:for-each select="$context">
 393                             <xsl:call-template name="malreader-read_list_helper"><xsl:with-param name="listkind" select="$listkind"/></xsl:call-template>
 394                         </xsl:for-each>
 395                     </xsl:otherwise>
 396                 </xsl:choose>
 397                 <xsl:sequence select="lvalue"/>
 398             </xsl:for-each>
 399           </xsl:when>
 400           <xsl:otherwise>
 401               <error><malval kind="error">EOF while reading list</malval></error>
 402           </xsl:otherwise>
 403         </xsl:choose>
 404     </xsl:template>
 405
 406     <xsl:template name="malreader-read_atom">
 407         <xsl:variable name="next">
 408           <xsl:call-template name="malreader-next"></xsl:call-template>
 409         </xsl:variable>
 410         <xsl:for-each select="$next">
 411             <xsl:sequence select="tokens"/>
 412             <xsl:sequence select="lvalue"/>
 413             <xsl:sequence select="error"/>
 414             <xsl:choose>
 415                 <xsl:when test="value/token/@type = 'number'">
 416                     <value>
 417                         <malval kind="number" value="{value/token/@text}" />
 418                     </value>
 419                 </xsl:when>
 420                 <xsl:when test="value/token/@type = 'symbol'">
 421                     <value>
 422                         <malval kind="symbol" value="{value/token/@text}" />
 423                     </value>
 424                 </xsl:when>
 425                 <xsl:when test="value/token/@type = 'string'">
 426                     <value>
 427                         <malval kind="string" value="{value/token/@text}" />
 428                     </value>
 429                 </xsl:when>
 430                 <xsl:when test="value/token/@type = 'keyword'">
 431                     <value>
 432                         <malval kind="keyword" value="{value/token/@text}" />
 433                     </value>
 434                 </xsl:when>
 435                 <xsl:when test="value/token/@type = 'true'">
 436                     <value>
 437                         <malval kind="true"/>
 438                     </value>
 439                 </xsl:when>
 440                 <xsl:when test="value/token/@type = 'false'">
 441                     <value>
 442                         <malval kind="false"/>
 443                     </value>
 444                 </xsl:when>
 445                 <xsl:when test="value/token/@type = 'nil'">
 446                     <value>
 447                         <malval kind="nil"/>
 448                     </value>
 449                 </xsl:when>
 450                 <xsl:otherwise>
 451                     <error>
 452                         <malval kind="error"><xsl:sequence select="value"/></malval>
 453                     </error>
 454                 </xsl:otherwise>
 455             </xsl:choose>
 456         </xsl:for-each>
 457     </xsl:template>
 458
 459     <xsl:function name="fn:check_string" as="xs:boolean">
 460         <xsl:param name="str" as="xs:string" />
 461         <xsl:sequence select="$str = '&quot;' or matches($str, '[^\\](\\[^n\\&quot;]|\\(\\\\)*&quot;$)')" />
 462     </xsl:function>
 463
 464     <xsl:function name="fn:process-string" as="xs:string">
 465         <xsl:param name="str" as="xs:string" />
 466         <xsl:sequence select="replace(replace($str, '([^\\]|^)\\n', '$1&#10;'), '\\([\\&quot;])', '$1')" />
 467     </xsl:function>
 468
 469     <xsl:function name="fn:list-ender" as="xs:string">
 470         <xsl:param name="str" as="xs:string" />
 471         <xsl:choose>
 472             <xsl:when test="$str = '('"><xsl:sequence select="')'" /></xsl:when>
 473             <xsl:when test="$str = '['"><xsl:sequence select="']'" /></xsl:when>
 474             <xsl:otherwise><xsl:sequence select="'}'" /></xsl:otherwise>
 475         </xsl:choose>
 476     </xsl:function>
 477
 478     <xsl:function name="fn:list-kind" as="xs:string">
 479         <xsl:param name="str" as="xs:string" />
 480         <xsl:choose>
 481             <xsl:when test="$str = '('"><xsl:sequence select="'list'" /></xsl:when>
 482             <xsl:when test="$str = '['"><xsl:sequence select="'vector'" /></xsl:when>
 483             <xsl:otherwise><xsl:sequence select="'hash'" /></xsl:otherwise>
 484         </xsl:choose>
 485     </xsl:function>
 486
 487 </xsl:stylesheet>