haskell/step7_quote.hs

   1 import System.IO (hFlush, stdout)
   2 import System.Environment (getArgs)
   3 import Control.Monad (mapM)
   4 import Control.Monad.Error (runErrorT)
   5 import Control.Monad.Trans (liftIO)
   6 import qualified Data.Map as Map
   7 import qualified Data.Traversable as DT
   8
   9 import Readline (readline, load_history)
  10 import Types
  11 import Reader (read_str)
  12 import Printer (_pr_str)
  13 import Env (Env, env_new, env_bind, env_get, env_set)
  14 import Core as Core
  15
  16 -- read
  17 mal_read :: String -> IOThrows MalVal
  18 mal_read str = read_str str
  19
  20 -- eval
  21 is_pair (MalList x _:xs) = True
  22 is_pair (MalVector x _:xs) = True
  23 is_pair _ = False
  24
  25 quasiquote :: MalVal -> MalVal
  26 quasiquote ast =
  27     case ast of
  28          (MalList (MalSymbol "unquote" : a1 : []) _) -> a1
  29          (MalList (MalList (MalSymbol "splice-unquote" : a01 : []) _ : rest) _) ->
  30             MalList [(MalSymbol "concat"), a01, quasiquote (MalList rest Nil)] Nil
  31          (MalVector (MalList (MalSymbol "splice-unquote" : a01 : []) _ : rest) _) ->
  32             MalList [(MalSymbol "concat"), a01, quasiquote (MalVector rest Nil)] Nil
  33          (MalList (a0 : rest) _) -> MalList [(MalSymbol "cons"),
  34                                              quasiquote a0,
  35                                              quasiquote (MalList rest Nil)] Nil
  36          (MalVector (a0 : rest) _) -> MalList [(MalSymbol "cons"),
  37                                                quasiquote a0,
  38                                                quasiquote (MalVector rest Nil)] Nil
  39          _ -> MalList [(MalSymbol "quote"), ast] Nil
  40
  41
  42 eval_ast :: MalVal -> Env -> IOThrows MalVal
  43 eval_ast sym@(MalSymbol _) env = env_get env sym
  44 eval_ast ast@(MalList lst m) env = do
  45     new_lst <- mapM (\x -> (eval x env)) lst
  46     return $ MalList new_lst m
  47 eval_ast ast@(MalVector lst m) env = do
  48     new_lst <- mapM (\x -> (eval x env)) lst
  49     return $ MalVector new_lst m
  50 eval_ast ast@(MalHashMap lst m) env = do
  51     new_hm <- DT.mapM (\x -> (eval x env)) lst
  52     return $ MalHashMap new_hm m
  53 eval_ast ast env = return ast
  54
  55 let_bind :: Env -> [MalVal] -> IOThrows Env
  56 let_bind env [] = return env
  57 let_bind env (b:e:xs) = do
  58     evaled <- eval e env
  59     x <- liftIO $ env_set env b evaled
  60     let_bind env xs
  61
  62 apply_ast :: MalVal -> Env -> IOThrows MalVal
  63 apply_ast ast@(MalList (MalSymbol "def!" : args) _) env = do
  64     case args of
  65          (a1@(MalSymbol _): a2 : []) -> do
  66             evaled <- eval a2 env
  67             liftIO $ env_set env a1 evaled
  68          _ -> throwStr "invalid def!"
  69 apply_ast ast@(MalList (MalSymbol "let*" : args) _) env = do
  70     case args of
  71          (a1 : a2 : []) -> do
  72             params <- (_to_list a1)
  73             let_env <- liftIO $ env_new $ Just env
  74             let_bind let_env params
  75             eval a2 let_env
  76          _ -> throwStr "invalid let*"
  77 apply_ast ast@(MalList (MalSymbol "quote" : args) _) env = do
  78     case args of
  79          a1 : [] -> return a1
  80          _ -> throwStr "invalid quote"
  81 apply_ast ast@(MalList (MalSymbol "quasiquote" : args) _) env = do
  82     case args of
  83          a1 : [] -> eval (quasiquote a1) env
  84          _ -> throwStr "invalid quasiquote"
  85 apply_ast ast@(MalList (MalSymbol "do" : args) _) env = do
  86     case args of
  87          ([]) -> return Nil
  88          _  -> do
  89             el <- eval_ast (MalList args Nil) env
  90             case el of
  91                  (MalList lst _) -> return $ last lst
  92
  93 apply_ast ast@(MalList (MalSymbol "if" : args) _) env = do
  94     case args of
  95          (a1 : a2 : a3 : []) -> do
  96             cond <- eval a1 env
  97             if cond == MalFalse || cond == Nil
  98                 then eval a3 env
  99                 else eval a2 env
 100          (a1 : a2 : []) -> do
 101             cond <- eval a1 env
 102             if cond == MalFalse || cond == Nil
 103                 then return Nil
 104                 else eval a2 env
 105          _ -> throwStr "invalid if"
 106 apply_ast ast@(MalList (MalSymbol "fn*" : args) _) env = do
 107     case args of
 108          (a1 : a2 : []) -> do
 109             params <- (_to_list a1)
 110             return $ (_malfunc a2 env (MalList params Nil)
 111                       (\args -> do
 112                         fn_env1 <- liftIO $ env_new $ Just env
 113                         fn_env2 <- liftIO $ env_bind fn_env1 params args
 114                         eval a2 fn_env2))
 115          _ -> throwStr "invalid fn*"
 116 apply_ast ast@(MalList _ _) env = do
 117     el <- eval_ast ast env
 118     case el of
 119          (MalList ((Func (Fn f) _) : rest) _) ->
 120             f $ rest
 121          (MalList ((MalFunc {ast=ast, env=fn_env, params=(MalList params Nil)}) : rest) _) -> do
 122             fn_env1 <- liftIO $ env_new $ Just fn_env
 123             fn_env2 <- liftIO $ env_bind fn_env1 params rest
 124             eval ast fn_env2
 125          el ->
 126             throwStr $ "invalid apply: " ++ (show el)
 127
 128 eval :: MalVal -> Env -> IOThrows MalVal
 129 eval ast env = do
 130     case ast of
 131          (MalList _ _) -> apply_ast ast env
 132          _             -> eval_ast ast env
 133
 134
 135 -- print
 136 mal_print :: MalVal -> String
 137 mal_print exp = show exp
 138
 139 -- repl
 140
 141 rep :: Env -> String -> IOThrows String
 142 rep env line = do
 143     ast <- mal_read line
 144     exp <- eval ast env
 145     return $ mal_print exp
 146
 147 repl_loop :: Env -> IO ()
 148 repl_loop env = do
 149     line <- readline "user> "
 150     case line of
 151         Nothing -> return ()
 152         Just "" -> repl_loop env
 153         Just str -> do
 154             res <- runErrorT $ rep env str
 155             out <- case res of
 156                 Left (StringError str) -> return $ "Error: " ++ str
 157                 Left (MalValError mv) -> return $ "Error: " ++ (show mv)
 158                 Right val -> return val
 159             putStrLn out
 160             hFlush stdout
 161             repl_loop env
 162
 163 main = do
 164     args <- getArgs
 165     load_history
 166
 167     repl_env <- env_new Nothing
 168
 169     -- core.hs: defined using Haskell
 170     (mapM (\(k,v) -> (env_set repl_env (MalSymbol k) v)) Core.ns)
 171     env_set repl_env (MalSymbol "eval") (_func (\[ast] -> eval ast repl_env))
 172     env_set repl_env (MalSymbol "*ARGV*") (MalList [] Nil)
 173
 174     -- core.mal: defined using the language itself
 175     runErrorT $ rep repl_env "(def! not (fn* (a) (if a false true)))"
 176     runErrorT $ rep repl_env "(def! load-file (fn* (f) (eval (read-string (str \"(do \" (slurp f) \")\")))))"
 177
 178     if length args > 0 then do
 179         env_set repl_env (MalSymbol "*ARGV*") (MalList (map MalString (drop 1 args)) Nil)
 180         runErrorT $ rep repl_env $ "(load-file \"" ++ (args !! 0) ++ "\")"
 181         return ()
 182     else
 183         repl_loop repl_env