gnu/packages/gcc.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012, 2013, 2014, 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2014, 2015 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2014, 2015, 2016, 2017 Ricardo Wurmus <rekado@elephly.net>
   5 ;;; Copyright © 2015 Andreas Enge <andreas@enge.fr>
   6 ;;; Copyright © 2015, 2016 Efraim Flashner <efraim@flashner.co.il>
   7 ;;; Copyright © 2016 Carlos Sánchez de La Lama <csanchezdll@gmail.com>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  12 ;;; under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation; either version 3 of the License, or (at
  14 ;;; your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful, but
  17 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu packages gcc)
  25   #:use-module ((guix licenses)
  26                 #:select (gpl3+ gpl2+ lgpl2.1+ lgpl2.0+ fdl1.3+))
  27   #:use-module (gnu packages)
  28   #:use-module (gnu packages bootstrap)
  29   #:use-module (gnu packages compression)
  30   #:use-module (gnu packages multiprecision)
  31   #:use-module (gnu packages texinfo)
  32   #:use-module (gnu packages dejagnu)
  33   #:use-module (gnu packages documentation)
  34   #:use-module (gnu packages xml)
  35   #:use-module (gnu packages docbook)
  36   #:use-module (gnu packages graphviz)
  37   #:use-module (gnu packages elf)
  38   #:use-module (gnu packages perl)
  39   #:use-module (guix packages)
  40   #:use-module (guix download)
  41   #:use-module (guix build-system gnu)
  42   #:use-module (guix build-system trivial)
  43   #:use-module (guix utils)
  44   #:use-module (srfi srfi-1)
  45   #:use-module (ice-9 regex))
  46
  47 (define %gcc-infrastructure
  48   ;; Base URL for GCC's infrastructure.
  49   "mirror://gcc/infrastructure/")
  50
  51 (define (gcc-configure-flags-for-triplet target)
  52   "Return a list of additional GCC `configure' flags for TARGET, a GNU triplet.
  53
  54 The purpose of this procedure is to translate extended GNU triplets---e.g.,
  55 where the OS part is overloaded to denote a specific ABI---into GCC
  56 `configure' options.  We take extended GNU triplets that glibc recognizes."
  57   (cond ((string-match "^mips64el.*gnuabin?64$" target)
  58          ;; Triplets recognized by glibc as denoting the N64 ABI; see
  59          ;; ports/sysdeps/mips/preconfigure.
  60          '("--with-abi=64"))
  61
  62         ((string-match "^arm.*-gnueabihf$" target)
  63          '("--with-arch=armv7-a"
  64            "--with-float=hard"
  65            "--with-mode=thumb"
  66            "--with-fpu=neon"))
  67
  68         (else
  69          ;; TODO: Add `arm.*-gnueabi', etc.
  70          '())))
  71
  72 (define-public gcc-4.7
  73   (let* ((stripped? #t)      ;whether to strip the compiler, not the libraries
  74          (maybe-target-tools
  75           (lambda ()
  76             ;; Return the `_FOR_TARGET' variables that are needed when
  77             ;; cross-compiling GCC.
  78             (let ((target (%current-target-system)))
  79               (if target
  80                   (map (lambda (var tool)
  81                          (string-append (string-append var "_FOR_TARGET")
  82                                         "=" target "-" tool))
  83                        '("CC"  "CXX" "LD" "AR" "NM" "RANLIB" "STRIP")
  84                        '("gcc" "g++" "ld" "ar" "nm" "ranlib" "strip"))
  85                   '()))))
  86          (libdir
  87           (let ((base '(or (assoc-ref outputs "lib")
  88                            (assoc-ref outputs "out"))))
  89             (lambda ()
  90               ;; Return the directory that contains lib/libgcc_s.so et al.
  91               (if (%current-target-system)
  92                   `(string-append ,base "/" ,(%current-target-system))
  93                   base))))
  94          (configure-flags
  95           (lambda ()
  96             ;; This is terrible.  Since we have two levels of quasiquotation,
  97             ;; we have to do this convoluted thing just so we can insert the
  98             ;; contents of (maybe-target-tools).
  99             (list 'quasiquote
 100                   (append
 101                    '("--enable-plugin"
 102                      "--enable-languages=c,c++"
 103                      "--disable-multilib"
 104                      "--with-system-zlib"
 105
 106                      ;; No pre-compiled libstdc++ headers, to save space.
 107                      "--disable-libstdcxx-pch"
 108
 109                      "--with-local-prefix=/no-gcc-local-prefix"
 110
 111                      ;; With a separate "lib" output, the build system
 112                      ;; incorrectly guesses GPLUSPLUS_INCLUDE_DIR, so force
 113                      ;; it.  (Don't use a versioned sub-directory, that's
 114                      ;; unnecessary.)
 115                      ,(string-append "--with-gxx-include-dir="
 116                                      (assoc-ref %outputs "out")
 117                                      "/include/c++")
 118
 119                      ,(let ((libc (assoc-ref %build-inputs "libc")))
 120                         (if libc
 121                             (string-append "--with-native-system-header-dir=" libc
 122                                            "/include")
 123                             "--without-headers")))
 124
 125                    ;; Pass the right options for the target triplet.
 126                    (let ((triplet
 127                           (or (%current-target-system)
 128                               (nix-system->gnu-triplet (%current-system)))))
 129                      (gcc-configure-flags-for-triplet triplet))
 130
 131                    (maybe-target-tools))))))
 132     (package
 133       (name "gcc")
 134       (version "4.7.4")
 135       (source (origin
 136                (method url-fetch)
 137                (uri (string-append "mirror://gnu/gcc/gcc-"
 138                                    version "/gcc-" version ".tar.bz2"))
 139                (sha256
 140                 (base32
 141                  "10k2k71kxgay283ylbbhhs51cl55zn2q38vj5pk4k950qdnirrlj"))))
 142       (build-system gnu-build-system)
 143
 144       ;; Separate out the run-time support libraries because all the
 145       ;; dynamic-linked objects depend on it.
 146       (outputs '("out"                    ;commands, etc. (60+ MiB)
 147                  "lib"                    ;libgcc_s, libgomp, etc. (15+ MiB)
 148                  "debug"))                ;debug symbols of run-time libraries
 149
 150       (inputs `(("gmp" ,gmp)
 151                 ("mpfr" ,mpfr)
 152                 ("mpc" ,mpc)
 153                 ("isl" ,isl)
 154                 ("cloog" ,cloog)
 155                 ("libelf" ,libelf)
 156                 ("zlib" ,zlib)))
 157
 158       ;; GCC < 5 is one of the few packages that doesn't ship .info files.
 159       ;; Newer texinfos fail to build the manual, so we use an older one.
 160       (native-inputs `(("texinfo" ,texinfo-5)))
 161
 162       (arguments
 163        `(#:out-of-source? #t
 164          #:configure-flags ,(configure-flags)
 165          #:make-flags
 166          ;; None of the flags below are needed when doing a Canadian cross.
 167          ;; TODO: Simplify this.
 168          ,(if (%current-target-system)
 169               (if stripped?
 170                   ''("CFLAGS=-g0 -O2")
 171                   ''())
 172               `(let* ((libc        (assoc-ref %build-inputs "libc"))
 173                       (libc-native (or (assoc-ref %build-inputs "libc-native")
 174                                        libc)))
 175                  `(,@(if libc
 176                          (list (string-append "LDFLAGS_FOR_TARGET="
 177                                               "-B" libc "/lib "
 178                                               "-Wl,-dynamic-linker "
 179                                               "-Wl," libc
 180                                               ,(glibc-dynamic-linker)))
 181                          '())
 182
 183                    ;; Native programs like 'genhooks' also need that right.
 184                    ,(string-append "LDFLAGS="
 185                                    "-Wl,-rpath=" libc-native "/lib "
 186                                    "-Wl,-dynamic-linker "
 187                                    "-Wl," libc-native ,(glibc-dynamic-linker))
 188                    ,(string-append "BOOT_CFLAGS=-O2 "
 189                                    ,(if stripped? "-g0" "-g")))))
 190
 191          #:tests? #f
 192
 193          #:phases
 194          (alist-cons-before
 195           'configure 'pre-configure
 196           (lambda* (#:key inputs outputs #:allow-other-keys)
 197             (let ((libdir ,(libdir))
 198                   (libc   (assoc-ref inputs "libc")))
 199               (when libc
 200                 ;; The following is not performed for `--without-headers'
 201                 ;; cross-compiler builds.
 202
 203                 ;; Join multi-line definitions of GLIBC_DYNAMIC_LINKER* into a
 204                 ;; single line, to allow the next step to work properly.
 205                 (for-each
 206                  (lambda (x)
 207                    (substitute* (find-files "gcc/config"
 208                                             "^(linux|gnu|sysv4)(64|-elf|-eabi)?\\.h$")
 209                      (("(#define (GLIBC|GNU_USER)_DYNAMIC_LINKER.*)\\\\\n$" _ line)
 210                       line)))
 211                  '(1 2 3))
 212
 213                 ;; Fix the dynamic linker's file name.
 214                 (substitute* (find-files "gcc/config"
 215                                          "^(linux|gnu|sysv4)(64|-elf|-eabi)?\\.h$")
 216                   (("#define (GLIBC|GNU_USER)_DYNAMIC_LINKER([^ \t]*).*$"
 217                     _ gnu-user suffix)
 218                    (format #f "#define ~a_DYNAMIC_LINKER~a \"~a\"~%"
 219                            gnu-user suffix
 220                            (string-append libc ,(glibc-dynamic-linker)))))
 221
 222                 ;; Tell where to find libstdc++, libc, and `?crt*.o', except
 223                 ;; `crt{begin,end}.o', which come with GCC.
 224                 (substitute* (find-files "gcc/config"
 225                                          "^gnu-user.*\\.h$")
 226                   (("#define GNU_USER_TARGET_LIB_SPEC (.*)$" _ suffix)
 227                    ;; Help libgcc_s.so be found (see also below.)  Always use
 228                    ;; '-lgcc_s' so that libgcc_s.so is always found by those
 229                    ;; programs that use 'pthread_cancel' (glibc dlopens
 230                    ;; libgcc_s.so when pthread_cancel support is needed, but
 231                    ;; having it in the application's RUNPATH isn't enough; see
 232                    ;; <http://sourceware.org/ml/libc-help/2013-11/msg00023.html>.)
 233                    ;;
 234                    ;; NOTE: The '-lgcc_s' added below needs to be removed in a
 235                    ;; later phase of %gcc-static.  If you change the string
 236                    ;; below, make sure to update the relevant code in
 237                    ;; %gcc-static package as needed.
 238                    (format #f "#define GNU_USER_TARGET_LIB_SPEC \
 239 \"-L~a/lib %{!static:-rpath=~a/lib %{!static-libgcc:-rpath=~a/lib -lgcc_s}} \" ~a"
 240                            libc libc libdir suffix))
 241                   (("#define GNU_USER_TARGET_STARTFILE_SPEC.*$" line)
 242                    (format #f "#define STANDARD_STARTFILE_PREFIX_1 \"~a/lib\"
 243 #define STANDARD_STARTFILE_PREFIX_2 \"\"
 244 ~a"
 245                            libc line)))
 246
 247               ;; The rs6000 (a.k.a. powerpc) config in GCC does not use
 248               ;; GNU_USER_* defines.  Do the above for this case.
 249               (substitute*
 250                   "gcc/config/rs6000/sysv4.h"
 251                 (("#define LIB_LINUX_SPEC (.*)$" _ suffix)
 252                  (format #f "#define LIB_LINUX_SPEC \
 253 \"-L~a/lib %{!static:-rpath=~a/lib %{!static-libgcc:-rpath=~a/lib -lgcc_s}} \" ~a"
 254                          libc libc libdir suffix))
 255                 (("#define      STARTFILE_LINUX_SPEC.*$" line)
 256                  (format #f "#define STANDARD_STARTFILE_PREFIX_1 \"~a/lib\"
 257 #define STANDARD_STARTFILE_PREFIX_2 \"\"
 258 ~a"
 259                          libc line))))
 260
 261               ;; Don't retain a dependency on the build-time sed.
 262               (substitute* "fixincludes/fixincl.x"
 263                 (("static char const sed_cmd_z\\[\\] =.*;")
 264                  "static char const sed_cmd_z[] = \"sed\";"))
 265
 266               ;; Aarch64 support didn't land in GCC until the 4.8 series.
 267               (when (file-exists? "gcc/config/aarch64")
 268                 ;; Force Aarch64 libdir to be /lib and not /lib64
 269                 (substitute* "gcc/config/aarch64/t-aarch64-linux"
 270                   (("lib64") "lib")))
 271
 272               (when (file-exists? "libbacktrace")
 273                 ;; GCC 4.8+ comes with libbacktrace.  By default it builds
 274                 ;; with -Werror, which fails with a -Wcast-qual error in glibc
 275                 ;; 2.21's stdlib-bsearch.h.  Remove -Werror.
 276                 (substitute* "libbacktrace/configure"
 277                   (("WARN_FLAGS=(.*)-Werror" _ flags)
 278                    (string-append "WARN_FLAGS=" flags)))
 279
 280                 (when (file-exists? "libsanitizer/libbacktrace")
 281                   ;; Same in libsanitizer's bundled copy (!) found in 4.9+.
 282                   (substitute* "libsanitizer/libbacktrace/Makefile.in"
 283                     (("-Werror")
 284                      ""))))
 285
 286               ;; Add a RUNPATH to libstdc++.so so that it finds libgcc_s.
 287               ;; See <https://gcc.gnu.org/bugzilla/show_bug.cgi?id=32354>
 288               ;; and <http://bugs.gnu.org/20358>.
 289               (substitute* "libstdc++-v3/src/Makefile.in"
 290                 (("^OPT_LDFLAGS = ")
 291                  "OPT_LDFLAGS = -Wl,-rpath=$(libdir) "))
 292
 293               ;; Move libstdc++*-gdb.py to the "lib" output to avoid a
 294               ;; circularity between "out" and "lib".  (Note:
 295               ;; --with-python-dir is useless because it imposes $(prefix) as
 296               ;; the parent directory.)
 297               (substitute* "libstdc++-v3/python/Makefile.in"
 298                 (("pythondir = .*$")
 299                  (string-append "pythondir = " libdir "/share"
 300                                 "/gcc-$(gcc_version)/python\n")))
 301
 302               ;; Avoid another circularity between the outputs: this #define
 303               ;; ends up in auto-host.h in the "lib" output, referring to
 304               ;; "out".  (This variable is used to augment cpp's search path,
 305               ;; but there's nothing useful to look for here.)
 306               (substitute* "gcc/config.in"
 307                 (("PREFIX_INCLUDE_DIR")
 308                  "PREFIX_INCLUDE_DIR_isnt_necessary_here"))))
 309
 310           (alist-cons-after
 311            'configure 'post-configure
 312            (lambda _
 313              ;; Don't store configure flags, to avoid retaining references to
 314              ;; build-time dependencies---e.g., `--with-ppl=/gnu/store/xxx'.
 315              (substitute* "Makefile"
 316                (("^TOPLEVEL_CONFIGURE_ARGUMENTS=(.*)$" _ rest)
 317                 "TOPLEVEL_CONFIGURE_ARGUMENTS=\n")))
 318            %standard-phases))))
 319
 320       (native-search-paths
 321        ;; Use the language-specific variables rather than 'CPATH' because they
 322        ;; are equivalent to '-isystem' whereas 'CPATH' is equivalent to '-I'.
 323        ;; The intent is to allow headers that are in the search path to be
 324        ;; treated as "system headers" (headers exempt from warnings) just like
 325        ;; the typical /usr/include headers on an FHS system.
 326        (list (search-path-specification
 327               (variable "C_INCLUDE_PATH")
 328               (files '("include")))
 329              (search-path-specification
 330               (variable "CPLUS_INCLUDE_PATH")
 331               (files '("include")))
 332              (search-path-specification
 333               (variable "LIBRARY_PATH")
 334               (files '("lib" "lib64")))))
 335
 336       (properties `((gcc-libc . ,(assoc-ref inputs "libc"))))
 337       (synopsis "GNU Compiler Collection")
 338       (description
 339        "GCC is the GNU Compiler Collection.  It provides compiler front-ends
 340 for several languages, including C, C++, Objective-C, Fortran, Java, Ada, and
 341 Go.  It also includes runtime support libraries for these languages.")
 342       (license gpl3+)
 343       (home-page "https://gcc.gnu.org/"))))
 344
 345 (define-public gcc-4.8
 346   (package (inherit gcc-4.7)
 347     (version "4.8.5")
 348     (source (origin
 349               (method url-fetch)
 350               (uri (string-append "mirror://gnu/gcc/gcc-"
 351                                   version "/gcc-" version ".tar.bz2"))
 352               (sha256
 353                (base32
 354                 "08yggr18v373a1ihj0rg2vd6psnic42b518xcgp3r9k81xz1xyr2"))
 355               (patches (search-patches "gcc-arm-link-spec-fix.patch"))))))
 356
 357 (define-public gcc-4.9
 358   (package (inherit gcc-4.7)
 359     (version "4.9.4")
 360     (source (origin
 361               (method url-fetch)
 362               (uri (string-append "mirror://gnu/gcc/gcc-"
 363                                   version "/gcc-" version ".tar.bz2"))
 364               (sha256
 365                (base32
 366                 "14l06m7nvcvb0igkbip58x59w3nq6315k6jcz3wr9ch1rn9d44bc"))
 367               (patches (search-patches "gcc-arm-bug-71399.patch"
 368                                        "gcc-libvtv-runpath.patch"))))
 369     (native-inputs `(("texinfo" ,texinfo)))))
 370
 371 (define-public gcc-5
 372   ;; Note: GCC >= 5 ships with .info files but 'make install' fails to install
 373   ;; them in a VPATH build.
 374   (package (inherit gcc-4.9)
 375     (version "5.4.0")
 376     (source (origin
 377               (method url-fetch)
 378               (uri (string-append "mirror://gnu/gcc/gcc-"
 379                                   version "/gcc-" version ".tar.bz2"))
 380               (sha256
 381                (base32
 382                 "0fihlcy5hnksdxk0sn6bvgnyq8gfrgs8m794b1jxwd1dxinzg3b0"))
 383               (patches (search-patches "gcc-arm-bug-71399.patch"
 384                                        "gcc-strmov-store-file-names.patch"
 385                                        "gcc-5.0-libvtv-runpath.patch"
 386                                        "gcc-5-source-date-epoch-1.patch"
 387                                        "gcc-5-source-date-epoch-2.patch"))))))
 388
 389 (define-public gcc-6
 390   (package
 391     (inherit gcc-5)
 392     (version "6.3.0")
 393     (source (origin
 394               (method url-fetch)
 395               (uri (string-append "mirror://gnu/gcc/gcc-"
 396                                   version "/gcc-" version ".tar.bz2"))
 397               (sha256
 398                (base32
 399                 "17xjz30jb65hcf714vn9gcxvrrji8j20xm7n33qg1ywhyzryfsph"))
 400               (patches (search-patches "gcc-strmov-store-file-names.patch"
 401                                        "gcc-5.0-libvtv-runpath.patch"))))))
 402 (define-public gcc-7
 403   (package
 404     (inherit gcc-6)
 405     (version "7.1.0")
 406     (source (origin
 407               (method url-fetch)
 408               (uri (string-append "mirror://gnu/gcc/gcc-"
 409                                   version "/gcc-" version ".tar.bz2"))
 410               (sha256
 411                (base32
 412                 "05xwps0ci7wgxh50askpa2r9p8518qxdgh6ad7pnyk7n6p13d0ca"))
 413               (patches (search-patches "gcc-strmov-store-file-names.patch"
 414                                        "gcc-5.0-libvtv-runpath.patch"))))))
 415
 416 ;; Note: When changing the default gcc version, update
 417 ;;       the gcc-toolchain-* definitions and the gfortran definition
 418 ;;       accordingly.
 419 (define-public gcc gcc-5)
 420
 421 (define-public (make-libstdc++ gcc)
 422   "Return a libstdc++ package based on GCC.  The primary use case is when
 423 using compilers other than GCC."
 424   (package
 425     (inherit gcc)
 426     (name "libstdc++")
 427     (arguments
 428      `(#:out-of-source? #t
 429        #:phases (alist-cons-before
 430                  'configure 'chdir
 431                  (lambda _
 432                    (chdir "libstdc++-v3"))
 433                  %standard-phases)
 434        #:configure-flags `("--disable-libstdcxx-pch"
 435                            ,(string-append "--with-gxx-include-dir="
 436                                            (assoc-ref %outputs "out")
 437                                            "/include"))))
 438     (outputs '("out" "debug"))
 439     (inputs '())
 440     (native-inputs '())
 441     (propagated-inputs '())
 442     (synopsis "GNU C++ standard library")))
 443
 444 (define-public libstdc++-4.9
 445   (make-libstdc++ gcc-4.9))
 446
 447 (define (make-libiberty gcc)
 448   "Return a libiberty package based on GCC."
 449   (package
 450     (inherit gcc)
 451     (name "libiberty")
 452     (arguments
 453      `(#:out-of-source? #t
 454        #:phases
 455        (modify-phases %standard-phases
 456          (add-before 'configure 'chdir
 457                      (lambda _
 458                        (chdir "libiberty")
 459                        #t))
 460          (replace
 461           'install
 462           (lambda* (#:key outputs #:allow-other-keys)
 463             (let* ((out     (assoc-ref outputs "out"))
 464                    (lib     (string-append out "/lib/"))
 465                    (include (string-append out "/include/")))
 466               (mkdir-p lib)
 467               (mkdir-p include)
 468               (copy-file "libiberty.a"
 469                          (string-append lib "libiberty.a"))
 470               (copy-file "../include/libiberty.h"
 471                          (string-append include "libiberty.h"))
 472               #t))))))
 473     (inputs '())
 474     (outputs '("out"))
 475     (native-inputs '())
 476     (propagated-inputs '())
 477     (synopsis "Collection of subroutines used by various GNU programs")))
 478
 479 (define-public libiberty
 480   (make-libiberty gcc))
 481
 482 (define* (custom-gcc gcc name languages
 483                      #:optional
 484                      (search-paths (package-native-search-paths gcc))
 485                      #:key (separate-lib-output? #t))
 486   "Return a custom version of GCC that supports LANGUAGES.  Use SEARCH-PATHS
 487 as the 'native-search-paths' field."
 488   (package (inherit gcc)
 489     (name name)
 490     (outputs (if separate-lib-output?
 491                  (package-outputs gcc)
 492                  (delete "lib" (package-outputs gcc))))
 493     (native-search-paths search-paths)
 494     (arguments
 495      (substitute-keyword-arguments `(#:modules ((guix build gnu-build-system)
 496                                                 (guix build utils)
 497                                                 (ice-9 regex)
 498                                                 (srfi srfi-1)
 499                                                 (srfi srfi-26))
 500                                                ,@(package-arguments gcc))
 501        ((#:configure-flags flags)
 502         `(cons (string-append "--enable-languages="
 503                               ,(string-join languages ","))
 504                (remove (cut string-match "--enable-languages.*" <>)
 505                        ,flags)))
 506        ((#:phases phases)
 507         `(modify-phases ,phases
 508            (add-after 'install 'remove-broken-or-conflicting-files
 509              (lambda* (#:key outputs #:allow-other-keys)
 510                (for-each delete-file
 511                          (find-files (string-append (assoc-ref outputs "out") "/bin")
 512                                      ".*(c\\+\\+|cpp|g\\+\\+|gcov|gcc.*)"))
 513                #t))))))))
 514
 515 (define %generic-search-paths
 516   ;; This is the language-neutral search path for GCC.  Entries in $CPATH are
 517   ;; not considered "system headers", which means GCC can raise warnings for
 518   ;; issues in those headers.  'CPATH' is the only one that works for
 519   ;; front-ends not in the C family.
 520   (list (search-path-specification
 521          (variable "CPATH")
 522          (files '("include")))
 523         (search-path-specification
 524          (variable "LIBRARY_PATH")
 525          (files '("lib" "lib64")))))
 526
 527 (define-public gfortran-4.8
 528   (custom-gcc gcc-4.8 "gfortran" '("fortran")
 529               %generic-search-paths))
 530
 531 (define-public gfortran-4.9
 532   (custom-gcc gcc-4.9 "gfortran" '("fortran")
 533               %generic-search-paths))
 534
 535 (define-public gfortran-5
 536   (custom-gcc gcc-5 "gfortran" '("fortran")
 537               %generic-search-paths))
 538
 539 (define-public gfortran-6
 540   (custom-gcc gcc-6 "gfortran" '("fortran")
 541               %generic-search-paths))
 542
 543 (define-public gfortran-7
 544   (custom-gcc gcc-7 "gfortran" '("fortran")
 545               %generic-search-paths))
 546
 547 (define-public gfortran
 548   ;; Note: Update this when GCC changes!  We cannot use
 549   ;; (custom-gcc gcc "fortran" …) because that would lead to a package object
 550   ;; that is not 'eq?' with GFORTRAN-5, and thus 'fold-packages' would
 551   ;; report two gfortran@5 that are in fact identical.
 552   gfortran-5)
 553
 554 (define-public gccgo-4.9
 555   (custom-gcc gcc-4.9 "gccgo" '("go")
 556               %generic-search-paths
 557               ;; Suppress the separate "lib" output, because otherwise the
 558               ;; "lib" and "out" outputs would refer to each other, creating
 559               ;; a cyclic dependency.  <http://debbugs.gnu.org/18101>
 560               #:separate-lib-output? #f))
 561
 562 (define-public gcc-objc-4.8
 563   (custom-gcc gcc-4.8 "gcc-objc" '("objc")
 564               (list (search-path-specification
 565                      (variable "OBJC_INCLUDE_PATH")
 566                      (files '("include")))
 567                     (search-path-specification
 568                      (variable "LIBRARY_PATH")
 569                      (files '("lib" "lib64"))))))
 570
 571 (define-public gcc-objc-4.9
 572   (custom-gcc gcc-4.9 "gcc-objc" '("objc")
 573               (list (search-path-specification
 574                      (variable "OBJC_INCLUDE_PATH")
 575                      (files '("include")))
 576                     (search-path-specification
 577                      (variable "LIBRARY_PATH")
 578                      (files '("lib" "lib64"))))))
 579
 580 (define-public gcc-objc gcc-objc-4.9)
 581
 582 (define-public gcc-objc++-4.8
 583   (custom-gcc gcc-4.8 "gcc-objc++" '("obj-c++")
 584               (list (search-path-specification
 585                      (variable "OBJCPLUS_INCLUDE_PATH")
 586                      (files '("include")))
 587                     (search-path-specification
 588                      (variable "LIBRARY_PATH")
 589                      (files '("lib" "lib64"))))))
 590
 591 (define-public gcc-objc++-4.9
 592   (custom-gcc gcc-4.9 "gcc-objc++" '("obj-c++")
 593               (list (search-path-specification
 594                      (variable "OBJCPLUS_INCLUDE_PATH")
 595                      (files '("include")))
 596                     (search-path-specification
 597                      (variable "LIBRARY_PATH")
 598                      (files '("lib" "lib64"))))))
 599
 600 (define-public gcc-objc++ gcc-objc++-4.9)
 601
 602 (define (make-libstdc++-doc gcc)
 603   "Return a package with the libstdc++ documentation for GCC."
 604   (package
 605     (inherit gcc)
 606     (name "libstdc++-doc")
 607     (version (package-version gcc))
 608     (synopsis "GNU libstdc++ documentation")
 609     (outputs '("out"))
 610     (native-inputs `(("doxygen" ,doxygen)
 611                      ("texinfo" ,texinfo)
 612                      ("libxml2" ,libxml2)
 613                      ("libxslt" ,libxslt)
 614                      ("docbook-xml" ,docbook-xml)
 615                      ("docbook-xsl" ,docbook-xsl)
 616                      ("graphviz" ,graphviz))) ;for 'dot', invoked by 'doxygen'
 617     (inputs '())
 618     (propagated-inputs '())
 619     (arguments
 620      '(#:out-of-source? #t
 621        #:tests? #f                                ;it's just documentation
 622        #:phases (modify-phases %standard-phases
 623                   (add-before 'configure 'chdir
 624                               (lambda _
 625                                 (chdir "libstdc++-v3")))
 626                   (add-before 'configure 'set-xsl-directory
 627                               (lambda* (#:key inputs #:allow-other-keys)
 628                                 (let ((docbook (assoc-ref inputs "docbook-xsl")))
 629                                   (substitute* (find-files "doc"
 630                                                            "^Makefile\\.in$")
 631                                     (("@XSL_STYLE_DIR@")
 632                                      (string-append
 633                                       docbook "/xml/xsl/"
 634                                       (strip-store-file-name docbook)))))))
 635                   (replace 'build
 636                            (lambda _
 637                              ;; XXX: There's also a 'doc-info' target, but it
 638                              ;; relies on docbook2X, which itself relies on
 639                              ;; DocBook 4.1.2, which is not really usable
 640                              ;; (lacks a catalog.xml.)
 641                              (zero? (system* "make"
 642                                              "doc-html"
 643                                              "doc-man"))))
 644                   (replace 'install
 645                            (lambda* (#:key outputs #:allow-other-keys)
 646                              (let ((out (assoc-ref outputs "out")))
 647                                (zero? (system* "make"
 648                                                "doc-install-html"
 649                                                "doc-install-man"))))))))))
 650
 651 (define-public libstdc++-doc-4.9
 652   (make-libstdc++-doc gcc-4.9))
 653
 654 (define-public libstdc++-doc-5
 655   (make-libstdc++-doc gcc-5))
 656
 657 (define-public isl
 658   (package
 659     (name "isl")
 660     (version "0.11.1")
 661     (source (origin
 662              (method url-fetch)
 663              (uri (list (string-append
 664                          "http://isl.gforge.inria.fr/isl-"
 665                          version
 666                          ".tar.bz2")
 667                         (string-append %gcc-infrastructure
 668                                        name "-" version ".tar.gz")))
 669              (sha256
 670               (base32
 671                "13d9cqa5rzhbjq0xf0b2dyxag7pqa72xj9dhsa03m8ccr1a4npq9"))
 672              (patches (search-patches "isl-0.11.1-aarch64-support.patch"))))
 673     (build-system gnu-build-system)
 674     (inputs `(("gmp" ,gmp)))
 675     (home-page "http://isl.gforge.inria.fr/")
 676     (synopsis
 677      "Manipulating sets and relations of integer points \
 678 bounded by linear constraints")
 679     (description
 680      "isl is a library for manipulating sets and relations of integer points
 681 bounded by linear constraints.  Supported operations on sets include
 682 intersection, union, set difference, emptiness check, convex hull, (integer)
 683 affine hull, integer projection, computing the lexicographic minimum using
 684 parametric integer programming, coalescing and parametric vertex
 685 enumeration.  It also includes an ILP solver based on generalized basis
 686 reduction, transitive closures on maps (which may encode infinite graphs),
 687 dependence analysis and bounds on piecewise step-polynomials.")
 688     (license lgpl2.1+)))
 689
 690 (define-public cloog
 691   (package
 692     (name "cloog")
 693     (version "0.18.0")
 694     (source
 695      (origin
 696       (method url-fetch)
 697       (uri (list (string-append
 698                   "http://www.bastoul.net/cloog/pages/download/count.php3?url=cloog-"
 699                   version
 700                   ".tar.gz")
 701                  (string-append %gcc-infrastructure
 702                                 name "-" version ".tar.gz")))
 703       (sha256
 704        (base32
 705         "0a12rwfwp22zd0nlld0xyql11cj390rrq1prw35yjsw8wzfshjhw"))
 706       (file-name (string-append name "-" version ".tar.gz"))))
 707     (build-system gnu-build-system)
 708     (inputs `(("gmp" ,gmp)
 709               ("isl" ,isl)))
 710     (arguments '(#:configure-flags '("--with-isl=system")))
 711     (home-page "http://www.cloog.org/")
 712     (synopsis "Library to generate code for scanning Z-polyhedra")
 713     (description
 714      "CLooG is a free software library to generate code for scanning
 715 Z-polyhedra.  That is, it finds a code (e.g., in C, FORTRAN...) that
 716 reaches each integral point of one or more parameterized polyhedra.
 717 CLooG has been originally written to solve the code generation problem
 718 for optimizing compilers based on the polytope model.  Nevertheless it
 719 is used now in various area e.g., to build control automata for
 720 high-level synthesis or to find the best polynomial approximation of a
 721 function.  CLooG may help in any situation where scanning polyhedra
 722 matters.  While the user has full control on generated code quality,
 723 CLooG is designed to avoid control overhead and to produce a very
 724 effective code.")
 725     (license gpl2+)))
 726
 727 (define-public gnu-c-manual
 728   (package
 729     (name "gnu-c-manual")
 730     (version "0.2.5")
 731     (source (origin
 732               (method url-fetch)
 733               (uri (string-append "mirror://gnu/gnu-c-manual/gnu-c-manual-"
 734                                   version ".tar.gz"))
 735               (sha256
 736                (base32
 737                 "1sfsj9256w18qzylgag2h5h377aq8in8929svblfnj9svfriqcys"))))
 738     (build-system gnu-build-system)
 739     (native-inputs `(("texinfo" ,texinfo)))
 740     (arguments
 741      '(#:phases (modify-phases %standard-phases
 742                   (delete 'configure)
 743                   (delete 'check)
 744                   (replace 'build
 745                            (lambda _
 746                              (zero? (system* "make"
 747                                              "gnu-c-manual.info"
 748                                              "gnu-c-manual.html"))))
 749                   (replace 'install
 750                            (lambda* (#:key outputs #:allow-other-keys)
 751                              (let* ((out (assoc-ref outputs "out"))
 752                                     (info (string-append out "/share/info"))
 753                                     (html (string-append
 754                                            out "/share/doc/gnu-c-manual")))
 755                                (mkdir-p info)
 756                                (mkdir-p html)
 757
 758                                (for-each (lambda (file)
 759                                            (copy-file file
 760                                                       (string-append info "/"
 761                                                                      file)))
 762                                          (find-files "." "\\.info(-[0-9])?$"))
 763                                (for-each (lambda (file)
 764                                            (copy-file file
 765                                                       (string-append html "/"
 766                                                                      file)))
 767                                          (find-files "." "\\.html$"))
 768                                #t))))))
 769     (synopsis "Reference manual for the C programming language")
 770     (description
 771      "This is a reference manual for the C programming language, as
 772 implemented by the GNU C Compiler (gcc).  As a reference, it is not intended
 773 to be a tutorial of the language.  Rather, it outlines all of the constructs
 774 of the language.  Library functions are not included.")
 775     (home-page "https://www.gnu.org/software/gnu-c-manual/")
 776     (license fdl1.3+)))