tests/profiles.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018, 2019, 2020, 2021 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2014 Alex Kost <alezost@gmail.com>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (test-profiles)
  21   #:use-module (guix tests)
  22   #:use-module (guix profiles)
  23   #:use-module (guix gexp)
  24   #:use-module (guix store)
  25   #:use-module (guix monads)
  26   #:use-module (guix grafts)
  27   #:use-module (guix packages)
  28   #:use-module (guix derivations)
  29   #:use-module (guix build-system trivial)
  30   #:use-module (gnu packages bootstrap)
  31   #:use-module ((gnu packages base) #:prefix packages:)
  32   #:use-module ((gnu packages guile) #:prefix packages:)
  33   #:use-module (ice-9 match)
  34   #:use-module (ice-9 regex)
  35   #:use-module (ice-9 popen)
  36   #:use-module (rnrs io ports)
  37   #:use-module (srfi srfi-1)
  38   #:use-module (srfi srfi-11)
  39   #:use-module (srfi srfi-34)
  40   #:use-module (srfi srfi-64))
  41
  42 ;; Test the (guix profiles) module.
  43
  44 (define %store
  45   (open-connection-for-tests))
  46
  47 ;; Globally disable grafts because they can trigger early builds.
  48 (%graft? #f)
  49
  50 ;; Example manifest entries.
  51
  52 (define guile-1.8.8
  53   (manifest-entry
  54     (name "guile")
  55     (version "1.8.8")
  56     (item "/gnu/store/...")
  57     (output "out")))
  58
  59 (define guile-2.0.9
  60   (manifest-entry
  61     (name "guile")
  62     (version "2.0.9")
  63     (item "/gnu/store/...")
  64     (output "out")))
  65
  66 (define guile-2.0.9:debug
  67   (manifest-entry (inherit guile-2.0.9)
  68     (output "debug")))
  69
  70 (define glibc
  71   (manifest-entry
  72     (name "glibc")
  73     (version "2.19")
  74     (item "/gnu/store/...")
  75     (output "out")))
  76
  77 \f
  78 (test-begin "profiles")
  79
  80 (test-assert "manifest-installed?"
  81   (let ((m (manifest (list guile-2.0.9 guile-2.0.9:debug))))
  82     (and (manifest-installed? m (manifest-pattern (name "guile")))
  83          (manifest-installed? m (manifest-pattern
  84                                   (name "guile") (output "debug")))
  85          (manifest-installed? m (manifest-pattern
  86                                   (name "guile") (output "out")
  87                                   (version "2.0.9")))
  88          (not (manifest-installed?
  89                m (manifest-pattern (name "guile") (version "1.8.8"))))
  90          (not (manifest-installed?
  91                m (manifest-pattern (name "guile") (output "foobar")))))))
  92
  93 (test-assert "manifest-matching-entries"
  94   (let* ((e (list guile-2.0.9 guile-2.0.9:debug))
  95          (m (manifest e)))
  96     (and (equal? e
  97                  (manifest-matching-entries m
  98                                             (list (manifest-pattern
  99                                                     (name "guile")
 100                                                     (output #f)))))
 101          (equal? (list guile-2.0.9)
 102                  (manifest-matching-entries m
 103                                             (list (manifest-pattern
 104                                                     (name "guile")
 105                                                     (version "2.0.9"))))))))
 106
 107 (test-assert "manifest-matching-entries, no match"
 108   (let ((m (manifest (list guile-2.0.9)))
 109         (p (manifest-pattern (name "python"))))
 110     (guard (c ((unmatched-pattern-error? c)
 111                (and (eq? p (unmatched-pattern-error-pattern c))
 112                     (eq? m (unmatched-pattern-error-manifest c)))))
 113       (manifest-matching-entries m (list p))
 114       #f)))
 115
 116 (test-equal "concatenate-manifests"
 117   (manifest (list guile-2.0.9 glibc))
 118   (concatenate-manifests (list (manifest (list guile-2.0.9))
 119                                (manifest (list glibc)))))
 120
 121 (test-assert "manifest-remove"
 122   (let* ((m0 (manifest (list guile-2.0.9 guile-2.0.9:debug)))
 123          (m1 (manifest-remove m0
 124                               (list (manifest-pattern (name "guile")))))
 125          (m2 (manifest-remove m1
 126                               (list (manifest-pattern (name "guile"))))) ; same
 127          (m3 (manifest-remove m2
 128                               (list (manifest-pattern
 129                                       (name "guile") (output "debug")))))
 130          (m4 (manifest-remove m3
 131                               (list (manifest-pattern (name "guile"))))))
 132     (match (manifest-entries m2)
 133       ((($ <manifest-entry> "guile" "2.0.9" "debug"))
 134        (and (equal? m1 m2)
 135             (null? (manifest-entries m3))
 136             (null? (manifest-entries m4)))))))
 137
 138 (test-assert "manifest-add"
 139   (let* ((m0 (manifest '()))
 140          (m1 (manifest-add m0 (list guile-1.8.8)))
 141          (m2 (manifest-add m1 (list guile-2.0.9)))
 142          (m3 (manifest-add m2 (list guile-2.0.9:debug)))
 143          (m4 (manifest-add m3 (list guile-2.0.9:debug))))
 144     (and (match (manifest-entries m1)
 145            ((($ <manifest-entry> "guile" "1.8.8" "out")) #t)
 146            (_ #f))
 147          (match (manifest-entries m2)
 148            ((($ <manifest-entry> "guile" "2.0.9" "out")) #t)
 149            (_ #f))
 150          (equal? m3 m4))))
 151
 152 (test-equal "manifest-add removes duplicates"    ;<https://bugs.gnu.org/30569>
 153   (list guile-2.0.9)
 154   (manifest-entries (manifest-add (manifest '())
 155                                   (list guile-2.0.9 guile-2.0.9))))
 156
 157 (test-equal "manifest->code, simple"
 158   '(begin
 159      (specifications->manifest (list "guile" "guile:debug" "glibc")))
 160   (manifest->code (manifest (list guile-2.0.9 guile-2.0.9:debug glibc))))
 161
 162 (test-equal "manifest->code, simple, versions"
 163   '(begin
 164      (specifications->manifest (list "guile@2.0.9" "guile@2.0.9:debug"
 165                                      "glibc@2.19")))
 166   (manifest->code (manifest (list guile-2.0.9 guile-2.0.9:debug glibc))
 167                   #:entry-package-version manifest-entry-version))
 168
 169 (test-equal "manifest->code, transformations"
 170   '(begin
 171      (use-modules (guix transformations))
 172
 173      (define transform1
 174        (options->transformation '((foo . "bar"))))
 175
 176      (packages->manifest
 177       (list (transform1 (specification->package "guile"))
 178             (specification->package "glibc"))))
 179   (manifest->code (manifest (list (manifest-entry
 180                                     (inherit guile-2.0.9)
 181                                     (properties `((transformations
 182                                                    . ((foo . "bar"))))))
 183                                   glibc))))
 184
 185 (test-assert "manifest-perform-transaction"
 186   (let* ((m0 (manifest (list guile-2.0.9 guile-2.0.9:debug)))
 187          (t1 (manifest-transaction
 188               (install (list guile-1.8.8))
 189               (remove (list (manifest-pattern (name "guile")
 190                                               (output "debug"))))))
 191          (t2 (manifest-transaction
 192               (remove (list (manifest-pattern (name "guile")
 193                                               (version "2.0.9")
 194                                               (output #f))))))
 195          (m1 (manifest-perform-transaction m0 t1))
 196          (m2 (manifest-perform-transaction m1 t2))
 197          (m3 (manifest-perform-transaction m0 t2)))
 198     (and (match (manifest-entries m1)
 199            ((($ <manifest-entry> "guile" "1.8.8" "out")) #t)
 200            (_ #f))
 201          (equal? m1 m2)
 202          (null? (manifest-entries m3)))))
 203
 204 (test-assert "manifest-transaction-effects"
 205   (let* ((m0 (manifest (list guile-1.8.8)))
 206          (t  (manifest-transaction
 207               (install (list guile-2.0.9 glibc)))))
 208     (let-values (((remove install upgrade downgrade)
 209                   (manifest-transaction-effects m0 t)))
 210       (and (null? remove) (null? downgrade)
 211            (equal? (list glibc) install)
 212            (equal? (list (cons guile-1.8.8 guile-2.0.9)) upgrade)))))
 213
 214 (test-assert "manifest-transaction-effects no double install or upgrades"
 215   (let* ((m0 (manifest (list guile-1.8.8)))
 216          (t  (manifest-transaction
 217               (install (list guile-2.0.9 glibc glibc)))))
 218     (let-values (((remove install upgrade downgrade)
 219                   (manifest-transaction-effects m0 t)))
 220       (and (null? remove) (null? downgrade)
 221            (equal? (list glibc) install)
 222            (equal? (list (cons guile-1.8.8 guile-2.0.9)) upgrade)))))
 223
 224 (test-assert "manifest-transaction-effects and downgrades"
 225   (let* ((m0 (manifest (list guile-2.0.9)))
 226          (t  (manifest-transaction (install (list guile-1.8.8)))))
 227     (let-values (((remove install upgrade downgrade)
 228                   (manifest-transaction-effects m0 t)))
 229       (and (null? remove) (null? install) (null? upgrade)
 230            (equal? (list (cons guile-2.0.9 guile-1.8.8)) downgrade)))))
 231
 232 (test-assert "manifest-transaction-effects no double downgrade"
 233   (let* ((m0 (manifest (list guile-2.0.9)))
 234          (t  (manifest-transaction (install (list guile-1.8.8 guile-1.8.8)))))
 235     (let-values (((remove install upgrade downgrade)
 236                   (manifest-transaction-effects m0 t)))
 237       (and (null? remove) (null? install) (null? upgrade)
 238            (equal? (list (cons guile-2.0.9 guile-1.8.8)) downgrade)))))
 239
 240 (test-assert "manifest-transaction-effects and pseudo-upgrades"
 241   (let* ((m0 (manifest (list guile-2.0.9)))
 242          (t  (manifest-transaction (install (list guile-2.0.9)))))
 243     (let-values (((remove install upgrade downgrade)
 244                   (manifest-transaction-effects m0 t)))
 245       (and (null? remove) (null? install) (null? downgrade)
 246            (equal? (list (cons guile-2.0.9 guile-2.0.9)) upgrade)))))
 247
 248 (test-assert "manifest-transaction-null?"
 249   (manifest-transaction-null? (manifest-transaction)))
 250
 251 (test-assert "manifest-transaction-removal-candidate?"
 252   (let ((m (manifest (list guile-2.0.9)))
 253         (t (manifest-transaction
 254             (remove (list (manifest-pattern (name "guile")))))))
 255     (and (manifest-transaction-removal-candidate? guile-2.0.9 t)
 256          (not (manifest-transaction-removal-candidate? glibc t)))))
 257
 258 (test-assert "manifest-transaction-effects no double removal"
 259   (let* ((m0 (manifest (list guile-2.0.9)))
 260          (t  (manifest-transaction
 261               (remove (list (manifest-pattern (name "guile")))))))
 262     (let-values (((remove install upgrade downgrade)
 263                   (manifest-transaction-effects m0 t)))
 264       (and (= 1 (length remove))
 265            (manifest-transaction-removal-candidate? guile-2.0.9 t)
 266            (null? install) (null? downgrade) (null? upgrade)))))
 267
 268 (test-assertm "profile-derivation"
 269   (mlet* %store-monad
 270       ((entry ->   (package->manifest-entry %bootstrap-guile))
 271        (guile      (package->derivation %bootstrap-guile))
 272        (drv        (profile-derivation (manifest (list entry))
 273                                        #:hooks '()
 274                                        #:locales? #f))
 275        (profile -> (derivation->output-path drv))
 276        (bindir ->  (string-append profile "/bin"))
 277        (_          (built-derivations (list drv))))
 278     (return (and (file-exists? (string-append bindir "/guile"))
 279                  (string=? (dirname (readlink bindir))
 280                            (derivation->output-path guile))))))
 281
 282 (test-assertm "load-profile"
 283   (mlet* %store-monad
 284       ((entry ->   (package->manifest-entry %bootstrap-guile))
 285        (guile      (package->derivation %bootstrap-guile))
 286        (drv        (profile-derivation (manifest (list entry))
 287                                        #:hooks '()
 288                                        #:locales? #f))
 289        (profile -> (derivation->output-path drv))
 290        (bindir ->  (string-append profile "/bin"))
 291        (_          (built-derivations (list drv))))
 292     (define-syntax-rule (with-environment-excursion exp ...)
 293       (let ((env (environ)))
 294         (dynamic-wind
 295           (const #t)
 296           (lambda () exp ...)
 297           (lambda () (environ env)))))
 298
 299     (return (and (with-environment-excursion
 300                   (load-profile profile)
 301                   (and (string-prefix? (string-append bindir ":")
 302                                        (getenv "PATH"))
 303                        (getenv "GUILE_LOAD_PATH")))
 304                  (with-environment-excursion
 305                   (load-profile profile #:pure? #t #:white-list '())
 306                   (equal? (list (string-append "PATH=" bindir))
 307                           (environ)))))))
 308
 309 (test-assertm "<profile>"
 310   (mlet* %store-monad
 311       ((entry ->   (package->manifest-entry %bootstrap-guile))
 312        (profile -> (profile (hooks '()) (locales? #f)
 313                             (content (manifest (list entry)))))
 314        (drv        (lower-object profile))
 315        (profile -> (derivation->output-path drv))
 316        (bindir ->  (string-append profile "/bin"))
 317        (_          (built-derivations (list drv))))
 318     (return (file-exists? (string-append bindir "/guile")))))
 319
 320 (test-assertm "profile-derivation relative symlinks, one entry"
 321   (mlet* %store-monad
 322       ((entry ->   (package->manifest-entry %bootstrap-guile))
 323        (guile      (package->derivation %bootstrap-guile))
 324        (drv        (profile-derivation (manifest (list entry))
 325                                        #:relative-symlinks? #t
 326                                        #:hooks '()
 327                                        #:locales? #f))
 328        (profile -> (derivation->output-path drv))
 329        (bindir ->  (string-append profile "/bin"))
 330        (_          (built-derivations (list drv))))
 331     (return (and (file-exists? (string-append bindir "/guile"))
 332                  (string=? (readlink bindir)
 333                            (string-append "../"
 334                                           (basename
 335                                            (derivation->output-path guile))
 336                                           "/bin"))))))
 337
 338 (unless (network-reachable?) (test-skip 1))
 339 (test-assertm "profile-derivation relative symlinks, two entries"
 340   (mlet* %store-monad
 341       ((manifest -> (packages->manifest
 342                      (list %bootstrap-guile gnu-make-for-tests)))
 343        (guile       (package->derivation %bootstrap-guile))
 344        (make        (package->derivation gnu-make-for-tests))
 345        (drv         (profile-derivation manifest
 346                                         #:relative-symlinks? #t
 347                                         #:hooks '()
 348                                         #:locales? #f))
 349        (profile ->  (derivation->output-path drv))
 350        (bindir ->   (string-append profile "/bin"))
 351        (_           (built-derivations (list drv))))
 352     (return (and (file-exists? (string-append bindir "/guile"))
 353                  (file-exists? (string-append bindir "/make"))
 354                  (string=? (readlink (string-append bindir "/guile"))
 355                            (string-append "../../"
 356                                           (basename
 357                                            (derivation->output-path guile))
 358                                           "/bin/guile"))
 359                  (string=? (readlink (string-append bindir "/make"))
 360                            (string-append "../../"
 361                                           (basename
 362                                            (derivation->output-path make))
 363                                           "/bin/make"))))))
 364
 365 (test-assertm "profile-derivation, inputs"
 366   (mlet* %store-monad
 367       ((entry ->   (package->manifest-entry packages:glibc "debug"))
 368        (drv        (profile-derivation (manifest (list entry))
 369                                        #:hooks '()
 370                                        #:locales? #f)))
 371     (return (derivation-inputs drv))))
 372
 373 (test-assertm "profile-derivation, cross-compilation"
 374   (mlet* %store-monad
 375       ((manifest -> (packages->manifest (list packages:sed packages:grep)))
 376        (target ->   "arm-linux-gnueabihf")
 377        (grep        (package->cross-derivation packages:grep target))
 378        (sed         (package->cross-derivation packages:sed target))
 379        (locales     (package->derivation packages:glibc-utf8-locales))
 380        (drv         (profile-derivation manifest
 381                                         #:hooks '()
 382                                         #:locales? #t
 383                                         #:target target)))
 384     (define (find-input package)
 385       (let ((name (string-append (package-full-name package "-") ".drv")))
 386         (any (lambda (input)
 387                (let ((input (derivation-input-path input)))
 388                  (and (string-suffix? name input) input)))
 389              (derivation-inputs drv))))
 390
 391     ;; The inputs for grep and sed should be cross-build derivations, but that
 392     ;; for the glibc-utf8-locales should be a native build.
 393     (return (and (string=? (derivation-system drv) (%current-system))
 394                  (string=? (find-input packages:grep)
 395                            (derivation-file-name grep))
 396                  (string=? (find-input packages:sed)
 397                            (derivation-file-name sed))
 398                  (string=? (find-input packages:glibc-utf8-locales)
 399                            (derivation-file-name locales))))))
 400
 401 (test-assert "package->manifest-entry defaults to \"out\""
 402   (let ((outputs (package-outputs packages:glibc)))
 403     (equal? (manifest-entry-output
 404              (package->manifest-entry (package
 405                                         (inherit packages:glibc)
 406                                         (outputs (reverse outputs)))))
 407             (manifest-entry-output
 408              (package->manifest-entry packages:glibc))
 409             "out")))
 410
 411 (test-assertm "profile-manifest, search-paths"
 412   (mlet* %store-monad
 413       ((guile ->   (package
 414                      (inherit %bootstrap-guile)
 415                      (native-search-paths
 416                       (package-native-search-paths packages:guile-2.0))))
 417        (entry ->   (package->manifest-entry guile))
 418        (drv        (profile-derivation (manifest (list entry))
 419                                        #:hooks '()
 420                                        #:locales? #f))
 421        (profile -> (derivation->output-path drv)))
 422     (mbegin %store-monad
 423       (built-derivations (list drv))
 424
 425       ;; Read the manifest back and make sure search paths are preserved.
 426       (let ((manifest (profile-manifest profile)))
 427         (match (manifest-entries manifest)
 428           ((result)
 429            (return (equal? (manifest-entry-search-paths result)
 430                            (manifest-entry-search-paths entry)
 431                            (package-native-search-paths
 432                             packages:guile-2.0)))))))))
 433
 434 (test-assert "package->manifest-entry, search paths"
 435   ;; See <http://bugs.gnu.org/22073>.
 436   (let ((mpl (@ (gnu packages python-xyz) python2-matplotlib)))
 437     (lset= eq?
 438            (package-transitive-native-search-paths mpl)
 439            (manifest-entry-search-paths
 440             (package->manifest-entry mpl)))))
 441
 442 (test-assert "packages->manifest, no duplicates"
 443   (let ((expected
 444          (manifest
 445           (list
 446            (package->manifest-entry packages:guile-2.2))))
 447         (manifest (packages->manifest
 448                    (list packages:guile-2.2 packages:guile-2.2))))
 449     (every manifest-entry=? (manifest-entries expected)
 450            (manifest-entries manifest))))
 451
 452 (test-equal "packages->manifest, propagated inputs"
 453   (map (match-lambda
 454          ((label package)
 455           (list (package-name package) (package-version package)
 456                 package)))
 457        (package-propagated-inputs packages:guile-2.2))
 458   (map (lambda (entry)
 459          (list (manifest-entry-name entry)
 460                (manifest-entry-version entry)
 461                (manifest-entry-item entry)))
 462        (manifest-entry-dependencies
 463         (package->manifest-entry packages:guile-2.2))))
 464
 465 (test-assert "manifest-entry-parent"
 466   (let ((entry (package->manifest-entry packages:guile-2.2)))
 467     (match (manifest-entry-dependencies entry)
 468       ((dependencies ..1)
 469        (and (every (lambda (parent)
 470                      (eq? entry (force parent)))
 471                    (map manifest-entry-parent dependencies))
 472             (not (force (manifest-entry-parent entry))))))))
 473
 474 (test-assertm "read-manifest"
 475   (mlet* %store-monad ((manifest -> (packages->manifest
 476                                      (list (package
 477                                              (inherit %bootstrap-guile)
 478                                              (native-search-paths
 479                                               (package-native-search-paths
 480                                                packages:guile-2.0))))))
 481                        (drv (profile-derivation manifest
 482                                                 #:hooks '()
 483                                                 #:locales? #f))
 484                        (out -> (derivation->output-path drv)))
 485     (define (entry->sexp entry)
 486       (list (manifest-entry-name entry)
 487             (manifest-entry-version entry)
 488             (manifest-entry-search-paths entry)
 489             (manifest-entry-dependencies entry)
 490             (force (manifest-entry-parent entry))))
 491
 492     (mbegin %store-monad
 493       (built-derivations (list drv))
 494       (let ((manifest2 (profile-manifest out)))
 495         (return (equal? (map entry->sexp (manifest-entries manifest))
 496                         (map entry->sexp (manifest-entries manifest2))))))))
 497
 498 (test-equal "collision"
 499   '(("guile-bootstrap" "2.0") ("guile-bootstrap" "42"))
 500   (guard (c ((profile-collision-error? c)
 501              (let ((entry1 (profile-collision-error-entry c))
 502                    (entry2 (profile-collision-error-conflict c)))
 503                (list (list (manifest-entry-name entry1)
 504                            (manifest-entry-version entry1))
 505                      (list (manifest-entry-name entry2)
 506                            (manifest-entry-version entry2))))))
 507     (run-with-store %store
 508       (mlet* %store-monad ((p0 -> (package
 509                                     (inherit %bootstrap-guile)
 510                                     (version "42")))
 511                            (p1 -> (dummy-package "p1"
 512                                     (propagated-inputs `(("p0" ,p0)))))
 513                            (manifest -> (packages->manifest
 514                                          (list %bootstrap-guile p1)))
 515                            (drv (profile-derivation manifest
 516                                                     #:hooks '()
 517                                                     #:locales? #f)))
 518         (return #f)))))
 519
 520 (test-equal "collision of propagated inputs"
 521   '(("guile-bootstrap" "2.0") ("guile-bootstrap" "42"))
 522   (guard (c ((profile-collision-error? c)
 523              (let ((entry1 (profile-collision-error-entry c))
 524                    (entry2 (profile-collision-error-conflict c)))
 525                (list (list (manifest-entry-name entry1)
 526                            (manifest-entry-version entry1))
 527                      (list (manifest-entry-name entry2)
 528                            (manifest-entry-version entry2))))))
 529     (run-with-store %store
 530       (mlet* %store-monad ((p0 -> (package
 531                                     (inherit %bootstrap-guile)
 532                                     (version "42")))
 533                            (p1 -> (dummy-package "p1"
 534                                     (propagated-inputs
 535                                      `(("guile" ,%bootstrap-guile)))))
 536                            (p2 -> (dummy-package "p2"
 537                                     (propagated-inputs
 538                                      `(("guile" ,p0)))))
 539                            (manifest -> (packages->manifest (list p1 p2)))
 540                            (drv (profile-derivation manifest
 541                                                     #:hooks '()
 542                                                     #:locales? #f)))
 543         (return #f)))))
 544
 545 (test-assertm "no collision"
 546   ;; Here we have an entry that is "lowered" (its 'item' field is a store file
 547   ;; name) and another entry (its 'item' field is a package) that is
 548   ;; equivalent.
 549   (mlet* %store-monad ((p -> (dummy-package "p"
 550                                (propagated-inputs
 551                                 `(("guile" ,%bootstrap-guile)))))
 552                        (guile    (package->derivation %bootstrap-guile))
 553                        (entry -> (manifest-entry
 554                                    (inherit (package->manifest-entry
 555                                              %bootstrap-guile))
 556                                    (item (derivation->output-path guile))))
 557                        (manifest -> (manifest
 558                                      (list entry
 559                                            (package->manifest-entry p))))
 560                        (drv (profile-derivation manifest)))
 561     (return (->bool drv))))
 562
 563 (test-assertm "etc/profile"
 564   ;; Make sure we get an 'etc/profile' file that at least defines $PATH.
 565   (mlet* %store-monad
 566       ((guile ->   (package
 567                      (inherit %bootstrap-guile)
 568                      (native-search-paths
 569                       (package-native-search-paths packages:guile-2.0))))
 570        (entry ->   (package->manifest-entry guile))
 571        (drv        (profile-derivation (manifest (list entry))
 572                                        #:hooks '()
 573                                        #:locales? #f))
 574        (profile -> (derivation->output-path drv)))
 575     (mbegin %store-monad
 576       (built-derivations (list drv))
 577       (let* ((pipe (open-input-pipe
 578                     (string-append "unset GUIX_PROFILE; "
 579                                    ;; 'source' is a Bashism; use '.' (dot).
 580                                    ". " profile "/etc/profile; "
 581                                    ;; Don't try to parse set(1) output because
 582                                    ;; it differs among shells; just use echo.
 583                                    "echo $PATH")))
 584              (path (get-string-all pipe)))
 585         (return
 586          (and (zero? (close-pipe pipe))
 587               (string-contains path (string-append profile "/bin"))))))))
 588
 589 (test-assertm "etc/profile when etc/ already exists"
 590   ;; Here 'union-build' makes the profile's etc/ a symlink to the package's
 591   ;; etc/ directory, which makes it read-only.  Make sure the profile build
 592   ;; handles that.
 593   (mlet* %store-monad
 594       ((thing ->   (dummy-package "dummy"
 595                      (build-system trivial-build-system)
 596                      (arguments
 597                       `(#:guile ,%bootstrap-guile
 598                         #:builder
 599                         (let ((out (assoc-ref %outputs "out")))
 600                           (mkdir out)
 601                           (mkdir (string-append out "/etc"))
 602                           (call-with-output-file (string-append out "/etc/foo")
 603                             (lambda (port)
 604                               (display "foo!" port)))
 605                           #t)))))
 606        (entry ->   (package->manifest-entry thing))
 607        (drv        (profile-derivation (manifest (list entry))
 608                                        #:hooks '()
 609                                        #:locales? #f))
 610        (profile -> (derivation->output-path drv)))
 611     (mbegin %store-monad
 612       (built-derivations (list drv))
 613       (return (and (file-exists? (string-append profile "/etc/profile"))
 614                    (string=? (call-with-input-file
 615                                  (string-append profile "/etc/foo")
 616                                get-string-all)
 617                              "foo!"))))))
 618
 619 (test-assertm "etc/profile when etc/ is a symlink"
 620   ;; When etc/ is a symlink, the unsymlink code in 0.8.2 would fail
 621   ;; gracelessly because 'scandir' would return #f.
 622   (mlet* %store-monad
 623       ((thing ->   (dummy-package "dummy"
 624                      (build-system trivial-build-system)
 625                      (arguments
 626                       `(#:guile ,%bootstrap-guile
 627                         #:builder
 628                         (let ((out (assoc-ref %outputs "out")))
 629                           (mkdir out)
 630                           (mkdir (string-append out "/foo"))
 631                           (symlink "foo" (string-append out "/etc"))
 632                           (call-with-output-file (string-append out "/etc/bar")
 633                             (lambda (port)
 634                               (display "foo!" port)))
 635                           #t)))))
 636        (entry ->   (package->manifest-entry thing))
 637        (drv        (profile-derivation (manifest (list entry))
 638                                        #:hooks '()
 639                                        #:locales? #f))
 640        (profile -> (derivation->output-path drv)))
 641     (mbegin %store-monad
 642       (built-derivations (list drv))
 643       (return (and (file-exists? (string-append profile "/etc/profile"))
 644                    (string=? (call-with-input-file
 645                                  (string-append profile "/etc/bar")
 646                                get-string-all)
 647                              "foo!"))))))
 648
 649 (test-assertm "profile-derivation when etc/ is a relative symlink"
 650   ;; See <https://bugs.gnu.org/32686>.
 651   (mlet* %store-monad
 652       ((etc        (gexp->derivation
 653                     "etc"
 654                     #~(begin
 655                         (mkdir #$output)
 656                         (call-with-output-file (string-append #$output "/foo")
 657                           (lambda (port)
 658                             (display "Heya!" port))))))
 659        (thing ->   (dummy-package "dummy"
 660                      (build-system trivial-build-system)
 661                      (inputs
 662                       `(("etc" ,etc)))
 663                      (arguments
 664                       `(#:guile ,%bootstrap-guile
 665                         #:builder
 666                         (let ((out (assoc-ref %outputs "out"))
 667                               (etc (assoc-ref %build-inputs "etc")))
 668                           (mkdir out)
 669                           (symlink etc (string-append out "/etc"))
 670                           #t)))))
 671        (entry ->   (package->manifest-entry thing))
 672        (drv        (profile-derivation (manifest (list entry))
 673                                        #:relative-symlinks? #t
 674                                        #:hooks '()
 675                                        #:locales? #f))
 676        (profile -> (derivation->output-path drv)))
 677     (mbegin %store-monad
 678       (built-derivations (list drv))
 679       (return (string=? (call-with-input-file
 680                             (string-append profile "/etc/foo")
 681                           get-string-all)
 682                         "Heya!")))))
 683
 684 (test-equalm "union vs. dangling symlink"        ;<https://bugs.gnu.org/26949>
 685   "does-not-exist"
 686   (mlet* %store-monad
 687       ((thing1 ->  (dummy-package "dummy"
 688                      (build-system trivial-build-system)
 689                      (arguments
 690                       `(#:guile ,%bootstrap-guile
 691                         #:builder
 692                         (let ((out (assoc-ref %outputs "out")))
 693                           (mkdir out)
 694                           (symlink "does-not-exist"
 695                                    (string-append out "/dangling"))
 696                           #t)))))
 697        (thing2 ->  (package (inherit thing1) (name "dummy2")))
 698        (drv        (profile-derivation (packages->manifest
 699                                         (list thing1 thing2))
 700                                        #:hooks '()
 701                                        #:locales? #f))
 702        (profile -> (derivation->output-path drv)))
 703     (mbegin %store-monad
 704       (built-derivations (list drv))
 705       (return (readlink (readlink (string-append profile "/dangling")))))))
 706
 707 (test-equalm "profile in profile"
 708   '("foo" "0")
 709
 710   ;; Make sure we can build a profile that has another profile has one of its
 711   ;; entries.  The new profile's /manifest and /etc/profile must override the
 712   ;; other's.
 713   (mlet* %store-monad
 714       ((prof0 (profile-derivation
 715                (manifest
 716                 (list (package->manifest-entry %bootstrap-guile)))
 717                #:hooks '()
 718                #:locales? #f))
 719        (prof1 (profile-derivation
 720                (manifest (list (manifest-entry
 721                                  (name "foo")
 722                                  (version "0")
 723                                  (item prof0))))
 724                #:hooks '()
 725                #:locales? #f)))
 726     (mbegin %store-monad
 727       (built-derivations (list prof1))
 728       (let ((out (derivation->output-path prof1)))
 729         (return (and (file-exists?
 730                       (string-append out "/bin/guile"))
 731                      (let ((manifest (profile-manifest out)))
 732                        (match (manifest-entries manifest)
 733                          ((entry)
 734                           (list (manifest-entry-name entry)
 735                                 (manifest-entry-version entry)))))))))))
 736
 737 (test-end "profiles")
 738
 739 ;;; Local Variables:
 740 ;;; eval: (put 'dummy-package 'scheme-indent-function 1)
 741 ;;; End: