gnu/packages/ci.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2015 Eric Bavier <bavier@member.fsf.org>
   3 ;;; Copyright © 2016 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;; Copyright © 2016, 2017 Mathieu Lirzin <mthl@gnu.org>
   5 ;;; Copyright © 2017, 2020, 2021 Mathieu Othacehe <m.othacehe@gmail.com>
   6 ;;; Copyright © 2017, 2019, 2020 Ricardo Wurmus <rekado@elephly.net>
   7 ;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  12 ;;; under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation; either version 3 of the License, or (at
  14 ;;; your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful, but
  17 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu packages ci)
  25   #:use-module ((guix licenses) #:prefix l:)
  26   #:use-module (gnu packages)
  27   #:use-module (guix packages)
  28   #:use-module (guix git-download)
  29   #:use-module (guix download)
  30   #:use-module (gnu packages autotools)
  31   #:use-module (gnu packages base)
  32   #:use-module (gnu packages docbook)
  33   #:use-module (gnu packages compression)
  34   #:use-module (gnu packages databases)
  35   #:use-module (gnu packages guile)
  36   #:use-module (gnu packages guile-xyz)
  37   #:use-module (gnu packages gnupg)
  38   #:use-module (gnu packages mail)
  39   #:use-module (gnu packages package-management)
  40   #:use-module (gnu packages perl)
  41   #:use-module (gnu packages perl-compression)
  42   #:use-module (gnu packages pkg-config)
  43   #:use-module (gnu packages tls)
  44   #:use-module (gnu packages texinfo)
  45   #:use-module (gnu packages version-control)
  46   #:use-module (gnu packages web)
  47   #:use-module (gnu packages xml)
  48   #:use-module (guix build-system gnu))
  49
  50 (define-public cuirass
  51   (let ((commit "eb94e7da6a5985a4b92d92aa22955e4013490e9c")
  52         (revision "5"))
  53     (package
  54       (name "cuirass")
  55       (version (git-version "1.0.0" revision commit))
  56       (source
  57        (origin
  58          (method git-fetch)
  59          (uri (git-reference
  60                (url "https://git.savannah.gnu.org/git/guix/guix-cuirass.git")
  61                (commit commit)))
  62          (file-name (git-file-name name version))
  63          (sha256
  64           (base32
  65            "1fyj33bhfl0zl7ik98dxqvb58n24zv3aw037gvri0p0xzyp2fhbx"))))
  66       (build-system gnu-build-system)
  67       (arguments
  68        `(#:modules ((guix build utils)
  69                     (guix build gnu-build-system)
  70                     (ice-9 rdelim)
  71                     (ice-9 popen))
  72          #:configure-flags '("--localstatedir=/var") ;for /var/log/cuirass
  73          #:parallel-tests? #f
  74          #:phases
  75          (modify-phases %standard-phases
  76            (add-before 'bootstrap 'fix-version-gen
  77              (lambda _
  78               (patch-shebang "build-aux/git-version-gen")
  79
  80               (call-with-output-file ".tarball-version"
  81                 (lambda (port)
  82                   (display ,version port)))))
  83            (add-before 'check 'set-PATH-for-tests
  84              (lambda* (#:key inputs #:allow-other-keys)
  85                (let ((pg (assoc-ref inputs "ephemeralpg"))
  86                      (path (getenv "PATH")))
  87                  (setenv "PATH" (string-append pg "/bin:" path))
  88                  #t)))
  89            ;; Disable the remote tests that require a Guix daemon connection.
  90            (add-before 'check 'disable-remote-tests
  91              (lambda _
  92                (substitute* "Makefile.am"
  93                  (("tests/remote.scm") ""))
  94                #t))
  95            (add-after 'install 'wrap-program
  96              (lambda* (#:key inputs outputs #:allow-other-keys)
  97                ;; Wrap the 'cuirass' command to refer to the right modules.
  98                (let* ((out    (assoc-ref outputs "out"))
  99                       (avahi  (assoc-ref inputs "guile-avahi"))
 100                       (gcrypt (assoc-ref inputs "guile-gcrypt"))
 101                       (json   (assoc-ref inputs "guile-json"))
 102                       (zmq    (assoc-ref inputs "guile-simple-zmq"))
 103                       (squee  (assoc-ref inputs "guile-squee"))
 104                       (git    (assoc-ref inputs "guile-git"))
 105                       (bytes  (assoc-ref inputs "guile-bytestructures"))
 106                       (fibers (assoc-ref inputs "guile-fibers"))
 107                       (zlib   (assoc-ref inputs "guile-zlib"))
 108                       (matd   (assoc-ref inputs "guile-mastodon"))
 109                       (tls    (assoc-ref inputs "gnutls"))
 110                       (mail   (assoc-ref inputs "mailutils"))
 111                       (guix   (assoc-ref inputs "guix"))
 112                       (deps   (list avahi gcrypt json zmq squee git bytes
 113                                     fibers zlib matd tls mail guix))
 114                       (guile  (assoc-ref %build-inputs "guile"))
 115                       (effective
 116                        (read-line
 117                         (open-pipe* OPEN_READ
 118                                     (string-append guile "/bin/guile")
 119                                     "-c" "(display (effective-version))")))
 120                       (mods
 121                        (string-drop-right  ;drop trailing colon
 122                         (string-join deps
 123                                      (string-append "/share/guile/site/"
 124                                                     effective ":")
 125                                      'suffix)
 126                         1))
 127                       (objs
 128                        (string-drop-right
 129                         (string-join deps
 130                                      (string-append "/lib/guile/" effective
 131                                                     "/site-ccache:")
 132                                      'suffix)
 133                         1)))
 134                  ;; Make sure 'cuirass' can find the relevant Guile modules.
 135                  (wrap-program (string-append out "/bin/cuirass")
 136                    `("PATH" ":" prefix (,(string-append out "/bin")))
 137                    `("GUILE_LOAD_PATH" ":" prefix (,mods))
 138                    `("GUILE_LOAD_COMPILED_PATH" ":" prefix (,objs)))
 139                  #t))))))
 140       (inputs
 141        `(("guile" ,guile-3.0/libgc-7)
 142          ("guile-avahi" ,guile-avahi)
 143          ("guile-fibers" ,guile-fibers)
 144          ("guile-gcrypt" ,guile-gcrypt)
 145          ("guile-json" ,guile-json-4)
 146          ("guile-simple-zmq" ,guile-simple-zmq)
 147          ("guile-squee" ,guile-squee)
 148          ("guile-git" ,guile-git)
 149          ("guile-zlib" ,guile-zlib)
 150          ("guile-mastodon" ,guile-mastodon)
 151          ("gnutls" ,gnutls)
 152          ("mailutils" ,mailutils)
 153          ;; FIXME: this is propagated by "guile-git", but it needs to be among
 154          ;; the inputs to add it to GUILE_LOAD_PATH.
 155          ("guile-bytestructures" ,guile-bytestructures)
 156          ("guix" ,guix)))
 157       (native-inputs
 158        `(("autoconf" ,autoconf)
 159          ("automake" ,automake)
 160          ("pkg-config" ,pkg-config)
 161          ("texinfo" ,texinfo)
 162          ("ephemeralpg" ,ephemeralpg)))
 163       (native-search-paths
 164        ;; For HTTPS access, Cuirass itself honors these variables, with the
 165        ;; same semantics as Git and OpenSSL (respectively).
 166        (list (search-path-specification
 167               (variable "GIT_SSL_CAINFO")
 168               (file-type 'regular)
 169               (separator #f)                      ;single entry
 170               (files '("etc/ssl/certs/ca-certificates.crt")))
 171              (search-path-specification
 172               (variable "SSL_CERT_DIR")
 173               (files '("etc/ssl/certs")))))
 174       (synopsis "Continuous integration system")
 175       (description
 176        "Cuirass is a continuous integration tool using GNU Guix.  It is
 177 intended as a replacement for Hydra.")
 178       (home-page "https://www.gnu.org/software/guix/")
 179       (license l:gpl3+))))