tests/opam.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2018 Julien Lepiller <julien@lepiller.eu>
   3 ;;; Copyright © 2021 Xinglu Chen <public@yoctocell.xyz>
   4 ;;; Copyright © 2021 Sarah Morgensen <iskarian@mgsn.dev>
   5 ;;;
   6 ;;; This file is part of GNU Guix.
   7 ;;;
   8 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   9 ;;; under the terms of the GNU General Public License as published by
  10 ;;; the Free Software Foundation; either version 3 of the License, or (at
  11 ;;; your option) any later version.
  12 ;;;
  13 ;;; GNU Guix is distributed in the hope that it will be useful, but
  14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;;; GNU General Public License for more details.
  17 ;;;
  18 ;;; You should have received a copy of the GNU General Public License
  19 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 (define-module (test-opam)
  22   #:use-module (guix import opam)
  23   #:use-module (guix base32)
  24   #:use-module (gcrypt hash)
  25   #:use-module (guix tests)
  26   #:use-module ((guix build syscalls) #:select (mkdtemp!))
  27   #:use-module ((guix build utils) #:select (delete-file-recursively mkdir-p which))
  28   #:use-module ((guix utils) #:select (call-with-temporary-output-file))
  29   #:use-module (srfi srfi-1)
  30   #:use-module (srfi srfi-64)
  31   #:use-module (web uri)
  32   #:use-module (ice-9 match)
  33   #:use-module (ice-9 peg))
  34
  35 (define test-opam-file
  36 "opam-version: \"2.0\"
  37   version: \"1.0.0\"
  38 maintainer: \"Alice Doe\"
  39 authors: [
  40   \"Alice Doe\"
  41   \"John Doe\"
  42 ]
  43 homepage: \"https://example.org/\"
  44 bug-reports: \"https://example.org/bugs\"
  45 dev-repo: \"https://example.org/git\"
  46 build: [
  47   [\"ocaml\" \"pkg/pkg.ml\" \"build\" \"--pinned\" \"%{pinned}%\"]
  48 ]
  49 build-test: [
  50   [\"ocaml\" \"pkg/pkg.ml\" \"build\" \"--pinned\" \"%{pinned}%\" \"--tests\" \"true\"]
  51 ]
  52 depends: [
  53   \"alcotest\" {test & >= \"0.7.2\"}
  54   \"ocamlbuild\" {build & >= \"0.9.2\"}
  55   \"zarith\" {>= \"0.7\"}
  56 ]
  57 synopsis: \"Some example package\"
  58 description: \"\"\"
  59 This package is just an example.\"\"\"
  60 license: \"BSD-3-Clause\"
  61 url {
  62   src: \"https://example.org/foo-1.0.0.tar.gz\"
  63   checksum: \"md5=74c6e897658e820006106f45f736381f\"
  64 }")
  65
  66 (define test-source-hash
  67   "")
  68
  69 (define test-repo
  70   (mkdtemp! "/tmp/opam-repo.XXXXXX"))
  71
  72 (test-begin "opam")
  73
  74 (test-assert "opam->guix-package"
  75   (mock ((guix import utils) url-fetch
  76          (lambda (url file-name)
  77            (match url
  78              ("https://example.org/foo-1.0.0.tar.gz"
  79               (begin
  80                 (mkdir-p "foo-1.0.0")
  81                 (system* "tar" "czvf" file-name "foo-1.0.0/")
  82                 (delete-file-recursively "foo-1.0.0")
  83                 (set! test-source-hash
  84                   (call-with-input-file file-name port-sha256))))
  85              (_ (error "Unexpected URL: " url)))))
  86         (let ((my-package (string-append test-repo
  87                                          "/packages/foo/foo.1.0.0")))
  88           (mkdir-p my-package)
  89           (with-output-to-file (string-append my-package "/opam")
  90             (lambda _
  91               (format #t "~a" test-opam-file))))
  92         (match (opam->guix-package "foo" #:repo (list test-repo))
  93           (('package
  94              ('name "ocaml-foo")
  95              ('version "1.0.0")
  96              ('source ('origin
  97                         ('method 'url-fetch)
  98                         ('uri "https://example.org/foo-1.0.0.tar.gz")
  99                         ('sha256
 100                          ('base32
 101                           (? string? hash)))))
 102              ('build-system 'ocaml-build-system)
 103              ('propagated-inputs ('list 'ocaml-zarith))
 104              ('native-inputs ('list 'ocaml-alcotest 'ocamlbuild))
 105              ('home-page "https://example.org/")
 106              ('synopsis "Some example package")
 107              ('description "This package is just an example.")
 108              ('license 'license:bsd-3))
 109            (string=? (bytevector->nix-base32-string
 110                       test-source-hash)
 111                      hash))
 112           (x
 113            (pk 'fail x #f)))))
 114
 115 ;; Test the opam file parser
 116 ;; We fold over some test cases. Each case is a pair of the string to parse and the
 117 ;; expected result.
 118 (define (test-opam-syntax name pattern test-cases)
 119   (test-assert name
 120     (fold (lambda (test acc)
 121             (display test) (newline)
 122             (match test
 123               ((str . expected)
 124                (and acc
 125                     (let ((result (peg:tree (match-pattern pattern str))))
 126                       (if (equal? result expected)
 127                           #t
 128                           (pk 'fail (list str result expected) #f)))))))
 129           #t test-cases)))
 130
 131 (test-opam-syntax
 132   "parse-strings" string-pat
 133   '(("" . #f)
 134     ("\"hello\"" . (string-pat "hello"))
 135     ("\"hello world\"" . (string-pat "hello world"))
 136     ("\"The dreaded \\\"é\\\"\"" . (string-pat "The dreaded \"é\""))
 137     ("\"Have some \\\\\\\\ :)\"" . (string-pat "Have some \\\\ :)"))
 138     ("\"今日は\"" . (string-pat "今日は"))))
 139
 140 (test-opam-syntax
 141   "parse-multiline-strings" multiline-string
 142   '(("" . #f)
 143     ("\"\"\"hello\"\"\"" . (multiline-string "hello"))
 144     ("\"\"\"hello \"world\"!\"\"\"" . (multiline-string "hello \"world\"!"))
 145     ("\"\"\"hello \"\"world\"\"!\"\"\"" . (multiline-string "hello \"\"world\"\"!"))))
 146
 147 (test-opam-syntax
 148   "parse-lists" list-pat
 149   '(("" . #f)
 150     ("[]" . list-pat)
 151     ("[make]" . (list-pat (var "make")))
 152     ("[\"make\"]" . (list-pat (string-pat "make")))
 153     ("[\n  a\n  b\n  c]" . (list-pat (var "a") (var "b") (var "c")))
 154     ("[a   b     \"c\"]" . (list-pat (var "a") (var "b") (string-pat "c")))
 155     ;; complex lists
 156     ("[(a & b)]" . (list-pat (choice-pat (group-pat (var "a") (var "b")))))
 157     ("[(a | b & c)]" . (list-pat (choice-pat (var "a") (group-pat (var "b") (var "c")))))
 158     ("[a (b | c) d]" . (list-pat (var "a") (choice-pat (var "b") (var "c")) (var "d")))))
 159
 160 (test-opam-syntax
 161   "parse-dicts" dict
 162   '(("" . #f)
 163     ("{}" . dict)
 164     ("{a: \"b\"}" . (dict (record "a" (string-pat "b"))))
 165     ("{a: \"b\"\nc: \"d\"}" . (dict (record "a" (string-pat "b")) (record "c" (string-pat "d"))))))
 166
 167 (test-opam-syntax
 168   "parse-conditions" condition
 169   '(("" . #f)
 170     ("{}" . #f)
 171     ("{build}" . (condition-var "build"))
 172     ("{>= \"0.2.0\"}" . (condition-greater-or-equal
 173                           (condition-string "0.2.0")))
 174     ("{>= \"0.2.0\" & test}" . (condition-and
 175                                  (condition-greater-or-equal
 176                                    (condition-string "0.2.0"))
 177                                  (condition-var "test")))
 178     ("{>= \"0.2.0\" | build}" . (condition-or
 179                                  (condition-greater-or-equal
 180                                    (condition-string "0.2.0"))
 181                                  (condition-var "build")))
 182     ("{ = \"1.0+beta19\" }" . (condition-eq
 183                                 (condition-string "1.0+beta19")))))
 184
 185 (test-opam-syntax
 186   "parse-comment" list-pat
 187   '(("" . #f)
 188     ("[#comment\n]" . list-pat)))
 189
 190 (test-end "opam")