tests/profiles.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2014 Alex Kost <alezost@gmail.com>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (test-profiles)
  21   #:use-module (guix tests)
  22   #:use-module (guix profiles)
  23   #:use-module (guix store)
  24   #:use-module (guix monads)
  25   #:use-module (guix grafts)
  26   #:use-module (guix packages)
  27   #:use-module (guix derivations)
  28   #:use-module (guix build-system trivial)
  29   #:use-module (gnu packages bootstrap)
  30   #:use-module ((gnu packages base) #:prefix packages:)
  31   #:use-module ((gnu packages guile) #:prefix packages:)
  32   #:use-module (ice-9 match)
  33   #:use-module (ice-9 regex)
  34   #:use-module (ice-9 popen)
  35   #:use-module (rnrs io ports)
  36   #:use-module (srfi srfi-1)
  37   #:use-module (srfi srfi-11)
  38   #:use-module (srfi srfi-34)
  39   #:use-module (srfi srfi-64))
  40
  41 ;; Test the (guix profiles) module.
  42
  43 (define %store
  44   (open-connection-for-tests))
  45
  46 ;; Globally disable grafts because they can trigger early builds.
  47 (%graft? #f)
  48
  49 (define-syntax-rule (test-assertm name exp)
  50   (test-assert name
  51     (run-with-store %store exp
  52                     #:guile-for-build (%guile-for-build))))
  53
  54 (define-syntax-rule (test-equalm name value exp)
  55   (test-equal name
  56     value
  57     (run-with-store %store exp
  58                     #:guile-for-build (%guile-for-build))))
  59
  60 ;; Example manifest entries.
  61
  62 (define guile-1.8.8
  63   (manifest-entry
  64     (name "guile")
  65     (version "1.8.8")
  66     (item "/gnu/store/...")
  67     (output "out")))
  68
  69 (define guile-2.0.9
  70   (manifest-entry
  71     (name "guile")
  72     (version "2.0.9")
  73     (item "/gnu/store/...")
  74     (output "out")))
  75
  76 (define guile-2.0.9:debug
  77   (manifest-entry (inherit guile-2.0.9)
  78     (output "debug")))
  79
  80 (define glibc
  81   (manifest-entry
  82     (name "glibc")
  83     (version "2.19")
  84     (item "/gnu/store/...")
  85     (output "out")))
  86
  87 \f
  88 (test-begin "profiles")
  89
  90 (test-assert "manifest-installed?"
  91   (let ((m (manifest (list guile-2.0.9 guile-2.0.9:debug))))
  92     (and (manifest-installed? m (manifest-pattern (name "guile")))
  93          (manifest-installed? m (manifest-pattern
  94                                   (name "guile") (output "debug")))
  95          (manifest-installed? m (manifest-pattern
  96                                   (name "guile") (output "out")
  97                                   (version "2.0.9")))
  98          (not (manifest-installed?
  99                m (manifest-pattern (name "guile") (version "1.8.8"))))
 100          (not (manifest-installed?
 101                m (manifest-pattern (name "guile") (output "foobar")))))))
 102
 103 (test-assert "manifest-matching-entries"
 104   (let* ((e (list guile-2.0.9 guile-2.0.9:debug))
 105          (m (manifest e)))
 106     (and (null? (manifest-matching-entries m
 107                                            (list (manifest-pattern
 108                                                    (name "python")))))
 109          (equal? e
 110                  (manifest-matching-entries m
 111                                             (list (manifest-pattern
 112                                                     (name "guile")
 113                                                     (output #f)))))
 114          (equal? (list guile-2.0.9)
 115                  (manifest-matching-entries m
 116                                             (list (manifest-pattern
 117                                                     (name "guile")
 118                                                     (version "2.0.9"))))))))
 119
 120 (test-assert "manifest-remove"
 121   (let* ((m0 (manifest (list guile-2.0.9 guile-2.0.9:debug)))
 122          (m1 (manifest-remove m0
 123                               (list (manifest-pattern (name "guile")))))
 124          (m2 (manifest-remove m1
 125                               (list (manifest-pattern (name "guile"))))) ; same
 126          (m3 (manifest-remove m2
 127                               (list (manifest-pattern
 128                                       (name "guile") (output "debug")))))
 129          (m4 (manifest-remove m3
 130                               (list (manifest-pattern (name "guile"))))))
 131     (match (manifest-entries m2)
 132       ((($ <manifest-entry> "guile" "2.0.9" "debug"))
 133        (and (equal? m1 m2)
 134             (null? (manifest-entries m3))
 135             (null? (manifest-entries m4)))))))
 136
 137 (test-assert "manifest-add"
 138   (let* ((m0 (manifest '()))
 139          (m1 (manifest-add m0 (list guile-1.8.8)))
 140          (m2 (manifest-add m1 (list guile-2.0.9)))
 141          (m3 (manifest-add m2 (list guile-2.0.9:debug)))
 142          (m4 (manifest-add m3 (list guile-2.0.9:debug))))
 143     (and (match (manifest-entries m1)
 144            ((($ <manifest-entry> "guile" "1.8.8" "out")) #t)
 145            (_ #f))
 146          (match (manifest-entries m2)
 147            ((($ <manifest-entry> "guile" "2.0.9" "out")) #t)
 148            (_ #f))
 149          (equal? m3 m4))))
 150
 151 (test-equal "manifest-add removes duplicates"    ;<https://bugs.gnu.org/30569>
 152   (list guile-2.0.9)
 153   (manifest-entries (manifest-add (manifest '())
 154                                   (list guile-2.0.9 guile-2.0.9))))
 155
 156 (test-assert "manifest-perform-transaction"
 157   (let* ((m0 (manifest (list guile-2.0.9 guile-2.0.9:debug)))
 158          (t1 (manifest-transaction
 159               (install (list guile-1.8.8))
 160               (remove (list (manifest-pattern (name "guile")
 161                                               (output "debug"))))))
 162          (t2 (manifest-transaction
 163               (remove (list (manifest-pattern (name "guile")
 164                                               (version "2.0.9")
 165                                               (output #f))))))
 166          (m1 (manifest-perform-transaction m0 t1))
 167          (m2 (manifest-perform-transaction m1 t2))
 168          (m3 (manifest-perform-transaction m0 t2)))
 169     (and (match (manifest-entries m1)
 170            ((($ <manifest-entry> "guile" "1.8.8" "out")) #t)
 171            (_ #f))
 172          (equal? m1 m2)
 173          (null? (manifest-entries m3)))))
 174
 175 (test-assert "manifest-transaction-effects"
 176   (let* ((m0 (manifest (list guile-1.8.8)))
 177          (t  (manifest-transaction
 178               (install (list guile-2.0.9 glibc))
 179               (remove (list (manifest-pattern (name "coreutils")))))))
 180     (let-values (((remove install upgrade downgrade)
 181                   (manifest-transaction-effects m0 t)))
 182       (and (null? remove) (null? downgrade)
 183            (equal? (list glibc) install)
 184            (equal? (list (cons guile-1.8.8 guile-2.0.9)) upgrade)))))
 185
 186 (test-assert "manifest-transaction-effects and downgrades"
 187   (let* ((m0 (manifest (list guile-2.0.9)))
 188          (t  (manifest-transaction (install (list guile-1.8.8)))))
 189     (let-values (((remove install upgrade downgrade)
 190                   (manifest-transaction-effects m0 t)))
 191       (and (null? remove) (null? install) (null? upgrade)
 192            (equal? (list (cons guile-2.0.9 guile-1.8.8)) downgrade)))))
 193
 194 (test-assert "manifest-transaction-effects and pseudo-upgrades"
 195   (let* ((m0 (manifest (list guile-2.0.9)))
 196          (t  (manifest-transaction (install (list guile-2.0.9)))))
 197     (let-values (((remove install upgrade downgrade)
 198                   (manifest-transaction-effects m0 t)))
 199       (and (null? remove) (null? install) (null? downgrade)
 200            (equal? (list (cons guile-2.0.9 guile-2.0.9)) upgrade)))))
 201
 202 (test-assert "manifest-transaction-null?"
 203   (manifest-transaction-null? (manifest-transaction)))
 204
 205 (test-assert "manifest-transaction-removal-candidate?"
 206   (let ((m (manifest (list guile-2.0.9)))
 207         (t (manifest-transaction
 208             (remove (list (manifest-pattern (name "guile")))))))
 209     (and (manifest-transaction-removal-candidate? guile-2.0.9 t)
 210          (not (manifest-transaction-removal-candidate? glibc t)))))
 211
 212 (test-assertm "profile-derivation"
 213   (mlet* %store-monad
 214       ((entry ->   (package->manifest-entry %bootstrap-guile))
 215        (guile      (package->derivation %bootstrap-guile))
 216        (drv        (profile-derivation (manifest (list entry))
 217                                        #:hooks '()
 218                                        #:locales? #f))
 219        (profile -> (derivation->output-path drv))
 220        (bindir ->  (string-append profile "/bin"))
 221        (_          (built-derivations (list drv))))
 222     (return (and (file-exists? (string-append bindir "/guile"))
 223                  (string=? (dirname (readlink bindir))
 224                            (derivation->output-path guile))))))
 225
 226 (test-assertm "profile-derivation, inputs"
 227   (mlet* %store-monad
 228       ((entry ->   (package->manifest-entry packages:glibc "debug"))
 229        (drv        (profile-derivation (manifest (list entry))
 230                                        #:hooks '()
 231                                        #:locales? #f)))
 232     (return (derivation-inputs drv))))
 233
 234 (test-assertm "profile-derivation, cross-compilation"
 235   (mlet* %store-monad
 236       ((manifest -> (packages->manifest (list packages:sed packages:grep)))
 237        (target ->   "arm-linux-gnueabihf")
 238        (grep        (package->cross-derivation packages:grep target))
 239        (sed         (package->cross-derivation packages:sed target))
 240        (locales     (package->derivation packages:glibc-utf8-locales))
 241        (drv         (profile-derivation manifest
 242                                         #:hooks '()
 243                                         #:locales? #t
 244                                         #:target target)))
 245     (define (find-input package)
 246       (let ((name (string-append (package-full-name package "-") ".drv")))
 247         (any (lambda (input)
 248                (let ((input (derivation-input-path input)))
 249                  (and (string-suffix? name input) input)))
 250              (derivation-inputs drv))))
 251
 252     ;; The inputs for grep and sed should be cross-build derivations, but that
 253     ;; for the glibc-utf8-locales should be a native build.
 254     (return (and (string=? (derivation-system drv) (%current-system))
 255                  (string=? (find-input packages:grep)
 256                            (derivation-file-name grep))
 257                  (string=? (find-input packages:sed)
 258                            (derivation-file-name sed))
 259                  (string=? (find-input packages:glibc-utf8-locales)
 260                            (derivation-file-name locales))))))
 261
 262 (test-assert "package->manifest-entry defaults to \"out\""
 263   (let ((outputs (package-outputs packages:glibc)))
 264     (equal? (manifest-entry-output
 265              (package->manifest-entry (package
 266                                         (inherit packages:glibc)
 267                                         (outputs (reverse outputs)))))
 268             (manifest-entry-output
 269              (package->manifest-entry packages:glibc))
 270             "out")))
 271
 272 (test-assertm "profile-manifest, search-paths"
 273   (mlet* %store-monad
 274       ((guile ->   (package
 275                      (inherit %bootstrap-guile)
 276                      (native-search-paths
 277                       (package-native-search-paths packages:guile-2.0))))
 278        (entry ->   (package->manifest-entry guile))
 279        (drv        (profile-derivation (manifest (list entry))
 280                                        #:hooks '()
 281                                        #:locales? #f))
 282        (profile -> (derivation->output-path drv)))
 283     (mbegin %store-monad
 284       (built-derivations (list drv))
 285
 286       ;; Read the manifest back and make sure search paths are preserved.
 287       (let ((manifest (profile-manifest profile)))
 288         (match (manifest-entries manifest)
 289           ((result)
 290            (return (equal? (manifest-entry-search-paths result)
 291                            (manifest-entry-search-paths entry)
 292                            (package-native-search-paths
 293                             packages:guile-2.0)))))))))
 294
 295 (test-assert "package->manifest-entry, search paths"
 296   ;; See <http://bugs.gnu.org/22073>.
 297   (let ((mpl (@ (gnu packages python) python2-matplotlib)))
 298     (lset= eq?
 299            (package-transitive-native-search-paths mpl)
 300            (manifest-entry-search-paths
 301             (package->manifest-entry mpl)))))
 302
 303 (test-equal "packages->manifest, propagated inputs"
 304   (map (match-lambda
 305          ((label package)
 306           (list (package-name package) (package-version package)
 307                 package)))
 308        (package-propagated-inputs packages:guile-2.2))
 309   (map (lambda (entry)
 310          (list (manifest-entry-name entry)
 311                (manifest-entry-version entry)
 312                (manifest-entry-item entry)))
 313        (manifest-entry-dependencies
 314         (package->manifest-entry packages:guile-2.2))))
 315
 316 (test-assert "manifest-entry-parent"
 317   (let ((entry (package->manifest-entry packages:guile-2.2)))
 318     (match (manifest-entry-dependencies entry)
 319       ((dependencies ..1)
 320        (and (every (lambda (parent)
 321                      (eq? entry (force parent)))
 322                    (map manifest-entry-parent dependencies))
 323             (not (force (manifest-entry-parent entry))))))))
 324
 325 (test-assertm "read-manifest"
 326   (mlet* %store-monad ((manifest -> (packages->manifest
 327                                      (list (package
 328                                              (inherit %bootstrap-guile)
 329                                              (native-search-paths
 330                                               (package-native-search-paths
 331                                                packages:guile-2.0))))))
 332                        (drv (profile-derivation manifest
 333                                                 #:hooks '()
 334                                                 #:locales? #f))
 335                        (out -> (derivation->output-path drv)))
 336     (define (entry->sexp entry)
 337       (list (manifest-entry-name entry)
 338             (manifest-entry-version entry)
 339             (manifest-entry-search-paths entry)
 340             (manifest-entry-dependencies entry)
 341             (force (manifest-entry-parent entry))))
 342
 343     (mbegin %store-monad
 344       (built-derivations (list drv))
 345       (let ((manifest2 (profile-manifest out)))
 346         (return (equal? (map entry->sexp (manifest-entries manifest))
 347                         (map entry->sexp (manifest-entries manifest2))))))))
 348
 349 (test-equal "collision"
 350   '(("guile-bootstrap" "2.0") ("guile-bootstrap" "42"))
 351   (guard (c ((profile-collision-error? c)
 352              (let ((entry1 (profile-collision-error-entry c))
 353                    (entry2 (profile-collision-error-conflict c)))
 354                (list (list (manifest-entry-name entry1)
 355                            (manifest-entry-version entry1))
 356                      (list (manifest-entry-name entry2)
 357                            (manifest-entry-version entry2))))))
 358     (run-with-store %store
 359       (mlet* %store-monad ((p0 -> (package
 360                                     (inherit %bootstrap-guile)
 361                                     (version "42")))
 362                            (p1 -> (dummy-package "p1"
 363                                     (propagated-inputs `(("p0" ,p0)))))
 364                            (manifest -> (packages->manifest
 365                                          (list %bootstrap-guile p1)))
 366                            (drv (profile-derivation manifest
 367                                                     #:hooks '()
 368                                                     #:locales? #f)))
 369         (return #f)))))
 370
 371 (test-equal "collision of propagated inputs"
 372   '(("guile-bootstrap" "2.0") ("guile-bootstrap" "42"))
 373   (guard (c ((profile-collision-error? c)
 374              (let ((entry1 (profile-collision-error-entry c))
 375                    (entry2 (profile-collision-error-conflict c)))
 376                (list (list (manifest-entry-name entry1)
 377                            (manifest-entry-version entry1))
 378                      (list (manifest-entry-name entry2)
 379                            (manifest-entry-version entry2))))))
 380     (run-with-store %store
 381       (mlet* %store-monad ((p0 -> (package
 382                                     (inherit %bootstrap-guile)
 383                                     (version "42")))
 384                            (p1 -> (dummy-package "p1"
 385                                     (propagated-inputs
 386                                      `(("guile" ,%bootstrap-guile)))))
 387                            (p2 -> (dummy-package "p2"
 388                                     (propagated-inputs
 389                                      `(("guile" ,p0)))))
 390                            (manifest -> (packages->manifest (list p1 p2)))
 391                            (drv (profile-derivation manifest
 392                                                     #:hooks '()
 393                                                     #:locales? #f)))
 394         (return #f)))))
 395
 396 (test-assertm "no collision"
 397   ;; Here we have an entry that is "lowered" (its 'item' field is a store file
 398   ;; name) and another entry (its 'item' field is a package) that is
 399   ;; equivalent.
 400   (mlet* %store-monad ((p -> (dummy-package "p"
 401                                (propagated-inputs
 402                                 `(("guile" ,%bootstrap-guile)))))
 403                        (guile    (package->derivation %bootstrap-guile))
 404                        (entry -> (manifest-entry
 405                                    (inherit (package->manifest-entry
 406                                              %bootstrap-guile))
 407                                    (item (derivation->output-path guile))))
 408                        (manifest -> (manifest
 409                                      (list entry
 410                                            (package->manifest-entry p))))
 411                        (drv (profile-derivation manifest)))
 412     (return (->bool drv))))
 413
 414 (test-assertm "etc/profile"
 415   ;; Make sure we get an 'etc/profile' file that at least defines $PATH.
 416   (mlet* %store-monad
 417       ((guile ->   (package
 418                      (inherit %bootstrap-guile)
 419                      (native-search-paths
 420                       (package-native-search-paths packages:guile-2.0))))
 421        (entry ->   (package->manifest-entry guile))
 422        (drv        (profile-derivation (manifest (list entry))
 423                                        #:hooks '()
 424                                        #:locales? #f))
 425        (profile -> (derivation->output-path drv)))
 426     (mbegin %store-monad
 427       (built-derivations (list drv))
 428       (let* ((pipe (open-input-pipe
 429                     (string-append "unset GUIX_PROFILE; "
 430                                    ;; 'source' is a Bashism; use '.' (dot).
 431                                    ". " profile "/etc/profile; "
 432                                    ;; Don't try to parse set(1) output because
 433                                    ;; it differs among shells; just use echo.
 434                                    "echo $PATH")))
 435              (path (get-string-all pipe)))
 436         (return
 437          (and (zero? (close-pipe pipe))
 438               (string-contains path (string-append profile "/bin"))))))))
 439
 440 (test-assertm "etc/profile when etc/ already exists"
 441   ;; Here 'union-build' makes the profile's etc/ a symlink to the package's
 442   ;; etc/ directory, which makes it read-only.  Make sure the profile build
 443   ;; handles that.
 444   (mlet* %store-monad
 445       ((thing ->   (dummy-package "dummy"
 446                      (build-system trivial-build-system)
 447                      (arguments
 448                       `(#:guile ,%bootstrap-guile
 449                         #:builder
 450                         (let ((out (assoc-ref %outputs "out")))
 451                           (mkdir out)
 452                           (mkdir (string-append out "/etc"))
 453                           (call-with-output-file (string-append out "/etc/foo")
 454                             (lambda (port)
 455                               (display "foo!" port))))))))
 456        (entry ->   (package->manifest-entry thing))
 457        (drv        (profile-derivation (manifest (list entry))
 458                                        #:hooks '()
 459                                        #:locales? #f))
 460        (profile -> (derivation->output-path drv)))
 461     (mbegin %store-monad
 462       (built-derivations (list drv))
 463       (return (and (file-exists? (string-append profile "/etc/profile"))
 464                    (string=? (call-with-input-file
 465                                  (string-append profile "/etc/foo")
 466                                get-string-all)
 467                              "foo!"))))))
 468
 469 (test-assertm "etc/profile when etc/ is a symlink"
 470   ;; When etc/ is a symlink, the unsymlink code in 0.8.2 would fail
 471   ;; gracelessly because 'scandir' would return #f.
 472   (mlet* %store-monad
 473       ((thing ->   (dummy-package "dummy"
 474                      (build-system trivial-build-system)
 475                      (arguments
 476                       `(#:guile ,%bootstrap-guile
 477                         #:builder
 478                         (let ((out (assoc-ref %outputs "out")))
 479                           (mkdir out)
 480                           (mkdir (string-append out "/foo"))
 481                           (symlink "foo" (string-append out "/etc"))
 482                           (call-with-output-file (string-append out "/etc/bar")
 483                             (lambda (port)
 484                               (display "foo!" port))))))))
 485        (entry ->   (package->manifest-entry thing))
 486        (drv        (profile-derivation (manifest (list entry))
 487                                        #:hooks '()
 488                                        #:locales? #f))
 489        (profile -> (derivation->output-path drv)))
 490     (mbegin %store-monad
 491       (built-derivations (list drv))
 492       (return (and (file-exists? (string-append profile "/etc/profile"))
 493                    (string=? (call-with-input-file
 494                                  (string-append profile "/etc/bar")
 495                                get-string-all)
 496                              "foo!"))))))
 497
 498 (test-equalm "union vs. dangling symlink"        ;<https://bugs.gnu.org/26949>
 499   "does-not-exist"
 500   (mlet* %store-monad
 501       ((thing1 ->  (dummy-package "dummy"
 502                      (build-system trivial-build-system)
 503                      (arguments
 504                       `(#:guile ,%bootstrap-guile
 505                         #:builder
 506                         (let ((out (assoc-ref %outputs "out")))
 507                           (mkdir out)
 508                           (symlink "does-not-exist"
 509                                    (string-append out "/dangling"))
 510                           #t)))))
 511        (thing2 ->  (package (inherit thing1) (name "dummy2")))
 512        (drv        (profile-derivation (packages->manifest
 513                                         (list thing1 thing2))
 514                                        #:hooks '()
 515                                        #:locales? #f))
 516        (profile -> (derivation->output-path drv)))
 517     (mbegin %store-monad
 518       (built-derivations (list drv))
 519       (return (readlink (readlink (string-append profile "/dangling")))))))
 520
 521 (test-end "profiles")
 522
 523 ;;; Local Variables:
 524 ;;; eval: (put 'dummy-package 'scheme-indent-function 1)
 525 ;;; End: