gnu/packages/emacs.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2019, 2021 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
   4 ;;; Copyright © 2014 Taylan Ulrich Bayirli/Kammer <taylanbayirli@gmail.com>
   5 ;;; Copyright © 2014, 2015, 2016, 2017, 2018, 2019, 2020 Mark H Weaver <mhw@netris.org>
   6 ;;; Copyright © 2014, 2015, 2016, 2017 Alex Kost <alezost@gmail.com>
   7 ;;; Copyright © 2016, 2018 Arun Isaac <arunisaac@systemreboot.net>
   8 ;;; Copyright © 2016 Federico Beffa <beffa@fbengineering.ch>
   9 ;;; Copyright © 2016 David Thompson <dthompson2@worcester.edu>
  10 ;;; Copyright © 2016 Nikita <nikita@n0.is>
  11 ;;; Copyright © 2017 Marius Bakke <mbakke@fastmail.com>
  12 ;;; Copyright © 2017, 2019, 2020 Maxim Cournoyer <maxim.cournoyer@gmail.com>
  13 ;;; Copyright © 2017 Alex Vong <alexvong1995@gmail.com>
  14 ;;; Copyright © 2017, 2018 Ricardo Wurmus <rekado@elephly.net>
  15 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
  16 ;;; Copyright © 2018 Efraim Flashner <efraim@flashner.co.il>
  17 ;;; Copyright © 2018 Mathieu Othacehe <m.othacehe@gmail.com>
  18 ;;; Copyright © 2018, 2019, 2021 Tobias Geerinckx-Rice <me@tobias.gr>
  19 ;;; Copyright © 2019 Jesse John Gildersleve <jessejohngildersleve@zohomail.eu>
  20 ;;; Copyright © 2019 Valentin Ignatev <valentignatev@gmail.com>
  21 ;;; Copyright © 2019 Leo Prikler <leo.prikler@student.tugraz.at>
  22 ;;; Copyright © 2019 Amin Bandali <bandali@gnu.org>
  23 ;;; Copyright © 2020 Jack Hill <jackhill@jackhill.us>
  24 ;;; Copyright © 2020 Morgan Smith <Morgan.J.Smith@outlook.com>
  25 ;;;
  26 ;;; This file is part of GNU Guix.
  27 ;;;
  28 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  29 ;;; under the terms of the GNU General Public License as published by
  30 ;;; the Free Software Foundation; either version 3 of the License, or (at
  31 ;;; your option) any later version.
  32 ;;;
  33 ;;; GNU Guix is distributed in the hope that it will be useful, but
  34 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  35 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  36 ;;; GNU General Public License for more details.
  37 ;;;
  38 ;;; You should have received a copy of the GNU General Public License
  39 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  40
  41 (define-module (gnu packages emacs)
  42   #:use-module ((guix licenses) #:prefix license:)
  43   #:use-module (guix packages)
  44   #:use-module (guix download)
  45   #:use-module (guix git-download)
  46   #:use-module (guix build-system gnu)
  47   #:use-module (guix build-system glib-or-gtk)
  48   #:use-module (gnu packages)
  49   #:use-module (gnu packages acl)
  50   #:use-module (gnu packages autotools)
  51   #:use-module (gnu packages base)
  52   #:use-module (gnu packages compression)
  53   #:use-module (gnu packages fontutils)
  54   #:use-module (gnu packages fribidi)
  55   #:use-module (gnu packages gd)
  56   #:use-module (gnu packages gettext)
  57   #:use-module (gnu packages glib)
  58   #:use-module (gnu packages gnome)     ; for librsvg
  59   #:use-module (gnu packages gtk)
  60   #:use-module (gnu packages guile)
  61   #:use-module (gnu packages image)
  62   #:use-module (gnu packages linux)     ; alsa-lib
  63   #:use-module (gnu packages mail)      ; for mailutils
  64   #:use-module (gnu packages multiprecision)
  65   #:use-module (gnu packages ncurses)
  66   #:use-module (gnu packages pkg-config)
  67   #:use-module (gnu packages texinfo)
  68   #:use-module (gnu packages tls)
  69   #:use-module (gnu packages web)       ; for jansson
  70   #:use-module (gnu packages webkit)
  71   #:use-module (gnu packages xml)
  72   #:use-module (gnu packages xorg)
  73   #:use-module (guix utils)
  74   #:use-module (srfi srfi-1))
  75
  76 (define-public emacs
  77   (package
  78     (name "emacs")
  79     (version "27.2")
  80     (source (origin
  81               (method url-fetch)
  82               (uri (string-append "mirror://gnu/emacs/emacs-"
  83                                   version ".tar.xz"))
  84               (sha256
  85                (base32
  86                 "1ff182gjw9wqsbx1kj5gl2r5pbqhp4ar54g04j33fgz6g17cr9xl"))
  87               (patches (search-patches "emacs-exec-path.patch"
  88                                        "emacs-fix-scheme-indent-function.patch"
  89                                        "emacs-ignore-empty-xim-styles.patch"
  90                                        "emacs-source-date-epoch.patch"))
  91               (modules '((guix build utils)))
  92               (snippet
  93                '(with-directory-excursion "lisp"
  94                   ;; Delete the bundled byte-compiled elisp files and generated
  95                   ;; autoloads.
  96                   (for-each delete-file
  97                             (append (find-files "." "\\.elc$")
  98                                     (find-files "." "loaddefs\\.el$")
  99                                     (find-files "eshell" "^esh-groups\\.el$")))
 100
 101                   ;; Make sure Tramp looks for binaries in the right places on
 102                   ;; remote Guix System machines, where 'getconf PATH' returns
 103                   ;; something bogus.
 104                   (substitute* "net/tramp-sh.el"
 105                     ;; Patch the line after "(defcustom tramp-remote-path".
 106                     (("\\(tramp-default-remote-path")
 107                      (format #f "(tramp-default-remote-path ~s ~s ~s ~s "
 108                              "~/.guix-profile/bin" "~/.guix-profile/sbin"
 109                              "/run/current-system/profile/bin"
 110                              "/run/current-system/profile/sbin")))
 111
 112                   ;; Make sure Man looks for C header files in the right
 113                   ;; places.
 114                   (substitute* "man.el"
 115                     (("\"/usr/local/include\"" line)
 116                      (string-join
 117                       (list line
 118                             "\"~/.guix-profile/include\""
 119                             "\"/var/guix/profiles/system/profile/include\"")
 120                       " ")))
 121                   #t))))
 122     (build-system glib-or-gtk-build-system)
 123     (arguments
 124      `(#:tests? #f                      ; no check target
 125        #:configure-flags (list "--with-modules"
 126                                "--with-cairo"
 127                                "--disable-build-details")
 128        #:phases
 129        (modify-phases %standard-phases
 130          (add-after 'unpack 'patch-program-file-names
 131            (lambda _
 132              (substitute* '("src/callproc.c"
 133                             "lisp/term.el"
 134                             "lisp/htmlfontify.el"
 135                             "lisp/textmodes/artist.el"
 136                             "lisp/progmodes/sh-script.el")
 137                (("\"/bin/sh\"")
 138                 (format #f "~s" (which "sh"))))
 139              #t))
 140          (add-before 'configure 'fix-/bin/pwd
 141            (lambda _
 142              ;; Use `pwd', not `/bin/pwd'.
 143              (substitute* (find-files "." "^Makefile\\.in$")
 144                (("/bin/pwd")
 145                 "pwd"))
 146              #t))
 147          (add-after 'install 'install-site-start
 148            ;; Use 'guix-emacs' in "site-start.el", which is used autoload the
 149            ;; Elisp packages found in EMACSLOADPATH.
 150            (lambda* (#:key inputs outputs #:allow-other-keys)
 151              (let* ((out      (assoc-ref outputs "out"))
 152                     (lisp-dir (string-append out "/share/emacs/site-lisp"))
 153                     (emacs    (string-append out "/bin/emacs")))
 154
 155                ;; This is duplicated from emacs-utils to prevent coupling.
 156                (define* (emacs-byte-compile-directory dir)
 157                  (let ((expr `(progn
 158                                (setq byte-compile-debug t)
 159                                (byte-recompile-directory
 160                                 (file-name-as-directory ,dir) 0 1))))
 161                    (invoke emacs "--quick" "--batch"
 162                            (format #f "--eval=~s" expr))))
 163
 164                (copy-file (assoc-ref inputs "guix-emacs.el")
 165                           (string-append lisp-dir "/guix-emacs.el"))
 166                (with-output-to-file (string-append lisp-dir "/site-start.el")
 167                  (lambda ()
 168                    (display
 169                     (string-append "(when (require 'guix-emacs nil t)\n"
 170                                    "  (guix-emacs-autoload-packages))\n"))))
 171                ;; Remove the extraneous subdirs.el file, as it causes Emacs to
 172                ;; add recursively all the the sub-directories of a profile's
 173                ;; share/emacs/site-lisp union when added to EMACSLOADPATH,
 174                ;; which leads to conflicts.
 175                (delete-file (string-append lisp-dir "/subdirs.el"))
 176                ;; Byte compile the site-start files.
 177                (emacs-byte-compile-directory lisp-dir))
 178              #t))
 179          (add-after 'glib-or-gtk-wrap 'restore-emacs-pdmp
 180            ;; restore the dump file that Emacs installs somewhere in
 181            ;; libexec/ to its original state
 182            (lambda* (#:key outputs target #:allow-other-keys)
 183              (let* ((libexec (string-append (assoc-ref outputs "out")
 184                                             "/libexec"))
 185                     ;; each of these find-files should return one file
 186                     (pdmp (find-files libexec "^emacs\\.pdmp$"))
 187                     (pdmp-real (find-files libexec
 188                                            "^\\.emacs\\.pdmp-real$")))
 189                (for-each (lambda (wrapper real)
 190                            (delete-file wrapper)
 191                            (rename-file real wrapper))
 192                          pdmp pdmp-real))
 193              #t))
 194          (add-after 'glib-or-gtk-wrap 'strip-double-wrap
 195            (lambda* (#:key outputs #:allow-other-keys)
 196              ;; Directly copy emacs-X.Y to emacs, so that it is not wrapped
 197              ;; twice.  This also fixes a minor issue, where WMs would not be
 198              ;; able to track emacs back to emacs.desktop.
 199              (with-directory-excursion (assoc-ref outputs "out")
 200                (copy-file
 201                 (car (find-files "bin" "^emacs-([0-9]+\\.)+[0-9]+$"))
 202                 "bin/emacs")
 203                #t)))
 204          (add-after 'strip-double-wrap 'wrap-emacs-paths
 205            (lambda* (#:key inputs outputs #:allow-other-keys)
 206              (let* ((out (assoc-ref outputs "out"))
 207                     (lisp-dirs (find-files (string-append out "/share/emacs")
 208                                            "^lisp$"
 209                                            #:directories? #t)))
 210                (for-each
 211                 (lambda (prog)
 212                   (wrap-program prog
 213                     ;; emacs-next and variants rely on uname being in PATH for
 214                     ;; Tramp.  Tramp paths can't be hardcoded, because they
 215                     ;; need to be portable.
 216                     `("PATH" suffix
 217                       ,(map (lambda (in) (string-append in "/bin"))
 218                             (list (assoc-ref inputs "gzip")
 219                                   (assoc-ref inputs "coreutils"))))
 220                     `("EMACSLOADPATH" suffix ,lisp-dirs)))
 221                 (find-files (string-append out "/bin")
 222                             ;; Matches versioned and unversioned emacs binaries.
 223                             ;; We don't patch emacsclient, because it takes its
 224                             ;; environment variables from emacs.
 225                             ;; Likewise, we don't need to patch helper binaries
 226                             ;; like etags, ctags or ebrowse.
 227                             "^emacs(-[0-9]+(\\.[0-9]+)*)?$"))
 228                #t)))
 229          (add-before 'reset-gzip-timestamps 'make-compressed-files-writable
 230            ;; The 'reset-gzip-timestamps phase will throw a permission error
 231            ;; if gzip files aren't writable then.  This phase is needed when
 232            ;; building from a git checkout.
 233            (lambda _
 234              (for-each make-file-writable
 235                        (find-files %output ".*\\.t?gz$"))
 236              #t)))))
 237     (inputs
 238      `(("gnutls" ,gnutls)
 239        ("ncurses" ,ncurses)
 240
 241        ;; Required for "core" functionality, such as dired and compression.
 242        ("coreutils" ,coreutils)
 243        ("gzip" ,gzip)
 244
 245        ;; Avoid Emacs's limited movemail substitute that retrieves POP3 email
 246        ;; only via insecure channels.  This is not needed for (modern) IMAP.
 247        ("mailutils" ,mailutils)
 248
 249        ;; TODO: Add the optional dependencies.
 250        ("libx11" ,libx11)
 251        ("gtk+" ,gtk+)
 252        ("cairo" ,cairo)
 253        ("pango" ,pango)
 254        ("harfbuzz" ,harfbuzz)
 255        ("libxft" ,libxft)
 256        ("libtiff" ,libtiff)
 257        ("giflib" ,giflib)
 258        ("libjpeg" ,libjpeg-turbo)
 259        ("acl" ,acl)
 260        ("jansson" ,jansson)
 261        ("gmp" ,gmp)
 262
 263        ;; When looking for libpng `configure' links with `-lpng -lz', so we
 264        ;; must also provide zlib as an input.
 265        ("libpng" ,libpng)
 266        ("zlib" ,zlib)
 267
 268        ("librsvg" ,librsvg)
 269        ("libxpm" ,libxpm)
 270        ("libxml2" ,libxml2)
 271        ("libice" ,libice)
 272        ("libsm" ,libsm)
 273        ("alsa-lib" ,alsa-lib)
 274        ("dbus" ,dbus)
 275
 276        ;; multilingualization support
 277        ("libotf" ,libotf)
 278        ("m17n-lib" ,m17n-lib)))
 279     (native-inputs
 280      `(("guix-emacs.el" ,(search-auxiliary-file "emacs/guix-emacs.el"))
 281        ("pkg-config" ,pkg-config)
 282        ("texinfo" ,texinfo)))
 283
 284     (native-search-paths
 285      (list (search-path-specification
 286             (variable "EMACSLOADPATH")
 287             (files '("share/emacs/site-lisp")))
 288            (search-path-specification
 289             (variable "INFOPATH")
 290             (files '("share/info")))))
 291
 292     (home-page "https://www.gnu.org/software/emacs/")
 293     (synopsis "The extensible, customizable, self-documenting text editor")
 294     (description
 295      "GNU Emacs is an extensible and highly customizable text editor.  It is
 296 based on an Emacs Lisp interpreter with extensions for text editing.  Emacs
 297 has been extended in essentially all areas of computing, giving rise to a
 298 vast array of packages supporting, e.g., email, IRC and XMPP messaging,
 299 spreadsheets, remote server editing, and much more.  Emacs includes extensive
 300 documentation on all aspects of the system, from basic editing to writing
 301 large Lisp programs.  It has full Unicode support for nearly all human
 302 languages.")
 303     (license license:gpl3+)))
 304
 305 (define-public emacs-next
 306   (let ((commit "2ea34662c20f71d35dd52a5ed996542c7386b9cb")
 307         (revision "0"))
 308     (package
 309       (inherit emacs)
 310       (name "emacs-next")
 311       (version (git-version "28.0.50" revision commit))
 312       (source
 313        (origin
 314          (inherit (package-source emacs))
 315          (method git-fetch)
 316          (uri (git-reference
 317                (url "https://git.savannah.gnu.org/git/emacs.git/")
 318                (commit commit)))
 319          (file-name (git-file-name name version))
 320          (sha256
 321           (base32
 322            "0igjm9kwiswn2dpiy2k9xikbdfc7njs07ry48fqz70anljj8y7y3"))))
 323       (native-inputs
 324        `(("autoconf" ,autoconf)
 325          ,@(package-native-inputs emacs))))))
 326
 327 (define-public emacs-next-pgtk
 328   (let ((commit "ae18c8ec4f0ef37c8c9cda473770ff47e41291e2")
 329         (revision "1"))
 330     (package
 331       (inherit emacs-next)
 332       (name "emacs-next-pgtk")
 333       (version (git-version "28.0.50" revision commit))
 334       (source
 335        (origin
 336          (method git-fetch)
 337          (uri (git-reference
 338                (url "https://git.savannah.gnu.org/git/emacs.git/")
 339                (commit commit)))
 340          (file-name (git-file-name name version))
 341          (sha256
 342           (base32
 343            "07hgfqh965zmra0rbmnf63p3lsinpv5hn5payqcrjx25pl75xnaf"))))
 344       (arguments
 345        (substitute-keyword-arguments (package-arguments emacs-next)
 346          ((#:configure-flags flags ''())
 347           `(cons* "--with-pgtk" "--with-xwidgets" ,flags))))
 348       (propagated-inputs
 349        `(("gsettings-desktop-schemas" ,gsettings-desktop-schemas)
 350          ("glib-networking" ,glib-networking)))
 351       (inputs
 352        `(("webkitgtk" ,webkitgtk)
 353          ,@(package-inputs emacs-next)))
 354       (home-page "https://github.com/masm11/emacs")
 355       (synopsis "Emacs text editor with @code{pgtk} and @code{xwidgets} support")
 356       (description "This is an unofficial Emacs fork build with a pure-GTK
 357 graphical toolkit to work natively on Wayland.  In addition to that, xwidgets
 358 also enabled and works without glitches even on X server."))))
 359
 360 (define-public emacs-minimal
 361   ;; This is the version that you should use as an input to packages that just
 362   ;; need to byte-compile .el files.
 363   (package/inherit emacs
 364     (name "emacs-minimal")
 365     (synopsis "The extensible text editor (used only for byte-compilation)")
 366     (build-system gnu-build-system)
 367     (arguments
 368      (substitute-keyword-arguments (package-arguments emacs)
 369        ((#:configure-flags flags ''())
 370         `(list "--with-gnutls=no" "--disable-build-details"))
 371        ((#:phases phases)
 372         `(modify-phases ,phases
 373            (delete 'restore-emacs-pdmp)
 374            (delete 'strip-double-wrap)))))
 375     (inputs
 376      `(("guix-emacs.el" ,(search-auxiliary-file "emacs/guix-emacs.el"))
 377        ("ncurses" ,ncurses)
 378        ("coreutils" ,coreutils)
 379        ("gzip" ,gzip)))
 380     (native-inputs
 381      `(("pkg-config" ,pkg-config)))))
 382
 383 (define-public emacs-xwidgets
 384   (package/inherit emacs
 385     (name "emacs-xwidgets")
 386     (synopsis "The extensible, customizable, self-documenting text
 387 editor (with xwidgets support)")
 388     (build-system gnu-build-system)
 389     (arguments
 390      (substitute-keyword-arguments (package-arguments emacs)
 391        ((#:configure-flags flags ''())
 392         `(cons "--with-xwidgets" ,flags))
 393        ((#:phases phases)
 394         `(modify-phases ,phases
 395            (delete 'restore-emacs-pdmp)
 396            (delete 'strip-double-wrap)))))
 397     (inputs
 398      `(("webkitgtk" ,webkitgtk)
 399        ("libxcomposite" ,libxcomposite)
 400        ,@(package-inputs emacs)))))
 401
 402 (define-public emacs-no-x
 403   (package/inherit emacs
 404     (name "emacs-no-x")
 405     (synopsis "The extensible, customizable, self-documenting text
 406 editor (console only)")
 407     (build-system gnu-build-system)
 408     (inputs (fold alist-delete
 409                   (package-inputs emacs)
 410                   '("libx11" "gtk+" "libxft" "libtiff" "giflib" "libjpeg"
 411                     "imagemagick" "libpng" "librsvg" "libxpm" "libice"
 412                     "libsm" "cairo" "pango" "harfbuzz"
 413
 414                     ;; These depend on libx11, so remove them as well.
 415                     "libotf" "m17n-lib" "dbus")))
 416     (arguments
 417      (substitute-keyword-arguments (package-arguments emacs)
 418        ((#:configure-flags flags ''())
 419         `(delete "--with-cairo" ,flags))
 420        ((#:phases phases)
 421         `(modify-phases ,phases
 422            (delete 'restore-emacs-pdmp)
 423            (delete 'strip-double-wrap)))))))
 424
 425 (define-public emacs-no-x-toolkit
 426   (package/inherit emacs
 427     (name "emacs-no-x-toolkit")
 428     (synopsis "The extensible, customizable, self-documenting text
 429 editor (without an X toolkit)" )
 430     (build-system gnu-build-system)
 431     (inputs (append `(("inotify-tools" ,inotify-tools))
 432                     (alist-delete "gtk+" (package-inputs emacs))))
 433     (arguments
 434      (substitute-keyword-arguments (package-arguments emacs)
 435        ((#:configure-flags flags ''())
 436         `(cons "--with-x-toolkit=no" ,flags))
 437        ((#:phases phases)
 438         `(modify-phases ,phases
 439            (delete 'restore-emacs-pdmp)
 440            (delete 'strip-double-wrap)))))))
 441
 442 (define-public emacs-wide-int
 443   (package/inherit emacs
 444     (name "emacs-wide-int")
 445     (synopsis "The extensible, customizable, self-documenting text
 446 editor (with wide ints)" )
 447     (arguments
 448      (substitute-keyword-arguments (package-arguments emacs)
 449        ((#:configure-flags flags)
 450         `(cons "--with-wide-int" ,flags))))))
 451
 452 (define-public guile-emacs
 453   (let ((commit "41120e0f595b16387eebfbf731fff70481de1b4b")
 454         (revision "0"))
 455     (package
 456       (inherit emacs)
 457       (name "guile-emacs")
 458       (version (git-version "0.0.0" revision commit))
 459       (source (origin
 460                 (method git-fetch)
 461                 (uri (git-reference
 462                       (url "https://git.hcoop.net/git/bpt/emacs.git")
 463                       (commit commit)))
 464                 (file-name (git-file-name name version))
 465                 (patches (search-patches "guile-emacs-fix-configure.patch"))
 466                 (sha256
 467                  (base32
 468                   "0lvcvsz0f4mawj04db35p1dvkffdqkz8pkhc0jzh9j9x2i63kcz6"))))
 469       (native-inputs
 470        `(("autoconf" ,autoconf)
 471          ("automake" ,automake)
 472          ("guile" ,guile-for-guile-emacs)
 473          ,@(package-native-inputs emacs)))
 474       (arguments
 475        (substitute-keyword-arguments `(;; Build fails if we allow parallel build.
 476                                        #:parallel-build? #f
 477                                        ;; Tests aren't passing for now.
 478                                        #:tests? #f
 479                                        ,@(package-arguments emacs))
 480          ((#:configure-flags flags ''())
 481           `(delete "--with-cairo" ,flags))
 482          ((#:phases phases)
 483           `(modify-phases ,phases
 484              (add-after 'unpack 'autogen
 485                (lambda _
 486                  (invoke "sh" "autogen.sh")))
 487              ;; Build sometimes fails: deps/dispnew.d: No such file or directory
 488              (add-before 'build 'make-deps-dir
 489                (lambda _
 490                  (invoke "mkdir" "-p" "src/deps")))
 491              (delete 'restore-emacs-pdmp)
 492              (delete 'strip-double-wrap))))))))
 493
 494 (define-public m17n-db
 495   (package
 496     (name "m17n-db")
 497     (version "1.8.0")
 498     (source
 499      (origin
 500        (method url-fetch)
 501        (uri (string-append "mirror://savannah/m17n/m17n-db-"
 502                            version ".tar.gz"))
 503        (sha256
 504         (base32
 505          "0vfw7z9i2s9np6nmx1d4dlsywm044rkaqarn7akffmb6bf1j6zv5"))))
 506     (build-system gnu-build-system)
 507     (inputs
 508      `(("gettext" ,gettext-minimal)))
 509     (arguments
 510      `(#:configure-flags
 511        (list (string-append "--with-charmaps="
 512                             (assoc-ref %build-inputs "libc")
 513                             "/share/i18n/charmaps"))))
 514     ;; With `guix lint' the home-page URI returns a small page saying
 515     ;; that your browser does not handle frames. This triggers the "URI
 516     ;; returns suspiciously small file" warning.
 517     (home-page "https://www.nongnu.org/m17n/")
 518     (synopsis "Multilingual text processing library (database)")
 519     (description "The m17n library realizes multilingualization of
 520 many aspects of applications.  The m17n library represents
 521 multilingual text as an object named M-text.  M-text is a string with
 522 attributes called text properties, and designed to substitute for
 523 string in C.  Text properties carry any information required to input,
 524 display and edit the text.
 525
 526 This package contains the library database.")
 527     (license license:lgpl2.1+)))
 528
 529 (define-public m17n-lib
 530   (package
 531     (name "m17n-lib")
 532     (version "1.8.0")
 533     (source
 534      (origin
 535        (method url-fetch)
 536        (uri (string-append "mirror://savannah/m17n/m17n-lib-"
 537                            version ".tar.gz"))
 538        (sha256
 539         (base32
 540          "0jp61y09xqj10mclpip48qlfhniw8gwy8b28cbzxy8hq8pkwmfkq"))))
 541     (build-system gnu-build-system)
 542     (inputs
 543      `(("fribidi" ,fribidi)
 544        ("gd" ,gd)
 545        ("libotf" ,libotf)
 546        ("libxft" ,libxft)
 547        ("libxml2" ,libxml2)
 548        ("m17n-db" ,m17n-db)))
 549     (arguments
 550      `(#:parallel-build? #f))
 551     ;; With `guix lint' the home-page URI returns a small page saying
 552     ;; that your browser does not handle frames. This triggers the "URI
 553     ;; returns suspiciously small file" warning.
 554     (home-page "https://www.nongnu.org/m17n/")
 555     (synopsis "Multilingual text processing library (runtime)")
 556     (description "The m17n library realizes multilingualization of
 557 many aspects of applications.  The m17n library represents
 558 multilingual text as an object named M-text.  M-text is a string with
 559 attributes called text properties, and designed to substitute for
 560 string in C.  Text properties carry any information required to input,
 561 display and edit the text.
 562
 563 This package contains the library runtime.")
 564     (license license:lgpl2.1+)))